lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use Carp;
   9 use strict;
  10 use warnings;
  11 use List::Util   qw/first/;
  12 use Scalar::Util qw/blessed/;
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.55';
  19
  20 # This would confuse some packagers
  21 #$VERSION      = eval $VERSION; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^(not )?between$/i, handler => '_where_field_BETWEEN'},
  29   {regex => qr/^(not )?in$/i,      handler => '_where_field_IN'},
  30 );
  31
  32 #======================================================================
  33 # DEBUGGING AND ERROR REPORTING
  34 #======================================================================
  35
  36 sub _debug {
  37   return unless $_[0]->{debug}; shift; # a little faster
  38   my $func = (caller(1))[3];
  39   warn "[$func] ", @_, "\n";
  40 }
  41
  42 sub belch (@) {
  43   my($func) = (caller(1))[3];
  44   carp "[$func] Warning: ", @_;
  45 }
  46
  47 sub puke (@) {
  48   my($func) = (caller(1))[3];
  49   croak "[$func] Fatal: ", @_;
  50 }
  51
  52
  53 #======================================================================
  54 # NEW
  55 #======================================================================
  56
  57 sub new {
  58   my $self = shift;
  59   my $class = ref($self) || $self;
  60   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  61
  62   # choose our case by keeping an option around
  63   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  64
  65   # default logic for interpreting arrayrefs
  66   $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
  67
  68   # how to return bind vars
  69   # LDNOTE: changed nwiger code : why this 'delete' ??
  70   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  71   $opt{bindtype} ||= 'normal';
  72
  73   # default comparison is "=", but can be overridden
  74   $opt{cmp} ||= '=';
  75
  76   # try to recognize which are the 'equality' and 'unequality' ops
  77   # (temporary quickfix, should go through a more seasoned API)
  78  $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  79  $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  80
  81   # SQL booleans
  82   $opt{sqltrue}  ||= '1=1';
  83   $opt{sqlfalse} ||= '0=1';
  84
  85   # special operators
  86   $opt{special_ops} ||= [];
  87   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
  88
  89   return bless \%opt, $class;
  90 }
  91
  92
  93
  94 #======================================================================
  95 # INSERT methods
  96 #======================================================================
  97
  98 sub insert {
  99   my $self  = shift;
 100   my $table = $self->_table(shift);
 101   my $data  = shift || return;
 102
 103   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 104   my ($sql, @bind) = $self->$method($data);
 105   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 106   return wantarray ? ($sql, @bind) : $sql;
 107 }
 108
 109 sub _insert_HASHREF { # explicit list of fields and then values
 110   my ($self, $data) = @_;
 111
 112   my @fields = sort keys %$data;
 113
 114   my ($sql, @bind) = $self->_insert_values($data);
 115
 116   # assemble SQL
 117   $_ = $self->_quote($_) foreach @fields;
 118   $sql = "( ".join(", ", @fields).") ".$sql;
 119
 120   return ($sql, @bind);
 121 }
 122
 123 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 124   my ($self, $data) = @_;
 125
 126   # no names (arrayref) so can't generate bindtype
 127   $self->{bindtype} ne 'columns'
 128     or belch "can't do 'columns' bindtype when called with arrayref";
 129
 130   # fold the list of values into a hash of column name - value pairs
 131   # (where the column names are artificially generated, and their
 132   # lexicographical ordering keep the ordering of the original list)
 133   my $i = "a";  # incremented values will be in lexicographical order
 134   my $data_in_hash = { map { ($i++ => $_) } @$data };
 135
 136   return $self->_insert_values($data_in_hash);
 137 }
 138
 139 sub _insert_ARRAYREFREF { # literal SQL with bind
 140   my ($self, $data) = @_;
 141
 142   my ($sql, @bind) = @${$data};
 143   $self->_assert_bindval_matches_bindtype(@bind);
 144
 145   return ($sql, @bind);
 146 }
 147
 148
 149 sub _insert_SCALARREF { # literal SQL without bind
 150   my ($self, $data) = @_;
 151
 152   return ($$data);
 153 }
 154
 155 sub _insert_values {
 156   my ($self, $data) = @_;
 157
 158   my (@values, @all_bind);
 159   foreach my $column (sort keys %$data) {
 160     my $v = $data->{$column};
 161
 162     $self->_SWITCH_refkind($v, {
 163
 164       ARRAYREF => sub {
 165         if ($self->{array_datatypes}) { # if array datatype are activated
 166           push @values, '?';
 167           push @all_bind, $self->_bindtype($column, $v);
 168         }
 169         else {                          # else literal SQL with bind
 170           my ($sql, @bind) = @$v;
 171           $self->_assert_bindval_matches_bindtype(@bind);
 172           push @values, $sql;
 173           push @all_bind, @bind;
 174         }
 175       },
 176
 177       ARRAYREFREF => sub { # literal SQL with bind
 178         my ($sql, @bind) = @${$v};
 179         $self->_assert_bindval_matches_bindtype(@bind);
 180         push @values, $sql;
 181         push @all_bind, @bind;
 182       },
 183
 184       # THINK : anything useful to do with a HASHREF ?
 185       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 186         #TODO in SQLA >= 2.0 it will die instead
 187         belch "HASH ref as bind value in insert is not supported";
 188         push @values, '?';
 189         push @all_bind, $self->_bindtype($column, $v);
 190       },
 191
 192       SCALARREF => sub {  # literal SQL without bind
 193         push @values, $$v;
 194       },
 195
 196       SCALAR_or_UNDEF => sub {
 197         push @values, '?';
 198         push @all_bind, $self->_bindtype($column, $v);
 199       },
 200
 201      });
 202
 203   }
 204
 205   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 206   return ($sql, @all_bind);
 207 }
 208
 209
 210
 211 #======================================================================
 212 # UPDATE methods
 213 #======================================================================
 214
 215
 216 sub update {
 217   my $self  = shift;
 218   my $table = $self->_table(shift);
 219   my $data  = shift || return;
 220   my $where = shift;
 221
 222   # first build the 'SET' part of the sql statement
 223   my (@set, @all_bind);
 224   puke "Unsupported data type specified to \$sql->update"
 225     unless ref $data eq 'HASH';
 226
 227   for my $k (sort keys %$data) {
 228     my $v = $data->{$k};
 229     my $r = ref $v;
 230     my $label = $self->_quote($k);
 231
 232     $self->_SWITCH_refkind($v, {
 233       ARRAYREF => sub {
 234         if ($self->{array_datatypes}) { # array datatype
 235           push @set, "$label = ?";
 236           push @all_bind, $self->_bindtype($k, $v);
 237         }
 238         else {                          # literal SQL with bind
 239           my ($sql, @bind) = @$v;
 240           $self->_assert_bindval_matches_bindtype(@bind);
 241           push @set, "$label = $sql";
 242           push @all_bind, @bind;
 243         }
 244       },
 245       ARRAYREFREF => sub { # literal SQL with bind
 246         my ($sql, @bind) = @${$v};
 247         $self->_assert_bindval_matches_bindtype(@bind);
 248         push @set, "$label = $sql";
 249         push @all_bind, @bind;
 250       },
 251       SCALARREF => sub {  # literal SQL without bind
 252         push @set, "$label = $$v";
 253        },
 254       SCALAR_or_UNDEF => sub {
 255         push @set, "$label = ?";
 256         push @all_bind, $self->_bindtype($k, $v);
 257       },
 258     });
 259   }
 260
 261   # generate sql
 262   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 263           . join ', ', @set;
 264
 265   if ($where) {
 266     my($where_sql, @where_bind) = $self->where($where);
 267     $sql .= $where_sql;
 268     push @all_bind, @where_bind;
 269   }
 270
 271   return wantarray ? ($sql, @all_bind) : $sql;
 272 }
 273
 274
 275
 276
 277 #======================================================================
 278 # SELECT
 279 #======================================================================
 280
 281
 282 sub select {
 283   my $self   = shift;
 284   my $table  = $self->_table(shift);
 285   my $fields = shift || '*';
 286   my $where  = shift;
 287   my $order  = shift;
 288
 289   my($where_sql, @bind) = $self->where($where, $order);
 290
 291   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 292                                    : $fields;
 293   my $sql = join(' ', $self->_sqlcase('select'), $f,
 294                       $self->_sqlcase('from'),   $table)
 295           . $where_sql;
 296
 297   return wantarray ? ($sql, @bind) : $sql;
 298 }
 299
 300 #======================================================================
 301 # DELETE
 302 #======================================================================
 303
 304
 305 sub delete {
 306   my $self  = shift;
 307   my $table = $self->_table(shift);
 308   my $where = shift;
 309
 310
 311   my($where_sql, @bind) = $self->where($where);
 312   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 313
 314   return wantarray ? ($sql, @bind) : $sql;
 315 }
 316
 317
 318 #======================================================================
 319 # WHERE: entry point
 320 #======================================================================
 321
 322
 323
 324 # Finally, a separate routine just to handle WHERE clauses
 325 sub where {
 326   my ($self, $where, $order) = @_;
 327
 328   # where ?
 329   my ($sql, @bind) = $self->_recurse_where($where);
 330   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 331
 332   # order by?
 333   if ($order) {
 334     $sql .= $self->_order_by($order);
 335   }
 336
 337   return wantarray ? ($sql, @bind) : $sql;
 338 }
 339
 340
 341 sub _recurse_where {
 342   my ($self, $where, $logic) = @_;
 343
 344   # dispatch on appropriate method according to refkind of $where
 345   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 346
 347
 348   my ($sql, @bind) =  $self->$method($where, $logic);
 349
 350   # DBIx::Class directly calls _recurse_where in scalar context, so
 351   # we must implement it, even if not in the official API
 352   return wantarray ? ($sql, @bind) : $sql;
 353 }
 354
 355
 356
 357 #======================================================================
 358 # WHERE: top-level ARRAYREF
 359 #======================================================================
 360
 361
 362 sub _where_ARRAYREF {
 363   my ($self, $where, $logic) = @_;
 364
 365   $logic = uc($logic || $self->{logic});
 366   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 367
 368   my @clauses = @$where;
 369
 370   my (@sql_clauses, @all_bind);
 371   # need to use while() so can shift() for pairs
 372   while (my $el = shift @clauses) {
 373
 374     # switch according to kind of $el and get corresponding ($sql, @bind)
 375     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 376
 377       # skip empty elements, otherwise get invalid trailing AND stuff
 378       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 379
 380       ARRAYREFREF => sub { @{${$el}}                 if @{${$el}}},
 381
 382       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 383            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 384            # side-effect: the first hashref within an array would change
 385            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 386            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 387            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 388
 389       SCALARREF => sub { ($$el);                                 },
 390
 391       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 392                         $self->_recurse_where({$el => shift(@clauses)})},
 393
 394       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 395     });
 396
 397     if ($sql) {
 398       push @sql_clauses, $sql;
 399       push @all_bind, @bind;
 400     }
 401   }
 402
 403   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 404 }
 405
 406 #======================================================================
 407 # WHERE: top-level ARRAYREFREF
 408 #======================================================================
 409
 410 sub _where_ARRAYREFREF {
 411     my ($self, $where) = @_;
 412     my ($sql, @bind) = @{${$where}};
 413
 414     return ($sql, @bind);
 415 }
 416
 417 #======================================================================
 418 # WHERE: top-level HASHREF
 419 #======================================================================
 420
 421 sub _where_HASHREF {
 422   my ($self, $where) = @_;
 423   my (@sql_clauses, @all_bind);
 424
 425   for my $k (sort keys %$where) {
 426     my $v = $where->{$k};
 427
 428     # ($k => $v) is either a special op or a regular hashpair
 429     my ($sql, @bind) = ($k =~ /^-(.+)/) ? $self->_where_op_in_hash($1, $v)
 430                                         : do {
 431          my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 432          $self->$method($k, $v);
 433        };
 434
 435     push @sql_clauses, $sql;
 436     push @all_bind, @bind;
 437   }
 438
 439   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 440 }
 441
 442
 443 sub _where_op_in_hash {
 444   my ($self, $op_str, $v) = @_;
 445
 446   $op_str =~ /^ (AND|OR|NEST) ( \_? \d* ) $/xi
 447     or puke "unknown operator: -$op_str";
 448
 449   my $op = uc($1); # uppercase, remove trailing digits
 450   if ($2) {
 451     belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
 452           . "You probably wanted ...-and => [ $op_str => COND1, $op_str => COND2 ... ]";
 453   }
 454
 455   $self->_debug("OP(-$op) within hashref, recursing...");
 456
 457   $self->_SWITCH_refkind($v, {
 458
 459     ARRAYREF => sub {
 460       return $self->_where_ARRAYREF($v, $op eq 'NEST' ? '' : $op);
 461     },
 462
 463     HASHREF => sub {
 464       if ($op eq 'OR') {
 465         return $self->_where_ARRAYREF([ map { $_ => $v->{$_} } (sort keys %$v) ], 'OR');
 466       }
 467       else {                  # NEST | AND
 468         return $self->_where_HASHREF($v);
 469       }
 470     },
 471
 472     SCALARREF  => sub {         # literal SQL
 473       $op eq 'NEST'
 474         or puke "-$op => \\\$scalar not supported, use -nest => ...";
 475       return ($$v);
 476     },
 477
 478     ARRAYREFREF => sub {        # literal SQL
 479       $op eq 'NEST'
 480         or puke "-$op => \\[..] not supported, use -nest => ...";
 481       return @{${$v}};
 482     },
 483
 484     SCALAR => sub { # permissively interpreted as SQL
 485       $op eq 'NEST'
 486         or puke "-$op => 'scalar' not supported, use -nest => \\'scalar'";
 487       belch "literal SQL should be -nest => \\'scalar' "
 488           . "instead of -nest => 'scalar' ";
 489       return ($v);
 490     },
 491
 492     UNDEF => sub {
 493       puke "-$op => undef not supported";
 494     },
 495    });
 496 }
 497
 498
 499 sub _where_hashpair_ARRAYREF {
 500   my ($self, $k, $v) = @_;
 501
 502   if( @$v ) {
 503     my @v = @$v; # need copy because of shift below
 504     $self->_debug("ARRAY($k) means distribute over elements");
 505
 506     # put apart first element if it is an operator (-and, -or)
 507     my $op = (
 508        (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
 509          ? shift @v
 510          : ''
 511     );
 512     my @distributed = map { {$k =>  $_} } @v;
 513
 514     if ($op) {
 515       $self->_debug("OP($op) reinjected into the distributed array");
 516       unshift @distributed, $op;
 517     }
 518
 519     my $logic = $op ? substr($op, 1) : '';
 520
 521     return $self->_recurse_where(\@distributed, $logic);
 522   }
 523   else {
 524     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 525     $self->_debug("empty ARRAY($k) means 0=1");
 526     return ($self->{sqlfalse});
 527   }
 528 }
 529
 530 sub _where_hashpair_HASHREF {
 531   my ($self, $k, $v, $logic) = @_;
 532   $logic ||= 'and';
 533
 534   my ($all_sql, @all_bind);
 535
 536   for my $op (sort keys %$v) {
 537     my $val = $v->{$op};
 538
 539     # put the operator in canonical form
 540     $op =~ s/^-//;       # remove initial dash
 541     $op =~ tr/_/ /;      # underscores become spaces
 542     $op =~ s/^\s+//;     # no initial space
 543     $op =~ s/\s+$//;     # no final space
 544     $op =~ s/\s+/ /;     # multiple spaces become one
 545
 546     my ($sql, @bind);
 547
 548     # CASE: special operators like -in or -between
 549     my $special_op = first {$op =~ $_->{regex}} @{$self->{special_ops}};
 550     if ($special_op) {
 551       my $handler = $special_op->{handler};
 552       if (! $handler) {
 553         puke "No handler supplied for special operator matching $special_op->{regex}";
 554       }
 555       elsif (not ref $handler) {
 556         ($sql, @bind) = $self->$handler ($k, $op, $val);
 557       }
 558       elsif (ref $handler eq 'CODE') {
 559         ($sql, @bind) = $handler->($self, $k, $op, $val);
 560       }
 561       else {
 562         puke "Illegal handler for special operator matching $special_op->{regex} - expecting a method name or a coderef";
 563       }
 564     }
 565     else {
 566       $self->_SWITCH_refkind($val, {
 567
 568         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 569           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 570         },
 571
 572         SCALARREF => sub {      # CASE: col => {op => \$scalar} (literal SQL without bind)
 573           $sql  = join ' ', $self->_convert($self->_quote($k)),
 574                             $self->_sqlcase($op),
 575                             $$val;
 576         },
 577
 578         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 579           my ($sub_sql, @sub_bind) = @$$val;
 580           $self->_assert_bindval_matches_bindtype(@sub_bind);
 581           $sql  = join ' ', $self->_convert($self->_quote($k)),
 582                             $self->_sqlcase($op),
 583                             $sub_sql;
 584           @bind = @sub_bind;
 585         },
 586
 587         HASHREF => sub {
 588           ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $op);
 589         },
 590
 591         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 592           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 593                    ($op =~ $self->{inequality_op}) ? 'is not' :
 594                puke "unexpected operator '$op' with undef operand";
 595           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 596         },
 597
 598         FALLBACK => sub {       # CASE: col => {op => $scalar}
 599           $sql  = join ' ', $self->_convert($self->_quote($k)),
 600                             $self->_sqlcase($op),
 601                             $self->_convert('?');
 602           @bind = $self->_bindtype($k, $val);
 603         },
 604       });
 605     }
 606
 607     ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
 608     push @all_bind, @bind;
 609   }
 610   return ($all_sql, @all_bind);
 611 }
 612
 613
 614
 615 sub _where_field_op_ARRAYREF {
 616   my ($self, $k, $op, $vals) = @_;
 617
 618   my @vals = @$vals;  #always work on a copy
 619
 620   if(@vals) {
 621     $self->_debug("ARRAY($vals) means multiple elements: [ @vals ]");
 622
 623     # see if the first element is an -and/-or op
 624     my $logic;
 625     if ($vals[0] =~ /^ - ( AND|OR ) $/ix) {
 626       $logic = uc $1;
 627       shift @vals;
 628     }
 629
 630     # distribute $op over each remaining member of @vals, append logic if exists
 631     return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 632
 633     # LDNOTE : had planned to change the distribution logic when
 634     # $op =~ $self->{inequality_op}, because of Morgan laws :
 635     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 636     # WHERE field != 22 OR  field != 33 : the user probably means
 637     # WHERE field != 22 AND field != 33.
 638     # To do this, replace the above to roughly :
 639     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 640     # return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 641
 642   }
 643   else {
 644     # try to DWIM on equality operators
 645     # LDNOTE : not 100% sure this is the correct thing to do ...
 646     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 647     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 648
 649     # otherwise
 650     puke "operator '$op' applied on an empty array (field '$k')";
 651   }
 652 }
 653
 654
 655 sub _where_hashpair_SCALARREF {
 656   my ($self, $k, $v) = @_;
 657   $self->_debug("SCALAR($k) means literal SQL: $$v");
 658   my $sql = $self->_quote($k) . " " . $$v;
 659   return ($sql);
 660 }
 661
 662 # literal SQL with bind
 663 sub _where_hashpair_ARRAYREFREF {
 664   my ($self, $k, $v) = @_;
 665   $self->_debug("REF($k) means literal SQL: @${$v}");
 666   my ($sql, @bind) = @${$v};
 667   $self->_assert_bindval_matches_bindtype(@bind);
 668   $sql  = $self->_quote($k) . " " . $sql;
 669   return ($sql, @bind );
 670 }
 671
 672 # literal SQL without bind
 673 sub _where_hashpair_SCALAR {
 674   my ($self, $k, $v) = @_;
 675   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 676   my $sql = join ' ', $self->_convert($self->_quote($k)),
 677                       $self->_sqlcase($self->{cmp}),
 678                       $self->_convert('?');
 679   my @bind =  $self->_bindtype($k, $v);
 680   return ( $sql, @bind);
 681 }
 682
 683
 684 sub _where_hashpair_UNDEF {
 685   my ($self, $k, $v) = @_;
 686   $self->_debug("UNDEF($k) means IS NULL");
 687   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 688   return ($sql);
 689 }
 690
 691 #======================================================================
 692 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 693 #======================================================================
 694
 695
 696 sub _where_SCALARREF {
 697   my ($self, $where) = @_;
 698
 699   # literal sql
 700   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 701   return ($$where);
 702 }
 703
 704
 705 sub _where_SCALAR {
 706   my ($self, $where) = @_;
 707
 708   # literal sql
 709   $self->_debug("NOREF(*top) means literal SQL: $where");
 710   return ($where);
 711 }
 712
 713
 714 sub _where_UNDEF {
 715   my ($self) = @_;
 716   return ();
 717 }
 718
 719
 720 #======================================================================
 721 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 722 #======================================================================
 723
 724
 725 sub _where_field_BETWEEN {
 726   my ($self, $k, $op, $vals) = @_;
 727
 728   (ref $vals eq 'ARRAY' && @$vals == 2) or
 729   (ref $vals eq 'REF' && (@$$vals == 1 || @$$vals == 2 || @$$vals == 3))
 730     or puke "special op 'between' requires an arrayref of two values (or a scalarref or arrayrefref for literal SQL)";
 731
 732   my ($clause, @bind, $label, $and, $placeholder);
 733   $label       = $self->_convert($self->_quote($k));
 734   $and         = ' ' . $self->_sqlcase('and') . ' ';
 735   $placeholder = $self->_convert('?');
 736   $op               = $self->_sqlcase($op);
 737
 738   if (ref $vals eq 'REF') {
 739     ($clause, @bind) = @$$vals;
 740   }
 741   else {
 742     my (@all_sql, @all_bind);
 743
 744     foreach my $val (@$vals) {
 745       my ($sql, @bind) = $self->_SWITCH_refkind($val, {
 746          SCALAR => sub {
 747            return ($placeholder, ($val));
 748          },
 749          SCALARREF => sub {
 750            return ($self->_convert($$val), ());
 751          },
 752       });
 753       push @all_sql, $sql;
 754       push @all_bind, @bind;
 755     }
 756
 757     $clause = (join $and, @all_sql);
 758     @bind = $self->_bindtype($k, @all_bind);
 759   }
 760   my $sql = "( $label $op $clause )";
 761   return ($sql, @bind)
 762 }
 763
 764
 765 sub _where_field_IN {
 766   my ($self, $k, $op, $vals) = @_;
 767
 768   # backwards compatibility : if scalar, force into an arrayref
 769   $vals = [$vals] if defined $vals && ! ref $vals;
 770
 771   my ($label)       = $self->_convert($self->_quote($k));
 772   my ($placeholder) = $self->_convert('?');
 773   $op               = $self->_sqlcase($op);
 774
 775   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
 776     ARRAYREF => sub {     # list of choices
 777       if (@$vals) { # nonempty list
 778         my $placeholders  = join ", ", (($placeholder) x @$vals);
 779         my $sql           = "$label $op ( $placeholders )";
 780         my @bind = $self->_bindtype($k, @$vals);
 781
 782         return ($sql, @bind);
 783       }
 784       else { # empty list : some databases won't understand "IN ()", so DWIM
 785         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
 786         return ($sql);
 787       }
 788     },
 789
 790     ARRAYREFREF => sub {  # literal SQL with bind
 791       my ($sql, @bind) = @$$vals;
 792       $self->_assert_bindval_matches_bindtype(@bind);
 793       return ("$label $op ( $sql )", @bind);
 794     },
 795
 796     FALLBACK => sub {
 797       puke "special op 'in' requires an arrayref (or arrayref-ref)";
 798     },
 799   });
 800
 801   return ($sql, @bind);
 802 }
 803
 804
 805
 806
 807
 808
 809 #======================================================================
 810 # ORDER BY
 811 #======================================================================
 812
 813 sub _order_by {
 814   my ($self, $arg) = @_;
 815
 816   # construct list of ordering instructions
 817   my @order = $self->_SWITCH_refkind($arg, {
 818
 819     ARRAYREF => sub {
 820       map {$self->_SWITCH_refkind($_, {
 821               SCALAR    => sub {$self->_quote($_)},
 822               UNDEF     => sub {},
 823               SCALARREF => sub {$$_}, # literal SQL, no quoting
 824               HASHREF   => sub {$self->_order_by_hash($_)}
 825              }) } @$arg;
 826     },
 827
 828     SCALAR    => sub {$self->_quote($arg)},
 829     UNDEF     => sub {},
 830     SCALARREF => sub {$$arg}, # literal SQL, no quoting
 831     HASHREF   => sub {$self->_order_by_hash($arg)},
 832
 833   });
 834
 835   # build SQL
 836   my $order = join ', ', @order;
 837   return $order ? $self->_sqlcase(' order by')." $order" : '';
 838 }
 839
 840
 841 sub _order_by_hash {
 842   my ($self, $hash) = @_;
 843
 844   # get first pair in hash
 845   my ($key, $val) = each %$hash;
 846
 847   # check if one pair was found and no other pair in hash
 848   $key && !(each %$hash)
 849     or puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
 850
 851   my ($order) = ($key =~ /^-(desc|asc)/i)
 852     or puke "invalid key in _order_by hash : $key";
 853
 854   $val = ref $val eq 'ARRAY' ? $val : [$val];
 855   return join ', ', map { $self->_quote($_) . ' ' . $self->_sqlcase($order) } @$val;
 856 }
 857
 858
 859
 860 #======================================================================
 861 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
 862 #======================================================================
 863
 864 sub _table  {
 865   my $self = shift;
 866   my $from = shift;
 867   $self->_SWITCH_refkind($from, {
 868     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
 869     SCALAR       => sub {$self->_quote($from)},
 870     SCALARREF    => sub {$$from},
 871     ARRAYREFREF  => sub {join ', ', @$from;},
 872   });
 873 }
 874
 875
 876 #======================================================================
 877 # UTILITY FUNCTIONS
 878 #======================================================================
 879
 880 sub _quote {
 881   my $self  = shift;
 882   my $label = shift;
 883
 884   $label or puke "can't quote an empty label";
 885
 886   # left and right quote characters
 887   my ($ql, $qr, @other) = $self->_SWITCH_refkind($self->{quote_char}, {
 888     SCALAR   => sub {($self->{quote_char}, $self->{quote_char})},
 889     ARRAYREF => sub {@{$self->{quote_char}}},
 890     UNDEF    => sub {()},
 891    });
 892   not @other
 893       or puke "quote_char must be an arrayref of 2 values";
 894
 895   # no quoting if no quoting chars
 896   $ql or return $label;
 897
 898   # no quoting for literal SQL
 899   return $$label if ref($label) eq 'SCALAR';
 900
 901   # separate table / column (if applicable)
 902   my $sep = $self->{name_sep} || '';
 903   my @to_quote = $sep ? split /\Q$sep\E/, $label : ($label);
 904
 905   # do the quoting, except for "*" or for `table`.*
 906   my @quoted = map { $_ eq '*' ? $_: $ql.$_.$qr} @to_quote;
 907
 908   # reassemble and return.
 909   return join $sep, @quoted;
 910 }
 911
 912
 913 # Conversion, if applicable
 914 sub _convert ($) {
 915   my ($self, $arg) = @_;
 916
 917 # LDNOTE : modified the previous implementation below because
 918 # it was not consistent : the first "return" is always an array,
 919 # the second "return" is context-dependent. Anyway, _convert
 920 # seems always used with just a single argument, so make it a
 921 # scalar function.
 922 #     return @_ unless $self->{convert};
 923 #     my $conv = $self->_sqlcase($self->{convert});
 924 #     my @ret = map { $conv.'('.$_.')' } @_;
 925 #     return wantarray ? @ret : $ret[0];
 926   if ($self->{convert}) {
 927     my $conv = $self->_sqlcase($self->{convert});
 928     $arg = $conv.'('.$arg.')';
 929   }
 930   return $arg;
 931 }
 932
 933 # And bindtype
 934 sub _bindtype (@) {
 935   my $self = shift;
 936   my($col, @vals) = @_;
 937
 938   #LDNOTE : changed original implementation below because it did not make
 939   # sense when bindtype eq 'columns' and @vals > 1.
 940 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
 941
 942   return $self->{bindtype} eq 'columns' ? map {[$col, $_]} @vals : @vals;
 943 }
 944
 945 # Dies if any element of @bind is not in [colname => value] format
 946 # if bindtype is 'columns'.
 947 sub _assert_bindval_matches_bindtype {
 948   my ($self, @bind) = @_;
 949
 950   if ($self->{bindtype} eq 'columns') {
 951     foreach my $val (@bind) {
 952       if (!defined $val || ref($val) ne 'ARRAY' || @$val != 2) {
 953         die "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
 954       }
 955     }
 956   }
 957 }
 958
 959 sub _join_sql_clauses {
 960   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
 961
 962   if (@$clauses_aref > 1) {
 963     my $join  = " " . $self->_sqlcase($logic) . " ";
 964     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
 965     return ($sql, @$bind_aref);
 966   }
 967   elsif (@$clauses_aref) {
 968     return ($clauses_aref->[0], @$bind_aref); # no parentheses
 969   }
 970   else {
 971     return (); # if no SQL, ignore @$bind_aref
 972   }
 973 }
 974
 975
 976 # Fix SQL case, if so requested
 977 sub _sqlcase {
 978   my $self = shift;
 979
 980   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
 981   # don't touch the argument ... crooked logic, but let's not change it!
 982   return $self->{case} ? $_[0] : uc($_[0]);
 983 }
 984
 985
 986 #======================================================================
 987 # DISPATCHING FROM REFKIND
 988 #======================================================================
 989
 990 sub _refkind {
 991   my ($self, $data) = @_;
 992   my $suffix = '';
 993   my $ref;
 994   my $n_steps = 0;
 995
 996   while (1) {
 997     # blessed objects are treated like scalars
 998     $ref = (blessed $data) ? '' : ref $data;
 999     $n_steps += 1 if $ref;
1000     last          if $ref ne 'REF';
1001     $data = $$data;
1002   }
1003
1004   my $base = $ref || (defined $data ? 'SCALAR' : 'UNDEF');
1005
1006   return $base . ('REF' x $n_steps);
1007 }
1008
1009
1010
1011 sub _try_refkind {
1012   my ($self, $data) = @_;
1013   my @try = ($self->_refkind($data));
1014   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1015   push @try, 'FALLBACK';
1016   return @try;
1017 }
1018
1019 sub _METHOD_FOR_refkind {
1020   my ($self, $meth_prefix, $data) = @_;
1021   my $method = first {$_} map {$self->can($meth_prefix."_".$_)}
1022                               $self->_try_refkind($data)
1023     or puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1024   return $method;
1025 }
1026
1027
1028 sub _SWITCH_refkind {
1029   my ($self, $data, $dispatch_table) = @_;
1030
1031   my $coderef = first {$_} map {$dispatch_table->{$_}}
1032                                $self->_try_refkind($data)
1033     or puke "no dispatch entry for ".$self->_refkind($data);
1034   $coderef->();
1035 }
1036
1037
1038
1039
1040 #======================================================================
1041 # VALUES, GENERATE, AUTOLOAD
1042 #======================================================================
1043
1044 # LDNOTE: original code from nwiger, didn't touch code in that section
1045 # I feel the AUTOLOAD stuff should not be the default, it should
1046 # only be activated on explicit demand by user.
1047
1048 sub values {
1049     my $self = shift;
1050     my $data = shift || return;
1051     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1052         unless ref $data eq 'HASH';
1053
1054     my @all_bind;
1055     foreach my $k ( sort keys %$data ) {
1056         my $v = $data->{$k};
1057         $self->_SWITCH_refkind($v, {
1058           ARRAYREF => sub {
1059             if ($self->{array_datatypes}) { # array datatype
1060               push @all_bind, $self->_bindtype($k, $v);
1061             }
1062             else {                          # literal SQL with bind
1063               my ($sql, @bind) = @$v;
1064               $self->_assert_bindval_matches_bindtype(@bind);
1065               push @all_bind, @bind;
1066             }
1067           },
1068           ARRAYREFREF => sub { # literal SQL with bind
1069             my ($sql, @bind) = @${$v};
1070             $self->_assert_bindval_matches_bindtype(@bind);
1071             push @all_bind, @bind;
1072           },
1073           SCALARREF => sub {  # literal SQL without bind
1074           },
1075           SCALAR_or_UNDEF => sub {
1076             push @all_bind, $self->_bindtype($k, $v);
1077           },
1078         });
1079     }
1080
1081     return @all_bind;
1082 }
1083
1084 sub generate {
1085     my $self  = shift;
1086
1087     my(@sql, @sqlq, @sqlv);
1088
1089     for (@_) {
1090         my $ref = ref $_;
1091         if ($ref eq 'HASH') {
1092             for my $k (sort keys %$_) {
1093                 my $v = $_->{$k};
1094                 my $r = ref $v;
1095                 my $label = $self->_quote($k);
1096                 if ($r eq 'ARRAY') {
1097                     # literal SQL with bind
1098                     my ($sql, @bind) = @$v;
1099                     $self->_assert_bindval_matches_bindtype(@bind);
1100                     push @sqlq, "$label = $sql";
1101                     push @sqlv, @bind;
1102                 } elsif ($r eq 'SCALAR') {
1103                     # literal SQL without bind
1104                     push @sqlq, "$label = $$v";
1105                 } else {
1106                     push @sqlq, "$label = ?";
1107                     push @sqlv, $self->_bindtype($k, $v);
1108                 }
1109             }
1110             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1111         } elsif ($ref eq 'ARRAY') {
1112             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1113             for my $v (@$_) {
1114                 my $r = ref $v;
1115                 if ($r eq 'ARRAY') {   # literal SQL with bind
1116                     my ($sql, @bind) = @$v;
1117                     $self->_assert_bindval_matches_bindtype(@bind);
1118                     push @sqlq, $sql;
1119                     push @sqlv, @bind;
1120                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1121                     # embedded literal SQL
1122                     push @sqlq, $$v;
1123                 } else {
1124                     push @sqlq, '?';
1125                     push @sqlv, $v;
1126                 }
1127             }
1128             push @sql, '(' . join(', ', @sqlq) . ')';
1129         } elsif ($ref eq 'SCALAR') {
1130             # literal SQL
1131             push @sql, $$_;
1132         } else {
1133             # strings get case twiddled
1134             push @sql, $self->_sqlcase($_);
1135         }
1136     }
1137
1138     my $sql = join ' ', @sql;
1139
1140     # this is pretty tricky
1141     # if ask for an array, return ($stmt, @bind)
1142     # otherwise, s/?/shift @sqlv/ to put it inline
1143     if (wantarray) {
1144         return ($sql, @sqlv);
1145     } else {
1146         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1147                              ref $d ? $d->[1] : $d/e;
1148         return $sql;
1149     }
1150 }
1151
1152
1153 sub DESTROY { 1 }
1154
1155 sub AUTOLOAD {
1156     # This allows us to check for a local, then _form, attr
1157     my $self = shift;
1158     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1159     return $self->generate($name, @_);
1160 }
1161
1162 1;
1163
1164
1165
1166 __END__
1167
1168 =head1 NAME
1169
1170 SQL::Abstract - Generate SQL from Perl data structures
1171
1172 =head1 SYNOPSIS
1173
1174     use SQL::Abstract;
1175
1176     my $sql = SQL::Abstract->new;
1177
1178     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1179
1180     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1181
1182     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1183
1184     my($stmt, @bind) = $sql->delete($table, \%where);
1185
1186     # Then, use these in your DBI statements
1187     my $sth = $dbh->prepare($stmt);
1188     $sth->execute(@bind);
1189
1190     # Just generate the WHERE clause
1191     my($stmt, @bind) = $sql->where(\%where, \@order);
1192
1193     # Return values in the same order, for hashed queries
1194     # See PERFORMANCE section for more details
1195     my @bind = $sql->values(\%fieldvals);
1196
1197 =head1 DESCRIPTION
1198
1199 This module was inspired by the excellent L<DBIx::Abstract>.
1200 However, in using that module I found that what I really wanted
1201 to do was generate SQL, but still retain complete control over my
1202 statement handles and use the DBI interface. So, I set out to
1203 create an abstract SQL generation module.
1204
1205 While based on the concepts used by L<DBIx::Abstract>, there are
1206 several important differences, especially when it comes to WHERE
1207 clauses. I have modified the concepts used to make the SQL easier
1208 to generate from Perl data structures and, IMO, more intuitive.
1209 The underlying idea is for this module to do what you mean, based
1210 on the data structures you provide it. The big advantage is that
1211 you don't have to modify your code every time your data changes,
1212 as this module figures it out.
1213
1214 To begin with, an SQL INSERT is as easy as just specifying a hash
1215 of C<key=value> pairs:
1216
1217     my %data = (
1218         name => 'Jimbo Bobson',
1219         phone => '123-456-7890',
1220         address => '42 Sister Lane',
1221         city => 'St. Louis',
1222         state => 'Louisiana',
1223     );
1224
1225 The SQL can then be generated with this:
1226
1227     my($stmt, @bind) = $sql->insert('people', \%data);
1228
1229 Which would give you something like this:
1230
1231     $stmt = "INSERT INTO people
1232                     (address, city, name, phone, state)
1233                     VALUES (?, ?, ?, ?, ?)";
1234     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1235              '123-456-7890', 'Louisiana');
1236
1237 These are then used directly in your DBI code:
1238
1239     my $sth = $dbh->prepare($stmt);
1240     $sth->execute(@bind);
1241
1242 =head2 Inserting and Updating Arrays
1243
1244 If your database has array types (like for example Postgres),
1245 activate the special option C<< array_datatypes => 1 >>
1246 when creating the C<SQL::Abstract> object.
1247 Then you may use an arrayref to insert and update database array types:
1248
1249     my $sql = SQL::Abstract->new(array_datatypes => 1);
1250     my %data = (
1251         planets => [qw/Mercury Venus Earth Mars/]
1252     );
1253
1254     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1255
1256 This results in:
1257
1258     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1259
1260     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1261
1262
1263 =head2 Inserting and Updating SQL
1264
1265 In order to apply SQL functions to elements of your C<%data> you may
1266 specify a reference to an arrayref for the given hash value. For example,
1267 if you need to execute the Oracle C<to_date> function on a value, you can
1268 say something like this:
1269
1270     my %data = (
1271         name => 'Bill',
1272         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1273     );
1274
1275 The first value in the array is the actual SQL. Any other values are
1276 optional and would be included in the bind values array. This gives
1277 you:
1278
1279     my($stmt, @bind) = $sql->insert('people', \%data);
1280
1281     $stmt = "INSERT INTO people (name, date_entered)
1282                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1283     @bind = ('Bill', '03/02/2003');
1284
1285 An UPDATE is just as easy, all you change is the name of the function:
1286
1287     my($stmt, @bind) = $sql->update('people', \%data);
1288
1289 Notice that your C<%data> isn't touched; the module will generate
1290 the appropriately quirky SQL for you automatically. Usually you'll
1291 want to specify a WHERE clause for your UPDATE, though, which is
1292 where handling C<%where> hashes comes in handy...
1293
1294 =head2 Complex where statements
1295
1296 This module can generate pretty complicated WHERE statements
1297 easily. For example, simple C<key=value> pairs are taken to mean
1298 equality, and if you want to see if a field is within a set
1299 of values, you can use an arrayref. Let's say we wanted to
1300 SELECT some data based on this criteria:
1301
1302     my %where = (
1303        requestor => 'inna',
1304        worker => ['nwiger', 'rcwe', 'sfz'],
1305        status => { '!=', 'completed' }
1306     );
1307
1308     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1309
1310 The above would give you something like this:
1311
1312     $stmt = "SELECT * FROM tickets WHERE
1313                 ( requestor = ? ) AND ( status != ? )
1314                 AND ( worker = ? OR worker = ? OR worker = ? )";
1315     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1316
1317 Which you could then use in DBI code like so:
1318
1319     my $sth = $dbh->prepare($stmt);
1320     $sth->execute(@bind);
1321
1322 Easy, eh?
1323
1324 =head1 FUNCTIONS
1325
1326 The functions are simple. There's one for each major SQL operation,
1327 and a constructor you use first. The arguments are specified in a
1328 similar order to each function (table, then fields, then a where
1329 clause) to try and simplify things.
1330
1331
1332
1333
1334 =head2 new(option => 'value')
1335
1336 The C<new()> function takes a list of options and values, and returns
1337 a new B<SQL::Abstract> object which can then be used to generate SQL
1338 through the methods below. The options accepted are:
1339
1340 =over
1341
1342 =item case
1343
1344 If set to 'lower', then SQL will be generated in all lowercase. By
1345 default SQL is generated in "textbook" case meaning something like:
1346
1347     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1348
1349 Any setting other than 'lower' is ignored.
1350
1351 =item cmp
1352
1353 This determines what the default comparison operator is. By default
1354 it is C<=>, meaning that a hash like this:
1355
1356     %where = (name => 'nwiger', email => 'nate@wiger.org');
1357
1358 Will generate SQL like this:
1359
1360     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1361
1362 However, you may want loose comparisons by default, so if you set
1363 C<cmp> to C<like> you would get SQL such as:
1364
1365     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1366
1367 You can also override the comparsion on an individual basis - see
1368 the huge section on L</"WHERE CLAUSES"> at the bottom.
1369
1370 =item sqltrue, sqlfalse
1371
1372 Expressions for inserting boolean values within SQL statements.
1373 By default these are C<1=1> and C<1=0>. They are used
1374 by the special operators C<-in> and C<-not_in> for generating
1375 correct SQL even when the argument is an empty array (see below).
1376
1377 =item logic
1378
1379 This determines the default logical operator for multiple WHERE
1380 statements in arrays or hashes. If absent, the default logic is "or"
1381 for arrays, and "and" for hashes. This means that a WHERE
1382 array of the form:
1383
1384     @where = (
1385         event_date => {'>=', '2/13/99'},
1386         event_date => {'<=', '4/24/03'},
1387     );
1388
1389 will generate SQL like this:
1390
1391     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1392
1393 This is probably not what you want given this query, though (look
1394 at the dates). To change the "OR" to an "AND", simply specify:
1395
1396     my $sql = SQL::Abstract->new(logic => 'and');
1397
1398 Which will change the above C<WHERE> to:
1399
1400     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1401
1402 The logic can also be changed locally by inserting
1403 a modifier in front of an arrayref :
1404
1405     @where = (-and => [event_date => {'>=', '2/13/99'},
1406                        event_date => {'<=', '4/24/03'} ]);
1407
1408 See the L</"WHERE CLAUSES"> section for explanations.
1409
1410 =item convert
1411
1412 This will automatically convert comparisons using the specified SQL
1413 function for both column and value. This is mostly used with an argument
1414 of C<upper> or C<lower>, so that the SQL will have the effect of
1415 case-insensitive "searches". For example, this:
1416
1417     $sql = SQL::Abstract->new(convert => 'upper');
1418     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1419
1420 Will turn out the following SQL:
1421
1422     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1423
1424 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1425 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1426 not validate this option; it will just pass through what you specify verbatim).
1427
1428 =item bindtype
1429
1430 This is a kludge because many databases suck. For example, you can't
1431 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1432 Instead, you have to use C<bind_param()>:
1433
1434     $sth->bind_param(1, 'reg data');
1435     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1436
1437 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1438 which loses track of which field each slot refers to. Fear not.
1439
1440 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1441 Currently, you can specify either C<normal> (default) or C<columns>. If you
1442 specify C<columns>, you will get an array that looks like this:
1443
1444     my $sql = SQL::Abstract->new(bindtype => 'columns');
1445     my($stmt, @bind) = $sql->insert(...);
1446
1447     @bind = (
1448         [ 'column1', 'value1' ],
1449         [ 'column2', 'value2' ],
1450         [ 'column3', 'value3' ],
1451     );
1452
1453 You can then iterate through this manually, using DBI's C<bind_param()>.
1454
1455     $sth->prepare($stmt);
1456     my $i = 1;
1457     for (@bind) {
1458         my($col, $data) = @$_;
1459         if ($col eq 'details' || $col eq 'comments') {
1460             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1461         } elsif ($col eq 'image') {
1462             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1463         } else {
1464             $sth->bind_param($i, $data);
1465         }
1466         $i++;
1467     }
1468     $sth->execute;      # execute without @bind now
1469
1470 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1471 Basically, the advantage is still that you don't have to care which fields
1472 are or are not included. You could wrap that above C<for> loop in a simple
1473 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1474 get a layer of abstraction over manual SQL specification.
1475
1476 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1477 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1478 will expect the bind values in this format.
1479
1480 =item quote_char
1481
1482 This is the character that a table or column name will be quoted
1483 with.  By default this is an empty string, but you could set it to
1484 the character C<`>, to generate SQL like this:
1485
1486   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1487
1488 Alternatively, you can supply an array ref of two items, the first being the left
1489 hand quote character, and the second the right hand quote character. For
1490 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1491 that generates SQL like this:
1492
1493   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1494
1495 Quoting is useful if you have tables or columns names that are reserved
1496 words in your database's SQL dialect.
1497
1498 =item name_sep
1499
1500 This is the character that separates a table and column name.  It is
1501 necessary to specify this when the C<quote_char> option is selected,
1502 so that tables and column names can be individually quoted like this:
1503
1504   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1505
1506 =item array_datatypes
1507
1508 When this option is true, arrayrefs in INSERT or UPDATE are
1509 interpreted as array datatypes and are passed directly
1510 to the DBI layer.
1511 When this option is false, arrayrefs are interpreted
1512 as literal SQL, just like refs to arrayrefs
1513 (but this behavior is for backwards compatibility; when writing
1514 new queries, use the "reference to arrayref" syntax
1515 for literal SQL).
1516
1517
1518 =item special_ops
1519
1520 Takes a reference to a list of "special operators"
1521 to extend the syntax understood by L<SQL::Abstract>.
1522 See section L</"SPECIAL OPERATORS"> for details.
1523
1524
1525
1526 =back
1527
1528 =head2 insert($table, \@values || \%fieldvals)
1529
1530 This is the simplest function. You simply give it a table name
1531 and either an arrayref of values or hashref of field/value pairs.
1532 It returns an SQL INSERT statement and a list of bind values.
1533 See the sections on L</"Inserting and Updating Arrays"> and
1534 L</"Inserting and Updating SQL"> for information on how to insert
1535 with those data types.
1536
1537 =head2 update($table, \%fieldvals, \%where)
1538
1539 This takes a table, hashref of field/value pairs, and an optional
1540 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1541 of bind values.
1542 See the sections on L</"Inserting and Updating Arrays"> and
1543 L</"Inserting and Updating SQL"> for information on how to insert
1544 with those data types.
1545
1546 =head2 select($source, $fields, $where, $order)
1547
1548 This returns a SQL SELECT statement and associated list of bind values, as
1549 specified by the arguments  :
1550
1551 =over
1552
1553 =item $source
1554
1555 Specification of the 'FROM' part of the statement.
1556 The argument can be either a plain scalar (interpreted as a table
1557 name, will be quoted), or an arrayref (interpreted as a list
1558 of table names, joined by commas, quoted), or a scalarref
1559 (literal table name, not quoted), or a ref to an arrayref
1560 (list of literal table names, joined by commas, not quoted).
1561
1562 =item $fields
1563
1564 Specification of the list of fields to retrieve from
1565 the source.
1566 The argument can be either an arrayref (interpreted as a list
1567 of field names, will be joined by commas and quoted), or a
1568 plain scalar (literal SQL, not quoted).
1569 Please observe that this API is not as flexible as for
1570 the first argument C<$table>, for backwards compatibility reasons.
1571
1572 =item $where
1573
1574 Optional argument to specify the WHERE part of the query.
1575 The argument is most often a hashref, but can also be
1576 an arrayref or plain scalar --
1577 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1578
1579 =item $order
1580
1581 Optional argument to specify the ORDER BY part of the query.
1582 The argument can be a scalar, a hashref or an arrayref
1583 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1584 for details.
1585
1586 =back
1587
1588
1589 =head2 delete($table, \%where)
1590
1591 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1592 It returns an SQL DELETE statement and list of bind values.
1593
1594 =head2 where(\%where, \@order)
1595
1596 This is used to generate just the WHERE clause. For example,
1597 if you have an arbitrary data structure and know what the
1598 rest of your SQL is going to look like, but want an easy way
1599 to produce a WHERE clause, use this. It returns an SQL WHERE
1600 clause and list of bind values.
1601
1602
1603 =head2 values(\%data)
1604
1605 This just returns the values from the hash C<%data>, in the same
1606 order that would be returned from any of the other above queries.
1607 Using this allows you to markedly speed up your queries if you
1608 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1609
1610 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1611
1612 Warning: This is an experimental method and subject to change.
1613
1614 This returns arbitrarily generated SQL. It's a really basic shortcut.
1615 It will return two different things, depending on return context:
1616
1617     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1618     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
1619
1620 These would return the following:
1621
1622     # First calling form
1623     $stmt = "CREATE TABLE test (?, ?)";
1624     @bind = (field1, field2);
1625
1626     # Second calling form
1627     $stmt_and_val = "CREATE TABLE test (field1, field2)";
1628
1629 Depending on what you're trying to do, it's up to you to choose the correct
1630 format. In this example, the second form is what you would want.
1631
1632 By the same token:
1633
1634     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
1635
1636 Might give you:
1637
1638     ALTER SESSION SET nls_date_format = 'MM/YY'
1639
1640 You get the idea. Strings get their case twiddled, but everything
1641 else remains verbatim.
1642
1643
1644
1645
1646 =head1 WHERE CLAUSES
1647
1648 =head2 Introduction
1649
1650 This module uses a variation on the idea from L<DBIx::Abstract>. It
1651 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
1652 module is that things in arrays are OR'ed, and things in hashes
1653 are AND'ed.>
1654
1655 The easiest way to explain is to show lots of examples. After
1656 each C<%where> hash shown, it is assumed you used:
1657
1658     my($stmt, @bind) = $sql->where(\%where);
1659
1660 However, note that the C<%where> hash can be used directly in any
1661 of the other functions as well, as described above.
1662
1663 =head2 Key-value pairs
1664
1665 So, let's get started. To begin, a simple hash:
1666
1667     my %where  = (
1668         user   => 'nwiger',
1669         status => 'completed'
1670     );
1671
1672 Is converted to SQL C<key = val> statements:
1673
1674     $stmt = "WHERE user = ? AND status = ?";
1675     @bind = ('nwiger', 'completed');
1676
1677 One common thing I end up doing is having a list of values that
1678 a field can be in. To do this, simply specify a list inside of
1679 an arrayref:
1680
1681     my %where  = (
1682         user   => 'nwiger',
1683         status => ['assigned', 'in-progress', 'pending'];
1684     );
1685
1686 This simple code will create the following:
1687
1688     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
1689     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
1690
1691 A field associated to an empty arrayref will be considered a
1692 logical false and will generate 0=1.
1693
1694 =head2 Specific comparison operators
1695
1696 If you want to specify a different type of operator for your comparison,
1697 you can use a hashref for a given column:
1698
1699     my %where  = (
1700         user   => 'nwiger',
1701         status => { '!=', 'completed' }
1702     );
1703
1704 Which would generate:
1705
1706     $stmt = "WHERE user = ? AND status != ?";
1707     @bind = ('nwiger', 'completed');
1708
1709 To test against multiple values, just enclose the values in an arrayref:
1710
1711     status => { '=', ['assigned', 'in-progress', 'pending'] };
1712
1713 Which would give you:
1714
1715     "WHERE status = ? OR status = ? OR status = ?"
1716
1717
1718 The hashref can also contain multiple pairs, in which case it is expanded
1719 into an C<AND> of its elements:
1720
1721     my %where  = (
1722         user   => 'nwiger',
1723         status => { '!=', 'completed', -not_like => 'pending%' }
1724     );
1725
1726     # Or more dynamically, like from a form
1727     $where{user} = 'nwiger';
1728     $where{status}{'!='} = 'completed';
1729     $where{status}{'-not_like'} = 'pending%';
1730
1731     # Both generate this
1732     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
1733     @bind = ('nwiger', 'completed', 'pending%');
1734
1735
1736 To get an OR instead, you can combine it with the arrayref idea:
1737
1738     my %where => (
1739          user => 'nwiger',
1740          priority => [ {'=', 2}, {'!=', 1} ]
1741     );
1742
1743 Which would generate:
1744
1745     $stmt = "WHERE user = ? AND priority = ? OR priority != ?";
1746     @bind = ('nwiger', '2', '1');
1747
1748 If you want to include literal SQL (with or without bind values), just use a
1749 scalar reference or array reference as the value:
1750
1751     my %where  = (
1752         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
1753         date_expires => { '<' => \"now()" }
1754     );
1755
1756 Which would generate:
1757
1758     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
1759     @bind = ('11/26/2008');
1760
1761
1762 =head2 Logic and nesting operators
1763
1764 In the example above,
1765 there is a subtle trap if you want to say something like
1766 this (notice the C<AND>):
1767
1768     WHERE priority != ? AND priority != ?
1769
1770 Because, in Perl you I<can't> do this:
1771
1772     priority => { '!=', 2, '!=', 1 }
1773
1774 As the second C<!=> key will obliterate the first. The solution
1775 is to use the special C<-modifier> form inside an arrayref:
1776
1777     priority => [ -and => {'!=', 2},
1778                           {'!=', 1} ]
1779
1780
1781 Normally, these would be joined by C<OR>, but the modifier tells it
1782 to use C<AND> instead. (Hint: You can use this in conjunction with the
1783 C<logic> option to C<new()> in order to change the way your queries
1784 work by default.) B<Important:> Note that the C<-modifier> goes
1785 B<INSIDE> the arrayref, as an extra first element. This will
1786 B<NOT> do what you think it might:
1787
1788     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
1789
1790 Here is a quick list of equivalencies, since there is some overlap:
1791
1792     # Same
1793     status => {'!=', 'completed', 'not like', 'pending%' }
1794     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
1795
1796     # Same
1797     status => {'=', ['assigned', 'in-progress']}
1798     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
1799     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
1800
1801
1802
1803 =head2 Special operators : IN, BETWEEN, etc.
1804
1805 You can also use the hashref format to compare a list of fields using the
1806 C<IN> comparison operator, by specifying the list as an arrayref:
1807
1808     my %where  = (
1809         status   => 'completed',
1810         reportid => { -in => [567, 2335, 2] }
1811     );
1812
1813 Which would generate:
1814
1815     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
1816     @bind = ('completed', '567', '2335', '2');
1817
1818 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
1819 the same way.
1820
1821 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
1822 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
1823 'sqltrue' (by default : C<1=1>).
1824
1825
1826
1827 Another pair of operators is C<-between> and C<-not_between>,
1828 used with an arrayref of two values:
1829
1830     my %where  = (
1831         user   => 'nwiger',
1832         completion_date => {
1833            -not_between => ['2002-10-01', '2003-02-06']
1834         }
1835     );
1836
1837 Would give you:
1838
1839     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
1840
1841 These are the two builtin "special operators"; but the
1842 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
1843
1844 =head2 Nested conditions, -and/-or prefixes
1845
1846 So far, we've seen how multiple conditions are joined with a top-level
1847 C<AND>.  We can change this by putting the different conditions we want in
1848 hashes and then putting those hashes in an array. For example:
1849
1850     my @where = (
1851         {
1852             user   => 'nwiger',
1853             status => { -like => ['pending%', 'dispatched'] },
1854         },
1855         {
1856             user   => 'robot',
1857             status => 'unassigned',
1858         }
1859     );
1860
1861 This data structure would create the following:
1862
1863     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
1864                 OR ( user = ? AND status = ? ) )";
1865     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
1866
1867
1868 There is also a special C<-nest>
1869 operator which adds an additional set of parens, to create a subquery.
1870 For example, to get something like this:
1871
1872     $stmt = "WHERE user = ? AND ( workhrs > ? OR geo = ? )";
1873     @bind = ('nwiger', '20', 'ASIA');
1874
1875 You would do:
1876
1877     my %where = (
1878          user => 'nwiger',
1879         -nest => [ workhrs => {'>', 20}, geo => 'ASIA' ],
1880     );
1881
1882
1883 Finally, clauses in hashrefs or arrayrefs can be
1884 prefixed with an C<-and> or C<-or> to change the logic
1885 inside :
1886
1887     my @where = (
1888          -and => [
1889             user => 'nwiger',
1890             -nest => [
1891                 -and => [workhrs => {'>', 20}, geo => 'ASIA' ],
1892                 -and => [workhrs => {'<', 50}, geo => 'EURO' ]
1893             ],
1894         ],
1895     );
1896
1897 That would yield:
1898
1899     WHERE ( user = ? AND
1900           ( ( workhrs > ? AND geo = ? )
1901          OR ( workhrs < ? AND geo = ? ) ) )
1902
1903
1904 =head2 Algebraic inconsistency, for historical reasons
1905
1906 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
1907 operator goes C<outside> of the nested structure; whereas when connecting
1908 several constraints on one column, the C<-and> operator goes
1909 C<inside> the arrayref. Here is an example combining both features :
1910
1911    my @where = (
1912      -and => [a => 1, b => 2],
1913      -or  => [c => 3, d => 4],
1914       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
1915    )
1916
1917 yielding
1918
1919   WHERE ( (    ( a = ? AND b = ? )
1920             OR ( c = ? OR d = ? )
1921             OR ( e LIKE ? AND e LIKE ? ) ) )
1922
1923 This difference in syntax is unfortunate but must be preserved for
1924 historical reasons. So be careful : the two examples below would
1925 seem algebraically equivalent, but they are not
1926
1927   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
1928   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
1929
1930   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
1931   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
1932
1933
1934 =head2 Literal SQL
1935
1936 Finally, sometimes only literal SQL will do. If you want to include
1937 literal SQL verbatim, you can specify it as a scalar reference, namely:
1938
1939     my $inn = 'is Not Null';
1940     my %where = (
1941         priority => { '<', 2 },
1942         requestor => \$inn
1943     );
1944
1945 This would create:
1946
1947     $stmt = "WHERE priority < ? AND requestor is Not Null";
1948     @bind = ('2');
1949
1950 Note that in this example, you only get one bind parameter back, since
1951 the verbatim SQL is passed as part of the statement.
1952
1953 Of course, just to prove a point, the above can also be accomplished
1954 with this:
1955
1956     my %where = (
1957         priority  => { '<', 2 },
1958         requestor => { '!=', undef },
1959     );
1960
1961
1962 TMTOWTDI.
1963
1964 Conditions on boolean columns can be expressed in the
1965 same way, passing a reference to an empty string :
1966
1967     my %where = (
1968         priority  => { '<', 2 },
1969         is_ready  => \"";
1970     );
1971
1972 which yields
1973
1974     $stmt = "WHERE priority < ? AND is_ready";
1975     @bind = ('2');
1976
1977
1978 =head2 Literal SQL with placeholders and bind values (subqueries)
1979
1980 If the literal SQL to be inserted has placeholders and bind values,
1981 use a reference to an arrayref (yes this is a double reference --
1982 not so common, but perfectly legal Perl). For example, to find a date
1983 in Postgres you can use something like this:
1984
1985     my %where = (
1986        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
1987     )
1988
1989 This would create:
1990
1991     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
1992     @bind = ('10');
1993
1994 Note that you must pass the bind values in the same format as they are returned
1995 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
1996 provide the bind values in the C<< [ column_meta => value ] >> format, where
1997 C<column_meta> is an opaque scalar value; most commonly the column name, but
1998 you can use any scalar value (including references and blessed references),
1999 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
2000 to C<columns> the above example will look like:
2001
2002     my %where = (
2003        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
2004     )
2005
2006 Literal SQL is especially useful for nesting parenthesized clauses in the
2007 main SQL query. Here is a first example :
2008
2009   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2010                                100, "foo%");
2011   my %where = (
2012     foo => 1234,
2013     bar => \["IN ($sub_stmt)" => @sub_bind],
2014   );
2015
2016 This yields :
2017
2018   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2019                                              WHERE c2 < ? AND c3 LIKE ?))";
2020   @bind = (1234, 100, "foo%");
2021
2022 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2023 are expressed in the same way. Of course the C<$sub_stmt> and
2024 its associated bind values can be generated through a former call
2025 to C<select()> :
2026
2027   my ($sub_stmt, @sub_bind)
2028      = $sql->select("t1", "c1", {c2 => {"<" => 100},
2029                                  c3 => {-like => "foo%"}});
2030   my %where = (
2031     foo => 1234,
2032     bar => \["> ALL ($sub_stmt)" => @sub_bind],
2033   );
2034
2035 In the examples above, the subquery was used as an operator on a column;
2036 but the same principle also applies for a clause within the main C<%where>
2037 hash, like an EXISTS subquery :
2038
2039   my ($sub_stmt, @sub_bind)
2040      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2041   my %where = (
2042     foo   => 1234,
2043     -nest => \["EXISTS ($sub_stmt)" => @sub_bind],
2044   );
2045
2046 which yields
2047
2048   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2049                                         WHERE c1 = ? AND c2 > t0.c0))";
2050   @bind = (1234, 1);
2051
2052
2053 Observe that the condition on C<c2> in the subquery refers to
2054 column C<t0.c0> of the main query : this is I<not> a bind
2055 value, so we have to express it through a scalar ref.
2056 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2057 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2058 what we wanted here.
2059
2060 Another use of the subquery technique is when some SQL clauses need
2061 parentheses, as it often occurs with some proprietary SQL extensions
2062 like for example fulltext expressions, geospatial expressions,
2063 NATIVE clauses, etc. Here is an example of a fulltext query in MySQL :
2064
2065   my %where = (
2066     -nest => \["MATCH (col1, col2) AGAINST (?)" => qw/apples/]
2067   );
2068
2069 Finally, here is an example where a subquery is used
2070 for expressing unary negation:
2071
2072   my ($sub_stmt, @sub_bind)
2073      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2074   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2075   my %where = (
2076         lname  => {like => '%son%'},
2077         -nest  => \["NOT ($sub_stmt)" => @sub_bind],
2078     );
2079
2080 This yields
2081
2082   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2083   @bind = ('%son%', 10, 20)
2084
2085
2086
2087 =head2 Conclusion
2088
2089 These pages could go on for a while, since the nesting of the data
2090 structures this module can handle are pretty much unlimited (the
2091 module implements the C<WHERE> expansion as a recursive function
2092 internally). Your best bet is to "play around" with the module a
2093 little to see how the data structures behave, and choose the best
2094 format for your data based on that.
2095
2096 And of course, all the values above will probably be replaced with
2097 variables gotten from forms or the command line. After all, if you
2098 knew everything ahead of time, you wouldn't have to worry about
2099 dynamically-generating SQL and could just hardwire it into your
2100 script.
2101
2102
2103
2104
2105 =head1 ORDER BY CLAUSES
2106
2107 Some functions take an order by clause. This can either be a scalar (just a
2108 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2109 or an array of either of the two previous forms. Examples:
2110
2111                Given            |         Will Generate
2112     ----------------------------------------------------------
2113                                 |
2114     \'colA DESC'                | ORDER BY colA DESC
2115                                 |
2116     'colA'                      | ORDER BY colA
2117                                 |
2118     [qw/colA colB/]             | ORDER BY colA, colB
2119                                 |
2120     {-asc  => 'colA'}           | ORDER BY colA ASC
2121                                 |
2122     {-desc => 'colB'}           | ORDER BY colB DESC
2123                                 |
2124     ['colA', {-asc => 'colB'}]  | ORDER BY colA, colB ASC
2125                                 |
2126     { -asc => [qw/colA colB] }  | ORDER BY colA ASC, colB ASC
2127                                 |
2128     [                           |
2129       { -asc => 'colA' },       | ORDER BY colA ASC, colB DESC,
2130       { -desc => [qw/colB/],    |          colC ASC, colD ASC
2131       { -asc => [qw/colC colD/],|
2132     ]                           |
2133     ===========================================================
2134
2135
2136
2137 =head1 SPECIAL OPERATORS
2138
2139   my $sqlmaker = SQL::Abstract->new(special_ops => [
2140      {
2141       regex => qr/.../,
2142       handler => sub {
2143         my ($self, $field, $op, $arg) = @_;
2144         ...
2145       },
2146      },
2147      {
2148       regex => qr/.../,
2149       handler => 'method_name',
2150      },
2151    ]);
2152
2153 A "special operator" is a SQL syntactic clause that can be
2154 applied to a field, instead of a usual binary operator.
2155 For example :
2156
2157    WHERE field IN (?, ?, ?)
2158    WHERE field BETWEEN ? AND ?
2159    WHERE MATCH(field) AGAINST (?, ?)
2160
2161 Special operators IN and BETWEEN are fairly standard and therefore
2162 are builtin within C<SQL::Abstract> (as the overridable methods
2163 C<_where_field_IN> and C<_where_field_BETWEEN>). For other operators,
2164 like the MATCH .. AGAINST example above which is specific to MySQL,
2165 you can write your own operator handlers - supply a C<special_ops>
2166 argument to the C<new> method. That argument takes an arrayref of
2167 operator definitions; each operator definition is a hashref with two
2168 entries:
2169
2170 =over
2171
2172 =item regex
2173
2174 the regular expression to match the operator
2175
2176 =item handler
2177
2178 Either a coderef or a plain scalar method name. In both cases
2179 the expected return is C<< ($sql, @bind) >>.
2180
2181 When supplied with a method name, it is simply called on the
2182 L<SQL::Abstract/> object as:
2183
2184  $self->$method_name ($field, $op, $arg)
2185
2186  Where:
2187
2188   $op is the part that matched the handler regex
2189   $field is the LHS of the operator
2190   $arg is the RHS
2191
2192 When supplied with a coderef, it is called as:
2193
2194  $coderef->($self, $field, $op, $arg)
2195
2196
2197 =back
2198
2199 For example, here is an implementation
2200 of the MATCH .. AGAINST syntax for MySQL
2201
2202   my $sqlmaker = SQL::Abstract->new(special_ops => [
2203
2204     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2205     {regex => qr/^match$/i,
2206      handler => sub {
2207        my ($self, $field, $op, $arg) = @_;
2208        $arg = [$arg] if not ref $arg;
2209        my $label         = $self->_quote($field);
2210        my ($placeholder) = $self->_convert('?');
2211        my $placeholders  = join ", ", (($placeholder) x @$arg);
2212        my $sql           = $self->_sqlcase('match') . " ($label) "
2213                          . $self->_sqlcase('against') . " ($placeholders) ";
2214        my @bind = $self->_bindtype($field, @$arg);
2215        return ($sql, @bind);
2216        }
2217      },
2218
2219   ]);
2220
2221
2222 =head1 PERFORMANCE
2223
2224 Thanks to some benchmarking by Mark Stosberg, it turns out that
2225 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2226 I must admit this wasn't an intentional design issue, but it's a
2227 byproduct of the fact that you get to control your C<DBI> handles
2228 yourself.
2229
2230 To maximize performance, use a code snippet like the following:
2231
2232     # prepare a statement handle using the first row
2233     # and then reuse it for the rest of the rows
2234     my($sth, $stmt);
2235     for my $href (@array_of_hashrefs) {
2236         $stmt ||= $sql->insert('table', $href);
2237         $sth  ||= $dbh->prepare($stmt);
2238         $sth->execute($sql->values($href));
2239     }
2240
2241 The reason this works is because the keys in your C<$href> are sorted
2242 internally by B<SQL::Abstract>. Thus, as long as your data retains
2243 the same structure, you only have to generate the SQL the first time
2244 around. On subsequent queries, simply use the C<values> function provided
2245 by this module to return your values in the correct order.
2246
2247
2248 =head1 FORMBUILDER
2249
2250 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2251 really like this part (I do, at least). Building up a complex query
2252 can be as simple as the following:
2253
2254     #!/usr/bin/perl
2255
2256     use CGI::FormBuilder;
2257     use SQL::Abstract;
2258
2259     my $form = CGI::FormBuilder->new(...);
2260     my $sql  = SQL::Abstract->new;
2261
2262     if ($form->submitted) {
2263         my $field = $form->field;
2264         my $id = delete $field->{id};
2265         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2266     }
2267
2268 Of course, you would still have to connect using C<DBI> to run the
2269 query, but the point is that if you make your form look like your
2270 table, the actual query script can be extremely simplistic.
2271
2272 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2273 a fast interface to returning and formatting data. I frequently
2274 use these three modules together to write complex database query
2275 apps in under 50 lines.
2276
2277
2278 =head1 CHANGES
2279
2280 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2281 Great care has been taken to preserve the I<published> behavior
2282 documented in previous versions in the 1.* family; however,
2283 some features that were previously undocumented, or behaved
2284 differently from the documentation, had to be changed in order
2285 to clarify the semantics. Hence, client code that was relying
2286 on some dark areas of C<SQL::Abstract> v1.*
2287 B<might behave differently> in v1.50.
2288
2289 The main changes are :
2290
2291 =over
2292
2293 =item *
2294
2295 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2296
2297 =item *
2298
2299 support for the { operator => \"..." } construct (to embed literal SQL)
2300
2301 =item *
2302
2303 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2304
2305 =item *
2306
2307 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2308
2309 =item *
2310
2311 defensive programming : check arguments
2312
2313 =item *
2314
2315 fixed bug with global logic, which was previously implemented
2316 through global variables yielding side-effects. Prior versions would
2317 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2318 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2319 Now this is interpreted
2320 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2321
2322
2323 =item *
2324
2325 fixed semantics of  _bindtype on array args
2326
2327 =item *
2328
2329 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2330 we just avoid shifting arrays within that tree.
2331
2332 =item *
2333
2334 dropped the C<_modlogic> function
2335
2336 =back
2337
2338
2339
2340 =head1 ACKNOWLEDGEMENTS
2341
2342 There are a number of individuals that have really helped out with
2343 this module. Unfortunately, most of them submitted bugs via CPAN
2344 so I have no idea who they are! But the people I do know are:
2345
2346     Ash Berlin (order_by hash term support)
2347     Matt Trout (DBIx::Class support)
2348     Mark Stosberg (benchmarking)
2349     Chas Owens (initial "IN" operator support)
2350     Philip Collins (per-field SQL functions)
2351     Eric Kolve (hashref "AND" support)
2352     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2353     Dan Kubb (support for "quote_char" and "name_sep")
2354     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2355     Laurent Dami (internal refactoring, multiple -nest, extensible list of special operators, literal SQL)
2356     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2357     Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2358
2359 Thanks!
2360
2361 =head1 SEE ALSO
2362
2363 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2364
2365 =head1 AUTHOR
2366
2367 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2368
2369 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2370
2371 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2372 While not an official support venue, C<DBIx::Class> makes heavy use of
2373 C<SQL::Abstract>, and as such list members there are very familiar with
2374 how to create queries.
2375
2376 =head1 LICENSE
2377
2378 This module is free software; you may copy this under the terms of
2379 the GNU General Public License, or the Artistic License, copies of
2380 which should have accompanied your Perl kit.
2381
2382 =cut
2383