lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use Carp;
   9 use strict;
  10 use warnings;
  11 use List::Util ();
  12 use Scalar::Util ();
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.67_03';
  19
  20 # This would confuse some packagers
  21 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^(not )?between$/i, handler => '_where_field_BETWEEN'},
  29   {regex => qr/^(not )?in$/i,      handler => '_where_field_IN'},
  30 );
  31
  32 # unaryish operators - key maps to handler
  33 my @BUILTIN_UNARY_OPS = (
  34   # the digits are backcompat stuff
  35   { regex => qr/^and  (?: \s? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  36   { regex => qr/^or   (?: \s? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  37   { regex => qr/^nest (?: \s? \d+ )? $/xi, handler => '_where_op_NEST' },
  38   { regex => qr/^ (?: not \s )? bool $/xi, handler => '_where_op_BOOL' },
  39 );
  40
  41 #======================================================================
  42 # DEBUGGING AND ERROR REPORTING
  43 #======================================================================
  44
  45 sub _debug {
  46   return unless $_[0]->{debug}; shift; # a little faster
  47   my $func = (caller(1))[3];
  48   warn "[$func] ", @_, "\n";
  49 }
  50
  51 sub belch (@) {
  52   my($func) = (caller(1))[3];
  53   carp "[$func] Warning: ", @_;
  54 }
  55
  56 sub puke (@) {
  57   my($func) = (caller(1))[3];
  58   croak "[$func] Fatal: ", @_;
  59 }
  60
  61
  62 #======================================================================
  63 # NEW
  64 #======================================================================
  65
  66 sub new {
  67   my $self = shift;
  68   my $class = ref($self) || $self;
  69   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  70
  71   # choose our case by keeping an option around
  72   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  73
  74   # default logic for interpreting arrayrefs
  75   $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
  76
  77   # how to return bind vars
  78   # LDNOTE: changed nwiger code : why this 'delete' ??
  79   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  80   $opt{bindtype} ||= 'normal';
  81
  82   # default comparison is "=", but can be overridden
  83   $opt{cmp} ||= '=';
  84
  85   # try to recognize which are the 'equality' and 'unequality' ops
  86   # (temporary quickfix, should go through a more seasoned API)
  87   $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  88   $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  89
  90   # SQL booleans
  91   $opt{sqltrue}  ||= '1=1';
  92   $opt{sqlfalse} ||= '0=1';
  93
  94   # special operators
  95   $opt{special_ops} ||= [];
  96   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
  97
  98   # unary operators
  99   $opt{unary_ops} ||= [];
 100   push @{$opt{unary_ops}}, @BUILTIN_UNARY_OPS;
 101
 102   return bless \%opt, $class;
 103 }
 104
 105
 106
 107 #======================================================================
 108 # INSERT methods
 109 #======================================================================
 110
 111 sub insert {
 112   my $self    = shift;
 113   my $table   = $self->_table(shift);
 114   my $data    = shift || return;
 115   my $options = shift;
 116
 117   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 118   my ($sql, @bind) = $self->$method($data);
 119   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 120
 121   if (my $ret = $options->{returning}) {
 122     $sql .= $self->_insert_returning ($ret);
 123   }
 124
 125   return wantarray ? ($sql, @bind) : $sql;
 126 }
 127
 128 sub _insert_returning {
 129   my ($self, $fields) = @_;
 130
 131   my $f = $self->_SWITCH_refkind($fields, {
 132     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$fields;},
 133     SCALAR       => sub {$self->_quote($fields)},
 134     SCALARREF    => sub {$$fields},
 135   });
 136   return join (' ', $self->_sqlcase(' returning'), $f);
 137 }
 138
 139 sub _insert_HASHREF { # explicit list of fields and then values
 140   my ($self, $data) = @_;
 141
 142   my @fields = sort keys %$data;
 143
 144   my ($sql, @bind) = $self->_insert_values($data);
 145
 146   # assemble SQL
 147   $_ = $self->_quote($_) foreach @fields;
 148   $sql = "( ".join(", ", @fields).") ".$sql;
 149
 150   return ($sql, @bind);
 151 }
 152
 153 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 154   my ($self, $data) = @_;
 155
 156   # no names (arrayref) so can't generate bindtype
 157   $self->{bindtype} ne 'columns'
 158     or belch "can't do 'columns' bindtype when called with arrayref";
 159
 160   # fold the list of values into a hash of column name - value pairs
 161   # (where the column names are artificially generated, and their
 162   # lexicographical ordering keep the ordering of the original list)
 163   my $i = "a";  # incremented values will be in lexicographical order
 164   my $data_in_hash = { map { ($i++ => $_) } @$data };
 165
 166   return $self->_insert_values($data_in_hash);
 167 }
 168
 169 sub _insert_ARRAYREFREF { # literal SQL with bind
 170   my ($self, $data) = @_;
 171
 172   my ($sql, @bind) = @${$data};
 173   $self->_assert_bindval_matches_bindtype(@bind);
 174
 175   return ($sql, @bind);
 176 }
 177
 178
 179 sub _insert_SCALARREF { # literal SQL without bind
 180   my ($self, $data) = @_;
 181
 182   return ($$data);
 183 }
 184
 185 sub _insert_values {
 186   my ($self, $data) = @_;
 187
 188   my (@values, @all_bind);
 189   foreach my $column (sort keys %$data) {
 190     my $v = $data->{$column};
 191
 192     $self->_SWITCH_refkind($v, {
 193
 194       ARRAYREF => sub {
 195         if ($self->{array_datatypes}) { # if array datatype are activated
 196           push @values, '?';
 197           push @all_bind, $self->_bindtype($column, $v);
 198         }
 199         else {                          # else literal SQL with bind
 200           my ($sql, @bind) = @$v;
 201           $self->_assert_bindval_matches_bindtype(@bind);
 202           push @values, $sql;
 203           push @all_bind, @bind;
 204         }
 205       },
 206
 207       ARRAYREFREF => sub { # literal SQL with bind
 208         my ($sql, @bind) = @${$v};
 209         $self->_assert_bindval_matches_bindtype(@bind);
 210         push @values, $sql;
 211         push @all_bind, @bind;
 212       },
 213
 214       # THINK : anything useful to do with a HASHREF ?
 215       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 216         #TODO in SQLA >= 2.0 it will die instead
 217         belch "HASH ref as bind value in insert is not supported";
 218         push @values, '?';
 219         push @all_bind, $self->_bindtype($column, $v);
 220       },
 221
 222       SCALARREF => sub {  # literal SQL without bind
 223         push @values, $$v;
 224       },
 225
 226       SCALAR_or_UNDEF => sub {
 227         push @values, '?';
 228         push @all_bind, $self->_bindtype($column, $v);
 229       },
 230
 231      });
 232
 233   }
 234
 235   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 236   return ($sql, @all_bind);
 237 }
 238
 239
 240
 241 #======================================================================
 242 # UPDATE methods
 243 #======================================================================
 244
 245
 246 sub update {
 247   my $self  = shift;
 248   my $table = $self->_table(shift);
 249   my $data  = shift || return;
 250   my $where = shift;
 251
 252   # first build the 'SET' part of the sql statement
 253   my (@set, @all_bind);
 254   puke "Unsupported data type specified to \$sql->update"
 255     unless ref $data eq 'HASH';
 256
 257   for my $k (sort keys %$data) {
 258     my $v = $data->{$k};
 259     my $r = ref $v;
 260     my $label = $self->_quote($k);
 261
 262     $self->_SWITCH_refkind($v, {
 263       ARRAYREF => sub {
 264         if ($self->{array_datatypes}) { # array datatype
 265           push @set, "$label = ?";
 266           push @all_bind, $self->_bindtype($k, $v);
 267         }
 268         else {                          # literal SQL with bind
 269           my ($sql, @bind) = @$v;
 270           $self->_assert_bindval_matches_bindtype(@bind);
 271           push @set, "$label = $sql";
 272           push @all_bind, @bind;
 273         }
 274       },
 275       ARRAYREFREF => sub { # literal SQL with bind
 276         my ($sql, @bind) = @${$v};
 277         $self->_assert_bindval_matches_bindtype(@bind);
 278         push @set, "$label = $sql";
 279         push @all_bind, @bind;
 280       },
 281       SCALARREF => sub {  # literal SQL without bind
 282         push @set, "$label = $$v";
 283        },
 284       SCALAR_or_UNDEF => sub {
 285         push @set, "$label = ?";
 286         push @all_bind, $self->_bindtype($k, $v);
 287       },
 288     });
 289   }
 290
 291   # generate sql
 292   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 293           . join ', ', @set;
 294
 295   if ($where) {
 296     my($where_sql, @where_bind) = $self->where($where);
 297     $sql .= $where_sql;
 298     push @all_bind, @where_bind;
 299   }
 300
 301   return wantarray ? ($sql, @all_bind) : $sql;
 302 }
 303
 304
 305
 306
 307 #======================================================================
 308 # SELECT
 309 #======================================================================
 310
 311
 312 sub select {
 313   my $self   = shift;
 314   my $table  = $self->_table(shift);
 315   my $fields = shift || '*';
 316   my $where  = shift;
 317   my $order  = shift;
 318
 319   my($where_sql, @bind) = $self->where($where, $order);
 320
 321   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 322                                    : $fields;
 323   my $sql = join(' ', $self->_sqlcase('select'), $f,
 324                       $self->_sqlcase('from'),   $table)
 325           . $where_sql;
 326
 327   return wantarray ? ($sql, @bind) : $sql;
 328 }
 329
 330 #======================================================================
 331 # DELETE
 332 #======================================================================
 333
 334
 335 sub delete {
 336   my $self  = shift;
 337   my $table = $self->_table(shift);
 338   my $where = shift;
 339
 340
 341   my($where_sql, @bind) = $self->where($where);
 342   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 343
 344   return wantarray ? ($sql, @bind) : $sql;
 345 }
 346
 347
 348 #======================================================================
 349 # WHERE: entry point
 350 #======================================================================
 351
 352
 353
 354 # Finally, a separate routine just to handle WHERE clauses
 355 sub where {
 356   my ($self, $where, $order) = @_;
 357
 358   # where ?
 359   my ($sql, @bind) = $self->_recurse_where($where);
 360   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 361
 362   # order by?
 363   if ($order) {
 364     $sql .= $self->_order_by($order);
 365   }
 366
 367   return wantarray ? ($sql, @bind) : $sql;
 368 }
 369
 370
 371 sub _recurse_where {
 372   my ($self, $where, $logic) = @_;
 373
 374   # dispatch on appropriate method according to refkind of $where
 375   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 376
 377   my ($sql, @bind) =  $self->$method($where, $logic);
 378
 379   # DBIx::Class directly calls _recurse_where in scalar context, so
 380   # we must implement it, even if not in the official API
 381   return wantarray ? ($sql, @bind) : $sql;
 382 }
 383
 384
 385
 386 #======================================================================
 387 # WHERE: top-level ARRAYREF
 388 #======================================================================
 389
 390
 391 sub _where_ARRAYREF {
 392   my ($self, $where, $logic) = @_;
 393
 394   $logic = uc($logic || $self->{logic});
 395   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 396
 397   my @clauses = @$where;
 398
 399   my (@sql_clauses, @all_bind);
 400   # need to use while() so can shift() for pairs
 401   while (my $el = shift @clauses) {
 402
 403     # switch according to kind of $el and get corresponding ($sql, @bind)
 404     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 405
 406       # skip empty elements, otherwise get invalid trailing AND stuff
 407       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 408
 409       ARRAYREFREF => sub {
 410         my ($s, @b) = @$$el;
 411         $self->_assert_bindval_matches_bindtype(@b);
 412         ($s, @b);
 413       },
 414
 415       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 416            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 417            # side-effect: the first hashref within an array would change
 418            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 419            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 420            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 421
 422       SCALARREF => sub { ($$el);                                 },
 423
 424       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 425                         $self->_recurse_where({$el => shift(@clauses)})},
 426
 427       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 428     });
 429
 430     if ($sql) {
 431       push @sql_clauses, $sql;
 432       push @all_bind, @bind;
 433     }
 434   }
 435
 436   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 437 }
 438
 439 #======================================================================
 440 # WHERE: top-level ARRAYREFREF
 441 #======================================================================
 442
 443 sub _where_ARRAYREFREF {
 444     my ($self, $where) = @_;
 445     my ($sql, @bind) = @$$where;
 446     $self->_assert_bindval_matches_bindtype(@bind);
 447     return ($sql, @bind);
 448 }
 449
 450 #======================================================================
 451 # WHERE: top-level HASHREF
 452 #======================================================================
 453
 454 sub _where_HASHREF {
 455   my ($self, $where) = @_;
 456   my (@sql_clauses, @all_bind);
 457
 458   for my $k (sort keys %$where) {
 459     my $v = $where->{$k};
 460
 461     # ($k => $v) is either a special unary op or a regular hashpair
 462     my ($sql, @bind) = do {
 463       if ($k =~ /^-./) {
 464         # put the operator in canonical form
 465         my $op = $k;
 466         $op =~ s/^-//;        # remove initial dash
 467         $op =~ s/[_\t ]+/ /g; # underscores and whitespace become single spaces
 468         $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 469
 470         $self->_debug("Unary OP(-$op) within hashref, recursing...");
 471
 472         my $op_entry = List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}};
 473         if (my $handler = $op_entry->{handler}) {
 474           if (not ref $handler) {
 475             if ($op =~ s/\s?\d+$//) {
 476               belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
 477                   . "You probably wanted ...-and => [ -$op => COND1, -$op => COND2 ... ]";
 478               }
 479             $self->$handler ($op, $v);
 480           }
 481           elsif (ref $handler eq 'CODE') {
 482             $handler->($self, $op, $v);
 483           }
 484           else {
 485             puke "Illegal handler for operator $k - expecting a method name or a coderef";
 486           }
 487         }
 488         else {
 489           $self->debug("Generic unary OP: $k - recursing as function");
 490           my ($sql, @bind) = $self->_where_func_generic ($op, $v);
 491           $sql = "($sql)" unless (defined($self->{_nested_func_lhs}) && ($self->{_nested_func_lhs} eq $k));  # top level vs nested
 492           ($sql, @bind);
 493         }
 494       }
 495       else {
 496         my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 497         $self->$method($k, $v);
 498       }
 499     };
 500
 501     push @sql_clauses, $sql;
 502     push @all_bind, @bind;
 503   }
 504
 505   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 506 }
 507
 508 sub _where_func_generic {
 509   my ($self, $op, $rhs) = @_;
 510
 511   my ($sql, @bind) = $self->_SWITCH_refkind ($rhs, {
 512     SCALAR =>   sub {
 513       puke "Illegal use of top-level '$op'"
 514         unless $self->{_nested_func_lhs};
 515
 516       return (
 517         $self->_convert('?'),
 518         $self->_bindtype($self->{_nested_func_lhs}, $rhs)
 519       );
 520     },
 521     FALLBACK => sub {
 522       $self->_recurse_where ($rhs)
 523     },
 524   });
 525
 526   $sql = sprintf ('%s %s',
 527     $self->_sqlcase($op),
 528     $sql,
 529   );
 530
 531   return ($sql, @bind);
 532 }
 533
 534 sub _where_op_ANDOR {
 535   my ($self, $op, $v) = @_;
 536
 537   $self->_SWITCH_refkind($v, {
 538     ARRAYREF => sub {
 539       return $self->_where_ARRAYREF($v, $op);
 540     },
 541
 542     HASHREF => sub {
 543       return ( $op =~ /^or/i )
 544         ? $self->_where_ARRAYREF( [ map { $_ => $v->{$_} } ( sort keys %$v ) ], $op )
 545         : $self->_where_HASHREF($v);
 546     },
 547
 548     SCALARREF  => sub {
 549       puke "-$op => \\\$scalar not supported, use -nest => ...";
 550     },
 551
 552     ARRAYREFREF => sub {
 553       puke "-$op => \\[..] not supported, use -nest => ...";
 554     },
 555
 556     SCALAR => sub { # permissively interpreted as SQL
 557       puke "-$op => 'scalar' not supported, use -nest => \\'scalar'";
 558     },
 559
 560     UNDEF => sub {
 561       puke "-$op => undef not supported";
 562     },
 563    });
 564 }
 565
 566 sub _where_op_NEST {
 567   my ($self, $op, $v) = @_;
 568
 569   $self->_SWITCH_refkind($v, {
 570
 571     SCALAR => sub { # permissively interpreted as SQL
 572       belch "literal SQL should be -nest => \\'scalar' "
 573           . "instead of -nest => 'scalar' ";
 574       return ($v);
 575     },
 576
 577     UNDEF => sub {
 578       puke "-$op => undef not supported";
 579     },
 580
 581     FALLBACK => sub {
 582       $self->_recurse_where ($v);
 583     },
 584
 585    });
 586 }
 587
 588
 589 sub _where_op_BOOL {
 590   my ($self, $op, $v) = @_;
 591
 592   my ( $prefix, $suffix ) = ( $op =~ /\bnot\b/i )
 593     ? ( '(NOT ', ')' )
 594     : ( '', '' );
 595
 596   my ($sql, @bind) = do {
 597     $self->_SWITCH_refkind($v, {
 598       SCALAR => sub { # interpreted as SQL column
 599         $self->_convert($self->_quote($v));
 600       },
 601
 602       UNDEF => sub {
 603         puke "-$op => undef not supported";
 604       },
 605
 606       FALLBACK => sub {
 607         $self->_recurse_where ($v);
 608       },
 609     });
 610   };
 611
 612   return (
 613     join ('', $prefix, $sql, $suffix),
 614     @bind,
 615   );
 616 }
 617
 618
 619 sub _where_hashpair_ARRAYREF {
 620   my ($self, $k, $v) = @_;
 621
 622   if( @$v ) {
 623     my @v = @$v; # need copy because of shift below
 624     $self->_debug("ARRAY($k) means distribute over elements");
 625
 626     # put apart first element if it is an operator (-and, -or)
 627     my $op = (
 628        (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
 629          ? shift @v
 630          : ''
 631     );
 632     my @distributed = map { {$k =>  $_} } @v;
 633
 634     if ($op) {
 635       $self->_debug("OP($op) reinjected into the distributed array");
 636       unshift @distributed, $op;
 637     }
 638
 639     my $logic = $op ? substr($op, 1) : '';
 640
 641     return $self->_recurse_where(\@distributed, $logic);
 642   }
 643   else {
 644     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 645     $self->_debug("empty ARRAY($k) means 0=1");
 646     return ($self->{sqlfalse});
 647   }
 648 }
 649
 650 sub _where_hashpair_HASHREF {
 651   my ($self, $k, $v, $logic) = @_;
 652   $logic ||= 'and';
 653
 654   local $self->{_nested_func_lhs} = $self->{_nested_func_lhs};
 655
 656   my ($all_sql, @all_bind);
 657
 658   for my $orig_op (sort keys %$v) {
 659     my $val = $v->{$orig_op};
 660
 661     # put the operator in canonical form
 662     my $op = $orig_op;
 663     $op =~ s/^-//;        # remove initial dash
 664     $op =~ s/[_\t ]+/ /g; # underscores and whitespace become single spaces
 665     $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 666
 667     my ($sql, @bind);
 668
 669     # CASE: col-value logic modifiers
 670     if ( $orig_op =~ /^ \- (and|or) $/xi ) {
 671       ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $1);
 672     }
 673     # CASE: special operators like -in or -between
 674     elsif ( my $special_op = List::Util::first {$op =~ $_->{regex}} @{$self->{special_ops}} ) {
 675       my $handler = $special_op->{handler};
 676       if (! $handler) {
 677         puke "No handler supplied for special operator $orig_op";
 678       }
 679       elsif (not ref $handler) {
 680         ($sql, @bind) = $self->$handler ($k, $op, $val);
 681       }
 682       elsif (ref $handler eq 'CODE') {
 683         ($sql, @bind) = $handler->($self, $k, $op, $val);
 684       }
 685       else {
 686         puke "Illegal handler for special operator $orig_op - expecting a method name or a coderef";
 687       }
 688     }
 689     else {
 690       $self->_SWITCH_refkind($val, {
 691
 692         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 693           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 694         },
 695
 696         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 697           my ($sub_sql, @sub_bind) = @$$val;
 698           $self->_assert_bindval_matches_bindtype(@sub_bind);
 699           $sql  = join ' ', $self->_convert($self->_quote($k)),
 700                             $self->_sqlcase($op),
 701                             $sub_sql;
 702           @bind = @sub_bind;
 703         },
 704
 705         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 706           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 707                    ($op =~ $self->{inequality_op}) ? 'is not' :
 708                puke "unexpected operator '$orig_op' with undef operand";
 709           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 710         },
 711
 712         FALLBACK => sub {       # CASE: col => {op/func => $stuff}
 713
 714           # retain for proper column type bind
 715           $self->{_nested_func_lhs} ||= $k;
 716
 717           ($sql, @bind) = $self->_where_func_generic ($op, $val);
 718
 719           $sql = join (' ',
 720             $self->_convert($self->_quote($k)),
 721             $self->{_nested_func_lhs} eq $k ? $sql : "($sql)",  # top level vs nested
 722           );
 723         },
 724       });
 725     }
 726
 727     ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
 728     push @all_bind, @bind;
 729   }
 730   return ($all_sql, @all_bind);
 731 }
 732
 733
 734
 735 sub _where_field_op_ARRAYREF {
 736   my ($self, $k, $op, $vals) = @_;
 737
 738   my @vals = @$vals;  #always work on a copy
 739
 740   if(@vals) {
 741     $self->_debug(sprintf '%s means multiple elements: [ %s ]',
 742       $vals,
 743       join (', ', map { defined $_ ? "'$_'" : 'NULL' } @vals ),
 744     );
 745
 746     # see if the first element is an -and/-or op
 747     my $logic;
 748     if (defined $vals[0] && $vals[0] =~ /^ - ( AND|OR ) $/ix) {
 749       $logic = uc $1;
 750       shift @vals;
 751     }
 752
 753     # distribute $op over each remaining member of @vals, append logic if exists
 754     return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 755
 756     # LDNOTE : had planned to change the distribution logic when
 757     # $op =~ $self->{inequality_op}, because of Morgan laws :
 758     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 759     # WHERE field != 22 OR  field != 33 : the user probably means
 760     # WHERE field != 22 AND field != 33.
 761     # To do this, replace the above to roughly :
 762     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 763     # return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 764
 765   }
 766   else {
 767     # try to DWIM on equality operators
 768     # LDNOTE : not 100% sure this is the correct thing to do ...
 769     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 770     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 771
 772     # otherwise
 773     puke "operator '$op' applied on an empty array (field '$k')";
 774   }
 775 }
 776
 777
 778 sub _where_hashpair_SCALARREF {
 779   my ($self, $k, $v) = @_;
 780   $self->_debug("SCALAR($k) means literal SQL: $$v");
 781   my $sql = $self->_quote($k) . " " . $$v;
 782   return ($sql);
 783 }
 784
 785 # literal SQL with bind
 786 sub _where_hashpair_ARRAYREFREF {
 787   my ($self, $k, $v) = @_;
 788   $self->_debug("REF($k) means literal SQL: @${$v}");
 789   my ($sql, @bind) = @$$v;
 790   $self->_assert_bindval_matches_bindtype(@bind);
 791   $sql  = $self->_quote($k) . " " . $sql;
 792   return ($sql, @bind );
 793 }
 794
 795 # literal SQL without bind
 796 sub _where_hashpair_SCALAR {
 797   my ($self, $k, $v) = @_;
 798   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 799   my $sql = join ' ', $self->_convert($self->_quote($k)),
 800                       $self->_sqlcase($self->{cmp}),
 801                       $self->_convert('?');
 802   my @bind =  $self->_bindtype($k, $v);
 803   return ( $sql, @bind);
 804 }
 805
 806
 807 sub _where_hashpair_UNDEF {
 808   my ($self, $k, $v) = @_;
 809   $self->_debug("UNDEF($k) means IS NULL");
 810   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 811   return ($sql);
 812 }
 813
 814 #======================================================================
 815 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 816 #======================================================================
 817
 818
 819 sub _where_SCALARREF {
 820   my ($self, $where) = @_;
 821
 822   # literal sql
 823   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 824   return ($$where);
 825 }
 826
 827
 828 sub _where_SCALAR {
 829   my ($self, $where) = @_;
 830
 831   # literal sql
 832   $self->_debug("NOREF(*top) means literal SQL: $where");
 833   return ($where);
 834 }
 835
 836
 837 sub _where_UNDEF {
 838   my ($self) = @_;
 839   return ();
 840 }
 841
 842
 843 #======================================================================
 844 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 845 #======================================================================
 846
 847
 848 sub _where_field_BETWEEN {
 849   my ($self, $k, $op, $vals) = @_;
 850
 851   my ($label, $and, $placeholder);
 852   $label       = $self->_convert($self->_quote($k));
 853   $and         = ' ' . $self->_sqlcase('and') . ' ';
 854   $placeholder = $self->_convert('?');
 855   $op               = $self->_sqlcase($op);
 856
 857   my ($clause, @bind) = $self->_SWITCH_refkind($vals, {
 858     ARRAYREFREF => sub {
 859       my ($s, @b) = @$$vals;
 860       $self->_assert_bindval_matches_bindtype(@b);
 861       ($s, @b);
 862     },
 863     SCALARREF => sub {
 864       return $$vals;
 865     },
 866     ARRAYREF => sub {
 867       puke "special op 'between' accepts an arrayref with exactly two values"
 868         if @$vals != 2;
 869
 870       my (@all_sql, @all_bind);
 871       foreach my $val (@$vals) {
 872         my ($sql, @bind) = $self->_SWITCH_refkind($val, {
 873            SCALAR => sub {
 874              return ($placeholder, ($val));
 875            },
 876            SCALARREF => sub {
 877              return ($self->_convert($$val), ());
 878            },
 879            ARRAYREFREF => sub {
 880              my ($sql, @bind) = @$$val;
 881              $self->_assert_bindval_matches_bindtype(@bind);
 882              return ($self->_convert($sql), @bind);
 883            },
 884         });
 885         push @all_sql, $sql;
 886         push @all_bind, @bind;
 887       }
 888
 889       return (
 890         (join $and, @all_sql),
 891         $self->_bindtype($k, @all_bind),
 892       );
 893     },
 894     FALLBACK => sub {
 895       puke "special op 'between' accepts an arrayref with two values, or a single literal scalarref/arrayref-ref";
 896     },
 897   });
 898
 899   my $sql = "( $label $op $clause )";
 900   return ($sql, @bind)
 901 }
 902
 903
 904 sub _where_field_IN {
 905   my ($self, $k, $op, $vals) = @_;
 906
 907   # backwards compatibility : if scalar, force into an arrayref
 908   $vals = [$vals] if defined $vals && ! ref $vals;
 909
 910   my ($label)       = $self->_convert($self->_quote($k));
 911   my ($placeholder) = $self->_convert('?');
 912   $op               = $self->_sqlcase($op);
 913
 914   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
 915     ARRAYREF => sub {     # list of choices
 916       if (@$vals) { # nonempty list
 917         my $placeholders  = join ", ", (($placeholder) x @$vals);
 918         my $sql           = "$label $op ( $placeholders )";
 919         my @bind = $self->_bindtype($k, @$vals);
 920
 921         return ($sql, @bind);
 922       }
 923       else { # empty list : some databases won't understand "IN ()", so DWIM
 924         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
 925         return ($sql);
 926       }
 927     },
 928
 929     SCALARREF => sub {  # literal SQL
 930       my $sql = $self->_open_outer_paren ($$vals);
 931       return ("$label $op ( $sql )");
 932     },
 933     ARRAYREFREF => sub {  # literal SQL with bind
 934       my ($sql, @bind) = @$$vals;
 935       $self->_assert_bindval_matches_bindtype(@bind);
 936       $sql = $self->_open_outer_paren ($sql);
 937       return ("$label $op ( $sql )", @bind);
 938     },
 939
 940     FALLBACK => sub {
 941       puke "special op 'in' requires an arrayref (or scalarref/arrayref-ref)";
 942     },
 943   });
 944
 945   return ($sql, @bind);
 946 }
 947
 948 # Some databases (SQLite) treat col IN (1, 2) different from
 949 # col IN ( (1, 2) ). Use this to strip all outer parens while
 950 # adding them back in the corresponding method
 951 sub _open_outer_paren {
 952   my ($self, $sql) = @_;
 953   $sql = $1 while $sql =~ /^ \s* \( (.*) \) \s* $/xs;
 954   return $sql;
 955 }
 956
 957
 958 #======================================================================
 959 # ORDER BY
 960 #======================================================================
 961
 962 sub _order_by {
 963   my ($self, $arg) = @_;
 964
 965   my (@sql, @bind);
 966   for my $c ($self->_order_by_chunks ($arg) ) {
 967     $self->_SWITCH_refkind ($c, {
 968       SCALAR => sub { push @sql, $c },
 969       ARRAYREF => sub { push @sql, shift @$c; push @bind, @$c },
 970     });
 971   }
 972
 973   my $sql = @sql
 974     ? sprintf ('%s %s',
 975         $self->_sqlcase(' order by'),
 976         join (', ', @sql)
 977       )
 978     : ''
 979   ;
 980
 981   return wantarray ? ($sql, @bind) : $sql;
 982 }
 983
 984 sub _order_by_chunks {
 985   my ($self, $arg) = @_;
 986
 987   return $self->_SWITCH_refkind($arg, {
 988
 989     ARRAYREF => sub {
 990       map { $self->_order_by_chunks ($_ ) } @$arg;
 991     },
 992
 993     ARRAYREFREF => sub {
 994       my ($s, @b) = @$$arg;
 995       $self->_assert_bindval_matches_bindtype(@b);
 996       [ $s, @b ];
 997     },
 998
 999     SCALAR    => sub {$self->_quote($arg)},
1000
1001     UNDEF     => sub {return () },
1002
1003     SCALARREF => sub {$$arg}, # literal SQL, no quoting
1004
1005     HASHREF   => sub {
1006       # get first pair in hash
1007       my ($key, $val, @rest) = %$arg;
1008
1009       return () unless $key;
1010
1011       if ( @rest or not $key =~ /^-(desc|asc)/i ) {
1012         puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
1013       }
1014
1015       my $direction = $1;
1016
1017       my @ret;
1018       for my $c ($self->_order_by_chunks ($val)) {
1019         my ($sql, @bind);
1020
1021         $self->_SWITCH_refkind ($c, {
1022           SCALAR => sub {
1023             $sql = $c;
1024           },
1025           ARRAYREF => sub {
1026             ($sql, @bind) = @$c;
1027           },
1028         });
1029
1030         $sql = $sql . ' ' . $self->_sqlcase($direction);
1031
1032         push @ret, [ $sql, @bind];
1033       }
1034
1035       return @ret;
1036     },
1037   });
1038 }
1039
1040
1041 #======================================================================
1042 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
1043 #======================================================================
1044
1045 sub _table  {
1046   my $self = shift;
1047   my $from = shift;
1048   $self->_SWITCH_refkind($from, {
1049     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
1050     SCALAR       => sub {$self->_quote($from)},
1051     SCALARREF    => sub {$$from},
1052     ARRAYREFREF  => sub {join ', ', @$from;},
1053   });
1054 }
1055
1056
1057 #======================================================================
1058 # UTILITY FUNCTIONS
1059 #======================================================================
1060
1061 # highly optimized, as it's called way too often
1062 sub _quote {
1063   # my ($self, $label) = @_;
1064
1065   return '' unless defined $_[1];
1066   return ${$_[1]} if ref($_[1]) eq 'SCALAR';
1067
1068   return $_[1] unless $_[0]->{quote_char};
1069
1070   my $qref = ref $_[0]->{quote_char};
1071   my ($l, $r);
1072   if (!$qref) {
1073     ($l, $r) = ( $_[0]->{quote_char}, $_[0]->{quote_char} );
1074   }
1075   elsif ($qref eq 'ARRAY') {
1076     ($l, $r) = @{$_[0]->{quote_char}};
1077   }
1078   else {
1079     puke "Unsupported quote_char format: $_[0]->{quote_char}";
1080   }
1081
1082   # parts containing * are naturally unquoted
1083   return join( $_[0]->{name_sep}||'', map
1084     { $_ eq '*' ? $_ : $l . $_ . $r }
1085     ( $_[0]->{name_sep} ? split (/\Q$_[0]->{name_sep}\E/, $_[1] ) : $_[1] )
1086   );
1087 }
1088
1089
1090 # Conversion, if applicable
1091 sub _convert ($) {
1092   #my ($self, $arg) = @_;
1093
1094 # LDNOTE : modified the previous implementation below because
1095 # it was not consistent : the first "return" is always an array,
1096 # the second "return" is context-dependent. Anyway, _convert
1097 # seems always used with just a single argument, so make it a
1098 # scalar function.
1099 #     return @_ unless $self->{convert};
1100 #     my $conv = $self->_sqlcase($self->{convert});
1101 #     my @ret = map { $conv.'('.$_.')' } @_;
1102 #     return wantarray ? @ret : $ret[0];
1103   if ($_[0]->{convert}) {
1104     return $_[0]->_sqlcase($_[0]->{convert}) .'(' . $_[1] . ')';
1105   }
1106   return $_[1];
1107 }
1108
1109 # And bindtype
1110 sub _bindtype (@) {
1111   #my ($self, $col, @vals) = @_;
1112
1113   #LDNOTE : changed original implementation below because it did not make
1114   # sense when bindtype eq 'columns' and @vals > 1.
1115 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
1116
1117   # called often - tighten code
1118   return $_[0]->{bindtype} eq 'columns'
1119     ? map {[$_[1], $_]} @_[2 .. $#_]
1120     : @_[2 .. $#_]
1121   ;
1122 }
1123
1124 # Dies if any element of @bind is not in [colname => value] format
1125 # if bindtype is 'columns'.
1126 sub _assert_bindval_matches_bindtype {
1127 #  my ($self, @bind) = @_;
1128   my $self = shift;
1129   if ($self->{bindtype} eq 'columns') {
1130     for (@_) {
1131       if (!defined $_ || ref($_) ne 'ARRAY' || @$_ != 2) {
1132         puke "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
1133       }
1134     }
1135   }
1136 }
1137
1138 sub _join_sql_clauses {
1139   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
1140
1141   if (@$clauses_aref > 1) {
1142     my $join  = " " . $self->_sqlcase($logic) . " ";
1143     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
1144     return ($sql, @$bind_aref);
1145   }
1146   elsif (@$clauses_aref) {
1147     return ($clauses_aref->[0], @$bind_aref); # no parentheses
1148   }
1149   else {
1150     return (); # if no SQL, ignore @$bind_aref
1151   }
1152 }
1153
1154
1155 # Fix SQL case, if so requested
1156 sub _sqlcase {
1157   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
1158   # don't touch the argument ... crooked logic, but let's not change it!
1159   return $_[0]->{case} ? $_[1] : uc($_[1]);
1160 }
1161
1162
1163 #======================================================================
1164 # DISPATCHING FROM REFKIND
1165 #======================================================================
1166
1167 sub _refkind {
1168   my ($self, $data) = @_;
1169
1170   return 'UNDEF' unless defined $data;
1171
1172   # blessed objects are treated like scalars
1173   my $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1174
1175   return 'SCALAR' unless $ref;
1176
1177   my $n_steps = 1;
1178   while ($ref eq 'REF') {
1179     $data = $$data;
1180     $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1181     $n_steps++ if $ref;
1182   }
1183
1184   return ($ref||'SCALAR') . ('REF' x $n_steps);
1185 }
1186
1187 sub _try_refkind {
1188   my ($self, $data) = @_;
1189   my @try = ($self->_refkind($data));
1190   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1191   push @try, 'FALLBACK';
1192   return \@try;
1193 }
1194
1195 sub _METHOD_FOR_refkind {
1196   my ($self, $meth_prefix, $data) = @_;
1197
1198   my $method;
1199   for (@{$self->_try_refkind($data)}) {
1200     $method = $self->can($meth_prefix."_".$_)
1201       and last;
1202   }
1203
1204   return $method || puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1205 }
1206
1207
1208 sub _SWITCH_refkind {
1209   my ($self, $data, $dispatch_table) = @_;
1210
1211   my $coderef;
1212   for (@{$self->_try_refkind($data)}) {
1213     $coderef = $dispatch_table->{$_}
1214       and last;
1215   }
1216
1217   puke "no dispatch entry for ".$self->_refkind($data)
1218     unless $coderef;
1219
1220   $coderef->();
1221 }
1222
1223
1224
1225
1226 #======================================================================
1227 # VALUES, GENERATE, AUTOLOAD
1228 #======================================================================
1229
1230 # LDNOTE: original code from nwiger, didn't touch code in that section
1231 # I feel the AUTOLOAD stuff should not be the default, it should
1232 # only be activated on explicit demand by user.
1233
1234 sub values {
1235     my $self = shift;
1236     my $data = shift || return;
1237     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1238         unless ref $data eq 'HASH';
1239
1240     my @all_bind;
1241     foreach my $k ( sort keys %$data ) {
1242         my $v = $data->{$k};
1243         $self->_SWITCH_refkind($v, {
1244           ARRAYREF => sub {
1245             if ($self->{array_datatypes}) { # array datatype
1246               push @all_bind, $self->_bindtype($k, $v);
1247             }
1248             else {                          # literal SQL with bind
1249               my ($sql, @bind) = @$v;
1250               $self->_assert_bindval_matches_bindtype(@bind);
1251               push @all_bind, @bind;
1252             }
1253           },
1254           ARRAYREFREF => sub { # literal SQL with bind
1255             my ($sql, @bind) = @${$v};
1256             $self->_assert_bindval_matches_bindtype(@bind);
1257             push @all_bind, @bind;
1258           },
1259           SCALARREF => sub {  # literal SQL without bind
1260           },
1261           SCALAR_or_UNDEF => sub {
1262             push @all_bind, $self->_bindtype($k, $v);
1263           },
1264         });
1265     }
1266
1267     return @all_bind;
1268 }
1269
1270 sub generate {
1271     my $self  = shift;
1272
1273     my(@sql, @sqlq, @sqlv);
1274
1275     for (@_) {
1276         my $ref = ref $_;
1277         if ($ref eq 'HASH') {
1278             for my $k (sort keys %$_) {
1279                 my $v = $_->{$k};
1280                 my $r = ref $v;
1281                 my $label = $self->_quote($k);
1282                 if ($r eq 'ARRAY') {
1283                     # literal SQL with bind
1284                     my ($sql, @bind) = @$v;
1285                     $self->_assert_bindval_matches_bindtype(@bind);
1286                     push @sqlq, "$label = $sql";
1287                     push @sqlv, @bind;
1288                 } elsif ($r eq 'SCALAR') {
1289                     # literal SQL without bind
1290                     push @sqlq, "$label = $$v";
1291                 } else {
1292                     push @sqlq, "$label = ?";
1293                     push @sqlv, $self->_bindtype($k, $v);
1294                 }
1295             }
1296             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1297         } elsif ($ref eq 'ARRAY') {
1298             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1299             for my $v (@$_) {
1300                 my $r = ref $v;
1301                 if ($r eq 'ARRAY') {   # literal SQL with bind
1302                     my ($sql, @bind) = @$v;
1303                     $self->_assert_bindval_matches_bindtype(@bind);
1304                     push @sqlq, $sql;
1305                     push @sqlv, @bind;
1306                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1307                     # embedded literal SQL
1308                     push @sqlq, $$v;
1309                 } else {
1310                     push @sqlq, '?';
1311                     push @sqlv, $v;
1312                 }
1313             }
1314             push @sql, '(' . join(', ', @sqlq) . ')';
1315         } elsif ($ref eq 'SCALAR') {
1316             # literal SQL
1317             push @sql, $$_;
1318         } else {
1319             # strings get case twiddled
1320             push @sql, $self->_sqlcase($_);
1321         }
1322     }
1323
1324     my $sql = join ' ', @sql;
1325
1326     # this is pretty tricky
1327     # if ask for an array, return ($stmt, @bind)
1328     # otherwise, s/?/shift @sqlv/ to put it inline
1329     if (wantarray) {
1330         return ($sql, @sqlv);
1331     } else {
1332         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1333                              ref $d ? $d->[1] : $d/e;
1334         return $sql;
1335     }
1336 }
1337
1338
1339 sub DESTROY { 1 }
1340
1341 sub AUTOLOAD {
1342     # This allows us to check for a local, then _form, attr
1343     my $self = shift;
1344     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1345     return $self->generate($name, @_);
1346 }
1347
1348 1;
1349
1350
1351
1352 __END__
1353
1354 =head1 NAME
1355
1356 SQL::Abstract - Generate SQL from Perl data structures
1357
1358 =head1 SYNOPSIS
1359
1360     use SQL::Abstract;
1361
1362     my $sql = SQL::Abstract->new;
1363
1364     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1365
1366     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1367
1368     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1369
1370     my($stmt, @bind) = $sql->delete($table, \%where);
1371
1372     # Then, use these in your DBI statements
1373     my $sth = $dbh->prepare($stmt);
1374     $sth->execute(@bind);
1375
1376     # Just generate the WHERE clause
1377     my($stmt, @bind) = $sql->where(\%where, \@order);
1378
1379     # Return values in the same order, for hashed queries
1380     # See PERFORMANCE section for more details
1381     my @bind = $sql->values(\%fieldvals);
1382
1383 =head1 DESCRIPTION
1384
1385 This module was inspired by the excellent L<DBIx::Abstract>.
1386 However, in using that module I found that what I really wanted
1387 to do was generate SQL, but still retain complete control over my
1388 statement handles and use the DBI interface. So, I set out to
1389 create an abstract SQL generation module.
1390
1391 While based on the concepts used by L<DBIx::Abstract>, there are
1392 several important differences, especially when it comes to WHERE
1393 clauses. I have modified the concepts used to make the SQL easier
1394 to generate from Perl data structures and, IMO, more intuitive.
1395 The underlying idea is for this module to do what you mean, based
1396 on the data structures you provide it. The big advantage is that
1397 you don't have to modify your code every time your data changes,
1398 as this module figures it out.
1399
1400 To begin with, an SQL INSERT is as easy as just specifying a hash
1401 of C<key=value> pairs:
1402
1403     my %data = (
1404         name => 'Jimbo Bobson',
1405         phone => '123-456-7890',
1406         address => '42 Sister Lane',
1407         city => 'St. Louis',
1408         state => 'Louisiana',
1409     );
1410
1411 The SQL can then be generated with this:
1412
1413     my($stmt, @bind) = $sql->insert('people', \%data);
1414
1415 Which would give you something like this:
1416
1417     $stmt = "INSERT INTO people
1418                     (address, city, name, phone, state)
1419                     VALUES (?, ?, ?, ?, ?)";
1420     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1421              '123-456-7890', 'Louisiana');
1422
1423 These are then used directly in your DBI code:
1424
1425     my $sth = $dbh->prepare($stmt);
1426     $sth->execute(@bind);
1427
1428 =head2 Inserting and Updating Arrays
1429
1430 If your database has array types (like for example Postgres),
1431 activate the special option C<< array_datatypes => 1 >>
1432 when creating the C<SQL::Abstract> object.
1433 Then you may use an arrayref to insert and update database array types:
1434
1435     my $sql = SQL::Abstract->new(array_datatypes => 1);
1436     my %data = (
1437         planets => [qw/Mercury Venus Earth Mars/]
1438     );
1439
1440     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1441
1442 This results in:
1443
1444     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1445
1446     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1447
1448
1449 =head2 Inserting and Updating SQL
1450
1451 In order to apply SQL functions to elements of your C<%data> you may
1452 specify a reference to an arrayref for the given hash value. For example,
1453 if you need to execute the Oracle C<to_date> function on a value, you can
1454 say something like this:
1455
1456     my %data = (
1457         name => 'Bill',
1458         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1459     );
1460
1461 The first value in the array is the actual SQL. Any other values are
1462 optional and would be included in the bind values array. This gives
1463 you:
1464
1465     my($stmt, @bind) = $sql->insert('people', \%data);
1466
1467     $stmt = "INSERT INTO people (name, date_entered)
1468                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1469     @bind = ('Bill', '03/02/2003');
1470
1471 An UPDATE is just as easy, all you change is the name of the function:
1472
1473     my($stmt, @bind) = $sql->update('people', \%data);
1474
1475 Notice that your C<%data> isn't touched; the module will generate
1476 the appropriately quirky SQL for you automatically. Usually you'll
1477 want to specify a WHERE clause for your UPDATE, though, which is
1478 where handling C<%where> hashes comes in handy...
1479
1480 =head2 Complex where statements
1481
1482 This module can generate pretty complicated WHERE statements
1483 easily. For example, simple C<key=value> pairs are taken to mean
1484 equality, and if you want to see if a field is within a set
1485 of values, you can use an arrayref. Let's say we wanted to
1486 SELECT some data based on this criteria:
1487
1488     my %where = (
1489        requestor => 'inna',
1490        worker => ['nwiger', 'rcwe', 'sfz'],
1491        status => { '!=', 'completed' }
1492     );
1493
1494     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1495
1496 The above would give you something like this:
1497
1498     $stmt = "SELECT * FROM tickets WHERE
1499                 ( requestor = ? ) AND ( status != ? )
1500                 AND ( worker = ? OR worker = ? OR worker = ? )";
1501     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1502
1503 Which you could then use in DBI code like so:
1504
1505     my $sth = $dbh->prepare($stmt);
1506     $sth->execute(@bind);
1507
1508 Easy, eh?
1509
1510 =head1 FUNCTIONS
1511
1512 The functions are simple. There's one for each major SQL operation,
1513 and a constructor you use first. The arguments are specified in a
1514 similar order to each function (table, then fields, then a where
1515 clause) to try and simplify things.
1516
1517
1518
1519
1520 =head2 new(option => 'value')
1521
1522 The C<new()> function takes a list of options and values, and returns
1523 a new B<SQL::Abstract> object which can then be used to generate SQL
1524 through the methods below. The options accepted are:
1525
1526 =over
1527
1528 =item case
1529
1530 If set to 'lower', then SQL will be generated in all lowercase. By
1531 default SQL is generated in "textbook" case meaning something like:
1532
1533     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1534
1535 Any setting other than 'lower' is ignored.
1536
1537 =item cmp
1538
1539 This determines what the default comparison operator is. By default
1540 it is C<=>, meaning that a hash like this:
1541
1542     %where = (name => 'nwiger', email => 'nate@wiger.org');
1543
1544 Will generate SQL like this:
1545
1546     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1547
1548 However, you may want loose comparisons by default, so if you set
1549 C<cmp> to C<like> you would get SQL such as:
1550
1551     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1552
1553 You can also override the comparsion on an individual basis - see
1554 the huge section on L</"WHERE CLAUSES"> at the bottom.
1555
1556 =item sqltrue, sqlfalse
1557
1558 Expressions for inserting boolean values within SQL statements.
1559 By default these are C<1=1> and C<1=0>. They are used
1560 by the special operators C<-in> and C<-not_in> for generating
1561 correct SQL even when the argument is an empty array (see below).
1562
1563 =item logic
1564
1565 This determines the default logical operator for multiple WHERE
1566 statements in arrays or hashes. If absent, the default logic is "or"
1567 for arrays, and "and" for hashes. This means that a WHERE
1568 array of the form:
1569
1570     @where = (
1571         event_date => {'>=', '2/13/99'},
1572         event_date => {'<=', '4/24/03'},
1573     );
1574
1575 will generate SQL like this:
1576
1577     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1578
1579 This is probably not what you want given this query, though (look
1580 at the dates). To change the "OR" to an "AND", simply specify:
1581
1582     my $sql = SQL::Abstract->new(logic => 'and');
1583
1584 Which will change the above C<WHERE> to:
1585
1586     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1587
1588 The logic can also be changed locally by inserting
1589 a modifier in front of an arrayref :
1590
1591     @where = (-and => [event_date => {'>=', '2/13/99'},
1592                        event_date => {'<=', '4/24/03'} ]);
1593
1594 See the L</"WHERE CLAUSES"> section for explanations.
1595
1596 =item convert
1597
1598 This will automatically convert comparisons using the specified SQL
1599 function for both column and value. This is mostly used with an argument
1600 of C<upper> or C<lower>, so that the SQL will have the effect of
1601 case-insensitive "searches". For example, this:
1602
1603     $sql = SQL::Abstract->new(convert => 'upper');
1604     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1605
1606 Will turn out the following SQL:
1607
1608     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1609
1610 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1611 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1612 not validate this option; it will just pass through what you specify verbatim).
1613
1614 =item bindtype
1615
1616 This is a kludge because many databases suck. For example, you can't
1617 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1618 Instead, you have to use C<bind_param()>:
1619
1620     $sth->bind_param(1, 'reg data');
1621     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1622
1623 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1624 which loses track of which field each slot refers to. Fear not.
1625
1626 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1627 Currently, you can specify either C<normal> (default) or C<columns>. If you
1628 specify C<columns>, you will get an array that looks like this:
1629
1630     my $sql = SQL::Abstract->new(bindtype => 'columns');
1631     my($stmt, @bind) = $sql->insert(...);
1632
1633     @bind = (
1634         [ 'column1', 'value1' ],
1635         [ 'column2', 'value2' ],
1636         [ 'column3', 'value3' ],
1637     );
1638
1639 You can then iterate through this manually, using DBI's C<bind_param()>.
1640
1641     $sth->prepare($stmt);
1642     my $i = 1;
1643     for (@bind) {
1644         my($col, $data) = @$_;
1645         if ($col eq 'details' || $col eq 'comments') {
1646             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1647         } elsif ($col eq 'image') {
1648             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1649         } else {
1650             $sth->bind_param($i, $data);
1651         }
1652         $i++;
1653     }
1654     $sth->execute;      # execute without @bind now
1655
1656 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1657 Basically, the advantage is still that you don't have to care which fields
1658 are or are not included. You could wrap that above C<for> loop in a simple
1659 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1660 get a layer of abstraction over manual SQL specification.
1661
1662 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1663 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1664 will expect the bind values in this format.
1665
1666 =item quote_char
1667
1668 This is the character that a table or column name will be quoted
1669 with.  By default this is an empty string, but you could set it to
1670 the character C<`>, to generate SQL like this:
1671
1672   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1673
1674 Alternatively, you can supply an array ref of two items, the first being the left
1675 hand quote character, and the second the right hand quote character. For
1676 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1677 that generates SQL like this:
1678
1679   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1680
1681 Quoting is useful if you have tables or columns names that are reserved
1682 words in your database's SQL dialect.
1683
1684 =item name_sep
1685
1686 This is the character that separates a table and column name.  It is
1687 necessary to specify this when the C<quote_char> option is selected,
1688 so that tables and column names can be individually quoted like this:
1689
1690   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1691
1692 =item array_datatypes
1693
1694 When this option is true, arrayrefs in INSERT or UPDATE are
1695 interpreted as array datatypes and are passed directly
1696 to the DBI layer.
1697 When this option is false, arrayrefs are interpreted
1698 as literal SQL, just like refs to arrayrefs
1699 (but this behavior is for backwards compatibility; when writing
1700 new queries, use the "reference to arrayref" syntax
1701 for literal SQL).
1702
1703
1704 =item special_ops
1705
1706 Takes a reference to a list of "special operators"
1707 to extend the syntax understood by L<SQL::Abstract>.
1708 See section L</"SPECIAL OPERATORS"> for details.
1709
1710 =item unary_ops
1711
1712 Takes a reference to a list of "unary operators"
1713 to extend the syntax understood by L<SQL::Abstract>.
1714 See section L</"UNARY OPERATORS"> for details.
1715
1716
1717
1718 =back
1719
1720 =head2 insert($table, \@values || \%fieldvals, \%options)
1721
1722 This is the simplest function. You simply give it a table name
1723 and either an arrayref of values or hashref of field/value pairs.
1724 It returns an SQL INSERT statement and a list of bind values.
1725 See the sections on L</"Inserting and Updating Arrays"> and
1726 L</"Inserting and Updating SQL"> for information on how to insert
1727 with those data types.
1728
1729 The optional C<\%options> hash reference may contain additional
1730 options to generate the insert SQL. Currently supported options
1731 are:
1732
1733 =over 4
1734
1735 =item returning
1736
1737 Takes either a scalar of raw SQL fields, or an array reference of
1738 field names, and adds on an SQL C<RETURNING> statement at the end.
1739 This allows you to return data generated by the insert statement
1740 (such as row IDs) without performing another C<SELECT> statement.
1741 Note, however, this is not part of the SQL standard and may not
1742 be supported by all database engines.
1743
1744 =back
1745
1746 =head2 update($table, \%fieldvals, \%where)
1747
1748 This takes a table, hashref of field/value pairs, and an optional
1749 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1750 of bind values.
1751 See the sections on L</"Inserting and Updating Arrays"> and
1752 L</"Inserting and Updating SQL"> for information on how to insert
1753 with those data types.
1754
1755 =head2 select($source, $fields, $where, $order)
1756
1757 This returns a SQL SELECT statement and associated list of bind values, as
1758 specified by the arguments  :
1759
1760 =over
1761
1762 =item $source
1763
1764 Specification of the 'FROM' part of the statement.
1765 The argument can be either a plain scalar (interpreted as a table
1766 name, will be quoted), or an arrayref (interpreted as a list
1767 of table names, joined by commas, quoted), or a scalarref
1768 (literal table name, not quoted), or a ref to an arrayref
1769 (list of literal table names, joined by commas, not quoted).
1770
1771 =item $fields
1772
1773 Specification of the list of fields to retrieve from
1774 the source.
1775 The argument can be either an arrayref (interpreted as a list
1776 of field names, will be joined by commas and quoted), or a
1777 plain scalar (literal SQL, not quoted).
1778 Please observe that this API is not as flexible as for
1779 the first argument C<$table>, for backwards compatibility reasons.
1780
1781 =item $where
1782
1783 Optional argument to specify the WHERE part of the query.
1784 The argument is most often a hashref, but can also be
1785 an arrayref or plain scalar --
1786 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1787
1788 =item $order
1789
1790 Optional argument to specify the ORDER BY part of the query.
1791 The argument can be a scalar, a hashref or an arrayref
1792 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1793 for details.
1794
1795 =back
1796
1797
1798 =head2 delete($table, \%where)
1799
1800 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1801 It returns an SQL DELETE statement and list of bind values.
1802
1803 =head2 where(\%where, \@order)
1804
1805 This is used to generate just the WHERE clause. For example,
1806 if you have an arbitrary data structure and know what the
1807 rest of your SQL is going to look like, but want an easy way
1808 to produce a WHERE clause, use this. It returns an SQL WHERE
1809 clause and list of bind values.
1810
1811
1812 =head2 values(\%data)
1813
1814 This just returns the values from the hash C<%data>, in the same
1815 order that would be returned from any of the other above queries.
1816 Using this allows you to markedly speed up your queries if you
1817 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1818
1819 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1820
1821 Warning: This is an experimental method and subject to change.
1822
1823 This returns arbitrarily generated SQL. It's a really basic shortcut.
1824 It will return two different things, depending on return context:
1825
1826     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1827     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
1828
1829 These would return the following:
1830
1831     # First calling form
1832     $stmt = "CREATE TABLE test (?, ?)";
1833     @bind = (field1, field2);
1834
1835     # Second calling form
1836     $stmt_and_val = "CREATE TABLE test (field1, field2)";
1837
1838 Depending on what you're trying to do, it's up to you to choose the correct
1839 format. In this example, the second form is what you would want.
1840
1841 By the same token:
1842
1843     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
1844
1845 Might give you:
1846
1847     ALTER SESSION SET nls_date_format = 'MM/YY'
1848
1849 You get the idea. Strings get their case twiddled, but everything
1850 else remains verbatim.
1851
1852
1853
1854
1855 =head1 WHERE CLAUSES
1856
1857 =head2 Introduction
1858
1859 This module uses a variation on the idea from L<DBIx::Abstract>. It
1860 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
1861 module is that things in arrays are OR'ed, and things in hashes
1862 are AND'ed.>
1863
1864 The easiest way to explain is to show lots of examples. After
1865 each C<%where> hash shown, it is assumed you used:
1866
1867     my($stmt, @bind) = $sql->where(\%where);
1868
1869 However, note that the C<%where> hash can be used directly in any
1870 of the other functions as well, as described above.
1871
1872 =head2 Key-value pairs
1873
1874 So, let's get started. To begin, a simple hash:
1875
1876     my %where  = (
1877         user   => 'nwiger',
1878         status => 'completed'
1879     );
1880
1881 Is converted to SQL C<key = val> statements:
1882
1883     $stmt = "WHERE user = ? AND status = ?";
1884     @bind = ('nwiger', 'completed');
1885
1886 One common thing I end up doing is having a list of values that
1887 a field can be in. To do this, simply specify a list inside of
1888 an arrayref:
1889
1890     my %where  = (
1891         user   => 'nwiger',
1892         status => ['assigned', 'in-progress', 'pending'];
1893     );
1894
1895 This simple code will create the following:
1896
1897     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
1898     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
1899
1900 A field associated to an empty arrayref will be considered a
1901 logical false and will generate 0=1.
1902
1903 =head2 Tests for NULL values
1904
1905 If the value part is C<undef> then this is converted to SQL <IS NULL>
1906
1907     my %where  = (
1908         user   => 'nwiger',
1909         status => undef,
1910     );
1911
1912 becomes:
1913
1914     $stmt = "WHERE user = ? AND status IS NULL";
1915     @bind = ('nwiger');
1916
1917 =head2 Specific comparison operators
1918
1919 If you want to specify a different type of operator for your comparison,
1920 you can use a hashref for a given column:
1921
1922     my %where  = (
1923         user   => 'nwiger',
1924         status => { '!=', 'completed' }
1925     );
1926
1927 Which would generate:
1928
1929     $stmt = "WHERE user = ? AND status != ?";
1930     @bind = ('nwiger', 'completed');
1931
1932 To test against multiple values, just enclose the values in an arrayref:
1933
1934     status => { '=', ['assigned', 'in-progress', 'pending'] };
1935
1936 Which would give you:
1937
1938     "WHERE status = ? OR status = ? OR status = ?"
1939
1940
1941 The hashref can also contain multiple pairs, in which case it is expanded
1942 into an C<AND> of its elements:
1943
1944     my %where  = (
1945         user   => 'nwiger',
1946         status => { '!=', 'completed', -not_like => 'pending%' }
1947     );
1948
1949     # Or more dynamically, like from a form
1950     $where{user} = 'nwiger';
1951     $where{status}{'!='} = 'completed';
1952     $where{status}{'-not_like'} = 'pending%';
1953
1954     # Both generate this
1955     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
1956     @bind = ('nwiger', 'completed', 'pending%');
1957
1958
1959 To get an OR instead, you can combine it with the arrayref idea:
1960
1961     my %where => (
1962          user => 'nwiger',
1963          priority => [ {'=', 2}, {'!=', 1} ]
1964     );
1965
1966 Which would generate:
1967
1968     $stmt = "WHERE user = ? AND priority = ? OR priority != ?";
1969     @bind = ('nwiger', '2', '1');
1970
1971 If you want to include literal SQL (with or without bind values), just use a
1972 scalar reference or array reference as the value:
1973
1974     my %where  = (
1975         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
1976         date_expires => { '<' => \"now()" }
1977     );
1978
1979 Which would generate:
1980
1981     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
1982     @bind = ('11/26/2008');
1983
1984
1985 =head2 Logic and nesting operators
1986
1987 In the example above,
1988 there is a subtle trap if you want to say something like
1989 this (notice the C<AND>):
1990
1991     WHERE priority != ? AND priority != ?
1992
1993 Because, in Perl you I<can't> do this:
1994
1995     priority => { '!=', 2, '!=', 1 }
1996
1997 As the second C<!=> key will obliterate the first. The solution
1998 is to use the special C<-modifier> form inside an arrayref:
1999
2000     priority => [ -and => {'!=', 2},
2001                           {'!=', 1} ]
2002
2003
2004 Normally, these would be joined by C<OR>, but the modifier tells it
2005 to use C<AND> instead. (Hint: You can use this in conjunction with the
2006 C<logic> option to C<new()> in order to change the way your queries
2007 work by default.) B<Important:> Note that the C<-modifier> goes
2008 B<INSIDE> the arrayref, as an extra first element. This will
2009 B<NOT> do what you think it might:
2010
2011     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
2012
2013 Here is a quick list of equivalencies, since there is some overlap:
2014
2015     # Same
2016     status => {'!=', 'completed', 'not like', 'pending%' }
2017     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
2018
2019     # Same
2020     status => {'=', ['assigned', 'in-progress']}
2021     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
2022     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
2023
2024
2025
2026 =head2 Special operators : IN, BETWEEN, etc.
2027
2028 You can also use the hashref format to compare a list of fields using the
2029 C<IN> comparison operator, by specifying the list as an arrayref:
2030
2031     my %where  = (
2032         status   => 'completed',
2033         reportid => { -in => [567, 2335, 2] }
2034     );
2035
2036 Which would generate:
2037
2038     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
2039     @bind = ('completed', '567', '2335', '2');
2040
2041 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
2042 the same way.
2043
2044 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
2045 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
2046 'sqltrue' (by default : C<1=1>).
2047
2048 In addition to the array you can supply a chunk of literal sql or
2049 literal sql with bind:
2050
2051     my %where = {
2052       customer => { -in => \[
2053         'SELECT cust_id FROM cust WHERE balance > ?',
2054         2000,
2055       ],
2056       status => { -in => \'SELECT status_codes FROM states' },
2057     };
2058
2059 would generate:
2060
2061     $stmt = "WHERE (
2062           customer IN ( SELECT cust_id FROM cust WHERE balance > ? )
2063       AND status IN ( SELECT status_codes FROM states )
2064     )";
2065     @bind = ('2000');
2066
2067
2068
2069 Another pair of operators is C<-between> and C<-not_between>,
2070 used with an arrayref of two values:
2071
2072     my %where  = (
2073         user   => 'nwiger',
2074         completion_date => {
2075            -not_between => ['2002-10-01', '2003-02-06']
2076         }
2077     );
2078
2079 Would give you:
2080
2081     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
2082
2083 Just like with C<-in> all plausible combinations of literal SQL
2084 are possible:
2085
2086     my %where = {
2087       start0 => { -between => [ 1, 2 ] },
2088       start1 => { -between => \["? AND ?", 1, 2] },
2089       start2 => { -between => \"lower(x) AND upper(y)" },
2090       start3 => { -between => [
2091         \"lower(x)",
2092         \["upper(?)", 'stuff' ],
2093       ] },
2094     };
2095
2096 Would give you:
2097
2098     $stmt = "WHERE (
2099           ( start0 BETWEEN ? AND ?                )
2100       AND ( start1 BETWEEN ? AND ?                )
2101       AND ( start2 BETWEEN lower(x) AND upper(y)  )
2102       AND ( start3 BETWEEN lower(x) AND upper(?)  )
2103     )";
2104     @bind = (1, 2, 1, 2, 'stuff');
2105
2106
2107 These are the two builtin "special operators"; but the
2108 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
2109
2110 =head2 Unary operators: bool
2111
2112 If you wish to test against boolean columns or functions within your
2113 database you can use the C<-bool> and C<-not_bool> operators. For
2114 example to test the column C<is_user> being true and the column
2115 C<is_enabled> being false you would use:-
2116
2117     my %where  = (
2118         -bool       => 'is_user',
2119         -not_bool   => 'is_enabled',
2120     );
2121
2122 Would give you:
2123
2124     WHERE is_user AND NOT is_enabled
2125
2126 If a more complex combination is required, testing more conditions,
2127 then you should use the and/or operators:-
2128
2129     my %where  = (
2130         -and           => [
2131             -bool      => 'one',
2132             -bool      => 'two',
2133             -bool      => 'three',
2134             -not_bool  => 'four',
2135         ],
2136     );
2137
2138 Would give you:
2139
2140     WHERE one AND two AND three AND NOT four
2141
2142
2143 =head2 Nested conditions, -and/-or prefixes
2144
2145 So far, we've seen how multiple conditions are joined with a top-level
2146 C<AND>.  We can change this by putting the different conditions we want in
2147 hashes and then putting those hashes in an array. For example:
2148
2149     my @where = (
2150         {
2151             user   => 'nwiger',
2152             status => { -like => ['pending%', 'dispatched'] },
2153         },
2154         {
2155             user   => 'robot',
2156             status => 'unassigned',
2157         }
2158     );
2159
2160 This data structure would create the following:
2161
2162     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
2163                 OR ( user = ? AND status = ? ) )";
2164     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
2165
2166
2167 There is also a special C<-nest>
2168 operator which adds an additional set of parens, to create a subquery.
2169 For example, to get something like this:
2170
2171     $stmt = "WHERE user = ? AND ( workhrs > ? OR geo = ? )";
2172     @bind = ('nwiger', '20', 'ASIA');
2173
2174 You would do:
2175
2176     my %where = (
2177          user => 'nwiger',
2178         -nest => [ workhrs => {'>', 20}, geo => 'ASIA' ],
2179     );
2180
2181
2182 Finally, clauses in hashrefs or arrayrefs can be
2183 prefixed with an C<-and> or C<-or> to change the logic
2184 inside :
2185
2186     my @where = (
2187          -and => [
2188             user => 'nwiger',
2189             -nest => [
2190                 -and => [workhrs => {'>', 20}, geo => 'ASIA' ],
2191                 -and => [workhrs => {'<', 50}, geo => 'EURO' ]
2192             ],
2193         ],
2194     );
2195
2196 That would yield:
2197
2198     WHERE ( user = ? AND
2199           ( ( workhrs > ? AND geo = ? )
2200          OR ( workhrs < ? AND geo = ? ) ) )
2201
2202
2203 =head2 Algebraic inconsistency, for historical reasons
2204
2205 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
2206 operator goes C<outside> of the nested structure; whereas when connecting
2207 several constraints on one column, the C<-and> operator goes
2208 C<inside> the arrayref. Here is an example combining both features :
2209
2210    my @where = (
2211      -and => [a => 1, b => 2],
2212      -or  => [c => 3, d => 4],
2213       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
2214    )
2215
2216 yielding
2217
2218   WHERE ( (    ( a = ? AND b = ? )
2219             OR ( c = ? OR d = ? )
2220             OR ( e LIKE ? AND e LIKE ? ) ) )
2221
2222 This difference in syntax is unfortunate but must be preserved for
2223 historical reasons. So be careful : the two examples below would
2224 seem algebraically equivalent, but they are not
2225
2226   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
2227   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
2228
2229   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
2230   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
2231
2232
2233 =head2 Literal SQL
2234
2235 Finally, sometimes only literal SQL will do. If you want to include
2236 literal SQL verbatim, you can specify it as a scalar reference, namely:
2237
2238     my $inn = 'is Not Null';
2239     my %where = (
2240         priority => { '<', 2 },
2241         requestor => \$inn
2242     );
2243
2244 This would create:
2245
2246     $stmt = "WHERE priority < ? AND requestor is Not Null";
2247     @bind = ('2');
2248
2249 Note that in this example, you only get one bind parameter back, since
2250 the verbatim SQL is passed as part of the statement.
2251
2252 Of course, just to prove a point, the above can also be accomplished
2253 with this:
2254
2255     my %where = (
2256         priority  => { '<', 2 },
2257         requestor => { '!=', undef },
2258     );
2259
2260
2261 TMTOWTDI
2262
2263 Conditions on boolean columns can be expressed in the same way, passing
2264 a reference to an empty string, however using liternal SQL in this way
2265 is deprecated - the preferred method is to use the boolean operators -
2266 see L</"Unary operators: bool"> :
2267
2268     my %where = (
2269         priority  => { '<', 2 },
2270         is_ready  => \"";
2271     );
2272
2273 which yields
2274
2275     $stmt = "WHERE priority < ? AND is_ready";
2276     @bind = ('2');
2277
2278 Literal SQL is also the only way to compare 2 columns to one another:
2279
2280     my %where = (
2281         priority => { '<', 2 },
2282         requestor => \'= submittor'
2283     );
2284
2285 which creates:
2286
2287     $stmt = "WHERE priority < ? AND requestor = submitter";
2288     @bind = ('2');
2289
2290 =head2 Literal SQL with placeholders and bind values (subqueries)
2291
2292 If the literal SQL to be inserted has placeholders and bind values,
2293 use a reference to an arrayref (yes this is a double reference --
2294 not so common, but perfectly legal Perl). For example, to find a date
2295 in Postgres you can use something like this:
2296
2297     my %where = (
2298        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
2299     )
2300
2301 This would create:
2302
2303     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
2304     @bind = ('10');
2305
2306 Note that you must pass the bind values in the same format as they are returned
2307 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
2308 provide the bind values in the C<< [ column_meta => value ] >> format, where
2309 C<column_meta> is an opaque scalar value; most commonly the column name, but
2310 you can use any scalar value (including references and blessed references),
2311 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
2312 to C<columns> the above example will look like:
2313
2314     my %where = (
2315        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
2316     )
2317
2318 Literal SQL is especially useful for nesting parenthesized clauses in the
2319 main SQL query. Here is a first example :
2320
2321   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2322                                100, "foo%");
2323   my %where = (
2324     foo => 1234,
2325     bar => \["IN ($sub_stmt)" => @sub_bind],
2326   );
2327
2328 This yields :
2329
2330   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2331                                              WHERE c2 < ? AND c3 LIKE ?))";
2332   @bind = (1234, 100, "foo%");
2333
2334 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2335 are expressed in the same way. Of course the C<$sub_stmt> and
2336 its associated bind values can be generated through a former call
2337 to C<select()> :
2338
2339   my ($sub_stmt, @sub_bind)
2340      = $sql->select("t1", "c1", {c2 => {"<" => 100},
2341                                  c3 => {-like => "foo%"}});
2342   my %where = (
2343     foo => 1234,
2344     bar => \["> ALL ($sub_stmt)" => @sub_bind],
2345   );
2346
2347 In the examples above, the subquery was used as an operator on a column;
2348 but the same principle also applies for a clause within the main C<%where>
2349 hash, like an EXISTS subquery :
2350
2351   my ($sub_stmt, @sub_bind)
2352      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2353   my %where = (
2354     foo   => 1234,
2355     -nest => \["EXISTS ($sub_stmt)" => @sub_bind],
2356   );
2357
2358 which yields
2359
2360   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2361                                         WHERE c1 = ? AND c2 > t0.c0))";
2362   @bind = (1234, 1);
2363
2364
2365 Observe that the condition on C<c2> in the subquery refers to
2366 column C<t0.c0> of the main query : this is I<not> a bind
2367 value, so we have to express it through a scalar ref.
2368 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2369 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2370 what we wanted here.
2371
2372 Another use of the subquery technique is when some SQL clauses need
2373 parentheses, as it often occurs with some proprietary SQL extensions
2374 like for example fulltext expressions, geospatial expressions,
2375 NATIVE clauses, etc. Here is an example of a fulltext query in MySQL :
2376
2377   my %where = (
2378     -nest => \["MATCH (col1, col2) AGAINST (?)" => qw/apples/]
2379   );
2380
2381 Finally, here is an example where a subquery is used
2382 for expressing unary negation:
2383
2384   my ($sub_stmt, @sub_bind)
2385      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2386   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2387   my %where = (
2388         lname  => {like => '%son%'},
2389         -nest  => \["NOT ($sub_stmt)" => @sub_bind],
2390     );
2391
2392 This yields
2393
2394   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2395   @bind = ('%son%', 10, 20)
2396
2397
2398
2399 =head2 Conclusion
2400
2401 These pages could go on for a while, since the nesting of the data
2402 structures this module can handle are pretty much unlimited (the
2403 module implements the C<WHERE> expansion as a recursive function
2404 internally). Your best bet is to "play around" with the module a
2405 little to see how the data structures behave, and choose the best
2406 format for your data based on that.
2407
2408 And of course, all the values above will probably be replaced with
2409 variables gotten from forms or the command line. After all, if you
2410 knew everything ahead of time, you wouldn't have to worry about
2411 dynamically-generating SQL and could just hardwire it into your
2412 script.
2413
2414
2415
2416
2417 =head1 ORDER BY CLAUSES
2418
2419 Some functions take an order by clause. This can either be a scalar (just a
2420 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2421 or an array of either of the two previous forms. Examples:
2422
2423                Given            |         Will Generate
2424     ----------------------------------------------------------
2425                                 |
2426     \'colA DESC'                | ORDER BY colA DESC
2427                                 |
2428     'colA'                      | ORDER BY colA
2429                                 |
2430     [qw/colA colB/]             | ORDER BY colA, colB
2431                                 |
2432     {-asc  => 'colA'}           | ORDER BY colA ASC
2433                                 |
2434     {-desc => 'colB'}           | ORDER BY colB DESC
2435                                 |
2436     ['colA', {-asc => 'colB'}]  | ORDER BY colA, colB ASC
2437                                 |
2438     { -asc => [qw/colA colB/] } | ORDER BY colA ASC, colB ASC
2439                                 |
2440     [                           |
2441       { -asc => 'colA' },       | ORDER BY colA ASC, colB DESC,
2442       { -desc => [qw/colB/],    |          colC ASC, colD ASC
2443       { -asc => [qw/colC colD/],|
2444     ]                           |
2445     ===========================================================
2446
2447
2448
2449 =head1 SPECIAL OPERATORS
2450
2451   my $sqlmaker = SQL::Abstract->new(special_ops => [
2452      {
2453       regex => qr/.../,
2454       handler => sub {
2455         my ($self, $field, $op, $arg) = @_;
2456         ...
2457       },
2458      },
2459      {
2460       regex => qr/.../,
2461       handler => 'method_name',
2462      },
2463    ]);
2464
2465 A "special operator" is a SQL syntactic clause that can be
2466 applied to a field, instead of a usual binary operator.
2467 For example :
2468
2469    WHERE field IN (?, ?, ?)
2470    WHERE field BETWEEN ? AND ?
2471    WHERE MATCH(field) AGAINST (?, ?)
2472
2473 Special operators IN and BETWEEN are fairly standard and therefore
2474 are builtin within C<SQL::Abstract> (as the overridable methods
2475 C<_where_field_IN> and C<_where_field_BETWEEN>). For other operators,
2476 like the MATCH .. AGAINST example above which is specific to MySQL,
2477 you can write your own operator handlers - supply a C<special_ops>
2478 argument to the C<new> method. That argument takes an arrayref of
2479 operator definitions; each operator definition is a hashref with two
2480 entries:
2481
2482 =over
2483
2484 =item regex
2485
2486 the regular expression to match the operator
2487
2488 =item handler
2489
2490 Either a coderef or a plain scalar method name. In both cases
2491 the expected return is C<< ($sql, @bind) >>.
2492
2493 When supplied with a method name, it is simply called on the
2494 L<SQL::Abstract/> object as:
2495
2496  $self->$method_name ($field, $op, $arg)
2497
2498  Where:
2499
2500   $op is the part that matched the handler regex
2501   $field is the LHS of the operator
2502   $arg is the RHS
2503
2504 When supplied with a coderef, it is called as:
2505
2506  $coderef->($self, $field, $op, $arg)
2507
2508
2509 =back
2510
2511 For example, here is an implementation
2512 of the MATCH .. AGAINST syntax for MySQL
2513
2514   my $sqlmaker = SQL::Abstract->new(special_ops => [
2515
2516     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2517     {regex => qr/^match$/i,
2518      handler => sub {
2519        my ($self, $field, $op, $arg) = @_;
2520        $arg = [$arg] if not ref $arg;
2521        my $label         = $self->_quote($field);
2522        my ($placeholder) = $self->_convert('?');
2523        my $placeholders  = join ", ", (($placeholder) x @$arg);
2524        my $sql           = $self->_sqlcase('match') . " ($label) "
2525                          . $self->_sqlcase('against') . " ($placeholders) ";
2526        my @bind = $self->_bindtype($field, @$arg);
2527        return ($sql, @bind);
2528        }
2529      },
2530
2531   ]);
2532
2533
2534 =head1 UNARY OPERATORS
2535
2536   my $sqlmaker = SQL::Abstract->new(unary_ops => [
2537      {
2538       regex => qr/.../,
2539       handler => sub {
2540         my ($self, $op, $arg) = @_;
2541         ...
2542       },
2543      },
2544      {
2545       regex => qr/.../,
2546       handler => 'method_name',
2547      },
2548    ]);
2549
2550 A "unary operator" is a SQL syntactic clause that can be
2551 applied to a field - the operator goes before the field
2552
2553 You can write your own operator handlers - supply a C<unary_ops>
2554 argument to the C<new> method. That argument takes an arrayref of
2555 operator definitions; each operator definition is a hashref with two
2556 entries:
2557
2558 =over
2559
2560 =item regex
2561
2562 the regular expression to match the operator
2563
2564 =item handler
2565
2566 Either a coderef or a plain scalar method name. In both cases
2567 the expected return is C<< $sql >>.
2568
2569 When supplied with a method name, it is simply called on the
2570 L<SQL::Abstract/> object as:
2571
2572  $self->$method_name ($op, $arg)
2573
2574  Where:
2575
2576   $op is the part that matched the handler regex
2577   $arg is the RHS or argument of the operator
2578
2579 When supplied with a coderef, it is called as:
2580
2581  $coderef->($self, $op, $arg)
2582
2583
2584 =back
2585
2586
2587 =head1 PERFORMANCE
2588
2589 Thanks to some benchmarking by Mark Stosberg, it turns out that
2590 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2591 I must admit this wasn't an intentional design issue, but it's a
2592 byproduct of the fact that you get to control your C<DBI> handles
2593 yourself.
2594
2595 To maximize performance, use a code snippet like the following:
2596
2597     # prepare a statement handle using the first row
2598     # and then reuse it for the rest of the rows
2599     my($sth, $stmt);
2600     for my $href (@array_of_hashrefs) {
2601         $stmt ||= $sql->insert('table', $href);
2602         $sth  ||= $dbh->prepare($stmt);
2603         $sth->execute($sql->values($href));
2604     }
2605
2606 The reason this works is because the keys in your C<$href> are sorted
2607 internally by B<SQL::Abstract>. Thus, as long as your data retains
2608 the same structure, you only have to generate the SQL the first time
2609 around. On subsequent queries, simply use the C<values> function provided
2610 by this module to return your values in the correct order.
2611
2612 However this depends on the values having the same type - if, for
2613 example, the values of a where clause may either have values
2614 (resulting in sql of the form C<column = ?> with a single bind
2615 value), or alternatively the values might be C<undef> (resulting in
2616 sql of the form C<column IS NULL> with no bind value) then the
2617 caching technique suggested will not work.
2618
2619 =head1 FORMBUILDER
2620
2621 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2622 really like this part (I do, at least). Building up a complex query
2623 can be as simple as the following:
2624
2625     #!/usr/bin/perl
2626
2627     use CGI::FormBuilder;
2628     use SQL::Abstract;
2629
2630     my $form = CGI::FormBuilder->new(...);
2631     my $sql  = SQL::Abstract->new;
2632
2633     if ($form->submitted) {
2634         my $field = $form->field;
2635         my $id = delete $field->{id};
2636         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2637     }
2638
2639 Of course, you would still have to connect using C<DBI> to run the
2640 query, but the point is that if you make your form look like your
2641 table, the actual query script can be extremely simplistic.
2642
2643 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2644 a fast interface to returning and formatting data. I frequently
2645 use these three modules together to write complex database query
2646 apps in under 50 lines.
2647
2648
2649 =head1 CHANGES
2650
2651 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2652 Great care has been taken to preserve the I<published> behavior
2653 documented in previous versions in the 1.* family; however,
2654 some features that were previously undocumented, or behaved
2655 differently from the documentation, had to be changed in order
2656 to clarify the semantics. Hence, client code that was relying
2657 on some dark areas of C<SQL::Abstract> v1.*
2658 B<might behave differently> in v1.50.
2659
2660 The main changes are :
2661
2662 =over
2663
2664 =item *
2665
2666 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2667
2668 =item *
2669
2670 support for the { operator => \"..." } construct (to embed literal SQL)
2671
2672 =item *
2673
2674 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2675
2676 =item *
2677
2678 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2679
2680 =item *
2681
2682 defensive programming : check arguments
2683
2684 =item *
2685
2686 fixed bug with global logic, which was previously implemented
2687 through global variables yielding side-effects. Prior versions would
2688 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2689 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2690 Now this is interpreted
2691 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2692
2693
2694 =item *
2695
2696 fixed semantics of  _bindtype on array args
2697
2698 =item *
2699
2700 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2701 we just avoid shifting arrays within that tree.
2702
2703 =item *
2704
2705 dropped the C<_modlogic> function
2706
2707 =back
2708
2709
2710
2711 =head1 ACKNOWLEDGEMENTS
2712
2713 There are a number of individuals that have really helped out with
2714 this module. Unfortunately, most of them submitted bugs via CPAN
2715 so I have no idea who they are! But the people I do know are:
2716
2717     Ash Berlin (order_by hash term support)
2718     Matt Trout (DBIx::Class support)
2719     Mark Stosberg (benchmarking)
2720     Chas Owens (initial "IN" operator support)
2721     Philip Collins (per-field SQL functions)
2722     Eric Kolve (hashref "AND" support)
2723     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2724     Dan Kubb (support for "quote_char" and "name_sep")
2725     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2726     Laurent Dami (internal refactoring, multiple -nest, extensible list of special operators, literal SQL)
2727     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2728     Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2729     Oliver Charles (support for "RETURNING" after "INSERT")
2730
2731 Thanks!
2732
2733 =head1 SEE ALSO
2734
2735 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2736
2737 =head1 AUTHOR
2738
2739 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2740
2741 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2742
2743 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2744 While not an official support venue, C<DBIx::Class> makes heavy use of
2745 C<SQL::Abstract>, and as such list members there are very familiar with
2746 how to create queries.
2747
2748 =head1 LICENSE
2749
2750 This module is free software; you may copy this under the same
2751 terms as perl itself (either the GNU General Public License or
2752 the Artistic License)
2753
2754 =cut
2755