lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use Carp;
   9 use strict;
  10 use warnings;
  11 use List::Util   qw/first/;
  12 use Scalar::Util qw/blessed/;
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.51';
  19
  20 # This would confuse some packagers
  21 #$VERSION      = eval $VERSION; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^(not )?between$/i, handler => \&_where_field_BETWEEN},
  29   {regex => qr/^(not )?in$/i,      handler => \&_where_field_IN},
  30 );
  31
  32 #======================================================================
  33 # DEBUGGING AND ERROR REPORTING
  34 #======================================================================
  35
  36 sub _debug {
  37   return unless $_[0]->{debug}; shift; # a little faster
  38   my $func = (caller(1))[3];
  39   warn "[$func] ", @_, "\n";
  40 }
  41
  42 sub belch (@) {
  43   my($func) = (caller(1))[3];
  44   carp "[$func] Warning: ", @_;
  45 }
  46
  47 sub puke (@) {
  48   my($func) = (caller(1))[3];
  49   croak "[$func] Fatal: ", @_;
  50 }
  51
  52
  53 #======================================================================
  54 # NEW
  55 #======================================================================
  56
  57 sub new {
  58   my $self = shift;
  59   my $class = ref($self) || $self;
  60   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  61
  62   # choose our case by keeping an option around
  63   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  64
  65   # default logic for interpreting arrayrefs
  66   $opt{logic} = uc $opt{logic} || 'OR';
  67
  68   # how to return bind vars
  69   # LDNOTE: changed nwiger code : why this 'delete' ??
  70   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  71   $opt{bindtype} ||= 'normal';
  72
  73   # default comparison is "=", but can be overridden
  74   $opt{cmp} ||= '=';
  75
  76   # try to recognize which are the 'equality' and 'unequality' ops
  77   # (temporary quickfix, should go through a more seasoned API)
  78  $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  79  $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  80
  81   # SQL booleans
  82   $opt{sqltrue}  ||= '1=1';
  83   $opt{sqlfalse} ||= '0=1';
  84
  85   # special operators
  86   $opt{special_ops} ||= [];
  87   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
  88
  89   return bless \%opt, $class;
  90 }
  91
  92
  93
  94 #======================================================================
  95 # INSERT methods
  96 #======================================================================
  97
  98 sub insert {
  99   my $self  = shift;
 100   my $table = $self->_table(shift);
 101   my $data  = shift || return;
 102
 103   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 104   my ($sql, @bind) = $self->$method($data);
 105   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 106   return wantarray ? ($sql, @bind) : $sql;
 107 }
 108
 109 sub _insert_HASHREF { # explicit list of fields and then values
 110   my ($self, $data) = @_;
 111
 112   my @fields = sort keys %$data;
 113
 114   my ($sql, @bind) = $self->_insert_values($data);
 115
 116   # assemble SQL
 117   $_ = $self->_quote($_) foreach @fields;
 118   $sql = "( ".join(", ", @fields).") ".$sql;
 119
 120   return ($sql, @bind);
 121 }
 122
 123 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 124   my ($self, $data) = @_;
 125
 126   # no names (arrayref) so can't generate bindtype
 127   $self->{bindtype} ne 'columns'
 128     or belch "can't do 'columns' bindtype when called with arrayref";
 129
 130   # fold the list of values into a hash of column name - value pairs
 131   # (where the column names are artificially generated, and their
 132   # lexicographical ordering keep the ordering of the original list)
 133   my $i = "a";  # incremented values will be in lexicographical order
 134   my $data_in_hash = { map { ($i++ => $_) } @$data };
 135
 136   return $self->_insert_values($data_in_hash);
 137 }
 138
 139 sub _insert_ARRAYREFREF { # literal SQL with bind
 140   my ($self, $data) = @_;
 141
 142   my ($sql, @bind) = @${$data};
 143   $self->_assert_bindval_matches_bindtype(@bind);
 144
 145   return ($sql, @bind);
 146 }
 147
 148
 149 sub _insert_SCALARREF { # literal SQL without bind
 150   my ($self, $data) = @_;
 151
 152   return ($$data);
 153 }
 154
 155 sub _insert_values {
 156   my ($self, $data) = @_;
 157
 158   my (@values, @all_bind);
 159   foreach my $column (sort keys %$data) {
 160     my $v = $data->{$column};
 161
 162     $self->_SWITCH_refkind($v, {
 163
 164       ARRAYREF => sub {
 165         if ($self->{array_datatypes}) { # if array datatype are activated
 166           push @values, '?';
 167           push @all_bind, $self->_bindtype($column, $v);
 168         }
 169         else {                          # else literal SQL with bind
 170           my ($sql, @bind) = @$v;
 171           $self->_assert_bindval_matches_bindtype(@bind);
 172           push @values, $sql;
 173           push @all_bind, @bind;
 174         }
 175       },
 176
 177       ARRAYREFREF => sub { # literal SQL with bind
 178         my ($sql, @bind) = @${$v};
 179         $self->_assert_bindval_matches_bindtype(@bind);
 180         push @values, $sql;
 181         push @all_bind, @bind;
 182       },
 183
 184       # THINK : anything useful to do with a HASHREF ?
 185       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 186         #TODO in SQLA >= 2.0 it will die instead
 187         belch "HASH ref as bind value in insert is not supported";
 188         push @values, '?';
 189         push @all_bind, $self->_bindtype($column, $v);
 190       },
 191
 192       SCALARREF => sub {  # literal SQL without bind
 193         push @values, $$v;
 194       },
 195
 196       SCALAR_or_UNDEF => sub {
 197         push @values, '?';
 198         push @all_bind, $self->_bindtype($column, $v);
 199       },
 200
 201      });
 202
 203   }
 204
 205   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 206   return ($sql, @all_bind);
 207 }
 208
 209
 210
 211 #======================================================================
 212 # UPDATE methods
 213 #======================================================================
 214
 215
 216 sub update {
 217   my $self  = shift;
 218   my $table = $self->_table(shift);
 219   my $data  = shift || return;
 220   my $where = shift;
 221
 222   # first build the 'SET' part of the sql statement
 223   my (@set, @all_bind);
 224   puke "Unsupported data type specified to \$sql->update"
 225     unless ref $data eq 'HASH';
 226
 227   for my $k (sort keys %$data) {
 228     my $v = $data->{$k};
 229     my $r = ref $v;
 230     my $label = $self->_quote($k);
 231
 232     $self->_SWITCH_refkind($v, {
 233       ARRAYREF => sub {
 234         if ($self->{array_datatypes}) { # array datatype
 235           push @set, "$label = ?";
 236           push @all_bind, $self->_bindtype($k, $v);
 237         }
 238         else {                          # literal SQL with bind
 239           my ($sql, @bind) = @$v;
 240           $self->_assert_bindval_matches_bindtype(@bind);
 241           push @set, "$label = $sql";
 242           push @all_bind, @bind;
 243         }
 244       },
 245       ARRAYREFREF => sub { # literal SQL with bind
 246         my ($sql, @bind) = @${$v};
 247         $self->_assert_bindval_matches_bindtype(@bind);
 248         push @set, "$label = $sql";
 249         push @all_bind, @bind;
 250       },
 251       SCALARREF => sub {  # literal SQL without bind
 252         push @set, "$label = $$v";
 253        },
 254       SCALAR_or_UNDEF => sub {
 255         push @set, "$label = ?";
 256         push @all_bind, $self->_bindtype($k, $v);
 257       },
 258     });
 259   }
 260
 261   # generate sql
 262   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 263           . join ', ', @set;
 264
 265   if ($where) {
 266     my($where_sql, @where_bind) = $self->where($where);
 267     $sql .= $where_sql;
 268     push @all_bind, @where_bind;
 269   }
 270
 271   return wantarray ? ($sql, @all_bind) : $sql;
 272 }
 273
 274
 275
 276
 277 #======================================================================
 278 # SELECT
 279 #======================================================================
 280
 281
 282 sub select {
 283   my $self   = shift;
 284   my $table  = $self->_table(shift);
 285   my $fields = shift || '*';
 286   my $where  = shift;
 287   my $order  = shift;
 288
 289   my($where_sql, @bind) = $self->where($where, $order);
 290
 291   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 292                                    : $fields;
 293   my $sql = join(' ', $self->_sqlcase('select'), $f,
 294                       $self->_sqlcase('from'),   $table)
 295           . $where_sql;
 296
 297   return wantarray ? ($sql, @bind) : $sql;
 298 }
 299
 300 #======================================================================
 301 # DELETE
 302 #======================================================================
 303
 304
 305 sub delete {
 306   my $self  = shift;
 307   my $table = $self->_table(shift);
 308   my $where = shift;
 309
 310
 311   my($where_sql, @bind) = $self->where($where);
 312   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 313
 314   return wantarray ? ($sql, @bind) : $sql;
 315 }
 316
 317
 318 #======================================================================
 319 # WHERE: entry point
 320 #======================================================================
 321
 322
 323
 324 # Finally, a separate routine just to handle WHERE clauses
 325 sub where {
 326   my ($self, $where, $order) = @_;
 327
 328   # where ?
 329   my ($sql, @bind) = $self->_recurse_where($where);
 330   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 331
 332   # order by?
 333   if ($order) {
 334     $sql .= $self->_order_by($order);
 335   }
 336
 337   return wantarray ? ($sql, @bind) : $sql;
 338 }
 339
 340
 341 sub _recurse_where {
 342   my ($self, $where, $logic) = @_;
 343
 344   # dispatch on appropriate method according to refkind of $where
 345   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 346
 347
 348   my ($sql, @bind) =  $self->$method($where, $logic);
 349
 350   # DBIx::Class directly calls _recurse_where in scalar context, so
 351   # we must implement it, even if not in the official API
 352   return wantarray ? ($sql, @bind) : $sql;
 353 }
 354
 355
 356
 357 #======================================================================
 358 # WHERE: top-level ARRAYREF
 359 #======================================================================
 360
 361
 362 sub _where_ARRAYREF {
 363   my ($self, $where, $logic) = @_;
 364
 365   $logic = uc($logic || $self->{logic});
 366   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 367
 368   my @clauses = @$where;
 369
 370   my (@sql_clauses, @all_bind);
 371   # need to use while() so can shift() for pairs
 372   while (my $el = shift @clauses) {
 373
 374     # switch according to kind of $el and get corresponding ($sql, @bind)
 375     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 376
 377       # skip empty elements, otherwise get invalid trailing AND stuff
 378       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 379
 380       ARRAYREFREF => sub { @{${$el}}                 if @{${$el}}},
 381
 382       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 383            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 384            # side-effect: the first hashref within an array would change
 385            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 386            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 387            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 388
 389       SCALARREF => sub { ($$el);                                 },
 390
 391       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 392                         $self->_recurse_where({$el => shift(@clauses)})},
 393
 394       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 395     });
 396
 397     if ($sql) {
 398       push @sql_clauses, $sql;
 399       push @all_bind, @bind;
 400     }
 401   }
 402
 403   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 404 }
 405
 406 #======================================================================
 407 # WHERE: top-level ARRAYREFREF
 408 #======================================================================
 409
 410 sub _where_ARRAYREFREF {
 411     my ($self, $where) = @_;
 412     my ($sql, @bind) = @{${$where}};
 413
 414     return ($sql, @bind);
 415 }
 416
 417 #======================================================================
 418 # WHERE: top-level HASHREF
 419 #======================================================================
 420
 421 sub _where_HASHREF {
 422   my ($self, $where) = @_;
 423   my (@sql_clauses, @all_bind);
 424
 425   # LDNOTE : don't really know why we need to sort keys
 426   for my $k (sort keys %$where) {
 427     my $v = $where->{$k};
 428
 429     # ($k => $v) is either a special op or a regular hashpair
 430     my ($sql, @bind) = ($k =~ /^-(.+)/) ? $self->_where_op_in_hash($1, $v)
 431                                         : do {
 432          my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 433          $self->$method($k, $v);
 434        };
 435
 436     push @sql_clauses, $sql;
 437     push @all_bind, @bind;
 438   }
 439
 440   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 441 }
 442
 443
 444 sub _where_op_in_hash {
 445   my ($self, $op_str, $v) = @_;
 446
 447   $op_str =~ /^ (AND|OR|NEST) ( \_? \d* ) $/xi
 448     or puke "unknown operator: -$op_str";
 449
 450   my $op = uc($1); # uppercase, remove trailing digits
 451   if ($2) {
 452     belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
 453           . "You probably wanted ...-and => [ $op_str => COND1, $op_str => COND2 ... ]";
 454   }
 455
 456   $self->_debug("OP(-$op) within hashref, recursing...");
 457
 458   $self->_SWITCH_refkind($v, {
 459
 460     ARRAYREF => sub {
 461       return $self->_where_ARRAYREF($v, $op eq 'NEST' ? '' : $op);
 462     },
 463
 464     HASHREF => sub {
 465       if ($op eq 'OR') {
 466         return $self->_where_ARRAYREF([%$v], 'OR');
 467       }
 468       else {                  # NEST | AND
 469         return $self->_where_HASHREF($v);
 470       }
 471     },
 472
 473     SCALARREF  => sub {         # literal SQL
 474       $op eq 'NEST'
 475         or puke "-$op => \\\$scalar not supported, use -nest => ...";
 476       return ($$v);
 477     },
 478
 479     ARRAYREFREF => sub {        # literal SQL
 480       $op eq 'NEST'
 481         or puke "-$op => \\[..] not supported, use -nest => ...";
 482       return @{${$v}};
 483     },
 484
 485     SCALAR => sub { # permissively interpreted as SQL
 486       $op eq 'NEST'
 487         or puke "-$op => 'scalar' not supported, use -nest => \\'scalar'";
 488       belch "literal SQL should be -nest => \\'scalar' "
 489           . "instead of -nest => 'scalar' ";
 490       return ($v);
 491     },
 492
 493     UNDEF => sub {
 494       puke "-$op => undef not supported";
 495     },
 496    });
 497 }
 498
 499
 500 sub _where_hashpair_ARRAYREF {
 501   my ($self, $k, $v) = @_;
 502
 503   if( @$v ) {
 504     my @v = @$v; # need copy because of shift below
 505     $self->_debug("ARRAY($k) means distribute over elements");
 506
 507     # put apart first element if it is an operator (-and, -or)
 508     my $op = ($v[0] =~ /^ - (?: AND|OR ) $/ix
 509       ? shift @v
 510       : ''
 511     );
 512     my @distributed = map { {$k =>  $_} } @v;
 513
 514     if ($op) {
 515       $self->_debug("OP($op) reinjected into the distributed array");
 516       unshift @distributed, $op;
 517     }
 518
 519     my $logic = $op ? substr($op, 1) : '';
 520
 521     return $self->_recurse_where(\@distributed, $logic);
 522   }
 523   else {
 524     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 525     $self->_debug("empty ARRAY($k) means 0=1");
 526     return ($self->{sqlfalse});
 527   }
 528 }
 529
 530 sub _where_hashpair_HASHREF {
 531   my ($self, $k, $v) = @_;
 532
 533   my (@all_sql, @all_bind);
 534
 535   for my $op (sort keys %$v) {
 536     my $val = $v->{$op};
 537
 538     # put the operator in canonical form
 539     $op =~ s/^-//;       # remove initial dash
 540     $op =~ tr/_/ /;      # underscores become spaces
 541     $op =~ s/^\s+//;     # no initial space
 542     $op =~ s/\s+$//;     # no final space
 543     $op =~ s/\s+/ /;     # multiple spaces become one
 544
 545     my ($sql, @bind);
 546
 547     # CASE: special operators like -in or -between
 548     my $special_op = first {$op =~ $_->{regex}} @{$self->{special_ops}};
 549     if ($special_op) {
 550       ($sql, @bind) = $special_op->{handler}->($self, $k, $op, $val);
 551     }
 552     else {
 553       $self->_SWITCH_refkind($val, {
 554
 555         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 556           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 557         },
 558
 559         SCALARREF => sub {      # CASE: col => {op => \$scalar} (literal SQL without bind)
 560           $sql  = join ' ', $self->_convert($self->_quote($k)),
 561                             $self->_sqlcase($op),
 562                             $$val;
 563         },
 564
 565         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 566           my ($sub_sql, @sub_bind) = @$$val;
 567           $self->_assert_bindval_matches_bindtype(@sub_bind);
 568           $sql  = join ' ', $self->_convert($self->_quote($k)),
 569                             $self->_sqlcase($op),
 570                             $sub_sql;
 571           @bind = @sub_bind;
 572         },
 573
 574         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 575           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 576                    ($op =~ $self->{inequality_op}) ? 'is not' :
 577                puke "unexpected operator '$op' with undef operand";
 578           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 579         },
 580
 581         FALLBACK => sub {       # CASE: col => {op => $scalar}
 582           $sql  = join ' ', $self->_convert($self->_quote($k)),
 583                             $self->_sqlcase($op),
 584                             $self->_convert('?');
 585           @bind = $self->_bindtype($k, $val);
 586         },
 587       });
 588     }
 589
 590     push @all_sql, $sql;
 591     push @all_bind, @bind;
 592   }
 593
 594   return $self->_join_sql_clauses('and', \@all_sql, \@all_bind);
 595 }
 596
 597
 598
 599 sub _where_field_op_ARRAYREF {
 600   my ($self, $k, $op, $vals) = @_;
 601
 602   if(@$vals) {
 603     $self->_debug("ARRAY($vals) means multiple elements: [ @$vals ]");
 604
 605     # LDNOTE : had planned to change the distribution logic when
 606     # $op =~ $self->{inequality_op}, because of Morgan laws :
 607     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 608     # WHERE field != 22 OR  field != 33 : the user probably means
 609     # WHERE field != 22 AND field != 33.
 610     # To do this, replace the line below by :
 611     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 612     # return $self->_recurse_where([map { {$k => {$op, $_}} } @$vals], $logic);
 613
 614     # distribute $op over each member of @$vals
 615     return $self->_recurse_where([map { {$k => {$op, $_}} } @$vals]);
 616   }
 617   else {
 618     # try to DWIM on equality operators
 619     # LDNOTE : not 100% sure this is the correct thing to do ...
 620     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 621     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 622
 623     # otherwise
 624     puke "operator '$op' applied on an empty array (field '$k')";
 625   }
 626 }
 627
 628
 629 sub _where_hashpair_SCALARREF {
 630   my ($self, $k, $v) = @_;
 631   $self->_debug("SCALAR($k) means literal SQL: $$v");
 632   my $sql = $self->_quote($k) . " " . $$v;
 633   return ($sql);
 634 }
 635
 636 # literal SQL with bind
 637 sub _where_hashpair_ARRAYREFREF {
 638   my ($self, $k, $v) = @_;
 639   $self->_debug("REF($k) means literal SQL: @${$v}");
 640   my ($sql, @bind) = @${$v};
 641   $self->_assert_bindval_matches_bindtype(@bind);
 642   $sql  = $self->_quote($k) . " " . $sql;
 643   return ($sql, @bind );
 644 }
 645
 646 # literal SQL without bind
 647 sub _where_hashpair_SCALAR {
 648   my ($self, $k, $v) = @_;
 649   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 650   my $sql = join ' ', $self->_convert($self->_quote($k)),
 651                       $self->_sqlcase($self->{cmp}),
 652                       $self->_convert('?');
 653   my @bind =  $self->_bindtype($k, $v);
 654   return ( $sql, @bind);
 655 }
 656
 657
 658 sub _where_hashpair_UNDEF {
 659   my ($self, $k, $v) = @_;
 660   $self->_debug("UNDEF($k) means IS NULL");
 661   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 662   return ($sql);
 663 }
 664
 665 #======================================================================
 666 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 667 #======================================================================
 668
 669
 670 sub _where_SCALARREF {
 671   my ($self, $where) = @_;
 672
 673   # literal sql
 674   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 675   return ($$where);
 676 }
 677
 678
 679 sub _where_SCALAR {
 680   my ($self, $where) = @_;
 681
 682   # literal sql
 683   $self->_debug("NOREF(*top) means literal SQL: $where");
 684   return ($where);
 685 }
 686
 687
 688 sub _where_UNDEF {
 689   my ($self) = @_;
 690   return ();
 691 }
 692
 693
 694 #======================================================================
 695 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 696 #======================================================================
 697
 698
 699 sub _where_field_BETWEEN {
 700   my ($self, $k, $op, $vals) = @_;
 701
 702   ref $vals eq 'ARRAY' && @$vals == 2
 703     or puke "special op 'between' requires an arrayref of two values";
 704
 705   my ($label)       = $self->_convert($self->_quote($k));
 706   my ($placeholder) = $self->_convert('?');
 707   my $and           = $self->_sqlcase('and');
 708   $op               = $self->_sqlcase($op);
 709
 710   my $sql  = "( $label $op $placeholder $and $placeholder )";
 711   my @bind = $self->_bindtype($k, @$vals);
 712   return ($sql, @bind)
 713 }
 714
 715
 716 sub _where_field_IN {
 717   my ($self, $k, $op, $vals) = @_;
 718
 719   # backwards compatibility : if scalar, force into an arrayref
 720   $vals = [$vals] if defined $vals && ! ref $vals;
 721
 722   my ($label)       = $self->_convert($self->_quote($k));
 723   my ($placeholder) = $self->_convert('?');
 724   $op               = $self->_sqlcase($op);
 725
 726   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
 727     ARRAYREF => sub {     # list of choices
 728       if (@$vals) { # nonempty list
 729         my $placeholders  = join ", ", (($placeholder) x @$vals);
 730         my $sql           = "$label $op ( $placeholders )";
 731         my @bind = $self->_bindtype($k, @$vals);
 732
 733         return ($sql, @bind);
 734       }
 735       else { # empty list : some databases won't understand "IN ()", so DWIM
 736         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
 737         return ($sql);
 738       }
 739     },
 740
 741     ARRAYREFREF => sub {  # literal SQL with bind
 742       my ($sql, @bind) = @$$vals;
 743       $self->_assert_bindval_matches_bindtype(@bind);
 744       return ("$label $op ( $sql )", @bind);
 745     },
 746
 747     FALLBACK => sub {
 748       puke "special op 'in' requires an arrayref (or arrayref-ref)";
 749     },
 750   });
 751
 752   return ($sql, @bind);
 753 }
 754
 755
 756
 757
 758
 759
 760 #======================================================================
 761 # ORDER BY
 762 #======================================================================
 763
 764 sub _order_by {
 765   my ($self, $arg) = @_;
 766
 767   # construct list of ordering instructions
 768   my @order = $self->_SWITCH_refkind($arg, {
 769
 770     ARRAYREF => sub {
 771       map {$self->_SWITCH_refkind($_, {
 772               SCALAR    => sub {$self->_quote($_)},
 773               UNDEF     => sub {},
 774               SCALARREF => sub {$$_}, # literal SQL, no quoting
 775               HASHREF   => sub {$self->_order_by_hash($_)}
 776              }) } @$arg;
 777     },
 778
 779     SCALAR    => sub {$self->_quote($arg)},
 780     UNDEF     => sub {},
 781     SCALARREF => sub {$$arg}, # literal SQL, no quoting
 782     HASHREF   => sub {$self->_order_by_hash($arg)},
 783
 784   });
 785
 786   # build SQL
 787   my $order = join ', ', @order;
 788   return $order ? $self->_sqlcase(' order by')." $order" : '';
 789 }
 790
 791
 792 sub _order_by_hash {
 793   my ($self, $hash) = @_;
 794
 795   # get first pair in hash
 796   my ($key, $val) = each %$hash;
 797
 798   # check if one pair was found and no other pair in hash
 799   $key && !(each %$hash)
 800     or puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
 801
 802   my ($order) = ($key =~ /^-(desc|asc)/i)
 803     or puke "invalid key in _order_by hash : $key";
 804
 805   return $self->_quote($val) ." ". $self->_sqlcase($order);
 806 }
 807
 808
 809
 810 #======================================================================
 811 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
 812 #======================================================================
 813
 814 sub _table  {
 815   my $self = shift;
 816   my $from = shift;
 817   $self->_SWITCH_refkind($from, {
 818     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
 819     SCALAR       => sub {$self->_quote($from)},
 820     SCALARREF    => sub {$$from},
 821     ARRAYREFREF  => sub {join ', ', @$from;},
 822   });
 823 }
 824
 825
 826 #======================================================================
 827 # UTILITY FUNCTIONS
 828 #======================================================================
 829
 830 sub _quote {
 831   my $self  = shift;
 832   my $label = shift;
 833
 834   $label or puke "can't quote an empty label";
 835
 836   # left and right quote characters
 837   my ($ql, $qr, @other) = $self->_SWITCH_refkind($self->{quote_char}, {
 838     SCALAR   => sub {($self->{quote_char}, $self->{quote_char})},
 839     ARRAYREF => sub {@{$self->{quote_char}}},
 840     UNDEF    => sub {()},
 841    });
 842   not @other
 843       or puke "quote_char must be an arrayref of 2 values";
 844
 845   # no quoting if no quoting chars
 846   $ql or return $label;
 847
 848   # no quoting for literal SQL
 849   return $$label if ref($label) eq 'SCALAR';
 850
 851   # separate table / column (if applicable)
 852   my $sep = $self->{name_sep} || '';
 853   my @to_quote = $sep ? split /\Q$sep\E/, $label : ($label);
 854
 855   # do the quoting, except for "*" or for `table`.*
 856   my @quoted = map { $_ eq '*' ? $_: $ql.$_.$qr} @to_quote;
 857
 858   # reassemble and return.
 859   return join $sep, @quoted;
 860 }
 861
 862
 863 # Conversion, if applicable
 864 sub _convert ($) {
 865   my ($self, $arg) = @_;
 866
 867 # LDNOTE : modified the previous implementation below because
 868 # it was not consistent : the first "return" is always an array,
 869 # the second "return" is context-dependent. Anyway, _convert
 870 # seems always used with just a single argument, so make it a
 871 # scalar function.
 872 #     return @_ unless $self->{convert};
 873 #     my $conv = $self->_sqlcase($self->{convert});
 874 #     my @ret = map { $conv.'('.$_.')' } @_;
 875 #     return wantarray ? @ret : $ret[0];
 876   if ($self->{convert}) {
 877     my $conv = $self->_sqlcase($self->{convert});
 878     $arg = $conv.'('.$arg.')';
 879   }
 880   return $arg;
 881 }
 882
 883 # And bindtype
 884 sub _bindtype (@) {
 885   my $self = shift;
 886   my($col, @vals) = @_;
 887
 888   #LDNOTE : changed original implementation below because it did not make
 889   # sense when bindtype eq 'columns' and @vals > 1.
 890 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
 891
 892   return $self->{bindtype} eq 'columns' ? map {[$col, $_]} @vals : @vals;
 893 }
 894
 895 # Dies if any element of @bind is not in [colname => value] format
 896 # if bindtype is 'columns'.
 897 sub _assert_bindval_matches_bindtype {
 898   my ($self, @bind) = @_;
 899
 900   if ($self->{bindtype} eq 'columns') {
 901     foreach my $val (@bind) {
 902       if (!defined $val || ref($val) ne 'ARRAY' || @$val != 2) {
 903         die "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
 904       }
 905     }
 906   }
 907 }
 908
 909 sub _join_sql_clauses {
 910   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
 911
 912   if (@$clauses_aref > 1) {
 913     my $join  = " " . $self->_sqlcase($logic) . " ";
 914     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
 915     return ($sql, @$bind_aref);
 916   }
 917   elsif (@$clauses_aref) {
 918     return ($clauses_aref->[0], @$bind_aref); # no parentheses
 919   }
 920   else {
 921     return (); # if no SQL, ignore @$bind_aref
 922   }
 923 }
 924
 925
 926 # Fix SQL case, if so requested
 927 sub _sqlcase {
 928   my $self = shift;
 929
 930   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
 931   # don't touch the argument ... crooked logic, but let's not change it!
 932   return $self->{case} ? $_[0] : uc($_[0]);
 933 }
 934
 935
 936 #======================================================================
 937 # DISPATCHING FROM REFKIND
 938 #======================================================================
 939
 940 sub _refkind {
 941   my ($self, $data) = @_;
 942   my $suffix = '';
 943   my $ref;
 944   my $n_steps = 0;
 945
 946   while (1) {
 947     # blessed objects are treated like scalars
 948     $ref = (blessed $data) ? '' : ref $data;
 949     $n_steps += 1 if $ref;
 950     last          if $ref ne 'REF';
 951     $data = $$data;
 952   }
 953
 954   my $base = $ref || (defined $data ? 'SCALAR' : 'UNDEF');
 955
 956   return $base . ('REF' x $n_steps);
 957 }
 958
 959
 960
 961 sub _try_refkind {
 962   my ($self, $data) = @_;
 963   my @try = ($self->_refkind($data));
 964   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
 965   push @try, 'FALLBACK';
 966   return @try;
 967 }
 968
 969 sub _METHOD_FOR_refkind {
 970   my ($self, $meth_prefix, $data) = @_;
 971   my $method = first {$_} map {$self->can($meth_prefix."_".$_)}
 972                               $self->_try_refkind($data)
 973     or puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
 974   return $method;
 975 }
 976
 977
 978 sub _SWITCH_refkind {
 979   my ($self, $data, $dispatch_table) = @_;
 980
 981   my $coderef = first {$_} map {$dispatch_table->{$_}}
 982                                $self->_try_refkind($data)
 983     or puke "no dispatch entry for ".$self->_refkind($data);
 984   $coderef->();
 985 }
 986
 987
 988
 989
 990 #======================================================================
 991 # VALUES, GENERATE, AUTOLOAD
 992 #======================================================================
 993
 994 # LDNOTE: original code from nwiger, didn't touch code in that section
 995 # I feel the AUTOLOAD stuff should not be the default, it should
 996 # only be activated on explicit demand by user.
 997
 998 sub values {
 999     my $self = shift;
1000     my $data = shift || return;
1001     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1002         unless ref $data eq 'HASH';
1003
1004     my @all_bind;
1005     foreach my $k ( sort keys %$data ) {
1006         my $v = $data->{$k};
1007         $self->_SWITCH_refkind($v, {
1008           ARRAYREF => sub {
1009             if ($self->{array_datatypes}) { # array datatype
1010               push @all_bind, $self->_bindtype($k, $v);
1011             }
1012             else {                          # literal SQL with bind
1013               my ($sql, @bind) = @$v;
1014               $self->_assert_bindval_matches_bindtype(@bind);
1015               push @all_bind, @bind;
1016             }
1017           },
1018           ARRAYREFREF => sub { # literal SQL with bind
1019             my ($sql, @bind) = @${$v};
1020             $self->_assert_bindval_matches_bindtype(@bind);
1021             push @all_bind, @bind;
1022           },
1023           SCALARREF => sub {  # literal SQL without bind
1024           },
1025           SCALAR_or_UNDEF => sub {
1026             push @all_bind, $self->_bindtype($k, $v);
1027           },
1028         });
1029     }
1030
1031     return @all_bind;
1032 }
1033
1034 sub generate {
1035     my $self  = shift;
1036
1037     my(@sql, @sqlq, @sqlv);
1038
1039     for (@_) {
1040         my $ref = ref $_;
1041         if ($ref eq 'HASH') {
1042             for my $k (sort keys %$_) {
1043                 my $v = $_->{$k};
1044                 my $r = ref $v;
1045                 my $label = $self->_quote($k);
1046                 if ($r eq 'ARRAY') {
1047                     # literal SQL with bind
1048                     my ($sql, @bind) = @$v;
1049                     $self->_assert_bindval_matches_bindtype(@bind);
1050                     push @sqlq, "$label = $sql";
1051                     push @sqlv, @bind;
1052                 } elsif ($r eq 'SCALAR') {
1053                     # literal SQL without bind
1054                     push @sqlq, "$label = $$v";
1055                 } else {
1056                     push @sqlq, "$label = ?";
1057                     push @sqlv, $self->_bindtype($k, $v);
1058                 }
1059             }
1060             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1061         } elsif ($ref eq 'ARRAY') {
1062             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1063             for my $v (@$_) {
1064                 my $r = ref $v;
1065                 if ($r eq 'ARRAY') {   # literal SQL with bind
1066                     my ($sql, @bind) = @$v;
1067                     $self->_assert_bindval_matches_bindtype(@bind);
1068                     push @sqlq, $sql;
1069                     push @sqlv, @bind;
1070                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1071                     # embedded literal SQL
1072                     push @sqlq, $$v;
1073                 } else {
1074                     push @sqlq, '?';
1075                     push @sqlv, $v;
1076                 }
1077             }
1078             push @sql, '(' . join(', ', @sqlq) . ')';
1079         } elsif ($ref eq 'SCALAR') {
1080             # literal SQL
1081             push @sql, $$_;
1082         } else {
1083             # strings get case twiddled
1084             push @sql, $self->_sqlcase($_);
1085         }
1086     }
1087
1088     my $sql = join ' ', @sql;
1089
1090     # this is pretty tricky
1091     # if ask for an array, return ($stmt, @bind)
1092     # otherwise, s/?/shift @sqlv/ to put it inline
1093     if (wantarray) {
1094         return ($sql, @sqlv);
1095     } else {
1096         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1097                              ref $d ? $d->[1] : $d/e;
1098         return $sql;
1099     }
1100 }
1101
1102
1103 sub DESTROY { 1 }
1104
1105 sub AUTOLOAD {
1106     # This allows us to check for a local, then _form, attr
1107     my $self = shift;
1108     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1109     return $self->generate($name, @_);
1110 }
1111
1112 1;
1113
1114
1115
1116 __END__
1117
1118 =head1 NAME
1119
1120 SQL::Abstract - Generate SQL from Perl data structures
1121
1122 =head1 SYNOPSIS
1123
1124     use SQL::Abstract;
1125
1126     my $sql = SQL::Abstract->new;
1127
1128     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1129
1130     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1131
1132     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1133
1134     my($stmt, @bind) = $sql->delete($table, \%where);
1135
1136     # Then, use these in your DBI statements
1137     my $sth = $dbh->prepare($stmt);
1138     $sth->execute(@bind);
1139
1140     # Just generate the WHERE clause
1141     my($stmt, @bind) = $sql->where(\%where, \@order);
1142
1143     # Return values in the same order, for hashed queries
1144     # See PERFORMANCE section for more details
1145     my @bind = $sql->values(\%fieldvals);
1146
1147 =head1 DESCRIPTION
1148
1149 This module was inspired by the excellent L<DBIx::Abstract>.
1150 However, in using that module I found that what I really wanted
1151 to do was generate SQL, but still retain complete control over my
1152 statement handles and use the DBI interface. So, I set out to
1153 create an abstract SQL generation module.
1154
1155 While based on the concepts used by L<DBIx::Abstract>, there are
1156 several important differences, especially when it comes to WHERE
1157 clauses. I have modified the concepts used to make the SQL easier
1158 to generate from Perl data structures and, IMO, more intuitive.
1159 The underlying idea is for this module to do what you mean, based
1160 on the data structures you provide it. The big advantage is that
1161 you don't have to modify your code every time your data changes,
1162 as this module figures it out.
1163
1164 To begin with, an SQL INSERT is as easy as just specifying a hash
1165 of C<key=value> pairs:
1166
1167     my %data = (
1168         name => 'Jimbo Bobson',
1169         phone => '123-456-7890',
1170         address => '42 Sister Lane',
1171         city => 'St. Louis',
1172         state => 'Louisiana',
1173     );
1174
1175 The SQL can then be generated with this:
1176
1177     my($stmt, @bind) = $sql->insert('people', \%data);
1178
1179 Which would give you something like this:
1180
1181     $stmt = "INSERT INTO people
1182                     (address, city, name, phone, state)
1183                     VALUES (?, ?, ?, ?, ?)";
1184     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1185              '123-456-7890', 'Louisiana');
1186
1187 These are then used directly in your DBI code:
1188
1189     my $sth = $dbh->prepare($stmt);
1190     $sth->execute(@bind);
1191
1192 =head2 Inserting and Updating Arrays
1193
1194 If your database has array types (like for example Postgres),
1195 activate the special option C<< array_datatypes => 1 >>
1196 when creating the C<SQL::Abstract> object.
1197 Then you may use an arrayref to insert and update database array types:
1198
1199     my $sql = SQL::Abstract->new(array_datatypes => 1);
1200     my %data = (
1201         planets => [qw/Mercury Venus Earth Mars/]
1202     );
1203
1204     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1205
1206 This results in:
1207
1208     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1209
1210     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1211
1212
1213 =head2 Inserting and Updating SQL
1214
1215 In order to apply SQL functions to elements of your C<%data> you may
1216 specify a reference to an arrayref for the given hash value. For example,
1217 if you need to execute the Oracle C<to_date> function on a value, you can
1218 say something like this:
1219
1220     my %data = (
1221         name => 'Bill',
1222         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1223     );
1224
1225 The first value in the array is the actual SQL. Any other values are
1226 optional and would be included in the bind values array. This gives
1227 you:
1228
1229     my($stmt, @bind) = $sql->insert('people', \%data);
1230
1231     $stmt = "INSERT INTO people (name, date_entered)
1232                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1233     @bind = ('Bill', '03/02/2003');
1234
1235 An UPDATE is just as easy, all you change is the name of the function:
1236
1237     my($stmt, @bind) = $sql->update('people', \%data);
1238
1239 Notice that your C<%data> isn't touched; the module will generate
1240 the appropriately quirky SQL for you automatically. Usually you'll
1241 want to specify a WHERE clause for your UPDATE, though, which is
1242 where handling C<%where> hashes comes in handy...
1243
1244 =head2 Complex where statements
1245
1246 This module can generate pretty complicated WHERE statements
1247 easily. For example, simple C<key=value> pairs are taken to mean
1248 equality, and if you want to see if a field is within a set
1249 of values, you can use an arrayref. Let's say we wanted to
1250 SELECT some data based on this criteria:
1251
1252     my %where = (
1253        requestor => 'inna',
1254        worker => ['nwiger', 'rcwe', 'sfz'],
1255        status => { '!=', 'completed' }
1256     );
1257
1258     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1259
1260 The above would give you something like this:
1261
1262     $stmt = "SELECT * FROM tickets WHERE
1263                 ( requestor = ? ) AND ( status != ? )
1264                 AND ( worker = ? OR worker = ? OR worker = ? )";
1265     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1266
1267 Which you could then use in DBI code like so:
1268
1269     my $sth = $dbh->prepare($stmt);
1270     $sth->execute(@bind);
1271
1272 Easy, eh?
1273
1274 =head1 FUNCTIONS
1275
1276 The functions are simple. There's one for each major SQL operation,
1277 and a constructor you use first. The arguments are specified in a
1278 similar order to each function (table, then fields, then a where
1279 clause) to try and simplify things.
1280
1281
1282
1283
1284 =head2 new(option => 'value')
1285
1286 The C<new()> function takes a list of options and values, and returns
1287 a new B<SQL::Abstract> object which can then be used to generate SQL
1288 through the methods below. The options accepted are:
1289
1290 =over
1291
1292 =item case
1293
1294 If set to 'lower', then SQL will be generated in all lowercase. By
1295 default SQL is generated in "textbook" case meaning something like:
1296
1297     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1298
1299 Any setting other than 'lower' is ignored.
1300
1301 =item cmp
1302
1303 This determines what the default comparison operator is. By default
1304 it is C<=>, meaning that a hash like this:
1305
1306     %where = (name => 'nwiger', email => 'nate@wiger.org');
1307
1308 Will generate SQL like this:
1309
1310     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1311
1312 However, you may want loose comparisons by default, so if you set
1313 C<cmp> to C<like> you would get SQL such as:
1314
1315     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1316
1317 You can also override the comparsion on an individual basis - see
1318 the huge section on L</"WHERE CLAUSES"> at the bottom.
1319
1320 =item sqltrue, sqlfalse
1321
1322 Expressions for inserting boolean values within SQL statements.
1323 By default these are C<1=1> and C<1=0>. They are used
1324 by the special operators C<-in> and C<-not_in> for generating
1325 correct SQL even when the argument is an empty array (see below).
1326
1327 =item logic
1328
1329 This determines the default logical operator for multiple WHERE
1330 statements in arrays or hashes. If absent, the default logic is "or"
1331 for arrays, and "and" for hashes. This means that a WHERE
1332 array of the form:
1333
1334     @where = (
1335         event_date => {'>=', '2/13/99'},
1336         event_date => {'<=', '4/24/03'},
1337     );
1338
1339 will generate SQL like this:
1340
1341     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1342
1343 This is probably not what you want given this query, though (look
1344 at the dates). To change the "OR" to an "AND", simply specify:
1345
1346     my $sql = SQL::Abstract->new(logic => 'and');
1347
1348 Which will change the above C<WHERE> to:
1349
1350     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1351
1352 The logic can also be changed locally by inserting
1353 a modifier in front of an arrayref :
1354
1355     @where = (-and => [event_date => {'>=', '2/13/99'},
1356                        event_date => {'<=', '4/24/03'} ]);
1357
1358 See the L</"WHERE CLAUSES"> section for explanations.
1359
1360 =item convert
1361
1362 This will automatically convert comparisons using the specified SQL
1363 function for both column and value. This is mostly used with an argument
1364 of C<upper> or C<lower>, so that the SQL will have the effect of
1365 case-insensitive "searches". For example, this:
1366
1367     $sql = SQL::Abstract->new(convert => 'upper');
1368     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1369
1370 Will turn out the following SQL:
1371
1372     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1373
1374 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1375 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1376 not validate this option; it will just pass through what you specify verbatim).
1377
1378 =item bindtype
1379
1380 This is a kludge because many databases suck. For example, you can't
1381 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1382 Instead, you have to use C<bind_param()>:
1383
1384     $sth->bind_param(1, 'reg data');
1385     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1386
1387 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1388 which loses track of which field each slot refers to. Fear not.
1389
1390 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1391 Currently, you can specify either C<normal> (default) or C<columns>. If you
1392 specify C<columns>, you will get an array that looks like this:
1393
1394     my $sql = SQL::Abstract->new(bindtype => 'columns');
1395     my($stmt, @bind) = $sql->insert(...);
1396
1397     @bind = (
1398         [ 'column1', 'value1' ],
1399         [ 'column2', 'value2' ],
1400         [ 'column3', 'value3' ],
1401     );
1402
1403 You can then iterate through this manually, using DBI's C<bind_param()>.
1404
1405     $sth->prepare($stmt);
1406     my $i = 1;
1407     for (@bind) {
1408         my($col, $data) = @$_;
1409         if ($col eq 'details' || $col eq 'comments') {
1410             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1411         } elsif ($col eq 'image') {
1412             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1413         } else {
1414             $sth->bind_param($i, $data);
1415         }
1416         $i++;
1417     }
1418     $sth->execute;      # execute without @bind now
1419
1420 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1421 Basically, the advantage is still that you don't have to care which fields
1422 are or are not included. You could wrap that above C<for> loop in a simple
1423 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1424 get a layer of abstraction over manual SQL specification.
1425
1426 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1427 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1428 will expect the bind values in this format.
1429
1430 =item quote_char
1431
1432 This is the character that a table or column name will be quoted
1433 with.  By default this is an empty string, but you could set it to
1434 the character C<`>, to generate SQL like this:
1435
1436   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1437
1438 Alternatively, you can supply an array ref of two items, the first being the left
1439 hand quote character, and the second the right hand quote character. For
1440 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1441 that generates SQL like this:
1442
1443   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1444
1445 Quoting is useful if you have tables or columns names that are reserved
1446 words in your database's SQL dialect.
1447
1448 =item name_sep
1449
1450 This is the character that separates a table and column name.  It is
1451 necessary to specify this when the C<quote_char> option is selected,
1452 so that tables and column names can be individually quoted like this:
1453
1454   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1455
1456 =item array_datatypes
1457
1458 When this option is true, arrayrefs in INSERT or UPDATE are
1459 interpreted as array datatypes and are passed directly
1460 to the DBI layer.
1461 When this option is false, arrayrefs are interpreted
1462 as literal SQL, just like refs to arrayrefs
1463 (but this behavior is for backwards compatibility; when writing
1464 new queries, use the "reference to arrayref" syntax
1465 for literal SQL).
1466
1467
1468 =item special_ops
1469
1470 Takes a reference to a list of "special operators"
1471 to extend the syntax understood by L<SQL::Abstract>.
1472 See section L</"SPECIAL OPERATORS"> for details.
1473
1474
1475
1476 =back
1477
1478 =head2 insert($table, \@values || \%fieldvals)
1479
1480 This is the simplest function. You simply give it a table name
1481 and either an arrayref of values or hashref of field/value pairs.
1482 It returns an SQL INSERT statement and a list of bind values.
1483 See the sections on L</"Inserting and Updating Arrays"> and
1484 L</"Inserting and Updating SQL"> for information on how to insert
1485 with those data types.
1486
1487 =head2 update($table, \%fieldvals, \%where)
1488
1489 This takes a table, hashref of field/value pairs, and an optional
1490 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1491 of bind values.
1492 See the sections on L</"Inserting and Updating Arrays"> and
1493 L</"Inserting and Updating SQL"> for information on how to insert
1494 with those data types.
1495
1496 =head2 select($source, $fields, $where, $order)
1497
1498 This returns a SQL SELECT statement and associated list of bind values, as
1499 specified by the arguments  :
1500
1501 =over
1502
1503 =item $source
1504
1505 Specification of the 'FROM' part of the statement.
1506 The argument can be either a plain scalar (interpreted as a table
1507 name, will be quoted), or an arrayref (interpreted as a list
1508 of table names, joined by commas, quoted), or a scalarref
1509 (literal table name, not quoted), or a ref to an arrayref
1510 (list of literal table names, joined by commas, not quoted).
1511
1512 =item $fields
1513
1514 Specification of the list of fields to retrieve from
1515 the source.
1516 The argument can be either an arrayref (interpreted as a list
1517 of field names, will be joined by commas and quoted), or a
1518 plain scalar (literal SQL, not quoted).
1519 Please observe that this API is not as flexible as for
1520 the first argument C<$table>, for backwards compatibility reasons.
1521
1522 =item $where
1523
1524 Optional argument to specify the WHERE part of the query.
1525 The argument is most often a hashref, but can also be
1526 an arrayref or plain scalar --
1527 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1528
1529 =item $order
1530
1531 Optional argument to specify the ORDER BY part of the query.
1532 The argument can be a scalar, a hashref or an arrayref
1533 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1534 for details.
1535
1536 =back
1537
1538
1539 =head2 delete($table, \%where)
1540
1541 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1542 It returns an SQL DELETE statement and list of bind values.
1543
1544 =head2 where(\%where, \@order)
1545
1546 This is used to generate just the WHERE clause. For example,
1547 if you have an arbitrary data structure and know what the
1548 rest of your SQL is going to look like, but want an easy way
1549 to produce a WHERE clause, use this. It returns an SQL WHERE
1550 clause and list of bind values.
1551
1552
1553 =head2 values(\%data)
1554
1555 This just returns the values from the hash C<%data>, in the same
1556 order that would be returned from any of the other above queries.
1557 Using this allows you to markedly speed up your queries if you
1558 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1559
1560 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1561
1562 Warning: This is an experimental method and subject to change.
1563
1564 This returns arbitrarily generated SQL. It's a really basic shortcut.
1565 It will return two different things, depending on return context:
1566
1567     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1568     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
1569
1570 These would return the following:
1571
1572     # First calling form
1573     $stmt = "CREATE TABLE test (?, ?)";
1574     @bind = (field1, field2);
1575
1576     # Second calling form
1577     $stmt_and_val = "CREATE TABLE test (field1, field2)";
1578
1579 Depending on what you're trying to do, it's up to you to choose the correct
1580 format. In this example, the second form is what you would want.
1581
1582 By the same token:
1583
1584     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
1585
1586 Might give you:
1587
1588     ALTER SESSION SET nls_date_format = 'MM/YY'
1589
1590 You get the idea. Strings get their case twiddled, but everything
1591 else remains verbatim.
1592
1593
1594
1595
1596 =head1 WHERE CLAUSES
1597
1598 =head2 Introduction
1599
1600 This module uses a variation on the idea from L<DBIx::Abstract>. It
1601 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
1602 module is that things in arrays are OR'ed, and things in hashes
1603 are AND'ed.>
1604
1605 The easiest way to explain is to show lots of examples. After
1606 each C<%where> hash shown, it is assumed you used:
1607
1608     my($stmt, @bind) = $sql->where(\%where);
1609
1610 However, note that the C<%where> hash can be used directly in any
1611 of the other functions as well, as described above.
1612
1613 =head2 Key-value pairs
1614
1615 So, let's get started. To begin, a simple hash:
1616
1617     my %where  = (
1618         user   => 'nwiger',
1619         status => 'completed'
1620     );
1621
1622 Is converted to SQL C<key = val> statements:
1623
1624     $stmt = "WHERE user = ? AND status = ?";
1625     @bind = ('nwiger', 'completed');
1626
1627 One common thing I end up doing is having a list of values that
1628 a field can be in. To do this, simply specify a list inside of
1629 an arrayref:
1630
1631     my %where  = (
1632         user   => 'nwiger',
1633         status => ['assigned', 'in-progress', 'pending'];
1634     );
1635
1636 This simple code will create the following:
1637
1638     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
1639     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
1640
1641 A field associated to an empty arrayref will be considered a
1642 logical false and will generate 0=1.
1643
1644 =head2 Specific comparison operators
1645
1646 If you want to specify a different type of operator for your comparison,
1647 you can use a hashref for a given column:
1648
1649     my %where  = (
1650         user   => 'nwiger',
1651         status => { '!=', 'completed' }
1652     );
1653
1654 Which would generate:
1655
1656     $stmt = "WHERE user = ? AND status != ?";
1657     @bind = ('nwiger', 'completed');
1658
1659 To test against multiple values, just enclose the values in an arrayref:
1660
1661     status => { '=', ['assigned', 'in-progress', 'pending'] };
1662
1663 Which would give you:
1664
1665     "WHERE status = ? OR status = ? OR status = ?"
1666
1667
1668 The hashref can also contain multiple pairs, in which case it is expanded
1669 into an C<AND> of its elements:
1670
1671     my %where  = (
1672         user   => 'nwiger',
1673         status => { '!=', 'completed', -not_like => 'pending%' }
1674     );
1675
1676     # Or more dynamically, like from a form
1677     $where{user} = 'nwiger';
1678     $where{status}{'!='} = 'completed';
1679     $where{status}{'-not_like'} = 'pending%';
1680
1681     # Both generate this
1682     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
1683     @bind = ('nwiger', 'completed', 'pending%');
1684
1685
1686 To get an OR instead, you can combine it with the arrayref idea:
1687
1688     my %where => (
1689          user => 'nwiger',
1690          priority => [ {'=', 2}, {'!=', 1} ]
1691     );
1692
1693 Which would generate:
1694
1695     $stmt = "WHERE user = ? AND priority = ? OR priority != ?";
1696     @bind = ('nwiger', '2', '1');
1697
1698 If you want to include literal SQL (with or without bind values), just use a
1699 scalar reference or array reference as the value:
1700
1701     my %where  = (
1702         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
1703         date_expires => { '<' => \"now()" }
1704     );
1705
1706 Which would generate:
1707
1708     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
1709     @bind = ('11/26/2008');
1710
1711
1712 =head2 Logic and nesting operators
1713
1714 In the example above,
1715 there is a subtle trap if you want to say something like
1716 this (notice the C<AND>):
1717
1718     WHERE priority != ? AND priority != ?
1719
1720 Because, in Perl you I<can't> do this:
1721
1722     priority => { '!=', 2, '!=', 1 }
1723
1724 As the second C<!=> key will obliterate the first. The solution
1725 is to use the special C<-modifier> form inside an arrayref:
1726
1727     priority => [ -and => {'!=', 2},
1728                           {'!=', 1} ]
1729
1730
1731 Normally, these would be joined by C<OR>, but the modifier tells it
1732 to use C<AND> instead. (Hint: You can use this in conjunction with the
1733 C<logic> option to C<new()> in order to change the way your queries
1734 work by default.) B<Important:> Note that the C<-modifier> goes
1735 B<INSIDE> the arrayref, as an extra first element. This will
1736 B<NOT> do what you think it might:
1737
1738     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
1739
1740 Here is a quick list of equivalencies, since there is some overlap:
1741
1742     # Same
1743     status => {'!=', 'completed', 'not like', 'pending%' }
1744     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
1745
1746     # Same
1747     status => {'=', ['assigned', 'in-progress']}
1748     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
1749     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
1750
1751
1752
1753 =head2 Special operators : IN, BETWEEN, etc.
1754
1755 You can also use the hashref format to compare a list of fields using the
1756 C<IN> comparison operator, by specifying the list as an arrayref:
1757
1758     my %where  = (
1759         status   => 'completed',
1760         reportid => { -in => [567, 2335, 2] }
1761     );
1762
1763 Which would generate:
1764
1765     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
1766     @bind = ('completed', '567', '2335', '2');
1767
1768 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
1769 the same way.
1770
1771 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
1772 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
1773 'sqltrue' (by default : C<1=1>).
1774
1775
1776
1777 Another pair of operators is C<-between> and C<-not_between>,
1778 used with an arrayref of two values:
1779
1780     my %where  = (
1781         user   => 'nwiger',
1782         completion_date => {
1783            -not_between => ['2002-10-01', '2003-02-06']
1784         }
1785     );
1786
1787 Would give you:
1788
1789     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
1790
1791 These are the two builtin "special operators"; but the
1792 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
1793
1794 =head2 Nested conditions, -and/-or prefixes
1795
1796 So far, we've seen how multiple conditions are joined with a top-level
1797 C<AND>.  We can change this by putting the different conditions we want in
1798 hashes and then putting those hashes in an array. For example:
1799
1800     my @where = (
1801         {
1802             user   => 'nwiger',
1803             status => { -like => ['pending%', 'dispatched'] },
1804         },
1805         {
1806             user   => 'robot',
1807             status => 'unassigned',
1808         }
1809     );
1810
1811 This data structure would create the following:
1812
1813     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
1814                 OR ( user = ? AND status = ? ) )";
1815     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
1816
1817
1818 There is also a special C<-nest>
1819 operator which adds an additional set of parens, to create a subquery.
1820 For example, to get something like this:
1821
1822     $stmt = "WHERE user = ? AND ( workhrs > ? OR geo = ? )";
1823     @bind = ('nwiger', '20', 'ASIA');
1824
1825 You would do:
1826
1827     my %where = (
1828          user => 'nwiger',
1829         -nest => [ workhrs => {'>', 20}, geo => 'ASIA' ],
1830     );
1831
1832
1833 Finally, clauses in hashrefs or arrayrefs can be
1834 prefixed with an C<-and> or C<-or> to change the logic
1835 inside :
1836
1837     my @where = (
1838          -and => [
1839             user => 'nwiger',
1840             -nest => [
1841                 -and => [workhrs => {'>', 20}, geo => 'ASIA' ],
1842                 -and => [workhrs => {'<', 50}, geo => 'EURO' ]
1843             ],
1844         ],
1845     );
1846
1847 That would yield:
1848
1849     WHERE ( user = ? AND
1850           ( ( workhrs > ? AND geo = ? )
1851          OR ( workhrs < ? AND geo = ? ) ) )
1852
1853
1854 =head2 Algebraic inconsistency, for historical reasons
1855
1856 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
1857 operator goes C<outside> of the nested structure; whereas when connecting
1858 several constraints on one column, the C<-and> operator goes
1859 C<inside> the arrayref. Here is an example combining both features :
1860
1861    my @where = (
1862      -and => [a => 1, b => 2],
1863      -or  => [c => 3, d => 4],
1864       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
1865    )
1866
1867 yielding
1868
1869   WHERE ( (    ( a = ? AND b = ? )
1870             OR ( c = ? OR d = ? )
1871             OR ( e LIKE ? AND e LIKE ? ) ) )
1872
1873 This difference in syntax is unfortunate but must be preserved for
1874 historical reasons. So be careful : the two examples below would
1875 seem algebraically equivalent, but they are not
1876
1877   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
1878   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
1879
1880   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
1881   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
1882
1883
1884 =head2 Literal SQL
1885
1886 Finally, sometimes only literal SQL will do. If you want to include
1887 literal SQL verbatim, you can specify it as a scalar reference, namely:
1888
1889     my $inn = 'is Not Null';
1890     my %where = (
1891         priority => { '<', 2 },
1892         requestor => \$inn
1893     );
1894
1895 This would create:
1896
1897     $stmt = "WHERE priority < ? AND requestor is Not Null";
1898     @bind = ('2');
1899
1900 Note that in this example, you only get one bind parameter back, since
1901 the verbatim SQL is passed as part of the statement.
1902
1903 Of course, just to prove a point, the above can also be accomplished
1904 with this:
1905
1906     my %where = (
1907         priority  => { '<', 2 },
1908         requestor => { '!=', undef },
1909     );
1910
1911
1912 TMTOWTDI.
1913
1914 Conditions on boolean columns can be expressed in the
1915 same way, passing a reference to an empty string :
1916
1917     my %where = (
1918         priority  => { '<', 2 },
1919         is_ready  => \"";
1920     );
1921
1922 which yields
1923
1924     $stmt = "WHERE priority < ? AND is_ready";
1925     @bind = ('2');
1926
1927
1928 =head2 Literal SQL with placeholders and bind values (subqueries)
1929
1930 If the literal SQL to be inserted has placeholders and bind values,
1931 use a reference to an arrayref (yes this is a double reference --
1932 not so common, but perfectly legal Perl). For example, to find a date
1933 in Postgres you can use something like this:
1934
1935     my %where = (
1936        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
1937     )
1938
1939 This would create:
1940
1941     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
1942     @bind = ('10');
1943
1944 Note that you must pass the bind values in the same format as they are returned
1945 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
1946 provide the bind values in the C<< [ column_meta => value ] >> format, where
1947 C<column_meta> is an opaque scalar value; most commonly the column name, but
1948 you can use any scalar value (including references and blessed references),
1949 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
1950 to C<columns> the above example will look like:
1951
1952     my %where = (
1953        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
1954     )
1955
1956 Literal SQL is especially useful for nesting parenthesized clauses in the
1957 main SQL query. Here is a first example :
1958
1959   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
1960                                100, "foo%");
1961   my %where = (
1962     foo => 1234,
1963     bar => \["IN ($sub_stmt)" => @sub_bind],
1964   );
1965
1966 This yields :
1967
1968   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
1969                                              WHERE c2 < ? AND c3 LIKE ?))";
1970   @bind = (1234, 100, "foo%");
1971
1972 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
1973 are expressed in the same way. Of course the C<$sub_stmt> and
1974 its associated bind values can be generated through a former call
1975 to C<select()> :
1976
1977   my ($sub_stmt, @sub_bind)
1978      = $sql->select("t1", "c1", {c2 => {"<" => 100},
1979                                  c3 => {-like => "foo%"}});
1980   my %where = (
1981     foo => 1234,
1982     bar => \["> ALL ($sub_stmt)" => @sub_bind],
1983   );
1984
1985 In the examples above, the subquery was used as an operator on a column;
1986 but the same principle also applies for a clause within the main C<%where>
1987 hash, like an EXISTS subquery :
1988
1989   my ($sub_stmt, @sub_bind)
1990      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
1991   my %where = (
1992     foo   => 1234,
1993     -nest => \["EXISTS ($sub_stmt)" => @sub_bind],
1994   );
1995
1996 which yields
1997
1998   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
1999                                         WHERE c1 = ? AND c2 > t0.c0))";
2000   @bind = (1234, 1);
2001
2002
2003 Observe that the condition on C<c2> in the subquery refers to
2004 column C<t0.c0> of the main query : this is I<not> a bind
2005 value, so we have to express it through a scalar ref.
2006 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2007 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2008 what we wanted here.
2009
2010 Another use of the subquery technique is when some SQL clauses need
2011 parentheses, as it often occurs with some proprietary SQL extensions
2012 like for example fulltext expressions, geospatial expressions,
2013 NATIVE clauses, etc. Here is an example of a fulltext query in MySQL :
2014
2015   my %where = (
2016     -nest => \["MATCH (col1, col2) AGAINST (?)" => qw/apples/]
2017   );
2018
2019 Finally, here is an example where a subquery is used
2020 for expressing unary negation:
2021
2022   my ($sub_stmt, @sub_bind)
2023      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2024   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2025   my %where = (
2026         lname  => {like => '%son%'},
2027         -nest  => \["NOT ($sub_stmt)" => @sub_bind],
2028     );
2029
2030 This yields
2031
2032   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2033   @bind = ('%son%', 10, 20)
2034
2035
2036
2037 =head2 Conclusion
2038
2039 These pages could go on for a while, since the nesting of the data
2040 structures this module can handle are pretty much unlimited (the
2041 module implements the C<WHERE> expansion as a recursive function
2042 internally). Your best bet is to "play around" with the module a
2043 little to see how the data structures behave, and choose the best
2044 format for your data based on that.
2045
2046 And of course, all the values above will probably be replaced with
2047 variables gotten from forms or the command line. After all, if you
2048 knew everything ahead of time, you wouldn't have to worry about
2049 dynamically-generating SQL and could just hardwire it into your
2050 script.
2051
2052
2053
2054
2055 =head1 ORDER BY CLAUSES
2056
2057 Some functions take an order by clause. This can either be a scalar (just a
2058 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2059 or an array of either of the two previous forms. Examples:
2060
2061              Given             |    Will Generate
2062     ----------------------------------------------------------
2063     \'colA DESC'               | ORDER BY colA DESC
2064     'colA'                     | ORDER BY colA
2065     [qw/colA colB/]            | ORDER BY colA, colB
2066     {-asc  => 'colA'}          | ORDER BY colA ASC
2067     {-desc => 'colB'}          | ORDER BY colB DESC
2068     [                          |
2069       {-asc  => 'colA'},       | ORDER BY colA ASC, colB DESC
2070       {-desc => 'colB'}        |
2071     ]                          |
2072     [colA => {-asc => 'colB'}] | ORDER BY colA, colB ASC
2073     ==========================================================
2074
2075
2076
2077 =head1 SPECIAL OPERATORS
2078
2079   my $sqlmaker = SQL::Abstract->new(special_ops => [
2080      {regex => qr/.../,
2081       handler => sub {
2082         my ($self, $field, $op, $arg) = @_;
2083         ...
2084         },
2085      },
2086    ]);
2087
2088 A "special operator" is a SQL syntactic clause that can be
2089 applied to a field, instead of a usual binary operator.
2090 For example :
2091
2092    WHERE field IN (?, ?, ?)
2093    WHERE field BETWEEN ? AND ?
2094    WHERE MATCH(field) AGAINST (?, ?)
2095
2096 Special operators IN and BETWEEN are fairly standard and therefore
2097 are builtin within C<SQL::Abstract>. For other operators,
2098 like the MATCH .. AGAINST example above which is
2099 specific to MySQL, you can write your own operator handlers :
2100 supply a C<special_ops> argument to the C<new> method.
2101 That argument takes an arrayref of operator definitions;
2102 each operator definition is a hashref with two entries
2103
2104 =over
2105
2106 =item regex
2107
2108 the regular expression to match the operator
2109
2110 =item handler
2111
2112 coderef that will be called when meeting that operator
2113 in the input tree. The coderef will be called with
2114 arguments  C<< ($self, $field, $op, $arg) >>, and
2115 should return a C<< ($sql, @bind) >> structure.
2116
2117 =back
2118
2119 For example, here is an implementation
2120 of the MATCH .. AGAINST syntax for MySQL
2121
2122   my $sqlmaker = SQL::Abstract->new(special_ops => [
2123
2124     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2125     {regex => qr/^match$/i,
2126      handler => sub {
2127        my ($self, $field, $op, $arg) = @_;
2128        $arg = [$arg] if not ref $arg;
2129        my $label         = $self->_quote($field);
2130        my ($placeholder) = $self->_convert('?');
2131        my $placeholders  = join ", ", (($placeholder) x @$arg);
2132        my $sql           = $self->_sqlcase('match') . " ($label) "
2133                          . $self->_sqlcase('against') . " ($placeholders) ";
2134        my @bind = $self->_bindtype($field, @$arg);
2135        return ($sql, @bind);
2136        }
2137      },
2138
2139   ]);
2140
2141
2142 =head1 PERFORMANCE
2143
2144 Thanks to some benchmarking by Mark Stosberg, it turns out that
2145 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2146 I must admit this wasn't an intentional design issue, but it's a
2147 byproduct of the fact that you get to control your C<DBI> handles
2148 yourself.
2149
2150 To maximize performance, use a code snippet like the following:
2151
2152     # prepare a statement handle using the first row
2153     # and then reuse it for the rest of the rows
2154     my($sth, $stmt);
2155     for my $href (@array_of_hashrefs) {
2156         $stmt ||= $sql->insert('table', $href);
2157         $sth  ||= $dbh->prepare($stmt);
2158         $sth->execute($sql->values($href));
2159     }
2160
2161 The reason this works is because the keys in your C<$href> are sorted
2162 internally by B<SQL::Abstract>. Thus, as long as your data retains
2163 the same structure, you only have to generate the SQL the first time
2164 around. On subsequent queries, simply use the C<values> function provided
2165 by this module to return your values in the correct order.
2166
2167
2168 =head1 FORMBUILDER
2169
2170 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2171 really like this part (I do, at least). Building up a complex query
2172 can be as simple as the following:
2173
2174     #!/usr/bin/perl
2175
2176     use CGI::FormBuilder;
2177     use SQL::Abstract;
2178
2179     my $form = CGI::FormBuilder->new(...);
2180     my $sql  = SQL::Abstract->new;
2181
2182     if ($form->submitted) {
2183         my $field = $form->field;
2184         my $id = delete $field->{id};
2185         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2186     }
2187
2188 Of course, you would still have to connect using C<DBI> to run the
2189 query, but the point is that if you make your form look like your
2190 table, the actual query script can be extremely simplistic.
2191
2192 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2193 a fast interface to returning and formatting data. I frequently
2194 use these three modules together to write complex database query
2195 apps in under 50 lines.
2196
2197
2198 =head1 CHANGES
2199
2200 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2201 Great care has been taken to preserve the I<published> behavior
2202 documented in previous versions in the 1.* family; however,
2203 some features that were previously undocumented, or behaved
2204 differently from the documentation, had to be changed in order
2205 to clarify the semantics. Hence, client code that was relying
2206 on some dark areas of C<SQL::Abstract> v1.*
2207 B<might behave differently> in v1.50.
2208
2209 The main changes are :
2210
2211 =over
2212
2213 =item *
2214
2215 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2216
2217 =item *
2218
2219 support for the { operator => \"..." } construct (to embed literal SQL)
2220
2221 =item *
2222
2223 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2224
2225 =item *
2226
2227 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2228
2229 =item *
2230
2231 defensive programming : check arguments
2232
2233 =item *
2234
2235 fixed bug with global logic, which was previously implemented
2236 through global variables yielding side-effects. Prior versions would
2237 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2238 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2239 Now this is interpreted
2240 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2241
2242
2243 =item *
2244
2245 fixed semantics of  _bindtype on array args
2246
2247 =item *
2248
2249 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2250 we just avoid shifting arrays within that tree.
2251
2252 =item *
2253
2254 dropped the C<_modlogic> function
2255
2256 =back
2257
2258
2259
2260 =head1 ACKNOWLEDGEMENTS
2261
2262 There are a number of individuals that have really helped out with
2263 this module. Unfortunately, most of them submitted bugs via CPAN
2264 so I have no idea who they are! But the people I do know are:
2265
2266     Ash Berlin (order_by hash term support)
2267     Matt Trout (DBIx::Class support)
2268     Mark Stosberg (benchmarking)
2269     Chas Owens (initial "IN" operator support)
2270     Philip Collins (per-field SQL functions)
2271     Eric Kolve (hashref "AND" support)
2272     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2273     Dan Kubb (support for "quote_char" and "name_sep")
2274     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2275     Laurent Dami (internal refactoring, multiple -nest, extensible list of special operators, literal SQL)
2276     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2277
2278 Thanks!
2279
2280 =head1 SEE ALSO
2281
2282 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2283
2284 =head1 AUTHOR
2285
2286 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2287
2288 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2289
2290 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2291 While not an official support venue, C<DBIx::Class> makes heavy use of
2292 C<SQL::Abstract>, and as such list members there are very familiar with
2293 how to create queries.
2294
2295 This module is free software; you may copy this under the terms of
2296 the GNU General Public License, or the Artistic License, copies of
2297 which should have accompanied your Perl kit.
2298
2299 =cut
2300