lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use strict;
   9 use warnings;
  10 use Carp ();
  11 use List::Util ();
  12 use Scalar::Util ();
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.74';
  19
  20 # This would confuse some packagers
  21 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^ (?: not \s )? between $/ix, handler => '_where_field_BETWEEN'},
  29   {regex => qr/^ (?: not \s )? in      $/ix, handler => '_where_field_IN'},
  30   {regex => qr/^ ident                 $/ix, handler => '_where_op_IDENT'},
  31   {regex => qr/^ value                 $/ix, handler => '_where_op_VALUE'},
  32 );
  33
  34 # unaryish operators - key maps to handler
  35 my @BUILTIN_UNARY_OPS = (
  36   # the digits are backcompat stuff
  37   { regex => qr/^ and  (?: [_\s]? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  38   { regex => qr/^ or   (?: [_\s]? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  39   { regex => qr/^ nest (?: [_\s]? \d+ )? $/xi, handler => '_where_op_NEST' },
  40   { regex => qr/^ (?: not \s )? bool     $/xi, handler => '_where_op_BOOL' },
  41   { regex => qr/^ ident                  $/xi, handler => '_where_op_IDENT' },
  42   { regex => qr/^ value                  $/ix, handler => '_where_op_VALUE' },
  43 );
  44
  45 #======================================================================
  46 # DEBUGGING AND ERROR REPORTING
  47 #======================================================================
  48
  49 sub _debug {
  50   return unless $_[0]->{debug}; shift; # a little faster
  51   my $func = (caller(1))[3];
  52   warn "[$func] ", @_, "\n";
  53 }
  54
  55 sub belch (@) {
  56   my($func) = (caller(1))[3];
  57   Carp::carp "[$func] Warning: ", @_;
  58 }
  59
  60 sub puke (@) {
  61   my($func) = (caller(1))[3];
  62   Carp::croak "[$func] Fatal: ", @_;
  63 }
  64
  65
  66 #======================================================================
  67 # NEW
  68 #======================================================================
  69
  70 sub new {
  71   my $self = shift;
  72   my $class = ref($self) || $self;
  73   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  74
  75   # choose our case by keeping an option around
  76   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  77
  78   # default logic for interpreting arrayrefs
  79   $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
  80
  81   # how to return bind vars
  82   # LDNOTE: changed nwiger code : why this 'delete' ??
  83   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  84   $opt{bindtype} ||= 'normal';
  85
  86   # default comparison is "=", but can be overridden
  87   $opt{cmp} ||= '=';
  88
  89   # try to recognize which are the 'equality' and 'inequality' ops
  90   # (temporary quickfix, should go through a more seasoned API)
  91   $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  92   $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  93
  94   # SQL booleans
  95   $opt{sqltrue}  ||= '1=1';
  96   $opt{sqlfalse} ||= '0=1';
  97
  98   # special operators
  99   $opt{special_ops} ||= [];
 100   # regexes are applied in order, thus push after user-defines
 101   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
 102
 103   # unary operators
 104   $opt{unary_ops} ||= [];
 105   push @{$opt{unary_ops}}, @BUILTIN_UNARY_OPS;
 106
 107   # rudimentary sanity-check for user supplied bits treated as functions/operators
 108   # If a purported  function matches this regular expression, an exception is thrown.
 109   # Literal SQL is *NOT* subject to this check, only functions (and column names
 110   # when quoting is not in effect)
 111
 112   # FIXME
 113   # need to guard against ()'s in column names too, but this will break tons of
 114   # hacks... ideas anyone?
 115   $opt{injection_guard} ||= qr/
 116     \;
 117       |
 118     ^ \s* go \s
 119   /xmi;
 120
 121   return bless \%opt, $class;
 122 }
 123
 124
 125 sub _assert_pass_injection_guard {
 126   if ($_[1] =~ $_[0]->{injection_guard}) {
 127     my $class = ref $_[0];
 128     puke "Possible SQL injection attempt '$_[1]'. If this is indeed a part of the "
 129      . "desired SQL use literal SQL ( \'...' or \[ '...' ] ) or supply your own "
 130      . "{injection_guard} attribute to ${class}->new()"
 131   }
 132 }
 133
 134
 135 #======================================================================
 136 # INSERT methods
 137 #======================================================================
 138
 139 sub insert {
 140   my $self    = shift;
 141   my $table   = $self->_table(shift);
 142   my $data    = shift || return;
 143   my $options = shift;
 144
 145   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 146   my ($sql, @bind) = $self->$method($data);
 147   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 148
 149   if ($options->{returning}) {
 150     my ($s, @b) = $self->_insert_returning ($options);
 151     $sql .= $s;
 152     push @bind, @b;
 153   }
 154
 155   return wantarray ? ($sql, @bind) : $sql;
 156 }
 157
 158 sub _insert_returning {
 159   my ($self, $options) = @_;
 160
 161   my $f = $options->{returning};
 162
 163   my $fieldlist = $self->_SWITCH_refkind($f, {
 164     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$f;},
 165     SCALAR       => sub {$self->_quote($f)},
 166     SCALARREF    => sub {$$f},
 167   });
 168   return $self->_sqlcase(' returning ') . $fieldlist;
 169 }
 170
 171 sub _insert_HASHREF { # explicit list of fields and then values
 172   my ($self, $data) = @_;
 173
 174   my @fields = sort keys %$data;
 175
 176   my ($sql, @bind) = $self->_insert_values($data);
 177
 178   # assemble SQL
 179   $_ = $self->_quote($_) foreach @fields;
 180   $sql = "( ".join(", ", @fields).") ".$sql;
 181
 182   return ($sql, @bind);
 183 }
 184
 185 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 186   my ($self, $data) = @_;
 187
 188   # no names (arrayref) so can't generate bindtype
 189   $self->{bindtype} ne 'columns'
 190     or belch "can't do 'columns' bindtype when called with arrayref";
 191
 192   # fold the list of values into a hash of column name - value pairs
 193   # (where the column names are artificially generated, and their
 194   # lexicographical ordering keep the ordering of the original list)
 195   my $i = "a";  # incremented values will be in lexicographical order
 196   my $data_in_hash = { map { ($i++ => $_) } @$data };
 197
 198   return $self->_insert_values($data_in_hash);
 199 }
 200
 201 sub _insert_ARRAYREFREF { # literal SQL with bind
 202   my ($self, $data) = @_;
 203
 204   my ($sql, @bind) = @${$data};
 205   $self->_assert_bindval_matches_bindtype(@bind);
 206
 207   return ($sql, @bind);
 208 }
 209
 210
 211 sub _insert_SCALARREF { # literal SQL without bind
 212   my ($self, $data) = @_;
 213
 214   return ($$data);
 215 }
 216
 217 sub _insert_values {
 218   my ($self, $data) = @_;
 219
 220   my (@values, @all_bind);
 221   foreach my $column (sort keys %$data) {
 222     my $v = $data->{$column};
 223
 224     $self->_SWITCH_refkind($v, {
 225
 226       ARRAYREF => sub {
 227         if ($self->{array_datatypes}) { # if array datatype are activated
 228           push @values, '?';
 229           push @all_bind, $self->_bindtype($column, $v);
 230         }
 231         else {                          # else literal SQL with bind
 232           my ($sql, @bind) = @$v;
 233           $self->_assert_bindval_matches_bindtype(@bind);
 234           push @values, $sql;
 235           push @all_bind, @bind;
 236         }
 237       },
 238
 239       ARRAYREFREF => sub { # literal SQL with bind
 240         my ($sql, @bind) = @${$v};
 241         $self->_assert_bindval_matches_bindtype(@bind);
 242         push @values, $sql;
 243         push @all_bind, @bind;
 244       },
 245
 246       # THINK : anything useful to do with a HASHREF ?
 247       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 248         #TODO in SQLA >= 2.0 it will die instead
 249         belch "HASH ref as bind value in insert is not supported";
 250         push @values, '?';
 251         push @all_bind, $self->_bindtype($column, $v);
 252       },
 253
 254       SCALARREF => sub {  # literal SQL without bind
 255         push @values, $$v;
 256       },
 257
 258       SCALAR_or_UNDEF => sub {
 259         push @values, '?';
 260         push @all_bind, $self->_bindtype($column, $v);
 261       },
 262
 263      });
 264
 265   }
 266
 267   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 268   return ($sql, @all_bind);
 269 }
 270
 271
 272
 273 #======================================================================
 274 # UPDATE methods
 275 #======================================================================
 276
 277
 278 sub update {
 279   my $self  = shift;
 280   my $table = $self->_table(shift);
 281   my $data  = shift || return;
 282   my $where = shift;
 283
 284   # first build the 'SET' part of the sql statement
 285   my (@set, @all_bind);
 286   puke "Unsupported data type specified to \$sql->update"
 287     unless ref $data eq 'HASH';
 288
 289   for my $k (sort keys %$data) {
 290     my $v = $data->{$k};
 291     my $r = ref $v;
 292     my $label = $self->_quote($k);
 293
 294     $self->_SWITCH_refkind($v, {
 295       ARRAYREF => sub {
 296         if ($self->{array_datatypes}) { # array datatype
 297           push @set, "$label = ?";
 298           push @all_bind, $self->_bindtype($k, $v);
 299         }
 300         else {                          # literal SQL with bind
 301           my ($sql, @bind) = @$v;
 302           $self->_assert_bindval_matches_bindtype(@bind);
 303           push @set, "$label = $sql";
 304           push @all_bind, @bind;
 305         }
 306       },
 307       ARRAYREFREF => sub { # literal SQL with bind
 308         my ($sql, @bind) = @${$v};
 309         $self->_assert_bindval_matches_bindtype(@bind);
 310         push @set, "$label = $sql";
 311         push @all_bind, @bind;
 312       },
 313       SCALARREF => sub {  # literal SQL without bind
 314         push @set, "$label = $$v";
 315       },
 316       HASHREF => sub {
 317         my ($op, $arg, @rest) = %$v;
 318
 319         puke 'Operator calls in update must be in the form { -op => $arg }'
 320           if (@rest or not $op =~ /^\-(.+)/);
 321
 322         local $self->{_nested_func_lhs} = $k;
 323         my ($sql, @bind) = $self->_where_unary_op ($1, $arg);
 324
 325         push @set, "$label = $sql";
 326         push @all_bind, @bind;
 327       },
 328       SCALAR_or_UNDEF => sub {
 329         push @set, "$label = ?";
 330         push @all_bind, $self->_bindtype($k, $v);
 331       },
 332     });
 333   }
 334
 335   # generate sql
 336   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 337           . join ', ', @set;
 338
 339   if ($where) {
 340     my($where_sql, @where_bind) = $self->where($where);
 341     $sql .= $where_sql;
 342     push @all_bind, @where_bind;
 343   }
 344
 345   return wantarray ? ($sql, @all_bind) : $sql;
 346 }
 347
 348
 349
 350
 351 #======================================================================
 352 # SELECT
 353 #======================================================================
 354
 355
 356 sub select {
 357   my $self   = shift;
 358   my $table  = $self->_table(shift);
 359   my $fields = shift || '*';
 360   my $where  = shift;
 361   my $order  = shift;
 362
 363   my($where_sql, @bind) = $self->where($where, $order);
 364
 365   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 366                                    : $fields;
 367   my $sql = join(' ', $self->_sqlcase('select'), $f,
 368                       $self->_sqlcase('from'),   $table)
 369           . $where_sql;
 370
 371   return wantarray ? ($sql, @bind) : $sql;
 372 }
 373
 374 #======================================================================
 375 # DELETE
 376 #======================================================================
 377
 378
 379 sub delete {
 380   my $self  = shift;
 381   my $table = $self->_table(shift);
 382   my $where = shift;
 383
 384
 385   my($where_sql, @bind) = $self->where($where);
 386   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 387
 388   return wantarray ? ($sql, @bind) : $sql;
 389 }
 390
 391
 392 #======================================================================
 393 # WHERE: entry point
 394 #======================================================================
 395
 396
 397
 398 # Finally, a separate routine just to handle WHERE clauses
 399 sub where {
 400   my ($self, $where, $order) = @_;
 401
 402   # where ?
 403   my ($sql, @bind) = $self->_recurse_where($where);
 404   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 405
 406   # order by?
 407   if ($order) {
 408     $sql .= $self->_order_by($order);
 409   }
 410
 411   return wantarray ? ($sql, @bind) : $sql;
 412 }
 413
 414
 415 sub _recurse_where {
 416   my ($self, $where, $logic) = @_;
 417
 418   # dispatch on appropriate method according to refkind of $where
 419   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 420
 421   my ($sql, @bind) =  $self->$method($where, $logic);
 422
 423   # DBIx::Class directly calls _recurse_where in scalar context, so
 424   # we must implement it, even if not in the official API
 425   return wantarray ? ($sql, @bind) : $sql;
 426 }
 427
 428
 429
 430 #======================================================================
 431 # WHERE: top-level ARRAYREF
 432 #======================================================================
 433
 434
 435 sub _where_ARRAYREF {
 436   my ($self, $where, $logic) = @_;
 437
 438   $logic = uc($logic || $self->{logic});
 439   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 440
 441   my @clauses = @$where;
 442
 443   my (@sql_clauses, @all_bind);
 444   # need to use while() so can shift() for pairs
 445   while (my $el = shift @clauses) {
 446
 447     # switch according to kind of $el and get corresponding ($sql, @bind)
 448     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 449
 450       # skip empty elements, otherwise get invalid trailing AND stuff
 451       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 452
 453       ARRAYREFREF => sub {
 454         my ($s, @b) = @$$el;
 455         $self->_assert_bindval_matches_bindtype(@b);
 456         ($s, @b);
 457       },
 458
 459       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 460            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 461            # side-effect: the first hashref within an array would change
 462            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 463            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 464            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 465
 466       SCALARREF => sub { ($$el);                                 },
 467
 468       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 469                         $self->_recurse_where({$el => shift(@clauses)})},
 470
 471       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 472     });
 473
 474     if ($sql) {
 475       push @sql_clauses, $sql;
 476       push @all_bind, @bind;
 477     }
 478   }
 479
 480   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 481 }
 482
 483 #======================================================================
 484 # WHERE: top-level ARRAYREFREF
 485 #======================================================================
 486
 487 sub _where_ARRAYREFREF {
 488     my ($self, $where) = @_;
 489     my ($sql, @bind) = @$$where;
 490     $self->_assert_bindval_matches_bindtype(@bind);
 491     return ($sql, @bind);
 492 }
 493
 494 #======================================================================
 495 # WHERE: top-level HASHREF
 496 #======================================================================
 497
 498 sub _where_HASHREF {
 499   my ($self, $where) = @_;
 500   my (@sql_clauses, @all_bind);
 501
 502   for my $k (sort keys %$where) {
 503     my $v = $where->{$k};
 504
 505     # ($k => $v) is either a special unary op or a regular hashpair
 506     my ($sql, @bind) = do {
 507       if ($k =~ /^-./) {
 508         # put the operator in canonical form
 509         my $op = $k;
 510         $op = substr $op, 1;  # remove initial dash
 511         $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 512         $op =~ s/\s+/ /g;     # compress whitespace
 513
 514         # so that -not_foo works correctly
 515         $op =~ s/^not_/NOT /i;
 516
 517         $self->_debug("Unary OP(-$op) within hashref, recursing...");
 518         my ($s, @b) = $self->_where_unary_op ($op, $v);
 519
 520         # top level vs nested
 521         # we assume that handled unary ops will take care of their ()s
 522         $s = "($s)" unless (
 523           List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}}
 524             or
 525           defined($self->{_nested_func_lhs}) && ($self->{_nested_func_lhs} eq $k)
 526         );
 527         ($s, @b);
 528       }
 529       else {
 530         my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 531         $self->$method($k, $v);
 532       }
 533     };
 534
 535     push @sql_clauses, $sql;
 536     push @all_bind, @bind;
 537   }
 538
 539   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 540 }
 541
 542 sub _where_unary_op {
 543   my ($self, $op, $rhs) = @_;
 544
 545   if (my $op_entry = List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}}) {
 546     my $handler = $op_entry->{handler};
 547
 548     if (not ref $handler) {
 549       if ($op =~ s/ [_\s]? \d+ $//x ) {
 550         belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
 551             . "You probably wanted ...-and => [ -$op => COND1, -$op => COND2 ... ]";
 552       }
 553       return $self->$handler ($op, $rhs);
 554     }
 555     elsif (ref $handler eq 'CODE') {
 556       return $handler->($self, $op, $rhs);
 557     }
 558     else {
 559       puke "Illegal handler for operator $op - expecting a method name or a coderef";
 560     }
 561   }
 562
 563   $self->_debug("Generic unary OP: $op - recursing as function");
 564
 565   $self->_assert_pass_injection_guard($op);
 566
 567   my ($sql, @bind) = $self->_SWITCH_refkind ($rhs, {
 568     SCALAR =>   sub {
 569       puke "Illegal use of top-level '$op'"
 570         unless $self->{_nested_func_lhs};
 571
 572       return (
 573         $self->_convert('?'),
 574         $self->_bindtype($self->{_nested_func_lhs}, $rhs)
 575       );
 576     },
 577     FALLBACK => sub {
 578       $self->_recurse_where ($rhs)
 579     },
 580   });
 581
 582   $sql = sprintf ('%s %s',
 583     $self->_sqlcase($op),
 584     $sql,
 585   );
 586
 587   return ($sql, @bind);
 588 }
 589
 590 sub _where_op_ANDOR {
 591   my ($self, $op, $v) = @_;
 592
 593   $self->_SWITCH_refkind($v, {
 594     ARRAYREF => sub {
 595       return $self->_where_ARRAYREF($v, $op);
 596     },
 597
 598     HASHREF => sub {
 599       return ( $op =~ /^or/i )
 600         ? $self->_where_ARRAYREF( [ map { $_ => $v->{$_} } ( sort keys %$v ) ], $op )
 601         : $self->_where_HASHREF($v);
 602     },
 603
 604     SCALARREF  => sub {
 605       puke "-$op => \\\$scalar makes little sense, use " .
 606         ($op =~ /^or/i
 607           ? '[ \$scalar, \%rest_of_conditions ] instead'
 608           : '-and => [ \$scalar, \%rest_of_conditions ] instead'
 609         );
 610     },
 611
 612     ARRAYREFREF => sub {
 613       puke "-$op => \\[...] makes little sense, use " .
 614         ($op =~ /^or/i
 615           ? '[ \[...], \%rest_of_conditions ] instead'
 616           : '-and => [ \[...], \%rest_of_conditions ] instead'
 617         );
 618     },
 619
 620     SCALAR => sub { # permissively interpreted as SQL
 621       puke "-$op => \$value makes little sense, use -bool => \$value instead";
 622     },
 623
 624     UNDEF => sub {
 625       puke "-$op => undef not supported";
 626     },
 627    });
 628 }
 629
 630 sub _where_op_NEST {
 631   my ($self, $op, $v) = @_;
 632
 633   $self->_SWITCH_refkind($v, {
 634
 635     SCALAR => sub { # permissively interpreted as SQL
 636       belch "literal SQL should be -nest => \\'scalar' "
 637           . "instead of -nest => 'scalar' ";
 638       return ($v);
 639     },
 640
 641     UNDEF => sub {
 642       puke "-$op => undef not supported";
 643     },
 644
 645     FALLBACK => sub {
 646       $self->_recurse_where ($v);
 647     },
 648
 649    });
 650 }
 651
 652
 653 sub _where_op_BOOL {
 654   my ($self, $op, $v) = @_;
 655
 656   my ($s, @b) = $self->_SWITCH_refkind($v, {
 657     SCALAR => sub { # interpreted as SQL column
 658       $self->_convert($self->_quote($v));
 659     },
 660
 661     UNDEF => sub {
 662       puke "-$op => undef not supported";
 663     },
 664
 665     FALLBACK => sub {
 666       $self->_recurse_where ($v);
 667     },
 668   });
 669
 670   $s = "(NOT $s)" if $op =~ /^not/i;
 671   ($s, @b);
 672 }
 673
 674
 675 sub _where_op_IDENT {
 676   my $self = shift;
 677   my ($op, $rhs) = splice @_, -2;
 678   if (ref $rhs) {
 679     puke "-$op takes a single scalar argument (a quotable identifier)";
 680   }
 681
 682   # in case we are called as a top level special op (no '=')
 683   my $lhs = shift;
 684
 685   $_ = $self->_convert($self->_quote($_)) for ($lhs, $rhs);
 686
 687   return $lhs
 688     ? "$lhs = $rhs"
 689     : $rhs
 690   ;
 691 }
 692
 693 sub _where_op_VALUE {
 694   my $self = shift;
 695   my ($op, $rhs) = splice @_, -2;
 696
 697   # in case we are called as a top level special op (no '=')
 698   my $lhs = shift;
 699
 700   my @bind =
 701     $self->_bindtype (
 702       ($lhs || $self->{_nested_func_lhs}),
 703       $rhs,
 704     )
 705   ;
 706
 707   return $lhs
 708     ? (
 709       $self->_convert($self->_quote($lhs)) . ' = ' . $self->_convert('?'),
 710       @bind
 711     )
 712     : (
 713       $self->_convert('?'),
 714       @bind,
 715     )
 716   ;
 717 }
 718
 719 sub _where_hashpair_ARRAYREF {
 720   my ($self, $k, $v) = @_;
 721
 722   if( @$v ) {
 723     my @v = @$v; # need copy because of shift below
 724     $self->_debug("ARRAY($k) means distribute over elements");
 725
 726     # put apart first element if it is an operator (-and, -or)
 727     my $op = (
 728        (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
 729          ? shift @v
 730          : ''
 731     );
 732     my @distributed = map { {$k =>  $_} } @v;
 733
 734     if ($op) {
 735       $self->_debug("OP($op) reinjected into the distributed array");
 736       unshift @distributed, $op;
 737     }
 738
 739     my $logic = $op ? substr($op, 1) : '';
 740
 741     return $self->_recurse_where(\@distributed, $logic);
 742   }
 743   else {
 744     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 745     $self->_debug("empty ARRAY($k) means 0=1");
 746     return ($self->{sqlfalse});
 747   }
 748 }
 749
 750 sub _where_hashpair_HASHREF {
 751   my ($self, $k, $v, $logic) = @_;
 752   $logic ||= 'and';
 753
 754   local $self->{_nested_func_lhs} = $self->{_nested_func_lhs};
 755
 756   my ($all_sql, @all_bind);
 757
 758   for my $orig_op (sort keys %$v) {
 759     my $val = $v->{$orig_op};
 760
 761     # put the operator in canonical form
 762     my $op = $orig_op;
 763
 764     # FIXME - we need to phase out dash-less ops
 765     $op =~ s/^-//;        # remove possible initial dash
 766     $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 767     $op =~ s/\s+/ /g;     # compress whitespace
 768
 769     $self->_assert_pass_injection_guard($op);
 770
 771     # so that -not_foo works correctly
 772     $op =~ s/^not_/NOT /i;
 773
 774     my ($sql, @bind);
 775
 776     # CASE: col-value logic modifiers
 777     if ( $orig_op =~ /^ \- (and|or) $/xi ) {
 778       ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $1);
 779     }
 780     # CASE: special operators like -in or -between
 781     elsif ( my $special_op = List::Util::first {$op =~ $_->{regex}} @{$self->{special_ops}} ) {
 782       my $handler = $special_op->{handler};
 783       if (! $handler) {
 784         puke "No handler supplied for special operator $orig_op";
 785       }
 786       elsif (not ref $handler) {
 787         ($sql, @bind) = $self->$handler ($k, $op, $val);
 788       }
 789       elsif (ref $handler eq 'CODE') {
 790         ($sql, @bind) = $handler->($self, $k, $op, $val);
 791       }
 792       else {
 793         puke "Illegal handler for special operator $orig_op - expecting a method name or a coderef";
 794       }
 795     }
 796     else {
 797       $self->_SWITCH_refkind($val, {
 798
 799         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 800           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 801         },
 802
 803         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 804           my ($sub_sql, @sub_bind) = @$$val;
 805           $self->_assert_bindval_matches_bindtype(@sub_bind);
 806           $sql  = join ' ', $self->_convert($self->_quote($k)),
 807                             $self->_sqlcase($op),
 808                             $sub_sql;
 809           @bind = @sub_bind;
 810         },
 811
 812         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 813           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 814                    ($op =~ $self->{inequality_op}) ? 'is not' :
 815                puke "unexpected operator '$orig_op' with undef operand";
 816           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 817         },
 818
 819         FALLBACK => sub {       # CASE: col => {op/func => $stuff}
 820
 821           # retain for proper column type bind
 822           $self->{_nested_func_lhs} ||= $k;
 823
 824           ($sql, @bind) = $self->_where_unary_op ($op, $val);
 825
 826           $sql = join (' ',
 827             $self->_convert($self->_quote($k)),
 828             $self->{_nested_func_lhs} eq $k ? $sql : "($sql)",  # top level vs nested
 829           );
 830         },
 831       });
 832     }
 833
 834     ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
 835     push @all_bind, @bind;
 836   }
 837   return ($all_sql, @all_bind);
 838 }
 839
 840
 841
 842 sub _where_field_op_ARRAYREF {
 843   my ($self, $k, $op, $vals) = @_;
 844
 845   my @vals = @$vals;  #always work on a copy
 846
 847   if(@vals) {
 848     $self->_debug(sprintf '%s means multiple elements: [ %s ]',
 849       $vals,
 850       join (', ', map { defined $_ ? "'$_'" : 'NULL' } @vals ),
 851     );
 852
 853     # see if the first element is an -and/-or op
 854     my $logic;
 855     if (defined $vals[0] && $vals[0] =~ /^ - ( AND|OR ) $/ix) {
 856       $logic = uc $1;
 857       shift @vals;
 858     }
 859
 860     # distribute $op over each remaining member of @vals, append logic if exists
 861     return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 862
 863     # LDNOTE : had planned to change the distribution logic when
 864     # $op =~ $self->{inequality_op}, because of Morgan laws :
 865     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 866     # WHERE field != 22 OR  field != 33 : the user probably means
 867     # WHERE field != 22 AND field != 33.
 868     # To do this, replace the above to roughly :
 869     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 870     # return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 871
 872   }
 873   else {
 874     # try to DWIM on equality operators
 875     # LDNOTE : not 100% sure this is the correct thing to do ...
 876     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 877     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 878
 879     # otherwise
 880     puke "operator '$op' applied on an empty array (field '$k')";
 881   }
 882 }
 883
 884
 885 sub _where_hashpair_SCALARREF {
 886   my ($self, $k, $v) = @_;
 887   $self->_debug("SCALAR($k) means literal SQL: $$v");
 888   my $sql = $self->_quote($k) . " " . $$v;
 889   return ($sql);
 890 }
 891
 892 # literal SQL with bind
 893 sub _where_hashpair_ARRAYREFREF {
 894   my ($self, $k, $v) = @_;
 895   $self->_debug("REF($k) means literal SQL: @${$v}");
 896   my ($sql, @bind) = @$$v;
 897   $self->_assert_bindval_matches_bindtype(@bind);
 898   $sql  = $self->_quote($k) . " " . $sql;
 899   return ($sql, @bind );
 900 }
 901
 902 # literal SQL without bind
 903 sub _where_hashpair_SCALAR {
 904   my ($self, $k, $v) = @_;
 905   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 906   my $sql = join ' ', $self->_convert($self->_quote($k)),
 907                       $self->_sqlcase($self->{cmp}),
 908                       $self->_convert('?');
 909   my @bind =  $self->_bindtype($k, $v);
 910   return ( $sql, @bind);
 911 }
 912
 913
 914 sub _where_hashpair_UNDEF {
 915   my ($self, $k, $v) = @_;
 916   $self->_debug("UNDEF($k) means IS NULL");
 917   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 918   return ($sql);
 919 }
 920
 921 #======================================================================
 922 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 923 #======================================================================
 924
 925
 926 sub _where_SCALARREF {
 927   my ($self, $where) = @_;
 928
 929   # literal sql
 930   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 931   return ($$where);
 932 }
 933
 934
 935 sub _where_SCALAR {
 936   my ($self, $where) = @_;
 937
 938   # literal sql
 939   $self->_debug("NOREF(*top) means literal SQL: $where");
 940   return ($where);
 941 }
 942
 943
 944 sub _where_UNDEF {
 945   my ($self) = @_;
 946   return ();
 947 }
 948
 949
 950 #======================================================================
 951 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 952 #======================================================================
 953
 954
 955 sub _where_field_BETWEEN {
 956   my ($self, $k, $op, $vals) = @_;
 957
 958   my ($label, $and, $placeholder);
 959   $label       = $self->_convert($self->_quote($k));
 960   $and         = ' ' . $self->_sqlcase('and') . ' ';
 961   $placeholder = $self->_convert('?');
 962   $op               = $self->_sqlcase($op);
 963
 964   my ($clause, @bind) = $self->_SWITCH_refkind($vals, {
 965     ARRAYREFREF => sub {
 966       my ($s, @b) = @$$vals;
 967       $self->_assert_bindval_matches_bindtype(@b);
 968       ($s, @b);
 969     },
 970     SCALARREF => sub {
 971       return $$vals;
 972     },
 973     ARRAYREF => sub {
 974       puke "special op 'between' accepts an arrayref with exactly two values"
 975         if @$vals != 2;
 976
 977       my (@all_sql, @all_bind);
 978       foreach my $val (@$vals) {
 979         my ($sql, @bind) = $self->_SWITCH_refkind($val, {
 980            SCALAR => sub {
 981              return ($placeholder, $self->_bindtype($k, $val) );
 982            },
 983            SCALARREF => sub {
 984              return $$val;
 985            },
 986            ARRAYREFREF => sub {
 987              my ($sql, @bind) = @$$val;
 988              $self->_assert_bindval_matches_bindtype(@bind);
 989              return ($sql, @bind);
 990            },
 991            HASHREF => sub {
 992              my ($func, $arg, @rest) = %$val;
 993              puke ("Only simple { -func => arg } functions accepted as sub-arguments to BETWEEN")
 994                if (@rest or $func !~ /^ \- (.+)/x);
 995              local $self->{_nested_func_lhs} = $k;
 996              $self->_where_unary_op ($1 => $arg);
 997            }
 998         });
 999         push @all_sql, $sql;
1000         push @all_bind, @bind;
1001       }
1002
1003       return (
1004         (join $and, @all_sql),
1005         @all_bind
1006       );
1007     },
1008     FALLBACK => sub {
1009       puke "special op 'between' accepts an arrayref with two values, or a single literal scalarref/arrayref-ref";
1010     },
1011   });
1012
1013   my $sql = "( $label $op $clause )";
1014   return ($sql, @bind)
1015 }
1016
1017
1018 sub _where_field_IN {
1019   my ($self, $k, $op, $vals) = @_;
1020
1021   # backwards compatibility : if scalar, force into an arrayref
1022   $vals = [$vals] if defined $vals && ! ref $vals;
1023
1024   my ($label)       = $self->_convert($self->_quote($k));
1025   my ($placeholder) = $self->_convert('?');
1026   $op               = $self->_sqlcase($op);
1027
1028   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
1029     ARRAYREF => sub {     # list of choices
1030       if (@$vals) { # nonempty list
1031         my (@all_sql, @all_bind);
1032
1033         for my $val (@$vals) {
1034           my ($sql, @bind) = $self->_SWITCH_refkind($val, {
1035             SCALAR => sub {
1036               return ($placeholder, $val);
1037             },
1038             SCALARREF => sub {
1039               return $$val;
1040             },
1041             ARRAYREFREF => sub {
1042               my ($sql, @bind) = @$$val;
1043               $self->_assert_bindval_matches_bindtype(@bind);
1044               return ($sql, @bind);
1045             },
1046             HASHREF => sub {
1047               my ($func, $arg, @rest) = %$val;
1048               puke ("Only simple { -func => arg } functions accepted as sub-arguments to IN")
1049                 if (@rest or $func !~ /^ \- (.+)/x);
1050               local $self->{_nested_func_lhs} = $k;
1051               $self->_where_unary_op ($1 => $arg);
1052             },
1053             UNDEF => sub {
1054               puke(
1055                 'SQL::Abstract before v1.75 used to generate incorrect SQL when the '
1056               . "-$op operator was given an undef-containing list: !!!AUDIT YOUR CODE "
1057               . 'AND DATA!!! (the upcoming Data::Query-based version of SQL::Abstract '
1058               . 'will emit the logically correct SQL instead of raising this exception)'
1059               );
1060             },
1061           });
1062           push @all_sql, $sql;
1063           push @all_bind, @bind;
1064         }
1065
1066         return (
1067           sprintf ('%s %s ( %s )',
1068             $label,
1069             $op,
1070             join (', ', @all_sql)
1071           ),
1072           $self->_bindtype($k, @all_bind),
1073         );
1074       }
1075       else { # empty list : some databases won't understand "IN ()", so DWIM
1076         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
1077         return ($sql);
1078       }
1079     },
1080
1081     SCALARREF => sub {  # literal SQL
1082       my $sql = $self->_open_outer_paren ($$vals);
1083       return ("$label $op ( $sql )");
1084     },
1085     ARRAYREFREF => sub {  # literal SQL with bind
1086       my ($sql, @bind) = @$$vals;
1087       $self->_assert_bindval_matches_bindtype(@bind);
1088       $sql = $self->_open_outer_paren ($sql);
1089       return ("$label $op ( $sql )", @bind);
1090     },
1091
1092     UNDEF => sub {
1093       puke "Argument passed to the '$op' operator can not be undefined";
1094     },
1095
1096     FALLBACK => sub {
1097       puke "special op $op requires an arrayref (or scalarref/arrayref-ref)";
1098     },
1099   });
1100
1101   return ($sql, @bind);
1102 }
1103
1104 # Some databases (SQLite) treat col IN (1, 2) different from
1105 # col IN ( (1, 2) ). Use this to strip all outer parens while
1106 # adding them back in the corresponding method
1107 sub _open_outer_paren {
1108   my ($self, $sql) = @_;
1109   $sql = $1 while $sql =~ /^ \s* \( (.*) \) \s* $/xs;
1110   return $sql;
1111 }
1112
1113
1114 #======================================================================
1115 # ORDER BY
1116 #======================================================================
1117
1118 sub _order_by {
1119   my ($self, $arg) = @_;
1120
1121   my (@sql, @bind);
1122   for my $c ($self->_order_by_chunks ($arg) ) {
1123     $self->_SWITCH_refkind ($c, {
1124       SCALAR => sub { push @sql, $c },
1125       ARRAYREF => sub { push @sql, shift @$c; push @bind, @$c },
1126     });
1127   }
1128
1129   my $sql = @sql
1130     ? sprintf ('%s %s',
1131         $self->_sqlcase(' order by'),
1132         join (', ', @sql)
1133       )
1134     : ''
1135   ;
1136
1137   return wantarray ? ($sql, @bind) : $sql;
1138 }
1139
1140 sub _order_by_chunks {
1141   my ($self, $arg) = @_;
1142
1143   return $self->_SWITCH_refkind($arg, {
1144
1145     ARRAYREF => sub {
1146       map { $self->_order_by_chunks ($_ ) } @$arg;
1147     },
1148
1149     ARRAYREFREF => sub {
1150       my ($s, @b) = @$$arg;
1151       $self->_assert_bindval_matches_bindtype(@b);
1152       [ $s, @b ];
1153     },
1154
1155     SCALAR    => sub {$self->_quote($arg)},
1156
1157     UNDEF     => sub {return () },
1158
1159     SCALARREF => sub {$$arg}, # literal SQL, no quoting
1160
1161     HASHREF   => sub {
1162       # get first pair in hash
1163       my ($key, $val, @rest) = %$arg;
1164
1165       return () unless $key;
1166
1167       if ( @rest or not $key =~ /^-(desc|asc)/i ) {
1168         puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
1169       }
1170
1171       my $direction = $1;
1172
1173       my @ret;
1174       for my $c ($self->_order_by_chunks ($val)) {
1175         my ($sql, @bind);
1176
1177         $self->_SWITCH_refkind ($c, {
1178           SCALAR => sub {
1179             $sql = $c;
1180           },
1181           ARRAYREF => sub {
1182             ($sql, @bind) = @$c;
1183           },
1184         });
1185
1186         $sql = $sql . ' ' . $self->_sqlcase($direction);
1187
1188         push @ret, [ $sql, @bind];
1189       }
1190
1191       return @ret;
1192     },
1193   });
1194 }
1195
1196
1197 #======================================================================
1198 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
1199 #======================================================================
1200
1201 sub _table  {
1202   my $self = shift;
1203   my $from = shift;
1204   $self->_SWITCH_refkind($from, {
1205     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
1206     SCALAR       => sub {$self->_quote($from)},
1207     SCALARREF    => sub {$$from},
1208   });
1209 }
1210
1211
1212 #======================================================================
1213 # UTILITY FUNCTIONS
1214 #======================================================================
1215
1216 # highly optimized, as it's called way too often
1217 sub _quote {
1218   # my ($self, $label) = @_;
1219
1220   return '' unless defined $_[1];
1221   return ${$_[1]} if ref($_[1]) eq 'SCALAR';
1222
1223   unless ($_[0]->{quote_char}) {
1224     $_[0]->_assert_pass_injection_guard($_[1]);
1225     return $_[1];
1226   }
1227
1228   my $qref = ref $_[0]->{quote_char};
1229   my ($l, $r);
1230   if (!$qref) {
1231     ($l, $r) = ( $_[0]->{quote_char}, $_[0]->{quote_char} );
1232   }
1233   elsif ($qref eq 'ARRAY') {
1234     ($l, $r) = @{$_[0]->{quote_char}};
1235   }
1236   else {
1237     puke "Unsupported quote_char format: $_[0]->{quote_char}";
1238   }
1239
1240   # parts containing * are naturally unquoted
1241   return join( $_[0]->{name_sep}||'', map
1242     { $_ eq '*' ? $_ : $l . $_ . $r }
1243     ( $_[0]->{name_sep} ? split (/\Q$_[0]->{name_sep}\E/, $_[1] ) : $_[1] )
1244   );
1245 }
1246
1247
1248 # Conversion, if applicable
1249 sub _convert ($) {
1250   #my ($self, $arg) = @_;
1251
1252 # LDNOTE : modified the previous implementation below because
1253 # it was not consistent : the first "return" is always an array,
1254 # the second "return" is context-dependent. Anyway, _convert
1255 # seems always used with just a single argument, so make it a
1256 # scalar function.
1257 #     return @_ unless $self->{convert};
1258 #     my $conv = $self->_sqlcase($self->{convert});
1259 #     my @ret = map { $conv.'('.$_.')' } @_;
1260 #     return wantarray ? @ret : $ret[0];
1261   if ($_[0]->{convert}) {
1262     return $_[0]->_sqlcase($_[0]->{convert}) .'(' . $_[1] . ')';
1263   }
1264   return $_[1];
1265 }
1266
1267 # And bindtype
1268 sub _bindtype (@) {
1269   #my ($self, $col, @vals) = @_;
1270
1271   #LDNOTE : changed original implementation below because it did not make
1272   # sense when bindtype eq 'columns' and @vals > 1.
1273 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
1274
1275   # called often - tighten code
1276   return $_[0]->{bindtype} eq 'columns'
1277     ? map {[$_[1], $_]} @_[2 .. $#_]
1278     : @_[2 .. $#_]
1279   ;
1280 }
1281
1282 # Dies if any element of @bind is not in [colname => value] format
1283 # if bindtype is 'columns'.
1284 sub _assert_bindval_matches_bindtype {
1285 #  my ($self, @bind) = @_;
1286   my $self = shift;
1287   if ($self->{bindtype} eq 'columns') {
1288     for (@_) {
1289       if (!defined $_ || ref($_) ne 'ARRAY' || @$_ != 2) {
1290         puke "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
1291       }
1292     }
1293   }
1294 }
1295
1296 sub _join_sql_clauses {
1297   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
1298
1299   if (@$clauses_aref > 1) {
1300     my $join  = " " . $self->_sqlcase($logic) . " ";
1301     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
1302     return ($sql, @$bind_aref);
1303   }
1304   elsif (@$clauses_aref) {
1305     return ($clauses_aref->[0], @$bind_aref); # no parentheses
1306   }
1307   else {
1308     return (); # if no SQL, ignore @$bind_aref
1309   }
1310 }
1311
1312
1313 # Fix SQL case, if so requested
1314 sub _sqlcase {
1315   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
1316   # don't touch the argument ... crooked logic, but let's not change it!
1317   return $_[0]->{case} ? $_[1] : uc($_[1]);
1318 }
1319
1320
1321 #======================================================================
1322 # DISPATCHING FROM REFKIND
1323 #======================================================================
1324
1325 sub _refkind {
1326   my ($self, $data) = @_;
1327
1328   return 'UNDEF' unless defined $data;
1329
1330   # blessed objects are treated like scalars
1331   my $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1332
1333   return 'SCALAR' unless $ref;
1334
1335   my $n_steps = 1;
1336   while ($ref eq 'REF') {
1337     $data = $$data;
1338     $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1339     $n_steps++ if $ref;
1340   }
1341
1342   return ($ref||'SCALAR') . ('REF' x $n_steps);
1343 }
1344
1345 sub _try_refkind {
1346   my ($self, $data) = @_;
1347   my @try = ($self->_refkind($data));
1348   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1349   push @try, 'FALLBACK';
1350   return \@try;
1351 }
1352
1353 sub _METHOD_FOR_refkind {
1354   my ($self, $meth_prefix, $data) = @_;
1355
1356   my $method;
1357   for (@{$self->_try_refkind($data)}) {
1358     $method = $self->can($meth_prefix."_".$_)
1359       and last;
1360   }
1361
1362   return $method || puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1363 }
1364
1365
1366 sub _SWITCH_refkind {
1367   my ($self, $data, $dispatch_table) = @_;
1368
1369   my $coderef;
1370   for (@{$self->_try_refkind($data)}) {
1371     $coderef = $dispatch_table->{$_}
1372       and last;
1373   }
1374
1375   puke "no dispatch entry for ".$self->_refkind($data)
1376     unless $coderef;
1377
1378   $coderef->();
1379 }
1380
1381
1382
1383
1384 #======================================================================
1385 # VALUES, GENERATE, AUTOLOAD
1386 #======================================================================
1387
1388 # LDNOTE: original code from nwiger, didn't touch code in that section
1389 # I feel the AUTOLOAD stuff should not be the default, it should
1390 # only be activated on explicit demand by user.
1391
1392 sub values {
1393     my $self = shift;
1394     my $data = shift || return;
1395     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1396         unless ref $data eq 'HASH';
1397
1398     my @all_bind;
1399     foreach my $k ( sort keys %$data ) {
1400         my $v = $data->{$k};
1401         $self->_SWITCH_refkind($v, {
1402           ARRAYREF => sub {
1403             if ($self->{array_datatypes}) { # array datatype
1404               push @all_bind, $self->_bindtype($k, $v);
1405             }
1406             else {                          # literal SQL with bind
1407               my ($sql, @bind) = @$v;
1408               $self->_assert_bindval_matches_bindtype(@bind);
1409               push @all_bind, @bind;
1410             }
1411           },
1412           ARRAYREFREF => sub { # literal SQL with bind
1413             my ($sql, @bind) = @${$v};
1414             $self->_assert_bindval_matches_bindtype(@bind);
1415             push @all_bind, @bind;
1416           },
1417           SCALARREF => sub {  # literal SQL without bind
1418           },
1419           SCALAR_or_UNDEF => sub {
1420             push @all_bind, $self->_bindtype($k, $v);
1421           },
1422         });
1423     }
1424
1425     return @all_bind;
1426 }
1427
1428 sub generate {
1429     my $self  = shift;
1430
1431     my(@sql, @sqlq, @sqlv);
1432
1433     for (@_) {
1434         my $ref = ref $_;
1435         if ($ref eq 'HASH') {
1436             for my $k (sort keys %$_) {
1437                 my $v = $_->{$k};
1438                 my $r = ref $v;
1439                 my $label = $self->_quote($k);
1440                 if ($r eq 'ARRAY') {
1441                     # literal SQL with bind
1442                     my ($sql, @bind) = @$v;
1443                     $self->_assert_bindval_matches_bindtype(@bind);
1444                     push @sqlq, "$label = $sql";
1445                     push @sqlv, @bind;
1446                 } elsif ($r eq 'SCALAR') {
1447                     # literal SQL without bind
1448                     push @sqlq, "$label = $$v";
1449                 } else {
1450                     push @sqlq, "$label = ?";
1451                     push @sqlv, $self->_bindtype($k, $v);
1452                 }
1453             }
1454             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1455         } elsif ($ref eq 'ARRAY') {
1456             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1457             for my $v (@$_) {
1458                 my $r = ref $v;
1459                 if ($r eq 'ARRAY') {   # literal SQL with bind
1460                     my ($sql, @bind) = @$v;
1461                     $self->_assert_bindval_matches_bindtype(@bind);
1462                     push @sqlq, $sql;
1463                     push @sqlv, @bind;
1464                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1465                     # embedded literal SQL
1466                     push @sqlq, $$v;
1467                 } else {
1468                     push @sqlq, '?';
1469                     push @sqlv, $v;
1470                 }
1471             }
1472             push @sql, '(' . join(', ', @sqlq) . ')';
1473         } elsif ($ref eq 'SCALAR') {
1474             # literal SQL
1475             push @sql, $$_;
1476         } else {
1477             # strings get case twiddled
1478             push @sql, $self->_sqlcase($_);
1479         }
1480     }
1481
1482     my $sql = join ' ', @sql;
1483
1484     # this is pretty tricky
1485     # if ask for an array, return ($stmt, @bind)
1486     # otherwise, s/?/shift @sqlv/ to put it inline
1487     if (wantarray) {
1488         return ($sql, @sqlv);
1489     } else {
1490         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1491                              ref $d ? $d->[1] : $d/e;
1492         return $sql;
1493     }
1494 }
1495
1496
1497 sub DESTROY { 1 }
1498
1499 sub AUTOLOAD {
1500     # This allows us to check for a local, then _form, attr
1501     my $self = shift;
1502     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1503     return $self->generate($name, @_);
1504 }
1505
1506 1;
1507
1508
1509
1510 __END__
1511
1512 =head1 NAME
1513
1514 SQL::Abstract - Generate SQL from Perl data structures
1515
1516 =head1 SYNOPSIS
1517
1518     use SQL::Abstract;
1519
1520     my $sql = SQL::Abstract->new;
1521
1522     my($stmt, @bind) = $sql->select($source, \@fields, \%where, \@order);
1523
1524     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1525
1526     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1527
1528     my($stmt, @bind) = $sql->delete($table, \%where);
1529
1530     # Then, use these in your DBI statements
1531     my $sth = $dbh->prepare($stmt);
1532     $sth->execute(@bind);
1533
1534     # Just generate the WHERE clause
1535     my($stmt, @bind) = $sql->where(\%where, \@order);
1536
1537     # Return values in the same order, for hashed queries
1538     # See PERFORMANCE section for more details
1539     my @bind = $sql->values(\%fieldvals);
1540
1541 =head1 DESCRIPTION
1542
1543 This module was inspired by the excellent L<DBIx::Abstract>.
1544 However, in using that module I found that what I really wanted
1545 to do was generate SQL, but still retain complete control over my
1546 statement handles and use the DBI interface. So, I set out to
1547 create an abstract SQL generation module.
1548
1549 While based on the concepts used by L<DBIx::Abstract>, there are
1550 several important differences, especially when it comes to WHERE
1551 clauses. I have modified the concepts used to make the SQL easier
1552 to generate from Perl data structures and, IMO, more intuitive.
1553 The underlying idea is for this module to do what you mean, based
1554 on the data structures you provide it. The big advantage is that
1555 you don't have to modify your code every time your data changes,
1556 as this module figures it out.
1557
1558 To begin with, an SQL INSERT is as easy as just specifying a hash
1559 of C<key=value> pairs:
1560
1561     my %data = (
1562         name => 'Jimbo Bobson',
1563         phone => '123-456-7890',
1564         address => '42 Sister Lane',
1565         city => 'St. Louis',
1566         state => 'Louisiana',
1567     );
1568
1569 The SQL can then be generated with this:
1570
1571     my($stmt, @bind) = $sql->insert('people', \%data);
1572
1573 Which would give you something like this:
1574
1575     $stmt = "INSERT INTO people
1576                     (address, city, name, phone, state)
1577                     VALUES (?, ?, ?, ?, ?)";
1578     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1579              '123-456-7890', 'Louisiana');
1580
1581 These are then used directly in your DBI code:
1582
1583     my $sth = $dbh->prepare($stmt);
1584     $sth->execute(@bind);
1585
1586 =head2 Inserting and Updating Arrays
1587
1588 If your database has array types (like for example Postgres),
1589 activate the special option C<< array_datatypes => 1 >>
1590 when creating the C<SQL::Abstract> object.
1591 Then you may use an arrayref to insert and update database array types:
1592
1593     my $sql = SQL::Abstract->new(array_datatypes => 1);
1594     my %data = (
1595         planets => [qw/Mercury Venus Earth Mars/]
1596     );
1597
1598     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1599
1600 This results in:
1601
1602     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1603
1604     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1605
1606
1607 =head2 Inserting and Updating SQL
1608
1609 In order to apply SQL functions to elements of your C<%data> you may
1610 specify a reference to an arrayref for the given hash value. For example,
1611 if you need to execute the Oracle C<to_date> function on a value, you can
1612 say something like this:
1613
1614     my %data = (
1615         name => 'Bill',
1616         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1617     );
1618
1619 The first value in the array is the actual SQL. Any other values are
1620 optional and would be included in the bind values array. This gives
1621 you:
1622
1623     my($stmt, @bind) = $sql->insert('people', \%data);
1624
1625     $stmt = "INSERT INTO people (name, date_entered)
1626                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1627     @bind = ('Bill', '03/02/2003');
1628
1629 An UPDATE is just as easy, all you change is the name of the function:
1630
1631     my($stmt, @bind) = $sql->update('people', \%data);
1632
1633 Notice that your C<%data> isn't touched; the module will generate
1634 the appropriately quirky SQL for you automatically. Usually you'll
1635 want to specify a WHERE clause for your UPDATE, though, which is
1636 where handling C<%where> hashes comes in handy...
1637
1638 =head2 Complex where statements
1639
1640 This module can generate pretty complicated WHERE statements
1641 easily. For example, simple C<key=value> pairs are taken to mean
1642 equality, and if you want to see if a field is within a set
1643 of values, you can use an arrayref. Let's say we wanted to
1644 SELECT some data based on this criteria:
1645
1646     my %where = (
1647        requestor => 'inna',
1648        worker => ['nwiger', 'rcwe', 'sfz'],
1649        status => { '!=', 'completed' }
1650     );
1651
1652     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1653
1654 The above would give you something like this:
1655
1656     $stmt = "SELECT * FROM tickets WHERE
1657                 ( requestor = ? ) AND ( status != ? )
1658                 AND ( worker = ? OR worker = ? OR worker = ? )";
1659     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1660
1661 Which you could then use in DBI code like so:
1662
1663     my $sth = $dbh->prepare($stmt);
1664     $sth->execute(@bind);
1665
1666 Easy, eh?
1667
1668 =head1 FUNCTIONS
1669
1670 The functions are simple. There's one for each major SQL operation,
1671 and a constructor you use first. The arguments are specified in a
1672 similar order to each function (table, then fields, then a where
1673 clause) to try and simplify things.
1674
1675
1676
1677
1678 =head2 new(option => 'value')
1679
1680 The C<new()> function takes a list of options and values, and returns
1681 a new B<SQL::Abstract> object which can then be used to generate SQL
1682 through the methods below. The options accepted are:
1683
1684 =over
1685
1686 =item case
1687
1688 If set to 'lower', then SQL will be generated in all lowercase. By
1689 default SQL is generated in "textbook" case meaning something like:
1690
1691     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1692
1693 Any setting other than 'lower' is ignored.
1694
1695 =item cmp
1696
1697 This determines what the default comparison operator is. By default
1698 it is C<=>, meaning that a hash like this:
1699
1700     %where = (name => 'nwiger', email => 'nate@wiger.org');
1701
1702 Will generate SQL like this:
1703
1704     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1705
1706 However, you may want loose comparisons by default, so if you set
1707 C<cmp> to C<like> you would get SQL such as:
1708
1709     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1710
1711 You can also override the comparison on an individual basis - see
1712 the huge section on L</"WHERE CLAUSES"> at the bottom.
1713
1714 =item sqltrue, sqlfalse
1715
1716 Expressions for inserting boolean values within SQL statements.
1717 By default these are C<1=1> and C<1=0>. They are used
1718 by the special operators C<-in> and C<-not_in> for generating
1719 correct SQL even when the argument is an empty array (see below).
1720
1721 =item logic
1722
1723 This determines the default logical operator for multiple WHERE
1724 statements in arrays or hashes. If absent, the default logic is "or"
1725 for arrays, and "and" for hashes. This means that a WHERE
1726 array of the form:
1727
1728     @where = (
1729         event_date => {'>=', '2/13/99'},
1730         event_date => {'<=', '4/24/03'},
1731     );
1732
1733 will generate SQL like this:
1734
1735     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1736
1737 This is probably not what you want given this query, though (look
1738 at the dates). To change the "OR" to an "AND", simply specify:
1739
1740     my $sql = SQL::Abstract->new(logic => 'and');
1741
1742 Which will change the above C<WHERE> to:
1743
1744     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1745
1746 The logic can also be changed locally by inserting
1747 a modifier in front of an arrayref :
1748
1749     @where = (-and => [event_date => {'>=', '2/13/99'},
1750                        event_date => {'<=', '4/24/03'} ]);
1751
1752 See the L</"WHERE CLAUSES"> section for explanations.
1753
1754 =item convert
1755
1756 This will automatically convert comparisons using the specified SQL
1757 function for both column and value. This is mostly used with an argument
1758 of C<upper> or C<lower>, so that the SQL will have the effect of
1759 case-insensitive "searches". For example, this:
1760
1761     $sql = SQL::Abstract->new(convert => 'upper');
1762     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1763
1764 Will turn out the following SQL:
1765
1766     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1767
1768 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1769 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1770 not validate this option; it will just pass through what you specify verbatim).
1771
1772 =item bindtype
1773
1774 This is a kludge because many databases suck. For example, you can't
1775 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1776 Instead, you have to use C<bind_param()>:
1777
1778     $sth->bind_param(1, 'reg data');
1779     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1780
1781 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1782 which loses track of which field each slot refers to. Fear not.
1783
1784 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1785 Currently, you can specify either C<normal> (default) or C<columns>. If you
1786 specify C<columns>, you will get an array that looks like this:
1787
1788     my $sql = SQL::Abstract->new(bindtype => 'columns');
1789     my($stmt, @bind) = $sql->insert(...);
1790
1791     @bind = (
1792         [ 'column1', 'value1' ],
1793         [ 'column2', 'value2' ],
1794         [ 'column3', 'value3' ],
1795     );
1796
1797 You can then iterate through this manually, using DBI's C<bind_param()>.
1798
1799     $sth->prepare($stmt);
1800     my $i = 1;
1801     for (@bind) {
1802         my($col, $data) = @$_;
1803         if ($col eq 'details' || $col eq 'comments') {
1804             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1805         } elsif ($col eq 'image') {
1806             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1807         } else {
1808             $sth->bind_param($i, $data);
1809         }
1810         $i++;
1811     }
1812     $sth->execute;      # execute without @bind now
1813
1814 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1815 Basically, the advantage is still that you don't have to care which fields
1816 are or are not included. You could wrap that above C<for> loop in a simple
1817 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1818 get a layer of abstraction over manual SQL specification.
1819
1820 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1821 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1822 will expect the bind values in this format.
1823
1824 =item quote_char
1825
1826 This is the character that a table or column name will be quoted
1827 with.  By default this is an empty string, but you could set it to
1828 the character C<`>, to generate SQL like this:
1829
1830   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1831
1832 Alternatively, you can supply an array ref of two items, the first being the left
1833 hand quote character, and the second the right hand quote character. For
1834 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1835 that generates SQL like this:
1836
1837   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1838
1839 Quoting is useful if you have tables or columns names that are reserved
1840 words in your database's SQL dialect.
1841
1842 =item name_sep
1843
1844 This is the character that separates a table and column name.  It is
1845 necessary to specify this when the C<quote_char> option is selected,
1846 so that tables and column names can be individually quoted like this:
1847
1848   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1849
1850 =item injection_guard
1851
1852 A regular expression C<qr/.../> that is applied to any C<-function> and unquoted
1853 column name specified in a query structure. This is a safety mechanism to avoid
1854 injection attacks when mishandling user input e.g.:
1855
1856   my %condition_as_column_value_pairs = get_values_from_user();
1857   $sqla->select( ... , \%condition_as_column_value_pairs );
1858
1859 If the expression matches an exception is thrown. Note that literal SQL
1860 supplied via C<\'...'> or C<\['...']> is B<not> checked in any way.
1861
1862 Defaults to checking for C<;> and the C<GO> keyword (TransactSQL)
1863
1864 =item array_datatypes
1865
1866 When this option is true, arrayrefs in INSERT or UPDATE are
1867 interpreted as array datatypes and are passed directly
1868 to the DBI layer.
1869 When this option is false, arrayrefs are interpreted
1870 as literal SQL, just like refs to arrayrefs
1871 (but this behavior is for backwards compatibility; when writing
1872 new queries, use the "reference to arrayref" syntax
1873 for literal SQL).
1874
1875
1876 =item special_ops
1877
1878 Takes a reference to a list of "special operators"
1879 to extend the syntax understood by L<SQL::Abstract>.
1880 See section L</"SPECIAL OPERATORS"> for details.
1881
1882 =item unary_ops
1883
1884 Takes a reference to a list of "unary operators"
1885 to extend the syntax understood by L<SQL::Abstract>.
1886 See section L</"UNARY OPERATORS"> for details.
1887
1888
1889
1890 =back
1891
1892 =head2 insert($table, \@values || \%fieldvals, \%options)
1893
1894 This is the simplest function. You simply give it a table name
1895 and either an arrayref of values or hashref of field/value pairs.
1896 It returns an SQL INSERT statement and a list of bind values.
1897 See the sections on L</"Inserting and Updating Arrays"> and
1898 L</"Inserting and Updating SQL"> for information on how to insert
1899 with those data types.
1900
1901 The optional C<\%options> hash reference may contain additional
1902 options to generate the insert SQL. Currently supported options
1903 are:
1904
1905 =over 4
1906
1907 =item returning
1908
1909 Takes either a scalar of raw SQL fields, or an array reference of
1910 field names, and adds on an SQL C<RETURNING> statement at the end.
1911 This allows you to return data generated by the insert statement
1912 (such as row IDs) without performing another C<SELECT> statement.
1913 Note, however, this is not part of the SQL standard and may not
1914 be supported by all database engines.
1915
1916 =back
1917
1918 =head2 update($table, \%fieldvals, \%where)
1919
1920 This takes a table, hashref of field/value pairs, and an optional
1921 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1922 of bind values.
1923 See the sections on L</"Inserting and Updating Arrays"> and
1924 L</"Inserting and Updating SQL"> for information on how to insert
1925 with those data types.
1926
1927 =head2 select($source, $fields, $where, $order)
1928
1929 This returns a SQL SELECT statement and associated list of bind values, as
1930 specified by the arguments  :
1931
1932 =over
1933
1934 =item $source
1935
1936 Specification of the 'FROM' part of the statement.
1937 The argument can be either a plain scalar (interpreted as a table
1938 name, will be quoted), or an arrayref (interpreted as a list
1939 of table names, joined by commas, quoted), or a scalarref
1940 (literal table name, not quoted), or a ref to an arrayref
1941 (list of literal table names, joined by commas, not quoted).
1942
1943 =item $fields
1944
1945 Specification of the list of fields to retrieve from
1946 the source.
1947 The argument can be either an arrayref (interpreted as a list
1948 of field names, will be joined by commas and quoted), or a
1949 plain scalar (literal SQL, not quoted).
1950 Please observe that this API is not as flexible as that of
1951 the first argument C<$source>, for backwards compatibility reasons.
1952
1953 =item $where
1954
1955 Optional argument to specify the WHERE part of the query.
1956 The argument is most often a hashref, but can also be
1957 an arrayref or plain scalar --
1958 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1959
1960 =item $order
1961
1962 Optional argument to specify the ORDER BY part of the query.
1963 The argument can be a scalar, a hashref or an arrayref
1964 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1965 for details.
1966
1967 =back
1968
1969
1970 =head2 delete($table, \%where)
1971
1972 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1973 It returns an SQL DELETE statement and list of bind values.
1974
1975 =head2 where(\%where, \@order)
1976
1977 This is used to generate just the WHERE clause. For example,
1978 if you have an arbitrary data structure and know what the
1979 rest of your SQL is going to look like, but want an easy way
1980 to produce a WHERE clause, use this. It returns an SQL WHERE
1981 clause and list of bind values.
1982
1983
1984 =head2 values(\%data)
1985
1986 This just returns the values from the hash C<%data>, in the same
1987 order that would be returned from any of the other above queries.
1988 Using this allows you to markedly speed up your queries if you
1989 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1990
1991 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1992
1993 Warning: This is an experimental method and subject to change.
1994
1995 This returns arbitrarily generated SQL. It's a really basic shortcut.
1996 It will return two different things, depending on return context:
1997
1998     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1999     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
2000
2001 These would return the following:
2002
2003     # First calling form
2004     $stmt = "CREATE TABLE test (?, ?)";
2005     @bind = (field1, field2);
2006
2007     # Second calling form
2008     $stmt_and_val = "CREATE TABLE test (field1, field2)";
2009
2010 Depending on what you're trying to do, it's up to you to choose the correct
2011 format. In this example, the second form is what you would want.
2012
2013 By the same token:
2014
2015     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
2016
2017 Might give you:
2018
2019     ALTER SESSION SET nls_date_format = 'MM/YY'
2020
2021 You get the idea. Strings get their case twiddled, but everything
2022 else remains verbatim.
2023
2024 =head1 WHERE CLAUSES
2025
2026 =head2 Introduction
2027
2028 This module uses a variation on the idea from L<DBIx::Abstract>. It
2029 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
2030 module is that things in arrays are OR'ed, and things in hashes
2031 are AND'ed.>
2032
2033 The easiest way to explain is to show lots of examples. After
2034 each C<%where> hash shown, it is assumed you used:
2035
2036     my($stmt, @bind) = $sql->where(\%where);
2037
2038 However, note that the C<%where> hash can be used directly in any
2039 of the other functions as well, as described above.
2040
2041 =head2 Key-value pairs
2042
2043 So, let's get started. To begin, a simple hash:
2044
2045     my %where  = (
2046         user   => 'nwiger',
2047         status => 'completed'
2048     );
2049
2050 Is converted to SQL C<key = val> statements:
2051
2052     $stmt = "WHERE user = ? AND status = ?";
2053     @bind = ('nwiger', 'completed');
2054
2055 One common thing I end up doing is having a list of values that
2056 a field can be in. To do this, simply specify a list inside of
2057 an arrayref:
2058
2059     my %where  = (
2060         user   => 'nwiger',
2061         status => ['assigned', 'in-progress', 'pending'];
2062     );
2063
2064 This simple code will create the following:
2065
2066     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
2067     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
2068
2069 A field associated to an empty arrayref will be considered a
2070 logical false and will generate 0=1.
2071
2072 =head2 Tests for NULL values
2073
2074 If the value part is C<undef> then this is converted to SQL <IS NULL>
2075
2076     my %where  = (
2077         user   => 'nwiger',
2078         status => undef,
2079     );
2080
2081 becomes:
2082
2083     $stmt = "WHERE user = ? AND status IS NULL";
2084     @bind = ('nwiger');
2085
2086 To test if a column IS NOT NULL:
2087
2088     my %where  = (
2089         user   => 'nwiger',
2090         status => { '!=', undef },
2091     );
2092
2093 =head2 Specific comparison operators
2094
2095 If you want to specify a different type of operator for your comparison,
2096 you can use a hashref for a given column:
2097
2098     my %where  = (
2099         user   => 'nwiger',
2100         status => { '!=', 'completed' }
2101     );
2102
2103 Which would generate:
2104
2105     $stmt = "WHERE user = ? AND status != ?";
2106     @bind = ('nwiger', 'completed');
2107
2108 To test against multiple values, just enclose the values in an arrayref:
2109
2110     status => { '=', ['assigned', 'in-progress', 'pending'] };
2111
2112 Which would give you:
2113
2114     "WHERE status = ? OR status = ? OR status = ?"
2115
2116
2117 The hashref can also contain multiple pairs, in which case it is expanded
2118 into an C<AND> of its elements:
2119
2120     my %where  = (
2121         user   => 'nwiger',
2122         status => { '!=', 'completed', -not_like => 'pending%' }
2123     );
2124
2125     # Or more dynamically, like from a form
2126     $where{user} = 'nwiger';
2127     $where{status}{'!='} = 'completed';
2128     $where{status}{'-not_like'} = 'pending%';
2129
2130     # Both generate this
2131     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
2132     @bind = ('nwiger', 'completed', 'pending%');
2133
2134
2135 To get an OR instead, you can combine it with the arrayref idea:
2136
2137     my %where => (
2138          user => 'nwiger',
2139          priority => [ { '=', 2 }, { '>', 5 } ]
2140     );
2141
2142 Which would generate:
2143
2144     $stmt = "WHERE ( priority = ? OR priority > ? ) AND user = ?";
2145     @bind = ('2', '5', 'nwiger');
2146
2147 If you want to include literal SQL (with or without bind values), just use a
2148 scalar reference or array reference as the value:
2149
2150     my %where  = (
2151         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
2152         date_expires => { '<' => \"now()" }
2153     );
2154
2155 Which would generate:
2156
2157     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
2158     @bind = ('11/26/2008');
2159
2160
2161 =head2 Logic and nesting operators
2162
2163 In the example above,
2164 there is a subtle trap if you want to say something like
2165 this (notice the C<AND>):
2166
2167     WHERE priority != ? AND priority != ?
2168
2169 Because, in Perl you I<can't> do this:
2170
2171     priority => { '!=', 2, '!=', 1 }
2172
2173 As the second C<!=> key will obliterate the first. The solution
2174 is to use the special C<-modifier> form inside an arrayref:
2175
2176     priority => [ -and => {'!=', 2},
2177                           {'!=', 1} ]
2178
2179
2180 Normally, these would be joined by C<OR>, but the modifier tells it
2181 to use C<AND> instead. (Hint: You can use this in conjunction with the
2182 C<logic> option to C<new()> in order to change the way your queries
2183 work by default.) B<Important:> Note that the C<-modifier> goes
2184 B<INSIDE> the arrayref, as an extra first element. This will
2185 B<NOT> do what you think it might:
2186
2187     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
2188
2189 Here is a quick list of equivalencies, since there is some overlap:
2190
2191     # Same
2192     status => {'!=', 'completed', 'not like', 'pending%' }
2193     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
2194
2195     # Same
2196     status => {'=', ['assigned', 'in-progress']}
2197     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
2198     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
2199
2200
2201
2202 =head2 Special operators : IN, BETWEEN, etc.
2203
2204 You can also use the hashref format to compare a list of fields using the
2205 C<IN> comparison operator, by specifying the list as an arrayref:
2206
2207     my %where  = (
2208         status   => 'completed',
2209         reportid => { -in => [567, 2335, 2] }
2210     );
2211
2212 Which would generate:
2213
2214     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
2215     @bind = ('completed', '567', '2335', '2');
2216
2217 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
2218 the same way.
2219
2220 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
2221 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
2222 'sqltrue' (by default : C<1=1>).
2223
2224 In addition to the array you can supply a chunk of literal sql or
2225 literal sql with bind:
2226
2227     my %where = {
2228       customer => { -in => \[
2229         'SELECT cust_id FROM cust WHERE balance > ?',
2230         2000,
2231       ],
2232       status => { -in => \'SELECT status_codes FROM states' },
2233     };
2234
2235 would generate:
2236
2237     $stmt = "WHERE (
2238           customer IN ( SELECT cust_id FROM cust WHERE balance > ? )
2239       AND status IN ( SELECT status_codes FROM states )
2240     )";
2241     @bind = ('2000');
2242
2243 Finally, if the argument to C<-in> is not a reference, it will be
2244 treated as a single-element array.
2245
2246 Another pair of operators is C<-between> and C<-not_between>,
2247 used with an arrayref of two values:
2248
2249     my %where  = (
2250         user   => 'nwiger',
2251         completion_date => {
2252            -not_between => ['2002-10-01', '2003-02-06']
2253         }
2254     );
2255
2256 Would give you:
2257
2258     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
2259
2260 Just like with C<-in> all plausible combinations of literal SQL
2261 are possible:
2262
2263     my %where = {
2264       start0 => { -between => [ 1, 2 ] },
2265       start1 => { -between => \["? AND ?", 1, 2] },
2266       start2 => { -between => \"lower(x) AND upper(y)" },
2267       start3 => { -between => [
2268         \"lower(x)",
2269         \["upper(?)", 'stuff' ],
2270       ] },
2271     };
2272
2273 Would give you:
2274
2275     $stmt = "WHERE (
2276           ( start0 BETWEEN ? AND ?                )
2277       AND ( start1 BETWEEN ? AND ?                )
2278       AND ( start2 BETWEEN lower(x) AND upper(y)  )
2279       AND ( start3 BETWEEN lower(x) AND upper(?)  )
2280     )";
2281     @bind = (1, 2, 1, 2, 'stuff');
2282
2283
2284 These are the two builtin "special operators"; but the
2285 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
2286
2287 =head2 Unary operators: bool
2288
2289 If you wish to test against boolean columns or functions within your
2290 database you can use the C<-bool> and C<-not_bool> operators. For
2291 example to test the column C<is_user> being true and the column
2292 C<is_enabled> being false you would use:-
2293
2294     my %where  = (
2295         -bool       => 'is_user',
2296         -not_bool   => 'is_enabled',
2297     );
2298
2299 Would give you:
2300
2301     WHERE is_user AND NOT is_enabled
2302
2303 If a more complex combination is required, testing more conditions,
2304 then you should use the and/or operators:-
2305
2306     my %where  = (
2307         -and           => [
2308             -bool      => 'one',
2309             -bool      => 'two',
2310             -bool      => 'three',
2311             -not_bool  => 'four',
2312         ],
2313     );
2314
2315 Would give you:
2316
2317     WHERE one AND two AND three AND NOT four
2318
2319
2320 =head2 Nested conditions, -and/-or prefixes
2321
2322 So far, we've seen how multiple conditions are joined with a top-level
2323 C<AND>.  We can change this by putting the different conditions we want in
2324 hashes and then putting those hashes in an array. For example:
2325
2326     my @where = (
2327         {
2328             user   => 'nwiger',
2329             status => { -like => ['pending%', 'dispatched'] },
2330         },
2331         {
2332             user   => 'robot',
2333             status => 'unassigned',
2334         }
2335     );
2336
2337 This data structure would create the following:
2338
2339     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
2340                 OR ( user = ? AND status = ? ) )";
2341     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
2342
2343
2344 Clauses in hashrefs or arrayrefs can be prefixed with an C<-and> or C<-or>
2345 to change the logic inside :
2346
2347     my @where = (
2348          -and => [
2349             user => 'nwiger',
2350             [
2351                 -and => [ workhrs => {'>', 20}, geo => 'ASIA' ],
2352                 -or => { workhrs => {'<', 50}, geo => 'EURO' },
2353             ],
2354         ],
2355     );
2356
2357 That would yield:
2358
2359     WHERE ( user = ? AND (
2360                ( workhrs > ? AND geo = ? )
2361             OR ( workhrs < ? OR geo = ? )
2362           ) )
2363
2364 =head3 Algebraic inconsistency, for historical reasons
2365
2366 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
2367 operator goes C<outside> of the nested structure; whereas when connecting
2368 several constraints on one column, the C<-and> operator goes
2369 C<inside> the arrayref. Here is an example combining both features :
2370
2371    my @where = (
2372      -and => [a => 1, b => 2],
2373      -or  => [c => 3, d => 4],
2374       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
2375    )
2376
2377 yielding
2378
2379   WHERE ( (    ( a = ? AND b = ? )
2380             OR ( c = ? OR d = ? )
2381             OR ( e LIKE ? AND e LIKE ? ) ) )
2382
2383 This difference in syntax is unfortunate but must be preserved for
2384 historical reasons. So be careful : the two examples below would
2385 seem algebraically equivalent, but they are not
2386
2387   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
2388   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
2389
2390   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
2391   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
2392
2393
2394 =head2 Literal SQL and value type operators
2395
2396 The basic premise of SQL::Abstract is that in WHERE specifications the "left
2397 side" is a column name and the "right side" is a value (normally rendered as
2398 a placeholder). This holds true for both hashrefs and arrayref pairs as you
2399 see in the L</WHERE CLAUSES> examples above. Sometimes it is necessary to
2400 alter this behavior. There are several ways of doing so.
2401
2402 =head3 -ident
2403
2404 This is a virtual operator that signals the string to its right side is an
2405 identifier (a column name) and not a value. For example to compare two
2406 columns you would write:
2407
2408     my %where = (
2409         priority => { '<', 2 },
2410         requestor => { -ident => 'submitter' },
2411     );
2412
2413 which creates:
2414
2415     $stmt = "WHERE priority < ? AND requestor = submitter";
2416     @bind = ('2');
2417
2418 If you are maintaining legacy code you may see a different construct as
2419 described in L</Deprecated usage of Literal SQL>, please use C<-ident> in new
2420 code.
2421
2422 =head3 -value
2423
2424 This is a virtual operator that signals that the construct to its right side
2425 is a value to be passed to DBI. This is for example necessary when you want
2426 to write a where clause against an array (for RDBMS that support such
2427 datatypes). For example:
2428
2429     my %where = (
2430         array => { -value => [1, 2, 3] }
2431     );
2432
2433 will result in:
2434
2435     $stmt = 'WHERE array = ?';
2436     @bind = ([1, 2, 3]);
2437
2438 Note that if you were to simply say:
2439
2440     my %where = (
2441         array => [1, 2, 3]
2442     );
2443
2444 the result would probably not be what you wanted:
2445
2446     $stmt = 'WHERE array = ? OR array = ? OR array = ?';
2447     @bind = (1, 2, 3);
2448
2449 =head3 Literal SQL
2450
2451 Finally, sometimes only literal SQL will do. To include a random snippet
2452 of SQL verbatim, you specify it as a scalar reference. Consider this only
2453 as a last resort. Usually there is a better way. For example:
2454
2455     my %where = (
2456         priority => { '<', 2 },
2457         requestor => { -in => \'(SELECT name FROM hitmen)' },
2458     );
2459
2460 Would create:
2461
2462     $stmt = "WHERE priority < ? AND requestor IN (SELECT name FROM hitmen)"
2463     @bind = (2);
2464
2465 Note that in this example, you only get one bind parameter back, since
2466 the verbatim SQL is passed as part of the statement.
2467
2468 =head4 CAVEAT
2469
2470   Never use untrusted input as a literal SQL argument - this is a massive
2471   security risk (there is no way to check literal snippets for SQL
2472   injections and other nastyness). If you need to deal with untrusted input
2473   use literal SQL with placeholders as described next.
2474
2475 =head3 Literal SQL with placeholders and bind values (subqueries)
2476
2477 If the literal SQL to be inserted has placeholders and bind values,
2478 use a reference to an arrayref (yes this is a double reference --
2479 not so common, but perfectly legal Perl). For example, to find a date
2480 in Postgres you can use something like this:
2481
2482     my %where = (
2483        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
2484     )
2485
2486 This would create:
2487
2488     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
2489     @bind = ('10');
2490
2491 Note that you must pass the bind values in the same format as they are returned
2492 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
2493 provide the bind values in the C<< [ column_meta => value ] >> format, where
2494 C<column_meta> is an opaque scalar value; most commonly the column name, but
2495 you can use any scalar value (including references and blessed references),
2496 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
2497 to C<columns> the above example will look like:
2498
2499     my %where = (
2500        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
2501     )
2502
2503 Literal SQL is especially useful for nesting parenthesized clauses in the
2504 main SQL query. Here is a first example :
2505
2506   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2507                                100, "foo%");
2508   my %where = (
2509     foo => 1234,
2510     bar => \["IN ($sub_stmt)" => @sub_bind],
2511   );
2512
2513 This yields :
2514
2515   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2516                                              WHERE c2 < ? AND c3 LIKE ?))";
2517   @bind = (1234, 100, "foo%");
2518
2519 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2520 are expressed in the same way. Of course the C<$sub_stmt> and
2521 its associated bind values can be generated through a former call
2522 to C<select()> :
2523
2524   my ($sub_stmt, @sub_bind)
2525      = $sql->select("t1", "c1", {c2 => {"<" => 100},
2526                                  c3 => {-like => "foo%"}});
2527   my %where = (
2528     foo => 1234,
2529     bar => \["> ALL ($sub_stmt)" => @sub_bind],
2530   );
2531
2532 In the examples above, the subquery was used as an operator on a column;
2533 but the same principle also applies for a clause within the main C<%where>
2534 hash, like an EXISTS subquery :
2535
2536   my ($sub_stmt, @sub_bind)
2537      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2538   my %where = ( -and => [
2539     foo   => 1234,
2540     \["EXISTS ($sub_stmt)" => @sub_bind],
2541   ]);
2542
2543 which yields
2544
2545   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2546                                         WHERE c1 = ? AND c2 > t0.c0))";
2547   @bind = (1234, 1);
2548
2549
2550 Observe that the condition on C<c2> in the subquery refers to
2551 column C<t0.c0> of the main query : this is I<not> a bind
2552 value, so we have to express it through a scalar ref.
2553 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2554 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2555 what we wanted here.
2556
2557 Finally, here is an example where a subquery is used
2558 for expressing unary negation:
2559
2560   my ($sub_stmt, @sub_bind)
2561      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2562   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2563   my %where = (
2564         lname  => {like => '%son%'},
2565         \["NOT ($sub_stmt)" => @sub_bind],
2566     );
2567
2568 This yields
2569
2570   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2571   @bind = ('%son%', 10, 20)
2572
2573 =head3 Deprecated usage of Literal SQL
2574
2575 Below are some examples of archaic use of literal SQL. It is shown only as
2576 reference for those who deal with legacy code. Each example has a much
2577 better, cleaner and safer alternative that users should opt for in new code.
2578
2579 =over
2580
2581 =item *
2582
2583     my %where = ( requestor => \'IS NOT NULL' )
2584
2585     $stmt = "WHERE requestor IS NOT NULL"
2586
2587 This used to be the way of generating NULL comparisons, before the handling
2588 of C<undef> got formalized. For new code please use the superior syntax as
2589 described in L</Tests for NULL values>.
2590
2591 =item *
2592
2593     my %where = ( requestor => \'= submitter' )
2594
2595     $stmt = "WHERE requestor = submitter"
2596
2597 This used to be the only way to compare columns. Use the superior L</-ident>
2598 method for all new code. For example an identifier declared in such a way
2599 will be properly quoted if L</quote_char> is properly set, while the legacy
2600 form will remain as supplied.
2601
2602 =item *
2603
2604     my %where = ( is_ready  => \"", completed => { '>', '2012-12-21' } )
2605
2606     $stmt = "WHERE completed > ? AND is_ready"
2607     @bind = ('2012-12-21')
2608
2609 Using an empty string literal used to be the only way to express a boolean.
2610 For all new code please use the much more readable
2611 L<-bool|/Unary operators: bool> operator.
2612
2613 =back
2614
2615 =head2 Conclusion
2616
2617 These pages could go on for a while, since the nesting of the data
2618 structures this module can handle are pretty much unlimited (the
2619 module implements the C<WHERE> expansion as a recursive function
2620 internally). Your best bet is to "play around" with the module a
2621 little to see how the data structures behave, and choose the best
2622 format for your data based on that.
2623
2624 And of course, all the values above will probably be replaced with
2625 variables gotten from forms or the command line. After all, if you
2626 knew everything ahead of time, you wouldn't have to worry about
2627 dynamically-generating SQL and could just hardwire it into your
2628 script.
2629
2630 =head1 ORDER BY CLAUSES
2631
2632 Some functions take an order by clause. This can either be a scalar (just a
2633 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2634 or an array of either of the two previous forms. Examples:
2635
2636                Given            |         Will Generate
2637     ----------------------------------------------------------
2638                                 |
2639     \'colA DESC'                | ORDER BY colA DESC
2640                                 |
2641     'colA'                      | ORDER BY colA
2642                                 |
2643     [qw/colA colB/]             | ORDER BY colA, colB
2644                                 |
2645     {-asc  => 'colA'}           | ORDER BY colA ASC
2646                                 |
2647     {-desc => 'colB'}           | ORDER BY colB DESC
2648                                 |
2649     ['colA', {-asc => 'colB'}]  | ORDER BY colA, colB ASC
2650                                 |
2651     { -asc => [qw/colA colB/] } | ORDER BY colA ASC, colB ASC
2652                                 |
2653     [                           |
2654       { -asc => 'colA' },       | ORDER BY colA ASC, colB DESC,
2655       { -desc => [qw/colB/],    |          colC ASC, colD ASC
2656       { -asc => [qw/colC colD/],|
2657     ]                           |
2658     ===========================================================
2659
2660
2661
2662 =head1 SPECIAL OPERATORS
2663
2664   my $sqlmaker = SQL::Abstract->new(special_ops => [
2665      {
2666       regex => qr/.../,
2667       handler => sub {
2668         my ($self, $field, $op, $arg) = @_;
2669         ...
2670       },
2671      },
2672      {
2673       regex => qr/.../,
2674       handler => 'method_name',
2675      },
2676    ]);
2677
2678 A "special operator" is a SQL syntactic clause that can be
2679 applied to a field, instead of a usual binary operator.
2680 For example :
2681
2682    WHERE field IN (?, ?, ?)
2683    WHERE field BETWEEN ? AND ?
2684    WHERE MATCH(field) AGAINST (?, ?)
2685
2686 Special operators IN and BETWEEN are fairly standard and therefore
2687 are builtin within C<SQL::Abstract> (as the overridable methods
2688 C<_where_field_IN> and C<_where_field_BETWEEN>). For other operators,
2689 like the MATCH .. AGAINST example above which is specific to MySQL,
2690 you can write your own operator handlers - supply a C<special_ops>
2691 argument to the C<new> method. That argument takes an arrayref of
2692 operator definitions; each operator definition is a hashref with two
2693 entries:
2694
2695 =over
2696
2697 =item regex
2698
2699 the regular expression to match the operator
2700
2701 =item handler
2702
2703 Either a coderef or a plain scalar method name. In both cases
2704 the expected return is C<< ($sql, @bind) >>.
2705
2706 When supplied with a method name, it is simply called on the
2707 L<SQL::Abstract/> object as:
2708
2709  $self->$method_name ($field, $op, $arg)
2710
2711  Where:
2712
2713   $op is the part that matched the handler regex
2714   $field is the LHS of the operator
2715   $arg is the RHS
2716
2717 When supplied with a coderef, it is called as:
2718
2719  $coderef->($self, $field, $op, $arg)
2720
2721
2722 =back
2723
2724 For example, here is an implementation
2725 of the MATCH .. AGAINST syntax for MySQL
2726
2727   my $sqlmaker = SQL::Abstract->new(special_ops => [
2728
2729     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2730     {regex => qr/^match$/i,
2731      handler => sub {
2732        my ($self, $field, $op, $arg) = @_;
2733        $arg = [$arg] if not ref $arg;
2734        my $label         = $self->_quote($field);
2735        my ($placeholder) = $self->_convert('?');
2736        my $placeholders  = join ", ", (($placeholder) x @$arg);
2737        my $sql           = $self->_sqlcase('match') . " ($label) "
2738                          . $self->_sqlcase('against') . " ($placeholders) ";
2739        my @bind = $self->_bindtype($field, @$arg);
2740        return ($sql, @bind);
2741        }
2742      },
2743
2744   ]);
2745
2746
2747 =head1 UNARY OPERATORS
2748
2749   my $sqlmaker = SQL::Abstract->new(unary_ops => [
2750      {
2751       regex => qr/.../,
2752       handler => sub {
2753         my ($self, $op, $arg) = @_;
2754         ...
2755       },
2756      },
2757      {
2758       regex => qr/.../,
2759       handler => 'method_name',
2760      },
2761    ]);
2762
2763 A "unary operator" is a SQL syntactic clause that can be
2764 applied to a field - the operator goes before the field
2765
2766 You can write your own operator handlers - supply a C<unary_ops>
2767 argument to the C<new> method. That argument takes an arrayref of
2768 operator definitions; each operator definition is a hashref with two
2769 entries:
2770
2771 =over
2772
2773 =item regex
2774
2775 the regular expression to match the operator
2776
2777 =item handler
2778
2779 Either a coderef or a plain scalar method name. In both cases
2780 the expected return is C<< $sql >>.
2781
2782 When supplied with a method name, it is simply called on the
2783 L<SQL::Abstract/> object as:
2784
2785  $self->$method_name ($op, $arg)
2786
2787  Where:
2788
2789   $op is the part that matched the handler regex
2790   $arg is the RHS or argument of the operator
2791
2792 When supplied with a coderef, it is called as:
2793
2794  $coderef->($self, $op, $arg)
2795
2796
2797 =back
2798
2799
2800 =head1 PERFORMANCE
2801
2802 Thanks to some benchmarking by Mark Stosberg, it turns out that
2803 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2804 I must admit this wasn't an intentional design issue, but it's a
2805 byproduct of the fact that you get to control your C<DBI> handles
2806 yourself.
2807
2808 To maximize performance, use a code snippet like the following:
2809
2810     # prepare a statement handle using the first row
2811     # and then reuse it for the rest of the rows
2812     my($sth, $stmt);
2813     for my $href (@array_of_hashrefs) {
2814         $stmt ||= $sql->insert('table', $href);
2815         $sth  ||= $dbh->prepare($stmt);
2816         $sth->execute($sql->values($href));
2817     }
2818
2819 The reason this works is because the keys in your C<$href> are sorted
2820 internally by B<SQL::Abstract>. Thus, as long as your data retains
2821 the same structure, you only have to generate the SQL the first time
2822 around. On subsequent queries, simply use the C<values> function provided
2823 by this module to return your values in the correct order.
2824
2825 However this depends on the values having the same type - if, for
2826 example, the values of a where clause may either have values
2827 (resulting in sql of the form C<column = ?> with a single bind
2828 value), or alternatively the values might be C<undef> (resulting in
2829 sql of the form C<column IS NULL> with no bind value) then the
2830 caching technique suggested will not work.
2831
2832 =head1 FORMBUILDER
2833
2834 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2835 really like this part (I do, at least). Building up a complex query
2836 can be as simple as the following:
2837
2838     #!/usr/bin/perl
2839
2840     use CGI::FormBuilder;
2841     use SQL::Abstract;
2842
2843     my $form = CGI::FormBuilder->new(...);
2844     my $sql  = SQL::Abstract->new;
2845
2846     if ($form->submitted) {
2847         my $field = $form->field;
2848         my $id = delete $field->{id};
2849         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2850     }
2851
2852 Of course, you would still have to connect using C<DBI> to run the
2853 query, but the point is that if you make your form look like your
2854 table, the actual query script can be extremely simplistic.
2855
2856 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2857 a fast interface to returning and formatting data. I frequently
2858 use these three modules together to write complex database query
2859 apps in under 50 lines.
2860
2861 =head1 REPO
2862
2863 =over
2864
2865 =item * gitweb: L<http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/SQL-Abstract.git>
2866
2867 =item * git: L<git://git.shadowcat.co.uk/dbsrgits/SQL-Abstract.git>
2868
2869 =back
2870
2871 =head1 CHANGES
2872
2873 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2874 Great care has been taken to preserve the I<published> behavior
2875 documented in previous versions in the 1.* family; however,
2876 some features that were previously undocumented, or behaved
2877 differently from the documentation, had to be changed in order
2878 to clarify the semantics. Hence, client code that was relying
2879 on some dark areas of C<SQL::Abstract> v1.*
2880 B<might behave differently> in v1.50.
2881
2882 The main changes are :
2883
2884 =over
2885
2886 =item *
2887
2888 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2889
2890 =item *
2891
2892 support for the { operator => \"..." } construct (to embed literal SQL)
2893
2894 =item *
2895
2896 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2897
2898 =item *
2899
2900 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2901
2902 =item *
2903
2904 defensive programming : check arguments
2905
2906 =item *
2907
2908 fixed bug with global logic, which was previously implemented
2909 through global variables yielding side-effects. Prior versions would
2910 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2911 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2912 Now this is interpreted
2913 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2914
2915
2916 =item *
2917
2918 fixed semantics of  _bindtype on array args
2919
2920 =item *
2921
2922 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2923 we just avoid shifting arrays within that tree.
2924
2925 =item *
2926
2927 dropped the C<_modlogic> function
2928
2929 =back
2930
2931 =head1 ACKNOWLEDGEMENTS
2932
2933 There are a number of individuals that have really helped out with
2934 this module. Unfortunately, most of them submitted bugs via CPAN
2935 so I have no idea who they are! But the people I do know are:
2936
2937     Ash Berlin (order_by hash term support)
2938     Matt Trout (DBIx::Class support)
2939     Mark Stosberg (benchmarking)
2940     Chas Owens (initial "IN" operator support)
2941     Philip Collins (per-field SQL functions)
2942     Eric Kolve (hashref "AND" support)
2943     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2944     Dan Kubb (support for "quote_char" and "name_sep")
2945     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2946     Laurent Dami (internal refactoring, extensible list of special operators, literal SQL)
2947     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2948     Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2949     Oliver Charles (support for "RETURNING" after "INSERT")
2950
2951 Thanks!
2952
2953 =head1 SEE ALSO
2954
2955 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2956
2957 =head1 AUTHOR
2958
2959 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2960
2961 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2962
2963 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2964 While not an official support venue, C<DBIx::Class> makes heavy use of
2965 C<SQL::Abstract>, and as such list members there are very familiar with
2966 how to create queries.
2967
2968 =head1 LICENSE
2969
2970 This module is free software; you may copy this under the same
2971 terms as perl itself (either the GNU General Public License or
2972 the Artistic License)
2973
2974 =cut
2975