lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use Carp;
   9 use strict;
  10 use warnings;
  11 use List::Util   qw/first/;
  12 use Scalar::Util qw/blessed/;
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.50';
  19
  20 # This would confuse some packagers
  21 #$VERSION      = eval $VERSION; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^(not )?between$/i, handler => \&_where_field_BETWEEN},
  29   {regex => qr/^(not )?in$/i,      handler => \&_where_field_IN},
  30 );
  31
  32 #======================================================================
  33 # DEBUGGING AND ERROR REPORTING
  34 #======================================================================
  35
  36 sub _debug {
  37   return unless $_[0]->{debug}; shift; # a little faster
  38   my $func = (caller(1))[3];
  39   warn "[$func] ", @_, "\n";
  40 }
  41
  42 sub belch (@) {
  43   my($func) = (caller(1))[3];
  44   carp "[$func] Warning: ", @_;
  45 }
  46
  47 sub puke (@) {
  48   my($func) = (caller(1))[3];
  49   croak "[$func] Fatal: ", @_;
  50 }
  51
  52
  53 #======================================================================
  54 # NEW
  55 #======================================================================
  56
  57 sub new {
  58   my $self = shift;
  59   my $class = ref($self) || $self;
  60   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  61
  62   # choose our case by keeping an option around
  63   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  64
  65   # default logic for interpreting arrayrefs
  66   $opt{logic} = uc $opt{logic} || 'OR';
  67
  68   # how to return bind vars
  69   # LDNOTE: changed nwiger code : why this 'delete' ??
  70   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  71   $opt{bindtype} ||= 'normal';
  72
  73   # default comparison is "=", but can be overridden
  74   $opt{cmp} ||= '=';
  75
  76   # try to recognize which are the 'equality' and 'unequality' ops
  77   # (temporary quickfix, should go through a more seasoned API)
  78  $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  79  $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  80
  81   # SQL booleans
  82   $opt{sqltrue}  ||= '1=1';
  83   $opt{sqlfalse} ||= '0=1';
  84
  85   # special operators
  86   $opt{special_ops} ||= [];
  87   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
  88
  89   return bless \%opt, $class;
  90 }
  91
  92
  93
  94 #======================================================================
  95 # INSERT methods
  96 #======================================================================
  97
  98 sub insert {
  99   my $self  = shift;
 100   my $table = $self->_table(shift);
 101   my $data  = shift || return;
 102
 103   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 104   my ($sql, @bind) = $self->$method($data);
 105   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 106   return wantarray ? ($sql, @bind) : $sql;
 107 }
 108
 109 sub _insert_HASHREF { # explicit list of fields and then values
 110   my ($self, $data) = @_;
 111
 112   my @fields = sort keys %$data;
 113
 114   my ($sql, @bind) = $self->_insert_values($data);
 115
 116   # assemble SQL
 117   $_ = $self->_quote($_) foreach @fields;
 118   $sql = "( ".join(", ", @fields).") ".$sql;
 119
 120   return ($sql, @bind);
 121 }
 122
 123 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 124   my ($self, $data) = @_;
 125
 126   # no names (arrayref) so can't generate bindtype
 127   $self->{bindtype} ne 'columns'
 128     or belch "can't do 'columns' bindtype when called with arrayref";
 129
 130   # fold the list of values into a hash of column name - value pairs
 131   # (where the column names are artificially generated, and their
 132   # lexicographical ordering keep the ordering of the original list)
 133   my $i = "a";  # incremented values will be in lexicographical order
 134   my $data_in_hash = { map { ($i++ => $_) } @$data };
 135
 136   return $self->_insert_values($data_in_hash);
 137 }
 138
 139 sub _insert_ARRAYREFREF { # literal SQL with bind
 140   my ($self, $data) = @_;
 141
 142   my ($sql, @bind) = @${$data};
 143   $self->_assert_bindval_matches_bindtype(@bind);
 144
 145   return ($sql, @bind);
 146 }
 147
 148
 149 sub _insert_SCALARREF { # literal SQL without bind
 150   my ($self, $data) = @_;
 151
 152   return ($$data);
 153 }
 154
 155 sub _insert_values {
 156   my ($self, $data) = @_;
 157
 158   my (@values, @all_bind);
 159   foreach my $column (sort keys %$data) {
 160     my $v = $data->{$column};
 161
 162     $self->_SWITCH_refkind($v, {
 163
 164       ARRAYREF => sub {
 165         if ($self->{array_datatypes}) { # if array datatype are activated
 166           push @values, '?';
 167           push @all_bind, $self->_bindtype($column, $v);
 168         }
 169         else {                          # else literal SQL with bind
 170           my ($sql, @bind) = @$v;
 171           $self->_assert_bindval_matches_bindtype(@bind);
 172           push @values, $sql;
 173           push @all_bind, @bind;
 174         }
 175       },
 176
 177       ARRAYREFREF => sub { # literal SQL with bind
 178         my ($sql, @bind) = @${$v};
 179         $self->_assert_bindval_matches_bindtype(@bind);
 180         push @values, $sql;
 181         push @all_bind, @bind;
 182       },
 183
 184       # THINK : anything useful to do with a HASHREF ?
 185       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 186         #TODO in SQLA >= 2.0 it will die instead
 187         belch "HASH ref as bind value in insert is not supported";
 188         push @values, '?';
 189         push @all_bind, $self->_bindtype($column, $v);
 190       },
 191
 192       SCALARREF => sub {  # literal SQL without bind
 193         push @values, $$v;
 194       },
 195
 196       SCALAR_or_UNDEF => sub {
 197         push @values, '?';
 198         push @all_bind, $self->_bindtype($column, $v);
 199       },
 200
 201      });
 202
 203   }
 204
 205   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 206   return ($sql, @all_bind);
 207 }
 208
 209
 210
 211 #======================================================================
 212 # UPDATE methods
 213 #======================================================================
 214
 215
 216 sub update {
 217   my $self  = shift;
 218   my $table = $self->_table(shift);
 219   my $data  = shift || return;
 220   my $where = shift;
 221
 222   # first build the 'SET' part of the sql statement
 223   my (@set, @all_bind);
 224   puke "Unsupported data type specified to \$sql->update"
 225     unless ref $data eq 'HASH';
 226
 227   for my $k (sort keys %$data) {
 228     my $v = $data->{$k};
 229     my $r = ref $v;
 230     my $label = $self->_quote($k);
 231
 232     $self->_SWITCH_refkind($v, {
 233       ARRAYREF => sub {
 234         if ($self->{array_datatypes}) { # array datatype
 235           push @set, "$label = ?";
 236           push @all_bind, $self->_bindtype($k, $v);
 237         }
 238         else {                          # literal SQL with bind
 239           my ($sql, @bind) = @$v;
 240           $self->_assert_bindval_matches_bindtype(@bind);
 241           push @set, "$label = $sql";
 242           push @all_bind, @bind;
 243         }
 244       },
 245       ARRAYREFREF => sub { # literal SQL with bind
 246         my ($sql, @bind) = @${$v};
 247         $self->_assert_bindval_matches_bindtype(@bind);
 248         push @set, "$label = $sql";
 249         push @all_bind, @bind;
 250       },
 251       SCALARREF => sub {  # literal SQL without bind
 252         push @set, "$label = $$v";
 253        },
 254       SCALAR_or_UNDEF => sub {
 255         push @set, "$label = ?";
 256         push @all_bind, $self->_bindtype($k, $v);
 257       },
 258     });
 259   }
 260
 261   # generate sql
 262   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 263           . join ', ', @set;
 264
 265   if ($where) {
 266     my($where_sql, @where_bind) = $self->where($where);
 267     $sql .= $where_sql;
 268     push @all_bind, @where_bind;
 269   }
 270
 271   return wantarray ? ($sql, @all_bind) : $sql;
 272 }
 273
 274
 275
 276
 277 #======================================================================
 278 # SELECT
 279 #======================================================================
 280
 281
 282 sub select {
 283   my $self   = shift;
 284   my $table  = $self->_table(shift);
 285   my $fields = shift || '*';
 286   my $where  = shift;
 287   my $order  = shift;
 288
 289   my($where_sql, @bind) = $self->where($where, $order);
 290
 291   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 292                                    : $fields;
 293   my $sql = join(' ', $self->_sqlcase('select'), $f,
 294                       $self->_sqlcase('from'),   $table)
 295           . $where_sql;
 296
 297   return wantarray ? ($sql, @bind) : $sql;
 298 }
 299
 300 #======================================================================
 301 # DELETE
 302 #======================================================================
 303
 304
 305 sub delete {
 306   my $self  = shift;
 307   my $table = $self->_table(shift);
 308   my $where = shift;
 309
 310
 311   my($where_sql, @bind) = $self->where($where);
 312   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 313
 314   return wantarray ? ($sql, @bind) : $sql;
 315 }
 316
 317
 318 #======================================================================
 319 # WHERE: entry point
 320 #======================================================================
 321
 322
 323
 324 # Finally, a separate routine just to handle WHERE clauses
 325 sub where {
 326   my ($self, $where, $order) = @_;
 327
 328   # where ?
 329   my ($sql, @bind) = $self->_recurse_where($where);
 330   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 331
 332   # order by?
 333   if ($order) {
 334     $sql .= $self->_order_by($order);
 335   }
 336
 337   return wantarray ? ($sql, @bind) : $sql;
 338 }
 339
 340
 341 sub _recurse_where {
 342   my ($self, $where, $logic) = @_;
 343
 344   # dispatch on appropriate method according to refkind of $where
 345   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 346
 347
 348   my ($sql, @bind) =  $self->$method($where, $logic);
 349
 350   # DBIx::Class directly calls _recurse_where in scalar context, so
 351   # we must implement it, even if not in the official API
 352   return wantarray ? ($sql, @bind) : $sql;
 353 }
 354
 355
 356
 357 #======================================================================
 358 # WHERE: top-level ARRAYREF
 359 #======================================================================
 360
 361
 362 sub _where_ARRAYREF {
 363   my ($self, $where, $logic) = @_;
 364
 365   $logic = uc($logic || $self->{logic});
 366   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 367
 368   my @clauses = @$where;
 369
 370   # if the array starts with [-and|or => ...], recurse with that logic
 371   my $first   = $clauses[0] || '';
 372   if ($first =~ /^-(and|or)/i) {
 373     $logic = $1;
 374     shift @clauses;
 375     return $self->_where_ARRAYREF(\@clauses, $logic);
 376   }
 377
 378   #otherwise..
 379   my (@sql_clauses, @all_bind);
 380
 381   # need to use while() so can shift() for pairs
 382   while (my $el = shift @clauses) {
 383
 384     # switch according to kind of $el and get corresponding ($sql, @bind)
 385     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 386
 387       # skip empty elements, otherwise get invalid trailing AND stuff
 388       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 389
 390       ARRAYREFREF => sub { @{${$el}}                 if @{${$el}}},
 391
 392       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 393            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 394            # side-effect: the first hashref within an array would change
 395            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 396            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 397            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 398
 399       SCALARREF => sub { ($$el);                                 },
 400
 401       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 402                         $self->_recurse_where({$el => shift(@clauses)})},
 403
 404       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 405     });
 406
 407     if ($sql) {
 408       push @sql_clauses, $sql;
 409       push @all_bind, @bind;
 410     }
 411   }
 412
 413   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 414 }
 415
 416 #======================================================================
 417 # WHERE: top-level ARRAYREFREF
 418 #======================================================================
 419
 420 sub _where_ARRAYREFREF {
 421     my ($self, $where) = @_;
 422     my ($sql, @bind) = @{${$where}};
 423
 424     return ($sql, @bind);
 425 }
 426
 427 #======================================================================
 428 # WHERE: top-level HASHREF
 429 #======================================================================
 430
 431 sub _where_HASHREF {
 432   my ($self, $where) = @_;
 433   my (@sql_clauses, @all_bind);
 434
 435   # LDNOTE : don't really know why we need to sort keys
 436   for my $k (sort keys %$where) {
 437     my $v = $where->{$k};
 438
 439     # ($k => $v) is either a special op or a regular hashpair
 440     my ($sql, @bind) = ($k =~ /^-(.+)/) ? $self->_where_op_in_hash($1, $v)
 441                                         : do {
 442          my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 443          $self->$method($k, $v);
 444        };
 445
 446     push @sql_clauses, $sql;
 447     push @all_bind, @bind;
 448   }
 449
 450   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 451 }
 452
 453
 454 sub _where_op_in_hash {
 455   my ($self, $op, $v) = @_;
 456
 457   $op =~ /^(AND|OR|NEST)[_\d]*/i
 458     or puke "unknown operator: -$op";
 459   $op = uc($1); # uppercase, remove trailing digits
 460   $self->_debug("OP(-$op) within hashref, recursing...");
 461
 462   $self->_SWITCH_refkind($v, {
 463
 464     ARRAYREF => sub {
 465       # LDNOTE : should deprecate {-or => [...]} and {-and => [...]}
 466       # because they are misleading; the only proper way would be
 467       # -nest => [-or => ...], -nest => [-and ...]
 468       return $self->_where_ARRAYREF($v, $op eq 'NEST' ? '' : $op);
 469     },
 470
 471     HASHREF => sub {
 472       if ($op eq 'OR') {
 473         belch "-or => {...} should be -nest => [...]";
 474         return $self->_where_ARRAYREF([%$v], 'OR');
 475       }
 476       else {                  # NEST | AND
 477         return $self->_where_HASHREF($v);
 478       }
 479     },
 480
 481     SCALARREF  => sub {         # literal SQL
 482       $op eq 'NEST'
 483         or puke "-$op => \\\$scalar not supported, use -nest => ...";
 484       return ($$v);
 485     },
 486
 487     ARRAYREFREF => sub {        # literal SQL
 488       $op eq 'NEST'
 489         or puke "-$op => \\[..] not supported, use -nest => ...";
 490       return @{${$v}};
 491     },
 492
 493     SCALAR => sub { # permissively interpreted as SQL
 494       $op eq 'NEST'
 495         or puke "-$op => 'scalar' not supported, use -nest => \\'scalar'";
 496       belch "literal SQL should be -nest => \\'scalar' "
 497           . "instead of -nest => 'scalar' ";
 498       return ($v);
 499     },
 500
 501     UNDEF => sub {
 502       puke "-$op => undef not supported";
 503     },
 504    });
 505 }
 506
 507
 508 sub _where_hashpair_ARRAYREF {
 509   my ($self, $k, $v) = @_;
 510
 511   if( @$v ) {
 512     my @v = @$v; # need copy because of shift below
 513     $self->_debug("ARRAY($k) means distribute over elements");
 514
 515     # put apart first element if it is an operator (-and, -or)
 516     my $op = $v[0] =~ /^-/ ? shift @v : undef;
 517     $self->_debug("OP($op) reinjected into the distributed array") if $op;
 518
 519     my @distributed = map { {$k =>  $_} } @v;
 520     unshift @distributed, $op if $op;
 521
 522     return $self->_recurse_where(\@distributed);
 523   }
 524   else {
 525     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 526     $self->_debug("empty ARRAY($k) means 0=1");
 527     return ($self->{sqlfalse});
 528   }
 529 }
 530
 531 sub _where_hashpair_HASHREF {
 532   my ($self, $k, $v) = @_;
 533
 534   my (@all_sql, @all_bind);
 535
 536   for my $op (sort keys %$v) {
 537     my $val = $v->{$op};
 538
 539     # put the operator in canonical form
 540     $op =~ s/^-//;       # remove initial dash
 541     $op =~ tr/_/ /;      # underscores become spaces
 542     $op =~ s/^\s+//;     # no initial space
 543     $op =~ s/\s+$//;     # no final space
 544     $op =~ s/\s+/ /;     # multiple spaces become one
 545
 546     my ($sql, @bind);
 547
 548     # CASE: special operators like -in or -between
 549     my $special_op = first {$op =~ $_->{regex}} @{$self->{special_ops}};
 550     if ($special_op) {
 551       ($sql, @bind) = $special_op->{handler}->($self, $k, $op, $val);
 552     }
 553     else {
 554       $self->_SWITCH_refkind($val, {
 555
 556         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 557           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 558         },
 559
 560         SCALARREF => sub {      # CASE: col => {op => \$scalar} (literal SQL without bind)
 561           $sql  = join ' ', $self->_convert($self->_quote($k)),
 562                             $self->_sqlcase($op),
 563                             $$val;
 564         },
 565
 566         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 567           my ($sub_sql, @sub_bind) = @$$val;
 568           $self->_assert_bindval_matches_bindtype(@sub_bind);
 569           $sql  = join ' ', $self->_convert($self->_quote($k)),
 570                             $self->_sqlcase($op),
 571                             $sub_sql;
 572           @bind = @sub_bind;
 573         },
 574
 575         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 576           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 577                    ($op =~ $self->{inequality_op}) ? 'is not' :
 578                puke "unexpected operator '$op' with undef operand";
 579           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 580         },
 581
 582         FALLBACK => sub {       # CASE: col => {op => $scalar}
 583           $sql  = join ' ', $self->_convert($self->_quote($k)),
 584                             $self->_sqlcase($op),
 585                             $self->_convert('?');
 586           @bind = $self->_bindtype($k, $val);
 587         },
 588       });
 589     }
 590
 591     push @all_sql, $sql;
 592     push @all_bind, @bind;
 593   }
 594
 595   return $self->_join_sql_clauses('and', \@all_sql, \@all_bind);
 596 }
 597
 598
 599
 600 sub _where_field_op_ARRAYREF {
 601   my ($self, $k, $op, $vals) = @_;
 602
 603   if(@$vals) {
 604     $self->_debug("ARRAY($vals) means multiple elements: [ @$vals ]");
 605
 606
 607
 608     # LDNOTE : change the distribution logic when
 609     # $op =~ $self->{inequality_op}, because of Morgan laws :
 610     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 611     # WHERE field != 22 OR  field != 33 : the user probably means
 612     # WHERE field != 22 AND field != 33.
 613     my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 614
 615     # distribute $op over each member of @$vals
 616     return $self->_recurse_where([map { {$k => {$op, $_}} } @$vals], $logic);
 617
 618   }
 619   else {
 620     # try to DWIM on equality operators
 621     # LDNOTE : not 100% sure this is the correct thing to do ...
 622     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 623     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 624
 625     # otherwise
 626     puke "operator '$op' applied on an empty array (field '$k')";
 627   }
 628 }
 629
 630
 631 sub _where_hashpair_SCALARREF {
 632   my ($self, $k, $v) = @_;
 633   $self->_debug("SCALAR($k) means literal SQL: $$v");
 634   my $sql = $self->_quote($k) . " " . $$v;
 635   return ($sql);
 636 }
 637
 638 # literal SQL with bind
 639 sub _where_hashpair_ARRAYREFREF {
 640   my ($self, $k, $v) = @_;
 641   $self->_debug("REF($k) means literal SQL: @${$v}");
 642   my ($sql, @bind) = @${$v};
 643   $self->_assert_bindval_matches_bindtype(@bind);
 644   $sql  = $self->_quote($k) . " " . $sql;
 645   return ($sql, @bind );
 646 }
 647
 648 # literal SQL without bind
 649 sub _where_hashpair_SCALAR {
 650   my ($self, $k, $v) = @_;
 651   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 652   my $sql = join ' ', $self->_convert($self->_quote($k)),
 653                       $self->_sqlcase($self->{cmp}),
 654                       $self->_convert('?');
 655   my @bind =  $self->_bindtype($k, $v);
 656   return ( $sql, @bind);
 657 }
 658
 659
 660 sub _where_hashpair_UNDEF {
 661   my ($self, $k, $v) = @_;
 662   $self->_debug("UNDEF($k) means IS NULL");
 663   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 664   return ($sql);
 665 }
 666
 667 #======================================================================
 668 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 669 #======================================================================
 670
 671
 672 sub _where_SCALARREF {
 673   my ($self, $where) = @_;
 674
 675   # literal sql
 676   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 677   return ($$where);
 678 }
 679
 680
 681 sub _where_SCALAR {
 682   my ($self, $where) = @_;
 683
 684   # literal sql
 685   $self->_debug("NOREF(*top) means literal SQL: $where");
 686   return ($where);
 687 }
 688
 689
 690 sub _where_UNDEF {
 691   my ($self) = @_;
 692   return ();
 693 }
 694
 695
 696 #======================================================================
 697 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 698 #======================================================================
 699
 700
 701 sub _where_field_BETWEEN {
 702   my ($self, $k, $op, $vals) = @_;
 703
 704   ref $vals eq 'ARRAY' && @$vals == 2
 705     or puke "special op 'between' requires an arrayref of two values";
 706
 707   my ($label)       = $self->_convert($self->_quote($k));
 708   my ($placeholder) = $self->_convert('?');
 709   my $and           = $self->_sqlcase('and');
 710   $op               = $self->_sqlcase($op);
 711
 712   my $sql  = "( $label $op $placeholder $and $placeholder )";
 713   my @bind = $self->_bindtype($k, @$vals);
 714   return ($sql, @bind)
 715 }
 716
 717
 718 sub _where_field_IN {
 719   my ($self, $k, $op, $vals) = @_;
 720
 721   # backwards compatibility : if scalar, force into an arrayref
 722   $vals = [$vals] if defined $vals && ! ref $vals;
 723
 724   my ($label)       = $self->_convert($self->_quote($k));
 725   my ($placeholder) = $self->_convert('?');
 726   $op               = $self->_sqlcase($op);
 727
 728   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
 729     ARRAYREF => sub {     # list of choices
 730       if (@$vals) { # nonempty list
 731         my $placeholders  = join ", ", (($placeholder) x @$vals);
 732         my $sql           = "$label $op ( $placeholders )";
 733         my @bind = $self->_bindtype($k, @$vals);
 734
 735         return ($sql, @bind);
 736       }
 737       else { # empty list : some databases won't understand "IN ()", so DWIM
 738         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
 739         return ($sql);
 740       }
 741     },
 742
 743     ARRAYREFREF => sub {  # literal SQL with bind
 744       my ($sql, @bind) = @$$vals;
 745       $self->_assert_bindval_matches_bindtype(@bind);
 746       return ("$label $op ( $sql )", @bind);
 747     },
 748
 749     FALLBACK => sub {
 750       puke "special op 'in' requires an arrayref (or arrayref-ref)";
 751     },
 752   });
 753
 754   return ($sql, @bind);
 755 }
 756
 757
 758
 759
 760
 761
 762 #======================================================================
 763 # ORDER BY
 764 #======================================================================
 765
 766 sub _order_by {
 767   my ($self, $arg) = @_;
 768
 769   # construct list of ordering instructions
 770   my @order = $self->_SWITCH_refkind($arg, {
 771
 772     ARRAYREF => sub {
 773       map {$self->_SWITCH_refkind($_, {
 774               SCALAR    => sub {$self->_quote($_)},
 775               UNDEF     => sub {},
 776               SCALARREF => sub {$$_}, # literal SQL, no quoting
 777               HASHREF   => sub {$self->_order_by_hash($_)}
 778              }) } @$arg;
 779     },
 780
 781     SCALAR    => sub {$self->_quote($arg)},
 782     UNDEF     => sub {},
 783     SCALARREF => sub {$$arg}, # literal SQL, no quoting
 784     HASHREF   => sub {$self->_order_by_hash($arg)},
 785
 786   });
 787
 788   # build SQL
 789   my $order = join ', ', @order;
 790   return $order ? $self->_sqlcase(' order by')." $order" : '';
 791 }
 792
 793
 794 sub _order_by_hash {
 795   my ($self, $hash) = @_;
 796
 797   # get first pair in hash
 798   my ($key, $val) = each %$hash;
 799
 800   # check if one pair was found and no other pair in hash
 801   $key && !(each %$hash)
 802     or puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
 803
 804   my ($order) = ($key =~ /^-(desc|asc)/i)
 805     or puke "invalid key in _order_by hash : $key";
 806
 807   return $self->_quote($val) ." ". $self->_sqlcase($order);
 808 }
 809
 810
 811
 812 #======================================================================
 813 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
 814 #======================================================================
 815
 816 sub _table  {
 817   my $self = shift;
 818   my $from = shift;
 819   $self->_SWITCH_refkind($from, {
 820     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
 821     SCALAR       => sub {$self->_quote($from)},
 822     SCALARREF    => sub {$$from},
 823     ARRAYREFREF  => sub {join ', ', @$from;},
 824   });
 825 }
 826
 827
 828 #======================================================================
 829 # UTILITY FUNCTIONS
 830 #======================================================================
 831
 832 sub _quote {
 833   my $self  = shift;
 834   my $label = shift;
 835
 836   $label or puke "can't quote an empty label";
 837
 838   # left and right quote characters
 839   my ($ql, $qr, @other) = $self->_SWITCH_refkind($self->{quote_char}, {
 840     SCALAR   => sub {($self->{quote_char}, $self->{quote_char})},
 841     ARRAYREF => sub {@{$self->{quote_char}}},
 842     UNDEF    => sub {()},
 843    });
 844   not @other
 845       or puke "quote_char must be an arrayref of 2 values";
 846
 847   # no quoting if no quoting chars
 848   $ql or return $label;
 849
 850   # no quoting for literal SQL
 851   return $$label if ref($label) eq 'SCALAR';
 852
 853   # separate table / column (if applicable)
 854   my $sep = $self->{name_sep} || '';
 855   my @to_quote = $sep ? split /\Q$sep\E/, $label : ($label);
 856
 857   # do the quoting, except for "*" or for `table`.*
 858   my @quoted = map { $_ eq '*' ? $_: $ql.$_.$qr} @to_quote;
 859
 860   # reassemble and return.
 861   return join $sep, @quoted;
 862 }
 863
 864
 865 # Conversion, if applicable
 866 sub _convert ($) {
 867   my ($self, $arg) = @_;
 868
 869 # LDNOTE : modified the previous implementation below because
 870 # it was not consistent : the first "return" is always an array,
 871 # the second "return" is context-dependent. Anyway, _convert
 872 # seems always used with just a single argument, so make it a
 873 # scalar function.
 874 #     return @_ unless $self->{convert};
 875 #     my $conv = $self->_sqlcase($self->{convert});
 876 #     my @ret = map { $conv.'('.$_.')' } @_;
 877 #     return wantarray ? @ret : $ret[0];
 878   if ($self->{convert}) {
 879     my $conv = $self->_sqlcase($self->{convert});
 880     $arg = $conv.'('.$arg.')';
 881   }
 882   return $arg;
 883 }
 884
 885 # And bindtype
 886 sub _bindtype (@) {
 887   my $self = shift;
 888   my($col, @vals) = @_;
 889
 890   #LDNOTE : changed original implementation below because it did not make
 891   # sense when bindtype eq 'columns' and @vals > 1.
 892 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
 893
 894   return $self->{bindtype} eq 'columns' ? map {[$col, $_]} @vals : @vals;
 895 }
 896
 897 # Dies if any element of @bind is not in [colname => value] format
 898 # if bindtype is 'columns'.
 899 sub _assert_bindval_matches_bindtype {
 900   my ($self, @bind) = @_;
 901
 902   if ($self->{bindtype} eq 'columns') {
 903     foreach my $val (@bind) {
 904       if (!defined $val || ref($val) ne 'ARRAY' || @$val != 2) {
 905         die "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
 906       }
 907     }
 908   }
 909 }
 910
 911 sub _join_sql_clauses {
 912   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
 913
 914   if (@$clauses_aref > 1) {
 915     my $join  = " " . $self->_sqlcase($logic) . " ";
 916     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
 917     return ($sql, @$bind_aref);
 918   }
 919   elsif (@$clauses_aref) {
 920     return ($clauses_aref->[0], @$bind_aref); # no parentheses
 921   }
 922   else {
 923     return (); # if no SQL, ignore @$bind_aref
 924   }
 925 }
 926
 927
 928 # Fix SQL case, if so requested
 929 sub _sqlcase {
 930   my $self = shift;
 931
 932   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
 933   # don't touch the argument ... crooked logic, but let's not change it!
 934   return $self->{case} ? $_[0] : uc($_[0]);
 935 }
 936
 937
 938 #======================================================================
 939 # DISPATCHING FROM REFKIND
 940 #======================================================================
 941
 942 sub _refkind {
 943   my ($self, $data) = @_;
 944   my $suffix = '';
 945   my $ref;
 946   my $n_steps = 0;
 947
 948   while (1) {
 949     # blessed objects are treated like scalars
 950     $ref = (blessed $data) ? '' : ref $data;
 951     $n_steps += 1 if $ref;
 952     last          if $ref ne 'REF';
 953     $data = $$data;
 954   }
 955
 956   my $base = $ref || (defined $data ? 'SCALAR' : 'UNDEF');
 957
 958   return $base . ('REF' x $n_steps);
 959 }
 960
 961
 962
 963 sub _try_refkind {
 964   my ($self, $data) = @_;
 965   my @try = ($self->_refkind($data));
 966   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
 967   push @try, 'FALLBACK';
 968   return @try;
 969 }
 970
 971 sub _METHOD_FOR_refkind {
 972   my ($self, $meth_prefix, $data) = @_;
 973   my $method = first {$_} map {$self->can($meth_prefix."_".$_)}
 974                               $self->_try_refkind($data)
 975     or puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
 976   return $method;
 977 }
 978
 979
 980 sub _SWITCH_refkind {
 981   my ($self, $data, $dispatch_table) = @_;
 982
 983   my $coderef = first {$_} map {$dispatch_table->{$_}}
 984                                $self->_try_refkind($data)
 985     or puke "no dispatch entry for ".$self->_refkind($data);
 986   $coderef->();
 987 }
 988
 989
 990
 991
 992 #======================================================================
 993 # VALUES, GENERATE, AUTOLOAD
 994 #======================================================================
 995
 996 # LDNOTE: original code from nwiger, didn't touch code in that section
 997 # I feel the AUTOLOAD stuff should not be the default, it should
 998 # only be activated on explicit demand by user.
 999
