Makefile.PL

   1 use inc::Module::Install 1.00;
   2 use strict;
   3 use warnings;
   4
   5 # to deal wuth x.y.z versions properly
   6 configure_requires 'ExtUtils::MakeMaker' => '6.54';
   7
   8 my $deps = {
   9   requires => {
  10     'Class::Base'              => '0',
  11     'Class::Data::Inheritable' => '0.02',
  12     'Digest::SHA'              => '0',
  13     'Carp::Clan'               => '0',
  14     'IO::Dir'                  => '0',
  15     'IO::Scalar'               => '2.110',
  16     'Parse::RecDescent'        => '1.964001',
  17     'Pod::Usage'               => '0',
  18     'DBI'                      => '0',
  19     'File::ShareDir'           => '1.0',
  20     'File::Spec'               => '0',
  21     'Scalar::Util'             => '0',
  22     'XML::Writer'              => '0.500',
  23     'Moo'                      => '0.009007',
  24   },
  25   recommends => {
  26     'Template'                 => '2.20',
  27     'GD'                       => '0',
  28     'GraphViz'                 => '0',
  29     'Graph::Directed'          => '0',
  30     'Spreadsheet::ParseExcel'  => '0.41',
  31     'Text::ParseWords'         => '0',
  32     'Text::RecordParser'       => '0.02',
  33     'XML::LibXML'              => '1.69',
  34   },
  35   test_requires => {
  36     'YAML'                     => '0.66',
  37     'File::Basename'           => '0',
  38     'Test::More'               => '0.6',
  39     'Test::Differences'        => '0',
  40     'Test::Exception'          => '0',
  41   },
  42 };
  43
  44 perl_version '5.005';
  45
  46 name        'SQL-Translator';
  47 author      'Ken Youens-Clark <kclark@cpan.org>';
  48 abstract    'SQL DDL transformations and more';
  49 license     'gpl';
  50 repository  'git://git.shadowcat.co.uk/dbsrgits/SQL-Translator.git';
  51 bugtracker  'http://rt.cpan.org/NoAuth/Bugs.html?Dist=SQL-Translator';
  52
  53 resources Ratings => 'http://cpanratings.perl.org/d/SQL-Translator';
  54
  55 all_from    'lib/SQL/Translator.pm';
  56
  57 for my $type (qw/requires recommends test_requires/) {
  58   no strict qw/refs/;
  59   my $f = \&$type;
  60   for my $mod (keys %{$deps->{$type} || {} }) {
  61     $f->($mod, $deps->{$type}{$mod});
  62   }
  63 }
  64
  65 install_script (qw|
  66   script/sqlt-diagram
  67   script/sqlt-diff
  68   script/sqlt-diff-old
  69   script/sqlt-dumper
  70   script/sqlt-graph
  71   script/sqlt
  72 |);
  73
  74 install_share();
  75
  76 tests_recursive ();
  77
  78
  79 # temporary(?) until I get around to fix M::I wrt xt/
  80 # needs Module::Install::AuthorTests
  81 eval {
  82   # this should not be necessary since the autoloader is supposed
  83   # to work, but there were reports of it failing
  84   require Module::Install::AuthorTests;
  85   recursive_author_tests (qw/xt/);
  86   1;
  87 } || do {
  88   if ($Module::Install::AUTHOR) {
  89     my $err = $@;
  90
  91     # better error message in case of missing dep
  92     eval { require Module::Install::AuthorTests }
  93       || die "\nYou need Module::Install::AuthorTests installed to run this Makefile.PL in author mode:\n\n$@\n";
  94
  95     die $err;
  96   }
  97 };
  98
  99 auto_install();
 100
 101 if ($Module::Install::AUTHOR) {
 102   _recompile_grammars();
 103   _recreate_rt_source();
 104 }
 105
 106 WriteAll();
 107
 108 sub _recompile_grammars {
 109   require File::Spec;
 110
 111   my $compiled_parser_dir = File::Spec->catdir(qw/
 112     share PrecompiledParsers Parse RecDescent DDL SQLT
 113   /);
 114
 115   # Currently consider only single-name parsers containing a grammar marker
 116   # This is somewhat fragile, but better than loading all kinds of parsers
 117   # to some of which we may not even have the deps
 118   my $parser_libdir = 'lib/SQL/Translator/Parser';
 119   for my $parser_fn (glob "$parser_libdir/*.pm") {
 120     die "$parser_fn does not look like a readable file\n"
 121       unless ( -f $parser_fn and -r $parser_fn );
 122
 123     my ($type) = $parser_fn =~ /^\Q$parser_libdir\E\/(.+)\.pm$/i
 124       or die "$parser_fn not named in expected format\n";
 125
 126     my $parser_source = do { local (@ARGV, $/) = $parser_fn; <> };
 127     next unless $parser_source =~ /\$GRAMMAR.+?END_OF_GRAMMAR/s;
 128
 129
 130     my $precomp_parser_fn = File::Spec->catfile($compiled_parser_dir, "$type.pm");
 131
 132     next if (
 133       -f $precomp_parser_fn
 134         and
 135       (stat($parser_fn))[9] <= (stat($precomp_parser_fn))[9]
 136     );
 137
 138
 139     print "Precompiling parser for $type\n";
 140
 141     require $parser_fn;
 142     require Parse::RecDescent;
 143
 144     Parse::RecDescent->Precompile(
 145       do {
 146         no strict 'refs';
 147         ${"SQL::Translator::Parser::${type}::GRAMMAR"}
 148           || die "No \$GRAMMAR global found in SQL::Translator::Parser::$type ($parser_fn)\n"
 149       },
 150       "Parse::RecDescent::DDL::SQLT::$type"
 151     );
 152
 153     rename( "$type.pm", $precomp_parser_fn )
 154       or die "Unable to move $type.pm to $compiled_parser_dir: $!\n";
 155   }
 156
 157 }
 158
 159 sub _recreate_rt_source {
 160   my $base_xml = "t/data/roundtrip.xml";
 161   my $autogen_yaml = "t/data/roundtrip_autogen.yaml";
 162
 163   print "Updating $autogen_yaml\n";
 164
 165   unlink $autogen_yaml;
 166
 167   eval {
 168
 169     use lib 'lib';
 170
 171     require SQL::Translator;
 172     require SQL::Translator::Parser::XML;
 173
 174     open (my $fh, '>', $autogen_yaml) or die "$autogen_yaml: $!\n";
 175
 176     my $tr = SQL::Translator->new;
 177     my $yaml = $tr->translate (
 178       parser => 'XML',
 179       file => $base_xml,
 180       producer => 'YAML',
 181     ) or  die sprintf ("Unable to translate %s to YAML: %s\n",
 182               $base_xml,
 183               $tr->error || 'error unknown'
 184           );
 185
 186     print $fh $yaml;
 187     close $fh;
 188   };
 189
 190   if ($@) {
 191     warn <<EOE;
 192
 193 =========================================================================
 194 ===============              WARNING !!!                =================
 195 =========================================================================
 196
 197 Unable to update the roundtrip schema (attempt triggered by AUTHOR mode).
 198 We will still generate a Makefile, but be aware that if you build a dist
 199 this way, it *WILL* be broken.
 200
 201 -------------------------------------------------------------------------
 202 $@
 203
 204 Press Enter to continue.
 205 EOE
 206   <>;
 207   }
 208 }