lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use strict;
   9 use warnings;
  10 use Carp ();
  11 use List::Util ();
  12 use Scalar::Util ();
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.73';
  19
  20 # This would confuse some packagers
  21 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^ (?: not \s )? between $/ix, handler => '_where_field_BETWEEN'},
  29   {regex => qr/^ (?: not \s )? in      $/ix, handler => '_where_field_IN'},
  30   {regex => qr/^ ident                 $/ix, handler => '_where_op_IDENT'},
  31   {regex => qr/^ value                 $/ix, handler => '_where_op_VALUE'},
  32 );
  33
  34 # unaryish operators - key maps to handler
  35 my @BUILTIN_UNARY_OPS = (
  36   # the digits are backcompat stuff
  37   { regex => qr/^ and  (?: [_\s]? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  38   { regex => qr/^ or   (?: [_\s]? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  39   { regex => qr/^ nest (?: [_\s]? \d+ )? $/xi, handler => '_where_op_NEST' },
  40   { regex => qr/^ (?: not \s )? bool     $/xi, handler => '_where_op_BOOL' },
  41   { regex => qr/^ ident                  $/xi, handler => '_where_op_IDENT' },
  42   { regex => qr/^ value                  $/ix, handler => '_where_op_VALUE' },
  43 );
  44
  45 #======================================================================
  46 # DEBUGGING AND ERROR REPORTING
  47 #======================================================================
  48
  49 sub _debug {
  50   return unless $_[0]->{debug}; shift; # a little faster
  51   my $func = (caller(1))[3];
  52   warn "[$func] ", @_, "\n";
  53 }
  54
  55 sub belch (@) {
  56   my($func) = (caller(1))[3];
  57   Carp::carp "[$func] Warning: ", @_;
  58 }
  59
  60 sub puke (@) {
  61   my($func) = (caller(1))[3];
  62   Carp::croak "[$func] Fatal: ", @_;
  63 }
  64
  65
  66 #======================================================================
  67 # NEW
  68 #======================================================================
  69
  70 sub new {
  71   my $self = shift;
  72   my $class = ref($self) || $self;
  73   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  74
  75   # choose our case by keeping an option around
  76   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  77
  78   # default logic for interpreting arrayrefs
  79   $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
  80
  81   # how to return bind vars
  82   # LDNOTE: changed nwiger code : why this 'delete' ??
  83   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  84   $opt{bindtype} ||= 'normal';
  85
  86   # default comparison is "=", but can be overridden
  87   $opt{cmp} ||= '=';
  88
  89   # try to recognize which are the 'equality' and 'unequality' ops
  90   # (temporary quickfix, should go through a more seasoned API)
  91   $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  92   $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  93
  94   # SQL booleans
  95   $opt{sqltrue}  ||= '1=1';
  96   $opt{sqlfalse} ||= '0=1';
  97
  98   # special operators
  99   $opt{special_ops} ||= [];
 100   # regexes are applied in order, thus push after user-defines
 101   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
 102
 103   # unary operators
 104   $opt{unary_ops} ||= [];
 105   push @{$opt{unary_ops}}, @BUILTIN_UNARY_OPS;
 106
 107   # rudimentary saniy-check for user supplied bits treated as functions/operators
 108   # If a purported  function matches this regular expression, an exception is thrown.
 109   # Literal SQL is *NOT* subject to this check, only functions (and column names
 110   # when quoting is not in effect)
 111
 112   # FIXME
 113   # need to guard against ()'s in column names too, but this will break tons of
 114   # hacks... ideas anyone?
 115   $opt{injection_guard} ||= qr/
 116     \;
 117       |
 118     ^ \s* go \s
 119   /xmi;
 120
 121   return bless \%opt, $class;
 122 }
 123
 124
 125 sub _assert_pass_injection_guard {
 126   if ($_[1] =~ $_[0]->{injection_guard}) {
 127     my $class = ref $_[0];
 128     puke "Possible SQL injection attempt '$_[1]'. If this is indeed a part of the "
 129      . "desired SQL use literal SQL ( \'...' or \[ '...' ] ) or supply your own "
 130      . "{injection_guard} attribute to ${class}->new()"
 131   }
 132 }
 133
 134
 135 #======================================================================
 136 # INSERT methods
 137 #======================================================================
 138
 139 sub insert {
 140   my $self    = shift;
 141   my $table   = $self->_table(shift);
 142   my $data    = shift || return;
 143   my $options = shift;
 144
 145   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 146   my ($sql, @bind) = $self->$method($data);
 147   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 148
 149   if ($options->{returning}) {
 150     my ($s, @b) = $self->_insert_returning ($options);
 151     $sql .= $s;
 152     push @bind, @b;
 153   }
 154
 155   return wantarray ? ($sql, @bind) : $sql;
 156 }
 157
 158 sub _insert_returning {
 159   my ($self, $options) = @_;
 160
 161   my $f = $options->{returning};
 162
 163   my $fieldlist = $self->_SWITCH_refkind($f, {
 164     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$f;},
 165     SCALAR       => sub {$self->_quote($f)},
 166     SCALARREF    => sub {$$f},
 167   });
 168   return $self->_sqlcase(' returning ') . $fieldlist;
 169 }
 170
 171 sub _insert_HASHREF { # explicit list of fields and then values
 172   my ($self, $data) = @_;
 173
 174   my @fields = sort keys %$data;
 175
 176   my ($sql, @bind) = $self->_insert_values($data);
 177
 178   # assemble SQL
 179   $_ = $self->_quote($_) foreach @fields;
 180   $sql = "( ".join(", ", @fields).") ".$sql;
 181
 182   return ($sql, @bind);
 183 }
 184
 185 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 186   my ($self, $data) = @_;
 187
 188   # no names (arrayref) so can't generate bindtype
 189   $self->{bindtype} ne 'columns'
 190     or belch "can't do 'columns' bindtype when called with arrayref";
 191
 192   # fold the list of values into a hash of column name - value pairs
 193   # (where the column names are artificially generated, and their
 194   # lexicographical ordering keep the ordering of the original list)
 195   my $i = "a";  # incremented values will be in lexicographical order
 196   my $data_in_hash = { map { ($i++ => $_) } @$data };
 197
 198   return $self->_insert_values($data_in_hash);
 199 }
 200
 201 sub _insert_ARRAYREFREF { # literal SQL with bind
 202   my ($self, $data) = @_;
 203
 204   my ($sql, @bind) = @${$data};
 205   $self->_assert_bindval_matches_bindtype(@bind);
 206
 207   return ($sql, @bind);
 208 }
 209
 210
 211 sub _insert_SCALARREF { # literal SQL without bind
 212   my ($self, $data) = @_;
 213
 214   return ($$data);
 215 }
 216
 217 sub _insert_values {
 218   my ($self, $data) = @_;
 219
 220   my (@values, @all_bind);
 221   foreach my $column (sort keys %$data) {
 222     my $v = $data->{$column};
 223
 224     $self->_SWITCH_refkind($v, {
 225
 226       ARRAYREF => sub {
 227         if ($self->{array_datatypes}) { # if array datatype are activated
 228           push @values, '?';
 229           push @all_bind, $self->_bindtype($column, $v);
 230         }
 231         else {                          # else literal SQL with bind
 232           my ($sql, @bind) = @$v;
 233           $self->_assert_bindval_matches_bindtype(@bind);
 234           push @values, $sql;
 235           push @all_bind, @bind;
 236         }
 237       },
 238
 239       ARRAYREFREF => sub { # literal SQL with bind
 240         my ($sql, @bind) = @${$v};
 241         $self->_assert_bindval_matches_bindtype(@bind);
 242         push @values, $sql;
 243         push @all_bind, @bind;
 244       },
 245
 246       # THINK : anything useful to do with a HASHREF ?
 247       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 248         #TODO in SQLA >= 2.0 it will die instead
 249         belch "HASH ref as bind value in insert is not supported";
 250         push @values, '?';
 251         push @all_bind, $self->_bindtype($column, $v);
 252       },
 253
 254       SCALARREF => sub {  # literal SQL without bind
 255         push @values, $$v;
 256       },
 257
 258       SCALAR_or_UNDEF => sub {
 259         push @values, '?';
 260         push @all_bind, $self->_bindtype($column, $v);
 261       },
 262
 263      });
 264
 265   }
 266
 267   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 268   return ($sql, @all_bind);
 269 }
 270
 271
 272
 273 #======================================================================
 274 # UPDATE methods
 275 #======================================================================
 276
 277
 278 sub update {
 279   my $self  = shift;
 280   my $table = $self->_table(shift);
 281   my $data  = shift || return;
 282   my $where = shift;
 283
 284   # first build the 'SET' part of the sql statement
 285   my (@set, @all_bind);
 286   puke "Unsupported data type specified to \$sql->update"
 287     unless ref $data eq 'HASH';
 288
 289   for my $k (sort keys %$data) {
 290     my $v = $data->{$k};
 291     my $r = ref $v;
 292     my $label = $self->_quote($k);
 293
 294     $self->_SWITCH_refkind($v, {
 295       ARRAYREF => sub {
 296         if ($self->{array_datatypes}) { # array datatype
 297           push @set, "$label = ?";
 298           push @all_bind, $self->_bindtype($k, $v);
 299         }
 300         else {                          # literal SQL with bind
 301           my ($sql, @bind) = @$v;
 302           $self->_assert_bindval_matches_bindtype(@bind);
 303           push @set, "$label = $sql";
 304           push @all_bind, @bind;
 305         }
 306       },
 307       ARRAYREFREF => sub { # literal SQL with bind
 308         my ($sql, @bind) = @${$v};
 309         $self->_assert_bindval_matches_bindtype(@bind);
 310         push @set, "$label = $sql";
 311         push @all_bind, @bind;
 312       },
 313       SCALARREF => sub {  # literal SQL without bind
 314         push @set, "$label = $$v";
 315       },
 316       HASHREF => sub {
 317         my ($op, $arg, @rest) = %$v;
 318
 319         puke 'Operator calls in update must be in the form { -op => $arg }'
 320           if (@rest or not $op =~ /^\-(.+)/);
 321
 322         local $self->{_nested_func_lhs} = $k;
 323         my ($sql, @bind) = $self->_where_unary_op ($1, $arg);
 324
 325         push @set, "$label = $sql";
 326         push @all_bind, @bind;
 327       },
 328       SCALAR_or_UNDEF => sub {
 329         push @set, "$label = ?";
 330         push @all_bind, $self->_bindtype($k, $v);
 331       },
 332     });
 333   }
 334
 335   # generate sql
 336   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 337           . join ', ', @set;
 338
 339   if ($where) {
 340     my($where_sql, @where_bind) = $self->where($where);
 341     $sql .= $where_sql;
 342     push @all_bind, @where_bind;
 343   }
 344
 345   return wantarray ? ($sql, @all_bind) : $sql;
 346 }
 347
 348
 349
 350
 351 #======================================================================
 352 # SELECT
 353 #======================================================================
 354
 355
 356 sub select {
 357   my $self   = shift;
 358   my $table  = $self->_table(shift);
 359   my $fields = shift || '*';
 360   my $where  = shift;
 361   my $order  = shift;
 362
 363   my($where_sql, @bind) = $self->where($where, $order);
 364
 365   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 366                                    : $fields;
 367   my $sql = join(' ', $self->_sqlcase('select'), $f,
 368                       $self->_sqlcase('from'),   $table)
 369           . $where_sql;
 370
 371   return wantarray ? ($sql, @bind) : $sql;
 372 }
 373
 374 #======================================================================
 375 # DELETE
 376 #======================================================================
 377
 378
 379 sub delete {
 380   my $self  = shift;
 381   my $table = $self->_table(shift);
 382   my $where = shift;
 383
 384
 385   my($where_sql, @bind) = $self->where($where);
 386   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 387
 388   return wantarray ? ($sql, @bind) : $sql;
 389 }
 390
 391
 392 #======================================================================
 393 # WHERE: entry point
 394 #======================================================================
 395
 396
 397
 398 # Finally, a separate routine just to handle WHERE clauses
 399 sub where {
 400   my ($self, $where, $order) = @_;
 401
 402   # where ?
 403   my ($sql, @bind) = $self->_recurse_where($where);
 404   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 405
 406   # order by?
 407   if ($order) {
 408     $sql .= $self->_order_by($order);
 409   }
 410
 411   return wantarray ? ($sql, @bind) : $sql;
 412 }
 413
 414
 415 sub _recurse_where {
 416   my ($self, $where, $logic) = @_;
 417
 418   # dispatch on appropriate method according to refkind of $where
 419   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 420
 421   my ($sql, @bind) =  $self->$method($where, $logic);
 422
 423   # DBIx::Class directly calls _recurse_where in scalar context, so
 424   # we must implement it, even if not in the official API
 425   return wantarray ? ($sql, @bind) : $sql;
 426 }
 427
 428
 429
 430 #======================================================================
 431 # WHERE: top-level ARRAYREF
 432 #======================================================================
 433
 434
 435 sub _where_ARRAYREF {
 436   my ($self, $where, $logic) = @_;
 437
 438   $logic = uc($logic || $self->{logic});
 439   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 440
 441   my @clauses = @$where;
 442
 443   my (@sql_clauses, @all_bind);
 444   # need to use while() so can shift() for pairs
 445   while (my $el = shift @clauses) {
 446
 447     # switch according to kind of $el and get corresponding ($sql, @bind)
 448     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 449
 450       # skip empty elements, otherwise get invalid trailing AND stuff
 451       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 452
 453       ARRAYREFREF => sub {
 454         my ($s, @b) = @$$el;
 455         $self->_assert_bindval_matches_bindtype(@b);
 456         ($s, @b);
 457       },
 458
 459       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 460            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 461            # side-effect: the first hashref within an array would change
 462            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 463            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 464            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 465
 466       SCALARREF => sub { ($$el);                                 },
 467
 468       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 469                         $self->_recurse_where({$el => shift(@clauses)})},
 470
 471       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 472     });
 473
 474     if ($sql) {
 475       push @sql_clauses, $sql;
 476       push @all_bind, @bind;
 477     }
 478   }
 479
 480   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 481 }
 482
 483 #======================================================================
 484 # WHERE: top-level ARRAYREFREF
 485 #======================================================================
 486
 487 sub _where_ARRAYREFREF {
 488     my ($self, $where) = @_;
 489     my ($sql, @bind) = @$$where;
 490     $self->_assert_bindval_matches_bindtype(@bind);
 491     return ($sql, @bind);
 492 }
 493
 494 #======================================================================
 495 # WHERE: top-level HASHREF
 496 #======================================================================
 497
 498 sub _where_HASHREF {
 499   my ($self, $where) = @_;
 500   my (@sql_clauses, @all_bind);
 501
 502   for my $k (sort keys %$where) {
 503     my $v = $where->{$k};
 504
 505     # ($k => $v) is either a special unary op or a regular hashpair
 506     my ($sql, @bind) = do {
 507       if ($k =~ /^-./) {
 508         # put the operator in canonical form
 509         my $op = $k;
 510         $op = substr $op, 1;  # remove initial dash
 511         $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 512         $op =~ s/\s+/ /g;     # compress whitespace
 513
 514         # so that -not_foo works correctly
 515         $op =~ s/^not_/NOT /i;
 516
 517         $self->_debug("Unary OP(-$op) within hashref, recursing...");
 518         my ($s, @b) = $self->_where_unary_op ($op, $v);
 519
 520         # top level vs nested
 521         # we assume that handled unary ops will take care of their ()s
 522         $s = "($s)" unless (
 523           List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}}
 524             or
 525           defined($self->{_nested_func_lhs}) && ($self->{_nested_func_lhs} eq $k)
 526         );
 527         ($s, @b);
 528       }
 529       else {
 530         my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 531         $self->$method($k, $v);
 532       }
 533     };
 534
 535     push @sql_clauses, $sql;
 536     push @all_bind, @bind;
 537   }
 538
 539   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 540 }
 541
 542 sub _where_unary_op {
 543   my ($self, $op, $rhs) = @_;
 544
 545   if (my $op_entry = List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}}) {
 546     my $handler = $op_entry->{handler};
 547
 548     if (not ref $handler) {
 549       if ($op =~ s/ [_\s]? \d+ $//x ) {
 550         belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
 551             . "You probably wanted ...-and => [ -$op => COND1, -$op => COND2 ... ]";
 552       }
 553       return $self->$handler ($op, $rhs);
 554     }
 555     elsif (ref $handler eq 'CODE') {
 556       return $handler->($self, $op, $rhs);
 557     }
 558     else {
 559       puke "Illegal handler for operator $op - expecting a method name or a coderef";
 560     }
 561   }
 562
 563   $self->_debug("Generic unary OP: $op - recursing as function");
 564
 565   $self->_assert_pass_injection_guard($op);
 566
 567   my ($sql, @bind) = $self->_SWITCH_refkind ($rhs, {
 568     SCALAR =>   sub {
 569       puke "Illegal use of top-level '$op'"
 570         unless $self->{_nested_func_lhs};
 571
 572       return (
 573         $self->_convert('?'),
 574         $self->_bindtype($self->{_nested_func_lhs}, $rhs)
 575       );
 576     },
 577     FALLBACK => sub {
 578       $self->_recurse_where ($rhs)
 579     },
 580   });
 581
 582   $sql = sprintf ('%s %s',
 583     $self->_sqlcase($op),
 584     $sql,
 585   );
 586
 587   return ($sql, @bind);
 588 }
 589
 590 sub _where_op_ANDOR {
 591   my ($self, $op, $v) = @_;
 592
 593   $self->_SWITCH_refkind($v, {
 594     ARRAYREF => sub {
 595       return $self->_where_ARRAYREF($v, $op);
 596     },
 597
 598     HASHREF => sub {
 599       return ( $op =~ /^or/i )
 600         ? $self->_where_ARRAYREF( [ map { $_ => $v->{$_} } ( sort keys %$v ) ], $op )
 601         : $self->_where_HASHREF($v);
 602     },
 603
 604     SCALARREF  => sub {
 605       puke "-$op => \\\$scalar makes little sense, use " .
 606         ($op =~ /^or/i
 607           ? '[ \$scalar, \%rest_of_conditions ] instead'
 608           : '-and => [ \$scalar, \%rest_of_conditions ] instead'
 609         );
 610     },
 611
 612     ARRAYREFREF => sub {
 613       puke "-$op => \\[...] makes little sense, use " .
 614         ($op =~ /^or/i
 615           ? '[ \[...], \%rest_of_conditions ] instead'
 616           : '-and => [ \[...], \%rest_of_conditions ] instead'
 617         );
 618     },
 619
 620     SCALAR => sub { # permissively interpreted as SQL
 621       puke "-$op => \$value makes little sense, use -bool => \$value instead";
 622     },
 623
 624     UNDEF => sub {
 625       puke "-$op => undef not supported";
 626     },
 627    });
 628 }
 629
 630 sub _where_op_NEST {
 631   my ($self, $op, $v) = @_;
 632
 633   $self->_SWITCH_refkind($v, {
 634
 635     SCALAR => sub { # permissively interpreted as SQL
 636       belch "literal SQL should be -nest => \\'scalar' "
 637           . "instead of -nest => 'scalar' ";
 638       return ($v);
 639     },
 640
 641     UNDEF => sub {
 642       puke "-$op => undef not supported";
 643     },
 644
 645     FALLBACK => sub {
 646       $self->_recurse_where ($v);
 647     },
 648
 649    });
 650 }
 651
 652
 653 sub _where_op_BOOL {
 654   my ($self, $op, $v) = @_;
 655
 656   my ($s, @b) = $self->_SWITCH_refkind($v, {
 657     SCALAR => sub { # interpreted as SQL column
 658       $self->_convert($self->_quote($v));
 659     },
 660
 661     UNDEF => sub {
 662       puke "-$op => undef not supported";
 663     },
 664
 665     FALLBACK => sub {
 666       $self->_recurse_where ($v);
 667     },
 668   });
 669
 670   $s = "(NOT $s)" if $op =~ /^not/i;
 671   ($s, @b);
 672 }
 673
 674
 675 sub _where_op_IDENT {
 676   my $self = shift;
 677   my ($op, $rhs) = splice @_, -2;
 678   if (ref $rhs) {
 679     puke "-$op takes a single scalar argument (a quotable identifier)";
 680   }
 681
 682   # in case we are called as a top level special op (no '=')
 683   my $lhs = shift;
 684
 685   $_ = $self->_convert($self->_quote($_)) for ($lhs, $rhs);
 686
 687   return $lhs
 688     ? "$lhs = $rhs"
 689     : $rhs
 690   ;
 691 }
 692
 693 sub _where_op_VALUE {
 694   my $self = shift;
 695   my ($op, $rhs) = splice @_, -2;
 696
 697   # in case we are called as a top level special op (no '=')
 698   my $lhs = shift;
 699
 700   my @bind =
 701     $self->_bindtype (
 702       ($lhs || $self->{_nested_func_lhs}),
 703       $rhs,
 704     )
 705   ;
 706
 707   return $lhs
 708     ? (
 709       $self->_convert($self->_quote($lhs)) . ' = ' . $self->_convert('?'),
 710       @bind
 711     )
 712     : (
 713       $self->_convert('?'),
 714       @bind,
 715     )
 716   ;
 717 }
 718
 719 sub _where_hashpair_ARRAYREF {
 720   my ($self, $k, $v) = @_;
 721
 722   if( @$v ) {
 723     my @v = @$v; # need copy because of shift below
 724     $self->_debug("ARRAY($k) means distribute over elements");
 725
 726     # put apart first element if it is an operator (-and, -or)
 727     my $op = (
 728        (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
 729          ? shift @v
 730          : ''
 731     );
 732     my @distributed = map { {$k =>  $_} } @v;
 733
 734     if ($op) {
 735       $self->_debug("OP($op) reinjected into the distributed array");
 736       unshift @distributed, $op;
 737     }
 738
 739     my $logic = $op ? substr($op, 1) : '';
 740
 741     return $self->_recurse_where(\@distributed, $logic);
 742   }
 743   else {
 744     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 745     $self->_debug("empty ARRAY($k) means 0=1");
 746     return ($self->{sqlfalse});
 747   }
 748 }
 749
 750 sub _where_hashpair_HASHREF {
 751   my ($self, $k, $v, $logic) = @_;
 752   $logic ||= 'and';
 753
 754   local $self->{_nested_func_lhs} = $self->{_nested_func_lhs};
 755
 756   my ($all_sql, @all_bind);
 757
 758   for my $orig_op (sort keys %$v) {
 759     my $val = $v->{$orig_op};
 760
 761     # put the operator in canonical form
 762     my $op = $orig_op;
 763
 764     # FIXME - we need to phase out dash-less ops
 765     $op =~ s/^-//;        # remove possible initial dash
 766     $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 767     $op =~ s/\s+/ /g;     # compress whitespace
 768
 769     $self->_assert_pass_injection_guard($op);
 770
 771     # so that -not_foo works correctly
 772     $op =~ s/^not_/NOT /i;
 773
 774     my ($sql, @bind);
 775
 776     # CASE: col-value logic modifiers
 777     if ( $orig_op =~ /^ \- (and|or) $/xi ) {
 778       ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $1);
 779     }
 780     # CASE: special operators like -in or -between
 781     elsif ( my $special_op = List::Util::first {$op =~ $_->{regex}} @{$self->{special_ops}} ) {
 782       my $handler = $special_op->{handler};
 783       if (! $handler) {
 784         puke "No handler supplied for special operator $orig_op";
 785       }
 786       elsif (not ref $handler) {
 787         ($sql, @bind) = $self->$handler ($k, $op, $val);
 788       }
 789       elsif (ref $handler eq 'CODE') {
 790         ($sql, @bind) = $handler->($self, $k, $op, $val);
 791       }
 792       else {
 793         puke "Illegal handler for special operator $orig_op - expecting a method name or a coderef";
 794       }
 795     }
 796     else {
 797       $self->_SWITCH_refkind($val, {
 798
 799         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 800           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 801         },
 802
 803         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 804           my ($sub_sql, @sub_bind) = @$$val;
 805           $self->_assert_bindval_matches_bindtype(@sub_bind);
 806           $sql  = join ' ', $self->_convert($self->_quote($k)),
 807                             $self->_sqlcase($op),
 808                             $sub_sql;
 809           @bind = @sub_bind;
 810         },
 811
 812         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 813           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 814                    ($op =~ $self->{inequality_op}) ? 'is not' :
 815                puke "unexpected operator '$orig_op' with undef operand";
 816           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 817         },
 818
 819         FALLBACK => sub {       # CASE: col => {op/func => $stuff}
 820
 821           # retain for proper column type bind
 822           $self->{_nested_func_lhs} ||= $k;
 823
 824           ($sql, @bind) = $self->_where_unary_op ($op, $val);
 825
 826           $sql = join (' ',
 827             $self->_convert($self->_quote($k)),
 828             $self->{_nested_func_lhs} eq $k ? $sql : "($sql)",  # top level vs nested
 829           );
 830         },
 831       });
 832     }
 833
 834     ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
 835     push @all_bind, @bind;
 836   }
 837   return ($all_sql, @all_bind);
 838 }
 839
 840
 841
 842 sub _where_field_op_ARRAYREF {
 843   my ($self, $k, $op, $vals) = @_;
 844
 845   my @vals = @$vals;  #always work on a copy
 846
 847   if(@vals) {
 848     $self->_debug(sprintf '%s means multiple elements: [ %s ]',
 849       $vals,
 850       join (', ', map { defined $_ ? "'$_'" : 'NULL' } @vals ),
 851     );
 852
 853     # see if the first element is an -and/-or op
 854     my $logic;
 855     if (defined $vals[0] && $vals[0] =~ /^ - ( AND|OR ) $/ix) {
 856       $logic = uc $1;
 857       shift @vals;
 858     }
 859
 860     # distribute $op over each remaining member of @vals, append logic if exists
 861     return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 862
 863     # LDNOTE : had planned to change the distribution logic when
 864     # $op =~ $self->{inequality_op}, because of Morgan laws :
 865     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 866     # WHERE field != 22 OR  field != 33 : the user probably means
 867     # WHERE field != 22 AND field != 33.
 868     # To do this, replace the above to roughly :
 869     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 870     # return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 871
 872   }
 873   else {
 874     # try to DWIM on equality operators
 875     # LDNOTE : not 100% sure this is the correct thing to do ...
 876     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 877     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 878
 879     # otherwise
 880     puke "operator '$op' applied on an empty array (field '$k')";
 881   }
 882 }
 883
 884
 885 sub _where_hashpair_SCALARREF {
 886   my ($self, $k, $v) = @_;
 887   $self->_debug("SCALAR($k) means literal SQL: $$v");
 888   my $sql = $self->_quote($k) . " " . $$v;
 889   return ($sql);
 890 }
 891
 892 # literal SQL with bind
 893 sub _where_hashpair_ARRAYREFREF {
 894   my ($self, $k, $v) = @_;
 895   $self->_debug("REF($k) means literal SQL: @${$v}");
 896   my ($sql, @bind) = @$$v;
 897   $self->_assert_bindval_matches_bindtype(@bind);
 898   $sql  = $self->_quote($k) . " " . $sql;
 899   return ($sql, @bind );
 900 }
 901
 902 # literal SQL without bind
 903 sub _where_hashpair_SCALAR {
 904   my ($self, $k, $v) = @_;
 905   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 906   my $sql = join ' ', $self->_convert($self->_quote($k)),
 907                       $self->_sqlcase($self->{cmp}),
 908                       $self->_convert('?');
 909   my @bind =  $self->_bindtype($k, $v);
 910   return ( $sql, @bind);
 911 }
 912
 913
 914 sub _where_hashpair_UNDEF {
 915   my ($self, $k, $v) = @_;
 916   $self->_debug("UNDEF($k) means IS NULL");
 917   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 918   return ($sql);
 919 }
 920
 921 #======================================================================
 922 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 923 #======================================================================
 924
 925
 926 sub _where_SCALARREF {
 927   my ($self, $where) = @_;
 928
 929   # literal sql
 930   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 931   return ($$where);
 932 }
 933
 934
 935 sub _where_SCALAR {
 936   my ($self, $where) = @_;
 937
 938   # literal sql
 939   $self->_debug("NOREF(*top) means literal SQL: $where");
 940   return ($where);
 941 }
 942
 943
 944 sub _where_UNDEF {
 945   my ($self) = @_;
 946   return ();
 947 }
 948
 949
 950 #======================================================================
 951 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 952 #======================================================================
 953
 954
 955 sub _where_field_BETWEEN {
 956   my ($self, $k, $op, $vals) = @_;
 957
 958   my ($label, $and, $placeholder);
 959   $label       = $self->_convert($self->_quote($k));
 960   $and         = ' ' . $self->_sqlcase('and') . ' ';
 961   $placeholder = $self->_convert('?');
 962   $op               = $self->_sqlcase($op);
 963
 964   my ($clause, @bind) = $self->_SWITCH_refkind($vals, {
 965     ARRAYREFREF => sub {
 966       my ($s, @b) = @$$vals;
 967       $self->_assert_bindval_matches_bindtype(@b);
 968       ($s, @b);
 969     },
 970     SCALARREF => sub {
 971       return $$vals;
 972     },
 973     ARRAYREF => sub {
 974       puke "special op 'between' accepts an arrayref with exactly two values"
 975         if @$vals != 2;
 976
 977       my (@all_sql, @all_bind);
 978       foreach my $val (@$vals) {
 979         my ($sql, @bind) = $self->_SWITCH_refkind($val, {
 980            SCALAR => sub {
 981              return ($placeholder, $self->_bindtype($k, $val) );
 982            },
 983            SCALARREF => sub {
 984              return $$val;
 985            },
 986            ARRAYREFREF => sub {
 987              my ($sql, @bind) = @$$val;
 988              $self->_assert_bindval_matches_bindtype(@bind);
 989              return ($sql, @bind);
 990            },
 991            HASHREF => sub {
 992              my ($func, $arg, @rest) = %$val;
 993              puke ("Only simple { -func => arg } functions accepted as sub-arguments to BETWEEN")
 994                if (@rest or $func !~ /^ \- (.+)/x);
 995              local $self->{_nested_func_lhs} = $k;
 996              $self->_where_unary_op ($1 => $arg);
 997            }
 998         });
 999         push @all_sql, $sql;
1000         push @all_bind, @bind;
1001       }
1002
1003       return (
1004         (join $and, @all_sql),
1005         @all_bind
1006       );
1007     },
1008     FALLBACK => sub {
1009       puke "special op 'between' accepts an arrayref with two values, or a single literal scalarref/arrayref-ref";
1010     },
1011   });
1012
1013   my $sql = "( $label $op $clause )";
1014   return ($sql, @bind)
1015 }
1016
1017
1018 sub _where_field_IN {
1019   my ($self, $k, $op, $vals) = @_;
1020
1021   # backwards compatibility : if scalar, force into an arrayref
1022   $vals = [$vals] if defined $vals && ! ref $vals;
1023
1024   my ($label)       = $self->_convert($self->_quote($k));
1025   my ($placeholder) = $self->_convert('?');
1026   $op               = $self->_sqlcase($op);
1027
1028   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
1029     ARRAYREF => sub {     # list of choices
1030       if (@$vals) { # nonempty list
1031         my (@all_sql, @all_bind);
1032
1033         for my $val (@$vals) {
1034           my ($sql, @bind) = $self->_SWITCH_refkind($val, {
1035             SCALAR => sub {
1036               return ($placeholder, $val);
1037             },
1038             SCALARREF => sub {
1039               return $$val;
1040             },
1041             ARRAYREFREF => sub {
1042               my ($sql, @bind) = @$$val;
1043               $self->_assert_bindval_matches_bindtype(@bind);
1044               return ($sql, @bind);
1045             },
1046             HASHREF => sub {
1047               my ($func, $arg, @rest) = %$val;
1048               puke ("Only simple { -func => arg } functions accepted as sub-arguments to IN")
1049                 if (@rest or $func !~ /^ \- (.+)/x);
1050               local $self->{_nested_func_lhs} = $k;
1051               $self->_where_unary_op ($1 => $arg);
1052             },
1053             UNDEF => sub {
1054               return $self->_sqlcase('null');
1055             },
1056           });
1057           push @all_sql, $sql;
1058           push @all_bind, @bind;
1059         }
1060
1061         return (
1062           sprintf ('%s %s ( %s )',
1063             $label,
1064             $op,
1065             join (', ', @all_sql)
1066           ),
1067           $self->_bindtype($k, @all_bind),
1068         );
1069       }
1070       else { # empty list : some databases won't understand "IN ()", so DWIM
1071         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
1072         return ($sql);
1073       }
1074     },
1075
1076     SCALARREF => sub {  # literal SQL
1077       my $sql = $self->_open_outer_paren ($$vals);
1078       return ("$label $op ( $sql )");
1079     },
1080     ARRAYREFREF => sub {  # literal SQL with bind
1081       my ($sql, @bind) = @$$vals;
1082       $self->_assert_bindval_matches_bindtype(@bind);
1083       $sql = $self->_open_outer_paren ($sql);
1084       return ("$label $op ( $sql )", @bind);
1085     },
1086
1087     FALLBACK => sub {
1088       puke "special op 'in' requires an arrayref (or scalarref/arrayref-ref)";
1089     },
1090   });
1091
1092   return ($sql, @bind);
1093 }
1094
1095 # Some databases (SQLite) treat col IN (1, 2) different from
1096 # col IN ( (1, 2) ). Use this to strip all outer parens while
1097 # adding them back in the corresponding method
1098 sub _open_outer_paren {
1099   my ($self, $sql) = @_;
1100   $sql = $1 while $sql =~ /^ \s* \( (.*) \) \s* $/xs;
1101   return $sql;
1102 }
1103
1104
1105 #======================================================================
1106 # ORDER BY
1107 #======================================================================
1108
1109 sub _order_by {
1110   my ($self, $arg) = @_;
1111
1112   my (@sql, @bind);
1113   for my $c ($self->_order_by_chunks ($arg) ) {
1114     $self->_SWITCH_refkind ($c, {
1115       SCALAR => sub { push @sql, $c },
1116       ARRAYREF => sub { push @sql, shift @$c; push @bind, @$c },
1117     });
1118   }
1119
1120   my $sql = @sql
1121     ? sprintf ('%s %s',
1122         $self->_sqlcase(' order by'),
1123         join (', ', @sql)
1124       )
1125     : ''
1126   ;
1127
1128   return wantarray ? ($sql, @bind) : $sql;
1129 }
1130
1131 sub _order_by_chunks {
1132   my ($self, $arg) = @_;
1133
1134   return $self->_SWITCH_refkind($arg, {
1135
1136     ARRAYREF => sub {
1137       map { $self->_order_by_chunks ($_ ) } @$arg;
1138     },
1139
1140     ARRAYREFREF => sub {
1141       my ($s, @b) = @$$arg;
1142       $self->_assert_bindval_matches_bindtype(@b);
1143       [ $s, @b ];
1144     },
1145
1146     SCALAR    => sub {$self->_quote($arg)},
1147
1148     UNDEF     => sub {return () },
1149
1150     SCALARREF => sub {$$arg}, # literal SQL, no quoting
1151
1152     HASHREF   => sub {
1153       return () unless %$arg;
1154
1155       my ($direction, $nulls, $val);
1156       foreach my $key (keys %$arg) {
1157         if ( $key =~ /^-(desc|asc)/i ) {
1158           puke "hash passed to _order_by must have exactly one of -desc or -asc"
1159               if defined $direction;
1160           $direction = $1;
1161           $val = $arg->{$key};
1162         } elsif ($key =~ /^-nulls$/i)  {
1163           $nulls = $arg->{$key};
1164           puke "invalid value for -nulls" unless $nulls =~ /^(?:first|last)$/i;
1165         } else {
1166           puke "invalid key in hash passed to _order_by";
1167         }
1168       }
1169       puke "hash passed to _order_by must have exactly one of -desc or -asc"
1170           unless defined $direction;
1171
1172       my @ret;
1173       for my $c ($self->_order_by_chunks ($val)) {
1174         my ($sql, @bind);
1175
1176         $self->_SWITCH_refkind ($c, {
1177           SCALAR => sub {
1178             $sql = $c;
1179           },
1180           ARRAYREF => sub {
1181             ($sql, @bind) = @$c;
1182           },
1183         });
1184
1185         $sql .= ' ' . $self->_sqlcase($direction);
1186         $sql .= ' ' . $self->_sqlcase("nulls $nulls")
1187             if defined $nulls;
1188
1189         push @ret, [ $sql, @bind];
1190       }
1191
1192       return @ret;
1193     },
1194   });
1195 }
1196
1197
1198 #======================================================================
1199 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
1200 #======================================================================
1201
1202 sub _table  {
1203   my $self = shift;
1204   my $from = shift;
1205   $self->_SWITCH_refkind($from, {
1206     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
1207     SCALAR       => sub {$self->_quote($from)},
1208     SCALARREF    => sub {$$from},
1209   });
1210 }
1211
1212
1213 #======================================================================
1214 # UTILITY FUNCTIONS
1215 #======================================================================
1216
1217 # highly optimized, as it's called way too often
1218 sub _quote {
1219   # my ($self, $label) = @_;
1220
1221   return '' unless defined $_[1];
1222   return ${$_[1]} if ref($_[1]) eq 'SCALAR';
1223
1224   unless ($_[0]->{quote_char}) {
1225     $_[0]->_assert_pass_injection_guard($_[1]);
1226     return $_[1];
1227   }
1228
1229   my $qref = ref $_[0]->{quote_char};
1230   my ($l, $r);
1231   if (!$qref) {
1232     ($l, $r) = ( $_[0]->{quote_char}, $_[0]->{quote_char} );
1233   }
1234   elsif ($qref eq 'ARRAY') {
1235     ($l, $r) = @{$_[0]->{quote_char}};
1236   }
1237   else {
1238     puke "Unsupported quote_char format: $_[0]->{quote_char}";
1239   }
1240
1241   # parts containing * are naturally unquoted
1242   return join( $_[0]->{name_sep}||'', map
1243     { $_ eq '*' ? $_ : $l . $_ . $r }
1244     ( $_[0]->{name_sep} ? split (/\Q$_[0]->{name_sep}\E/, $_[1] ) : $_[1] )
1245   );
1246 }
1247
1248
1249 # Conversion, if applicable
1250 sub _convert ($) {
1251   #my ($self, $arg) = @_;
1252
1253 # LDNOTE : modified the previous implementation below because
1254 # it was not consistent : the first "return" is always an array,
1255 # the second "return" is context-dependent. Anyway, _convert
1256 # seems always used with just a single argument, so make it a
1257 # scalar function.
1258 #     return @_ unless $self->{convert};
1259 #     my $conv = $self->_sqlcase($self->{convert});
1260 #     my @ret = map { $conv.'('.$_.')' } @_;
1261 #     return wantarray ? @ret : $ret[0];
1262   if ($_[0]->{convert}) {
1263     return $_[0]->_sqlcase($_[0]->{convert}) .'(' . $_[1] . ')';
1264   }
1265   return $_[1];
1266 }
1267
1268 # And bindtype
1269 sub _bindtype (@) {
1270   #my ($self, $col, @vals) = @_;
1271
1272   #LDNOTE : changed original implementation below because it did not make
1273   # sense when bindtype eq 'columns' and @vals > 1.
1274 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
1275
1276   # called often - tighten code
1277   return $_[0]->{bindtype} eq 'columns'
1278     ? map {[$_[1], $_]} @_[2 .. $#_]
1279     : @_[2 .. $#_]
1280   ;
1281 }
1282
1283 # Dies if any element of @bind is not in [colname => value] format
1284 # if bindtype is 'columns'.
1285 sub _assert_bindval_matches_bindtype {
1286 #  my ($self, @bind) = @_;
1287   my $self = shift;
1288   if ($self->{bindtype} eq 'columns') {
1289     for (@_) {
1290       if (!defined $_ || ref($_) ne 'ARRAY' || @$_ != 2) {
1291         puke "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
1292       }
1293     }
1294   }
1295 }
1296
1297 sub _join_sql_clauses {
1298   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
1299
1300   if (@$clauses_aref > 1) {
1301     my $join  = " " . $self->_sqlcase($logic) . " ";
1302     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
1303     return ($sql, @$bind_aref);
1304   }
1305   elsif (@$clauses_aref) {
1306     return ($clauses_aref->[0], @$bind_aref); # no parentheses
1307   }
1308   else {
1309     return (); # if no SQL, ignore @$bind_aref
1310   }
1311 }
1312
1313
1314 # Fix SQL case, if so requested
1315 sub _sqlcase {
1316   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
1317   # don't touch the argument ... crooked logic, but let's not change it!
1318   return $_[0]->{case} ? $_[1] : uc($_[1]);
1319 }
1320
1321
1322 #======================================================================
1323 # DISPATCHING FROM REFKIND
1324 #======================================================================
1325
1326 sub _refkind {
1327   my ($self, $data) = @_;
1328
1329   return 'UNDEF' unless defined $data;
1330
1331   # blessed objects are treated like scalars
1332   my $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1333
1334   return 'SCALAR' unless $ref;
1335
1336   my $n_steps = 1;
1337   while ($ref eq 'REF') {
1338     $data = $$data;
1339     $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1340     $n_steps++ if $ref;
1341   }
1342
1343   return ($ref||'SCALAR') . ('REF' x $n_steps);
1344 }
1345
1346 sub _try_refkind {
1347   my ($self, $data) = @_;
1348   my @try = ($self->_refkind($data));
1349   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1350   push @try, 'FALLBACK';
1351   return \@try;
1352 }
1353
1354 sub _METHOD_FOR_refkind {
1355   my ($self, $meth_prefix, $data) = @_;
1356
1357   my $method;
1358   for (@{$self->_try_refkind($data)}) {
1359     $method = $self->can($meth_prefix."_".$_)
1360       and last;
1361   }
1362
1363   return $method || puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1364 }
1365
1366
1367 sub _SWITCH_refkind {
1368   my ($self, $data, $dispatch_table) = @_;
1369
1370   my $coderef;
1371   for (@{$self->_try_refkind($data)}) {
1372     $coderef = $dispatch_table->{$_}
1373       and last;
1374   }
1375
1376   puke "no dispatch entry for ".$self->_refkind($data)
1377     unless $coderef;
1378
1379   $coderef->();
1380 }
1381
1382
1383
1384
1385 #======================================================================
1386 # VALUES, GENERATE, AUTOLOAD
1387 #======================================================================
1388
1389 # LDNOTE: original code from nwiger, didn't touch code in that section
1390 # I feel the AUTOLOAD stuff should not be the default, it should
1391 # only be activated on explicit demand by user.
1392
1393 sub values {
1394     my $self = shift;
1395     my $data = shift || return;
1396     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1397         unless ref $data eq 'HASH';
1398
1399     my @all_bind;
1400     foreach my $k ( sort keys %$data ) {
1401         my $v = $data->{$k};
1402         $self->_SWITCH_refkind($v, {
1403           ARRAYREF => sub {
1404             if ($self->{array_datatypes}) { # array datatype
1405               push @all_bind, $self->_bindtype($k, $v);
1406             }
1407             else {                          # literal SQL with bind
1408               my ($sql, @bind) = @$v;
1409               $self->_assert_bindval_matches_bindtype(@bind);
1410               push @all_bind, @bind;
1411             }
1412           },
1413           ARRAYREFREF => sub { # literal SQL with bind
1414             my ($sql, @bind) = @${$v};
1415             $self->_assert_bindval_matches_bindtype(@bind);
1416             push @all_bind, @bind;
1417           },
1418           SCALARREF => sub {  # literal SQL without bind
1419           },
1420           SCALAR_or_UNDEF => sub {
1421             push @all_bind, $self->_bindtype($k, $v);
1422           },
1423         });
1424     }
1425
1426     return @all_bind;
1427 }
1428
1429 sub generate {
1430     my $self  = shift;
1431
1432     my(@sql, @sqlq, @sqlv);
1433
1434     for (@_) {
1435         my $ref = ref $_;
1436         if ($ref eq 'HASH') {
1437             for my $k (sort keys %$_) {
1438                 my $v = $_->{$k};
1439                 my $r = ref $v;
1440                 my $label = $self->_quote($k);
1441                 if ($r eq 'ARRAY') {
1442                     # literal SQL with bind
1443                     my ($sql, @bind) = @$v;
1444                     $self->_assert_bindval_matches_bindtype(@bind);
1445                     push @sqlq, "$label = $sql";
1446                     push @sqlv, @bind;
1447                 } elsif ($r eq 'SCALAR') {
1448                     # literal SQL without bind
1449                     push @sqlq, "$label = $$v";
1450                 } else {
1451                     push @sqlq, "$label = ?";
1452                     push @sqlv, $self->_bindtype($k, $v);
1453                 }
1454             }
1455             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1456         } elsif ($ref eq 'ARRAY') {
1457             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1458             for my $v (@$_) {
1459                 my $r = ref $v;
1460                 if ($r eq 'ARRAY') {   # literal SQL with bind
1461                     my ($sql, @bind) = @$v;
1462                     $self->_assert_bindval_matches_bindtype(@bind);
1463                     push @sqlq, $sql;
1464                     push @sqlv, @bind;
1465                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1466                     # embedded literal SQL
1467                     push @sqlq, $$v;
1468                 } else {
1469                     push @sqlq, '?';
1470                     push @sqlv, $v;
1471                 }
1472             }
1473             push @sql, '(' . join(', ', @sqlq) . ')';
1474         } elsif ($ref eq 'SCALAR') {
1475             # literal SQL
1476             push @sql, $$_;
1477         } else {
1478             # strings get case twiddled
1479             push @sql, $self->_sqlcase($_);
1480         }
1481     }
1482
1483     my $sql = join ' ', @sql;
1484
1485     # this is pretty tricky
1486     # if ask for an array, return ($stmt, @bind)
1487     # otherwise, s/?/shift @sqlv/ to put it inline
1488     if (wantarray) {
1489         return ($sql, @sqlv);
1490     } else {
1491         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1492                              ref $d ? $d->[1] : $d/e;
1493         return $sql;
1494     }
1495 }
1496
1497
1498 sub DESTROY { 1 }
1499
1500 sub AUTOLOAD {
1501     # This allows us to check for a local, then _form, attr
1502     my $self = shift;
1503     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1504     return $self->generate($name, @_);
1505 }
1506
1507 1;
1508
1509
1510
1511 __END__
1512
1513 =head1 NAME
1514
1515 SQL::Abstract - Generate SQL from Perl data structures
1516
1517 =head1 SYNOPSIS
1518
1519     use SQL::Abstract;
1520
1521     my $sql = SQL::Abstract->new;
1522
1523     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1524
1525     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1526
1527     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1528
1529     my($stmt, @bind) = $sql->delete($table, \%where);
1530
1531     # Then, use these in your DBI statements
1532     my $sth = $dbh->prepare($stmt);
1533     $sth->execute(@bind);
1534
1535     # Just generate the WHERE clause
1536     my($stmt, @bind) = $sql->where(\%where, \@order);
1537
1538     # Return values in the same order, for hashed queries
1539     # See PERFORMANCE section for more details
1540     my @bind = $sql->values(\%fieldvals);
1541
1542 =head1 DESCRIPTION
1543
1544 This module was inspired by the excellent L<DBIx::Abstract>.
1545 However, in using that module I found that what I really wanted
1546 to do was generate SQL, but still retain complete control over my
1547 statement handles and use the DBI interface. So, I set out to
1548 create an abstract SQL generation module.
1549
1550 While based on the concepts used by L<DBIx::Abstract>, there are
1551 several important differences, especially when it comes to WHERE
1552 clauses. I have modified the concepts used to make the SQL easier
1553 to generate from Perl data structures and, IMO, more intuitive.
1554 The underlying idea is for this module to do what you mean, based
1555 on the data structures you provide it. The big advantage is that
1556 you don't have to modify your code every time your data changes,
1557 as this module figures it out.
1558
1559 To begin with, an SQL INSERT is as easy as just specifying a hash
1560 of C<key=value> pairs:
1561
1562     my %data = (
1563         name => 'Jimbo Bobson',
1564         phone => '123-456-7890',
1565         address => '42 Sister Lane',
1566         city => 'St. Louis',
1567         state => 'Louisiana',
1568     );
1569
1570 The SQL can then be generated with this:
1571
1572     my($stmt, @bind) = $sql->insert('people', \%data);
1573
1574 Which would give you something like this:
1575
1576     $stmt = "INSERT INTO people
1577                     (address, city, name, phone, state)
1578                     VALUES (?, ?, ?, ?, ?)";
1579     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1580              '123-456-7890', 'Louisiana');
1581
1582 These are then used directly in your DBI code:
1583
1584     my $sth = $dbh->prepare($stmt);
1585     $sth->execute(@bind);
1586
1587 =head2 Inserting and Updating Arrays
1588
1589 If your database has array types (like for example Postgres),
1590 activate the special option C<< array_datatypes => 1 >>
1591 when creating the C<SQL::Abstract> object.
1592 Then you may use an arrayref to insert and update database array types:
1593
1594     my $sql = SQL::Abstract->new(array_datatypes => 1);
1595     my %data = (
1596         planets => [qw/Mercury Venus Earth Mars/]
1597     );
1598
1599     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1600
1601 This results in:
1602
1603     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1604
1605     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1606
1607
1608 =head2 Inserting and Updating SQL
1609
1610 In order to apply SQL functions to elements of your C<%data> you may
1611 specify a reference to an arrayref for the given hash value. For example,
1612 if you need to execute the Oracle C<to_date> function on a value, you can
1613 say something like this:
1614
1615     my %data = (
1616         name => 'Bill',
1617         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1618     );
1619
1620 The first value in the array is the actual SQL. Any other values are
1621 optional and would be included in the bind values array. This gives
1622 you:
1623
1624     my($stmt, @bind) = $sql->insert('people', \%data);
1625
1626     $stmt = "INSERT INTO people (name, date_entered)
1627                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1628     @bind = ('Bill', '03/02/2003');
1629
1630 An UPDATE is just as easy, all you change is the name of the function:
1631
1632     my($stmt, @bind) = $sql->update('people', \%data);
1633
1634 Notice that your C<%data> isn't touched; the module will generate
1635 the appropriately quirky SQL for you automatically. Usually you'll
1636 want to specify a WHERE clause for your UPDATE, though, which is
1637 where handling C<%where> hashes comes in handy...
1638
1639 =head2 Complex where statements
1640
1641 This module can generate pretty complicated WHERE statements
1642 easily. For example, simple C<key=value> pairs are taken to mean
1643 equality, and if you want to see if a field is within a set
1644 of values, you can use an arrayref. Let's say we wanted to
1645 SELECT some data based on this criteria:
1646
1647     my %where = (
1648        requestor => 'inna',
1649        worker => ['nwiger', 'rcwe', 'sfz'],
1650        status => { '!=', 'completed' }
1651     );
1652
1653     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1654
1655 The above would give you something like this:
1656
1657     $stmt = "SELECT * FROM tickets WHERE
1658                 ( requestor = ? ) AND ( status != ? )
1659                 AND ( worker = ? OR worker = ? OR worker = ? )";
1660     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1661
1662 Which you could then use in DBI code like so:
1663
1664     my $sth = $dbh->prepare($stmt);
1665     $sth->execute(@bind);
1666
1667 Easy, eh?
1668
1669 =head1 FUNCTIONS
1670
1671 The functions are simple. There's one for each major SQL operation,
1672 and a constructor you use first. The arguments are specified in a
1673 similar order to each function (table, then fields, then a where
1674 clause) to try and simplify things.
1675
1676
1677
1678
1679 =head2 new(option => 'value')
1680
1681 The C<new()> function takes a list of options and values, and returns
1682 a new B<SQL::Abstract> object which can then be used to generate SQL
1683 through the methods below. The options accepted are:
1684
1685 =over
1686
1687 =item case
1688
1689 If set to 'lower', then SQL will be generated in all lowercase. By
1690 default SQL is generated in "textbook" case meaning something like:
1691
1692     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1693
1694 Any setting other than 'lower' is ignored.
1695
1696 =item cmp
1697
1698 This determines what the default comparison operator is. By default
1699 it is C<=>, meaning that a hash like this:
1700
1701     %where = (name => 'nwiger', email => 'nate@wiger.org');
1702
1703 Will generate SQL like this:
1704
1705     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1706
1707 However, you may want loose comparisons by default, so if you set
1708 C<cmp> to C<like> you would get SQL such as:
1709
1710     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1711
1712 You can also override the comparsion on an individual basis - see
1713 the huge section on L</"WHERE CLAUSES"> at the bottom.
1714
1715 =item sqltrue, sqlfalse
1716
1717 Expressions for inserting boolean values within SQL statements.
1718 By default these are C<1=1> and C<1=0>. They are used
1719 by the special operators C<-in> and C<-not_in> for generating
1720 correct SQL even when the argument is an empty array (see below).
1721
1722 =item logic
1723
1724 This determines the default logical operator for multiple WHERE
1725 statements in arrays or hashes. If absent, the default logic is "or"
1726 for arrays, and "and" for hashes. This means that a WHERE
1727 array of the form:
1728
1729     @where = (
1730         event_date => {'>=', '2/13/99'},
1731         event_date => {'<=', '4/24/03'},
1732     );
1733
1734 will generate SQL like this:
1735
1736     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1737
1738 This is probably not what you want given this query, though (look
1739 at the dates). To change the "OR" to an "AND", simply specify:
1740
1741     my $sql = SQL::Abstract->new(logic => 'and');
1742
1743 Which will change the above C<WHERE> to:
1744
1745     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1746
1747 The logic can also be changed locally by inserting
1748 a modifier in front of an arrayref :
1749
1750     @where = (-and => [event_date => {'>=', '2/13/99'},
1751                        event_date => {'<=', '4/24/03'} ]);
1752
1753 See the L</"WHERE CLAUSES"> section for explanations.
1754
1755 =item convert
1756
1757 This will automatically convert comparisons using the specified SQL
1758 function for both column and value. This is mostly used with an argument
1759 of C<upper> or C<lower>, so that the SQL will have the effect of
1760 case-insensitive "searches". For example, this:
1761
1762     $sql = SQL::Abstract->new(convert => 'upper');
1763     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1764
1765 Will turn out the following SQL:
1766
1767     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1768
1769 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1770 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1771 not validate this option; it will just pass through what you specify verbatim).
1772
1773 =item bindtype
1774
1775 This is a kludge because many databases suck. For example, you can't
1776 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1777 Instead, you have to use C<bind_param()>:
1778
1779     $sth->bind_param(1, 'reg data');
1780     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1781
1782 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1783 which loses track of which field each slot refers to. Fear not.
1784
1785 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1786 Currently, you can specify either C<normal> (default) or C<columns>. If you
1787 specify C<columns>, you will get an array that looks like this:
1788
1789     my $sql = SQL::Abstract->new(bindtype => 'columns');
1790     my($stmt, @bind) = $sql->insert(...);
1791
1792     @bind = (
1793         [ 'column1', 'value1' ],
1794         [ 'column2', 'value2' ],
1795         [ 'column3', 'value3' ],
1796     );
1797
1798 You can then iterate through this manually, using DBI's C<bind_param()>.
1799
1800     $sth->prepare($stmt);
1801     my $i = 1;
1802     for (@bind) {
1803         my($col, $data) = @$_;
1804         if ($col eq 'details' || $col eq 'comments') {
1805             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1806         } elsif ($col eq 'image') {
1807             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1808         } else {
1809             $sth->bind_param($i, $data);
1810         }
1811         $i++;
1812     }
1813     $sth->execute;      # execute without @bind now
1814
1815 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1816 Basically, the advantage is still that you don't have to care which fields
1817 are or are not included. You could wrap that above C<for> loop in a simple
1818 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1819 get a layer of abstraction over manual SQL specification.
1820
1821 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1822 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1823 will expect the bind values in this format.
1824
1825 =item quote_char
1826
1827 This is the character that a table or column name will be quoted
1828 with.  By default this is an empty string, but you could set it to
1829 the character C<`>, to generate SQL like this:
1830
1831   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1832
1833 Alternatively, you can supply an array ref of two items, the first being the left
1834 hand quote character, and the second the right hand quote character. For
1835 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1836 that generates SQL like this:
1837
1838   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1839
1840 Quoting is useful if you have tables or columns names that are reserved
1841 words in your database's SQL dialect.
1842
1843 =item name_sep
1844
1845 This is the character that separates a table and column name.  It is
1846 necessary to specify this when the C<quote_char> option is selected,
1847 so that tables and column names can be individually quoted like this:
1848
1849   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1850
1851 =item injection_guard
1852
1853 A regular expression C<qr/.../> that is applied to any C<-function> and unquoted
1854 column name specified in a query structure. This is a safety mechanism to avoid
1855 injection attacks when mishandling user input e.g.:
1856
1857   my %condition_as_column_value_pairs = get_values_from_user();
1858   $sqla->select( ... , \%condition_as_column_value_pairs );
1859
1860 If the expression matches an exception is thrown. Note that literal SQL
1861 supplied via C<\'...'> or C<\['...']> is B<not> checked in any way.
1862
1863 Defaults to checking for C<;> and the C<GO> keyword (TransactSQL)
1864
1865 =item array_datatypes
1866
1867 When this option is true, arrayrefs in INSERT or UPDATE are
1868 interpreted as array datatypes and are passed directly
1869 to the DBI layer.
1870 When this option is false, arrayrefs are interpreted
1871 as literal SQL, just like refs to arrayrefs
1872 (but this behavior is for backwards compatibility; when writing
1873 new queries, use the "reference to arrayref" syntax
1874 for literal SQL).
1875
1876
1877 =item special_ops
1878
1879 Takes a reference to a list of "special operators"
1880 to extend the syntax understood by L<SQL::Abstract>.
1881 See section L</"SPECIAL OPERATORS"> for details.
1882
1883 =item unary_ops
1884
1885 Takes a reference to a list of "unary operators"
1886 to extend the syntax understood by L<SQL::Abstract>.
1887 See section L</"UNARY OPERATORS"> for details.
1888
1889
1890
1891 =back
1892
1893 =head2 insert($table, \@values || \%fieldvals, \%options)
1894
1895 This is the simplest function. You simply give it a table name
1896 and either an arrayref of values or hashref of field/value pairs.
1897 It returns an SQL INSERT statement and a list of bind values.
1898 See the sections on L</"Inserting and Updating Arrays"> and
1899 L</"Inserting and Updating SQL"> for information on how to insert
1900 with those data types.
1901
1902 The optional C<\%options> hash reference may contain additional
1903 options to generate the insert SQL. Currently supported options
1904 are:
1905
1906 =over 4
1907
1908 =item returning
1909
1910 Takes either a scalar of raw SQL fields, or an array reference of
1911 field names, and adds on an SQL C<RETURNING> statement at the end.
1912 This allows you to return data generated by the insert statement
1913 (such as row IDs) without performing another C<SELECT> statement.
1914 Note, however, this is not part of the SQL standard and may not
1915 be supported by all database engines.
1916
1917 =back
1918
1919 =head2 update($table, \%fieldvals, \%where)
1920
1921 This takes a table, hashref of field/value pairs, and an optional
1922 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1923 of bind values.
1924 See the sections on L</"Inserting and Updating Arrays"> and
1925 L</"Inserting and Updating SQL"> for information on how to insert
1926 with those data types.
1927
1928 =head2 select($source, $fields, $where, $order)
1929
1930 This returns a SQL SELECT statement and associated list of bind values, as
1931 specified by the arguments  :
1932
1933 =over
1934
1935 =item $source
1936
1937 Specification of the 'FROM' part of the statement.
1938 The argument can be either a plain scalar (interpreted as a table
1939 name, will be quoted), or an arrayref (interpreted as a list
1940 of table names, joined by commas, quoted), or a scalarref
1941 (literal table name, not quoted), or a ref to an arrayref
1942 (list of literal table names, joined by commas, not quoted).
1943
1944 =item $fields
1945
1946 Specification of the list of fields to retrieve from
1947 the source.
1948 The argument can be either an arrayref (interpreted as a list
1949 of field names, will be joined by commas and quoted), or a
1950 plain scalar (literal SQL, not quoted).
1951 Please observe that this API is not as flexible as for
1952 the first argument C<$table>, for backwards compatibility reasons.
1953
1954 =item $where
1955
1956 Optional argument to specify the WHERE part of the query.
1957 The argument is most often a hashref, but can also be
1958 an arrayref or plain scalar --
1959 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1960
1961 =item $order
1962
1963 Optional argument to specify the ORDER BY part of the query.
1964 The argument can be a scalar, a hashref or an arrayref
1965 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1966 for details.
1967
1968 =back
1969
1970
1971 =head2 delete($table, \%where)
1972
1973 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1974 It returns an SQL DELETE statement and list of bind values.
1975
1976 =head2 where(\%where, \@order)
1977
1978 This is used to generate just the WHERE clause. For example,
1979 if you have an arbitrary data structure and know what the
1980 rest of your SQL is going to look like, but want an easy way
1981 to produce a WHERE clause, use this. It returns an SQL WHERE
1982 clause and list of bind values.
1983
1984
1985 =head2 values(\%data)
1986
1987 This just returns the values from the hash C<%data>, in the same
1988 order that would be returned from any of the other above queries.
1989 Using this allows you to markedly speed up your queries if you
1990 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1991
1992 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1993
1994 Warning: This is an experimental method and subject to change.
1995
1996 This returns arbitrarily generated SQL. It's a really basic shortcut.
1997 It will return two different things, depending on return context:
1998
1999     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
2000     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
2001
2002 These would return the following:
2003
2004     # First calling form
2005     $stmt = "CREATE TABLE test (?, ?)";
2006     @bind = (field1, field2);
2007
2008     # Second calling form
2009     $stmt_and_val = "CREATE TABLE test (field1, field2)";
2010
2011 Depending on what you're trying to do, it's up to you to choose the correct
2012 format. In this example, the second form is what you would want.
2013
2014 By the same token:
2015
2016     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
2017
2018 Might give you:
2019
2020     ALTER SESSION SET nls_date_format = 'MM/YY'
2021
2022 You get the idea. Strings get their case twiddled, but everything
2023 else remains verbatim.
2024
2025 =head1 WHERE CLAUSES
2026
2027 =head2 Introduction
2028
2029 This module uses a variation on the idea from L<DBIx::Abstract>. It
2030 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
2031 module is that things in arrays are OR'ed, and things in hashes
2032 are AND'ed.>
2033
2034 The easiest way to explain is to show lots of examples. After
2035 each C<%where> hash shown, it is assumed you used:
2036
2037     my($stmt, @bind) = $sql->where(\%where);
2038
2039 However, note that the C<%where> hash can be used directly in any
2040 of the other functions as well, as described above.
2041
2042 =head2 Key-value pairs
2043
2044 So, let's get started. To begin, a simple hash:
2045
2046     my %where  = (
2047         user   => 'nwiger',
2048         status => 'completed'
2049     );
2050
2051 Is converted to SQL C<key = val> statements:
2052
2053     $stmt = "WHERE user = ? AND status = ?";
2054     @bind = ('nwiger', 'completed');
2055
2056 One common thing I end up doing is having a list of values that
2057 a field can be in. To do this, simply specify a list inside of
2058 an arrayref:
2059
2060     my %where  = (
2061         user   => 'nwiger',
2062         status => ['assigned', 'in-progress', 'pending'];
2063     );
2064
2065 This simple code will create the following:
2066
2067     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
2068     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
2069
2070 A field associated to an empty arrayref will be considered a
2071 logical false and will generate 0=1.
2072
2073 =head2 Tests for NULL values
2074
2075 If the value part is C<undef> then this is converted to SQL <IS NULL>
2076
2077     my %where  = (
2078         user   => 'nwiger',
2079         status => undef,
2080     );
2081
2082 becomes:
2083
2084     $stmt = "WHERE user = ? AND status IS NULL";
2085     @bind = ('nwiger');
2086
2087 To test if a column IS NOT NULL:
2088
2089     my %where  = (
2090         user   => 'nwiger',
2091         status => { '!=', undef },
2092     );
2093
2094 =head2 Specific comparison operators
2095
2096 If you want to specify a different type of operator for your comparison,
2097 you can use a hashref for a given column:
2098
2099     my %where  = (
2100         user   => 'nwiger',
2101         status => { '!=', 'completed' }
2102     );
2103
2104 Which would generate:
2105
2106     $stmt = "WHERE user = ? AND status != ?";
2107     @bind = ('nwiger', 'completed');
2108
2109 To test against multiple values, just enclose the values in an arrayref:
2110
2111     status => { '=', ['assigned', 'in-progress', 'pending'] };
2112
2113 Which would give you:
2114
2115     "WHERE status = ? OR status = ? OR status = ?"
2116
2117
2118 The hashref can also contain multiple pairs, in which case it is expanded
2119 into an C<AND> of its elements:
2120
2121     my %where  = (
2122         user   => 'nwiger',
2123         status => { '!=', 'completed', -not_like => 'pending%' }
2124     );
2125
2126     # Or more dynamically, like from a form
2127     $where{user} = 'nwiger';
2128     $where{status}{'!='} = 'completed';
2129     $where{status}{'-not_like'} = 'pending%';
2130
2131     # Both generate this
2132     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
2133     @bind = ('nwiger', 'completed', 'pending%');
2134
2135
2136 To get an OR instead, you can combine it with the arrayref idea:
2137
2138     my %where => (
2139          user => 'nwiger',
2140          priority => [ { '=', 2 }, { '>', 5 } ]
2141     );
2142
2143 Which would generate:
2144
2145     $stmt = "WHERE ( priority = ? OR priority > ? ) AND user = ?";
2146     @bind = ('2', '5', 'nwiger');
2147
2148 If you want to include literal SQL (with or without bind values), just use a
2149 scalar reference or array reference as the value:
2150
2151     my %where  = (
2152         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
2153         date_expires => { '<' => \"now()" }
2154     );
2155
2156 Which would generate:
2157
2158     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
2159     @bind = ('11/26/2008');
2160
2161
2162 =head2 Logic and nesting operators
2163
2164 In the example above,
2165 there is a subtle trap if you want to say something like
2166 this (notice the C<AND>):
2167
2168     WHERE priority != ? AND priority != ?
2169
2170 Because, in Perl you I<can't> do this:
2171
2172     priority => { '!=', 2, '!=', 1 }
2173
2174 As the second C<!=> key will obliterate the first. The solution
2175 is to use the special C<-modifier> form inside an arrayref:
2176
2177     priority => [ -and => {'!=', 2},
2178                           {'!=', 1} ]
2179
2180
2181 Normally, these would be joined by C<OR>, but the modifier tells it
2182 to use C<AND> instead. (Hint: You can use this in conjunction with the
2183 C<logic> option to C<new()> in order to change the way your queries
2184 work by default.) B<Important:> Note that the C<-modifier> goes
2185 B<INSIDE> the arrayref, as an extra first element. This will
2186 B<NOT> do what you think it might:
2187
2188     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
2189
2190 Here is a quick list of equivalencies, since there is some overlap:
2191
2192     # Same
2193     status => {'!=', 'completed', 'not like', 'pending%' }
2194     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
2195
2196     # Same
2197     status => {'=', ['assigned', 'in-progress']}
2198     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
2199     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
2200
2201
2202
2203 =head2 Special operators : IN, BETWEEN, etc.
2204
2205 You can also use the hashref format to compare a list of fields using the
2206 C<IN> comparison operator, by specifying the list as an arrayref:
2207
2208     my %where  = (
2209         status   => 'completed',
2210         reportid => { -in => [567, 2335, 2] }
2211     );
2212
2213 Which would generate:
2214
2215     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
2216     @bind = ('completed', '567', '2335', '2');
2217
2218 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
2219 the same way.
2220
2221 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
2222 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
2223 'sqltrue' (by default : C<1=1>).
2224
2225 In addition to the array you can supply a chunk of literal sql or
2226 literal sql with bind:
2227
2228     my %where = {
2229       customer => { -in => \[
2230         'SELECT cust_id FROM cust WHERE balance > ?',
2231         2000,
2232       ],
2233       status => { -in => \'SELECT status_codes FROM states' },
2234     };
2235
2236 would generate:
2237
2238     $stmt = "WHERE (
2239           customer IN ( SELECT cust_id FROM cust WHERE balance > ? )
2240       AND status IN ( SELECT status_codes FROM states )
2241     )";
2242     @bind = ('2000');
2243
2244
2245
2246 Another pair of operators is C<-between> and C<-not_between>,
2247 used with an arrayref of two values:
2248
2249     my %where  = (
2250         user   => 'nwiger',
2251         completion_date => {
2252            -not_between => ['2002-10-01', '2003-02-06']
2253         }
2254     );
2255
2256 Would give you:
2257
2258     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
2259
2260 Just like with C<-in> all plausible combinations of literal SQL
2261 are possible:
2262
2263     my %where = {
2264       start0 => { -between => [ 1, 2 ] },
2265       start1 => { -between => \["? AND ?", 1, 2] },
2266       start2 => { -between => \"lower(x) AND upper(y)" },
2267       start3 => { -between => [
2268         \"lower(x)",
2269         \["upper(?)", 'stuff' ],
2270       ] },
2271     };
2272
2273 Would give you:
2274
2275     $stmt = "WHERE (
2276           ( start0 BETWEEN ? AND ?                )
2277       AND ( start1 BETWEEN ? AND ?                )
2278       AND ( start2 BETWEEN lower(x) AND upper(y)  )
2279       AND ( start3 BETWEEN lower(x) AND upper(?)  )
2280     )";
2281     @bind = (1, 2, 1, 2, 'stuff');
2282
2283
2284 These are the two builtin "special operators"; but the
2285 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
2286
2287 =head2 Unary operators: bool
2288
2289 If you wish to test against boolean columns or functions within your
2290 database you can use the C<-bool> and C<-not_bool> operators. For
2291 example to test the column C<is_user> being true and the column
2292 C<is_enabled> being false you would use:-
2293
2294     my %where  = (
2295         -bool       => 'is_user',
2296         -not_bool   => 'is_enabled',
2297     );
2298
2299 Would give you:
2300
2301     WHERE is_user AND NOT is_enabled
2302
2303 If a more complex combination is required, testing more conditions,
2304 then you should use the and/or operators:-
2305
2306     my %where  = (
2307         -and           => [
2308             -bool      => 'one',
2309             -bool      => 'two',
2310             -bool      => 'three',
2311             -not_bool  => 'four',
2312         ],
2313     );
2314
2315 Would give you:
2316
2317     WHERE one AND two AND three AND NOT four
2318
2319
2320 =head2 Nested conditions, -and/-or prefixes
2321
2322 So far, we've seen how multiple conditions are joined with a top-level
2323 C<AND>.  We can change this by putting the different conditions we want in
2324 hashes and then putting those hashes in an array. For example:
2325
2326     my @where = (
2327         {
2328             user   => 'nwiger',
2329             status => { -like => ['pending%', 'dispatched'] },
2330         },
2331         {
2332             user   => 'robot',
2333             status => 'unassigned',
2334         }
2335     );
2336
2337 This data structure would create the following:
2338
2339     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
2340                 OR ( user = ? AND status = ? ) )";
2341     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
2342
2343
2344 Clauses in hashrefs or arrayrefs can be prefixed with an C<-and> or C<-or>
2345 to change the logic inside :
2346
2347     my @where = (
2348          -and => [
2349             user => 'nwiger',
2350             [
2351                 -and => [ workhrs => {'>', 20}, geo => 'ASIA' ],
2352                 -or => { workhrs => {'<', 50}, geo => 'EURO' },
2353             ],
2354         ],
2355     );
2356
2357 That would yield:
2358
2359     WHERE ( user = ? AND (
2360                ( workhrs > ? AND geo = ? )
2361             OR ( workhrs < ? OR geo = ? )
2362           ) )
2363
2364 =head3 Algebraic inconsistency, for historical reasons
2365
2366 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
2367 operator goes C<outside> of the nested structure; whereas when connecting
2368 several constraints on one column, the C<-and> operator goes
2369 C<inside> the arrayref. Here is an example combining both features :
2370
2371    my @where = (
2372      -and => [a => 1, b => 2],
2373      -or  => [c => 3, d => 4],
2374       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
2375    )
2376
2377 yielding
2378
2379   WHERE ( (    ( a = ? AND b = ? )
2380             OR ( c = ? OR d = ? )
2381             OR ( e LIKE ? AND e LIKE ? ) ) )
2382
2383 This difference in syntax is unfortunate but must be preserved for
2384 historical reasons. So be careful : the two examples below would
2385 seem algebraically equivalent, but they are not
2386
2387   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
2388   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
2389
2390   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
2391   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
2392
2393
2394 =head2 Literal SQL and value type operators
2395
2396 The basic premise of SQL::Abstract is that in WHERE specifications the "left
2397 side" is a column name and the "right side" is a value (normally rendered as
2398 a placeholder). This holds true for both hashrefs and arrayref pairs as you
2399 see in the L</WHERE CLAUSES> examples above. Sometimes it is necessary to
2400 alter this behavior. There are several ways of doing so.
2401
2402 =head3 -ident
2403
2404 This is a virtual operator that signals the string to its right side is an
2405 identifier (a column name) and not a value. For example to compare two
2406 columns you would write:
2407
2408     my %where = (
2409         priority => { '<', 2 },
2410         requestor => { -ident => 'submitter' },
2411     );
2412
2413 which creates:
2414
2415     $stmt = "WHERE priority < ? AND requestor = submitter";
2416     @bind = ('2');
2417
2418 If you are maintaining legacy code you may see a different construct as
2419 described in L</Deprecated usage of Literal SQL>, please use C<-ident> in new
2420 code.
2421
2422 =head3 -value
2423
2424 This is a virtual operator that signals that the construct to its right side
2425 is a value to be passed to DBI. This is for example necessary when you want
2426 to write a where clause against an array (for RDBMS that support such
2427 datatypes). For example:
2428
2429     my %where = (
2430         array => { -value => [1, 2, 3] }
2431     );
2432
2433 will result in:
2434
2435     $stmt = 'WHERE array = ?';
2436     @bind = ([1, 2, 3]);
2437
2438 Note that if you were to simply say:
2439
2440     my %where = (
2441         array => [1, 2, 3]
2442     );
2443
2444 the result would porbably be not what you wanted:
2445
2446     $stmt = 'WHERE array = ? OR array = ? OR array = ?';
2447     @bind = (1, 2, 3);
2448
2449 =head3 Literal SQL
2450
2451 Finally, sometimes only literal SQL will do. To include a random snippet
2452 of SQL verbatim, you specify it as a scalar reference. Consider this only
2453 as a last resort. Usually there is a better way. For example:
2454
2455     my %where = (
2456         priority => { '<', 2 },
2457         requestor => { -in => \'(SELECT name FROM hitmen)' },
2458     );
2459
2460 Would create:
2461
2462     $stmt = "WHERE priority < ? AND requestor IN (SELECT name FROM hitmen)"
2463     @bind = (2);
2464
2465 Note that in this example, you only get one bind parameter back, since
2466 the verbatim SQL is passed as part of the statement.
2467
2468 =head4 CAVEAT
2469
2470   Never use untrusted input as a literal SQL argument - this is a massive
2471   security risk (there is no way to check literal snippets for SQL
2472   injections and other nastyness). If you need to deal with untrusted input
2473   use literal SQL with placeholders as described next.
2474
2475 =head3 Literal SQL with placeholders and bind values (subqueries)
2476
2477 If the literal SQL to be inserted has placeholders and bind values,
2478 use a reference to an arrayref (yes this is a double reference --
2479 not so common, but perfectly legal Perl). For example, to find a date
2480 in Postgres you can use something like this:
2481
2482     my %where = (
2483        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
2484     )
2485
2486 This would create:
2487
2488     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
2489     @bind = ('10');
2490
2491 Note that you must pass the bind values in the same format as they are returned
2492 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
2493 provide the bind values in the C<< [ column_meta => value ] >> format, where
2494 C<column_meta> is an opaque scalar value; most commonly the column name, but
2495 you can use any scalar value (including references and blessed references),
2496 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
2497 to C<columns> the above example will look like:
2498
2499     my %where = (
2500        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
2501     )
2502
2503 Literal SQL is especially useful for nesting parenthesized clauses in the
2504 main SQL query. Here is a first example :
2505
2506   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2507                                100, "foo%");
2508   my %where = (
2509     foo => 1234,
2510     bar => \["IN ($sub_stmt)" => @sub_bind],
2511   );
2512
2513 This yields :
2514
2515   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2516                                              WHERE c2 < ? AND c3 LIKE ?))";
2517   @bind = (1234, 100, "foo%");
2518
2519 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2520 are expressed in the same way. Of course the C<$sub_stmt> and
2521 its associated bind values can be generated through a former call
2522 to C<select()> :
2523
2524   my ($sub_stmt, @sub_bind)
2525      = $sql->select("t1", "c1", {c2 => {"<" => 100},
2526                                  c3 => {-like => "foo%"}});
2527   my %where = (
2528     foo => 1234,
2529     bar => \["> ALL ($sub_stmt)" => @sub_bind],
2530   );
2531
2532 In the examples above, the subquery was used as an operator on a column;
2533 but the same principle also applies for a clause within the main C<%where>
2534 hash, like an EXISTS subquery :
2535
2536   my ($sub_stmt, @sub_bind)
2537      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2538   my %where = ( -and => [
2539     foo   => 1234,
2540     \["EXISTS ($sub_stmt)" => @sub_bind],
2541   ]);
2542
2543 which yields
2544
2545   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2546                                         WHERE c1 = ? AND c2 > t0.c0))";
2547   @bind = (1234, 1);
2548
2549
2550 Observe that the condition on C<c2> in the subquery refers to
2551 column C<t0.c0> of the main query : this is I<not> a bind
2552 value, so we have to express it through a scalar ref.
2553 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2554 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2555 what we wanted here.
2556
2557 Finally, here is an example where a subquery is used
2558 for expressing unary negation:
2559
2560   my ($sub_stmt, @sub_bind)
2561      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2562   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2563   my %where = (
2564         lname  => {like => '%son%'},
2565         \["NOT ($sub_stmt)" => @sub_bind],
2566     );
2567
2568 This yields
2569
2570   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2571   @bind = ('%son%', 10, 20)
2572
2573 =head3 Deprecated usage of Literal SQL
2574
2575 Below are some examples of archaic use of literal SQL. It is shown only as
2576 reference for those who deal with legacy code. Each example has a much
2577 better, cleaner and safer alternative that users should opt for in new code.
2578
2579 =over
2580
2581 =item *
2582
2583     my %where = ( requestor => \'IS NOT NULL' )
2584
2585     $stmt = "WHERE requestor IS NOT NULL"
2586
2587 This used to be the way of generating NULL comparisons, before the handling
2588 of C<undef> got formalized. For new code please use the superior syntax as
2589 described in L</Tests for NULL values>.
2590
2591 =item *
2592
2593     my %where = ( requestor => \'= submitter' )
2594
2595     $stmt = "WHERE requestor = submitter"
2596
2597 This used to be the only way to compare columns. Use the superior L</-ident>
2598 method for all new code. For example an identifier declared in such a way
2599 will be properly quoted if L</quote_char> is properly set, while the legacy
2600 form will remain as supplied.
2601
2602 =item *
2603
2604     my %where = ( is_ready  => \"", completed => { '>', '2012-12-21' } )
2605
2606     $stmt = "WHERE completed > ? AND is_ready"
2607     @bind = ('2012-12-21')
2608
2609 Using an empty string literal used to be the only way to express a boolean.
2610 For all new code please use the much more readable
2611 L<-bool|/Unary operators: bool> operator.
2612
2613 =back
2614
2615 =head2 Conclusion
2616
2617 These pages could go on for a while, since the nesting of the data
2618 structures this module can handle are pretty much unlimited (the
2619 module implements the C<WHERE> expansion as a recursive function
2620 internally). Your best bet is to "play around" with the module a
2621 little to see how the data structures behave, and choose the best
2622 format for your data based on that.
2623
2624 And of course, all the values above will probably be replaced with
2625 variables gotten from forms or the command line. After all, if you
2626 knew everything ahead of time, you wouldn't have to worry about
2627 dynamically-generating SQL and could just hardwire it into your
2628 script.
2629
2630 =head1 ORDER BY CLAUSES
2631
2632 Some functions take an order by clause. This can either be a scalar (just a
2633 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2634 optionally with C<< -nulls => 'first' >> or C<< -nulls => 'last' >>,
2635 or an array of either of the two previous forms. Examples:
2636
2637                Given            |         Will Generate
2638     ----------------------------------------------------------
2639                                 |
2640     \'colA DESC'                | ORDER BY colA DESC
2641                                 |
2642     'colA'                      | ORDER BY colA
2643                                 |
2644     [qw/colA colB/]             | ORDER BY colA, colB
2645                                 |
2646     {-asc  => 'colA'}           | ORDER BY colA ASC
2647                                 |
2648     {-desc => 'colB'}           | ORDER BY colB DESC
2649                                 |
2650     {                           |
2651       -asc => 'colA',           | ORDER BY colA ASC NULLS LAST
2652       -nulls => 'last',         |
2653     }                           |
2654                                 |
2655     ['colA', {-asc => 'colB'}]  | ORDER BY colA, colB ASC
2656                                 |
2657     { -asc => [qw/colA colB/] } | ORDER BY colA ASC, colB ASC
2658                                 |
2659     {                           |
2660       -asc => [qw/colA colB/]   | ORDER BY colA ASC NULLS FIRST,
2661       -nulls => 'first'         |          colB ASC NULLS FIRST
2662     }                           |
2663                                 |
2664     [                           |
2665       { -asc => 'colA' },       | ORDER BY colA ASC, colB DESC,
2666       { -desc => [qw/colB/],    |          colC ASC, colD ASC
2667       { -asc => [qw/colC colD/],|
2668     ]                           |
2669     ===========================================================
2670
2671
2672
2673 =head1 SPECIAL OPERATORS
2674
2675   my $sqlmaker = SQL::Abstract->new(special_ops => [
2676      {
2677       regex => qr/.../,
2678       handler => sub {
2679         my ($self, $field, $op, $arg) = @_;
2680         ...
2681       },
2682      },
2683      {
2684       regex => qr/.../,
2685       handler => 'method_name',
2686      },
2687    ]);
2688
2689 A "special operator" is a SQL syntactic clause that can be
2690 applied to a field, instead of a usual binary operator.
2691 For example :
2692
2693    WHERE field IN (?, ?, ?)
2694    WHERE field BETWEEN ? AND ?
2695    WHERE MATCH(field) AGAINST (?, ?)
2696
2697 Special operators IN and BETWEEN are fairly standard and therefore
2698 are builtin within C<SQL::Abstract> (as the overridable methods
2699 C<_where_field_IN> and C<_where_field_BETWEEN>). For other operators,
2700 like the MATCH .. AGAINST example above which is specific to MySQL,
2701 you can write your own operator handlers - supply a C<special_ops>
2702 argument to the C<new> method. That argument takes an arrayref of
2703 operator definitions; each operator definition is a hashref with two
2704 entries:
2705
2706 =over
2707
2708 =item regex
2709
2710 the regular expression to match the operator
2711
2712 =item handler
2713
2714 Either a coderef or a plain scalar method name. In both cases
2715 the expected return is C<< ($sql, @bind) >>.
2716
2717 When supplied with a method name, it is simply called on the
2718 L<SQL::Abstract/> object as:
2719
2720  $self->$method_name ($field, $op, $arg)
2721
2722  Where:
2723
2724   $op is the part that matched the handler regex
2725   $field is the LHS of the operator
2726   $arg is the RHS
2727
2728 When supplied with a coderef, it is called as:
2729
2730  $coderef->($self, $field, $op, $arg)
2731
2732
2733 =back
2734
2735 For example, here is an implementation
2736 of the MATCH .. AGAINST syntax for MySQL
2737
2738   my $sqlmaker = SQL::Abstract->new(special_ops => [
2739
2740     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2741     {regex => qr/^match$/i,
2742      handler => sub {
2743        my ($self, $field, $op, $arg) = @_;
2744        $arg = [$arg] if not ref $arg;
2745        my $label         = $self->_quote($field);
2746        my ($placeholder) = $self->_convert('?');
2747        my $placeholders  = join ", ", (($placeholder) x @$arg);
2748        my $sql           = $self->_sqlcase('match') . " ($label) "
2749                          . $self->_sqlcase('against') . " ($placeholders) ";
2750        my @bind = $self->_bindtype($field, @$arg);
2751        return ($sql, @bind);
2752        }
2753      },
2754
2755   ]);
2756
2757
2758 =head1 UNARY OPERATORS
2759
2760   my $sqlmaker = SQL::Abstract->new(unary_ops => [
2761      {
2762       regex => qr/.../,
2763       handler => sub {
2764         my ($self, $op, $arg) = @_;
2765         ...
2766       },
2767      },
2768      {
2769       regex => qr/.../,
2770       handler => 'method_name',
2771      },
2772    ]);
2773
2774 A "unary operator" is a SQL syntactic clause that can be
2775 applied to a field - the operator goes before the field
2776
2777 You can write your own operator handlers - supply a C<unary_ops>
2778 argument to the C<new> method. That argument takes an arrayref of
2779 operator definitions; each operator definition is a hashref with two
2780 entries:
2781
2782 =over
2783
2784 =item regex
2785
2786 the regular expression to match the operator
2787
2788 =item handler
2789
2790 Either a coderef or a plain scalar method name. In both cases
2791 the expected return is C<< $sql >>.
2792
2793 When supplied with a method name, it is simply called on the
2794 L<SQL::Abstract/> object as:
2795
2796  $self->$method_name ($op, $arg)
2797
2798  Where:
2799
2800   $op is the part that matched the handler regex
2801   $arg is the RHS or argument of the operator
2802
2803 When supplied with a coderef, it is called as:
2804
2805  $coderef->($self, $op, $arg)
2806
2807
2808 =back
2809
2810
2811 =head1 PERFORMANCE
2812
2813 Thanks to some benchmarking by Mark Stosberg, it turns out that
2814 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2815 I must admit this wasn't an intentional design issue, but it's a
2816 byproduct of the fact that you get to control your C<DBI> handles
2817 yourself.
2818
2819 To maximize performance, use a code snippet like the following:
2820
2821     # prepare a statement handle using the first row
2822     # and then reuse it for the rest of the rows
2823     my($sth, $stmt);
2824     for my $href (@array_of_hashrefs) {
2825         $stmt ||= $sql->insert('table', $href);
2826         $sth  ||= $dbh->prepare($stmt);
2827         $sth->execute($sql->values($href));
2828     }
2829
2830 The reason this works is because the keys in your C<$href> are sorted
2831 internally by B<SQL::Abstract>. Thus, as long as your data retains
2832 the same structure, you only have to generate the SQL the first time
2833 around. On subsequent queries, simply use the C<values> function provided
2834 by this module to return your values in the correct order.
2835
2836 However this depends on the values having the same type - if, for
2837 example, the values of a where clause may either have values
2838 (resulting in sql of the form C<column = ?> with a single bind
2839 value), or alternatively the values might be C<undef> (resulting in
2840 sql of the form C<column IS NULL> with no bind value) then the
2841 caching technique suggested will not work.
2842
2843 =head1 FORMBUILDER
2844
2845 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2846 really like this part (I do, at least). Building up a complex query
2847 can be as simple as the following:
2848
2849     #!/usr/bin/perl
2850
2851     use CGI::FormBuilder;
2852     use SQL::Abstract;
2853
2854     my $form = CGI::FormBuilder->new(...);
2855     my $sql  = SQL::Abstract->new;
2856
2857     if ($form->submitted) {
2858         my $field = $form->field;
2859         my $id = delete $field->{id};
2860         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2861     }
2862
2863 Of course, you would still have to connect using C<DBI> to run the
2864 query, but the point is that if you make your form look like your
2865 table, the actual query script can be extremely simplistic.
2866
2867 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2868 a fast interface to returning and formatting data. I frequently
2869 use these three modules together to write complex database query
2870 apps in under 50 lines.
2871
2872 =head1 REPO
2873
2874 =over
2875
2876 =item * gitweb: L<http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/SQL-Abstract.git>
2877
2878 =item * git: L<git://git.shadowcat.co.uk/dbsrgits/SQL-Abstract.git>
2879
2880 =back
2881
2882 =head1 CHANGES
2883
2884 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2885 Great care has been taken to preserve the I<published> behavior
2886 documented in previous versions in the 1.* family; however,
2887 some features that were previously undocumented, or behaved
2888 differently from the documentation, had to be changed in order
2889 to clarify the semantics. Hence, client code that was relying
2890 on some dark areas of C<SQL::Abstract> v1.*
2891 B<might behave differently> in v1.50.
2892
2893 The main changes are :
2894
2895 =over
2896
2897 =item *
2898
2899 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2900
2901 =item *
2902
2903 support for the { operator => \"..." } construct (to embed literal SQL)
2904
2905 =item *
2906
2907 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2908
2909 =item *
2910
2911 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2912
2913 =item *
2914
2915 defensive programming : check arguments
2916
2917 =item *
2918
2919 fixed bug with global logic, which was previously implemented
2920 through global variables yielding side-effects. Prior versions would
2921 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2922 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2923 Now this is interpreted
2924 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2925
2926
2927 =item *
2928
2929 fixed semantics of  _bindtype on array args
2930
2931 =item *
2932
2933 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2934 we just avoid shifting arrays within that tree.
2935
2936 =item *
2937
2938 dropped the C<_modlogic> function
2939
2940 =back
2941
2942 =head1 ACKNOWLEDGEMENTS
2943
2944 There are a number of individuals that have really helped out with
2945 this module. Unfortunately, most of them submitted bugs via CPAN
2946 so I have no idea who they are! But the people I do know are:
2947
2948     Ash Berlin (order_by hash term support)
2949     Matt Trout (DBIx::Class support)
2950     Mark Stosberg (benchmarking)
2951     Chas Owens (initial "IN" operator support)
2952     Philip Collins (per-field SQL functions)
2953     Eric Kolve (hashref "AND" support)
2954     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2955     Dan Kubb (support for "quote_char" and "name_sep")
2956     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2957     Laurent Dami (internal refactoring, extensible list of special operators, literal SQL)
2958     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2959     Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2960     Oliver Charles (support for "RETURNING" after "INSERT")
2961
2962 Thanks!
2963
2964 =head1 SEE ALSO
2965
2966 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2967
2968 =head1 AUTHOR
2969
2970 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2971
2972 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2973
2974 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2975 While not an official support venue, C<DBIx::Class> makes heavy use of
2976 C<SQL::Abstract>, and as such list members there are very familiar with
2977 how to create queries.
2978
2979 =head1 LICENSE
2980
2981 This module is free software; you may copy this under the same
2982 terms as perl itself (either the GNU General Public License or
2983 the Artistic License)
2984
2985 =cut
2986