lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use Carp;
   9 use strict;
  10 use warnings;
  11 use List::Util ();
  12 use Scalar::Util ();
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.63_01';
  19
  20 # This would confuse some packagers
  21 #$VERSION      = eval $VERSION; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^(not )?between$/i, handler => '_where_field_BETWEEN'},
  29   {regex => qr/^(not )?in$/i,      handler => '_where_field_IN'},
  30 );
  31
  32 # unaryish operators - key maps to handler
  33 my @BUILTIN_UNARY_OPS = (
  34   # the digits are backcompat stuff
  35   { regex => qr/^and  (?: \s? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  36   { regex => qr/^or   (?: \s? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  37   { regex => qr/^nest (?: \s? \d+ )? $/xi, handler => '_where_op_NEST' },
  38   { regex => qr/^ (?: not \s )? bool $/xi, handler => '_where_op_BOOL' },
  39 );
  40
  41 #======================================================================
  42 # DEBUGGING AND ERROR REPORTING
  43 #======================================================================
  44
  45 sub _debug {
  46   return unless $_[0]->{debug}; shift; # a little faster
  47   my $func = (caller(1))[3];
  48   warn "[$func] ", @_, "\n";
  49 }
  50
  51 sub belch (@) {
  52   my($func) = (caller(1))[3];
  53   carp "[$func] Warning: ", @_;
  54 }
  55
  56 sub puke (@) {
  57   my($func) = (caller(1))[3];
  58   croak "[$func] Fatal: ", @_;
  59 }
  60
  61
  62 #======================================================================
  63 # NEW
  64 #======================================================================
  65
  66 sub new {
  67   my $self = shift;
  68   my $class = ref($self) || $self;
  69   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  70
  71   # choose our case by keeping an option around
  72   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  73
  74   # default logic for interpreting arrayrefs
  75   $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
  76
  77   # how to return bind vars
  78   # LDNOTE: changed nwiger code : why this 'delete' ??
  79   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  80   $opt{bindtype} ||= 'normal';
  81
  82   # default comparison is "=", but can be overridden
  83   $opt{cmp} ||= '=';
  84
  85   # try to recognize which are the 'equality' and 'unequality' ops
  86   # (temporary quickfix, should go through a more seasoned API)
  87   $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  88   $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  89
  90   # SQL booleans
  91   $opt{sqltrue}  ||= '1=1';
  92   $opt{sqlfalse} ||= '0=1';
  93
  94   # special operators
  95   $opt{special_ops} ||= [];
  96   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
  97
  98   # unary operators
  99   $opt{unary_ops} ||= [];
 100   push @{$opt{unary_ops}}, @BUILTIN_UNARY_OPS;
 101
 102   return bless \%opt, $class;
 103 }
 104
 105
 106
 107 #======================================================================
 108 # INSERT methods
 109 #======================================================================
 110
 111 sub insert {
 112   my $self    = shift;
 113   my $table   = $self->_table(shift);
 114   my $data    = shift || return;
 115   my $options = shift;
 116
 117   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 118   my ($sql, @bind) = $self->$method($data);
 119   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 120
 121   if (my $ret = $options->{returning}) {
 122     $sql .= $self->_insert_returning ($ret);
 123   }
 124
 125   return wantarray ? ($sql, @bind) : $sql;
 126 }
 127
 128 sub _insert_returning {
 129   my ($self, $fields) = @_;
 130
 131   my $f = $self->_SWITCH_refkind($fields, {
 132     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$fields;},
 133     SCALAR       => sub {$self->_quote($fields)},
 134     SCALARREF    => sub {$$fields},
 135   });
 136   return join (' ', $self->_sqlcase(' returning'), $f);
 137 }
 138
 139 sub _insert_HASHREF { # explicit list of fields and then values
 140   my ($self, $data) = @_;
 141
 142   my @fields = sort keys %$data;
 143
 144   my ($sql, @bind) = $self->_insert_values($data);
 145
 146   # assemble SQL
 147   $_ = $self->_quote($_) foreach @fields;
 148   $sql = "( ".join(", ", @fields).") ".$sql;
 149
 150   return ($sql, @bind);
 151 }
 152
 153 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 154   my ($self, $data) = @_;
 155
 156   # no names (arrayref) so can't generate bindtype
 157   $self->{bindtype} ne 'columns'
 158     or belch "can't do 'columns' bindtype when called with arrayref";
 159
 160   # fold the list of values into a hash of column name - value pairs
 161   # (where the column names are artificially generated, and their
 162   # lexicographical ordering keep the ordering of the original list)
 163   my $i = "a";  # incremented values will be in lexicographical order
 164   my $data_in_hash = { map { ($i++ => $_) } @$data };
 165
 166   return $self->_insert_values($data_in_hash);
 167 }
 168
 169 sub _insert_ARRAYREFREF { # literal SQL with bind
 170   my ($self, $data) = @_;
 171
 172   my ($sql, @bind) = @${$data};
 173   $self->_assert_bindval_matches_bindtype(@bind);
 174
 175   return ($sql, @bind);
 176 }
 177
 178
 179 sub _insert_SCALARREF { # literal SQL without bind
 180   my ($self, $data) = @_;
 181
 182   return ($$data);
 183 }
 184
 185 sub _insert_values {
 186   my ($self, $data) = @_;
 187
 188   my (@values, @all_bind);
 189   foreach my $column (sort keys %$data) {
 190     my $v = $data->{$column};
 191
 192     $self->_SWITCH_refkind($v, {
 193
 194       ARRAYREF => sub {
 195         if ($self->{array_datatypes}) { # if array datatype are activated
 196           push @values, '?';
 197           push @all_bind, $self->_bindtype($column, $v);
 198         }
 199         else {                          # else literal SQL with bind
 200           my ($sql, @bind) = @$v;
 201           $self->_assert_bindval_matches_bindtype(@bind);
 202           push @values, $sql;
 203           push @all_bind, @bind;
 204         }
 205       },
 206
 207       ARRAYREFREF => sub { # literal SQL with bind
 208         my ($sql, @bind) = @${$v};
 209         $self->_assert_bindval_matches_bindtype(@bind);
 210         push @values, $sql;
 211         push @all_bind, @bind;
 212       },
 213
 214       # THINK : anything useful to do with a HASHREF ?
 215       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 216         #TODO in SQLA >= 2.0 it will die instead
 217         belch "HASH ref as bind value in insert is not supported";
 218         push @values, '?';
 219         push @all_bind, $self->_bindtype($column, $v);
 220       },
 221
 222       SCALARREF => sub {  # literal SQL without bind
 223         push @values, $$v;
 224       },
 225
 226       SCALAR_or_UNDEF => sub {
 227         push @values, '?';
 228         push @all_bind, $self->_bindtype($column, $v);
 229       },
 230
 231      });
 232
 233   }
 234
 235   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 236   return ($sql, @all_bind);
 237 }
 238
 239
 240
 241 #======================================================================
 242 # UPDATE methods
 243 #======================================================================
 244
 245
 246 sub update {
 247   my $self  = shift;
 248   my $table = $self->_table(shift);
 249   my $data  = shift || return;
 250   my $where = shift;
 251
 252   # first build the 'SET' part of the sql statement
 253   my (@set, @all_bind);
 254   puke "Unsupported data type specified to \$sql->update"
 255     unless ref $data eq 'HASH';
 256
 257   for my $k (sort keys %$data) {
 258     my $v = $data->{$k};
 259     my $r = ref $v;
 260     my $label = $self->_quote($k);
 261
 262     $self->_SWITCH_refkind($v, {
 263       ARRAYREF => sub {
 264         if ($self->{array_datatypes}) { # array datatype
 265           push @set, "$label = ?";
 266           push @all_bind, $self->_bindtype($k, $v);
 267         }
 268         else {                          # literal SQL with bind
 269           my ($sql, @bind) = @$v;
 270           $self->_assert_bindval_matches_bindtype(@bind);
 271           push @set, "$label = $sql";
 272           push @all_bind, @bind;
 273         }
 274       },
 275       ARRAYREFREF => sub { # literal SQL with bind
 276         my ($sql, @bind) = @${$v};
 277         $self->_assert_bindval_matches_bindtype(@bind);
 278         push @set, "$label = $sql";
 279         push @all_bind, @bind;
 280       },
 281       SCALARREF => sub {  # literal SQL without bind
 282         push @set, "$label = $$v";
 283        },
 284       SCALAR_or_UNDEF => sub {
 285         push @set, "$label = ?";
 286         push @all_bind, $self->_bindtype($k, $v);
 287       },
 288     });
 289   }
 290
 291   # generate sql
 292   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 293           . join ', ', @set;
 294
 295   if ($where) {
 296     my($where_sql, @where_bind) = $self->where($where);
 297     $sql .= $where_sql;
 298     push @all_bind, @where_bind;
 299   }
 300
 301   return wantarray ? ($sql, @all_bind) : $sql;
 302 }
 303
 304
 305
 306
 307 #======================================================================
 308 # SELECT
 309 #======================================================================
 310
 311
 312 sub select {
 313   my $self   = shift;
 314   my $table  = $self->_table(shift);
 315   my $fields = shift || '*';
 316   my $where  = shift;
 317   my $order  = shift;
 318
 319   my($where_sql, @bind) = $self->where($where, $order);
 320
 321   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 322                                    : $fields;
 323   my $sql = join(' ', $self->_sqlcase('select'), $f,
 324                       $self->_sqlcase('from'),   $table)
 325           . $where_sql;
 326
 327   return wantarray ? ($sql, @bind) : $sql;
 328 }
 329
 330 #======================================================================
 331 # DELETE
 332 #======================================================================
 333
 334
 335 sub delete {
 336   my $self  = shift;
 337   my $table = $self->_table(shift);
 338   my $where = shift;
 339
 340
 341   my($where_sql, @bind) = $self->where($where);
 342   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 343
 344   return wantarray ? ($sql, @bind) : $sql;
 345 }
 346
 347
 348 #======================================================================
 349 # WHERE: entry point
 350 #======================================================================
 351
 352
 353
 354 # Finally, a separate routine just to handle WHERE clauses
 355 sub where {
 356   my ($self, $where, $order) = @_;
 357
 358   # where ?
 359   my ($sql, @bind) = $self->_recurse_where($where);
 360   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 361
 362   # order by?
 363   if ($order) {
 364     $sql .= $self->_order_by($order);
 365   }
 366
 367   return wantarray ? ($sql, @bind) : $sql;
 368 }
 369
 370
 371 sub _recurse_where {
 372   my ($self, $where, $logic) = @_;
 373
 374   # dispatch on appropriate method according to refkind of $where
 375   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 376
 377   my ($sql, @bind) =  $self->$method($where, $logic);
 378
 379   # DBIx::Class directly calls _recurse_where in scalar context, so
 380   # we must implement it, even if not in the official API
 381   return wantarray ? ($sql, @bind) : $sql;
 382 }
 383
 384
 385
 386 #======================================================================
 387 # WHERE: top-level ARRAYREF
 388 #======================================================================
 389
 390
 391 sub _where_ARRAYREF {
 392   my ($self, $where, $logic) = @_;
 393
 394   $logic = uc($logic || $self->{logic});
 395   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 396
 397   my @clauses = @$where;
 398
 399   my (@sql_clauses, @all_bind);
 400   # need to use while() so can shift() for pairs
 401   while (my $el = shift @clauses) {
 402
 403     # switch according to kind of $el and get corresponding ($sql, @bind)
 404     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 405
 406       # skip empty elements, otherwise get invalid trailing AND stuff
 407       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 408
 409       ARRAYREFREF => sub { @{${$el}}                 if @{${$el}}},
 410
 411       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 412            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 413            # side-effect: the first hashref within an array would change
 414            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 415            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 416            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 417
 418       SCALARREF => sub { ($$el);                                 },
 419
 420       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 421                         $self->_recurse_where({$el => shift(@clauses)})},
 422
 423       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 424     });
 425
 426     if ($sql) {
 427       push @sql_clauses, $sql;
 428       push @all_bind, @bind;
 429     }
 430   }
 431
 432   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 433 }
 434
 435 #======================================================================
 436 # WHERE: top-level ARRAYREFREF
 437 #======================================================================
 438
 439 sub _where_ARRAYREFREF {
 440     my ($self, $where) = @_;
 441     my ($sql, @bind) = @{${$where}};
 442
 443     return ($sql, @bind);
 444 }
 445
 446 #======================================================================
 447 # WHERE: top-level HASHREF
 448 #======================================================================
 449
 450 sub _where_HASHREF {
 451   my ($self, $where) = @_;
 452   my (@sql_clauses, @all_bind);
 453
 454   for my $k (sort keys %$where) {
 455     my $v = $where->{$k};
 456
 457     # ($k => $v) is either a special unary op or a regular hashpair
 458     my ($sql, @bind) = do {
 459       if ($k =~ /^-./) {
 460         # put the operator in canonical form
 461         my $op = $k;
 462         $op =~ s/^-//;        # remove initial dash
 463         $op =~ s/[_\t ]+/ /g; # underscores and whitespace become single spaces
 464         $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 465
 466         $self->_debug("Unary OP(-$op) within hashref, recursing...");
 467
 468         my $op_entry = List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}};
 469         if (my $handler = $op_entry->{handler}) {
 470           if (not ref $handler) {
 471             if ($op =~ s/\s?\d+$//) {
 472               belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
 473                   . "You probably wanted ...-and => [ -$op => COND1, -$op => COND2 ... ]";
 474               }
 475             $self->$handler ($op, $v);
 476           }
 477           elsif (ref $handler eq 'CODE') {
 478             $handler->($self, $op, $v);
 479           }
 480           else {
 481             puke "Illegal handler for operator $k - expecting a method name or a coderef";
 482           }
 483         }
 484         else {
 485           $self->debug("Generic unary OP: $k - recursing as function");
 486           my ($sql, @bind) = $self->_where_func_generic ($op, $v);
 487           $sql = "($sql)" unless $self->{_nested_func_lhs} eq $k;  # top level vs nested
 488           ($sql, @bind);
 489         }
 490       }
 491       else {
 492         my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 493         $self->$method($k, $v);
 494       }
 495     };
 496
 497     push @sql_clauses, $sql;
 498     push @all_bind, @bind;
 499   }
 500
 501   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 502 }
 503
 504 sub _where_func_generic {
 505   my ($self, $op, $rhs) = @_;
 506
 507   my ($sql, @bind) = $self->_SWITCH_refkind ($rhs, {
 508     SCALAR =>   sub {
 509       puke "Illegal use of top-level '$op'"
 510         unless $self->{_nested_func_lhs};
 511
 512       return (
 513         $self->_convert('?'),
 514         $self->_bindtype($self->{_nested_func_lhs}, $rhs)
 515       );
 516     },
 517     FALLBACK => sub {
 518       $self->_recurse_where ($rhs)
 519     },
 520   });
 521
 522   $sql = sprintf ('%s %s',
 523     $self->_sqlcase($op),
 524     $sql,
 525   );
 526
 527   return ($sql, @bind);
 528 }
 529
 530 sub _where_op_ANDOR {
 531   my ($self, $op, $v) = @_;
 532
 533   $self->_SWITCH_refkind($v, {
 534     ARRAYREF => sub {
 535       return $self->_where_ARRAYREF($v, $op);
 536     },
 537
 538     HASHREF => sub {
 539       return ( $op =~ /^or/i )
 540         ? $self->_where_ARRAYREF( [ map { $_ => $v->{$_} } ( sort keys %$v ) ], $op )
 541         : $self->_where_HASHREF($v);
 542     },
 543
 544     SCALARREF  => sub {
 545       puke "-$op => \\\$scalar not supported, use -nest => ...";
 546     },
 547
 548     ARRAYREFREF => sub {
 549       puke "-$op => \\[..] not supported, use -nest => ...";
 550     },
 551
 552     SCALAR => sub { # permissively interpreted as SQL
 553       puke "-$op => 'scalar' not supported, use -nest => \\'scalar'";
 554     },
 555
 556     UNDEF => sub {
 557       puke "-$op => undef not supported";
 558     },
 559    });
 560 }
 561
 562 sub _where_op_NEST {
 563   my ($self, $op, $v) = @_;
 564
 565   $self->_SWITCH_refkind($v, {
 566
 567     SCALAR => sub { # permissively interpreted as SQL
 568       belch "literal SQL should be -nest => \\'scalar' "
 569           . "instead of -nest => 'scalar' ";
 570       return ($v);
 571     },
 572
 573     UNDEF => sub {
 574       puke "-$op => undef not supported";
 575     },
 576
 577     FALLBACK => sub {
 578       $self->_recurse_where ($v);
 579     },
 580
 581    });
 582 }
 583
 584
 585 sub _where_op_BOOL {
 586   my ($self, $op, $v) = @_;
 587
 588   my ( $prefix, $suffix ) = ( $op =~ /\bnot\b/i )
 589     ? ( '(NOT ', ')' )
 590     : ( '', '' );
 591
 592   my ($sql, @bind) = do {
 593     $self->_SWITCH_refkind($v, {
 594       SCALAR => sub { # interpreted as SQL column
 595         $self->_convert($self->_quote($v));
 596       },
 597
 598       UNDEF => sub {
 599         puke "-$op => undef not supported";
 600       },
 601
 602       FALLBACK => sub {
 603         $self->_recurse_where ($v);
 604       },
 605     });
 606   };
 607
 608   return (
 609     join ('', $prefix, $sql, $suffix),
 610     @bind,
 611   );
 612 }
 613
 614
 615 sub _where_hashpair_ARRAYREF {
 616   my ($self, $k, $v) = @_;
 617
 618   if( @$v ) {
 619     my @v = @$v; # need copy because of shift below
 620     $self->_debug("ARRAY($k) means distribute over elements");
 621
 622     # put apart first element if it is an operator (-and, -or)
 623     my $op = (
 624        (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
 625          ? shift @v
 626          : ''
 627     );
 628     my @distributed = map { {$k =>  $_} } @v;
 629
 630     if ($op) {
 631       $self->_debug("OP($op) reinjected into the distributed array");
 632       unshift @distributed, $op;
 633     }
 634
 635     my $logic = $op ? substr($op, 1) : '';
 636
 637     return $self->_recurse_where(\@distributed, $logic);
 638   }
 639   else {
 640     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 641     $self->_debug("empty ARRAY($k) means 0=1");
 642     return ($self->{sqlfalse});
 643   }
 644 }
 645
 646 sub _where_hashpair_HASHREF {
 647   my ($self, $k, $v, $logic) = @_;
 648   $logic ||= 'and';
 649
 650   local $self->{_nested_func_lhs} = $self->{_nested_func_lhs};
 651
 652   my ($all_sql, @all_bind);
 653
 654   for my $orig_op (sort keys %$v) {
 655     my $val = $v->{$orig_op};
 656
 657     # put the operator in canonical form
 658     my $op = $orig_op;
 659     $op =~ s/^-//;        # remove initial dash
 660     $op =~ s/[_\t ]+/ /g; # underscores and whitespace become single spaces
 661     $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 662
 663     my ($sql, @bind);
 664
 665     # CASE: col-value logic modifiers
 666     if ( $orig_op =~ /^ \- (and|or) $/xi ) {
 667       ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $1);
 668     }
 669     # CASE: special operators like -in or -between
 670     elsif ( my $special_op = List::Util::first {$op =~ $_->{regex}} @{$self->{special_ops}} ) {
 671       my $handler = $special_op->{handler};
 672       if (! $handler) {
 673         puke "No handler supplied for special operator $orig_op";
 674       }
 675       elsif (not ref $handler) {
 676         ($sql, @bind) = $self->$handler ($k, $op, $val);
 677       }
 678       elsif (ref $handler eq 'CODE') {
 679         ($sql, @bind) = $handler->($self, $k, $op, $val);
 680       }
 681       else {
 682         puke "Illegal handler for special operator $orig_op - expecting a method name or a coderef";
 683       }
 684     }
 685     else {
 686       $self->_SWITCH_refkind($val, {
 687
 688         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 689           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 690         },
 691
 692         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 693           my ($sub_sql, @sub_bind) = @$$val;
 694           $self->_assert_bindval_matches_bindtype(@sub_bind);
 695           $sql  = join ' ', $self->_convert($self->_quote($k)),
 696                             $self->_sqlcase($op),
 697                             $sub_sql;
 698           @bind = @sub_bind;
 699         },
 700
 701         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 702           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 703                    ($op =~ $self->{inequality_op}) ? 'is not' :
 704                puke "unexpected operator '$orig_op' with undef operand";
 705           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 706         },
 707
 708         FALLBACK => sub {       # CASE: col => {op/func => $stuff}
 709
 710           # retain for proper column type bind
 711           $self->{_nested_func_lhs} ||= $k;
 712
 713           ($sql, @bind) = $self->_where_func_generic ($op, $val);
 714
 715           $sql = join (' ',
 716             $self->_convert($self->_quote($k)),
 717             $self->{_nested_func_lhs} eq $k ? $sql : "($sql)",  # top level vs nested
 718           );
 719         },
 720       });
 721     }
 722
 723     ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
 724     push @all_bind, @bind;
 725   }
 726   return ($all_sql, @all_bind);
 727 }
 728
 729
 730
 731 sub _where_field_op_ARRAYREF {
 732   my ($self, $k, $op, $vals) = @_;
 733
 734   my @vals = @$vals;  #always work on a copy
 735
 736   if(@vals) {
 737     $self->_debug(sprintf '%s means multiple elements: [ %s ]',
 738       $vals,
 739       join (', ', map { defined $_ ? "'$_'" : 'NULL' } @vals ),
 740     );
 741
 742     # see if the first element is an -and/-or op
 743     my $logic;
 744     if (defined $vals[0] && $vals[0] =~ /^ - ( AND|OR ) $/ix) {
 745       $logic = uc $1;
 746       shift @vals;
 747     }
 748
 749     # distribute $op over each remaining member of @vals, append logic if exists
 750     return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 751
 752     # LDNOTE : had planned to change the distribution logic when
 753     # $op =~ $self->{inequality_op}, because of Morgan laws :
 754     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 755     # WHERE field != 22 OR  field != 33 : the user probably means
 756     # WHERE field != 22 AND field != 33.
 757     # To do this, replace the above to roughly :
 758     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 759     # return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 760
 761   }
 762   else {
 763     # try to DWIM on equality operators
 764     # LDNOTE : not 100% sure this is the correct thing to do ...
 765     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 766     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 767
 768     # otherwise
 769     puke "operator '$op' applied on an empty array (field '$k')";
 770   }
 771 }
 772
 773
 774 sub _where_hashpair_SCALARREF {
 775   my ($self, $k, $v) = @_;
 776   $self->_debug("SCALAR($k) means literal SQL: $$v");
 777   my $sql = $self->_quote($k) . " " . $$v;
 778   return ($sql);
 779 }
 780
 781 # literal SQL with bind
 782 sub _where_hashpair_ARRAYREFREF {
 783   my ($self, $k, $v) = @_;
 784   $self->_debug("REF($k) means literal SQL: @${$v}");
 785   my ($sql, @bind) = @${$v};
 786   $self->_assert_bindval_matches_bindtype(@bind);
 787   $sql  = $self->_quote($k) . " " . $sql;
 788   return ($sql, @bind );
 789 }
 790
 791 # literal SQL without bind
 792 sub _where_hashpair_SCALAR {
 793   my ($self, $k, $v) = @_;
 794   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 795   my $sql = join ' ', $self->_convert($self->_quote($k)),
 796                       $self->_sqlcase($self->{cmp}),
 797                       $self->_convert('?');
 798   my @bind =  $self->_bindtype($k, $v);
 799   return ( $sql, @bind);
 800 }
 801
 802
 803 sub _where_hashpair_UNDEF {
 804   my ($self, $k, $v) = @_;
 805   $self->_debug("UNDEF($k) means IS NULL");
 806   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 807   return ($sql);
 808 }
 809
 810 #======================================================================
 811 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 812 #======================================================================
 813
 814
 815 sub _where_SCALARREF {
 816   my ($self, $where) = @_;
 817
 818   # literal sql
 819   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 820   return ($$where);
 821 }
 822
 823
 824 sub _where_SCALAR {
 825   my ($self, $where) = @_;
 826
 827   # literal sql
 828   $self->_debug("NOREF(*top) means literal SQL: $where");
 829   return ($where);
 830 }
 831
 832
 833 sub _where_UNDEF {
 834   my ($self) = @_;
 835   return ();
 836 }
 837
 838
 839 #======================================================================
 840 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 841 #======================================================================
 842
 843
 844 sub _where_field_BETWEEN {
 845   my ($self, $k, $op, $vals) = @_;
 846
 847   my ($label, $and, $placeholder);
 848   $label       = $self->_convert($self->_quote($k));
 849   $and         = ' ' . $self->_sqlcase('and') . ' ';
 850   $placeholder = $self->_convert('?');
 851   $op               = $self->_sqlcase($op);
 852
 853   my ($clause, @bind) = $self->_SWITCH_refkind($vals, {
 854     ARRAYREFREF => sub {
 855       return @$$vals;
 856     },
 857     SCALARREF => sub {
 858       return $$vals;
 859     },
 860     ARRAYREF => sub {
 861       puke "special op 'between' accepts an arrayref with exactly two values"
 862         if @$vals != 2;
 863
 864       my (@all_sql, @all_bind);
 865       foreach my $val (@$vals) {
 866         my ($sql, @bind) = $self->_SWITCH_refkind($val, {
 867            SCALAR => sub {
 868              return ($placeholder, ($val));
 869            },
 870            SCALARREF => sub {
 871              return ($self->_convert($$val), ());
 872            },
 873            ARRAYREFREF => sub {
 874              my ($sql, @bind) = @$$val;
 875              return ($self->_convert($sql), @bind);
 876            },
 877         });
 878         push @all_sql, $sql;
 879         push @all_bind, @bind;
 880       }
 881
 882       return (
 883         (join $and, @all_sql),
 884         $self->_bindtype($k, @all_bind),
 885       );
 886     },
 887     FALLBACK => sub {
 888       puke "special op 'between' accepts an arrayref with two values, or a single literal scalarref/arrayref-ref";
 889     },
 890   });
 891
 892   my $sql = "( $label $op $clause )";
 893   return ($sql, @bind)
 894 }
 895
 896
 897 sub _where_field_IN {
 898   my ($self, $k, $op, $vals) = @_;
 899
 900   # backwards compatibility : if scalar, force into an arrayref
 901   $vals = [$vals] if defined $vals && ! ref $vals;
 902
 903   my ($label)       = $self->_convert($self->_quote($k));
 904   my ($placeholder) = $self->_convert('?');
 905   $op               = $self->_sqlcase($op);
 906
 907   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
 908     ARRAYREF => sub {     # list of choices
 909       if (@$vals) { # nonempty list
 910         my $placeholders  = join ", ", (($placeholder) x @$vals);
 911         my $sql           = "$label $op ( $placeholders )";
 912         my @bind = $self->_bindtype($k, @$vals);
 913
 914         return ($sql, @bind);
 915       }
 916       else { # empty list : some databases won't understand "IN ()", so DWIM
 917         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
 918         return ($sql);
 919       }
 920     },
 921
 922     SCALARREF => sub {  # literal SQL
 923       my $sql = $self->_open_outer_paren ($$vals);
 924       return ("$label $op ( $sql )");
 925     },
 926     ARRAYREFREF => sub {  # literal SQL with bind
 927       my ($sql, @bind) = @$$vals;
 928       $self->_assert_bindval_matches_bindtype(@bind);
 929       $sql = $self->_open_outer_paren ($sql);
 930       return ("$label $op ( $sql )", @bind);
 931     },
 932
 933     FALLBACK => sub {
 934       puke "special op 'in' requires an arrayref (or scalarref/arrayref-ref)";
 935     },
 936   });
 937
 938   return ($sql, @bind);
 939 }
 940
 941 # Some databases (SQLite) treat col IN (1, 2) different from
 942 # col IN ( (1, 2) ). Use this to strip all outer parens while
 943 # adding them back in the corresponding method
 944 sub _open_outer_paren {
 945   my ($self, $sql) = @_;
 946   $sql = $1 while $sql =~ /^ \s* \( (.*) \) \s* $/xs;
 947   return $sql;
 948 }
 949
 950
 951 #======================================================================
 952 # ORDER BY
 953 #======================================================================
 954
 955 sub _order_by {
 956   my ($self, $arg) = @_;
 957
 958   my (@sql, @bind);
 959   for my $c ($self->_order_by_chunks ($arg) ) {
 960     $self->_SWITCH_refkind ($c, {
 961       SCALAR => sub { push @sql, $c },
 962       ARRAYREF => sub { push @sql, shift @$c; push @bind, @$c },
 963     });
 964   }
 965
 966   my $sql = @sql
 967     ? sprintf ('%s %s',
 968         $self->_sqlcase(' order by'),
 969         join (', ', @sql)
 970       )
 971     : ''
 972   ;
 973
 974   return wantarray ? ($sql, @bind) : $sql;
 975 }
 976
 977 sub _order_by_chunks {
 978   my ($self, $arg) = @_;
 979
 980   return $self->_SWITCH_refkind($arg, {
 981
 982     ARRAYREF => sub {
 983       map { $self->_order_by_chunks ($_ ) } @$arg;
 984     },
 985
 986     ARRAYREFREF => sub { [ @$$arg ] },
 987
 988     SCALAR    => sub {$self->_quote($arg)},
 989
 990     UNDEF     => sub {return () },
 991
 992     SCALARREF => sub {$$arg}, # literal SQL, no quoting
 993
 994     HASHREF   => sub {
 995       # get first pair in hash
 996       my ($key, $val) = each %$arg;
 997
 998       return () unless $key;
 999
1000       if ( (keys %$arg) > 1 or not $key =~ /^-(desc|asc)/i ) {
1001         puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
1002       }
1003
1004       my $direction = $1;
1005
1006       my @ret;
1007       for my $c ($self->_order_by_chunks ($val)) {
1008         my ($sql, @bind);
1009
1010         $self->_SWITCH_refkind ($c, {
1011           SCALAR => sub {
1012             $sql = $c;
1013           },
1014           ARRAYREF => sub {
1015             ($sql, @bind) = @$c;
1016           },
1017         });
1018
1019         $sql = $sql . ' ' . $self->_sqlcase($direction);
1020
1021         push @ret, [ $sql, @bind];
1022       }
1023
1024       return @ret;
1025     },
1026   });
1027 }
1028
1029
1030 #======================================================================
1031 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
1032 #======================================================================
1033
1034 sub _table  {
1035   my $self = shift;
1036   my $from = shift;
1037   $self->_SWITCH_refkind($from, {
1038     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
1039     SCALAR       => sub {$self->_quote($from)},
1040     SCALARREF    => sub {$$from},
1041     ARRAYREFREF  => sub {join ', ', @$from;},
1042   });
1043 }
1044
1045
1046 #======================================================================
1047 # UTILITY FUNCTIONS
1048 #======================================================================
1049
1050 sub _quote {
1051   my $self  = shift;
1052   my $label = shift;
1053
1054   $label or puke "can't quote an empty label";
1055
1056   # left and right quote characters
1057   my ($ql, $qr, @other) = $self->_SWITCH_refkind($self->{quote_char}, {
1058     SCALAR   => sub {($self->{quote_char}, $self->{quote_char})},
1059     ARRAYREF => sub {@{$self->{quote_char}}},
1060     UNDEF    => sub {()},
1061    });
1062   not @other
1063       or puke "quote_char must be an arrayref of 2 values";
1064
1065   # no quoting if no quoting chars
1066   $ql or return $label;
1067
1068   # no quoting for literal SQL
1069   return $$label if ref($label) eq 'SCALAR';
1070
1071   # separate table / column (if applicable)
1072   my $sep = $self->{name_sep} || '';
1073   my @to_quote = $sep ? split /\Q$sep\E/, $label : ($label);
1074
1075   # do the quoting, except for "*" or for `table`.*
1076   my @quoted = map { $_ eq '*' ? $_: $ql.$_.$qr} @to_quote;
1077
1078   # reassemble and return.
1079   return join $sep, @quoted;
1080 }
1081
1082
1083 # Conversion, if applicable
1084 sub _convert ($) {
1085   my ($self, $arg) = @_;
1086
1087 # LDNOTE : modified the previous implementation below because
1088 # it was not consistent : the first "return" is always an array,
1089 # the second "return" is context-dependent. Anyway, _convert
1090 # seems always used with just a single argument, so make it a
1091 # scalar function.
1092 #     return @_ unless $self->{convert};
1093 #     my $conv = $self->_sqlcase($self->{convert});
1094 #     my @ret = map { $conv.'('.$_.')' } @_;
1095 #     return wantarray ? @ret : $ret[0];
1096   if ($self->{convert}) {
1097     my $conv = $self->_sqlcase($self->{convert});
1098     $arg = $conv.'('.$arg.')';
1099   }
1100   return $arg;
1101 }
1102
1103 # And bindtype
1104 sub _bindtype (@) {
1105   my $self = shift;
1106   my($col, @vals) = @_;
1107
1108   #LDNOTE : changed original implementation below because it did not make
1109   # sense when bindtype eq 'columns' and @vals > 1.
1110 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
1111
1112   return $self->{bindtype} eq 'columns' ? map {[$col, $_]} @vals : @vals;
1113 }
1114
1115 # Dies if any element of @bind is not in [colname => value] format
1116 # if bindtype is 'columns'.
1117 sub _assert_bindval_matches_bindtype {
1118   my ($self, @bind) = @_;
1119
1120   if ($self->{bindtype} eq 'columns') {
1121     foreach my $val (@bind) {
1122       if (!defined $val || ref($val) ne 'ARRAY' || @$val != 2) {
1123         die "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
1124       }
1125     }
1126   }
1127 }
1128
1129 sub _join_sql_clauses {
1130   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
1131
1132   if (@$clauses_aref > 1) {
1133     my $join  = " " . $self->_sqlcase($logic) . " ";
1134     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
1135     return ($sql, @$bind_aref);
1136   }
1137   elsif (@$clauses_aref) {
1138     return ($clauses_aref->[0], @$bind_aref); # no parentheses
1139   }
1140   else {
1141     return (); # if no SQL, ignore @$bind_aref
1142   }
1143 }
1144
1145
1146 # Fix SQL case, if so requested
1147 sub _sqlcase {
1148   my $self = shift;
1149
1150   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
1151   # don't touch the argument ... crooked logic, but let's not change it!
1152   return $self->{case} ? $_[0] : uc($_[0]);
1153 }
1154
1155
1156 #======================================================================
1157 # DISPATCHING FROM REFKIND
1158 #======================================================================
1159
1160 sub _refkind {
1161   my ($self, $data) = @_;
1162   my $suffix = '';
1163   my $ref;
1164   my $n_steps = 0;
1165
1166   while (1) {
1167     # blessed objects are treated like scalars
1168     $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1169     $n_steps += 1 if $ref;
1170     last          if $ref ne 'REF';
1171     $data = $$data;
1172   }
1173
1174   my $base = $ref || (defined $data ? 'SCALAR' : 'UNDEF');
1175
1176   return $base . ('REF' x $n_steps);
1177 }
1178
1179
1180
1181 sub _try_refkind {
1182   my ($self, $data) = @_;
1183   my @try = ($self->_refkind($data));
1184   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1185   push @try, 'FALLBACK';
1186   return @try;
1187 }
1188
1189 sub _METHOD_FOR_refkind {
1190   my ($self, $meth_prefix, $data) = @_;
1191
1192   my $method;
1193   for ($self->_try_refkind($data)) {
1194     $method = $self->can($meth_prefix."_".$_)
1195       and last;
1196   }
1197
1198   return $method || puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1199 }
1200
1201
1202 sub _SWITCH_refkind {
1203   my ($self, $data, $dispatch_table) = @_;
1204
1205   my $coderef;
1206   for ($self->_try_refkind($data)) {
1207     $coderef = $dispatch_table->{$_}
1208       and last;
1209   }
1210
1211   puke "no dispatch entry for ".$self->_refkind($data)
1212     unless $coderef;
1213
1214   $coderef->();
1215 }
1216
1217
1218
1219
1220 #======================================================================
1221 # VALUES, GENERATE, AUTOLOAD
1222 #======================================================================
1223
1224 # LDNOTE: original code from nwiger, didn't touch code in that section
1225 # I feel the AUTOLOAD stuff should not be the default, it should
1226 # only be activated on explicit demand by user.
1227
1228 sub values {
1229     my $self = shift;
1230     my $data = shift || return;
1231     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1232         unless ref $data eq 'HASH';
1233
1234     my @all_bind;
1235     foreach my $k ( sort keys %$data ) {
1236         my $v = $data->{$k};
1237         $self->_SWITCH_refkind($v, {
1238           ARRAYREF => sub {
1239             if ($self->{array_datatypes}) { # array datatype
1240               push @all_bind, $self->_bindtype($k, $v);
1241             }
1242             else {                          # literal SQL with bind
1243               my ($sql, @bind) = @$v;
1244               $self->_assert_bindval_matches_bindtype(@bind);
1245               push @all_bind, @bind;
1246             }
1247           },
1248           ARRAYREFREF => sub { # literal SQL with bind
1249             my ($sql, @bind) = @${$v};
1250             $self->_assert_bindval_matches_bindtype(@bind);
1251             push @all_bind, @bind;
1252           },
1253           SCALARREF => sub {  # literal SQL without bind
1254           },
1255           SCALAR_or_UNDEF => sub {
1256             push @all_bind, $self->_bindtype($k, $v);
1257           },
1258         });
1259     }
1260
1261     return @all_bind;
1262 }
1263
1264 sub generate {
1265     my $self  = shift;
1266
1267     my(@sql, @sqlq, @sqlv);
1268
1269     for (@_) {
1270         my $ref = ref $_;
1271         if ($ref eq 'HASH') {
1272             for my $k (sort keys %$_) {
1273                 my $v = $_->{$k};
1274                 my $r = ref $v;
1275                 my $label = $self->_quote($k);
1276                 if ($r eq 'ARRAY') {
1277                     # literal SQL with bind
1278                     my ($sql, @bind) = @$v;
1279                     $self->_assert_bindval_matches_bindtype(@bind);
1280                     push @sqlq, "$label = $sql";
1281                     push @sqlv, @bind;
1282                 } elsif ($r eq 'SCALAR') {
1283                     # literal SQL without bind
1284                     push @sqlq, "$label = $$v";
1285                 } else {
1286                     push @sqlq, "$label = ?";
1287                     push @sqlv, $self->_bindtype($k, $v);
1288                 }
1289             }
1290             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1291         } elsif ($ref eq 'ARRAY') {
1292             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1293             for my $v (@$_) {
1294                 my $r = ref $v;
1295                 if ($r eq 'ARRAY') {   # literal SQL with bind
1296                     my ($sql, @bind) = @$v;
1297                     $self->_assert_bindval_matches_bindtype(@bind);
1298                     push @sqlq, $sql;
1299                     push @sqlv, @bind;
1300                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1301                     # embedded literal SQL
1302                     push @sqlq, $$v;
1303                 } else {
1304                     push @sqlq, '?';
1305                     push @sqlv, $v;
1306                 }
1307             }
1308             push @sql, '(' . join(', ', @sqlq) . ')';
1309         } elsif ($ref eq 'SCALAR') {
1310             # literal SQL
1311             push @sql, $$_;
1312         } else {
1313             # strings get case twiddled
1314             push @sql, $self->_sqlcase($_);
1315         }
1316     }
1317
1318     my $sql = join ' ', @sql;
1319
1320     # this is pretty tricky
1321     # if ask for an array, return ($stmt, @bind)
1322     # otherwise, s/?/shift @sqlv/ to put it inline
1323     if (wantarray) {
1324         return ($sql, @sqlv);
1325     } else {
1326         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1327                              ref $d ? $d->[1] : $d/e;
1328         return $sql;
1329     }
1330 }
1331
1332
1333 sub DESTROY { 1 }
1334
1335 sub AUTOLOAD {
1336     # This allows us to check for a local, then _form, attr
1337     my $self = shift;
1338     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1339     return $self->generate($name, @_);
1340 }
1341
1342 1;
1343
1344
1345
1346 __END__
1347
1348 =head1 NAME
1349
1350 SQL::Abstract - Generate SQL from Perl data structures
1351
1352 =head1 SYNOPSIS
1353
1354     use SQL::Abstract;
1355
1356     my $sql = SQL::Abstract->new;
1357
1358     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1359
1360     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1361
1362     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1363
1364     my($stmt, @bind) = $sql->delete($table, \%where);
1365
1366     # Then, use these in your DBI statements
1367     my $sth = $dbh->prepare($stmt);
1368     $sth->execute(@bind);
1369
1370     # Just generate the WHERE clause
1371     my($stmt, @bind) = $sql->where(\%where, \@order);
1372
1373     # Return values in the same order, for hashed queries
1374     # See PERFORMANCE section for more details
1375     my @bind = $sql->values(\%fieldvals);
1376
1377 =head1 DESCRIPTION
1378
1379 This module was inspired by the excellent L<DBIx::Abstract>.
1380 However, in using that module I found that what I really wanted
1381 to do was generate SQL, but still retain complete control over my
1382 statement handles and use the DBI interface. So, I set out to
1383 create an abstract SQL generation module.
1384
1385 While based on the concepts used by L<DBIx::Abstract>, there are
1386 several important differences, especially when it comes to WHERE
1387 clauses. I have modified the concepts used to make the SQL easier
1388 to generate from Perl data structures and, IMO, more intuitive.
1389 The underlying idea is for this module to do what you mean, based
1390 on the data structures you provide it. The big advantage is that
1391 you don't have to modify your code every time your data changes,
1392 as this module figures it out.
1393
1394 To begin with, an SQL INSERT is as easy as just specifying a hash
1395 of C<key=value> pairs:
1396
1397     my %data = (
1398         name => 'Jimbo Bobson',
1399         phone => '123-456-7890',
1400         address => '42 Sister Lane',
1401         city => 'St. Louis',
1402         state => 'Louisiana',
1403     );
1404
1405 The SQL can then be generated with this:
1406
1407     my($stmt, @bind) = $sql->insert('people', \%data);
1408
1409 Which would give you something like this:
1410
1411     $stmt = "INSERT INTO people
1412                     (address, city, name, phone, state)
1413                     VALUES (?, ?, ?, ?, ?)";
1414     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1415              '123-456-7890', 'Louisiana');
1416
1417 These are then used directly in your DBI code:
1418
1419     my $sth = $dbh->prepare($stmt);
1420     $sth->execute(@bind);
1421
1422 =head2 Inserting and Updating Arrays
1423
1424 If your database has array types (like for example Postgres),
1425 activate the special option C<< array_datatypes => 1 >>
1426 when creating the C<SQL::Abstract> object.
1427 Then you may use an arrayref to insert and update database array types:
1428
1429     my $sql = SQL::Abstract->new(array_datatypes => 1);
1430     my %data = (
1431         planets => [qw/Mercury Venus Earth Mars/]
1432     );
1433
1434     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1435
1436 This results in:
1437
1438     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1439
1440     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1441
1442
1443 =head2 Inserting and Updating SQL
1444
1445 In order to apply SQL functions to elements of your C<%data> you may
1446 specify a reference to an arrayref for the given hash value. For example,
1447 if you need to execute the Oracle C<to_date> function on a value, you can
1448 say something like this:
1449
1450     my %data = (
1451         name => 'Bill',
1452         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1453     );
1454
1455 The first value in the array is the actual SQL. Any other values are
1456 optional and would be included in the bind values array. This gives
1457 you:
1458
1459     my($stmt, @bind) = $sql->insert('people', \%data);
1460
1461     $stmt = "INSERT INTO people (name, date_entered)
1462                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1463     @bind = ('Bill', '03/02/2003');
1464
1465 An UPDATE is just as easy, all you change is the name of the function:
1466
1467     my($stmt, @bind) = $sql->update('people', \%data);
1468
1469 Notice that your C<%data> isn't touched; the module will generate
1470 the appropriately quirky SQL for you automatically. Usually you'll
1471 want to specify a WHERE clause for your UPDATE, though, which is
1472 where handling C<%where> hashes comes in handy...
1473
1474 =head2 Complex where statements
1475
1476 This module can generate pretty complicated WHERE statements
1477 easily. For example, simple C<key=value> pairs are taken to mean
1478 equality, and if you want to see if a field is within a set
1479 of values, you can use an arrayref. Let's say we wanted to
1480 SELECT some data based on this criteria:
1481
1482     my %where = (
1483        requestor => 'inna',
1484        worker => ['nwiger', 'rcwe', 'sfz'],
1485        status => { '!=', 'completed' }
1486     );
1487
1488     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1489
1490 The above would give you something like this:
1491
1492     $stmt = "SELECT * FROM tickets WHERE
1493                 ( requestor = ? ) AND ( status != ? )
1494                 AND ( worker = ? OR worker = ? OR worker = ? )";
1495     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1496
1497 Which you could then use in DBI code like so:
1498
1499     my $sth = $dbh->prepare($stmt);
1500     $sth->execute(@bind);
1501
1502 Easy, eh?
1503
1504 =head1 FUNCTIONS
1505
1506 The functions are simple. There's one for each major SQL operation,
1507 and a constructor you use first. The arguments are specified in a
1508 similar order to each function (table, then fields, then a where
1509 clause) to try and simplify things.
1510
1511
1512
1513
1514 =head2 new(option => 'value')
1515
1516 The C<new()> function takes a list of options and values, and returns
1517 a new B<SQL::Abstract> object which can then be used to generate SQL
1518 through the methods below. The options accepted are:
1519
1520 =over
1521
1522 =item case
1523
1524 If set to 'lower', then SQL will be generated in all lowercase. By
1525 default SQL is generated in "textbook" case meaning something like:
1526
1527     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1528
1529 Any setting other than 'lower' is ignored.
1530
1531 =item cmp
1532
1533 This determines what the default comparison operator is. By default
1534 it is C<=>, meaning that a hash like this:
1535
1536     %where = (name => 'nwiger', email => 'nate@wiger.org');
1537
1538 Will generate SQL like this:
1539
1540     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1541
1542 However, you may want loose comparisons by default, so if you set
1543 C<cmp> to C<like> you would get SQL such as:
1544
1545     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1546
1547 You can also override the comparsion on an individual basis - see
1548 the huge section on L</"WHERE CLAUSES"> at the bottom.
1549
1550 =item sqltrue, sqlfalse
1551
1552 Expressions for inserting boolean values within SQL statements.
1553 By default these are C<1=1> and C<1=0>. They are used
1554 by the special operators C<-in> and C<-not_in> for generating
1555 correct SQL even when the argument is an empty array (see below).
1556
1557 =item logic
1558
1559 This determines the default logical operator for multiple WHERE
1560 statements in arrays or hashes. If absent, the default logic is "or"
1561 for arrays, and "and" for hashes. This means that a WHERE
1562 array of the form:
1563
1564     @where = (
1565         event_date => {'>=', '2/13/99'},
1566         event_date => {'<=', '4/24/03'},
1567     );
1568
1569 will generate SQL like this:
1570
1571     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1572
1573 This is probably not what you want given this query, though (look
1574 at the dates). To change the "OR" to an "AND", simply specify:
1575
1576     my $sql = SQL::Abstract->new(logic => 'and');
1577
1578 Which will change the above C<WHERE> to:
1579
1580     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1581
1582 The logic can also be changed locally by inserting
1583 a modifier in front of an arrayref :
1584
1585     @where = (-and => [event_date => {'>=', '2/13/99'},
1586                        event_date => {'<=', '4/24/03'} ]);
1587
1588 See the L</"WHERE CLAUSES"> section for explanations.
1589
1590 =item convert
1591
1592 This will automatically convert comparisons using the specified SQL
1593 function for both column and value. This is mostly used with an argument
1594 of C<upper> or C<lower>, so that the SQL will have the effect of
1595 case-insensitive "searches". For example, this:
1596
1597     $sql = SQL::Abstract->new(convert => 'upper');
1598     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1599
1600 Will turn out the following SQL:
1601
1602     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1603
1604 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1605 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1606 not validate this option; it will just pass through what you specify verbatim).
1607
1608 =item bindtype
1609
1610 This is a kludge because many databases suck. For example, you can't
1611 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1612 Instead, you have to use C<bind_param()>:
1613
1614     $sth->bind_param(1, 'reg data');
1615     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1616
1617 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1618 which loses track of which field each slot refers to. Fear not.
1619
1620 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1621 Currently, you can specify either C<normal> (default) or C<columns>. If you
1622 specify C<columns>, you will get an array that looks like this:
1623
1624     my $sql = SQL::Abstract->new(bindtype => 'columns');
1625     my($stmt, @bind) = $sql->insert(...);
1626
1627     @bind = (
1628         [ 'column1', 'value1' ],
1629         [ 'column2', 'value2' ],
1630         [ 'column3', 'value3' ],
1631     );
1632
1633 You can then iterate through this manually, using DBI's C<bind_param()>.
1634
1635     $sth->prepare($stmt);
1636     my $i = 1;
1637     for (@bind) {
1638         my($col, $data) = @$_;
1639         if ($col eq 'details' || $col eq 'comments') {
1640             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1641         } elsif ($col eq 'image') {
1642             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1643         } else {
1644             $sth->bind_param($i, $data);
1645         }
1646         $i++;
1647     }
1648     $sth->execute;      # execute without @bind now
1649
1650 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1651 Basically, the advantage is still that you don't have to care which fields
1652 are or are not included. You could wrap that above C<for> loop in a simple
1653 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1654 get a layer of abstraction over manual SQL specification.
1655
1656 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1657 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1658 will expect the bind values in this format.
1659
1660 =item quote_char
1661
1662 This is the character that a table or column name will be quoted
1663 with.  By default this is an empty string, but you could set it to
1664 the character C<`>, to generate SQL like this:
1665
1666   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1667
1668 Alternatively, you can supply an array ref of two items, the first being the left
1669 hand quote character, and the second the right hand quote character. For
1670 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1671 that generates SQL like this:
1672
1673   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1674
1675 Quoting is useful if you have tables or columns names that are reserved
1676 words in your database's SQL dialect.
1677
1678 =item name_sep
1679
1680 This is the character that separates a table and column name.  It is
1681 necessary to specify this when the C<quote_char> option is selected,
1682 so that tables and column names can be individually quoted like this:
1683
1684   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1685
1686 =item array_datatypes
1687
1688 When this option is true, arrayrefs in INSERT or UPDATE are
1689 interpreted as array datatypes and are passed directly
1690 to the DBI layer.
1691 When this option is false, arrayrefs are interpreted
1692 as literal SQL, just like refs to arrayrefs
1693 (but this behavior is for backwards compatibility; when writing
1694 new queries, use the "reference to arrayref" syntax
1695 for literal SQL).
1696
1697
1698 =item special_ops
1699
1700 Takes a reference to a list of "special operators"
1701 to extend the syntax understood by L<SQL::Abstract>.
1702 See section L</"SPECIAL OPERATORS"> for details.
1703
1704 =item unary_ops
1705
1706 Takes a reference to a list of "unary operators"
1707 to extend the syntax understood by L<SQL::Abstract>.
1708 See section L</"UNARY OPERATORS"> for details.
1709
1710
1711
1712 =back
1713
1714 =head2 insert($table, \@values || \%fieldvals, \%options)
1715
1716 This is the simplest function. You simply give it a table name
1717 and either an arrayref of values or hashref of field/value pairs.
1718 It returns an SQL INSERT statement and a list of bind values.
1719 See the sections on L</"Inserting and Updating Arrays"> and
1720 L</"Inserting and Updating SQL"> for information on how to insert
1721 with those data types.
1722
1723 The optional C<\%options> hash reference may contain additional
1724 options to generate the insert SQL. Currently supported options
1725 are:
1726
1727 =over 4
1728
1729 =item returning
1730
1731 Takes either a scalar of raw SQL fields, or an array reference of
1732 field names, and adds on an SQL C<RETURNING> statement at the end.
1733 This allows you to return data generated by the insert statement
1734 (such as row IDs) without performing another C<SELECT> statement.
1735 Note, however, this is not part of the SQL standard and may not
1736 be supported by all database engines.
1737
1738 =back
1739
1740 =head2 update($table, \%fieldvals, \%where)
1741
1742 This takes a table, hashref of field/value pairs, and an optional
1743 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1744 of bind values.
1745 See the sections on L</"Inserting and Updating Arrays"> and
1746 L</"Inserting and Updating SQL"> for information on how to insert
1747 with those data types.
1748
1749 =head2 select($source, $fields, $where, $order)
1750
1751 This returns a SQL SELECT statement and associated list of bind values, as
1752 specified by the arguments  :
1753
1754 =over
1755
1756 =item $source
1757
1758 Specification of the 'FROM' part of the statement.
1759 The argument can be either a plain scalar (interpreted as a table
1760 name, will be quoted), or an arrayref (interpreted as a list
1761 of table names, joined by commas, quoted), or a scalarref
1762 (literal table name, not quoted), or a ref to an arrayref
1763 (list of literal table names, joined by commas, not quoted).
1764
1765 =item $fields
1766
1767 Specification of the list of fields to retrieve from
1768 the source.
1769 The argument can be either an arrayref (interpreted as a list
1770 of field names, will be joined by commas and quoted), or a
1771 plain scalar (literal SQL, not quoted).
1772 Please observe that this API is not as flexible as for
1773 the first argument C<$table>, for backwards compatibility reasons.
1774
1775 =item $where
1776
1777 Optional argument to specify the WHERE part of the query.
1778 The argument is most often a hashref, but can also be
1779 an arrayref or plain scalar --
1780 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1781
1782 =item $order
1783
1784 Optional argument to specify the ORDER BY part of the query.
1785 The argument can be a scalar, a hashref or an arrayref
1786 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1787 for details.
1788
1789 =back
1790
1791
1792 =head2 delete($table, \%where)
1793
1794 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1795 It returns an SQL DELETE statement and list of bind values.
1796
1797 =head2 where(\%where, \@order)
1798
1799 This is used to generate just the WHERE clause. For example,
1800 if you have an arbitrary data structure and know what the
1801 rest of your SQL is going to look like, but want an easy way
1802 to produce a WHERE clause, use this. It returns an SQL WHERE
1803 clause and list of bind values.
1804
1805
1806 =head2 values(\%data)
1807
1808 This just returns the values from the hash C<%data>, in the same
1809 order that would be returned from any of the other above queries.
1810 Using this allows you to markedly speed up your queries if you
1811 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1812
1813 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1814
1815 Warning: This is an experimental method and subject to change.
1816
1817 This returns arbitrarily generated SQL. It's a really basic shortcut.
1818 It will return two different things, depending on return context:
1819
1820     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1821     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
1822
1823 These would return the following:
1824
1825     # First calling form
1826     $stmt = "CREATE TABLE test (?, ?)";
1827     @bind = (field1, field2);
1828
1829     # Second calling form
1830     $stmt_and_val = "CREATE TABLE test (field1, field2)";
1831
1832 Depending on what you're trying to do, it's up to you to choose the correct
1833 format. In this example, the second form is what you would want.
1834
1835 By the same token:
1836
1837     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
1838
1839 Might give you:
1840
1841     ALTER SESSION SET nls_date_format = 'MM/YY'
1842
1843 You get the idea. Strings get their case twiddled, but everything
1844 else remains verbatim.
1845
1846
1847
1848
1849 =head1 WHERE CLAUSES
1850
1851 =head2 Introduction
1852
1853 This module uses a variation on the idea from L<DBIx::Abstract>. It
1854 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
1855 module is that things in arrays are OR'ed, and things in hashes
1856 are AND'ed.>
1857
1858 The easiest way to explain is to show lots of examples. After
1859 each C<%where> hash shown, it is assumed you used:
1860
1861     my($stmt, @bind) = $sql->where(\%where);
1862
1863 However, note that the C<%where> hash can be used directly in any
1864 of the other functions as well, as described above.
1865
1866 =head2 Key-value pairs
1867
1868 So, let's get started. To begin, a simple hash:
1869
1870     my %where  = (
1871         user   => 'nwiger',
1872         status => 'completed'
1873     );
1874
1875 Is converted to SQL C<key = val> statements:
1876
1877     $stmt = "WHERE user = ? AND status = ?";
1878     @bind = ('nwiger', 'completed');
1879
1880 One common thing I end up doing is having a list of values that
1881 a field can be in. To do this, simply specify a list inside of
1882 an arrayref:
1883
1884     my %where  = (
1885         user   => 'nwiger',
1886         status => ['assigned', 'in-progress', 'pending'];
1887     );
1888
1889 This simple code will create the following:
1890
1891     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
1892     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
1893
1894 A field associated to an empty arrayref will be considered a
1895 logical false and will generate 0=1.
1896
1897 =head2 Specific comparison operators
1898
1899 If you want to specify a different type of operator for your comparison,
1900 you can use a hashref for a given column:
1901
1902     my %where  = (
1903         user   => 'nwiger',
1904         status => { '!=', 'completed' }
1905     );
1906
1907 Which would generate:
1908
1909     $stmt = "WHERE user = ? AND status != ?";
1910     @bind = ('nwiger', 'completed');
1911
1912 To test against multiple values, just enclose the values in an arrayref:
1913
1914     status => { '=', ['assigned', 'in-progress', 'pending'] };
1915
1916 Which would give you:
1917
1918     "WHERE status = ? OR status = ? OR status = ?"
1919
1920
1921 The hashref can also contain multiple pairs, in which case it is expanded
1922 into an C<AND> of its elements:
1923
1924     my %where  = (
1925         user   => 'nwiger',
1926         status => { '!=', 'completed', -not_like => 'pending%' }
1927     );
1928
1929     # Or more dynamically, like from a form
1930     $where{user} = 'nwiger';
1931     $where{status}{'!='} = 'completed';
1932     $where{status}{'-not_like'} = 'pending%';
1933
1934     # Both generate this
1935     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
1936     @bind = ('nwiger', 'completed', 'pending%');
1937
1938
1939 To get an OR instead, you can combine it with the arrayref idea:
1940
1941     my %where => (
1942          user => 'nwiger',
1943          priority => [ {'=', 2}, {'!=', 1} ]
1944     );
1945
1946 Which would generate:
1947
1948     $stmt = "WHERE user = ? AND priority = ? OR priority != ?";
1949     @bind = ('nwiger', '2', '1');
1950
1951 If you want to include literal SQL (with or without bind values), just use a
1952 scalar reference or array reference as the value:
1953
1954     my %where  = (
1955         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
1956         date_expires => { '<' => \"now()" }
1957     );
1958
1959 Which would generate:
1960
1961     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
1962     @bind = ('11/26/2008');
1963
1964
1965 =head2 Logic and nesting operators
1966
1967 In the example above,
1968 there is a subtle trap if you want to say something like
1969 this (notice the C<AND>):
1970
1971     WHERE priority != ? AND priority != ?
1972
1973 Because, in Perl you I<can't> do this:
1974
1975     priority => { '!=', 2, '!=', 1 }
1976
1977 As the second C<!=> key will obliterate the first. The solution
1978 is to use the special C<-modifier> form inside an arrayref:
1979
1980     priority => [ -and => {'!=', 2},
1981                           {'!=', 1} ]
1982
1983
1984 Normally, these would be joined by C<OR>, but the modifier tells it
1985 to use C<AND> instead. (Hint: You can use this in conjunction with the
1986 C<logic> option to C<new()> in order to change the way your queries
1987 work by default.) B<Important:> Note that the C<-modifier> goes
1988 B<INSIDE> the arrayref, as an extra first element. This will
1989 B<NOT> do what you think it might:
1990
1991     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
1992
1993 Here is a quick list of equivalencies, since there is some overlap:
1994
1995     # Same
1996     status => {'!=', 'completed', 'not like', 'pending%' }
1997     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
1998
1999     # Same
2000     status => {'=', ['assigned', 'in-progress']}
2001     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
2002     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
2003
2004
2005
2006 =head2 Special operators : IN, BETWEEN, etc.
2007
2008 You can also use the hashref format to compare a list of fields using the
2009 C<IN> comparison operator, by specifying the list as an arrayref:
2010
2011     my %where  = (
2012         status   => 'completed',
2013         reportid => { -in => [567, 2335, 2] }
2014     );
2015
2016 Which would generate:
2017
2018     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
2019     @bind = ('completed', '567', '2335', '2');
2020
2021 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
2022 the same way.
2023
2024 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
2025 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
2026 'sqltrue' (by default : C<1=1>).
2027
2028 In addition to the array you can supply a chunk of literal sql or
2029 literal sql with bind:
2030
2031     my %where = {
2032       customer => { -in => \[
2033         'SELECT cust_id FROM cust WHERE balance > ?',
2034         2000,
2035       ],
2036       status => { -in => \'SELECT status_codes FROM states' },
2037     };
2038
2039 would generate:
2040
2041     $stmt = "WHERE (
2042           customer IN ( SELECT cust_id FROM cust WHERE balance > ? )
2043       AND status IN ( SELECT status_codes FROM states )
2044     )";
2045     @bind = ('2000');
2046
2047
2048
2049 Another pair of operators is C<-between> and C<-not_between>,
2050 used with an arrayref of two values:
2051
2052     my %where  = (
2053         user   => 'nwiger',
2054         completion_date => {
2055            -not_between => ['2002-10-01', '2003-02-06']
2056         }
2057     );
2058
2059 Would give you:
2060
2061     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
2062
2063 Just like with C<-in> all plausible combinations of literal SQL
2064 are possible:
2065
2066     my %where = {
2067       start0 => { -between => [ 1, 2 ] },
2068       start1 => { -between => \["? AND ?", 1, 2] },
2069       start2 => { -between => \"lower(x) AND upper(y)" },
2070       start3 => { -between => [
2071         \"lower(x)",
2072         \["upper(?)", 'stuff' ],
2073       ] },
2074     };
2075
2076 Would give you:
2077
2078     $stmt = "WHERE (
2079           ( start0 BETWEEN ? AND ?                )
2080       AND ( start1 BETWEEN ? AND ?                )
2081       AND ( start2 BETWEEN lower(x) AND upper(y)  )
2082       AND ( start3 BETWEEN lower(x) AND upper(?)  )
2083     )";
2084     @bind = (1, 2, 1, 2, 'stuff');
2085
2086
2087 These are the two builtin "special operators"; but the
2088 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
2089
2090 =head2 Unary operators: bool
2091
2092 If you wish to test against boolean columns or functions within your
2093 database you can use the C<-bool> and C<-not_bool> operators. For
2094 example to test the column C<is_user> being true and the column
2095 <is_enabled> being false you would use:-
2096
2097     my %where  = (
2098         -bool       => 'is_user',
2099         -not_bool   => 'is_enabled',
2100     );
2101
2102 Would give you:
2103
2104     WHERE is_user AND NOT is_enabled
2105
2106 If a more complex combination is required, testing more conditions,
2107 then you should use the and/or operators:-
2108
2109     my %where  = (
2110         -and           => [
2111             -bool      => 'one',
2112             -bool      => 'two',
2113             -bool      => 'three',
2114             -not_bool  => 'four',
2115         ],
2116     );
2117
2118 Would give you:
2119
2120     WHERE one AND two AND three AND NOT four
2121
2122
2123 =head2 Nested conditions, -and/-or prefixes
2124
2125 So far, we've seen how multiple conditions are joined with a top-level
2126 C<AND>.  We can change this by putting the different conditions we want in
2127 hashes and then putting those hashes in an array. For example:
2128
2129     my @where = (
2130         {
2131             user   => 'nwiger',
2132             status => { -like => ['pending%', 'dispatched'] },
2133         },
2134         {
2135             user   => 'robot',
2136             status => 'unassigned',
2137         }
2138     );
2139
2140 This data structure would create the following:
2141
2142     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
2143                 OR ( user = ? AND status = ? ) )";
2144     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
2145
2146
2147 There is also a special C<-nest>
2148 operator which adds an additional set of parens, to create a subquery.
2149 For example, to get something like this:
2150
2151     $stmt = "WHERE user = ? AND ( workhrs > ? OR geo = ? )";
2152     @bind = ('nwiger', '20', 'ASIA');
2153
2154 You would do:
2155
2156     my %where = (
2157          user => 'nwiger',
2158         -nest => [ workhrs => {'>', 20}, geo => 'ASIA' ],
2159     );
2160
2161
2162 Finally, clauses in hashrefs or arrayrefs can be
2163 prefixed with an C<-and> or C<-or> to change the logic
2164 inside :
2165
2166     my @where = (
2167          -and => [
2168             user => 'nwiger',
2169             -nest => [
2170                 -and => [workhrs => {'>', 20}, geo => 'ASIA' ],
2171                 -and => [workhrs => {'<', 50}, geo => 'EURO' ]
2172             ],
2173         ],
2174     );
2175
2176 That would yield:
2177
2178     WHERE ( user = ? AND
2179           ( ( workhrs > ? AND geo = ? )
2180          OR ( workhrs < ? AND geo = ? ) ) )
2181
2182
2183 =head2 Algebraic inconsistency, for historical reasons
2184
2185 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
2186 operator goes C<outside> of the nested structure; whereas when connecting
2187 several constraints on one column, the C<-and> operator goes
2188 C<inside> the arrayref. Here is an example combining both features :
2189
2190    my @where = (
2191      -and => [a => 1, b => 2],
2192      -or  => [c => 3, d => 4],
2193       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
2194    )
2195
2196 yielding
2197
2198   WHERE ( (    ( a = ? AND b = ? )
2199             OR ( c = ? OR d = ? )
2200             OR ( e LIKE ? AND e LIKE ? ) ) )
2201
2202 This difference in syntax is unfortunate but must be preserved for
2203 historical reasons. So be careful : the two examples below would
2204 seem algebraically equivalent, but they are not
2205
2206   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
2207   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
2208
2209   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
2210   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
2211
2212
2213 =head2 Literal SQL
2214
2215 Finally, sometimes only literal SQL will do. If you want to include
2216 literal SQL verbatim, you can specify it as a scalar reference, namely:
2217
2218     my $inn = 'is Not Null';
2219     my %where = (
2220         priority => { '<', 2 },
2221         requestor => \$inn
2222     );
2223
2224 This would create:
2225
2226     $stmt = "WHERE priority < ? AND requestor is Not Null";
2227     @bind = ('2');
2228
2229 Note that in this example, you only get one bind parameter back, since
2230 the verbatim SQL is passed as part of the statement.
2231
2232 Of course, just to prove a point, the above can also be accomplished
2233 with this:
2234
2235     my %where = (
2236         priority  => { '<', 2 },
2237         requestor => { '!=', undef },
2238     );
2239
2240
2241 TMTOWTDI
2242
2243 Conditions on boolean columns can be expressed in the same way, passing
2244 a reference to an empty string, however using liternal SQL in this way
2245 is deprecated - the preferred method is to use the boolean operators -
2246 see L</"Unary operators: bool"> :
2247
2248     my %where = (
2249         priority  => { '<', 2 },
2250         is_ready  => \"";
2251     );
2252
2253 which yields
2254
2255     $stmt = "WHERE priority < ? AND is_ready";
2256     @bind = ('2');
2257
2258
2259 =head2 Literal SQL with placeholders and bind values (subqueries)
2260
2261 If the literal SQL to be inserted has placeholders and bind values,
2262 use a reference to an arrayref (yes this is a double reference --
2263 not so common, but perfectly legal Perl). For example, to find a date
2264 in Postgres you can use something like this:
2265
2266     my %where = (
2267        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
2268     )
2269
2270 This would create:
2271
2272     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
2273     @bind = ('10');
2274
2275 Note that you must pass the bind values in the same format as they are returned
2276 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
2277 provide the bind values in the C<< [ column_meta => value ] >> format, where
2278 C<column_meta> is an opaque scalar value; most commonly the column name, but
2279 you can use any scalar value (including references and blessed references),
2280 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
2281 to C<columns> the above example will look like:
2282
2283     my %where = (
2284        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
2285     )
2286
2287 Literal SQL is especially useful for nesting parenthesized clauses in the
2288 main SQL query. Here is a first example :
2289
2290   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2291                                100, "foo%");
2292   my %where = (
2293     foo => 1234,
2294     bar => \["IN ($sub_stmt)" => @sub_bind],
2295   );
2296
2297 This yields :
2298
2299   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2300                                              WHERE c2 < ? AND c3 LIKE ?))";
2301   @bind = (1234, 100, "foo%");
2302
2303 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2304 are expressed in the same way. Of course the C<$sub_stmt> and
2305 its associated bind values can be generated through a former call
2306 to C<select()> :
2307
2308   my ($sub_stmt, @sub_bind)
2309      = $sql->select("t1", "c1", {c2 => {"<" => 100},
2310                                  c3 => {-like => "foo%"}});
2311   my %where = (
2312     foo => 1234,
2313     bar => \["> ALL ($sub_stmt)" => @sub_bind],
2314   );
2315
2316 In the examples above, the subquery was used as an operator on a column;
2317 but the same principle also applies for a clause within the main C<%where>
2318 hash, like an EXISTS subquery :
2319
2320   my ($sub_stmt, @sub_bind)
2321      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2322   my %where = (
2323     foo   => 1234,
2324     -nest => \["EXISTS ($sub_stmt)" => @sub_bind],
2325   );
2326
2327 which yields
2328
2329   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2330                                         WHERE c1 = ? AND c2 > t0.c0))";
2331   @bind = (1234, 1);
2332
2333
2334 Observe that the condition on C<c2> in the subquery refers to
2335 column C<t0.c0> of the main query : this is I<not> a bind
2336 value, so we have to express it through a scalar ref.
2337 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2338 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2339 what we wanted here.
2340
2341 Another use of the subquery technique is when some SQL clauses need
2342 parentheses, as it often occurs with some proprietary SQL extensions
2343 like for example fulltext expressions, geospatial expressions,
2344 NATIVE clauses, etc. Here is an example of a fulltext query in MySQL :
2345
2346   my %where = (
2347     -nest => \["MATCH (col1, col2) AGAINST (?)" => qw/apples/]
2348   );
2349
2350 Finally, here is an example where a subquery is used
2351 for expressing unary negation:
2352
2353   my ($sub_stmt, @sub_bind)
2354      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2355   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2356   my %where = (
2357         lname  => {like => '%son%'},
2358         -nest  => \["NOT ($sub_stmt)" => @sub_bind],
2359     );
2360
2361 This yields
2362
2363   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2364   @bind = ('%son%', 10, 20)
2365
2366
2367
2368 =head2 Conclusion
2369
2370 These pages could go on for a while, since the nesting of the data
2371 structures this module can handle are pretty much unlimited (the
2372 module implements the C<WHERE> expansion as a recursive function
2373 internally). Your best bet is to "play around" with the module a
2374 little to see how the data structures behave, and choose the best
2375 format for your data based on that.
2376
2377 And of course, all the values above will probably be replaced with
2378 variables gotten from forms or the command line. After all, if you
2379 knew everything ahead of time, you wouldn't have to worry about
2380 dynamically-generating SQL and could just hardwire it into your
2381 script.
2382
2383
2384
2385
2386 =head1 ORDER BY CLAUSES
2387
2388 Some functions take an order by clause. This can either be a scalar (just a
2389 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2390 or an array of either of the two previous forms. Examples:
2391
2392                Given            |         Will Generate
2393     ----------------------------------------------------------
2394                                 |
2395     \'colA DESC'                | ORDER BY colA DESC
2396                                 |
2397     'colA'                      | ORDER BY colA
2398                                 |
2399     [qw/colA colB/]             | ORDER BY colA, colB
2400                                 |
2401     {-asc  => 'colA'}           | ORDER BY colA ASC
2402                                 |
2403     {-desc => 'colB'}           | ORDER BY colB DESC
2404                                 |
2405     ['colA', {-asc => 'colB'}]  | ORDER BY colA, colB ASC
2406                                 |
2407     { -asc => [qw/colA colB/] } | ORDER BY colA ASC, colB ASC
2408                                 |
2409     [                           |
2410       { -asc => 'colA' },       | ORDER BY colA ASC, colB DESC,
2411       { -desc => [qw/colB/],    |          colC ASC, colD ASC
2412       { -asc => [qw/colC colD/],|
2413     ]                           |
2414     ===========================================================
2415
2416
2417
2418 =head1 SPECIAL OPERATORS
2419
2420   my $sqlmaker = SQL::Abstract->new(special_ops => [
2421      {
2422       regex => qr/.../,
2423       handler => sub {
2424         my ($self, $field, $op, $arg) = @_;
2425         ...
2426       },
2427      },
2428      {
2429       regex => qr/.../,
2430       handler => 'method_name',
2431      },
2432    ]);
2433
2434 A "special operator" is a SQL syntactic clause that can be
2435 applied to a field, instead of a usual binary operator.
2436 For example :
2437
2438    WHERE field IN (?, ?, ?)
2439    WHERE field BETWEEN ? AND ?
2440    WHERE MATCH(field) AGAINST (?, ?)
2441
2442 Special operators IN and BETWEEN are fairly standard and therefore
2443 are builtin within C<SQL::Abstract> (as the overridable methods
2444 C<_where_field_IN> and C<_where_field_BETWEEN>). For other operators,
2445 like the MATCH .. AGAINST example above which is specific to MySQL,
2446 you can write your own operator handlers - supply a C<special_ops>
2447 argument to the C<new> method. That argument takes an arrayref of
2448 operator definitions; each operator definition is a hashref with two
2449 entries:
2450
2451 =over
2452
2453 =item regex
2454
2455 the regular expression to match the operator
2456
2457 =item handler
2458
2459 Either a coderef or a plain scalar method name. In both cases
2460 the expected return is C<< ($sql, @bind) >>.
2461
2462 When supplied with a method name, it is simply called on the
2463 L<SQL::Abstract/> object as:
2464
2465  $self->$method_name ($field, $op, $arg)
2466
2467  Where:
2468
2469   $op is the part that matched the handler regex
2470   $field is the LHS of the operator
2471   $arg is the RHS
2472
2473 When supplied with a coderef, it is called as:
2474
2475  $coderef->($self, $field, $op, $arg)
2476
2477
2478 =back
2479
2480 For example, here is an implementation
2481 of the MATCH .. AGAINST syntax for MySQL
2482
2483   my $sqlmaker = SQL::Abstract->new(special_ops => [
2484
2485     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2486     {regex => qr/^match$/i,
2487      handler => sub {
2488        my ($self, $field, $op, $arg) = @_;
2489        $arg = [$arg] if not ref $arg;
2490        my $label         = $self->_quote($field);
2491        my ($placeholder) = $self->_convert('?');
2492        my $placeholders  = join ", ", (($placeholder) x @$arg);
2493        my $sql           = $self->_sqlcase('match') . " ($label) "
2494                          . $self->_sqlcase('against') . " ($placeholders) ";
2495        my @bind = $self->_bindtype($field, @$arg);
2496        return ($sql, @bind);
2497        }
2498      },
2499
2500   ]);
2501
2502
2503 =head1 UNARY OPERATORS
2504
2505   my $sqlmaker = SQL::Abstract->new(unary_ops => [
2506      {
2507       regex => qr/.../,
2508       handler => sub {
2509         my ($self, $op, $arg) = @_;
2510         ...
2511       },
2512      },
2513      {
2514       regex => qr/.../,
2515       handler => 'method_name',
2516      },
2517    ]);
2518
2519 A "unary operator" is a SQL syntactic clause that can be
2520 applied to a field - the operator goes before the field
2521
2522 You can write your own operator handlers - supply a C<unary_ops>
2523 argument to the C<new> method. That argument takes an arrayref of
2524 operator definitions; each operator definition is a hashref with two
2525 entries:
2526
2527 =over
2528
2529 =item regex
2530
2531 the regular expression to match the operator
2532
2533 =item handler
2534
2535 Either a coderef or a plain scalar method name. In both cases
2536 the expected return is C<< $sql >>.
2537
2538 When supplied with a method name, it is simply called on the
2539 L<SQL::Abstract/> object as:
2540
2541  $self->$method_name ($op, $arg)
2542
2543  Where:
2544
2545   $op is the part that matched the handler regex
2546   $arg is the RHS or argument of the operator
2547
2548 When supplied with a coderef, it is called as:
2549
2550  $coderef->($self, $op, $arg)
2551
2552
2553 =back
2554
2555
2556 =head1 PERFORMANCE
2557
2558 Thanks to some benchmarking by Mark Stosberg, it turns out that
2559 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2560 I must admit this wasn't an intentional design issue, but it's a
2561 byproduct of the fact that you get to control your C<DBI> handles
2562 yourself.
2563
2564 To maximize performance, use a code snippet like the following:
2565
2566     # prepare a statement handle using the first row
2567     # and then reuse it for the rest of the rows
2568     my($sth, $stmt);
2569     for my $href (@array_of_hashrefs) {
2570         $stmt ||= $sql->insert('table', $href);
2571         $sth  ||= $dbh->prepare($stmt);
2572         $sth->execute($sql->values($href));
2573     }
2574
2575 The reason this works is because the keys in your C<$href> are sorted
2576 internally by B<SQL::Abstract>. Thus, as long as your data retains
2577 the same structure, you only have to generate the SQL the first time
2578 around. On subsequent queries, simply use the C<values> function provided
2579 by this module to return your values in the correct order.
2580
2581
2582 =head1 FORMBUILDER
2583
2584 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2585 really like this part (I do, at least). Building up a complex query
2586 can be as simple as the following:
2587
2588     #!/usr/bin/perl
2589
2590     use CGI::FormBuilder;
2591     use SQL::Abstract;
2592
2593     my $form = CGI::FormBuilder->new(...);
2594     my $sql  = SQL::Abstract->new;
2595
2596     if ($form->submitted) {
2597         my $field = $form->field;
2598         my $id = delete $field->{id};
2599         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2600     }
2601
2602 Of course, you would still have to connect using C<DBI> to run the
2603 query, but the point is that if you make your form look like your
2604 table, the actual query script can be extremely simplistic.
2605
2606 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2607 a fast interface to returning and formatting data. I frequently
2608 use these three modules together to write complex database query
2609 apps in under 50 lines.
2610
2611
2612 =head1 CHANGES
2613
2614 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2615 Great care has been taken to preserve the I<published> behavior
2616 documented in previous versions in the 1.* family; however,
2617 some features that were previously undocumented, or behaved
2618 differently from the documentation, had to be changed in order
2619 to clarify the semantics. Hence, client code that was relying
2620 on some dark areas of C<SQL::Abstract> v1.*
2621 B<might behave differently> in v1.50.
2622
2623 The main changes are :
2624
2625 =over
2626
2627 =item *
2628
2629 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2630
2631 =item *
2632
2633 support for the { operator => \"..." } construct (to embed literal SQL)
2634
2635 =item *
2636
2637 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2638
2639 =item *
2640
2641 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2642
2643 =item *
2644
2645 defensive programming : check arguments
2646
2647 =item *
2648
2649 fixed bug with global logic, which was previously implemented
2650 through global variables yielding side-effects. Prior versions would
2651 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2652 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2653 Now this is interpreted
2654 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2655
2656
2657 =item *
2658
2659 fixed semantics of  _bindtype on array args
2660
2661 =item *
2662
2663 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2664 we just avoid shifting arrays within that tree.
2665
2666 =item *
2667
2668 dropped the C<_modlogic> function
2669
2670 =back
2671
2672
2673
2674 =head1 ACKNOWLEDGEMENTS
2675
2676 There are a number of individuals that have really helped out with
2677 this module. Unfortunately, most of them submitted bugs via CPAN
2678 so I have no idea who they are! But the people I do know are:
2679
2680     Ash Berlin (order_by hash term support)
2681     Matt Trout (DBIx::Class support)
2682     Mark Stosberg (benchmarking)
2683     Chas Owens (initial "IN" operator support)
2684     Philip Collins (per-field SQL functions)
2685     Eric Kolve (hashref "AND" support)
2686     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2687     Dan Kubb (support for "quote_char" and "name_sep")
2688     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2689     Laurent Dami (internal refactoring, multiple -nest, extensible list of special operators, literal SQL)
2690     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2691     Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2692     Oliver Charles (support for "RETURNING" after "INSERT")
2693
2694 Thanks!
2695
2696 =head1 SEE ALSO
2697
2698 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2699
2700 =head1 AUTHOR
2701
2702 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2703
2704 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2705
2706 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2707 While not an official support venue, C<DBIx::Class> makes heavy use of
2708 C<SQL::Abstract>, and as such list members there are very familiar with
2709 how to create queries.
2710
2711 =head1 LICENSE
2712
2713 This module is free software; you may copy this under the same
2714 terms as perl itself (either the GNU General Public License or
2715 the Artistic License)
2716
2717 =cut
2718