1000 sub values {
1001     my $self = shift;
1002     my $data = shift || return;
1003     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1004         unless ref $data eq 'HASH';
1005
1006     my @all_bind;
1007     foreach my $k ( sort keys %$data ) {
1008         my $v = $data->{$k};
1009         $self->_SWITCH_refkind($v, {
1010           ARRAYREF => sub {
1011             if ($self->{array_datatypes}) { # array datatype
1012               push @all_bind, $self->_bindtype($k, $v);
1013             }
1014             else {                          # literal SQL with bind
1015               my ($sql, @bind) = @$v;
1016               $self->_assert_bindval_matches_bindtype(@bind);
1017               push @all_bind, @bind;
1018             }
1019           },
1020           ARRAYREFREF => sub { # literal SQL with bind
1021             my ($sql, @bind) = @${$v};
1022             $self->_assert_bindval_matches_bindtype(@bind);
1023             push @all_bind, @bind;
1024           },
1025           SCALARREF => sub {  # literal SQL without bind
1026           },
1027           SCALAR_or_UNDEF => sub {
1028             push @all_bind, $self->_bindtype($k, $v);
1029           },
1030         });
1031     }
1032
1033     return @all_bind;
1034 }
1035
1036 sub generate {
1037     my $self  = shift;
1038
1039     my(@sql, @sqlq, @sqlv);
1040
1041     for (@_) {
1042         my $ref = ref $_;
1043         if ($ref eq 'HASH') {
1044             for my $k (sort keys %$_) {
1045                 my $v = $_->{$k};
1046                 my $r = ref $v;
1047                 my $label = $self->_quote($k);
1048                 if ($r eq 'ARRAY') {
1049                     # literal SQL with bind
1050                     my ($sql, @bind) = @$v;
1051                     $self->_assert_bindval_matches_bindtype(@bind);
1052                     push @sqlq, "$label = $sql";
1053                     push @sqlv, @bind;
1054                 } elsif ($r eq 'SCALAR') {
1055                     # literal SQL without bind
1056                     push @sqlq, "$label = $$v";
1057                 } else {
1058                     push @sqlq, "$label = ?";
1059                     push @sqlv, $self->_bindtype($k, $v);
1060                 }
1061             }
1062             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1063         } elsif ($ref eq 'ARRAY') {
1064             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1065             for my $v (@$_) {
1066                 my $r = ref $v;
1067                 if ($r eq 'ARRAY') {   # literal SQL with bind
1068                     my ($sql, @bind) = @$v;
1069                     $self->_assert_bindval_matches_bindtype(@bind);
1070                     push @sqlq, $sql;
1071                     push @sqlv, @bind;
1072                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1073                     # embedded literal SQL
1074                     push @sqlq, $$v;
1075                 } else {
1076                     push @sqlq, '?';
1077                     push @sqlv, $v;
1078                 }
1079             }
1080             push @sql, '(' . join(', ', @sqlq) . ')';
1081         } elsif ($ref eq 'SCALAR') {
1082             # literal SQL
1083             push @sql, $$_;
1084         } else {
1085             # strings get case twiddled
1086             push @sql, $self->_sqlcase($_);
1087         }
1088     }
1089
1090     my $sql = join ' ', @sql;
1091
1092     # this is pretty tricky
1093     # if ask for an array, return ($stmt, @bind)
1094     # otherwise, s/?/shift @sqlv/ to put it inline
1095     if (wantarray) {
1096         return ($sql, @sqlv);
1097     } else {
1098         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1099                              ref $d ? $d->[1] : $d/e;
1100         return $sql;
1101     }
1102 }
1103
1104
1105 sub DESTROY { 1 }
1106
1107 sub AUTOLOAD {
1108     # This allows us to check for a local, then _form, attr
1109     my $self = shift;
1110     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1111     return $self->generate($name, @_);
1112 }
1113
1114 1;
1115
1116
1117
1118 __END__
1119
1120 =head1 NAME
1121
1122 SQL::Abstract - Generate SQL from Perl data structures
1123
1124 =head1 SYNOPSIS
1125
1126     use SQL::Abstract;
1127
1128     my $sql = SQL::Abstract->new;
1129
1130     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1131
1132     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1133
1134     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1135
1136     my($stmt, @bind) = $sql->delete($table, \%where);
1137
1138     # Then, use these in your DBI statements
1139     my $sth = $dbh->prepare($stmt);
1140     $sth->execute(@bind);
1141
1142     # Just generate the WHERE clause
1143     my($stmt, @bind) = $sql->where(\%where, \@order);
1144
1145     # Return values in the same order, for hashed queries
1146     # See PERFORMANCE section for more details
1147     my @bind = $sql->values(\%fieldvals);
1148
1149 =head1 DESCRIPTION
1150
1151 This module was inspired by the excellent L<DBIx::Abstract>.
1152 However, in using that module I found that what I really wanted
1153 to do was generate SQL, but still retain complete control over my
1154 statement handles and use the DBI interface. So, I set out to
1155 create an abstract SQL generation module.
1156
1157 While based on the concepts used by L<DBIx::Abstract>, there are
1158 several important differences, especially when it comes to WHERE
1159 clauses. I have modified the concepts used to make the SQL easier
1160 to generate from Perl data structures and, IMO, more intuitive.
1161 The underlying idea is for this module to do what you mean, based
1162 on the data structures you provide it. The big advantage is that
1163 you don't have to modify your code every time your data changes,
1164 as this module figures it out.
1165
1166 To begin with, an SQL INSERT is as easy as just specifying a hash
1167 of C<key=value> pairs:
1168
1169     my %data = (
1170         name => 'Jimbo Bobson',
1171         phone => '123-456-7890',
1172         address => '42 Sister Lane',
1173         city => 'St. Louis',
1174         state => 'Louisiana',
1175     );
1176
1177 The SQL can then be generated with this:
1178
1179     my($stmt, @bind) = $sql->insert('people', \%data);
1180
1181 Which would give you something like this:
1182
1183     $stmt = "INSERT INTO people
1184                     (address, city, name, phone, state)
1185                     VALUES (?, ?, ?, ?, ?)";
1186     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1187              '123-456-7890', 'Louisiana');
1188
1189 These are then used directly in your DBI code:
1190
1191     my $sth = $dbh->prepare($stmt);
1192     $sth->execute(@bind);
1193
1194 =head2 Inserting and Updating Arrays
1195
1196 If your database has array types (like for example Postgres),
1197 activate the special option C<< array_datatypes => 1 >>
1198 when creating the C<SQL::Abstract> object.
1199 Then you may use an arrayref to insert and update database array types:
1200
1201     my $sql = SQL::Abstract->new(array_datatypes => 1);
1202     my %data = (
1203         planets => [qw/Mercury Venus Earth Mars/]
1204     );
1205
1206     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1207
1208 This results in:
1209
1210     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1211
1212     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1213
1214
1215 =head2 Inserting and Updating SQL
1216
1217 In order to apply SQL functions to elements of your C<%data> you may
1218 specify a reference to an arrayref for the given hash value. For example,
1219 if you need to execute the Oracle C<to_date> function on a value, you can
1220 say something like this:
1221
1222     my %data = (
1223         name => 'Bill',
1224         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1225     );
1226
1227 The first value in the array is the actual SQL. Any other values are
1228 optional and would be included in the bind values array. This gives
1229 you:
1230
1231     my($stmt, @bind) = $sql->insert('people', \%data);
1232
1233     $stmt = "INSERT INTO people (name, date_entered)
1234                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1235     @bind = ('Bill', '03/02/2003');
1236
1237 An UPDATE is just as easy, all you change is the name of the function:
1238
1239     my($stmt, @bind) = $sql->update('people', \%data);
1240
1241 Notice that your C<%data> isn't touched; the module will generate
1242 the appropriately quirky SQL for you automatically. Usually you'll
1243 want to specify a WHERE clause for your UPDATE, though, which is
1244 where handling C<%where> hashes comes in handy...
1245
1246 =head2 Complex where statements
1247
1248 This module can generate pretty complicated WHERE statements
1249 easily. For example, simple C<key=value> pairs are taken to mean
1250 equality, and if you want to see if a field is within a set
1251 of values, you can use an arrayref. Let's say we wanted to
1252 SELECT some data based on this criteria:
1253
1254     my %where = (
1255        requestor => 'inna',
1256        worker => ['nwiger', 'rcwe', 'sfz'],
1257        status => { '!=', 'completed' }
1258     );
1259
1260     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1261
1262 The above would give you something like this:
1263
1264     $stmt = "SELECT * FROM tickets WHERE
1265                 ( requestor = ? ) AND ( status != ? )
1266                 AND ( worker = ? OR worker = ? OR worker = ? )";
1267     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1268
1269 Which you could then use in DBI code like so:
1270
1271     my $sth = $dbh->prepare($stmt);
1272     $sth->execute(@bind);
1273
1274 Easy, eh?
1275
1276 =head1 FUNCTIONS
1277
1278 The functions are simple. There's one for each major SQL operation,
1279 and a constructor you use first. The arguments are specified in a
1280 similar order to each function (table, then fields, then a where
1281 clause) to try and simplify things.
1282
1283
1284
1285
1286 =head2 new(option => 'value')
1287
1288 The C<new()> function takes a list of options and values, and returns
1289 a new B<SQL::Abstract> object which can then be used to generate SQL
1290 through the methods below. The options accepted are:
1291
1292 =over
1293
1294 =item case
1295
1296 If set to 'lower', then SQL will be generated in all lowercase. By
1297 default SQL is generated in "textbook" case meaning something like:
1298
1299     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1300
1301 Any setting other than 'lower' is ignored.
1302
1303 =item cmp
1304
1305 This determines what the default comparison operator is. By default
1306 it is C<=>, meaning that a hash like this:
1307
1308     %where = (name => 'nwiger', email => 'nate@wiger.org');
1309
1310 Will generate SQL like this:
1311
1312     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1313
1314 However, you may want loose comparisons by default, so if you set
1315 C<cmp> to C<like> you would get SQL such as:
1316
1317     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1318
1319 You can also override the comparsion on an individual basis - see
1320 the huge section on L</"WHERE CLAUSES"> at the bottom.
1321
1322 =item sqltrue, sqlfalse
1323
1324 Expressions for inserting boolean values within SQL statements.
1325 By default these are C<1=1> and C<1=0>.
1326
1327 =item logic
1328
1329 This determines the default logical operator for multiple WHERE
1330 statements in arrays. By default it is "or", meaning that a WHERE
1331 array of the form:
1332
1333     @where = (
1334         event_date => {'>=', '2/13/99'},
1335         event_date => {'<=', '4/24/03'},
1336     );
1337
1338 Will generate SQL like this:
1339
1340     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1341
1342 This is probably not what you want given this query, though (look
1343 at the dates). To change the "OR" to an "AND", simply specify:
1344
1345     my $sql = SQL::Abstract->new(logic => 'and');
1346
1347 Which will change the above C<WHERE> to:
1348
1349     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1350
1351 The logic can also be changed locally by inserting
1352 an extra first element in the array :
1353
1354     @where = (-and => event_date => {'>=', '2/13/99'},
1355                       event_date => {'<=', '4/24/03'} );
1356
1357 See the L</"WHERE CLAUSES"> section for explanations.
1358
1359 =item convert
1360
1361 This will automatically convert comparisons using the specified SQL
1362 function for both column and value. This is mostly used with an argument
1363 of C<upper> or C<lower>, so that the SQL will have the effect of
1364 case-insensitive "searches". For example, this:
1365
1366     $sql = SQL::Abstract->new(convert => 'upper');
1367     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1368
1369 Will turn out the following SQL:
1370
1371     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1372
1373 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1374 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1375 not validate this option; it will just pass through what you specify verbatim).
1376
1377 =item bindtype
1378
1379 This is a kludge because many databases suck. For example, you can't
1380 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1381 Instead, you have to use C<bind_param()>:
1382
1383     $sth->bind_param(1, 'reg data');
1384     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1385
1386 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1387 which loses track of which field each slot refers to. Fear not.
1388
1389 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1390 Currently, you can specify either C<normal> (default) or C<columns>. If you
1391 specify C<columns>, you will get an array that looks like this:
1392
1393     my $sql = SQL::Abstract->new(bindtype => 'columns');
1394     my($stmt, @bind) = $sql->insert(...);
1395
1396     @bind = (
1397         [ 'column1', 'value1' ],
1398         [ 'column2', 'value2' ],
1399         [ 'column3', 'value3' ],
1400     );
1401
1402 You can then iterate through this manually, using DBI's C<bind_param()>.
1403
1404     $sth->prepare($stmt);
1405     my $i = 1;
1406     for (@bind) {
1407         my($col, $data) = @$_;
1408         if ($col eq 'details' || $col eq 'comments') {
1409             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1410         } elsif ($col eq 'image') {
1411             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1412         } else {
1413             $sth->bind_param($i, $data);
1414         }
1415         $i++;
1416     }
1417     $sth->execute;      # execute without @bind now
1418
1419 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1420 Basically, the advantage is still that you don't have to care which fields
1421 are or are not included. You could wrap that above C<for> loop in a simple
1422 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1423 get a layer of abstraction over manual SQL specification.
1424
1425 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1426 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1427 will expect the bind values in this format.
1428
1429 =item quote_char
1430
1431 This is the character that a table or column name will be quoted
1432 with.  By default this is an empty string, but you could set it to
1433 the character C<`>, to generate SQL like this:
1434
1435   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1436
1437 Alternatively, you can supply an array ref of two items, the first being the left
1438 hand quote character, and the second the right hand quote character. For
1439 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1440 that generates SQL like this:
1441
1442   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1443
1444 Quoting is useful if you have tables or columns names that are reserved
1445 words in your database's SQL dialect.
1446
1447 =item name_sep
1448
1449 This is the character that separates a table and column name.  It is
1450 necessary to specify this when the C<quote_char> option is selected,
1451 so that tables and column names can be individually quoted like this:
1452
1453   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1454
1455 =item array_datatypes
1456
1457 When this option is true, arrayrefs in INSERT or UPDATE are
1458 interpreted as array datatypes and are passed directly
1459 to the DBI layer.
1460 When this option is false, arrayrefs are interpreted
1461 as literal SQL, just like refs to arrayrefs
1462 (but this behavior is for backwards compatibility; when writing
1463 new queries, use the "reference to arrayref" syntax
1464 for literal SQL).
1465
1466
1467 =item special_ops
1468
1469 Takes a reference to a list of "special operators"
1470 to extend the syntax understood by L<SQL::Abstract>.
1471 See section L</"SPECIAL OPERATORS"> for details.
1472
1473
1474
1475 =back
1476
1477 =head2 insert($table, \@values || \%fieldvals)
1478
1479 This is the simplest function. You simply give it a table name
1480 and either an arrayref of values or hashref of field/value pairs.
1481 It returns an SQL INSERT statement and a list of bind values.
1482 See the sections on L</"Inserting and Updating Arrays"> and
1483 L</"Inserting and Updating SQL"> for information on how to insert
1484 with those data types.
1485
1486 =head2 update($table, \%fieldvals, \%where)
1487
1488 This takes a table, hashref of field/value pairs, and an optional
1489 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1490 of bind values.
1491 See the sections on L</"Inserting and Updating Arrays"> and
1492 L</"Inserting and Updating SQL"> for information on how to insert
1493 with those data types.
1494
1495 =head2 select($source, $fields, $where, $order)
1496
1497 This returns a SQL SELECT statement and associated list of bind values, as
1498 specified by the arguments  :
1499
1500 =over
1501
1502 =item $source
1503
1504 Specification of the 'FROM' part of the statement.
1505 The argument can be either a plain scalar (interpreted as a table
1506 name, will be quoted), or an arrayref (interpreted as a list
1507 of table names, joined by commas, quoted), or a scalarref
1508 (literal table name, not quoted), or a ref to an arrayref
1509 (list of literal table names, joined by commas, not quoted).
1510
1511 =item $fields
1512
1513 Specification of the list of fields to retrieve from
1514 the source.
1515 The argument can be either an arrayref (interpreted as a list
1516 of field names, will be joined by commas and quoted), or a
1517 plain scalar (literal SQL, not quoted).
1518 Please observe that this API is not as flexible as for
1519 the first argument C<$table>, for backwards compatibility reasons.
1520
1521 =item $where
1522
1523 Optional argument to specify the WHERE part of the query.
1524 The argument is most often a hashref, but can also be
1525 an arrayref or plain scalar --
1526 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1527
1528 =item $order
1529
1530 Optional argument to specify the ORDER BY part of the query.
1531 The argument can be a scalar, a hashref or an arrayref
1532 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1533 for details.
1534
1535 =back
1536
1537
1538 =head2 delete($table, \%where)
1539
1540 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1541 It returns an SQL DELETE statement and list of bind values.
1542
1543 =head2 where(\%where, \@order)
1544
1545 This is used to generate just the WHERE clause. For example,
1546 if you have an arbitrary data structure and know what the
1547 rest of your SQL is going to look like, but want an easy way
1548 to produce a WHERE clause, use this. It returns an SQL WHERE
1549 clause and list of bind values.
1550
1551
1552 =head2 values(\%data)
1553
1554 This just returns the values from the hash C<%data>, in the same
1555 order that would be returned from any of the other above queries.
1556 Using this allows you to markedly speed up your queries if you
1557 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1558
1559 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1560
1561 Warning: This is an experimental method and subject to change.
1562
1563 This returns arbitrarily generated SQL. It's a really basic shortcut.
1564 It will return two different things, depending on return context:
1565
1566     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1567     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
1568
1569 These would return the following:
1570
1571     # First calling form
1572     $stmt = "CREATE TABLE test (?, ?)";
1573     @bind = (field1, field2);
1574
1575     # Second calling form
1576     $stmt_and_val = "CREATE TABLE test (field1, field2)";
1577
1578 Depending on what you're trying to do, it's up to you to choose the correct
1579 format. In this example, the second form is what you would want.
1580
1581 By the same token:
1582
1583     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
1584
1585 Might give you:
1586
1587     ALTER SESSION SET nls_date_format = 'MM/YY'
1588
1589 You get the idea. Strings get their case twiddled, but everything
1590 else remains verbatim.
1591
1592
1593
1594
1595 =head1 WHERE CLAUSES
1596
1597 =head2 Introduction
1598
1599 This module uses a variation on the idea from L<DBIx::Abstract>. It
1600 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
1601 module is that things in arrays are OR'ed, and things in hashes
1602 are AND'ed.>
1603
1604 The easiest way to explain is to show lots of examples. After
1605 each C<%where> hash shown, it is assumed you used:
1606
1607     my($stmt, @bind) = $sql->where(\%where);
1608
1609 However, note that the C<%where> hash can be used directly in any
1610 of the other functions as well, as described above.
1611
1612 =head2 Key-value pairs
1613
1614 So, let's get started. To begin, a simple hash:
1615
1616     my %where  = (
1617         user   => 'nwiger',
1618         status => 'completed'
1619     );
1620
1621 Is converted to SQL C<key = val> statements:
1622
1623     $stmt = "WHERE user = ? AND status = ?";
1624     @bind = ('nwiger', 'completed');
1625
1626 One common thing I end up doing is having a list of values that
1627 a field can be in. To do this, simply specify a list inside of
1628 an arrayref:
1629
1630     my %where  = (
1631         user   => 'nwiger',
1632         status => ['assigned', 'in-progress', 'pending'];
1633     );
1634
1635 This simple code will create the following:
1636
1637     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
1638     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
1639
1640 An empty arrayref will be considered a logical false and
1641 will generate 0=1.
1642
1643 =head2 Key-value pairs
1644
1645 If you want to specify a different type of operator for your comparison,
1646 you can use a hashref for a given column:
1647
1648     my %where  = (
1649         user   => 'nwiger',
1650         status => { '!=', 'completed' }
1651     );
1652
1653 Which would generate:
1654
1655     $stmt = "WHERE user = ? AND status != ?";
1656     @bind = ('nwiger', 'completed');
1657
1658 To test against multiple values, just enclose the values in an arrayref:
1659
1660     status => { '!=', ['assigned', 'in-progress', 'pending'] };
1661
1662 Which would give you:
1663
1664     "WHERE status != ? AND status != ? AND status != ?"
1665
1666 Notice that since the operator was recognized as being a 'negative'
1667 operator, the arrayref was interpreted with 'AND' logic (because
1668 of Morgan's laws). By contrast, the reverse
1669
1670     status => { '=', ['assigned', 'in-progress', 'pending'] };
1671
1672 would generate :
1673
1674     "WHERE status = ? OR status = ? OR status = ?"
1675
1676
1677 The hashref can also contain multiple pairs, in which case it is expanded
1678 into an C<AND> of its elements:
1679
1680     my %where  = (
1681         user   => 'nwiger',
1682         status => { '!=', 'completed', -not_like => 'pending%' }
1683     );
1684
1685     # Or more dynamically, like from a form
1686     $where{user} = 'nwiger';
1687     $where{status}{'!='} = 'completed';
1688     $where{status}{'-not_like'} = 'pending%';
1689
1690     # Both generate this
1691     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
1692     @bind = ('nwiger', 'completed', 'pending%');
1693
1694
1695 To get an OR instead, you can combine it with the arrayref idea:
1696
1697     my %where => (
1698          user => 'nwiger',
1699          priority => [ {'=', 2}, {'!=', 1} ]
1700     );
1701
1702 Which would generate:
1703
1704     $stmt = "WHERE user = ? AND priority = ? OR priority != ?";
1705     @bind = ('nwiger', '2', '1');
1706
1707 If you want to include literal SQL (with or without bind values), just use a
1708 scalar reference or array reference as the value:
1709
1710     my %where  = (
1711         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
1712         date_expires => { '<' => \"now()" }
1713     );
1714
1715 Which would generate:
1716
1717     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
1718     @bind = ('11/26/2008');
1719
1720
1721 =head2 Logic and nesting operators
1722
1723 In the example above,
1724 there is a subtle trap if you want to say something like
1725 this (notice the C<AND>):
1726
1727     WHERE priority != ? AND priority != ?
1728
1729 Because, in Perl you I<can't> do this:
1730
1731     priority => { '!=', 2, '!=', 1 }
1732
1733 As the second C<!=> key will obliterate the first. The solution
1734 is to use the special C<-modifier> form inside an arrayref:
1735
1736     priority => [ -and => {'!=', 2},
1737                           {'!=', 1} ]
1738
1739
1740 Normally, these would be joined by C<OR>, but the modifier tells it
1741 to use C<AND> instead. (Hint: You can use this in conjunction with the
1742 C<logic> option to C<new()> in order to change the way your queries
1743 work by default.) B<Important:> Note that the C<-modifier> goes
1744 B<INSIDE> the arrayref, as an extra first element. This will
1745 B<NOT> do what you think it might:
1746
1747     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
1748
1749 Here is a quick list of equivalencies, since there is some overlap:
1750
1751     # Same
1752     status => {'!=', 'completed', 'not like', 'pending%' }
1753     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
1754
1755     # Same
1756     status => {'=', ['assigned', 'in-progress']}
1757     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
1758     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
1759
1760 In addition to C<-and> and C<-or>, there is also a special C<-nest>
1761 operator which adds an additional set of parens, to create a subquery.
1762 For example, to get something like this:
1763
1764     $stmt = "WHERE user = ? AND ( workhrs > ? OR geo = ? )";
1765     @bind = ('nwiger', '20', 'ASIA');
1766
1767 You would do:
1768
1769     my %where = (
1770          user => 'nwiger',
1771         -nest => [ workhrs => {'>', 20}, geo => 'ASIA' ],
1772     );
1773
1774 If you need several nested subexpressions, you can number
1775 the C<-nest> branches :
1776
1777     my %where = (
1778          user => 'nwiger',
1779         -nest1 => ...,
1780         -nest2 => ...,
1781         ...
1782     );
1783
1784
1785 =head2 Special operators : IN, BETWEEN, etc.
1786
1787 You can also use the hashref format to compare a list of fields using the
1788 C<IN> comparison operator, by specifying the list as an arrayref:
1789
1790     my %where  = (
1791         status   => 'completed',
1792         reportid => { -in => [567, 2335, 2] }
1793     );
1794
1795 Which would generate:
1796
1797     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
1798     @bind = ('completed', '567', '2335', '2');
1799
1800 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
1801 the same way.
1802
1803 Another pair of operators is C<-between> and C<-not_between>,
1804 used with an arrayref of two values:
1805
1806     my %where  = (
1807         user   => 'nwiger',
1808         completion_date => {
1809            -not_between => ['2002-10-01', '2003-02-06']
1810         }
1811     );
1812
1813 Would give you:
1814
1815     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
1816
1817 These are the two builtin "special operators"; but the
1818 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
1819
1820 =head2 Nested conditions
1821
1822 So far, we've seen how multiple conditions are joined with a top-level
1823 C<AND>.  We can change this by putting the different conditions we want in
1824 hashes and then putting those hashes in an array. For example:
1825
1826     my @where = (
1827         {
1828             user   => 'nwiger',
1829             status => { -like => ['pending%', 'dispatched'] },
1830         },
1831         {
1832             user   => 'robot',
1833             status => 'unassigned',
1834         }
1835     );
1836
1837 This data structure would create the following:
1838
1839     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
1840                 OR ( user = ? AND status = ? ) )";
1841     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
1842
1843 This can be combined with the C<-nest> operator to properly group
1844 SQL statements:
1845
1846     my @where = (
1847          -and => [
1848             user => 'nwiger',
1849             -nest => [
1850                 ["-and", workhrs => {'>', 20}, geo => 'ASIA' ],
1851                 ["-and", workhrs => {'<', 50}, geo => 'EURO' ]
1852             ],
1853         ],
1854     );
1855
1856 That would yield:
1857
1858     WHERE ( user = ? AND
1859           ( ( workhrs > ? AND geo = ? )
1860          OR ( workhrs < ? AND geo = ? ) ) )
1861
1862 =head2 Literal SQL
1863
1864 Finally, sometimes only literal SQL will do. If you want to include
1865 literal SQL verbatim, you can specify it as a scalar reference, namely:
1866
1867     my $inn = 'is Not Null';
1868     my %where = (
1869         priority => { '<', 2 },
1870         requestor => \$inn
1871     );
1872
1873 This would create:
1874
1875     $stmt = "WHERE priority < ? AND requestor is Not Null";
1876     @bind = ('2');
1877
1878 Note that in this example, you only get one bind parameter back, since
1879 the verbatim SQL is passed as part of the statement.
1880
1881 Of course, just to prove a point, the above can also be accomplished
1882 with this:
1883
1884     my %where = (
1885         priority  => { '<', 2 },
1886         requestor => { '!=', undef },
1887     );
1888
1889
1890 TMTOWTDI.
1891
1892 Conditions on boolean columns can be expressed in the
1893 same way, passing a reference to an empty string :
1894
1895     my %where = (
1896         priority  => { '<', 2 },
1897         is_ready  => \"";
1898     );
1899
1900 which yields
1901
1902     $stmt = "WHERE priority < ? AND is_ready";
1903     @bind = ('2');
1904
1905
1906 =head2 Literal SQL with placeholders and bind values (subqueries)
1907
1908 If the literal SQL to be inserted has placeholders and bind values,
1909 use a reference to an arrayref (yes this is a double reference --
1910 not so common, but perfectly legal Perl). For example, to find a date
1911 in Postgres you can use something like this:
1912
1913     my %where = (
1914        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
1915     )
1916
1917 This would create:
1918
1919     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
1920     @bind = ('10');
1921
1922 Note that you must pass the bind values in the same format as they are returned
1923 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
1924 provide the bind values in the C<< [ column_meta => value ] >> format, where
1925 C<column_meta> is an opaque scalar value; most commonly the column name, but
1926 you can use any scalar value (including references and blessed references),
1927 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
1928 to C<columns> the above example will look like:
1929
1930     my %where = (
1931        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
1932     )
1933
1934 Literal SQL is especially useful for nesting parenthesized clauses in the
1935 main SQL query. Here is a first example :
1936
1937   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
1938                                100, "foo%");
1939   my %where = (
1940     foo => 1234,
1941     bar => \["IN ($sub_stmt)" => @sub_bind],
1942   );
1943
1944 This yields :
1945
1946   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
1947                                              WHERE c2 < ? AND c3 LIKE ?))";
1948   @bind = (1234, 100, "foo%");
1949
1950 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
1951 are expressed in the same way. Of course the C<$sub_stmt> and
1952 its associated bind values can be generated through a former call
1953 to C<select()> :
1954
1955   my ($sub_stmt, @sub_bind)
1956      = $sql->select("t1", "c1", {c2 => {"<" => 100},
1957                                  c3 => {-like => "foo%"}});
1958   my %where = (
1959     foo => 1234,
1960     bar => \["> ALL ($sub_stmt)" => @sub_bind],
1961   );
1962
1963 In the examples above, the subquery was used as an operator on a column;
1964 but the same principle also applies for a clause within the main C<%where>
1965 hash, like an EXISTS subquery :
1966
1967   my ($sub_stmt, @sub_bind)
1968      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
1969   my %where = (
1970     foo   => 1234,
1971     -nest => \["EXISTS ($sub_stmt)" => @sub_bind],
1972   );
1973
1974 which yields
1975
1976   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
1977                                         WHERE c1 = ? AND c2 > t0.c0))";
1978   @bind = (1234, 1);
1979
1980
1981 Observe that the condition on C<c2> in the subquery refers to
1982 column C<t0.c0> of the main query : this is I<not> a bind
1983 value, so we have to express it through a scalar ref.
1984 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
1985 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
1986 what we wanted here.
1987
1988 Another use of the subquery technique is when some SQL clauses need
1989 parentheses, as it often occurs with some proprietary SQL extensions
1990 like for example fulltext expressions, geospatial expressions,
1991 NATIVE clauses, etc. Here is an example of a fulltext query in MySQL :
1992
1993   my %where = (
1994     -nest => \["MATCH (col1, col2) AGAINST (?)" => qw/apples/]
1995   );
1996
1997 Finally, here is an example where a subquery is used
1998 for expressing unary negation:
1999
2000   my ($sub_stmt, @sub_bind)
2001      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2002   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2003   my %where = (
2004         lname  => {like => '%son%'},
2005         -nest  => \["NOT ($sub_stmt)" => @sub_bind],
2006     );
2007
2008 This yields
2009
2010   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2011   @bind = ('%son%', 10, 20)
2012
2013
2014
2015 =head2 Conclusion
2016
2017 These pages could go on for a while, since the nesting of the data
2018 structures this module can handle are pretty much unlimited (the
2019 module implements the C<WHERE> expansion as a recursive function
2020 internally). Your best bet is to "play around" with the module a
2021 little to see how the data structures behave, and choose the best
2022 format for your data based on that.
2023
2024 And of course, all the values above will probably be replaced with
2025 variables gotten from forms or the command line. After all, if you
2026 knew everything ahead of time, you wouldn't have to worry about
2027 dynamically-generating SQL and could just hardwire it into your
2028 script.
2029
2030
2031
2032
2033 =head1 ORDER BY CLAUSES
2034
2035 Some functions take an order by clause. This can either be a scalar (just a
2036 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2037 or an array of either of the two previous forms. Examples:
2038
2039              Given             |    Will Generate
2040     ----------------------------------------------------------
2041     \'colA DESC'               | ORDER BY colA DESC
2042     'colA'                     | ORDER BY colA
2043     [qw/colA colB/]            | ORDER BY colA, colB
2044     {-asc  => 'colA'}          | ORDER BY colA ASC
2045     {-desc => 'colB'}          | ORDER BY colB DESC
2046     [                          |
2047       {-asc  => 'colA'},       | ORDER BY colA ASC, colB DESC
2048       {-desc => 'colB'}        |
2049     ]                          |
2050     [colA => {-asc => 'colB'}] | ORDER BY colA, colB ASC
2051     ==========================================================
2052
2053
2054
2055 =head1 SPECIAL OPERATORS
2056
2057   my $sqlmaker = SQL::Abstract->new(special_ops => [
2058      {regex => qr/.../,
2059       handler => sub {
2060         my ($self, $field, $op, $arg) = @_;
2061         ...
2062         },
2063      },
2064    ]);
2065
2066 A "special operator" is a SQL syntactic clause that can be
2067 applied to a field, instead of a usual binary operator.
2068 For example :
2069
2070    WHERE field IN (?, ?, ?)
2071    WHERE field BETWEEN ? AND ?
2072    WHERE MATCH(field) AGAINST (?, ?)
2073
2074 Special operators IN and BETWEEN are fairly standard and therefore
2075 are builtin within C<SQL::Abstract>. For other operators,
2076 like the MATCH .. AGAINST example above which is
2077 specific to MySQL, you can write your own operator handlers :
2078 supply a C<special_ops> argument to the C<new> method.
2079 That argument takes an arrayref of operator definitions;
2080 each operator definition is a hashref with two entries
2081
2082 =over
2083
2084 =item regex
2085
2086 the regular expression to match the operator
2087
2088 =item handler
2089
2090 coderef that will be called when meeting that operator
2091 in the input tree. The coderef will be called with
2092 arguments  C<< ($self, $field, $op, $arg) >>, and
2093 should return a C<< ($sql, @bind) >> structure.
2094
2095 =back
2096
2097 For example, here is an implementation
2098 of the MATCH .. AGAINST syntax for MySQL
2099
2100   my $sqlmaker = SQL::Abstract->new(special_ops => [
2101
2102     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2103     {regex => qr/^match$/i,
2104      handler => sub {
2105        my ($self, $field, $op, $arg) = @_;
2106        $arg = [$arg] if not ref $arg;
2107        my $label         = $self->_quote($field);
2108        my ($placeholder) = $self->_convert('?');
2109        my $placeholders  = join ", ", (($placeholder) x @$arg);
2110        my $sql           = $self->_sqlcase('match') . " ($label) "
2111                          . $self->_sqlcase('against') . " ($placeholders) ";
2112        my @bind = $self->_bindtype($field, @$arg);
2113        return ($sql, @bind);
2114        }
2115      },
2116
2117   ]);
2118
2119
2120 =head1 PERFORMANCE
2121
2122 Thanks to some benchmarking by Mark Stosberg, it turns out that
2123 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2124 I must admit this wasn't an intentional design issue, but it's a
2125 byproduct of the fact that you get to control your C<DBI> handles
2126 yourself.
2127
2128 To maximize performance, use a code snippet like the following:
2129
2130     # prepare a statement handle using the first row
2131     # and then reuse it for the rest of the rows
2132     my($sth, $stmt);
2133     for my $href (@array_of_hashrefs) {
2134         $stmt ||= $sql->insert('table', $href);
2135         $sth  ||= $dbh->prepare($stmt);
2136         $sth->execute($sql->values($href));
2137     }
2138
2139 The reason this works is because the keys in your C<$href> are sorted
2140 internally by B<SQL::Abstract>. Thus, as long as your data retains
2141 the same structure, you only have to generate the SQL the first time
2142 around. On subsequent queries, simply use the C<values> function provided
2143 by this module to return your values in the correct order.
2144
2145
2146 =head1 FORMBUILDER
2147
2148 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2149 really like this part (I do, at least). Building up a complex query
2150 can be as simple as the following:
2151
2152     #!/usr/bin/perl
2153
2154     use CGI::FormBuilder;
2155     use SQL::Abstract;
2156
2157     my $form = CGI::FormBuilder->new(...);
2158     my $sql  = SQL::Abstract->new;
2159
2160     if ($form->submitted) {
2161         my $field = $form->field;
2162         my $id = delete $field->{id};
2163         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2164     }
2165
2166 Of course, you would still have to connect using C<DBI> to run the
2167 query, but the point is that if you make your form look like your
2168 table, the actual query script can be extremely simplistic.
2169
2170 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2171 a fast interface to returning and formatting data. I frequently
2172 use these three modules together to write complex database query
2173 apps in under 50 lines.
2174
2175
2176 =head1 CHANGES
2177
2178 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2179 Great care has been taken to preserve the I<published> behavior
2180 documented in previous versions in the 1.* family; however,
2181 some features that were previously undocumented, or behaved
2182 differently from the documentation, had to be changed in order
2183 to clarify the semantics. Hence, client code that was relying
2184 on some dark areas of C<SQL::Abstract> v1.*
2185 B<might behave differently> in v1.50.
2186
2187 The main changes are :
2188
2189 =over
2190
2191 =item *
2192
2193 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2194
2195 =item *
2196
2197 support for the { operator => \"..." } construct (to embed literal SQL)
2198
2199 =item *
2200
2201 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2202
2203 =item *
2204
2205 added -nest1, -nest2 or -nest_1, -nest_2, ...
2206
2207 =item *
2208
2209 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2210
2211 =item *
2212
2213 defensive programming : check arguments
2214
2215 =item *
2216
2217 fixed bug with global logic, which was previously implemented
2218 through global variables yielding side-effects. Prior versons would
2219 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2220 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2221 Now this is interpreted
2222 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2223
2224 =item *
2225
2226 C<-and> / C<-or> operators are no longer accepted
2227 in the middle of an arrayref : they are
2228 only admitted if in first position.
2229
2230 =item *
2231
2232 changed logic for distributing an op over arrayrefs
2233
2234 =item *
2235
2236 fixed semantics of  _bindtype on array args
2237
2238 =item *
2239
2240 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2241 we just avoid shifting arrays within that tree.
2242
2243 =item *
2244
2245 dropped the C<_modlogic> function
2246
2247 =back
2248
2249
2250
2251 =head1 ACKNOWLEDGEMENTS
2252
2253 There are a number of individuals that have really helped out with
2254 this module. Unfortunately, most of them submitted bugs via CPAN
2255 so I have no idea who they are! But the people I do know are:
2256
2257     Ash Berlin (order_by hash term support)
2258     Matt Trout (DBIx::Class support)
2259     Mark Stosberg (benchmarking)
2260     Chas Owens (initial "IN" operator support)
2261     Philip Collins (per-field SQL functions)
2262     Eric Kolve (hashref "AND" support)
2263     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2264     Dan Kubb (support for "quote_char" and "name_sep")
2265     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2266     Laurent Dami (internal refactoring, multiple -nest, extensible list of special operators, literal SQL)
2267     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2268
2269 Thanks!
2270
2271 =head1 SEE ALSO
2272
2273 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2274
2275 =head1 AUTHOR
2276
2277 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2278
2279 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2280
2281 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2282 While not an official support venue, C<DBIx::Class> makes heavy use of
2283 C<SQL::Abstract>, and as such list members there are very familiar with
2284 how to create queries.
2285
2286 This module is free software; you may copy this under the terms of
2287 the GNU General Public License, or the Artistic License, copies of
2288 which should have accompanied your Perl kit.
2289
2290 =cut
2291