lib/SQL/Translator/Producer/YAML.pm

   1 use MooseX::Declare;
   2 role SQL::Translator::Producer::YAML {
   3     use YAML qw(Dump);
   4     use SQL::Translator::Types qw(Column Constraint Index Procedure Table Trigger View);
   5
   6     method produce {
   7         my $schema = $self->schema;
   8         my $translator = $self->translator;
   9
  10         return Dump({
  11             schema => {
  12                 tables =>     { map { ($_->name => $self->_create_table($_)) } $schema->get_tables, },
  13                 views =>      { map { ($_->name => $self->_create_view($_)) } $schema->get_views, },
  14                 triggers =>   { map { ($_->name => $self->_create_trigger($_)) } $schema->get_triggers, },
  15                 procedures => { map { ($_->name => $self->_create_procedure($_)) } $schema->get_procedures, },
  16             },
  17             translator => {
  18                 add_drop_table => $translator->add_drop_table,
  19                 filename       => $translator->filename,
  20                 no_comments    => $translator->no_comments,
  21                 parser_args    => $translator->parser_args,
  22                 producer_args  => $translator->producer_args,
  23                 parser_type    => $translator->parser_type,
  24                 producer_type  => $translator->producer_type,
  25                 show_warnings  => $translator->show_warnings,
  26                 trace          => $translator->trace,
  27                 version        => $translator->version,
  28             },
  29             keys %{$schema->extra} ? ('extra' => { $schema->extra } ) : (),
  30         });
  31     }
  32
  33     method _create_table(Table $table) {
  34         return {
  35             'name'        => scalar $table->name,
  36             'options'     => scalar $table->options,
  37             $table->comments ? ('comments'    => $table->comments ) : (),
  38             'constraints' => [ map { $self->_create_constraint($_) } $table->get_constraints ],
  39             'indices'     => [ map { $self->_create_index($_) } $table->get_indices ],
  40             'fields'      => { map { ($_->name => $self->_create_field($_)) } $table->get_fields
  41             },
  42             keys %{$table->extra} ? ('extra' => { $table->extra } ) : (),
  43         };
  44     }
  45
  46     method _create_constraint(Constraint $constraint) {
  47         return {
  48             'deferrable'       => scalar $constraint->deferrable,
  49             'expression'       => scalar $constraint->expression,
  50             'fields'           => [ $constraint->fields ],
  51             'match_type'       => scalar $constraint->match_type,
  52             'name'             => scalar $constraint->name,
  53             'options'          => scalar $constraint->options,
  54     #        'on_delete'        => scalar $constraint->on_delete,
  55     #        'on_update'        => scalar $constraint->on_update,
  56             'reference_fields' => [ map { ref $_ ? $_->name : $_ } $constraint->reference_fields ],
  57             'reference_table'  => scalar $constraint->reference_table,
  58             'type'             => scalar $constraint->type,
  59             keys %{$constraint->extra} ? ('extra' => { $constraint->extra } ) : (),
  60         };
  61     }
  62
  63     method _create_field(Column $field) {
  64         return {
  65             'name'              => scalar $field->name,
  66             'data_type'         => scalar $field->data_type,
  67             'size'              => [ $field->size ],
  68             'default_value'     => scalar $field->default_value,
  69             'is_nullable'       => scalar $field->is_nullable,
  70             'is_primary_key'    => scalar $field->is_primary_key,
  71             'is_unique'         => scalar $field->is_unique,
  72             $field->is_auto_increment ? ('is_auto_increment' => 1) : (),
  73             $field->comments ? ('comments' => $field->comments) : (),
  74             keys %{$field->extra} ? ('extra' => { $field->extra } ) : (),
  75         };
  76     }
  77
  78     method _create_procedure(Procedure $procedure) {
  79         return {
  80             'name'       => scalar $procedure->name,
  81             'sql'        => scalar $procedure->sql,
  82             'parameters' => scalar $procedure->parameters,
  83             'owner'      => scalar $procedure->owner,
  84             'comments'   => scalar $procedure->comments,
  85             keys %{$procedure->extra} ? ('extra' => { $procedure->extra } ) : (),
  86         };
  87     }
  88
  89     method _create_trigger(Trigger $trigger) {
  90         return {
  91             'name'                => scalar $trigger->name,
  92             'perform_action_when' => scalar $trigger->perform_action_when,
  93             'database_events'     => scalar $trigger->database_events,
  94             'fields'              => [ $trigger->fields ],
  95             'on_table'            => scalar $trigger->on_table,
  96             'action'              => scalar $trigger->action,
  97             keys %{$trigger->extra} ? ('extra' => { $trigger->extra } ) : (),
  98         };
  99     }
 100
 101     method _create_view(View $view) {
 102         return {
 103             'name'   => scalar $view->name,
 104             'sql'    => scalar $view->sql,
 105             'fields' => [ $view->fields ],
 106             keys %{$view->extra} ? ('extra' => { $view->extra } ) : (),
 107         };
 108     }
 109
 110     method _create_index(Index $index) {
 111         return {
 112             'name'      => scalar $index->name,
 113             'type'      => scalar $index->type,
 114             'fields'    => [ $index->fields ],
 115             'options'   => scalar $index->options,
 116             keys %{$index->extra} ? ('extra' => { $index->extra } ) : (),
 117         };
 118     }
 119 }