bin/sqlt

   1 #!/usr/bin/perl -w
   2 # vim: set ft=perl:
   3
   4 # -------------------------------------------------------------------
   5 # $Id$
   6 # -------------------------------------------------------------------
   7 # Copyright (C) 2002-2009 SQLFairy Authors
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License as
  11 # published by the Free Software Foundation; version 2.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  21 # 02111-1307  USA
  22 # -------------------------------------------------------------------
  23
  24 =head1 NAME
  25
  26 sqlt - convert SQL schema using SQL::Translator
  27
  28 =head1 SYNOPSIS
  29
  30 For help:
  31
  32   sqlt -h|--help
  33
  34 For a list of all parsers and producers:
  35
  36   sqlt -l|--list
  37
  38 To translate a schema:
  39
  40   sqlt -f|--from|--parser MySQL
  41        -t|--to|--producer Oracle
  42        [options]
  43        file [file2 ...]
  44
  45   General Options:
  46
  47     -d|--debug         Print debug info
  48     -v|--validate      Validate the schema
  49     --version          Show the version of SQL::Translator
  50     --trace            Print parser trace info
  51     --show-warnings    Print warnings to STDERR
  52
  53   General Parser Options:
  54
  55     --skip             Comma-separated list of tables to skip (only implemented in some parsers)
  56     --ignore_opts      Comma-separated list of table options to ignore
  57
  58   DBI Parser Options:
  59
  60     --dsn              DSN for connecting to database
  61                        (see also --use-same-auth below)
  62     --db-user          Database user
  63     --db-password      Database password
  64
  65   xSV Parser Options:
  66
  67     --fs               The field separator
  68     --rs               The record separator
  69     --no-trim          Don't trim whitespace on fields
  70     --no-scan          Don't scan fields for data types and sizes
  71
  72   MySQL Parser Options:
  73
  74     --mysql-parser-version  Target MySQL parser version for dealing with
  75                               /*! comments; default = 30000
  76
  77   MySQL Producer Options:
  78
  79     --mysql-version  MySQL server version
  80
  81   General Producer Options
  82
  83     --producer-db-user   Database user for producer
  84     --producer-db-pass   Database password for producer
  85     --producer-dsn       DSN for producer
  86     --use-same-auth      Use these DSN, user, password for producer output
  87
  88   DB Producer Options:
  89
  90     --add-drop-table   Add 'DROP TABLE' statements before creates
  91     --quote-table-names  Quote all table names in statements
  92     --quote-field-names  Qjuote all field names in statements
  93     --no-comments      Don't include comments in SQL output
  94
  95   PostgreSQL Producer Options:
  96
  97     --postgres-version   PostgreSQL server version
  98
  99   Diagram Producer Options:
 100
 101     --imap-file        Filename to put image map data
 102     --imap-url         URL to use for image map
 103
 104   Dumper Producer Options:
 105
 106     --skip             Comma-separated list of tables to skip
 107     --skiplike         Regex for tables to skip
 108     --add-truncate     Add "TRUNCATE TABLE" statements for each table
 109
 110   HTML/POD Producer Options:
 111
 112     --pretty           Use CGI::Pretty for the output
 113     --title            Title of schema
 114
 115   TTSchema Producer Options:
 116
 117     --template             The path to the template
 118     --tt-var var=value     Pass extra variables to the template
 119     --tt-conf option=value Pass extra config options to Template
 120
 121   XML-SQLFairy Producer Options:
 122
 123     --add-prefix       Use an explicit namespace prefix of 'sqlf:'
 124     --prefix=<p>       Use the namespace prefix given as argument.
 125     --no-newlines      Write the XML as a single line.
 126     --indent=<n>       Use <n> characters of whitespace to indent the XML.
 127
 128   ClassDBI Producer Options:
 129
 130     --package          Base package name for Class::DBI modules.
 131
 132 =head1 DESCRIPTION
 133
 134 This script is part of the SQL Fairy project.  It will try to convert
 135 any source file for which it has a grammar into any format for which
 136 it has a producer.
 137
 138 If using "show-warnings," be sure to redirect STDERR to a separate file.
 139 In bash, you could do this:
 140
 141     $ sql_translator.pl -f MySQL -t PostgreSQL --show-warnings \
 142        file.sql 1>out 2>err
 143
 144 You can specify a parser or producer located in any module that Perl
 145 knows about, allowing you to easily substitute your own.
 146
 147 =cut
 148
 149 # -------------------------------------------------------------------
 150
 151 use strict;
 152 use Getopt::Long;
 153 use Pod::Usage;
 154 use SQL::Translator;
 155
 156 my $from;             # the original database
 157 my $to;               # the destination database
 158 my $help;             # show POD and bail
 159 my $stdin;            # whether to read STDIN for create script
 160 my $no_comments;      # whether to put comments in out file
 161 my $show_warnings;    # whether to show warnings from SQL::Translator
 162 my $add_drop_table;   # whether to add "DROP table" statements
 163 my $quote_table_names;  # whether to quote table names
 164 my $quote_field_names;  # whether to quote field names
 165 my $debug;            # whether to print debug info
 166 my $trace;            # whether to print parser trace
 167 my $list;             # list all parsers and producers
 168 my $no_trim;          # don't trim whitespace on xSV fields
 169 my $no_scan;          # don't scan xSV fields for data types and sizes
 170 my $field_separator;  # for xSV files
 171 my $record_separator; # for xSV files
 172 my $validate;         # whether to validate the parsed document
 173 my $imap_file;        # filename where to place image map coords
 174 my $imap_url;         # URL to use in making image map
 175 my $pretty;           # use CGI::Pretty instead of CGI (HTML producer)
 176 my $template;         # template to pass to TTSchema producer
 177 my %tt_vars;          # additional template vars to pass the TTSchema producer
 178 my %tt_conf;          # additional template conf to pass the TTSchema producer
 179 my $title;            # title for HTML/POD producer
 180 my $add_prefix;       # Use explicit namespace prefix (XML producer)
 181 my $prefix;           # Set explicit namespace prefix (XML producer)
 182 my $newlines;         # Add newlines around tags (XML producer)
 183 my $indent;           # Number of indent chars for XML
 184 my $package_name;     # Base class name for ClassDBI
 185 my $use_same_auth =0; # producer uses same DSN, user, password as parser
 186 my $dsn;              # DBI parser
 187 my $db_user;          # DBI parser
 188 my $db_password;      # DBI parser
 189 my $show_version;     # Show version and exit script
 190 my $skip;
 191 my $skiplike;
 192 my $ignore_opts;
 193 my $producer_db_user; # DSN     for producer (e.g. Dumper, ClassDBI)
 194 my $producer_db_password; # db_pass "
 195 my $producer_dsn;     # db_user "
 196 my $add_truncate;
 197 my $mysql_parser_version;  # MySQL parser arg for /*! comments
 198 my $postgres_version; # PostgreSQL version
 199 my $mysql_version; # MySQL version
 200
 201 GetOptions(
 202     'add-drop-table'   => \$add_drop_table,
 203     'quote_table_names'   => \$quote_table_names,
 204     'quote_field_names'   => \$quote_field_names,
 205     'd|debug'          => \$debug,
 206     'f|from|parser:s'  => \$from,
 207     'fs:s'             => \$field_separator,
 208     'h|help'           => \$help,
 209     'imap-file:s'      => \$imap_file,
 210     'imap-url:s'       => \$imap_url,
 211     't|to|producer:s'  => \$to,
 212     'l|list'           => \$list,
 213     'pretty!'          => \$pretty,
 214     'no-comments'      => \$no_comments,
 215     'no-scan'          => \$no_scan,
 216     'no-trim'          => \$no_trim,
 217     'rs:s'             => \$record_separator,
 218     'show-warnings'    => \$show_warnings,
 219     'template:s'       => \$template,
 220     'tt-var=s'         => \%tt_vars,
 221     'tt-conf=s'        => \%tt_conf,
 222     'title:s'          => \$title,
 223     'trace'            => \$trace,
 224     'v|validate'       => \$validate,
 225     'dsn:s'            => \$dsn,
 226     'db-user:s'        => \$db_user,
 227     'db-password:s'    => \$db_password,
 228     'producer-dsn:s'   => \$producer_dsn,
 229     'producer-db-user:s'=> \$producer_db_user,
 230     'producer-db-pass:s'=> \$producer_db_password,
 231     'skip:s'           => \$skip,
 232     'skiplike:s'       => \$skiplike,
 233     'ignore_opts:s'    => \$ignore_opts,
 234     'add_truncate'     => \$add_truncate,
 235     'add-prefix'       => \$add_prefix,
 236     'prefix:s'         => \$prefix,
 237     'indent:s'         => \$indent,
 238     'newlines!'        => \$newlines,
 239     'package=s'        => \$package_name,
 240     'use-same-auth'    => \$use_same_auth,
 241     'version'          => \$show_version,
 242     'mysql-parser-version=i' => \$mysql_parser_version,
 243     'postgres-version=f' => \$postgres_version,
 244     'mysql-version=f' => \$mysql_version,
 245 ) or pod2usage(2);
 246
 247 if ($use_same_auth) {
 248         $producer_dsn = $dsn;
 249         $producer_db_user = $db_user;
 250         $producer_db_password = $db_password;
 251 }
 252
 253 $from = 'DBI' if !defined $from && defined $dsn;
 254 my @files = @ARGV; # source files
 255 unless ( @files ) {
 256     if ( defined($from) && $from eq 'DBI' ) {
 257         @files = ('!');
 258     }
 259     else {
 260         @files = ('-');
 261     }
 262 }
 263
 264 pod2usage(1) if $help;
 265
 266 if ( $show_version ) {
 267     print "SQL::Translator v", $SQL::Translator::VERSION, "\n";
 268     exit(0);
 269 }
 270
 271 my $translator           =  SQL::Translator->new(
 272     debug                => $debug          ||  0,
 273     trace                => $trace          ||  0,
 274     no_comments          => $no_comments    ||  0,
 275     show_warnings        => $show_warnings  ||  0,
 276     add_drop_table       => $add_drop_table ||  0,
 277     quote_table_names    => $quote_table_names ||  1,
 278     quote_field_names    => $quote_field_names ||  1,
 279     validate             => $validate       ||  0,
 280     parser_args          => {
 281         trim_fields      => $no_trim ? 0 : 1,
 282         scan_fields      => $no_scan ? 0 : 1,
 283         field_separator  => $field_separator,
 284         record_separator => $record_separator,
 285         dsn              => $dsn,
 286         db_user          => $db_user,
 287         db_password      => $db_password,
 288         mysql_parser_version => $mysql_parser_version,
 289         skip => $skip,
 290         ignore_opts => $ignore_opts,
 291     },
 292     producer_args   => {
 293         imap_file        => $imap_file,
 294         imap_url         => $imap_url,
 295         pretty           => $pretty,
 296         ttfile           => $template,
 297         tt_vars          => \%tt_vars,
 298         tt_conf          => \%tt_conf,
 299         title            => $title,
 300         dsn              => $producer_dsn,
 301         db_user          => $producer_db_user,
 302         db_password      => $producer_db_password,
 303         skip             => $skip,
 304         skiplike         => $skiplike,
 305         add_truncate     => $add_truncate,
 306         add_prefix       => $add_prefix,
 307         prefix           => $prefix,
 308         indent           => $indent,
 309         newlines         => $newlines,
 310         postgres_version => $postgres_version,
 311         mysql_version    => $mysql_version,
 312             package_name     => $package_name,
 313     },
 314 );
 315
 316 if ( $list ) {
 317     my @parsers   = $translator->list_parsers;
 318     my @producers = $translator->list_producers;
 319
 320     for ( @parsers, @producers ) {
 321         if ( $_ =~ m/.+::(\w+)\.pm/ ) {
 322             $_ = $1;
 323         }
 324     }
 325
 326     print "\nParsers:\n",   map { "\t$_\n" } sort @parsers;
 327     print "\nProducers:\n", map { "\t$_\n" } sort @producers;
 328     print "\n";
 329     exit(0);
 330 }
 331
 332 pod2usage( msg => 'Please supply "from" and "to" arguments' )
 333     unless $from && $to;
 334
 335 $translator->parser($from);
 336 $translator->producer($to);
 337
 338 for my $file (@files) {
 339     my @args =
 340         ($file eq '-') ? (data => \*STDIN) :
 341         ($file eq '!') ? (data => '') :
 342         (file => $file);
 343
 344     my $output = $translator->translate(@args) or die
 345         "Error: " . $translator->error;
 346
 347     print $output;
 348 }
 349
 350 # ----------------------------------------------------
 351 # It is not all books that are as dull as their readers.
 352 # Henry David Thoreau
 353 # ----------------------------------------------------
 354
 355 =pod
 356
 357 =head1 AUTHOR
 358
 359 Ken Youens-Clark E<lt>kclark@cpan.orgE<gt>,
 360 darren chamberlain E<lt>darren@cpan.orgE<gt>.
 361
 362 =head1 SEE ALSO
 363
 364 SQL::Translator, L<http://sqlfairy.sourceforge.net>.
 365
 366 =cut