lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use strict;
   9 use warnings;
  10 use Carp ();
  11 use List::Util ();
  12 use Scalar::Util ();
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.73_01';
  19
  20 # This would confuse some packagers
  21 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^ (?: not \s )? between $/ix, handler => '_where_field_BETWEEN'},
  29   {regex => qr/^ (?: not \s )? in      $/ix, handler => '_where_field_IN'},
  30   {regex => qr/^ ident                 $/ix, handler => '_where_op_IDENT'},
  31   {regex => qr/^ value                 $/ix, handler => '_where_op_VALUE'},
  32 );
  33
  34 # unaryish operators - key maps to handler
  35 my @BUILTIN_UNARY_OPS = (
  36   # the digits are backcompat stuff
  37   { regex => qr/^ and  (?: [_\s]? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  38   { regex => qr/^ or   (?: [_\s]? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  39   { regex => qr/^ nest (?: [_\s]? \d+ )? $/xi, handler => '_where_op_NEST' },
  40   { regex => qr/^ (?: not \s )? bool     $/xi, handler => '_where_op_BOOL' },
  41   { regex => qr/^ ident                  $/xi, handler => '_where_op_IDENT' },
  42   { regex => qr/^ value                  $/ix, handler => '_where_op_VALUE' },
  43 );
  44
  45 #======================================================================
  46 # DEBUGGING AND ERROR REPORTING
  47 #======================================================================
  48
  49 sub _debug {
  50   return unless $_[0]->{debug}; shift; # a little faster
  51   my $func = (caller(1))[3];
  52   warn "[$func] ", @_, "\n";
  53 }
  54
  55 sub belch (@) {
  56   my($func) = (caller(1))[3];
  57   Carp::carp "[$func] Warning: ", @_;
  58 }
  59
  60 sub puke (@) {
  61   my($func) = (caller(1))[3];
  62   Carp::croak "[$func] Fatal: ", @_;
  63 }
  64
  65
  66 #======================================================================
  67 # NEW
  68 #======================================================================
  69
  70 sub new {
  71   my $self = shift;
  72   my $class = ref($self) || $self;
  73   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  74
  75   # choose our case by keeping an option around
  76   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  77
  78   # default logic for interpreting arrayrefs
  79   $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
  80
  81   # how to return bind vars
  82   # LDNOTE: changed nwiger code : why this 'delete' ??
  83   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  84   $opt{bindtype} ||= 'normal';
  85
  86   # default comparison is "=", but can be overridden
  87   $opt{cmp} ||= '=';
  88
  89   # try to recognize which are the 'equality' and 'unequality' ops
  90   # (temporary quickfix, should go through a more seasoned API)
  91   $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  92   $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  93
  94   # SQL booleans
  95   $opt{sqltrue}  ||= '1=1';
  96   $opt{sqlfalse} ||= '0=1';
  97
  98   # special operators
  99   $opt{special_ops} ||= [];
 100   # regexes are applied in order, thus push after user-defines
 101   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
 102
 103   # unary operators
 104   $opt{unary_ops} ||= [];
 105   push @{$opt{unary_ops}}, @BUILTIN_UNARY_OPS;
 106
 107   # rudimentary saniy-check for user supplied bits treated as functions/operators
 108   # If a purported  function matches this regular expression, an exception is thrown.
 109   # Literal SQL is *NOT* subject to this check, only functions (and column names
 110   # when quoting is not in effect)
 111
 112   # FIXME
 113   # need to guard against ()'s in column names too, but this will break tons of
 114   # hacks... ideas anyone?
 115   $opt{injection_guard} ||= qr/
 116     \;
 117       |
 118     ^ \s* go \s
 119   /xmi;
 120
 121   return bless \%opt, $class;
 122 }
 123
 124
 125 sub _assert_pass_injection_guard {
 126   if ($_[1] =~ $_[0]->{injection_guard}) {
 127     my $class = ref $_[0];
 128     puke "Possible SQL injection attempt '$_[1]'. If this is indeed a part of the "
 129      . "desired SQL use literal SQL ( \'...' or \[ '...' ] ) or supply your own "
 130      . "{injection_guard} attribute to ${class}->new()"
 131   }
 132 }
 133
 134
 135 #======================================================================
 136 # INSERT methods
 137 #======================================================================
 138
 139 sub insert {
 140   my $self    = shift;
 141   my $table   = $self->_table(shift);
 142   my $data    = shift || return;
 143   my $options = shift;
 144
 145   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 146   my ($sql, @bind) = $self->$method($data);
 147   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 148
 149   if ($options->{returning}) {
 150     my ($s, @b) = $self->_insert_returning ($options);
 151     $sql .= $s;
 152     push @bind, @b;
 153   }
 154
 155   return wantarray ? ($sql, @bind) : $sql;
 156 }
 157
 158 sub _insert_returning {
 159   my ($self, $options) = @_;
 160
 161   my $f = $options->{returning};
 162
 163   my $fieldlist = $self->_SWITCH_refkind($f, {
 164     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$f;},
 165     SCALAR       => sub {$self->_quote($f)},
 166     SCALARREF    => sub {$$f},
 167   });
 168   return $self->_sqlcase(' returning ') . $fieldlist;
 169 }
 170
 171 sub _insert_HASHREF { # explicit list of fields and then values
 172   my ($self, $data) = @_;
 173
 174   my @fields = sort keys %$data;
 175
 176   my ($sql, @bind) = $self->_insert_values($data);
 177
 178   # assemble SQL
 179   $_ = $self->_quote($_) foreach @fields;
 180   $sql = "( ".join(", ", @fields).") ".$sql;
 181
 182   return ($sql, @bind);
 183 }
 184
 185 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 186   my ($self, $data) = @_;
 187
 188   # no names (arrayref) so can't generate bindtype
 189   $self->{bindtype} ne 'columns'
 190     or belch "can't do 'columns' bindtype when called with arrayref";
 191
 192   # fold the list of values into a hash of column name - value pairs
 193   # (where the column names are artificially generated, and their
 194   # lexicographical ordering keep the ordering of the original list)
 195   my $i = "a";  # incremented values will be in lexicographical order
 196   my $data_in_hash = { map { ($i++ => $_) } @$data };
 197
 198   return $self->_insert_values($data_in_hash);
 199 }
 200
 201 sub _insert_ARRAYREFREF { # literal SQL with bind
 202   my ($self, $data) = @_;
 203
 204   my ($sql, @bind) = @${$data};
 205   $self->_assert_bindval_matches_bindtype(@bind);
 206
 207   return ($sql, @bind);
 208 }
 209
 210
 211 sub _insert_SCALARREF { # literal SQL without bind
 212   my ($self, $data) = @_;
 213
 214   return ($$data);
 215 }
 216
 217 sub _insert_values {
 218   my ($self, $data) = @_;
 219
 220   my (@values, @all_bind);
 221   foreach my $column (sort keys %$data) {
 222     my $v = $data->{$column};
 223
 224     $self->_SWITCH_refkind($v, {
 225
 226       ARRAYREF => sub {
 227         if ($self->{array_datatypes}) { # if array datatype are activated
 228           push @values, '?';
 229           push @all_bind, $self->_bindtype($column, $v);
 230         }
 231         else {                          # else literal SQL with bind
 232           my ($sql, @bind) = @$v;
 233           $self->_assert_bindval_matches_bindtype(@bind);
 234           push @values, $sql;
 235           push @all_bind, @bind;
 236         }
 237       },
 238
 239       ARRAYREFREF => sub { # literal SQL with bind
 240         my ($sql, @bind) = @${$v};
 241         $self->_assert_bindval_matches_bindtype(@bind);
 242         push @values, $sql;
 243         push @all_bind, @bind;
 244       },
 245
 246       # THINK : anything useful to do with a HASHREF ?
 247       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 248         #TODO in SQLA >= 2.0 it will die instead
 249         belch "HASH ref as bind value in insert is not supported";
 250         push @values, '?';
 251         push @all_bind, $self->_bindtype($column, $v);
 252       },
 253
 254       SCALARREF => sub {  # literal SQL without bind
 255         push @values, $$v;
 256       },
 257
 258       SCALAR_or_UNDEF => sub {
 259         push @values, '?';
 260         push @all_bind, $self->_bindtype($column, $v);
 261       },
 262
 263      });
 264
 265   }
 266
 267   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 268   return ($sql, @all_bind);
 269 }
 270
 271
 272
 273 #======================================================================
 274 # UPDATE methods
 275 #======================================================================
 276
 277
 278 sub update {
 279   my $self  = shift;
 280   my $table = $self->_table(shift);
 281   my $data  = shift || return;
 282   my $where = shift;
 283
 284   # first build the 'SET' part of the sql statement
 285   my (@set, @all_bind);
 286   puke "Unsupported data type specified to \$sql->update"
 287     unless ref $data eq 'HASH';
 288
 289   for my $k (sort keys %$data) {
 290     my $v = $data->{$k};
 291     my $r = ref $v;
 292     my $label = $self->_quote($k);
 293
 294     $self->_SWITCH_refkind($v, {
 295       ARRAYREF => sub {
 296         if ($self->{array_datatypes}) { # array datatype
 297           push @set, "$label = ?";
 298           push @all_bind, $self->_bindtype($k, $v);
 299         }
 300         else {                          # literal SQL with bind
 301           my ($sql, @bind) = @$v;
 302           $self->_assert_bindval_matches_bindtype(@bind);
 303           push @set, "$label = $sql";
 304           push @all_bind, @bind;
 305         }
 306       },
 307       ARRAYREFREF => sub { # literal SQL with bind
 308         my ($sql, @bind) = @${$v};
 309         $self->_assert_bindval_matches_bindtype(@bind);
 310         push @set, "$label = $sql";
 311         push @all_bind, @bind;
 312       },
 313       SCALARREF => sub {  # literal SQL without bind
 314         push @set, "$label = $$v";
 315       },
 316       HASHREF => sub {
 317         my ($op, $arg, @rest) = %$v;
 318
 319         puke 'Operator calls in update must be in the form { -op => $arg }'
 320           if (@rest or not $op =~ /^\-(.+)/);
 321
 322         local $self->{_nested_func_lhs} = $k;
 323         my ($sql, @bind) = $self->_where_unary_op ($1, $arg);
 324
 325         push @set, "$label = $sql";
 326         push @all_bind, @bind;
 327       },
 328       SCALAR_or_UNDEF => sub {
 329         push @set, "$label = ?";
 330         push @all_bind, $self->_bindtype($k, $v);
 331       },
 332     });
 333   }
 334
 335   # generate sql
 336   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 337           . join ', ', @set;
 338
 339   if ($where) {
 340     my($where_sql, @where_bind) = $self->where($where);
 341     $sql .= $where_sql;
 342     push @all_bind, @where_bind;
 343   }
 344
 345   return wantarray ? ($sql, @all_bind) : $sql;
 346 }
 347
 348
 349
 350
 351 #======================================================================
 352 # SELECT
 353 #======================================================================
 354
 355
 356 sub select {
 357   my $self   = shift;
 358   my $table  = $self->_table(shift);
 359   my $fields = shift || '*';
 360   my $where  = shift;
 361   my $order  = shift;
 362
 363   my($where_sql, @bind) = $self->where($where, $order);
 364
 365   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 366                                    : $fields;
 367   my $sql = join(' ', $self->_sqlcase('select'), $f,
 368                       $self->_sqlcase('from'),   $table)
 369           . $where_sql;
 370
 371   return wantarray ? ($sql, @bind) : $sql;
 372 }
 373
 374 #======================================================================
 375 # DELETE
 376 #======================================================================
 377
 378
 379 sub delete {
 380   my $self  = shift;
 381   my $table = $self->_table(shift);
 382   my $where = shift;
 383
 384
 385   my($where_sql, @bind) = $self->where($where);
 386   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 387
 388   return wantarray ? ($sql, @bind) : $sql;
 389 }
 390
 391
 392 #======================================================================
 393 # WHERE: entry point
 394 #======================================================================
 395
 396
 397
 398 # Finally, a separate routine just to handle WHERE clauses
 399 sub where {
 400   my ($self, $where, $order) = @_;
 401
 402   # where ?
 403   my ($sql, @bind) = $self->_recurse_where($where);
 404   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 405
 406   # order by?
 407   if ($order) {
 408     $sql .= $self->_order_by($order);
 409   }
 410
 411   return wantarray ? ($sql, @bind) : $sql;
 412 }
 413
 414
 415 sub _recurse_where {
 416   my ($self, $where, $logic) = @_;
 417
 418   # dispatch on appropriate method according to refkind of $where
 419   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 420
 421   my ($sql, @bind) =  $self->$method($where, $logic);
 422
 423   # DBIx::Class directly calls _recurse_where in scalar context, so
 424   # we must implement it, even if not in the official API
 425   return wantarray ? ($sql, @bind) : $sql;
 426 }
 427
 428
 429
 430 #======================================================================
 431 # WHERE: top-level ARRAYREF
 432 #======================================================================
 433
 434
 435 sub _where_ARRAYREF {
 436   my ($self, $where, $logic) = @_;
 437
 438   $logic = uc($logic || $self->{logic});
 439   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 440
 441   my @clauses = @$where;
 442
 443   my (@sql_clauses, @all_bind);
 444   # need to use while() so can shift() for pairs
 445   while (my $el = shift @clauses) {
 446
 447     # switch according to kind of $el and get corresponding ($sql, @bind)
 448     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 449
 450       # skip empty elements, otherwise get invalid trailing AND stuff
 451       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 452
 453       ARRAYREFREF => sub {
 454         my ($s, @b) = @$$el;
 455         $self->_assert_bindval_matches_bindtype(@b);
 456         ($s, @b);
 457       },
 458
 459       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 460            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 461            # side-effect: the first hashref within an array would change
 462            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 463            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 464            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 465
 466       SCALARREF => sub { ($$el);                                 },
 467
 468       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 469                         $self->_recurse_where({$el => shift(@clauses)})},
 470
 471       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 472     });
 473
 474     if ($sql) {
 475       push @sql_clauses, $sql;
 476       push @all_bind, @bind;
 477     }
 478   }
 479
 480   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 481 }
 482
 483 #======================================================================
 484 # WHERE: top-level ARRAYREFREF
 485 #======================================================================
 486
 487 sub _where_ARRAYREFREF {
 488     my ($self, $where) = @_;
 489     my ($sql, @bind) = @$$where;
 490     $self->_assert_bindval_matches_bindtype(@bind);
 491     return ($sql, @bind);
 492 }
 493
 494 #======================================================================
 495 # WHERE: top-level HASHREF
 496 #======================================================================
 497
 498 sub _where_HASHREF {
 499   my ($self, $where) = @_;
 500   my (@sql_clauses, @all_bind);
 501
 502   for my $k (sort keys %$where) {
 503     my $v = $where->{$k};
 504
 505     # ($k => $v) is either a special unary op or a regular hashpair
 506     my ($sql, @bind) = do {
 507       if ($k =~ /^-./) {
 508         # put the operator in canonical form
 509         my $op = $k;
 510         $op = substr $op, 1;  # remove initial dash
 511         $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 512         $op =~ s/\s+/ /g;     # compress whitespace
 513
 514         # so that -not_foo works correctly
 515         $op =~ s/^not_/NOT /i;
 516
 517         $self->_debug("Unary OP(-$op) within hashref, recursing...");
 518         my ($s, @b) = $self->_where_unary_op ($op, $v);
 519
 520         # top level vs nested
 521         # we assume that handled unary ops will take care of their ()s
 522         $s = "($s)" unless (
 523           List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}}
 524             or
 525           defined($self->{_nested_func_lhs}) && ($self->{_nested_func_lhs} eq $k)
 526         );
 527         ($s, @b);
 528       }
 529       else {
 530         my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 531         $self->$method($k, $v);
 532       }
 533     };
 534
 535     push @sql_clauses, $sql;
 536     push @all_bind, @bind;
 537   }
 538
 539   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 540 }
 541
 542 sub _where_unary_op {
 543   my ($self, $op, $rhs) = @_;
 544
 545   if (my $op_entry = List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}}) {
 546     my $handler = $op_entry->{handler};
 547
 548     if (not ref $handler) {
 549       if ($op =~ s/ [_\s]? \d+ $//x ) {
 550         belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
 551             . "You probably wanted ...-and => [ -$op => COND1, -$op => COND2 ... ]";
 552       }
 553       return $self->$handler ($op, $rhs);
 554     }
 555     elsif (ref $handler eq 'CODE') {
 556       return $handler->($self, $op, $rhs);
 557     }
 558     else {
 559       puke "Illegal handler for operator $op - expecting a method name or a coderef";
 560     }
 561   }
 562
 563   $self->_debug("Generic unary OP: $op - recursing as function");
 564
 565   $self->_assert_pass_injection_guard($op);
 566
 567   my ($sql, @bind) = $self->_SWITCH_refkind ($rhs, {
 568     SCALAR =>   sub {
 569       puke "Illegal use of top-level '$op'"
 570         unless $self->{_nested_func_lhs};
 571
 572       return (
 573         $self->_convert('?'),
 574         $self->_bindtype($self->{_nested_func_lhs}, $rhs)
 575       );
 576     },
 577     FALLBACK => sub {
 578       $self->_recurse_where ($rhs)
 579     },
 580   });
 581
 582   $sql = sprintf ('%s %s',
 583     $self->_sqlcase($op),
 584     $sql,
 585   );
 586
 587   return ($sql, @bind);
 588 }
 589
 590 sub _where_op_ANDOR {
 591   my ($self, $op, $v) = @_;
 592
 593   $self->_SWITCH_refkind($v, {
 594     ARRAYREF => sub {
 595       return $self->_where_ARRAYREF($v, $op);
 596     },
 597
 598     HASHREF => sub {
 599       return ( $op =~ /^or/i )
 600         ? $self->_where_ARRAYREF( [ map { $_ => $v->{$_} } ( sort keys %$v ) ], $op )
 601         : $self->_where_HASHREF($v);
 602     },
 603
 604     SCALARREF  => sub {
 605       puke "-$op => \\\$scalar makes little sense, use " .
 606         ($op =~ /^or/i
 607           ? '[ \$scalar, \%rest_of_conditions ] instead'
 608           : '-and => [ \$scalar, \%rest_of_conditions ] instead'
 609         );
 610     },
 611
 612     ARRAYREFREF => sub {
 613       puke "-$op => \\[...] makes little sense, use " .
 614         ($op =~ /^or/i
 615           ? '[ \[...], \%rest_of_conditions ] instead'
 616           : '-and => [ \[...], \%rest_of_conditions ] instead'
 617         );
 618     },
 619
 620     SCALAR => sub { # permissively interpreted as SQL
 621       puke "-$op => \$value makes little sense, use -bool => \$value instead";
 622     },
 623
 624     UNDEF => sub {
 625       puke "-$op => undef not supported";
 626     },
 627    });
 628 }
 629
 630 sub _where_op_NEST {
 631   my ($self, $op, $v) = @_;
 632
 633   $self->_SWITCH_refkind($v, {
 634
 635     SCALAR => sub { # permissively interpreted as SQL
 636       belch "literal SQL should be -nest => \\'scalar' "
 637           . "instead of -nest => 'scalar' ";
 638       return ($v);
 639     },
 640
 641     UNDEF => sub {
 642       puke "-$op => undef not supported";
 643     },
 644
 645     FALLBACK => sub {
 646       $self->_recurse_where ($v);
 647     },
 648
 649    });
 650 }
 651
 652
 653 sub _where_op_BOOL {
 654   my ($self, $op, $v) = @_;
 655
 656   my ($s, @b) = $self->_SWITCH_refkind($v, {
 657     SCALAR => sub { # interpreted as SQL column
 658       $self->_convert($self->_quote($v));
 659     },
 660
 661     UNDEF => sub {
 662       puke "-$op => undef not supported";
 663     },
 664
 665     FALLBACK => sub {
 666       $self->_recurse_where ($v);
 667     },
 668   });
 669
 670   $s = "(NOT $s)" if $op =~ /^not/i;
 671   ($s, @b);
 672 }
 673
 674
 675 sub _where_op_IDENT {
 676   my $self = shift;
 677   my ($op, $rhs) = splice @_, -2;
 678   if (ref $rhs) {
 679     puke "-$op takes a single scalar argument (a quotable identifier)";
 680   }
 681
 682   # in case we are called as a top level special op (no '=')
 683   my $lhs = shift;
 684
 685   $_ = $self->_convert($self->_quote($_)) for ($lhs, $rhs);
 686
 687   return $lhs
 688     ? "$lhs = $rhs"
 689     : $rhs
 690   ;
 691 }
 692
 693 sub _where_op_VALUE {
 694   my $self = shift;
 695   my ($op, $rhs) = splice @_, -2;
 696
 697   # in case we are called as a top level special op (no '=')
 698   my $lhs = shift;
 699
 700   my @bind =
 701     $self->_bindtype (
 702       ($lhs || $self->{_nested_func_lhs}),
 703       $rhs,
 704     )
 705   ;
 706
 707   return $lhs
 708     ? (
 709       $self->_convert($self->_quote($lhs)) . ' = ' . $self->_convert('?'),
 710       @bind
 711     )
 712     : (
 713       $self->_convert('?'),
 714       @bind,
 715     )
 716   ;
 717 }
 718
 719 sub _where_hashpair_ARRAYREF {
 720   my ($self, $k, $v) = @_;
 721
 722   if( @$v ) {
 723     my @v = @$v; # need copy because of shift below
 724     $self->_debug("ARRAY($k) means distribute over elements");
 725
 726     # put apart first element if it is an operator (-and, -or)
 727     my $op = (
 728        (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
 729          ? shift @v
 730          : ''
 731     );
 732     my @distributed = map { {$k =>  $_} } @v;
 733
 734     if ($op) {
 735       $self->_debug("OP($op) reinjected into the distributed array");
 736       unshift @distributed, $op;
 737     }
 738
 739     my $logic = $op ? substr($op, 1) : '';
 740
 741     return $self->_recurse_where(\@distributed, $logic);
 742   }
 743   else {
 744     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 745     $self->_debug("empty ARRAY($k) means 0=1");
 746     return ($self->{sqlfalse});
 747   }
 748 }
 749
 750 sub _where_hashpair_HASHREF {
 751   my ($self, $k, $v, $logic) = @_;
 752   $logic ||= 'and';
 753
 754   local $self->{_nested_func_lhs} = $self->{_nested_func_lhs};
 755
 756   my ($all_sql, @all_bind);
 757
 758   for my $orig_op (sort keys %$v) {
 759     my $val = $v->{$orig_op};
 760
 761     # put the operator in canonical form
 762     my $op = $orig_op;
 763
 764     # FIXME - we need to phase out dash-less ops
 765     $op =~ s/^-//;        # remove possible initial dash
 766     $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 767     $op =~ s/\s+/ /g;     # compress whitespace
 768
 769     $self->_assert_pass_injection_guard($op);
 770
 771     # so that -not_foo works correctly
 772     $op =~ s/^not_/NOT /i;
 773
 774     my ($sql, @bind);
 775
 776     # CASE: col-value logic modifiers
 777     if ( $orig_op =~ /^ \- (and|or) $/xi ) {
 778       ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $1);
 779     }
 780     # CASE: special operators like -in or -between
 781     elsif ( my $special_op = List::Util::first {$op =~ $_->{regex}} @{$self->{special_ops}} ) {
 782       my $handler = $special_op->{handler};
 783       if (! $handler) {
 784         puke "No handler supplied for special operator $orig_op";
 785       }
 786       elsif (not ref $handler) {
 787         ($sql, @bind) = $self->$handler ($k, $op, $val);
 788       }
 789       elsif (ref $handler eq 'CODE') {
 790         ($sql, @bind) = $handler->($self, $k, $op, $val);
 791       }
 792       else {
 793         puke "Illegal handler for special operator $orig_op - expecting a method name or a coderef";
 794       }
 795     }
 796     else {
 797       $self->_SWITCH_refkind($val, {
 798
 799         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 800           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 801         },
 802
 803         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 804           my ($sub_sql, @sub_bind) = @$$val;
 805           $self->_assert_bindval_matches_bindtype(@sub_bind);
 806           $sql  = join ' ', $self->_convert($self->_quote($k)),
 807                             $self->_sqlcase($op),
 808                             $sub_sql;
 809           @bind = @sub_bind;
 810         },
 811
 812         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 813           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 814                    ($op =~ $self->{inequality_op}) ? 'is not' :
 815                puke "unexpected operator '$orig_op' with undef operand";
 816           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 817         },
 818
 819         FALLBACK => sub {       # CASE: col => {op/func => $stuff}
 820
 821           # retain for proper column type bind
 822           $self->{_nested_func_lhs} ||= $k;
 823
 824           ($sql, @bind) = $self->_where_unary_op ($op, $val);
 825
 826           $sql = join (' ',
 827             $self->_convert($self->_quote($k)),
 828             $self->{_nested_func_lhs} eq $k ? $sql : "($sql)",  # top level vs nested
 829           );
 830         },
 831       });
 832     }
 833
 834     ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
 835     push @all_bind, @bind;
 836   }
 837   return ($all_sql, @all_bind);
 838 }
 839
 840
 841
 842 sub _where_field_op_ARRAYREF {
 843   my ($self, $k, $op, $vals) = @_;
 844
 845   my @vals = @$vals;  #always work on a copy
 846
 847   if(@vals) {
 848     $self->_debug(sprintf '%s means multiple elements: [ %s ]',
 849       $vals,
 850       join (', ', map { defined $_ ? "'$_'" : 'NULL' } @vals ),
 851     );
 852
 853     # see if the first element is an -and/-or op
 854     my $logic;
 855     if (defined $vals[0] && $vals[0] =~ /^ - ( AND|OR ) $/ix) {
 856       $logic = uc $1;
 857       shift @vals;
 858     }
 859
 860     # distribute $op over each remaining member of @vals, append logic if exists
 861     return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 862
 863     # LDNOTE : had planned to change the distribution logic when
 864     # $op =~ $self->{inequality_op}, because of Morgan laws :
 865     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 866     # WHERE field != 22 OR  field != 33 : the user probably means
 867     # WHERE field != 22 AND field != 33.
 868     # To do this, replace the above to roughly :
 869     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 870     # return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 871
 872   }
 873   else {
 874     # try to DWIM on equality operators
 875     # LDNOTE : not 100% sure this is the correct thing to do ...
 876     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 877     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 878
 879     # otherwise
 880     puke "operator '$op' applied on an empty array (field '$k')";
 881   }
 882 }
 883
 884
 885 sub _where_hashpair_SCALARREF {
 886   my ($self, $k, $v) = @_;
 887   $self->_debug("SCALAR($k) means literal SQL: $$v");
 888   my $sql = $self->_quote($k) . " " . $$v;
 889   return ($sql);
 890 }
 891
 892 # literal SQL with bind
 893 sub _where_hashpair_ARRAYREFREF {
 894   my ($self, $k, $v) = @_;
 895   $self->_debug("REF($k) means literal SQL: @${$v}");
 896   my ($sql, @bind) = @$$v;
 897   $self->_assert_bindval_matches_bindtype(@bind);
 898   $sql  = $self->_quote($k) . " " . $sql;
 899   return ($sql, @bind );
 900 }
 901
 902 # literal SQL without bind
 903 sub _where_hashpair_SCALAR {
 904   my ($self, $k, $v) = @_;
 905   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 906   my $sql = join ' ', $self->_convert($self->_quote($k)),
 907                       $self->_sqlcase($self->{cmp}),
 908                       $self->_convert('?');
 909   my @bind =  $self->_bindtype($k, $v);
 910   return ( $sql, @bind);
 911 }
 912
 913
 914 sub _where_hashpair_UNDEF {
 915   my ($self, $k, $v) = @_;
 916   $self->_debug("UNDEF($k) means IS NULL");
 917   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 918   return ($sql);
 919 }
 920
 921 #======================================================================
 922 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 923 #======================================================================
 924
 925
 926 sub _where_SCALARREF {
 927   my ($self, $where) = @_;
 928
 929   # literal sql
 930   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 931   return ($$where);
 932 }
 933
 934
 935 sub _where_SCALAR {
 936   my ($self, $where) = @_;
 937
 938   # literal sql
 939   $self->_debug("NOREF(*top) means literal SQL: $where");
 940   return ($where);
 941 }
 942
 943
 944 sub _where_UNDEF {
 945   my ($self) = @_;
 946   return ();
 947 }
 948
 949
 950 #======================================================================
 951 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 952 #======================================================================
 953
 954
 955 sub _where_field_BETWEEN {
 956   my ($self, $k, $op, $vals) = @_;
 957
 958   my ($label, $and, $placeholder);
 959   $label       = $self->_convert($self->_quote($k));
 960   $and         = ' ' . $self->_sqlcase('and') . ' ';
 961   $placeholder = $self->_convert('?');
 962   $op               = $self->_sqlcase($op);
 963
 964   my ($clause, @bind) = $self->_SWITCH_refkind($vals, {
 965     ARRAYREFREF => sub {
 966       my ($s, @b) = @$$vals;
 967       $self->_assert_bindval_matches_bindtype(@b);
 968       ($s, @b);
 969     },
 970     SCALARREF => sub {
 971       return $$vals;
 972     },
 973     ARRAYREF => sub {
 974       puke "special op 'between' accepts an arrayref with exactly two values"
 975         if @$vals != 2;
 976
 977       my (@all_sql, @all_bind);
 978       foreach my $val (@$vals) {
 979         my ($sql, @bind) = $self->_SWITCH_refkind($val, {
 980            SCALAR => sub {
 981              return ($placeholder, $self->_bindtype($k, $val) );
 982            },
 983            SCALARREF => sub {
 984              return $$val;
 985            },
 986            ARRAYREFREF => sub {
 987              my ($sql, @bind) = @$$val;
 988              $self->_assert_bindval_matches_bindtype(@bind);
 989              return ($sql, @bind);
 990            },
 991            HASHREF => sub {
 992              my ($func, $arg, @rest) = %$val;
 993              puke ("Only simple { -func => arg } functions accepted as sub-arguments to BETWEEN")
 994                if (@rest or $func !~ /^ \- (.+)/x);
 995              local $self->{_nested_func_lhs} = $k;
 996              $self->_where_unary_op ($1 => $arg);
 997            }
 998         });
 999         push @all_sql, $sql;
1000         push @all_bind, @bind;
1001       }
1002
1003       return (
1004         (join $and, @all_sql),
1005         @all_bind
1006       );
1007     },
1008     FALLBACK => sub {
1009       puke "special op 'between' accepts an arrayref with two values, or a single literal scalarref/arrayref-ref";
1010     },
1011   });
1012
1013   my $sql = "( $label $op $clause )";
1014   return ($sql, @bind)
1015 }
1016
1017
1018 sub _where_field_IN {
1019   my ($self, $k, $op, $vals) = @_;
1020
1021   # backwards compatibility : if scalar, force into an arrayref
1022   $vals = [$vals] if defined $vals && ! ref $vals;
1023
1024   my ($label)       = $self->_convert($self->_quote($k));
1025   my ($placeholder) = $self->_convert('?');
1026   $op               = $self->_sqlcase($op);
1027
1028   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
1029     ARRAYREF => sub {     # list of choices
1030       if (@$vals) { # nonempty list
1031         my (@all_sql, @all_bind);
1032
1033         for my $val (@$vals) {
1034           my ($sql, @bind) = $self->_SWITCH_refkind($val, {
1035             SCALAR => sub {
1036               return ($placeholder, $val);
1037             },
1038             SCALARREF => sub {
1039               return $$val;
1040             },
1041             ARRAYREFREF => sub {
1042               my ($sql, @bind) = @$$val;
1043               $self->_assert_bindval_matches_bindtype(@bind);
1044               return ($sql, @bind);
1045             },
1046             HASHREF => sub {
1047               my ($func, $arg, @rest) = %$val;
1048               puke ("Only simple { -func => arg } functions accepted as sub-arguments to IN")
1049                 if (@rest or $func !~ /^ \- (.+)/x);
1050               local $self->{_nested_func_lhs} = $k;
1051               $self->_where_unary_op ($1 => $arg);
1052             },
1053             UNDEF => sub {
1054               return $self->_sqlcase('null');
1055             },
1056           });
1057           push @all_sql, $sql;
1058           push @all_bind, @bind;
1059         }
1060
1061         return (
1062           sprintf ('%s %s ( %s )',
1063             $label,
1064             $op,
1065             join (', ', @all_sql)
1066           ),
1067           $self->_bindtype($k, @all_bind),
1068         );
1069       }
1070       else { # empty list : some databases won't understand "IN ()", so DWIM
1071         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
1072         return ($sql);
1073       }
1074     },
1075
1076     SCALARREF => sub {  # literal SQL
1077       my $sql = $self->_open_outer_paren ($$vals);
1078       return ("$label $op ( $sql )");
1079     },
1080     ARRAYREFREF => sub {  # literal SQL with bind
1081       my ($sql, @bind) = @$$vals;
1082       $self->_assert_bindval_matches_bindtype(@bind);
1083       $sql = $self->_open_outer_paren ($sql);
1084       return ("$label $op ( $sql )", @bind);
1085     },
1086
1087     FALLBACK => sub {
1088       puke "special op 'in' requires an arrayref (or scalarref/arrayref-ref)";
1089     },
1090   });
1091
1092   return ($sql, @bind);
1093 }
1094
1095 # Some databases (SQLite) treat col IN (1, 2) different from
1096 # col IN ( (1, 2) ). Use this to strip all outer parens while
1097 # adding them back in the corresponding method
1098 sub _open_outer_paren {
1099   my ($self, $sql) = @_;
1100   $sql = $1 while $sql =~ /^ \s* \( (.*) \) \s* $/xs;
1101   return $sql;
1102 }
1103
1104
1105 #======================================================================
1106 # ORDER BY
1107 #======================================================================
1108
1109 sub _order_by {
1110   my ($self, $arg) = @_;
1111
1112   my (@sql, @bind);
1113   for my $c ($self->_order_by_chunks ($arg) ) {
1114     $self->_SWITCH_refkind ($c, {
1115       SCALAR => sub { push @sql, $c },
1116       ARRAYREF => sub { push @sql, shift @$c; push @bind, @$c },
1117     });
1118   }
1119
1120   my $sql = @sql
1121     ? sprintf ('%s %s',
1122         $self->_sqlcase(' order by'),
1123         join (', ', @sql)
1124       )
1125     : ''
1126   ;
1127
1128   return wantarray ? ($sql, @bind) : $sql;
1129 }
1130
1131 sub _order_by_chunks {
1132   my ($self, $arg) = @_;
1133
1134   return $self->_SWITCH_refkind($arg, {
1135
1136     ARRAYREF => sub {
1137       map { $self->_order_by_chunks ($_ ) } @$arg;
1138     },
1139
1140     ARRAYREFREF => sub {
1141       my ($s, @b) = @$$arg;
1142       $self->_assert_bindval_matches_bindtype(@b);
1143       [ $s, @b ];
1144     },
1145
1146     SCALAR    => sub {$self->_quote($arg)},
1147
1148     UNDEF     => sub {return () },
1149
1150     SCALARREF => sub {$$arg}, # literal SQL, no quoting
1151
1152     HASHREF   => sub {
1153       # get first pair in hash
1154       my ($key, $val, @rest) = %$arg;
1155
1156       return () unless $key;
1157
1158       if ( @rest or not $key =~ /^-(desc|asc)/i ) {
1159         puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
1160       }
1161
1162       my $direction = $1;
1163
1164       my @ret;
1165       for my $c ($self->_order_by_chunks ($val)) {
1166         my ($sql, @bind);
1167
1168         $self->_SWITCH_refkind ($c, {
1169           SCALAR => sub {
1170             $sql = $c;
1171           },
1172           ARRAYREF => sub {
1173             ($sql, @bind) = @$c;
1174           },
1175         });
1176
1177         $sql = $sql . ' ' . $self->_sqlcase($direction);
1178
1179         push @ret, [ $sql, @bind];
1180       }
1181
1182       return @ret;
1183     },
1184   });
1185 }
1186
1187
1188 #======================================================================
1189 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
1190 #======================================================================
1191
1192 sub _table  {
1193   my $self = shift;
1194   my $from = shift;
1195   $self->_SWITCH_refkind($from, {
1196     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
1197     SCALAR       => sub {$self->_quote($from)},
1198     SCALARREF    => sub {$$from},
1199   });
1200 }
1201
1202
1203 #======================================================================
1204 # UTILITY FUNCTIONS
1205 #======================================================================
1206
1207 # highly optimized, as it's called way too often
1208 sub _quote {
1209   # my ($self, $label) = @_;
1210
1211   return '' unless defined $_[1];
1212   return ${$_[1]} if ref($_[1]) eq 'SCALAR';
1213
1214   unless ($_[0]->{quote_char}) {
1215     $_[0]->_assert_pass_injection_guard($_[1]);
1216     return $_[1];
1217   }
1218
1219   my $qref = ref $_[0]->{quote_char};
1220   my ($l, $r);
1221   if (!$qref) {
1222     ($l, $r) = ( $_[0]->{quote_char}, $_[0]->{quote_char} );
1223   }
1224   elsif ($qref eq 'ARRAY') {
1225     ($l, $r) = @{$_[0]->{quote_char}};
1226   }
1227   else {
1228     puke "Unsupported quote_char format: $_[0]->{quote_char}";
1229   }
1230
1231   # parts containing * are naturally unquoted
1232   return join( $_[0]->{name_sep}||'', map
1233     { $_ eq '*' ? $_ : $l . $_ . $r }
1234     ( $_[0]->{name_sep} ? split (/\Q$_[0]->{name_sep}\E/, $_[1] ) : $_[1] )
1235   );
1236 }
1237
1238
1239 # Conversion, if applicable
1240 sub _convert ($) {
1241   #my ($self, $arg) = @_;
1242
1243 # LDNOTE : modified the previous implementation below because
1244 # it was not consistent : the first "return" is always an array,
1245 # the second "return" is context-dependent. Anyway, _convert
1246 # seems always used with just a single argument, so make it a
1247 # scalar function.
1248 #     return @_ unless $self->{convert};
1249 #     my $conv = $self->_sqlcase($self->{convert});
1250 #     my @ret = map { $conv.'('.$_.')' } @_;
1251 #     return wantarray ? @ret : $ret[0];
1252   if ($_[0]->{convert}) {
1253     return $_[0]->_sqlcase($_[0]->{convert}) .'(' . $_[1] . ')';
1254   }
1255   return $_[1];
1256 }
1257
1258 # And bindtype
1259 sub _bindtype (@) {
1260   #my ($self, $col, @vals) = @_;
1261
1262   #LDNOTE : changed original implementation below because it did not make
1263   # sense when bindtype eq 'columns' and @vals > 1.
1264 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
1265
1266   # called often - tighten code
1267   return $_[0]->{bindtype} eq 'columns'
1268     ? map {[$_[1], $_]} @_[2 .. $#_]
1269     : @_[2 .. $#_]
1270   ;
1271 }
1272
1273 # Dies if any element of @bind is not in [colname => value] format
1274 # if bindtype is 'columns'.
1275 sub _assert_bindval_matches_bindtype {
1276 #  my ($self, @bind) = @_;
1277   my $self = shift;
1278   if ($self->{bindtype} eq 'columns') {
1279     for (@_) {
1280       if (!defined $_ || ref($_) ne 'ARRAY' || @$_ != 2) {
1281         puke "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
1282       }
1283     }
1284   }
1285 }
1286
1287 sub _join_sql_clauses {
1288   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
1289
1290   if (@$clauses_aref > 1) {
1291     my $join  = " " . $self->_sqlcase($logic) . " ";
1292     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
1293     return ($sql, @$bind_aref);
1294   }
1295   elsif (@$clauses_aref) {
1296     return ($clauses_aref->[0], @$bind_aref); # no parentheses
1297   }
1298   else {
1299     return (); # if no SQL, ignore @$bind_aref
1300   }
1301 }
1302
1303
1304 # Fix SQL case, if so requested
1305 sub _sqlcase {
1306   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
1307   # don't touch the argument ... crooked logic, but let's not change it!
1308   return $_[0]->{case} ? $_[1] : uc($_[1]);
1309 }
1310
1311
1312 #======================================================================
1313 # DISPATCHING FROM REFKIND
1314 #======================================================================
1315
1316 sub _refkind {
1317   my ($self, $data) = @_;
1318
1319   return 'UNDEF' unless defined $data;
1320
1321   # blessed objects are treated like scalars
1322   my $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1323
1324   return 'SCALAR' unless $ref;
1325
1326   my $n_steps = 1;
1327   while ($ref eq 'REF') {
1328     $data = $$data;
1329     $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1330     $n_steps++ if $ref;
1331   }
1332
1333   return ($ref||'SCALAR') . ('REF' x $n_steps);
1334 }
1335
1336 sub _try_refkind {
1337   my ($self, $data) = @_;
1338   my @try = ($self->_refkind($data));
1339   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1340   push @try, 'FALLBACK';
1341   return \@try;
1342 }
1343
1344 sub _METHOD_FOR_refkind {
1345   my ($self, $meth_prefix, $data) = @_;
1346
1347   my $method;
1348   for (@{$self->_try_refkind($data)}) {
1349     $method = $self->can($meth_prefix."_".$_)
1350       and last;
1351   }
1352
1353   return $method || puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1354 }
1355
1356
1357 sub _SWITCH_refkind {
1358   my ($self, $data, $dispatch_table) = @_;
1359
1360   my $coderef;
1361   for (@{$self->_try_refkind($data)}) {
1362     $coderef = $dispatch_table->{$_}
1363       and last;
1364   }
1365
1366   puke "no dispatch entry for ".$self->_refkind($data)
1367     unless $coderef;
1368
1369   $coderef->();
1370 }
1371
1372
1373
1374
1375 #======================================================================
1376 # VALUES, GENERATE, AUTOLOAD
1377 #======================================================================
1378
1379 # LDNOTE: original code from nwiger, didn't touch code in that section
1380 # I feel the AUTOLOAD stuff should not be the default, it should
1381 # only be activated on explicit demand by user.
1382
1383 sub values {
1384     my $self = shift;
1385     my $data = shift || return;
1386     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1387         unless ref $data eq 'HASH';
1388
1389     my @all_bind;
1390     foreach my $k ( sort keys %$data ) {
1391         my $v = $data->{$k};
1392         $self->_SWITCH_refkind($v, {
1393           ARRAYREF => sub {
1394             if ($self->{array_datatypes}) { # array datatype
1395               push @all_bind, $self->_bindtype($k, $v);
1396             }
1397             else {                          # literal SQL with bind
1398               my ($sql, @bind) = @$v;
1399               $self->_assert_bindval_matches_bindtype(@bind);
1400               push @all_bind, @bind;
1401             }
1402           },
1403           ARRAYREFREF => sub { # literal SQL with bind
1404             my ($sql, @bind) = @${$v};
1405             $self->_assert_bindval_matches_bindtype(@bind);
1406             push @all_bind, @bind;
1407           },
1408           SCALARREF => sub {  # literal SQL without bind
1409           },
1410           SCALAR_or_UNDEF => sub {
1411             push @all_bind, $self->_bindtype($k, $v);
1412           },
1413         });
1414     }
1415
1416     return @all_bind;
1417 }
1418
1419 sub generate {
1420     my $self  = shift;
1421
1422     my(@sql, @sqlq, @sqlv);
1423
1424     for (@_) {
1425         my $ref = ref $_;
1426         if ($ref eq 'HASH') {
1427             for my $k (sort keys %$_) {
1428                 my $v = $_->{$k};
1429                 my $r = ref $v;
1430                 my $label = $self->_quote($k);
1431                 if ($r eq 'ARRAY') {
1432                     # literal SQL with bind
1433                     my ($sql, @bind) = @$v;
1434                     $self->_assert_bindval_matches_bindtype(@bind);
1435                     push @sqlq, "$label = $sql";
1436                     push @sqlv, @bind;
1437                 } elsif ($r eq 'SCALAR') {
1438                     # literal SQL without bind
1439                     push @sqlq, "$label = $$v";
1440                 } else {
1441                     push @sqlq, "$label = ?";
1442                     push @sqlv, $self->_bindtype($k, $v);
1443                 }
1444             }
1445             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1446         } elsif ($ref eq 'ARRAY') {
1447             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1448             for my $v (@$_) {
1449                 my $r = ref $v;
1450                 if ($r eq 'ARRAY') {   # literal SQL with bind
1451                     my ($sql, @bind) = @$v;
1452                     $self->_assert_bindval_matches_bindtype(@bind);
1453                     push @sqlq, $sql;
1454                     push @sqlv, @bind;
1455                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1456                     # embedded literal SQL
1457                     push @sqlq, $$v;
1458                 } else {
1459                     push @sqlq, '?';
1460                     push @sqlv, $v;
1461                 }
1462             }
1463             push @sql, '(' . join(', ', @sqlq) . ')';
1464         } elsif ($ref eq 'SCALAR') {
1465             # literal SQL
1466             push @sql, $$_;
1467         } else {
1468             # strings get case twiddled
1469             push @sql, $self->_sqlcase($_);
1470         }
1471     }
1472
1473     my $sql = join ' ', @sql;
1474
1475     # this is pretty tricky
1476     # if ask for an array, return ($stmt, @bind)
1477     # otherwise, s/?/shift @sqlv/ to put it inline
1478     if (wantarray) {
1479         return ($sql, @sqlv);
1480     } else {
1481         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1482                              ref $d ? $d->[1] : $d/e;
1483         return $sql;
1484     }
1485 }
1486
1487
1488 sub DESTROY { 1 }
1489
1490 sub AUTOLOAD {
1491     # This allows us to check for a local, then _form, attr
1492     my $self = shift;
1493     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1494     return $self->generate($name, @_);
1495 }
1496
1497 1;
1498
1499
1500
1501 __END__
1502
1503 =head1 NAME
1504
1505 SQL::Abstract - Generate SQL from Perl data structures
1506
1507 =head1 SYNOPSIS
1508
1509     use SQL::Abstract;
1510
1511     my $sql = SQL::Abstract->new;
1512
1513     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1514
1515     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1516
1517     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1518
1519     my($stmt, @bind) = $sql->delete($table, \%where);
1520
1521     # Then, use these in your DBI statements
1522     my $sth = $dbh->prepare($stmt);
1523     $sth->execute(@bind);
1524
1525     # Just generate the WHERE clause
1526     my($stmt, @bind) = $sql->where(\%where, \@order);
1527
1528     # Return values in the same order, for hashed queries
1529     # See PERFORMANCE section for more details
1530     my @bind = $sql->values(\%fieldvals);
1531
1532 =head1 DESCRIPTION
1533
1534 This module was inspired by the excellent L<DBIx::Abstract>.
1535 However, in using that module I found that what I really wanted
1536 to do was generate SQL, but still retain complete control over my
1537 statement handles and use the DBI interface. So, I set out to
1538 create an abstract SQL generation module.
1539
1540 While based on the concepts used by L<DBIx::Abstract>, there are
1541 several important differences, especially when it comes to WHERE
1542 clauses. I have modified the concepts used to make the SQL easier
1543 to generate from Perl data structures and, IMO, more intuitive.
1544 The underlying idea is for this module to do what you mean, based
1545 on the data structures you provide it. The big advantage is that
1546 you don't have to modify your code every time your data changes,
1547 as this module figures it out.
1548
1549 To begin with, an SQL INSERT is as easy as just specifying a hash
1550 of C<key=value> pairs:
1551
1552     my %data = (
1553         name => 'Jimbo Bobson',
1554         phone => '123-456-7890',
1555         address => '42 Sister Lane',
1556         city => 'St. Louis',
1557         state => 'Louisiana',
1558     );
1559
1560 The SQL can then be generated with this:
1561
1562     my($stmt, @bind) = $sql->insert('people', \%data);
1563
1564 Which would give you something like this:
1565
1566     $stmt = "INSERT INTO people
1567                     (address, city, name, phone, state)
1568                     VALUES (?, ?, ?, ?, ?)";
1569     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1570              '123-456-7890', 'Louisiana');
1571
1572 These are then used directly in your DBI code:
1573
1574     my $sth = $dbh->prepare($stmt);
1575     $sth->execute(@bind);
1576
1577 =head2 Inserting and Updating Arrays
1578
1579 If your database has array types (like for example Postgres),
1580 activate the special option C<< array_datatypes => 1 >>
1581 when creating the C<SQL::Abstract> object.
1582 Then you may use an arrayref to insert and update database array types:
1583
1584     my $sql = SQL::Abstract->new(array_datatypes => 1);
1585     my %data = (
1586         planets => [qw/Mercury Venus Earth Mars/]
1587     );
1588
1589     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1590
1591 This results in:
1592
1593     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1594
1595     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1596
1597
1598 =head2 Inserting and Updating SQL
1599
1600 In order to apply SQL functions to elements of your C<%data> you may
1601 specify a reference to an arrayref for the given hash value. For example,
1602 if you need to execute the Oracle C<to_date> function on a value, you can
1603 say something like this:
1604
1605     my %data = (
1606         name => 'Bill',
1607         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1608     );
1609
1610 The first value in the array is the actual SQL. Any other values are
1611 optional and would be included in the bind values array. This gives
1612 you:
1613
1614     my($stmt, @bind) = $sql->insert('people', \%data);
1615
1616     $stmt = "INSERT INTO people (name, date_entered)
1617                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1618     @bind = ('Bill', '03/02/2003');
1619
1620 An UPDATE is just as easy, all you change is the name of the function:
1621
1622     my($stmt, @bind) = $sql->update('people', \%data);
1623
1624 Notice that your C<%data> isn't touched; the module will generate
1625 the appropriately quirky SQL for you automatically. Usually you'll
1626 want to specify a WHERE clause for your UPDATE, though, which is
1627 where handling C<%where> hashes comes in handy...
1628
1629 =head2 Complex where statements
1630
1631 This module can generate pretty complicated WHERE statements
1632 easily. For example, simple C<key=value> pairs are taken to mean
1633 equality, and if you want to see if a field is within a set
1634 of values, you can use an arrayref. Let's say we wanted to
1635 SELECT some data based on this criteria:
1636
1637     my %where = (
1638        requestor => 'inna',
1639        worker => ['nwiger', 'rcwe', 'sfz'],
1640        status => { '!=', 'completed' }
1641     );
1642
1643     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1644
1645 The above would give you something like this:
1646
1647     $stmt = "SELECT * FROM tickets WHERE
1648                 ( requestor = ? ) AND ( status != ? )
1649                 AND ( worker = ? OR worker = ? OR worker = ? )";
1650     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1651
1652 Which you could then use in DBI code like so:
1653
1654     my $sth = $dbh->prepare($stmt);
1655     $sth->execute(@bind);
1656
1657 Easy, eh?
1658
1659 =head1 FUNCTIONS
1660
1661 The functions are simple. There's one for each major SQL operation,
1662 and a constructor you use first. The arguments are specified in a
1663 similar order to each function (table, then fields, then a where
1664 clause) to try and simplify things.
1665
1666
1667
1668
1669 =head2 new(option => 'value')
1670
1671 The C<new()> function takes a list of options and values, and returns
1672 a new B<SQL::Abstract> object which can then be used to generate SQL
1673 through the methods below. The options accepted are:
1674
1675 =over
1676
1677 =item case
1678
1679 If set to 'lower', then SQL will be generated in all lowercase. By
1680 default SQL is generated in "textbook" case meaning something like:
1681
1682     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1683
1684 Any setting other than 'lower' is ignored.
1685
1686 =item cmp
1687
1688 This determines what the default comparison operator is. By default
1689 it is C<=>, meaning that a hash like this:
1690
1691     %where = (name => 'nwiger', email => 'nate@wiger.org');
1692
1693 Will generate SQL like this:
1694
1695     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1696
1697 However, you may want loose comparisons by default, so if you set
1698 C<cmp> to C<like> you would get SQL such as:
1699
1700     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1701
1702 You can also override the comparsion on an individual basis - see
1703 the huge section on L</"WHERE CLAUSES"> at the bottom.
1704
1705 =item sqltrue, sqlfalse
1706
1707 Expressions for inserting boolean values within SQL statements.
1708 By default these are C<1=1> and C<1=0>. They are used
1709 by the special operators C<-in> and C<-not_in> for generating
1710 correct SQL even when the argument is an empty array (see below).
1711
1712 =item logic
1713
1714 This determines the default logical operator for multiple WHERE
1715 statements in arrays or hashes. If absent, the default logic is "or"
1716 for arrays, and "and" for hashes. This means that a WHERE
1717 array of the form:
1718
1719     @where = (
1720         event_date => {'>=', '2/13/99'},
1721         event_date => {'<=', '4/24/03'},
1722     );
1723
1724 will generate SQL like this:
1725
1726     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1727
1728 This is probably not what you want given this query, though (look
1729 at the dates). To change the "OR" to an "AND", simply specify:
1730
1731     my $sql = SQL::Abstract->new(logic => 'and');
1732
1733 Which will change the above C<WHERE> to:
1734
1735     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1736
1737 The logic can also be changed locally by inserting
1738 a modifier in front of an arrayref :
1739
1740     @where = (-and => [event_date => {'>=', '2/13/99'},
1741                        event_date => {'<=', '4/24/03'} ]);
1742
1743 See the L</"WHERE CLAUSES"> section for explanations.
1744
1745 =item convert
1746
1747 This will automatically convert comparisons using the specified SQL
1748 function for both column and value. This is mostly used with an argument
1749 of C<upper> or C<lower>, so that the SQL will have the effect of
1750 case-insensitive "searches". For example, this:
1751
1752     $sql = SQL::Abstract->new(convert => 'upper');
1753     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1754
1755 Will turn out the following SQL:
1756
1757     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1758
1759 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1760 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1761 not validate this option; it will just pass through what you specify verbatim).
1762
1763 =item bindtype
1764
1765 This is a kludge because many databases suck. For example, you can't
1766 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1767 Instead, you have to use C<bind_param()>:
1768
1769     $sth->bind_param(1, 'reg data');
1770     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1771
1772 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1773 which loses track of which field each slot refers to. Fear not.
1774
1775 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1776 Currently, you can specify either C<normal> (default) or C<columns>. If you
1777 specify C<columns>, you will get an array that looks like this:
1778
1779     my $sql = SQL::Abstract->new(bindtype => 'columns');
1780     my($stmt, @bind) = $sql->insert(...);
1781
1782     @bind = (
1783         [ 'column1', 'value1' ],
1784         [ 'column2', 'value2' ],
1785         [ 'column3', 'value3' ],
1786     );
1787
1788 You can then iterate through this manually, using DBI's C<bind_param()>.
1789
1790     $sth->prepare($stmt);
1791     my $i = 1;
1792     for (@bind) {
1793         my($col, $data) = @$_;
1794         if ($col eq 'details' || $col eq 'comments') {
1795             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1796         } elsif ($col eq 'image') {
1797             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1798         } else {
1799             $sth->bind_param($i, $data);
1800         }
1801         $i++;
1802     }
1803     $sth->execute;      # execute without @bind now
1804
1805 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1806 Basically, the advantage is still that you don't have to care which fields
1807 are or are not included. You could wrap that above C<for> loop in a simple
1808 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1809 get a layer of abstraction over manual SQL specification.
1810
1811 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1812 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1813 will expect the bind values in this format.
1814
1815 =item quote_char
1816
1817 This is the character that a table or column name will be quoted
1818 with.  By default this is an empty string, but you could set it to
1819 the character C<`>, to generate SQL like this:
1820
1821   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1822
1823 Alternatively, you can supply an array ref of two items, the first being the left
1824 hand quote character, and the second the right hand quote character. For
1825 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1826 that generates SQL like this:
1827
1828   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1829
1830 Quoting is useful if you have tables or columns names that are reserved
1831 words in your database's SQL dialect.
1832
1833 =item name_sep
1834
1835 This is the character that separates a table and column name.  It is
1836 necessary to specify this when the C<quote_char> option is selected,
1837 so that tables and column names can be individually quoted like this:
1838
1839   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1840
1841 =item injection_guard
1842
1843 A regular expression C<qr/.../> that is applied to any C<-function> and unquoted
1844 column name specified in a query structure. This is a safety mechanism to avoid
1845 injection attacks when mishandling user input e.g.:
1846
1847   my %condition_as_column_value_pairs = get_values_from_user();
1848   $sqla->select( ... , \%condition_as_column_value_pairs );
1849
1850 If the expression matches an exception is thrown. Note that literal SQL
1851 supplied via C<\'...'> or C<\['...']> is B<not> checked in any way.
1852
1853 Defaults to checking for C<;> and the C<GO> keyword (TransactSQL)
1854
1855 =item array_datatypes
1856
1857 When this option is true, arrayrefs in INSERT or UPDATE are
1858 interpreted as array datatypes and are passed directly
1859 to the DBI layer.
1860 When this option is false, arrayrefs are interpreted
1861 as literal SQL, just like refs to arrayrefs
1862 (but this behavior is for backwards compatibility; when writing
1863 new queries, use the "reference to arrayref" syntax
1864 for literal SQL).
1865
1866
1867 =item special_ops
1868
1869 Takes a reference to a list of "special operators"
1870 to extend the syntax understood by L<SQL::Abstract>.
1871 See section L</"SPECIAL OPERATORS"> for details.
1872
1873 =item unary_ops
1874
1875 Takes a reference to a list of "unary operators"
1876 to extend the syntax understood by L<SQL::Abstract>.
1877 See section L</"UNARY OPERATORS"> for details.
1878
1879
1880
1881 =back
1882
1883 =head2 insert($table, \@values || \%fieldvals, \%options)
1884
1885 This is the simplest function. You simply give it a table name
1886 and either an arrayref of values or hashref of field/value pairs.
1887 It returns an SQL INSERT statement and a list of bind values.
1888 See the sections on L</"Inserting and Updating Arrays"> and
1889 L</"Inserting and Updating SQL"> for information on how to insert
1890 with those data types.
1891
1892 The optional C<\%options> hash reference may contain additional
1893 options to generate the insert SQL. Currently supported options
1894 are:
1895
1896 =over 4
1897
1898 =item returning
1899
1900 Takes either a scalar of raw SQL fields, or an array reference of
1901 field names, and adds on an SQL C<RETURNING> statement at the end.
1902 This allows you to return data generated by the insert statement
1903 (such as row IDs) without performing another C<SELECT> statement.
1904 Note, however, this is not part of the SQL standard and may not
1905 be supported by all database engines.
1906
1907 =back
1908
1909 =head2 update($table, \%fieldvals, \%where)
1910
1911 This takes a table, hashref of field/value pairs, and an optional
1912 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1913 of bind values.
1914 See the sections on L</"Inserting and Updating Arrays"> and
1915 L</"Inserting and Updating SQL"> for information on how to insert
1916 with those data types.
1917
1918 =head2 select($source, $fields, $where, $order)
1919
1920 This returns a SQL SELECT statement and associated list of bind values, as
1921 specified by the arguments  :
1922
1923 =over
1924
1925 =item $source
1926
1927 Specification of the 'FROM' part of the statement.
1928 The argument can be either a plain scalar (interpreted as a table
1929 name, will be quoted), or an arrayref (interpreted as a list
1930 of table names, joined by commas, quoted), or a scalarref
1931 (literal table name, not quoted), or a ref to an arrayref
1932 (list of literal table names, joined by commas, not quoted).
1933
1934 =item $fields
1935
1936 Specification of the list of fields to retrieve from
1937 the source.
1938 The argument can be either an arrayref (interpreted as a list
1939 of field names, will be joined by commas and quoted), or a
1940 plain scalar (literal SQL, not quoted).
1941 Please observe that this API is not as flexible as for
1942 the first argument C<$table>, for backwards compatibility reasons.
1943
1944 =item $where
1945
1946 Optional argument to specify the WHERE part of the query.
1947 The argument is most often a hashref, but can also be
1948 an arrayref or plain scalar --
1949 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1950
1951 =item $order
1952
1953 Optional argument to specify the ORDER BY part of the query.
1954 The argument can be a scalar, a hashref or an arrayref
1955 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1956 for details.
1957
1958 =back
1959
1960
1961 =head2 delete($table, \%where)
1962
1963 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1964 It returns an SQL DELETE statement and list of bind values.
1965
1966 =head2 where(\%where, \@order)
1967
1968 This is used to generate just the WHERE clause. For example,
1969 if you have an arbitrary data structure and know what the
1970 rest of your SQL is going to look like, but want an easy way
1971 to produce a WHERE clause, use this. It returns an SQL WHERE
1972 clause and list of bind values.
1973
1974
1975 =head2 values(\%data)
1976
1977 This just returns the values from the hash C<%data>, in the same
1978 order that would be returned from any of the other above queries.
1979 Using this allows you to markedly speed up your queries if you
1980 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1981
1982 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1983
1984 Warning: This is an experimental method and subject to change.
1985
1986 This returns arbitrarily generated SQL. It's a really basic shortcut.
1987 It will return two different things, depending on return context:
1988
1989     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1990     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
1991
1992 These would return the following:
1993
1994     # First calling form
1995     $stmt = "CREATE TABLE test (?, ?)";
1996     @bind = (field1, field2);
1997
1998     # Second calling form
1999     $stmt_and_val = "CREATE TABLE test (field1, field2)";
2000
2001 Depending on what you're trying to do, it's up to you to choose the correct
2002 format. In this example, the second form is what you would want.
2003
2004 By the same token:
2005
2006     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
2007
2008 Might give you:
2009
2010     ALTER SESSION SET nls_date_format = 'MM/YY'
2011
2012 You get the idea. Strings get their case twiddled, but everything
2013 else remains verbatim.
2014
2015 =head1 WHERE CLAUSES
2016
2017 =head2 Introduction
2018
2019 This module uses a variation on the idea from L<DBIx::Abstract>. It
2020 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
2021 module is that things in arrays are OR'ed, and things in hashes
2022 are AND'ed.>
2023
2024 The easiest way to explain is to show lots of examples. After
2025 each C<%where> hash shown, it is assumed you used:
2026
2027     my($stmt, @bind) = $sql->where(\%where);
2028
2029 However, note that the C<%where> hash can be used directly in any
2030 of the other functions as well, as described above.
2031
2032 =head2 Key-value pairs
2033
2034 So, let's get started. To begin, a simple hash:
2035
2036     my %where  = (
2037         user   => 'nwiger',
2038         status => 'completed'
2039     );
2040
2041 Is converted to SQL C<key = val> statements:
2042
2043     $stmt = "WHERE user = ? AND status = ?";
2044     @bind = ('nwiger', 'completed');
2045
2046 One common thing I end up doing is having a list of values that
2047 a field can be in. To do this, simply specify a list inside of
2048 an arrayref:
2049
2050     my %where  = (
2051         user   => 'nwiger',
2052         status => ['assigned', 'in-progress', 'pending'];
2053     );
2054
2055 This simple code will create the following:
2056
2057     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
2058     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
2059
2060 A field associated to an empty arrayref will be considered a
2061 logical false and will generate 0=1.
2062
2063 =head2 Tests for NULL values
2064
2065 If the value part is C<undef> then this is converted to SQL <IS NULL>
2066
2067     my %where  = (
2068         user   => 'nwiger',
2069         status => undef,
2070     );
2071
2072 becomes:
2073
2074     $stmt = "WHERE user = ? AND status IS NULL";
2075     @bind = ('nwiger');
2076
2077 To test if a column IS NOT NULL:
2078
2079     my %where  = (
2080         user   => 'nwiger',
2081         status => { '!=', undef },
2082     );
2083
2084 =head2 Specific comparison operators
2085
2086 If you want to specify a different type of operator for your comparison,
2087 you can use a hashref for a given column:
2088
2089     my %where  = (
2090         user   => 'nwiger',
2091         status => { '!=', 'completed' }
2092     );
2093
2094 Which would generate:
2095
2096     $stmt = "WHERE user = ? AND status != ?";
2097     @bind = ('nwiger', 'completed');
2098
2099 To test against multiple values, just enclose the values in an arrayref:
2100
2101     status => { '=', ['assigned', 'in-progress', 'pending'] };
2102
2103 Which would give you:
2104
2105     "WHERE status = ? OR status = ? OR status = ?"
2106
2107
2108 The hashref can also contain multiple pairs, in which case it is expanded
2109 into an C<AND> of its elements:
2110
2111     my %where  = (
2112         user   => 'nwiger',
2113         status => { '!=', 'completed', -not_like => 'pending%' }
2114     );
2115
2116     # Or more dynamically, like from a form
2117     $where{user} = 'nwiger';
2118     $where{status}{'!='} = 'completed';
2119     $where{status}{'-not_like'} = 'pending%';
2120
2121     # Both generate this
2122     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
2123     @bind = ('nwiger', 'completed', 'pending%');
2124
2125
2126 To get an OR instead, you can combine it with the arrayref idea:
2127
2128     my %where => (
2129          user => 'nwiger',
2130          priority => [ { '=', 2 }, { '>', 5 } ]
2131     );
2132
2133 Which would generate:
2134
2135     $stmt = "WHERE ( priority = ? OR priority > ? ) AND user = ?";
2136     @bind = ('2', '5', 'nwiger');
2137
2138 If you want to include literal SQL (with or without bind values), just use a
2139 scalar reference or array reference as the value:
2140
2141     my %where  = (
2142         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
2143         date_expires => { '<' => \"now()" }
2144     );
2145
2146 Which would generate:
2147
2148     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
2149     @bind = ('11/26/2008');
2150
2151
2152 =head2 Logic and nesting operators
2153
2154 In the example above,
2155 there is a subtle trap if you want to say something like
2156 this (notice the C<AND>):
2157
2158     WHERE priority != ? AND priority != ?
2159
2160 Because, in Perl you I<can't> do this:
2161
2162     priority => { '!=', 2, '!=', 1 }
2163
2164 As the second C<!=> key will obliterate the first. The solution
2165 is to use the special C<-modifier> form inside an arrayref:
2166
2167     priority => [ -and => {'!=', 2},
2168                           {'!=', 1} ]
2169
2170
2171 Normally, these would be joined by C<OR>, but the modifier tells it
2172 to use C<AND> instead. (Hint: You can use this in conjunction with the
2173 C<logic> option to C<new()> in order to change the way your queries
2174 work by default.) B<Important:> Note that the C<-modifier> goes
2175 B<INSIDE> the arrayref, as an extra first element. This will
2176 B<NOT> do what you think it might:
2177
2178     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
2179
2180 Here is a quick list of equivalencies, since there is some overlap:
2181
2182     # Same
2183     status => {'!=', 'completed', 'not like', 'pending%' }
2184     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
2185
2186     # Same
2187     status => {'=', ['assigned', 'in-progress']}
2188     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
2189     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
2190
2191
2192
2193 =head2 Special operators : IN, BETWEEN, etc.
2194
2195 You can also use the hashref format to compare a list of fields using the
2196 C<IN> comparison operator, by specifying the list as an arrayref:
2197
2198     my %where  = (
2199         status   => 'completed',
2200         reportid => { -in => [567, 2335, 2] }
2201     );
2202
2203 Which would generate:
2204
2205     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
2206     @bind = ('completed', '567', '2335', '2');
2207
2208 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
2209 the same way.
2210
2211 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
2212 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
2213 'sqltrue' (by default : C<1=1>).
2214
2215 In addition to the array you can supply a chunk of literal sql or
2216 literal sql with bind:
2217
2218     my %where = {
2219       customer => { -in => \[
2220         'SELECT cust_id FROM cust WHERE balance > ?',
2221         2000,
2222       ],
2223       status => { -in => \'SELECT status_codes FROM states' },
2224     };
2225
2226 would generate:
2227
2228     $stmt = "WHERE (
2229           customer IN ( SELECT cust_id FROM cust WHERE balance > ? )
2230       AND status IN ( SELECT status_codes FROM states )
2231     )";
2232     @bind = ('2000');
2233
2234
2235
2236 Another pair of operators is C<-between> and C<-not_between>,
2237 used with an arrayref of two values:
2238
2239     my %where  = (
2240         user   => 'nwiger',
2241         completion_date => {
2242            -not_between => ['2002-10-01', '2003-02-06']
2243         }
2244     );
2245
2246 Would give you:
2247
2248     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
2249
2250 Just like with C<-in> all plausible combinations of literal SQL
2251 are possible:
2252
2253     my %where = {
2254       start0 => { -between => [ 1, 2 ] },
2255       start1 => { -between => \["? AND ?", 1, 2] },
2256       start2 => { -between => \"lower(x) AND upper(y)" },
2257       start3 => { -between => [
2258         \"lower(x)",
2259         \["upper(?)", 'stuff' ],
2260       ] },
2261     };
2262
2263 Would give you:
2264
2265     $stmt = "WHERE (
2266           ( start0 BETWEEN ? AND ?                )
2267       AND ( start1 BETWEEN ? AND ?                )
2268       AND ( start2 BETWEEN lower(x) AND upper(y)  )
2269       AND ( start3 BETWEEN lower(x) AND upper(?)  )
2270     )";
2271     @bind = (1, 2, 1, 2, 'stuff');
2272
2273
2274 These are the two builtin "special operators"; but the
2275 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
2276
2277 =head2 Unary operators: bool
2278
2279 If you wish to test against boolean columns or functions within your
2280 database you can use the C<-bool> and C<-not_bool> operators. For
2281 example to test the column C<is_user> being true and the column
2282 C<is_enabled> being false you would use:-
2283
2284     my %where  = (
2285         -bool       => 'is_user',
2286         -not_bool   => 'is_enabled',
2287     );
2288
2289 Would give you:
2290
2291     WHERE is_user AND NOT is_enabled
2292
2293 If a more complex combination is required, testing more conditions,
2294 then you should use the and/or operators:-
2295
2296     my %where  = (
2297         -and           => [
2298             -bool      => 'one',
2299             -bool      => 'two',
2300             -bool      => 'three',
2301             -not_bool  => 'four',
2302         ],
2303     );
2304
2305 Would give you:
2306
2307     WHERE one AND two AND three AND NOT four
2308
2309
2310 =head2 Nested conditions, -and/-or prefixes
2311
2312 So far, we've seen how multiple conditions are joined with a top-level
2313 C<AND>.  We can change this by putting the different conditions we want in
2314 hashes and then putting those hashes in an array. For example:
2315
2316     my @where = (
2317         {
2318             user   => 'nwiger',
2319             status => { -like => ['pending%', 'dispatched'] },
2320         },
2321         {
2322             user   => 'robot',
2323             status => 'unassigned',
2324         }
2325     );
2326
2327 This data structure would create the following:
2328
2329     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
2330                 OR ( user = ? AND status = ? ) )";
2331     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
2332
2333
2334 Clauses in hashrefs or arrayrefs can be prefixed with an C<-and> or C<-or>
2335 to change the logic inside :
2336
2337     my @where = (
2338          -and => [
2339             user => 'nwiger',
2340             [
2341                 -and => [ workhrs => {'>', 20}, geo => 'ASIA' ],
2342                 -or => { workhrs => {'<', 50}, geo => 'EURO' },
2343             ],
2344         ],
2345     );
2346
2347 That would yield:
2348
2349     WHERE ( user = ? AND (
2350                ( workhrs > ? AND geo = ? )
2351             OR ( workhrs < ? OR geo = ? )
2352           ) )
2353
2354 =head3 Algebraic inconsistency, for historical reasons
2355
2356 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
2357 operator goes C<outside> of the nested structure; whereas when connecting
2358 several constraints on one column, the C<-and> operator goes
2359 C<inside> the arrayref. Here is an example combining both features :
2360
2361    my @where = (
2362      -and => [a => 1, b => 2],
2363      -or  => [c => 3, d => 4],
2364       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
2365    )
2366
2367 yielding
2368
2369   WHERE ( (    ( a = ? AND b = ? )
2370             OR ( c = ? OR d = ? )
2371             OR ( e LIKE ? AND e LIKE ? ) ) )
2372
2373 This difference in syntax is unfortunate but must be preserved for
2374 historical reasons. So be careful : the two examples below would
2375 seem algebraically equivalent, but they are not
2376
2377   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
2378   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
2379
2380   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
2381   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
2382
2383
2384 =head2 Literal SQL and value type operators
2385
2386 The basic premise of SQL::Abstract is that in WHERE specifications the "left
2387 side" is a column name and the "right side" is a value (normally rendered as
2388 a placeholder). This holds true for both hashrefs and arrayref pairs as you
2389 see in the L</WHERE CLAUSES> examples above. Sometimes it is necessary to
2390 alter this behavior. There are several ways of doing so.
2391
2392 =head3 -ident
2393
2394 This is a virtual operator that signals the string to its right side is an
2395 identifier (a column name) and not a value. For example to compare two
2396 columns you would write:
2397
2398     my %where = (
2399         priority => { '<', 2 },
2400         requestor => { -ident => 'submitter' },
2401     );
2402
2403 which creates:
2404
2405     $stmt = "WHERE priority < ? AND requestor = submitter";
2406     @bind = ('2');
2407
2408 If you are maintaining legacy code you may see a different construct as
2409 described in L</Deprecated usage of Literal SQL>, please use C<-ident> in new
2410 code.
2411
2412 =head3 -value
2413
2414 This is a virtual operator that signals that the construct to its right side
2415 is a value to be passed to DBI. This is for example necessary when you want
2416 to write a where clause against an array (for RDBMS that support such
2417 datatypes). For example:
2418
2419     my %where = (
2420         array => { -value => [1, 2, 3] }
2421     );
2422
2423 will result in:
2424
2425     $stmt = 'WHERE array = ?';
2426     @bind = ([1, 2, 3]);
2427
2428 Note that if you were to simply say:
2429
2430     my %where = (
2431         array => [1, 2, 3]
2432     );
2433
2434 the result would porbably be not what you wanted:
2435
2436     $stmt = 'WHERE array = ? OR array = ? OR array = ?';
2437     @bind = (1, 2, 3);
2438
2439 =head3 Literal SQL
2440
2441 Finally, sometimes only literal SQL will do. To include a random snippet
2442 of SQL verbatim, you specify it as a scalar reference. Consider this only
2443 as a last resort. Usually there is a better way. For example:
2444
2445     my %where = (
2446         priority => { '<', 2 },
2447         requestor => { -in => \'(SELECT name FROM hitmen)' },
2448     );
2449
2450 Would create:
2451
2452     $stmt = "WHERE priority < ? AND requestor IN (SELECT name FROM hitmen)"
2453     @bind = (2);
2454
2455 Note that in this example, you only get one bind parameter back, since
2456 the verbatim SQL is passed as part of the statement.
2457
2458 =head4 CAVEAT
2459
2460   Never use untrusted input as a literal SQL argument - this is a massive
2461   security risk (there is no way to check literal snippets for SQL
2462   injections and other nastyness). If you need to deal with untrusted input
2463   use literal SQL with placeholders as described next.
2464
2465 =head3 Literal SQL with placeholders and bind values (subqueries)
2466
2467 If the literal SQL to be inserted has placeholders and bind values,
2468 use a reference to an arrayref (yes this is a double reference --
2469 not so common, but perfectly legal Perl). For example, to find a date
2470 in Postgres you can use something like this:
2471
2472     my %where = (
2473        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
2474     )
2475
2476 This would create:
2477
2478     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
2479     @bind = ('10');
2480
2481 Note that you must pass the bind values in the same format as they are returned
2482 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
2483 provide the bind values in the C<< [ column_meta => value ] >> format, where
2484 C<column_meta> is an opaque scalar value; most commonly the column name, but
2485 you can use any scalar value (including references and blessed references),
2486 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
2487 to C<columns> the above example will look like:
2488
2489     my %where = (
2490        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
2491     )
2492
2493 Literal SQL is especially useful for nesting parenthesized clauses in the
2494 main SQL query. Here is a first example :
2495
2496   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2497                                100, "foo%");
2498   my %where = (
2499     foo => 1234,
2500     bar => \["IN ($sub_stmt)" => @sub_bind],
2501   );
2502
2503 This yields :
2504
2505   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2506                                              WHERE c2 < ? AND c3 LIKE ?))";
2507   @bind = (1234, 100, "foo%");
2508
2509 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2510 are expressed in the same way. Of course the C<$sub_stmt> and
2511 its associated bind values can be generated through a former call
2512 to C<select()> :
2513
2514   my ($sub_stmt, @sub_bind)
2515      = $sql->select("t1", "c1", {c2 => {"<" => 100},
2516                                  c3 => {-like => "foo%"}});
2517   my %where = (
2518     foo => 1234,
2519     bar => \["> ALL ($sub_stmt)" => @sub_bind],
2520   );
2521
2522 In the examples above, the subquery was used as an operator on a column;
2523 but the same principle also applies for a clause within the main C<%where>
2524 hash, like an EXISTS subquery :
2525
2526   my ($sub_stmt, @sub_bind)
2527      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2528   my %where = ( -and => [
2529     foo   => 1234,
2530     \["EXISTS ($sub_stmt)" => @sub_bind],
2531   ]);
2532
2533 which yields
2534
2535   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2536                                         WHERE c1 = ? AND c2 > t0.c0))";
2537   @bind = (1234, 1);
2538
2539
2540 Observe that the condition on C<c2> in the subquery refers to
2541 column C<t0.c0> of the main query : this is I<not> a bind
2542 value, so we have to express it through a scalar ref.
2543 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2544 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2545 what we wanted here.
2546
2547 Finally, here is an example where a subquery is used
2548 for expressing unary negation:
2549
2550   my ($sub_stmt, @sub_bind)
2551      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2552   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2553   my %where = (
2554         lname  => {like => '%son%'},
2555         \["NOT ($sub_stmt)" => @sub_bind],
2556     );
2557
2558 This yields
2559
2560   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2561   @bind = ('%son%', 10, 20)
2562
2563 =head3 Deprecated usage of Literal SQL
2564
2565 Below are some examples of archaic use of literal SQL. It is shown only as
2566 reference for those who deal with legacy code. Each example has a much
2567 better, cleaner and safer alternative that users should opt for in new code.
2568
2569 =over
2570
2571 =item *
2572
2573     my %where = ( requestor => \'IS NOT NULL' )
2574
2575     $stmt = "WHERE requestor IS NOT NULL"
2576
2577 This used to be the way of generating NULL comparisons, before the handling
2578 of C<undef> got formalized. For new code please use the superior syntax as
2579 described in L</Tests for NULL values>.
2580
2581 =item *
2582
2583     my %where = ( requestor => \'= submitter' )
2584
2585     $stmt = "WHERE requestor = submitter"
2586
2587 This used to be the only way to compare columns. Use the superior L</-ident>
2588 method for all new code. For example an identifier declared in such a way
2589 will be properly quoted if L</quote_char> is properly set, while the legacy
2590 form will remain as supplied.
2591
2592 =item *
2593
2594     my %where = ( is_ready  => \"", completed => { '>', '2012-12-21' } )
2595
2596     $stmt = "WHERE completed > ? AND is_ready"
2597     @bind = ('2012-12-21')
2598
2599 Using an empty string literal used to be the only way to express a boolean.
2600 For all new code please use the much more readable
2601 L<-bool|/Unary operators: bool> operator.
2602
2603 =back
2604
2605 =head2 Conclusion
2606
2607 These pages could go on for a while, since the nesting of the data
2608 structures this module can handle are pretty much unlimited (the
2609 module implements the C<WHERE> expansion as a recursive function
2610 internally). Your best bet is to "play around" with the module a
2611 little to see how the data structures behave, and choose the best
2612 format for your data based on that.
2613
2614 And of course, all the values above will probably be replaced with
2615 variables gotten from forms or the command line. After all, if you
2616 knew everything ahead of time, you wouldn't have to worry about
2617 dynamically-generating SQL and could just hardwire it into your
2618 script.
2619
2620 =head1 ORDER BY CLAUSES
2621
2622 Some functions take an order by clause. This can either be a scalar (just a
2623 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2624 or an array of either of the two previous forms. Examples:
2625
2626                Given            |         Will Generate
2627     ----------------------------------------------------------
2628                                 |
2629     \'colA DESC'                | ORDER BY colA DESC
2630                                 |
2631     'colA'                      | ORDER BY colA
2632                                 |
2633     [qw/colA colB/]             | ORDER BY colA, colB
2634                                 |
2635     {-asc  => 'colA'}           | ORDER BY colA ASC
2636                                 |
2637     {-desc => 'colB'}           | ORDER BY colB DESC
2638                                 |
2639     ['colA', {-asc => 'colB'}]  | ORDER BY colA, colB ASC
2640                                 |
2641     { -asc => [qw/colA colB/] } | ORDER BY colA ASC, colB ASC
2642                                 |
2643     [                           |
2644       { -asc => 'colA' },       | ORDER BY colA ASC, colB DESC,
2645       { -desc => [qw/colB/],    |          colC ASC, colD ASC
2646       { -asc => [qw/colC colD/],|
2647     ]                           |
2648     ===========================================================
2649
2650
2651
2652 =head1 SPECIAL OPERATORS
2653
2654   my $sqlmaker = SQL::Abstract->new(special_ops => [
2655      {
2656       regex => qr/.../,
2657       handler => sub {
2658         my ($self, $field, $op, $arg) = @_;
2659         ...
2660       },
2661      },
2662      {
2663       regex => qr/.../,
2664       handler => 'method_name',
2665      },
2666    ]);
2667
2668 A "special operator" is a SQL syntactic clause that can be
2669 applied to a field, instead of a usual binary operator.
2670 For example :
2671
2672    WHERE field IN (?, ?, ?)
2673    WHERE field BETWEEN ? AND ?
2674    WHERE MATCH(field) AGAINST (?, ?)
2675
2676 Special operators IN and BETWEEN are fairly standard and therefore
2677 are builtin within C<SQL::Abstract> (as the overridable methods
2678 C<_where_field_IN> and C<_where_field_BETWEEN>). For other operators,
2679 like the MATCH .. AGAINST example above which is specific to MySQL,
2680 you can write your own operator handlers - supply a C<special_ops>
2681 argument to the C<new> method. That argument takes an arrayref of
2682 operator definitions; each operator definition is a hashref with two
2683 entries:
2684
2685 =over
2686
2687 =item regex
2688
2689 the regular expression to match the operator
2690
2691 =item handler
2692
2693 Either a coderef or a plain scalar method name. In both cases
2694 the expected return is C<< ($sql, @bind) >>.
2695
2696 When supplied with a method name, it is simply called on the
2697 L<SQL::Abstract/> object as:
2698
2699  $self->$method_name ($field, $op, $arg)
2700
2701  Where:
2702
2703   $op is the part that matched the handler regex
2704   $field is the LHS of the operator
2705   $arg is the RHS
2706
2707 When supplied with a coderef, it is called as:
2708
2709  $coderef->($self, $field, $op, $arg)
2710
2711
2712 =back
2713
2714 For example, here is an implementation
2715 of the MATCH .. AGAINST syntax for MySQL
2716
2717   my $sqlmaker = SQL::Abstract->new(special_ops => [
2718
2719     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2720     {regex => qr/^match$/i,
2721      handler => sub {
2722        my ($self, $field, $op, $arg) = @_;
2723        $arg = [$arg] if not ref $arg;
2724        my $label         = $self->_quote($field);
2725        my ($placeholder) = $self->_convert('?');
2726        my $placeholders  = join ", ", (($placeholder) x @$arg);
2727        my $sql           = $self->_sqlcase('match') . " ($label) "
2728                          . $self->_sqlcase('against') . " ($placeholders) ";
2729        my @bind = $self->_bindtype($field, @$arg);
2730        return ($sql, @bind);
2731        }
2732      },
2733
2734   ]);
2735
2736
2737 =head1 UNARY OPERATORS
2738
2739   my $sqlmaker = SQL::Abstract->new(unary_ops => [
2740      {
2741       regex => qr/.../,
2742       handler => sub {
2743         my ($self, $op, $arg) = @_;
2744         ...
2745       },
2746      },
2747      {
2748       regex => qr/.../,
2749       handler => 'method_name',
2750      },
2751    ]);
2752
2753 A "unary operator" is a SQL syntactic clause that can be
2754 applied to a field - the operator goes before the field
2755
2756 You can write your own operator handlers - supply a C<unary_ops>
2757 argument to the C<new> method. That argument takes an arrayref of
2758 operator definitions; each operator definition is a hashref with two
2759 entries:
2760
2761 =over
2762
2763 =item regex
2764
2765 the regular expression to match the operator
2766
2767 =item handler
2768
2769 Either a coderef or a plain scalar method name. In both cases
2770 the expected return is C<< $sql >>.
2771
2772 When supplied with a method name, it is simply called on the
2773 L<SQL::Abstract/> object as:
2774
2775  $self->$method_name ($op, $arg)
2776
2777  Where:
2778
2779   $op is the part that matched the handler regex
2780   $arg is the RHS or argument of the operator
2781
2782 When supplied with a coderef, it is called as:
2783
2784  $coderef->($self, $op, $arg)
2785
2786
2787 =back
2788
2789
2790 =head1 PERFORMANCE
2791
2792 Thanks to some benchmarking by Mark Stosberg, it turns out that
2793 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2794 I must admit this wasn't an intentional design issue, but it's a
2795 byproduct of the fact that you get to control your C<DBI> handles
2796 yourself.
2797
2798 To maximize performance, use a code snippet like the following:
2799
2800     # prepare a statement handle using the first row
2801     # and then reuse it for the rest of the rows
2802     my($sth, $stmt);
2803     for my $href (@array_of_hashrefs) {
2804         $stmt ||= $sql->insert('table', $href);
2805         $sth  ||= $dbh->prepare($stmt);
2806         $sth->execute($sql->values($href));
2807     }
2808
2809 The reason this works is because the keys in your C<$href> are sorted
2810 internally by B<SQL::Abstract>. Thus, as long as your data retains
2811 the same structure, you only have to generate the SQL the first time
2812 around. On subsequent queries, simply use the C<values> function provided
2813 by this module to return your values in the correct order.
2814
2815 However this depends on the values having the same type - if, for
2816 example, the values of a where clause may either have values
2817 (resulting in sql of the form C<column = ?> with a single bind
2818 value), or alternatively the values might be C<undef> (resulting in
2819 sql of the form C<column IS NULL> with no bind value) then the
2820 caching technique suggested will not work.
2821
2822 =head1 FORMBUILDER
2823
2824 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2825 really like this part (I do, at least). Building up a complex query
2826 can be as simple as the following:
2827
2828     #!/usr/bin/perl
2829
2830     use CGI::FormBuilder;
2831     use SQL::Abstract;
2832
2833     my $form = CGI::FormBuilder->new(...);
2834     my $sql  = SQL::Abstract->new;
2835
2836     if ($form->submitted) {
2837         my $field = $form->field;
2838         my $id = delete $field->{id};
2839         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2840     }
2841
2842 Of course, you would still have to connect using C<DBI> to run the
2843 query, but the point is that if you make your form look like your
2844 table, the actual query script can be extremely simplistic.
2845
2846 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2847 a fast interface to returning and formatting data. I frequently
2848 use these three modules together to write complex database query
2849 apps in under 50 lines.
2850
2851 =head1 REPO
2852
2853 =over
2854
2855 =item * gitweb: L<http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/SQL-Abstract.git>
2856
2857 =item * git: L<git://git.shadowcat.co.uk/dbsrgits/SQL-Abstract.git>
2858
2859 =back
2860
2861 =head1 CHANGES
2862
2863 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2864 Great care has been taken to preserve the I<published> behavior
2865 documented in previous versions in the 1.* family; however,
2866 some features that were previously undocumented, or behaved
2867 differently from the documentation, had to be changed in order
2868 to clarify the semantics. Hence, client code that was relying
2869 on some dark areas of C<SQL::Abstract> v1.*
2870 B<might behave differently> in v1.50.
2871
2872 The main changes are :
2873
2874 =over
2875
2876 =item *
2877
2878 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2879
2880 =item *
2881
2882 support for the { operator => \"..." } construct (to embed literal SQL)
2883
2884 =item *
2885
2886 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2887
2888 =item *
2889
2890 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2891
2892 =item *
2893
2894 defensive programming : check arguments
2895
2896 =item *
2897
2898 fixed bug with global logic, which was previously implemented
2899 through global variables yielding side-effects. Prior versions would
2900 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2901 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2902 Now this is interpreted
2903 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2904
2905
2906 =item *
2907
2908 fixed semantics of  _bindtype on array args
2909
2910 =item *
2911
2912 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2913 we just avoid shifting arrays within that tree.
2914
2915 =item *
2916
2917 dropped the C<_modlogic> function
2918
2919 =back
2920
2921 =head1 ACKNOWLEDGEMENTS
2922
2923 There are a number of individuals that have really helped out with
2924 this module. Unfortunately, most of them submitted bugs via CPAN
2925 so I have no idea who they are! But the people I do know are:
2926
2927     Ash Berlin (order_by hash term support)
2928     Matt Trout (DBIx::Class support)
2929     Mark Stosberg (benchmarking)
2930     Chas Owens (initial "IN" operator support)
2931     Philip Collins (per-field SQL functions)
2932     Eric Kolve (hashref "AND" support)
2933     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2934     Dan Kubb (support for "quote_char" and "name_sep")
2935     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2936     Laurent Dami (internal refactoring, extensible list of special operators, literal SQL)
2937     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2938     Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2939     Oliver Charles (support for "RETURNING" after "INSERT")
2940
2941 Thanks!
2942
2943 =head1 SEE ALSO
2944
2945 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2946
2947 =head1 AUTHOR
2948
2949 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2950
2951 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2952
2953 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2954 While not an official support venue, C<DBIx::Class> makes heavy use of
2955 C<SQL::Abstract>, and as such list members there are very familiar with
2956 how to create queries.
2957
2958 =head1 LICENSE
2959
2960 This module is free software; you may copy this under the same
2961 terms as perl itself (either the GNU General Public License or
2962 the Artistic License)
2963
2964 =cut
2965