lib/SQL/Translator.pm

   1 use MooseX::Declare;
   2 class SQL::Translator {
   3     use TryCatch;
   4     use MooseX::Types::Moose qw(Bool HashRef Int Str Undef);
   5     use SQL::Translator::Types qw(DBIHandle Parser Producer Schema);
   6     use SQL::Translator::Object::Schema;
   7
   8     our $VERSION = '0.001';
   9
  10     has 'parser' => (
  11         isa => Str,
  12         is => 'rw',
  13         init_arg => 'from',
  14     );
  15
  16     has 'producer' => (
  17         isa => Str,
  18         is => 'rw',
  19         init_arg => 'to',
  20     );
  21
  22     has '_parser' => (
  23         isa => Parser,
  24         is => 'rw',
  25         lazy_build => 1,
  26         handles => [ qw(parse) ],
  27     );
  28
  29     has '_producer' => (
  30         isa => Producer,
  31         is => 'rw',
  32         lazy_build => 1,
  33         handles => [ qw(produce) ],
  34     );
  35
  36     has 'dbh' => (
  37         isa => DBIHandle,
  38         is => 'ro',
  39         predicate => 'has_dbh',
  40     );
  41
  42     has 'schema' => (
  43         isa => Schema,
  44         is => 'rw',
  45         lazy => 1,
  46         clearer => '_clear_schema',
  47         default => sub { SQL::Translator::Object::Schema->new },
  48     );
  49
  50     has 'parser_args' => (
  51         isa => HashRef,
  52         is => 'rw',
  53         predicate => 'has_parser_args',
  54     );
  55
  56     has 'producer_args' => (
  57         isa => HashRef,
  58         is => 'rw',
  59         predicate => 'has_producer_args',
  60     );
  61
  62     has 'add_drop_table' => (isa => Bool, is => 'rw', default => 0);
  63     has 'no_comments' => (isa => Bool, is => 'rw', default => 0);
  64     has 'show_warnings' => (isa => Bool, is => 'rw', default => 1);
  65     has 'trace' => (isa => Bool, is => 'rw', default => 0);
  66     has 'quote_table_names' => (isa => Bool, is => 'rw', default => 0);
  67     has 'quote_field_names' => (isa => Bool, is => 'rw', default => 0);
  68     has 'version' => (isa => Str, is => 'rw');
  69     has 'filename' => (isa => Str, is => 'rw');
  70
  71     has '_producer_mapping' => (
  72         isa => HashRef,
  73         is => 'ro',
  74         default => sub { { MySQL => 'SQL::MySQL', SQLite => 'SQL::SQLite', PostgreSQL => 'SQL::PostgreSQL', XML => 'XML', YAML => 'YAML' } }
  75     );
  76
  77     method _build__parser {
  78         my $class = 'SQL::Translator::Parser';
  79
  80         Class::MOP::load_class($class);
  81
  82         my $parser;
  83         if ($self->has_dbh) {
  84             $parser = $class->new({ translator => $self, dbh => $self->dbh });
  85         } else {
  86             $parser = $class->new({ translator => $self, type => $self->parser || '' });
  87         }
  88
  89         return $parser;
  90     }
  91
  92     method _build__producer {
  93         my $mapping = $self->_producer_mapping;
  94
  95         my $class = 'SQL::Translator::Producer';
  96         my $role = $class . '::' . $mapping->{$self->producer};
  97
  98         Class::MOP::load_class($class);
  99         Class::MOP::load_class($role);
 100
 101         my $producer = $class->new({ translator => $self });
 102         $role->meta->apply($producer);
 103
 104         return $producer;
 105     }
 106
 107     method translate(:$data, :$producer?, :$producer_args?, :$parser?, :$parser_args?) {
 108         my $return;
 109
 110         $parser ||= $self->parser;
 111         if (defined $parser) {
 112             $self->_clear_parser;
 113             $self->_clear_schema;
 114             $self->parser($parser);
 115             $self->parse($data);
 116             $return = $self->schema;
 117         }
 118
 119         $producer ||= $self->producer;
 120         if (defined $producer) {
 121             $self->_clear_producer;
 122             $self->producer($producer);
 123             $return = $self->produce;
 124         }
 125
 126         return $return;
 127     }
 128
 129     method parser_type { return $self->parser }
 130     method producer_type { return $self->producer }
 131
 132     method engine_version(Int|Str|Undef $v, Str $target = 'perl') {
 133         return undef unless $v;
 134
 135         my @vers;
 136
 137         # X.Y.Z style
 138         if ( $v =~ / ^ (\d+) \. (\d{1,3}) (?: \. (\d{1,3}) )? $ /x ) {
 139             push @vers, $1, $2, $3;
 140         }
 141
 142         # XYYZZ (mysql) style
 143         elsif ( $v =~ / ^ (\d) (\d{2}) (\d{2}) $ /x ) {
 144             push @vers, $1, $2, $3;
 145         }
 146
 147         # XX.YYYZZZ (perl) style or simply X
 148         elsif ( $v =~ / ^ (\d+) (?: \. (\d{3}) (\d{3}) )? $ /x ) {
 149             push @vers, $1, $2, $3;
 150         }
 151         else {
 152             #how do I croak sanely here?
 153             die "Unparseable MySQL version '$v'";
 154         }
 155
 156         if ($target eq 'perl') {
 157             return sprintf ('%d.%03d%03d', map { $_ || 0 } (@vers) );
 158         }
 159         elsif ($target eq 'mysql') {
 160             return sprintf ('%d%02d%02d', map { $_ || 0 } (@vers) );
 161         }
 162         else {
 163             #how do I croak sanely here?
 164             die "Unknown version target '$target'";
 165         }
 166     }
 167 }