lib/SQL/Translator.pm

   1 use MooseX::Declare;
   2 class SQL::Translator {
   3     use TryCatch;
   4     use MooseX::Types::Moose qw(Bool HashRef Int Str Undef);
   5     use MooseX::Aliases;
   6     use SQL::Translator::Types qw(DBIHandle Parser Producer Schema);
   7     use SQL::Translator::Object::Schema;
   8
   9     our $VERSION = '0.001';
  10     $VERSION = eval $VERSION;
  11
  12     has 'parser' => (
  13         isa => Str,
  14         is => 'rw',
  15         alias => 'from',
  16     );
  17
  18     has 'producer' => (
  19         isa => Str,
  20         is => 'rw',
  21         alias => 'to',
  22     );
  23
  24     has '_parser' => (
  25         isa => Parser,
  26         is => 'rw',
  27         lazy_build => 1,
  28         handles => [ qw(parse) ],
  29         predicate => 'has_parser',
  30     );
  31
  32     has '_producer' => (
  33         isa => Producer,
  34         is => 'rw',
  35         lazy_build => 1,
  36         handles => [ qw(produce) ],
  37         predicate => 'has_producer',
  38     );
  39
  40     has 'dbh' => (
  41         isa => DBIHandle,
  42         is => 'ro',
  43         predicate => 'has_dbh',
  44     );
  45
  46     has 'schema' => (
  47         isa => Schema,
  48         is => 'rw',
  49         lazy => 1,
  50         clearer => '_clear_schema',
  51         default => sub { SQL::Translator::Object::Schema->new },
  52     );
  53
  54     has 'parser_args' => (
  55         isa => HashRef,
  56         is => 'rw',
  57         predicate => 'has_parser_args',
  58     );
  59
  60     has 'producer_args' => (
  61         isa => HashRef,
  62         is => 'rw',
  63         predicate => 'has_producer_args',
  64     );
  65
  66     has 'version' => (isa => Str, is => 'ro', default => $VERSION);
  67     has 'add_drop_table' => (isa => Bool, is => 'rw', default => 0);
  68     has 'no_comments' => (isa => Bool, is => 'rw', default => 0);
  69     has 'show_warnings' => (isa => Bool, is => 'rw', default => 1);
  70     has 'trace' => (isa => Bool, is => 'rw', default => 0);
  71     has 'quote_table_names' => (isa => Bool, is => 'rw', default => 0);
  72     has 'quote_field_names' => (isa => Bool, is => 'rw', default => 0);
  73     has 'filename' => (isa => Str, is => 'rw');
  74
  75     has '_producer_mapping' => (
  76         isa => HashRef,
  77         is => 'ro',
  78         default => sub { { MySQL => 'SQL::MySQL', SQLite => 'SQL::SQLite', PostgreSQL => 'SQL::PostgreSQL', XML => 'XML', YAML => 'YAML' } }
  79     );
  80
  81     method _build__parser {
  82         my $class = 'SQL::Translator::Parser';
  83
  84         Class::MOP::load_class($class);
  85
  86         my $parser;
  87         if ($self->has_dbh) {
  88             $parser = $class->new({ translator => $self, dbh => $self->dbh });
  89         } else {
  90             $parser = $class->new({ translator => $self, type => $self->parser || '' });
  91         }
  92
  93         return $parser;
  94     }
  95
  96     method _build__producer {
  97         my $mapping = $self->_producer_mapping;
  98
  99         my $class = 'SQL::Translator::Producer';
 100         my $role = $class . '::' . $mapping->{$self->producer};
 101
 102         Class::MOP::load_class($class);
 103         Class::MOP::load_class($role);
 104
 105         my $producer = $class->new({ translator => $self });
 106         $role->meta->apply($producer);
 107
 108         return $producer;
 109     }
 110
 111     method translate(:$data, :$producer?, :$producer_args?, :$parser?, :$parser_args?) {
 112         my $return;
 113
 114         $self->_clear_schema if defined $parser;
 115
 116         $parser ||= $self->parser unless $self->has_parser;
 117         if (defined $parser) {
 118             $self->_clear_parser;
 119             $self->parser($parser);
 120             $self->parse($data);
 121             $return = $self->schema;
 122         }
 123
 124         $producer ||= $self->producer unless $self->has_producer;
 125         if (defined $producer) {
 126             $self->_clear_producer;
 127             $self->producer($producer);
 128             $return = $self->produce;
 129         }
 130
 131         return $return;
 132     }
 133
 134     method parser_type { return $self->parser }
 135     method producer_type { return $self->producer }
 136
 137     method engine_version(Int|Str|Undef $v, Str $target = 'perl') {
 138         return undef unless $v;
 139
 140         my @vers;
 141
 142         # X.Y.Z style
 143         if ( $v =~ / ^ (\d+) \. (\d{1,3}) (?: \. (\d{1,3}) )? $ /x ) {
 144             push @vers, $1, $2, $3;
 145         }
 146
 147         # XYYZZ (mysql) style
 148         elsif ( $v =~ / ^ (\d) (\d{2}) (\d{2}) $ /x ) {
 149             push @vers, $1, $2, $3;
 150         }
 151
 152         # XX.YYYZZZ (perl) style or simply X
 153         elsif ( $v =~ / ^ (\d+) (?: \. (\d{3}) (\d{3}) )? $ /x ) {
 154             push @vers, $1, $2, $3;
 155         }
 156         else {
 157             #how do I croak sanely here?
 158             die "Unparseable MySQL version '$v'";
 159         }
 160
 161         if ($target eq 'perl') {
 162             return sprintf ('%d.%03d%03d', map { $_ || 0 } (@vers) );
 163         }
 164         elsif ($target eq 'mysql') {
 165             return sprintf ('%d%02d%02d', map { $_ || 0 } (@vers) );
 166         }
 167         else {
 168             #how do I croak sanely here?
 169             die "Unknown version target '$target'";
 170         }
 171     }
 172 }