t/05in_between.t

   1 use strict;
   2 use warnings;
   3 use Test::More;
   4 use Test::Warn;
   5 use Test::Exception;
   6 use SQL::Abstract::Test import => [qw(is_same_sql_bind diag_where)];
   7
   8 use SQL::Abstract;
   9
  10 my @in_between_tests = (
  11   {
  12     where => { x => { -between => [1, 2] } },
  13     stmt => 'WHERE (x BETWEEN ? AND ?)',
  14     bind => [qw/1 2/],
  15     test => '-between with two placeholders',
  16   },
  17   {
  18     where => { x => { -between => [\"1", 2] } },
  19     stmt => 'WHERE (x BETWEEN 1 AND ?)',
  20     bind => [qw/2/],
  21     test => '-between with one literal sql arg and one placeholder',
  22   },
  23   {
  24     where => { x => { -between => [1, \"2"] } },
  25     stmt => 'WHERE (x BETWEEN ? AND 2)',
  26     bind => [qw/1/],
  27     test => '-between with one placeholder and one literal sql arg',
  28   },
  29   {
  30     where => { x => { -between => [\'current_date - 1', \'current_date - 0'] } },
  31     stmt => 'WHERE (x BETWEEN current_date - 1 AND current_date - 0)',
  32     bind => [],
  33     test => '-between with two literal sql arguments',
  34   },
  35   {
  36     where => { x => { -between => [ \['current_date - ?', 1], \['current_date - ?', 0] ] } },
  37     stmt => 'WHERE (x BETWEEN current_date - ? AND current_date - ?)',
  38     bind => [1, 0],
  39     test => '-between with two literal sql arguments with bind',
  40   },
  41   {
  42     where => { x => { -between => \['? AND ?', 1, 2] } },
  43     stmt => 'WHERE (x BETWEEN ? AND ?)',
  44     bind => [1,2],
  45     test => '-between with literal sql with placeholders (\["? AND ?", scalar, scalar])',
  46   },
  47   {
  48     where => { x => { -between => \["'something' AND ?", 2] } },
  49     stmt => "WHERE (x BETWEEN 'something' AND ?)",
  50     bind => [2],
  51     test => '-between with literal sql with one literal arg and one placeholder (\["\'something\' AND ?", scalar])',
  52   },
  53   {
  54     where => { x => { -between => \["? AND 'something'", 1] } },
  55     stmt => "WHERE (x BETWEEN ? AND 'something')",
  56     bind => [1],
  57     test => '-between with literal sql with one placeholder and one literal arg (\["? AND \'something\'", scalar])',
  58   },
  59   {
  60     where => { x => { -between => \"'this' AND 'that'" } },
  61     stmt => "WHERE (x BETWEEN 'this' AND 'that')",
  62     bind => [],
  63     test => '-between with literal sql with a literal (\"\'this\' AND \'that\'")',
  64   },
  65
  66   # generate a set of invalid -between tests
  67   ( map { {
  68     where => { x => { -between => $_ } },
  69     test => 'invalid -between args',
  70     throws => qr|Operator 'BETWEEN' requires either an arrayref with two defined values or expressions, or a single literal scalarref/arrayref-ref|,
  71   } } (
  72     [ 1, 2, 3 ],
  73     [ 1, undef, 3 ],
  74     [ undef, 2, 3 ],
  75     [ 1, 2, undef ],
  76     [ 1, undef ],
  77     [ undef, 2 ],
  78     [ undef, undef ],
  79     [ 1 ],
  80     [ undef ],
  81     [],
  82     1,
  83     undef,
  84   )),
  85   {
  86     where => {
  87       start0 => { -between => [ 1, { -upper => 2 } ] },
  88       start1 => { -between => \["? AND ?", 1, 2] },
  89       start2 => { -between => \"lower(x) AND upper(y)" },
  90       start3 => { -between => [
  91         \"lower(x)",
  92         \["upper(?)", 'stuff' ],
  93       ] },
  94     },
  95     stmt => "WHERE (
  96           ( start0 BETWEEN ? AND UPPER ?          )
  97       AND ( start1 BETWEEN ? AND ?                )
  98       AND ( start2 BETWEEN lower(x) AND upper(y)  )
  99       AND ( start3 BETWEEN lower(x) AND upper(?)  )
 100     )",
 101     bind => [1, 2, 1, 2, 'stuff'],
 102     test => '-between POD test',
 103   },
 104   {
 105     args => { bindtype => 'columns' },
 106     where => {
 107       start0 => { -between => [ 1, { -upper => 2 } ] },
 108       start1 => { -between => \["? AND ?", [ start1 => 1], [start1 => 2] ] },
 109       start2 => { -between => \"lower(x) AND upper(y)" },
 110       start3 => { -between => [
 111         \"lower(x)",
 112         \["upper(?)", [ start3 => 'stuff'] ],
 113       ] },
 114     },
 115     stmt => "WHERE (
 116           ( start0 BETWEEN ? AND UPPER ?          )
 117       AND ( start1 BETWEEN ? AND ?                )
 118       AND ( start2 BETWEEN lower(x) AND upper(y)  )
 119       AND ( start3 BETWEEN lower(x) AND upper(?)  )
 120     )",
 121     bind => [
 122       [ start0 => 1 ],
 123       [ start0 => 2 ],
 124       [ start1 => 1 ],
 125       [ start1 => 2 ],
 126       [ start3 => 'stuff' ],
 127     ],
 128     test => '-between POD test',
 129   },
 130
 131   {
 132     parenthesis_significant => 1,
 133     where => { x => { -in => [ 1 .. 3] } },
 134     stmt => "WHERE ( x IN (?, ?, ?) )",
 135     bind => [ 1 .. 3],
 136     test => '-in with an array of scalars',
 137   },
 138   {
 139     parenthesis_significant => 1,
 140     where => { x => { -in => [] } },
 141     stmt => "WHERE ( 0=1 )",
 142     bind => [],
 143     test => '-in with an empty array',
 144   },
 145   {
 146     parenthesis_significant => 1,
 147     where => { x => { -in => \'( 1,2,lower(y) )' } },
 148     stmt => "WHERE ( x IN ( 1,2,lower(y) ) )",
 149     bind => [],
 150     test => '-in with a literal scalarref',
 151   },
 152
 153   # note that outer parens are opened even though literal was requested below
 154   {
 155     parenthesis_significant => 1,
 156     where => { x => { -in => \['( ( ?,?,lower(y) ) )', 1, 2] } },
 157     stmt => "WHERE ( x IN ( ?,?,lower(y) ) )",
 158     bind => [1, 2],
 159     test => '-in with a literal arrayrefref',
 160   },
 161   {
 162     parenthesis_significant => 1,
 163     where => {
 164       status => { -in => \"(SELECT status_codes\nFROM states)" },
 165     },
 166     stmt => " WHERE ( status IN ( SELECT status_codes FROM states )) ",
 167     bind => [],
 168     test => '-in multi-line subquery test',
 169   },
 170   {
 171     parenthesis_significant => 1,
 172     where => {
 173       customer => { -in => \[
 174         'SELECT cust_id FROM cust WHERE balance > ?',
 175         2000,
 176       ]},
 177       status => { -in => \'SELECT status_codes FROM states' },
 178     },
 179     stmt => "
 180       WHERE ((
 181             customer IN ( SELECT cust_id FROM cust WHERE balance > ? )
 182         AND status IN ( SELECT status_codes FROM states )
 183       ))
 184     ",
 185     bind => [2000],
 186     test => '-in POD test',
 187   },
 188
 189   {
 190     where => { x => { -in => [ \['LOWER(?)', 'A' ], \'LOWER(b)', { -lower => 'c' } ] } },
 191     stmt => " WHERE ( x IN ( LOWER(?), LOWER(b), LOWER ? ) )",
 192     bind => [qw/A c/],
 193     test => '-in with an array of function array refs with args',
 194   },
 195   {
 196     throws => qr/
 197       \QSQL::Abstract before v1.75 used to generate incorrect SQL \E
 198       \Qwhen the -IN operator was given an undef-containing list: \E
 199       \Q!!!AUDIT YOUR CODE AND DATA!!! (the upcoming Data::Query-based \E
 200       \Qversion of SQL::Abstract will emit the logically correct SQL \E
 201       \Qinstead of raising this exception)\E
 202     /x,
 203     where => { x => { -in => [ 1, undef ] } },
 204     stmt => " WHERE ( x IN ( ? ) OR x IS NULL )",
 205     bind => [ 1 ],
 206     test => '-in with undef as an element',
 207   },
 208   {
 209     throws => qr/
 210       \QSQL::Abstract before v1.75 used to generate incorrect SQL \E
 211       \Qwhen the -IN operator was given an undef-containing list: \E
 212       \Q!!!AUDIT YOUR CODE AND DATA!!! (the upcoming Data::Query-based \E
 213       \Qversion of SQL::Abstract will emit the logically correct SQL \E
 214       \Qinstead of raising this exception)\E
 215     /x,
 216     where => { x => { -in => [ 1, undef, 2, 3, undef ] } },
 217     stmt => " WHERE ( x IN ( ?, ?, ? ) OR x IS NULL )",
 218     bind => [ 1, 2, 3 ],
 219     test => '-in with multiple undef elements',
 220   },
 221 );
 222
 223 for my $case (@in_between_tests) {
 224   TODO: {
 225     local $TODO = $case->{todo} if $case->{todo};
 226     local $SQL::Abstract::Test::parenthesis_significant = $case->{parenthesis_significant};
 227     my $label = $case->{test} || 'in-between test';
 228
 229     my $sql = SQL::Abstract->new ($case->{args} || {});
 230
 231     if (my $e = $case->{throws}) {
 232       throws_ok { $sql->where($case->{where}) } $e, "$label throws correctly";
 233     }
 234     else {
 235       my ($stmt, @bind);
 236       warnings_are {
 237         ($stmt, @bind) = $sql->where($case->{where});
 238       } [], "$label gives no warnings";
 239
 240       is_same_sql_bind(
 241         $stmt,
 242         \@bind,
 243         $case->{stmt},
 244         $case->{bind},
 245         "$label generates correct SQL and bind",
 246       ) || diag_where ( $case->{where} );
 247     }
 248   }
 249 }
 250
 251 done_testing;