Makefile.PL

   1 use inc::Module::Install 1.06;
   2 use strict;
   3 use warnings;
   4
   5 # to deal wuth x.y.z versions properly
   6 configure_requires 'ExtUtils::MakeMaker' => '6.54';
   7
   8 perl_version '5.008001';
   9
  10 my $deps = {
  11   requires => {
  12     'Class::Base'              => '0',
  13     'Class::Data::Inheritable' => '0.02',
  14     'Digest::SHA'              => '0',
  15     'Carp::Clan'               => '0',
  16     'IO::Scalar'               => '2.110',
  17     'Parse::RecDescent'        => '1.967009',
  18     'DBI'                      => '0',
  19     'File::ShareDir'           => '1.0',
  20     'File::Spec'               => '0',
  21     'XML::Writer'              => '0.500',
  22     'Moo'                      => '1.000003',
  23     'Package::Variant'         => '1.001001',
  24     'Try::Tiny'                => '0.04',
  25   },
  26   recommends => {
  27     'Template'                 => '2.20',
  28     'GD'                       => '0',
  29     'GraphViz'                 => '0',
  30     'Graph::Directed'          => '0',
  31     'Spreadsheet::ParseExcel'  => '0.41',
  32     'Text::ParseWords'         => '0',
  33     'Text::RecordParser'       => '0.02',
  34     'XML::LibXML'              => '1.69',
  35   },
  36   test_requires => {
  37     'YAML'                     => '0.66',
  38     'Test::More'               => '0.88',
  39     'Test::Differences'        => '0',
  40     'Test::Exception'          => '0.31',
  41   },
  42 };
  43
  44
  45 name        'SQL-Translator';
  46 author      'Ken Youens-Clark <kclark@cpan.org>';
  47 abstract    'SQL DDL transformations and more';
  48 license     'gpl';
  49 repository  'git://git.shadowcat.co.uk/dbsrgits/SQL-Translator.git';
  50 bugtracker  'http://rt.cpan.org/NoAuth/Bugs.html?Dist=SQL-Translator';
  51
  52 resources Ratings => 'http://cpanratings.perl.org/d/SQL-Translator';
  53
  54 Meta->{values}{x_authority} = 'cpan:JROBINSON';
  55
  56 all_from    'lib/SQL/Translator.pm';
  57
  58 for my $type (qw/requires recommends test_requires/) {
  59   no strict qw/refs/;
  60   my $f = \&$type;
  61   for my $mod (keys %{$deps->{$type} || {} }) {
  62     $f->($mod, $deps->{$type}{$mod});
  63   }
  64 }
  65
  66 no_index directory => $_ for (qw|
  67   lib/SQL/Translator/Schema/Graph
  68 |);
  69 no_index package => $_ for (qw|
  70   SQL::Translator::Schema::Graph
  71 |);
  72
  73 install_script (qw|
  74   script/sqlt-diagram
  75   script/sqlt-diff
  76   script/sqlt-diff-old
  77   script/sqlt-dumper
  78   script/sqlt-graph
  79   script/sqlt
  80 |);
  81
  82 install_share();
  83
  84 tests_recursive ();
  85
  86
  87 # temporary(?) until I get around to fix M::I wrt xt/
  88 # needs Module::Install::AuthorTests
  89 eval {
  90   # this should not be necessary since the autoloader is supposed
  91   # to work, but there were reports of it failing
  92   require Module::Install::AuthorTests;
  93   recursive_author_tests (qw/xt/);
  94   1;
  95 } || do {
  96   if ($Module::Install::AUTHOR) {
  97     my $err = $@;
  98
  99     # better error message in case of missing dep
 100     eval { require Module::Install::AuthorTests }
 101       || die "\nYou need Module::Install::AuthorTests installed to run this Makefile.PL in author mode:\n\n$@\n";
 102
 103     die $err;
 104   }
 105 };
 106
 107 auto_install();
 108
 109 if ($Module::Install::AUTHOR) {
 110   _recompile_grammars();
 111   _recreate_rt_source();
 112 }
 113
 114 WriteAll();
 115
 116 sub _recompile_grammars {
 117   return; # disabled until RT#74593 is resolved
 118
 119   require File::Spec;
 120
 121   my $compiled_parser_dir = File::Spec->catdir(qw/
 122     share PrecompiledParsers Parse RecDescent DDL SQLT
 123   /);
 124
 125   # Currently consider only single-name parsers containing a grammar marker
 126   # This is somewhat fragile, but better than loading all kinds of parsers
 127   # to some of which we may not even have the deps
 128   my $parser_libdir = 'lib/SQL/Translator/Parser';
 129   for my $parser_fn (glob "$parser_libdir/*.pm") {
 130     die "$parser_fn does not look like a readable file\n"
 131       unless ( -f $parser_fn and -r $parser_fn );
 132
 133     my ($type) = $parser_fn =~ /^\Q$parser_libdir\E\/(.+)\.pm$/i
 134       or die "$parser_fn not named in expected format\n";
 135
 136     my $parser_source = do { local (@ARGV, $/) = $parser_fn; <> };
 137     next unless $parser_source =~ /\$GRAMMAR.+?END_OF_GRAMMAR/s;
 138
 139
 140     my $precomp_parser_fn = File::Spec->catfile($compiled_parser_dir, "$type.pm");
 141
 142     next if (
 143       -f $precomp_parser_fn
 144         and
 145       (stat($parser_fn))[9] <= (stat($precomp_parser_fn))[9]
 146     );
 147
 148
 149     print "Precompiling parser for $type\n";
 150
 151     require $parser_fn;
 152     require Parse::RecDescent;
 153
 154     Parse::RecDescent->Precompile(
 155       do {
 156         no strict 'refs';
 157         ${"SQL::Translator::Parser::${type}::GRAMMAR"}
 158           || die "No \$GRAMMAR global found in SQL::Translator::Parser::$type ($parser_fn)\n"
 159       },
 160       "Parse::RecDescent::DDL::SQLT::$type"
 161     );
 162
 163     rename( "$type.pm", $precomp_parser_fn )
 164       or die "Unable to move $type.pm to $compiled_parser_dir: $!\n";
 165   }
 166
 167 }
 168
 169 sub _recreate_rt_source {
 170   my $base_xml = "t/data/roundtrip.xml";
 171   my $autogen_yaml = "t/data/roundtrip_autogen.yaml";
 172
 173   print "Updating $autogen_yaml\n";
 174
 175   unlink $autogen_yaml;
 176
 177   eval {
 178
 179     use lib 'lib';
 180
 181     require SQL::Translator;
 182     require SQL::Translator::Parser::XML;
 183
 184     open (my $fh, '>', $autogen_yaml) or die "$autogen_yaml: $!\n";
 185
 186     my $tr = SQL::Translator->new;
 187     my $yaml = $tr->translate (
 188       parser => 'XML',
 189       file => $base_xml,
 190       producer => 'YAML',
 191     ) or  die sprintf ("Unable to translate %s to YAML: %s\n",
 192               $base_xml,
 193               $tr->error || 'error unknown'
 194           );
 195
 196     print $fh $yaml;
 197     close $fh;
 198   };
 199
 200   if ($@) {
 201     warn <<EOE;
 202
 203 =========================================================================
 204 ===============              WARNING !!!                =================
 205 =========================================================================
 206
 207 Unable to update the roundtrip schema (attempt triggered by AUTHOR mode).
 208 We will still generate a Makefile, but be aware that if you build a dist
 209 this way, it *WILL* be broken.
 210
 211 -------------------------------------------------------------------------
 212 $@
 213
 214 Press Enter to continue.
 215 EOE
 216   <>;
 217   }
 218 }