lib/SQL/Translator/Parser/PostgreSQL.pm

   1 package SQL::Translator::Parser::PostgreSQL;
   2
   3 =head1 NAME
   4
   5 SQL::Translator::Parser::PostgreSQL - parser for PostgreSQL
   6
   7 =head1 SYNOPSIS
   8
   9   use SQL::Translator;
  10   use SQL::Translator::Parser::PostgreSQL;
  11
  12   my $translator = SQL::Translator->new;
  13   $translator->parser("SQL::Translator::Parser::PostgreSQL");
  14
  15 =head1 DESCRIPTION
  16
  17 The grammar was started from the MySQL parsers.  Here is the description
  18 from PostgreSQL:
  19
  20 Table:
  21 (http://www.postgresql.org/docs/view.php?version=7.3&idoc=1&file=sql-createtable.html)
  22
  23   CREATE [ [ LOCAL ] { TEMPORARY | TEMP } ] TABLE table_name (
  24       { column_name data_type [ DEFAULT default_expr ]
  25          [ column_constraint [, ... ] ]
  26       | table_constraint }  [, ... ]
  27   )
  28   [ INHERITS ( parent_table [, ... ] ) ]
  29   [ WITH OIDS | WITHOUT OIDS ]
  30
  31   where column_constraint is:
  32
  33   [ CONSTRAINT constraint_name ]
  34   { NOT NULL | NULL | UNIQUE | PRIMARY KEY |
  35     CHECK (expression) |
  36     REFERENCES reftable [ ( refcolumn ) ] [ MATCH FULL | MATCH PARTIAL ]
  37       [ ON DELETE action ] [ ON UPDATE action ] }
  38   [ DEFERRABLE | NOT DEFERRABLE ]
  39   [ INITIALLY DEFERRED | INITIALLY IMMEDIATE ]
  40
  41   and table_constraint is:
  42
  43   [ CONSTRAINT constraint_name ]
  44   { UNIQUE ( column_name [, ... ] ) |
  45     PRIMARY KEY ( column_name [, ... ] ) |
  46     CHECK ( expression ) |
  47     FOREIGN KEY ( column_name [, ... ] )
  48      REFERENCES reftable [ ( refcolumn [, ... ] ) ]
  49       [ MATCH FULL | MATCH PARTIAL ]
  50       [ ON DELETE action ] [ ON UPDATE action ] }
  51   [ DEFERRABLE | NOT DEFERRABLE ]
  52   [ INITIALLY DEFERRED | INITIALLY IMMEDIATE ]
  53
  54 Index:
  55 (http://www.postgresql.org/docs/view.php?version=7.3&idoc=1&file=sql-createindex.html)
  56
  57   CREATE [ UNIQUE ] INDEX index_name ON table
  58       [ USING acc_method ] ( column [ ops_name ] [, ...] )
  59       [ WHERE predicate ]
  60   CREATE [ UNIQUE ] INDEX index_name ON table
  61       [ USING acc_method ] ( func_name( column [, ... ]) [ ops_name ] )
  62       [ WHERE predicate ]
  63
  64 Alter table:
  65
  66   ALTER TABLE [ ONLY ] table [ * ]
  67       ADD [ COLUMN ] column type [ column_constraint [ ... ] ]
  68   ALTER TABLE [ ONLY ] table [ * ]
  69       ALTER [ COLUMN ] column { SET DEFAULT value | DROP DEFAULT }
  70   ALTER TABLE [ ONLY ] table [ * ]
  71       ALTER [ COLUMN ] column SET STATISTICS integer
  72   ALTER TABLE [ ONLY ] table [ * ]
  73       RENAME [ COLUMN ] column TO newcolumn
  74   ALTER TABLE table
  75       RENAME TO new_table
  76   ALTER TABLE table
  77       ADD table_constraint_definition
  78   ALTER TABLE [ ONLY ] table
  79           DROP CONSTRAINT constraint { RESTRICT | CASCADE }
  80   ALTER TABLE table
  81           OWNER TO new_owner
  82
  83 View table:
  84
  85     CREATE [ OR REPLACE ] VIEW view [ ( column name list ) ] AS SELECT query
  86
  87 =cut
  88
  89 use strict;
  90 use warnings;
  91
  92 our $VERSION = '1.59';
  93
  94 our $DEBUG;
  95 $DEBUG   = 0 unless defined $DEBUG;
  96
  97 use Data::Dumper;
  98 use SQL::Translator::Utils qw/ddl_parser_instance/;
  99
 100 use base qw(Exporter);
 101 our @EXPORT_OK = qw(parse);
 102
 103 our $GRAMMAR = <<'END_OF_GRAMMAR';
 104
 105 { my ( %tables, @views, @triggers, $table_order, $field_order, @table_comments) }
 106
 107 #
 108 # The "eofile" rule makes the parser fail if any "statement" rule
 109 # fails.  Otherwise, the first successful match by a "statement"
 110 # won't cause the failure needed to know that the parse, as a whole,
 111 # failed. -ky
 112 #
 113 startrule : statement(s) eofile {
 114     {
 115         tables => \%tables,
 116         views => \@views,
 117         triggers => \@triggers,
 118     }
 119 }
 120
 121 eofile : /^\Z/
 122
 123 statement : create
 124   | comment_on_table
 125   | comment_on_column
 126   | comment_on_other
 127   | comment
 128   | alter
 129   | grant
 130   | revoke
 131   | drop
 132   | insert
 133   | connect
 134   | update
 135   | set
 136   | select
 137   | copy
 138   | readin_symbol
 139   | commit
 140   | <error>
 141
 142 commit : /commit/i ';'
 143
 144 connect : /^\s*\\connect.*\n/
 145
 146 set : /set/i /[^;]*/ ';'
 147
 148 revoke : /revoke/i WORD(s /,/) /on/i TABLE(?) table_id /from/i NAME(s /,/) ';'
 149     {
 150         my $table_info  = $item{'table_id'};
 151         my $schema_name = $table_info->{'schema_name'};
 152         my $table_name  = $table_info->{'table_name'};
 153         push @{ $tables{ $table_name }{'permissions'} }, {
 154             type       => 'revoke',
 155             actions    => $item[2],
 156             users      => $item[7],
 157         }
 158     }
 159
 160 revoke : /revoke/i WORD(s /,/) /on/i SCHEMA(?) schema_name /from/i NAME(s /,/) ';'
 161     { 1 }
 162
 163 grant : /grant/i WORD(s /,/) /on/i TABLE(?) table_id /to/i NAME(s /,/) ';'
 164     {
 165         my $table_info  = $item{'table_id'};
 166         my $schema_name = $table_info->{'schema_name'};
 167         my $table_name  = $table_info->{'table_name'};
 168         push @{ $tables{ $table_name }{'permissions'} }, {
 169             type       => 'grant',
 170             actions    => $item[2],
 171             users      => $item[7],
 172         }
 173     }
 174
 175 grant : /grant/i WORD(s /,/) /on/i SCHEMA(?) schema_name /to/i NAME(s /,/) ';'
 176     { 1 }
 177
 178 drop : /drop/i /[^;]*/ ';'
 179
 180 string :
 181    /'(\.|''|[^\\'])*'/
 182
 183 nonstring : /[^;\'"]+/
 184
 185 statement_body : string | nonstring
 186
 187 insert : /insert/i statement_body(s?) ';'
 188
 189 update : /update/i statement_body(s?) ';'
 190
 191 #
 192 # Create table.
 193 #
 194 create : CREATE temporary(?) TABLE table_id '(' create_definition(s? /,/) ')' table_option(s?) ';'
 195     {
 196         my $table_info  = $item{'table_id'};
 197         my $schema_name = $table_info->{'schema_name'};
 198         my $table_name  = $table_info->{'table_name'};
 199         $tables{ $table_name }{'order'}       = ++$table_order;
 200         $tables{ $table_name }{'schema_name'} = $schema_name;
 201         $tables{ $table_name }{'table_name'}  = $table_name;
 202
 203         $tables{ $table_name }{'temporary'} = $item[2][0];
 204
 205         if ( @table_comments ) {
 206             $tables{ $table_name }{'comments'} = [ @table_comments ];
 207             @table_comments = ();
 208         }
 209
 210         my @constraints;
 211         for my $definition ( @{ $item[6] } ) {
 212             if ( $definition->{'supertype'} eq 'field' ) {
 213                 my $field_name = $definition->{'name'};
 214                 $tables{ $table_name }{'fields'}{ $field_name } =
 215                     { %$definition, order => $field_order++ };
 216
 217                 for my $constraint ( @{ $definition->{'constraints'} || [] } ) {
 218                     $constraint->{'fields'} = [ $field_name ];
 219                     push @{ $tables{ $table_name }{'constraints'} },
 220                         $constraint;
 221                 }
 222             }
 223             elsif ( $definition->{'supertype'} eq 'constraint' ) {
 224                 push @{ $tables{ $table_name }{'constraints'} }, $definition;
 225             }
 226             elsif ( $definition->{'supertype'} eq 'index' ) {
 227                 push @{ $tables{ $table_name }{'indices'} }, $definition;
 228             }
 229         }
 230
 231         for my $option ( @{ $item[8] } ) {
 232             $tables{ $table_name }{'table_options(s?)'}{ $option->{'type'} } =
 233                 $option;
 234         }
 235
 236         1;
 237     }
 238
 239 create : CREATE unique(?) /(index|key)/i index_name /on/i table_id using_method(?) '(' field_name(s /,/) ')' where_predicate(?) ';'
 240     {
 241         my $table_info  = $item{'table_id'};
 242         my $schema_name = $table_info->{'schema_name'};
 243         my $table_name  = $table_info->{'table_name'};
 244         push @{ $tables{ $table_name }{'indices'} },
 245             {
 246                 name      => $item{'index_name'},
 247                 supertype => $item{'unique'}[0] ? 'constraint' : 'index',
 248                 type      => $item{'unique'}[0] ? 'unique'     : 'normal',
 249                 fields    => $item[9],
 250                 method    => $item{'using_method'}[0],
 251             }
 252         ;
 253     }
 254
 255 create : CREATE or_replace(?) temporary(?) VIEW view_id view_fields(?) /AS/i view_target ';'
 256     {
 257         push @views, {
 258             schema_name  => $item{view_id}{schema_name},
 259             view_name    => $item{view_id}{view_name},
 260             sql          => $item{view_target},
 261             fields       => $item[6],
 262             is_temporary => $item[3][0],
 263         }
 264     }
 265
 266 trigger_name : NAME
 267
 268 trigger_scope : /FOR/i /EACH/i /(ROW|STATEMENT)/i { $return = lc $1 }
 269
 270 before_or_after : /(before|after)/i { $return = lc $1 }
 271
 272 trigger_action : /.+/
 273
 274 database_event : /insert|update|delete/i
 275 database_events : database_event(s /OR/)
 276
 277 create : CREATE /TRIGGER/i trigger_name before_or_after database_events /ON/i table_id trigger_scope(?) trigger_action
 278     {
 279         # Hack to pass roundtrip tests which have trigger statements terminated by double semicolon
 280         # and expect the returned data to have the same
 281         my $action = $item{trigger_action};
 282         $action =~ s/;$//;
 283
 284         push @triggers, {
 285             name => $item{trigger_name},
 286             perform_action_when => $item{before_or_after},
 287             database_events => $item{database_events},
 288             on_table => $item{table_id}{table_name},
 289             scope => $item{'trigger_scope(?)'}[0],
 290             action => $action,
 291         }
 292     }
 293
 294 #
 295 # Create anything else (e.g., domain, etc.)
 296 #
 297 create : CREATE WORD /[^;]+/ ';'
 298     { @table_comments = (); }
 299
 300 using_method : /using/i WORD { $item[2] }
 301
 302 where_predicate : /where/i /[^;]+/
 303
 304 create_definition : field
 305     | table_constraint
 306     | <error>
 307
 308 comment : /^\s*(?:#|-{2})(.*)\n/
 309     {
 310         my $comment =  $item[1];
 311         $comment    =~ s/^\s*(#|-*)\s*//;
 312         $comment    =~ s/\s*$//;
 313         $return     = $comment;
 314         push @table_comments, $comment;
 315     }
 316
 317 comment_on_table : /comment/i /on/i /table/i table_id /is/i comment_phrase ';'
 318     {
 319         my $table_info  = $item{'table_id'};
 320         my $schema_name = $table_info->{'schema_name'};
 321         my $table_name  = $table_info->{'table_name'};
 322         push @{ $tables{ $table_name }{'comments'} }, $item{'comment_phrase'};
 323     }
 324
 325 comment_on_column : /comment/i /on/i /column/i column_name /is/i comment_phrase ';'
 326     {
 327         my $table_name = $item[4]->{'table'};
 328         my $field_name = $item[4]->{'field'};
 329         if ($tables{ $table_name }{'fields'}{ $field_name } ) {
 330           push @{ $tables{ $table_name }{'fields'}{ $field_name }{'comments'} },
 331               $item{'comment_phrase'};
 332         }
 333         else {
 334            die "No such column as $table_name.$field_name";
 335         }
 336     }
 337
 338 comment_on_other : /comment/i /on/i /\w+/ /\w+/ /is/i comment_phrase ';'
 339     {
 340         push(@table_comments, $item{'comment_phrase'});
 341     }
 342
 343 # [added by cjm 20041019]
 344 # [TODO: other comment-on types]
 345 # for now we just have a general mechanism for handling other
 346 # kinds of comments than table/column; I'm not sure of the best
 347 # way to incorporate these into the datamodel
 348 #
 349 # this is the exhaustive list of types of comment:
 350 #COMMENT ON DATABASE my_database IS 'Development Database';
 351 #COMMENT ON INDEX my_index IS 'Enforces uniqueness on employee id';
 352 #COMMENT ON RULE my_rule IS 'Logs UPDATES of employee records';
 353 #COMMENT ON SEQUENCE my_sequence IS 'Used to generate primary keys';
 354 #COMMENT ON TABLE my_table IS 'Employee Information';
 355 #COMMENT ON TYPE my_type IS 'Complex Number support';
 356 #COMMENT ON VIEW my_view IS 'View of departmental costs';
 357 #COMMENT ON COLUMN my_table.my_field IS 'Employee ID number';
 358 #COMMENT ON TRIGGER my_trigger ON my_table IS 'Used for R.I.';
 359 #
 360 # this is tested by test 08
 361
 362 column_name : NAME '.' NAME
 363     { $return = { table => $item[1], field => $item[3] } }
 364
 365 comment_phrase : /null/i
 366     { $return = 'NULL' }
 367     | SQSTRING
 368
 369 field : field_comment(s?) field_name data_type field_meta(s?) field_comment(s?)
 370     {
 371         my ( $default, @constraints, $is_pk );
 372         my $is_nullable = 1;
 373         for my $meta ( @{ $item[4] } ) {
 374             if ( $meta->{'type'} eq 'default' ) {
 375                 $default = $meta;
 376                 next;
 377             }
 378             elsif ( $meta->{'type'} eq 'not_null' ) {
 379                 $is_nullable = 0;
 380             }
 381             elsif ( $meta->{'type'} eq 'primary_key' ) {
 382                 $is_pk = 1;
 383             }
 384
 385             push @constraints, $meta if $meta->{'supertype'} eq 'constraint';
 386         }
 387
 388         my @comments = ( @{ $item[1] }, @{ $item[5] } );
 389
 390         $return = {
 391             supertype         => 'field',
 392             name              => $item{'field_name'},
 393             data_type         => $item{'data_type'}{'type'},
 394             size              => $item{'data_type'}{'size'},
 395             is_nullable       => $is_nullable,
 396             default           => $default->{'value'},
 397             constraints       => [ @constraints ],
 398             comments          => [ @comments ],
 399             is_primary_key    => $is_pk || 0,
 400             is_auto_increment => $item{'data_type'}{'is_auto_increment'},
 401         }
 402     }
 403     | <error>
 404
 405 field_comment : /^\s*(?:#|-{2})(.*)\n/
 406     {
 407         my $comment =  $item[1];
 408         $comment    =~ s/^\s*(#|-*)\s*//;
 409         $comment    =~ s/\s*$//;
 410         $return     = $comment;
 411     }
 412
 413 field_meta : default_val
 414     | column_constraint
 415
 416 view_fields : '(' field_name(s /,/) ')'
 417     { $return = join (',', @{$item[2]} ) }
 418
 419 column_constraint : constraint_name(?) column_constraint_type deferrable(?) deferred(?)
 420     {
 421         my $desc       = $item{'column_constraint_type'};
 422         my $type       = $desc->{'type'};
 423         my $fields     = $desc->{'fields'}     || [];
 424         my $expression = $desc->{'expression'} || '';
 425
 426         $return              =  {
 427             supertype        => 'constraint',
 428             name             => $item{'constraint_name'}[0] || '',
 429             type             => $type,
 430             expression       => $type eq 'check' ? $expression : '',
 431             deferrable       => $item{'deferrable'},
 432             deferred         => $item{'deferred'},
 433             reference_table  => $desc->{'reference_table'},
 434             reference_fields => $desc->{'reference_fields'},
 435             match_type       => $desc->{'match_type'},
 436             on_delete        => $desc->{'on_delete'} || $desc->{'on_delete_do'},
 437             on_update        => $desc->{'on_update'} || $desc->{'on_update_do'},
 438         }
 439     }
 440
 441 constraint_name : /constraint/i NAME { $item[2] }
 442
 443 column_constraint_type : /not null/i { $return = { type => 'not_null' } }
 444     |
 445     /null/i
 446         { $return = { type => 'null' } }
 447     |
 448     /unique/i
 449         { $return = { type => 'unique' } }
 450     |
 451     /primary key/i
 452         { $return = { type => 'primary_key' } }
 453     |
 454     /check/i '(' /[^)]+/ ')'
 455         { $return = { type => 'check', expression => $item[3] } }
 456     |
 457     /references/i table_id parens_word_list(?) match_type(?) key_action(s?)
 458     {
 459         my $table_info  = $item{'table_id'};
 460         my $schema_name = $table_info->{'schema_name'};
 461         my $table_name  = $table_info->{'table_name'};
 462         my ( $on_delete, $on_update );
 463         for my $action ( @{ $item[5] || [] } ) {
 464             $on_delete = $action->{'action'} if $action->{'type'} eq 'delete';
 465             $on_update = $action->{'action'} if $action->{'type'} eq 'update';
 466         }
 467
 468         $return              =  {
 469             type             => 'foreign_key',
 470             reference_table  => $table_name,
 471             reference_fields => $item[3][0],
 472             match_type       => $item[4][0],
 473             on_delete        => $on_delete,
 474             on_update        => $on_update,
 475         }
 476     }
 477
 478 table_id : schema_qualification(?) NAME {
 479     $return = { schema_name => $item[1][0], table_name => $item[2] }
 480 }
 481
 482 view_id : schema_qualification(?) NAME {
 483     $return = { schema_name => $item[1][0], view_name => $item[2] }
 484 }
 485
 486 view_target : /select|with/i /[^;]+/ {
 487     $return = "$item[1] $item[2]";
 488 }
 489
 490 # SELECT views _may_ support outer parens, and we used to produce
 491 # such sql, although non-standard. Use ugly lookeahead to parse
 492 view_target : '('   /select/i    / [^;]+ (?= \) ) /x    ')'    {
 493     $return = "$item[2] $item[3]"
 494 }
 495
 496 view_target_spec :
 497
 498 schema_qualification : NAME '.'
 499
 500 schema_name : NAME
 501
 502 field_name : NAME
 503
 504 double_quote: /"/
 505
 506 index_name : NAME
 507
 508 array_indicator : '[' ']'
 509     { $return = $item[1].$item[2] }
 510
 511 data_type : pg_data_type parens_value_list(?) array_indicator(?)
 512     {
 513         my $data_type = $item[1];
 514
 515         $data_type->{type} .= $item[3][0] if $item[3][0];
 516
 517         #
 518         # We can deduce some sizes from the data type's name.
 519         #
 520         if ( my @size = @{$item[2]} ) {
 521             $data_type->{'size'} = (@size == 1 ? $size[0] : \@size);
 522         }
 523
 524         $return  = $data_type;
 525     }
 526
 527 pg_data_type :
 528     /(bigint|int8)/i
 529         {
 530             $return = {
 531                 type => 'integer',
 532                 size => 20,
 533             };
 534         }
 535     |
 536     /(smallint|int2)/i
 537         {
 538             $return = {
 539                 type => 'integer',
 540                 size => 5,
 541             };
 542         }
 543     |
 544     /interval/i
 545         {
 546             $return = { type => 'interval' };
 547         }
 548     |
 549     /(integer|int4?)/i # interval must come before this
 550         {
 551             $return = {
 552                 type => 'integer',
 553                 size => 10,
 554             };
 555         }
 556     |
 557     /(real|float4)/i
 558         {
 559             $return = {
 560                 type => 'real',
 561                 size => 10,
 562             };
 563         }
 564     |
 565     /(double precision|float8?)/i
 566         {
 567             $return = {
 568                 type => 'float',
 569                 size => 20,
 570             };
 571         }
 572     |
 573     /(bigserial|serial8)/i
 574         {
 575             $return = {
 576                 type              => 'integer',
 577                 size              => 20,
 578                 is_auto_increment => 1,
 579             };
 580         }
 581     |
 582     /serial4?/i
 583         {
 584             $return = {
 585                 type              => 'integer',
 586                 size              => 11,
 587                 is_auto_increment => 1,
 588             };
 589         }
 590     |
 591     /(bit varying|varbit)/i
 592         {
 593             $return = { type => 'varbit' };
 594         }
 595     |
 596     /character varying/i
 597         {
 598             $return = { type => 'varchar' };
 599         }
 600     |
 601     /char(acter)?/i
 602         {
 603             $return = { type => 'char' };
 604         }
 605     |
 606     /bool(ean)?/i
 607         {
 608             $return = { type => 'boolean' };
 609         }
 610     |
 611     /bytea/i
 612         {
 613             $return = { type => 'bytea' };
 614         }
 615     |
 616     / ( timestamp (?:tz)? ) (?: \( \d \) )? ( \s with (?:out)? \s time \s zone )? /ix
 617         {
 618             $return = { type => 'timestamp' . ($2||'') };
 619         }
 620     |
 621     / ( time (?:tz)? ) (?: \( \d \) )? ( \s with (?:out)? \s time \s zone )? /ix
 622         {
 623             $return = { type => 'time' . ($2||'') };
 624         }
 625     |
 626     /text/i
 627         {
 628             $return = {
 629                 type => 'text',
 630                 size => 64_000,
 631             };
 632         }
 633     |
 634     /(bit|box|cidr|circle|date|inet|line|lseg|macaddr|money|numeric|decimal|path|point|polygon|varchar|json|hstore|uuid)/i
 635         {
 636             $return = { type => $item[1] };
 637         }
 638
 639 parens_value_list : '(' VALUE(s /,/) ')'
 640     { $item[2] }
 641
 642
 643 parens_word_list : '(' NAME(s /,/) ')'
 644     { $item[2] }
 645
 646 field_size : '(' num_range ')' { $item{'num_range'} }
 647
 648 num_range : DIGITS ',' DIGITS
 649     { $return = $item[1].','.$item[3] }
 650     | DIGITS
 651     { $return = $item[1] }
 652
 653 table_constraint : comment(s?) constraint_name(?) table_constraint_type deferrable(?) deferred(?) comment(s?)
 654     {
 655         my $desc       = $item{'table_constraint_type'};
 656         my $type       = $desc->{'type'};
 657         my $fields     = $desc->{'fields'};
 658         my $expression = $desc->{'expression'};
 659         my @comments   = ( @{ $item[1] }, @{ $item[-1] } );
 660
 661         $return              =  {
 662             name             => $item[2][0] || '',
 663             supertype        => 'constraint',
 664             type             => $type,
 665             fields           => $type ne 'check' ? $fields : [],
 666             expression       => $type eq 'check' ? $expression : '',
 667             deferrable       => $item{'deferrable'},
 668             deferred         => $item{'deferred'},
 669             reference_table  => $desc->{'reference_table'},
 670             reference_fields => $desc->{'reference_fields'},
 671             match_type       => $desc->{'match_type'},
 672             on_delete        => $desc->{'on_delete'} || $desc->{'on_delete_do'},
 673             on_update        => $desc->{'on_update'} || $desc->{'on_update_do'},
 674             comments         => [ @comments ],
 675         }
 676     }
 677
 678 table_constraint_type : /primary key/i '(' NAME(s /,/) ')'
 679     {
 680         $return = {
 681             type   => 'primary_key',
 682             fields => $item[3],
 683         }
 684     }
 685     |
 686     /unique/i '(' NAME(s /,/) ')'
 687     {
 688         $return    =  {
 689             type   => 'unique',
 690             fields => $item[3],
 691         }
 692     }
 693     |
 694     /check/i '(' /[^)]+/ ')'
 695     {
 696         $return        =  {
 697             type       => 'check',
 698             expression => $item[3],
 699         }
 700     }
 701     |
 702     /foreign key/i '(' NAME(s /,/) ')' /references/i table_id parens_word_list(?) match_type(?) key_action(s?)
 703     {
 704         my ( $on_delete, $on_update );
 705         for my $action ( @{ $item[9] || [] } ) {
 706             $on_delete = $action->{'action'} if $action->{'type'} eq 'delete';
 707             $on_update = $action->{'action'} if $action->{'type'} eq 'update';
 708         }
 709
 710         $return              =  {
 711             supertype        => 'constraint',
 712             type             => 'foreign_key',
 713             fields           => $item[3],
 714             reference_table  => $item[6]->{'table_name'},
 715             reference_fields => $item[7][0],
 716             match_type       => $item[8][0],
 717             on_delete     => $on_delete || '',
 718             on_update     => $on_update || '',
 719         }
 720     }
 721
 722 deferrable : not(?) /deferrable/i
 723     {
 724         $return = ( $item[1] =~ /not/i ) ? 0 : 1;
 725     }
 726
 727 deferred : /initially/i /(deferred|immediate)/i { $item[2] }
 728
 729 match_type : /match/i /partial|full|simple/i { $item[2] }
 730
 731 key_action : key_delete
 732     |
 733     key_update
 734
 735 key_delete : /on delete/i key_mutation
 736     {
 737         $return = {
 738             type   => 'delete',
 739             action => $item[2],
 740         };
 741     }
 742
 743 key_update : /on update/i key_mutation
 744     {
 745         $return = {
 746             type   => 'update',
 747             action => $item[2],
 748         };
 749     }
 750
 751 key_mutation : /no action/i { $return = 'no_action' }
 752     |
 753     /restrict/i { $return = 'restrict' }
 754     |
 755     /cascade/i { $return = 'cascade' }
 756     |
 757     /set null/i { $return = 'set null' }
 758     |
 759     /set default/i { $return = 'set default' }
 760
 761 alter : alter_table table_id add_column field ';'
 762     {
 763         my $field_def = $item[4];
 764         $tables{ $item[2]->{'table_name'} }{'fields'}{ $field_def->{'name'} } = {
 765             %$field_def, order => $field_order++
 766         };
 767         1;
 768     }
 769
 770 alter : alter_table table_id ADD table_constraint ';'
 771     {
 772         my $table_name = $item[2]->{'table_name'};
 773         my $constraint = $item[4];
 774         push @{ $tables{ $table_name }{'constraints'} }, $constraint;
 775         1;
 776     }
 777
 778 alter : alter_table table_id drop_column NAME restrict_or_cascade(?) ';'
 779     {
 780         $tables{ $item[2]->{'table_name'} }{'fields'}{ $item[4] }{'drop'} = 1;
 781         1;
 782     }
 783
 784 alter : alter_table table_id alter_column NAME alter_default_val ';'
 785     {
 786         $tables{ $item[2]->{'table_name'} }{'fields'}{ $item[4] }{'default'} =
 787             $item[5]->{'value'};
 788         1;
 789     }
 790
 791 #
 792 # These will just parse for now but won't affect the structure. - ky
 793 #
 794 alter : alter_table table_id /rename/i /to/i NAME ';'
 795     { 1 }
 796
 797 alter : alter_table table_id alter_column NAME SET /statistics/i INTEGER ';'
 798     { 1 }
 799
 800 alter : alter_table table_id alter_column NAME SET /storage/i storage_type ';'
 801     { 1 }
 802
 803 alter : alter_table table_id rename_column NAME /to/i NAME ';'
 804     { 1 }
 805
 806 alter : alter_table table_id DROP /constraint/i NAME restrict_or_cascade ';'
 807     { 1 }
 808
 809 alter : alter_table table_id /owner/i /to/i NAME ';'
 810     { 1 }
 811
 812 alter : alter_sequence NAME /owned/i /by/i column_name ';'
 813     { 1 }
 814
 815 storage_type : /(plain|external|extended|main)/i
 816
 817 temporary : /temp(orary)?\b/i
 818   {
 819     1;
 820   }
 821
 822 or_replace : /or replace/i
 823
 824 alter_default_val : SET default_val
 825     {
 826         $return = { value => $item[2]->{'value'} }
 827     }
 828     | DROP DEFAULT
 829     {
 830         $return = { value => undef }
 831     }
 832
 833 #
 834 # This is a little tricky to get right, at least WRT to making the
 835 # tests pass.  The problem is that the constraints are stored just as
 836 # a list (no name access), and the tests expect the constraints in a
 837 # particular order.  I'm going to leave the rule but disable the code
 838 # for now. - ky
 839 #
 840 alter : alter_table table_id alter_column NAME alter_nullable ';'
 841     {
 842 #        my $table_name  = $item[2]->{'table_name'};
 843 #        my $field_name  = $item[4];
 844 #        my $is_nullable = $item[5]->{'is_nullable'};
 845 #
 846 #        $tables{ $table_name }{'fields'}{ $field_name }{'is_nullable'} =
 847 #            $is_nullable;
 848 #
 849 #        if ( $is_nullable ) {
 850 #            1;
 851 #            push @{ $tables{ $table_name }{'constraints'} }, {
 852 #                type   => 'not_null',
 853 #                fields => [ $field_name ],
 854 #            };
 855 #        }
 856 #        else {
 857 #            for my $i (
 858 #                0 .. $#{ $tables{ $table_name }{'constraints'} || [] }
 859 #            ) {
 860 #                my $c = $tables{ $table_name }{'constraints'}[ $i ] or next;
 861 #                my $fields = join( '', @{ $c->{'fields'} || [] } ) or next;
 862 #                if ( $c->{'type'} eq 'not_null' && $fields eq $field_name ) {
 863 #                    delete $tables{ $table_name }{'constraints'}[ $i ];
 864 #                    last;
 865 #                }
 866 #            }
 867 #        }
 868
 869         1;
 870     }
 871
 872 alter_nullable : SET not_null
 873     {
 874         $return = { is_nullable => 0 }
 875     }
 876     | DROP not_null
 877     {
 878         $return = { is_nullable => 1 }
 879     }
 880
 881 not_null : /not/i /null/i
 882
 883 not : /not/i
 884
 885 add_column : ADD COLUMN(?)
 886
 887 alter_table : ALTER TABLE ONLY(?)
 888
 889 alter_sequence : ALTER SEQUENCE
 890
 891 drop_column : DROP COLUMN(?)
 892
 893 alter_column : ALTER COLUMN(?)
 894
 895 rename_column : /rename/i COLUMN(?)
 896
 897 restrict_or_cascade : /restrict/i |
 898     /cascade/i
 899
 900 # Handle functions that can be called
 901 select : SELECT select_function ';'
 902     { 1 }
 903
 904 # Read the setval function but don't do anything with it because this parser
 905 # isn't handling sequences
 906 select_function : schema_qualification(?) /setval/i '(' VALUE /,/ VALUE /,/ /(true|false)/i ')'
 907     { 1 }
 908
 909 # Skipping all COPY commands
 910 copy : COPY WORD /[^;]+/ ';' { 1 }
 911     { 1 }
 912
 913 # The "\." allows reading in from STDIN but this isn't needed for schema
 914 # creation, so it is skipped.
 915 readin_symbol : '\.'
 916     {1}
 917
 918 #
 919 # End basically useless stuff. - ky
 920 #
 921
 922 create_table : CREATE TABLE
 923
 924 create_index : CREATE /index/i
 925
 926 default_val  : DEFAULT DEFAULT_VALUE ( '::' data_type )(?)
 927     {
 928         my $val =  $item[2];
 929         $val =~ s/^\((\d+)\)\z/$1/; # for example (0)::smallint
 930         $return =  {
 931             supertype => 'constraint',
 932             type      => 'default',
 933             value     => $val,
 934         }
 935     }
 936     | /null/i
 937     {
 938         $return =  {
 939             supertype => 'constraint',
 940             type      => 'default',
 941             value     => 'NULL',
 942         }
 943     }
 944
 945 DEFAULT_VALUE : VALUE
 946     | /\w+\(.*\)/
 947     | /\w+/
 948     | /\(\d+\)/
 949
 950 name_with_opt_paren : NAME parens_value_list(s?)
 951     { $item[2][0] ? "$item[1]($item[2][0][0])" : $item[1] }
 952
 953 unique : /unique/i { 1 }
 954
 955 key : /key/i | /index/i
 956
 957 table_option : /inherits/i '(' NAME(s /,/) ')'
 958     {
 959         $return = { type => 'inherits', table_name => $item[3] }
 960     }
 961     |
 962     /with(out)? oids/i
 963     {
 964         $return = { type => $item[1] =~ /out/i ? 'without_oids' : 'with_oids' }
 965     }
 966
 967 ADD : /add/i
 968
 969 ALTER : /alter/i
 970
 971 CREATE : /create/i
 972
 973 ONLY : /only/i
 974
 975 DEFAULT : /default/i
 976
 977 DROP : /drop/i
 978
 979 COLUMN : /column/i
 980
 981 TABLE : /table/i
 982
 983 VIEW : /view/i
 984
 985 SCHEMA : /schema/i
 986
 987 SEMICOLON : /\s*;\n?/
 988
 989 SEQUENCE : /sequence/i
 990
 991 SELECT : /select/i
 992
 993 COPY : /copy/i
 994
 995 INTEGER : /\d+/
 996
 997 WORD : /\w+/
 998
 999 DIGITS : /\d+/
1000
1001 COMMA : ','
1002
1003 SET : /set/i
1004
1005 NAME : DQSTRING
1006     | /\w+/
1007
1008 DQSTRING : '"' /((?:[^"]|"")+)/ '"'
1009     { ($return = $item[2]) =~ s/""/"/g; }
1010
1011 SQSTRING : "'" /((?:[^']|'')*)/ "'"
1012     { ($return = $item[2]) =~ s/''/'/g }
1013
1014 VALUE : /[-+]?\d*\.?\d+(?:[eE]\d+)?/
1015     | SQSTRING
1016     | /null/i
1017     { 'NULL' }
1018
1019 END_OF_GRAMMAR
1020
1021 sub parse {
1022     my ( $translator, $data ) = @_;
1023
1024     # Enable warnings within the Parse::RecDescent module.
1025     local $::RD_ERRORS = 1 unless defined $::RD_ERRORS; # Make sure the parser dies when it encounters an error
1026     local $::RD_WARN   = 1 unless defined $::RD_WARN; # Enable warnings. This will warn on unused rules &c.
1027     local $::RD_HINT   = 1 unless defined $::RD_HINT; # Give out hints to help fix problems.
1028
1029     local $::RD_TRACE  = $translator->trace ? 1 : undef;
1030     local $DEBUG       = $translator->debug;
1031
1032     my $parser = ddl_parser_instance('PostgreSQL');
1033
1034     my $result = $parser->startrule($data);
1035     die "Parse failed.\n" unless defined $result;
1036     warn Dumper($result) if $DEBUG;
1037
1038     my $schema = $translator->schema;
1039     my @tables = sort {
1040         ( $result->{tables}{ $a }{'order'} || 0 ) <=> ( $result->{tables}{ $b }{'order'} || 0 )
1041     } keys %{ $result->{tables} };
1042
1043     for my $table_name ( @tables ) {
1044         my $tdata =  $result->{tables}{ $table_name };
1045         my $table =  $schema->add_table(
1046             #schema => $tdata->{'schema_name'},
1047             name   => $tdata->{'table_name'},
1048         ) or die "Couldn't create table '$table_name': " . $schema->error;
1049
1050         $table->extra(temporary => 1) if $tdata->{'temporary'};
1051
1052         $table->comments( $tdata->{'comments'} );
1053
1054         my @fields = sort {
1055             $tdata->{'fields'}{ $a }{'order'}
1056             <=>
1057             $tdata->{'fields'}{ $b }{'order'}
1058         } keys %{ $tdata->{'fields'} };
1059
1060         for my $fname ( @fields ) {
1061             my $fdata = $tdata->{'fields'}{ $fname };
1062             next if $fdata->{'drop'};
1063             my $field = $table->add_field(
1064                 name              => $fdata->{'name'},
1065                 data_type         => $fdata->{'data_type'},
1066                 size              => $fdata->{'size'},
1067                 default_value     => $fdata->{'default'},
1068                 is_auto_increment => $fdata->{'is_auto_increment'},
1069                 is_nullable       => $fdata->{'is_nullable'},
1070                 comments          => $fdata->{'comments'},
1071             ) or die $table->error;
1072
1073             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
1074
1075             for my $cdata ( @{ $fdata->{'constraints'} } ) {
1076                 next unless $cdata->{'type'} eq 'foreign_key';
1077                 $cdata->{'fields'} ||= [ $field->name ];
1078                 push @{ $tdata->{'constraints'} }, $cdata;
1079             }
1080         }
1081
1082         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
1083             my $index  =  $table->add_index(
1084                 name   => $idata->{'name'},
1085                 type   => uc $idata->{'type'},
1086                 fields => $idata->{'fields'},
1087             ) or die $table->error . ' ' . $table->name;
1088         }
1089
1090         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
1091             my $constraint       =  $table->add_constraint(
1092                 name             => $cdata->{'name'},
1093                 type             => $cdata->{'type'},
1094                 fields           => $cdata->{'fields'},
1095                 reference_table  => $cdata->{'reference_table'},
1096                 reference_fields => $cdata->{'reference_fields'},
1097                 match_type       => $cdata->{'match_type'} || '',
1098                 on_delete        => $cdata->{'on_delete'} || $cdata->{'on_delete_do'},
1099                 on_update        => $cdata->{'on_update'} || $cdata->{'on_update_do'},
1100                 expression       => $cdata->{'expression'},
1101             ) or die "Can't add constraint of type '" .
1102                 $cdata->{'type'} .  "' to table '" . $table->name .
1103                 "': " . $table->error;
1104         }
1105     }
1106
1107     for my $vinfo (@{$result->{views}}) {
1108       my $sql = $vinfo->{sql};
1109       $sql =~ s/\A\s+|\s+\z//g;
1110       my $view = $schema->add_view (
1111         name => $vinfo->{view_name},
1112         sql => $sql,
1113         fields => $vinfo->{fields},
1114       );
1115
1116       $view->extra ( temporary => 1 ) if $vinfo->{is_temporary};
1117     }
1118
1119     for my $trigger (@{ $result->{triggers} }) {
1120         $schema->add_trigger( %$trigger );
1121     }
1122
1123     return 1;
1124 }
1125
1126 1;
1127
1128 # -------------------------------------------------------------------
1129 # Rescue the drowning and tie your shoestrings.
1130 # Henry David Thoreau
1131 # -------------------------------------------------------------------
1132
1133 =pod
1134
1135 =head1 AUTHORS
1136
1137 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>,
1138 Allen Day E<lt>allenday@ucla.eduE<gt>.
1139
1140 =head1 SEE ALSO
1141
1142 perl(1), Parse::RecDescent.
1143
1144 =cut