lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use Carp;
   9 use strict;
  10 use warnings;
  11 use List::Util   qw/first/;
  12 use Scalar::Util qw/blessed/;
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.50';
  19
  20 # This would confuse some packagers
  21 #$VERSION      = eval $VERSION; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^(not )?between$/i, handler => \&_where_field_BETWEEN},
  29   {regex => qr/^(not )?in$/i,      handler => \&_where_field_IN},
  30 );
  31
  32 #======================================================================
  33 # DEBUGGING AND ERROR REPORTING
  34 #======================================================================
  35
  36 sub _debug {
  37   return unless $_[0]->{debug}; shift; # a little faster
  38   my $func = (caller(1))[3];
  39   warn "[$func] ", @_, "\n";
  40 }
  41
  42 sub belch (@) {
  43   my($func) = (caller(1))[3];
  44   carp "[$func] Warning: ", @_;
  45 }
  46
  47 sub puke (@) {
  48   my($func) = (caller(1))[3];
  49   croak "[$func] Fatal: ", @_;
  50 }
  51
  52
  53 #======================================================================
  54 # NEW
  55 #======================================================================
  56
  57 sub new {
  58   my $self = shift;
  59   my $class = ref($self) || $self;
  60   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  61
  62   # choose our case by keeping an option around
  63   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  64
  65   # default logic for interpreting arrayrefs
  66   $opt{logic} = uc $opt{logic} || 'OR';
  67
  68   # how to return bind vars
  69   # LDNOTE: changed nwiger code : why this 'delete' ??
  70   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  71   $opt{bindtype} ||= 'normal';
  72
  73   # default comparison is "=", but can be overridden
  74   $opt{cmp} ||= '=';
  75
  76   # try to recognize which are the 'equality' and 'unequality' ops
  77   # (temporary quickfix, should go through a more seasoned API)
  78  $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  79  $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  80
  81   # SQL booleans
  82   $opt{sqltrue}  ||= '1=1';
  83   $opt{sqlfalse} ||= '0=1';
  84
  85   # special operators
  86   $opt{special_ops} ||= [];
  87   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
  88
  89   return bless \%opt, $class;
  90 }
  91
  92
  93
  94 #======================================================================
  95 # INSERT methods
  96 #======================================================================
  97
  98 sub insert {
  99   my $self  = shift;
 100   my $table = $self->_table(shift);
 101   my $data  = shift || return;
 102
 103   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 104   my ($sql, @bind) = $self->$method($data);
 105   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 106   return wantarray ? ($sql, @bind) : $sql;
 107 }
 108
 109 sub _insert_HASHREF { # explicit list of fields and then values
 110   my ($self, $data) = @_;
 111
 112   my @fields = sort keys %$data;
 113
 114   my ($sql, @bind) = $self->_insert_values($data);
 115
 116   # assemble SQL
 117   $_ = $self->_quote($_) foreach @fields;
 118   $sql = "( ".join(", ", @fields).") ".$sql;
 119
 120   return ($sql, @bind);
 121 }
 122
 123 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 124   my ($self, $data) = @_;
 125
 126   # no names (arrayref) so can't generate bindtype
 127   $self->{bindtype} ne 'columns'
 128     or belch "can't do 'columns' bindtype when called with arrayref";
 129
 130   # fold the list of values into a hash of column name - value pairs
 131   # (where the column names are artificially generated, and their
 132   # lexicographical ordering keep the ordering of the original list)
 133   my $i = "a";  # incremented values will be in lexicographical order
 134   my $data_in_hash = { map { ($i++ => $_) } @$data };
 135
 136   return $self->_insert_values($data_in_hash);
 137 }
 138
 139 sub _insert_ARRAYREFREF { # literal SQL with bind
 140   my ($self, $data) = @_;
 141
 142   my ($sql, @bind) = @${$data};
 143   $self->_assert_bindval_matches_bindtype(@bind);
 144
 145   return ($sql, @bind);
 146 }
 147
 148
 149 sub _insert_SCALARREF { # literal SQL without bind
 150   my ($self, $data) = @_;
 151
 152   return ($$data);
 153 }
 154
 155 sub _insert_values {
 156   my ($self, $data) = @_;
 157
 158   my (@values, @all_bind);
 159   foreach my $column (sort keys %$data) {
 160     my $v = $data->{$column};
 161
 162     $self->_SWITCH_refkind($v, {
 163
 164       ARRAYREF => sub {
 165         if ($self->{array_datatypes}) { # if array datatype are activated
 166           push @values, '?';
 167           push @all_bind, $self->_bindtype($column, $v);
 168         }
 169         else {                          # else literal SQL with bind
 170           my ($sql, @bind) = @$v;
 171           $self->_assert_bindval_matches_bindtype(@bind);
 172           push @values, $sql;
 173           push @all_bind, @bind;
 174         }
 175       },
 176
 177       ARRAYREFREF => sub { # literal SQL with bind
 178         my ($sql, @bind) = @${$v};
 179         $self->_assert_bindval_matches_bindtype(@bind);
 180         push @values, $sql;
 181         push @all_bind, @bind;
 182       },
 183
 184       # THINK : anything useful to do with a HASHREF ?
 185       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 186         #TODO in SQLA >= 2.0 it will die instead
 187         belch "HASH ref as bind value in insert is not supported";
 188         push @values, '?';
 189         push @all_bind, $self->_bindtype($column, $v);
 190       },
 191
 192       SCALARREF => sub {  # literal SQL without bind
 193         push @values, $$v;
 194       },
 195
 196       SCALAR_or_UNDEF => sub {
 197         push @values, '?';
 198         push @all_bind, $self->_bindtype($column, $v);
 199       },
 200
 201      });
 202
 203   }
 204
 205   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 206   return ($sql, @all_bind);
 207 }
 208
 209
 210
 211 #======================================================================
 212 # UPDATE methods
 213 #======================================================================
 214
 215
 216 sub update {
 217   my $self  = shift;
 218   my $table = $self->_table(shift);
 219   my $data  = shift || return;
 220   my $where = shift;
 221
 222   # first build the 'SET' part of the sql statement
 223   my (@set, @all_bind);
 224   puke "Unsupported data type specified to \$sql->update"
 225     unless ref $data eq 'HASH';
 226
 227   for my $k (sort keys %$data) {
 228     my $v = $data->{$k};
 229     my $r = ref $v;
 230     my $label = $self->_quote($k);
 231
 232     $self->_SWITCH_refkind($v, {
 233       ARRAYREF => sub {
 234         if ($self->{array_datatypes}) { # array datatype
 235           push @set, "$label = ?";
 236           push @all_bind, $self->_bindtype($k, $v);
 237         }
 238         else {                          # literal SQL with bind
 239           my ($sql, @bind) = @$v;
 240           $self->_assert_bindval_matches_bindtype(@bind);
 241           push @set, "$label = $sql";
 242           push @all_bind, @bind;
 243         }
 244       },
 245       ARRAYREFREF => sub { # literal SQL with bind
 246         my ($sql, @bind) = @${$v};
 247         $self->_assert_bindval_matches_bindtype(@bind);
 248         push @set, "$label = $sql";
 249         push @all_bind, @bind;
 250       },
 251       SCALARREF => sub {  # literal SQL without bind
 252         push @set, "$label = $$v";
 253        },
 254       SCALAR_or_UNDEF => sub {
 255         push @set, "$label = ?";
 256         push @all_bind, $self->_bindtype($k, $v);
 257       },
 258     });
 259   }
 260
 261   # generate sql
 262   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 263           . join ', ', @set;
 264
 265   if ($where) {
 266     my($where_sql, @where_bind) = $self->where($where);
 267     $sql .= $where_sql;
 268     push @all_bind, @where_bind;
 269   }
 270
 271   return wantarray ? ($sql, @all_bind) : $sql;
 272 }
 273
 274
 275
 276
 277 #======================================================================
 278 # SELECT
 279 #======================================================================
 280
 281
 282 sub select {
 283   my $self   = shift;
 284   my $table  = $self->_table(shift);
 285   my $fields = shift || '*';
 286   my $where  = shift;
 287   my $order  = shift;
 288
 289   my($where_sql, @bind) = $self->where($where, $order);
 290
 291   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 292                                    : $fields;
 293   my $sql = join(' ', $self->_sqlcase('select'), $f,
 294                       $self->_sqlcase('from'),   $table)
 295           . $where_sql;
 296
 297   return wantarray ? ($sql, @bind) : $sql;
 298 }
 299
 300 #======================================================================
 301 # DELETE
 302 #======================================================================
 303
 304
 305 sub delete {
 306   my $self  = shift;
 307   my $table = $self->_table(shift);
 308   my $where = shift;
 309
 310
 311   my($where_sql, @bind) = $self->where($where);
 312   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 313
 314   return wantarray ? ($sql, @bind) : $sql;
 315 }
 316
 317
 318 #======================================================================
 319 # WHERE: entry point
 320 #======================================================================
 321
 322
 323
 324 # Finally, a separate routine just to handle WHERE clauses
 325 sub where {
 326   my ($self, $where, $order) = @_;
 327
 328   # where ?
 329   my ($sql, @bind) = $self->_recurse_where($where);
 330   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 331
 332   # order by?
 333   if ($order) {
 334     $sql .= $self->_order_by($order);
 335   }
 336
 337   return wantarray ? ($sql, @bind) : $sql;
 338 }
 339
 340
 341 sub _recurse_where {
 342   my ($self, $where, $logic) = @_;
 343
 344   # dispatch on appropriate method according to refkind of $where
 345   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 346
 347
 348   my ($sql, @bind) =  $self->$method($where, $logic);
 349
 350   # DBIx::Class directly calls _recurse_where in scalar context, so
 351   # we must implement it, even if not in the official API
 352   return wantarray ? ($sql, @bind) : $sql;
 353 }
 354
 355
 356
 357 #======================================================================
 358 # WHERE: top-level ARRAYREF
 359 #======================================================================
 360
 361
 362 sub _where_ARRAYREF {
 363   my ($self, $where, $logic) = @_;
 364
 365   $logic = uc($logic || $self->{logic});
 366   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 367
 368   my @clauses = @$where;
 369
 370   my (@sql_clauses, @all_bind);
 371   # need to use while() so can shift() for pairs
 372   while (my $el = shift @clauses) {
 373
 374     # switch according to kind of $el and get corresponding ($sql, @bind)
 375     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 376
 377       # skip empty elements, otherwise get invalid trailing AND stuff
 378       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 379
 380       ARRAYREFREF => sub { @{${$el}}                 if @{${$el}}},
 381
 382       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 383            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 384            # side-effect: the first hashref within an array would change
 385            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 386            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 387            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 388
 389       SCALARREF => sub { ($$el);                                 },
 390
 391       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 392                         $self->_recurse_where({$el => shift(@clauses)})},
 393
 394       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 395     });
 396
 397     if ($sql) {
 398       push @sql_clauses, $sql;
 399       push @all_bind, @bind;
 400     }
 401   }
 402
 403   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 404 }
 405
 406 #======================================================================
 407 # WHERE: top-level ARRAYREFREF
 408 #======================================================================
 409
 410 sub _where_ARRAYREFREF {
 411     my ($self, $where) = @_;
 412     my ($sql, @bind) = @{${$where}};
 413
 414     return ($sql, @bind);
 415 }
 416
 417 #======================================================================
 418 # WHERE: top-level HASHREF
 419 #======================================================================
 420
 421 sub _where_HASHREF {
 422   my ($self, $where) = @_;
 423   my (@sql_clauses, @all_bind);
 424
 425   # LDNOTE : don't really know why we need to sort keys
 426   for my $k (sort keys %$where) {
 427     my $v = $where->{$k};
 428
 429     # ($k => $v) is either a special op or a regular hashpair
 430     my ($sql, @bind) = ($k =~ /^-(.+)/) ? $self->_where_op_in_hash($1, $v)
 431                                         : do {
 432          my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 433          $self->$method($k, $v);
 434        };
 435
 436     push @sql_clauses, $sql;
 437     push @all_bind, @bind;
 438   }
 439
 440   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 441 }
 442
 443
 444 sub _where_op_in_hash {
 445   my ($self, $op, $v) = @_;
 446
 447   $op =~ /^(AND|OR|NEST)[_\d]*/i
 448     or puke "unknown operator: -$op";
 449   $op = uc($1); # uppercase, remove trailing digits
 450   $self->_debug("OP(-$op) within hashref, recursing...");
 451
 452   $self->_SWITCH_refkind($v, {
 453
 454     ARRAYREF => sub {
 455       return $self->_where_ARRAYREF($v, $op eq 'NEST' ? '' : $op);
 456     },
 457
 458     HASHREF => sub {
 459       if ($op eq 'OR') {
 460         return $self->_where_ARRAYREF([%$v], 'OR');
 461       }
 462       else {                  # NEST | AND
 463         return $self->_where_HASHREF($v);
 464       }
 465     },
 466
 467     SCALARREF  => sub {         # literal SQL
 468       $op eq 'NEST'
 469         or puke "-$op => \\\$scalar not supported, use -nest => ...";
 470       return ($$v);
 471     },
 472
 473     ARRAYREFREF => sub {        # literal SQL
 474       $op eq 'NEST'
 475         or puke "-$op => \\[..] not supported, use -nest => ...";
 476       return @{${$v}};
 477     },
 478
 479     SCALAR => sub { # permissively interpreted as SQL
 480       $op eq 'NEST'
 481         or puke "-$op => 'scalar' not supported, use -nest => \\'scalar'";
 482       belch "literal SQL should be -nest => \\'scalar' "
 483           . "instead of -nest => 'scalar' ";
 484       return ($v);
 485     },
 486
 487     UNDEF => sub {
 488       puke "-$op => undef not supported";
 489     },
 490    });
 491 }
 492
 493
 494 sub _where_hashpair_ARRAYREF {
 495   my ($self, $k, $v) = @_;
 496
 497   if( @$v ) {
 498     my @v = @$v; # need copy because of shift below
 499     $self->_debug("ARRAY($k) means distribute over elements");
 500
 501     # put apart first element if it is an operator (-and, -or)
 502     my $op = ($v[0] =~ /^ - (?: AND|OR ) $/ix
 503       ? shift @v
 504       : ''
 505     );
 506     my @distributed = map { {$k =>  $_} } @v;
 507
 508     if ($op) {
 509       $self->_debug("OP($op) reinjected into the distributed array");
 510       unshift @distributed, $op;
 511     }
 512
 513     my $logic = $op ? substr($op, 1) : '';
 514
 515     return $self->_recurse_where(\@distributed, $logic);
 516   }
 517   else {
 518     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 519     $self->_debug("empty ARRAY($k) means 0=1");
 520     return ($self->{sqlfalse});
 521   }
 522 }
 523
 524 sub _where_hashpair_HASHREF {
 525   my ($self, $k, $v) = @_;
 526
 527   my (@all_sql, @all_bind);
 528
 529   for my $op (sort keys %$v) {
 530     my $val = $v->{$op};
 531
 532     # put the operator in canonical form
 533     $op =~ s/^-//;       # remove initial dash
 534     $op =~ tr/_/ /;      # underscores become spaces
 535     $op =~ s/^\s+//;     # no initial space
 536     $op =~ s/\s+$//;     # no final space
 537     $op =~ s/\s+/ /;     # multiple spaces become one
 538
 539     my ($sql, @bind);
 540
 541     # CASE: special operators like -in or -between
 542     my $special_op = first {$op =~ $_->{regex}} @{$self->{special_ops}};
 543     if ($special_op) {
 544       ($sql, @bind) = $special_op->{handler}->($self, $k, $op, $val);
 545     }
 546     else {
 547       $self->_SWITCH_refkind($val, {
 548
 549         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 550           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 551         },
 552
 553         SCALARREF => sub {      # CASE: col => {op => \$scalar} (literal SQL without bind)
 554           $sql  = join ' ', $self->_convert($self->_quote($k)),
 555                             $self->_sqlcase($op),
 556                             $$val;
 557         },
 558
 559         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 560           my ($sub_sql, @sub_bind) = @$$val;
 561           $self->_assert_bindval_matches_bindtype(@sub_bind);
 562           $sql  = join ' ', $self->_convert($self->_quote($k)),
 563                             $self->_sqlcase($op),
 564                             $sub_sql;
 565           @bind = @sub_bind;
 566         },
 567
 568         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 569           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 570                    ($op =~ $self->{inequality_op}) ? 'is not' :
 571                puke "unexpected operator '$op' with undef operand";
 572           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 573         },
 574
 575         FALLBACK => sub {       # CASE: col => {op => $scalar}
 576           $sql  = join ' ', $self->_convert($self->_quote($k)),
 577                             $self->_sqlcase($op),
 578                             $self->_convert('?');
 579           @bind = $self->_bindtype($k, $val);
 580         },
 581       });
 582     }
 583
 584     push @all_sql, $sql;
 585     push @all_bind, @bind;
 586   }
 587
 588   return $self->_join_sql_clauses('and', \@all_sql, \@all_bind);
 589 }
 590
 591
 592
 593 sub _where_field_op_ARRAYREF {
 594   my ($self, $k, $op, $vals) = @_;
 595
 596   if(@$vals) {
 597     $self->_debug("ARRAY($vals) means multiple elements: [ @$vals ]");
 598
 599     # LDNOTE : had planned to change the distribution logic when
 600     # $op =~ $self->{inequality_op}, because of Morgan laws :
 601     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 602     # WHERE field != 22 OR  field != 33 : the user probably means
 603     # WHERE field != 22 AND field != 33.
 604     # To do this, replace the line below by :
 605     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 606     # return $self->_recurse_where([map { {$k => {$op, $_}} } @$vals], $logic);
 607
 608     # distribute $op over each member of @$vals
 609     return $self->_recurse_where([map { {$k => {$op, $_}} } @$vals]);
 610   }
 611   else {
 612     # try to DWIM on equality operators
 613     # LDNOTE : not 100% sure this is the correct thing to do ...
 614     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 615     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 616
 617     # otherwise
 618     puke "operator '$op' applied on an empty array (field '$k')";
 619   }
 620 }
 621
 622
 623 sub _where_hashpair_SCALARREF {
 624   my ($self, $k, $v) = @_;
 625   $self->_debug("SCALAR($k) means literal SQL: $$v");
 626   my $sql = $self->_quote($k) . " " . $$v;
 627   return ($sql);
 628 }
 629
 630 # literal SQL with bind
 631 sub _where_hashpair_ARRAYREFREF {
 632   my ($self, $k, $v) = @_;
 633   $self->_debug("REF($k) means literal SQL: @${$v}");
 634   my ($sql, @bind) = @${$v};
 635   $self->_assert_bindval_matches_bindtype(@bind);
 636   $sql  = $self->_quote($k) . " " . $sql;
 637   return ($sql, @bind );
 638 }
 639
 640 # literal SQL without bind
 641 sub _where_hashpair_SCALAR {
 642   my ($self, $k, $v) = @_;
 643   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 644   my $sql = join ' ', $self->_convert($self->_quote($k)),
 645                       $self->_sqlcase($self->{cmp}),
 646                       $self->_convert('?');
 647   my @bind =  $self->_bindtype($k, $v);
 648   return ( $sql, @bind);
 649 }
 650
 651
 652 sub _where_hashpair_UNDEF {
 653   my ($self, $k, $v) = @_;
 654   $self->_debug("UNDEF($k) means IS NULL");
 655   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 656   return ($sql);
 657 }
 658
 659 #======================================================================
 660 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 661 #======================================================================
 662
 663
 664 sub _where_SCALARREF {
 665   my ($self, $where) = @_;
 666
 667   # literal sql
 668   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 669   return ($$where);
 670 }
 671
 672
 673 sub _where_SCALAR {
 674   my ($self, $where) = @_;
 675
 676   # literal sql
 677   $self->_debug("NOREF(*top) means literal SQL: $where");
 678   return ($where);
 679 }
 680
 681
 682 sub _where_UNDEF {
 683   my ($self) = @_;
 684   return ();
 685 }
 686
 687
 688 #======================================================================
 689 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 690 #======================================================================
 691
 692
 693 sub _where_field_BETWEEN {
 694   my ($self, $k, $op, $vals) = @_;
 695
 696   ref $vals eq 'ARRAY' && @$vals == 2
 697     or puke "special op 'between' requires an arrayref of two values";
 698
 699   my ($label)       = $self->_convert($self->_quote($k));
 700   my ($placeholder) = $self->_convert('?');
 701   my $and           = $self->_sqlcase('and');
 702   $op               = $self->_sqlcase($op);
 703
 704   my $sql  = "( $label $op $placeholder $and $placeholder )";
 705   my @bind = $self->_bindtype($k, @$vals);
 706   return ($sql, @bind)
 707 }
 708
 709
 710 sub _where_field_IN {
 711   my ($self, $k, $op, $vals) = @_;
 712
 713   # backwards compatibility : if scalar, force into an arrayref
 714   $vals = [$vals] if defined $vals && ! ref $vals;
 715
 716   my ($label)       = $self->_convert($self->_quote($k));
 717   my ($placeholder) = $self->_convert('?');
 718   $op               = $self->_sqlcase($op);
 719
 720   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
 721     ARRAYREF => sub {     # list of choices
 722       if (@$vals) { # nonempty list
 723         my $placeholders  = join ", ", (($placeholder) x @$vals);
 724         my $sql           = "$label $op ( $placeholders )";
 725         my @bind = $self->_bindtype($k, @$vals);
 726
 727         return ($sql, @bind);
 728       }
 729       else { # empty list : some databases won't understand "IN ()", so DWIM
 730         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
 731         return ($sql);
 732       }
 733     },
 734
 735     ARRAYREFREF => sub {  # literal SQL with bind
 736       my ($sql, @bind) = @$$vals;
 737       $self->_assert_bindval_matches_bindtype(@bind);
 738       return ("$label $op ( $sql )", @bind);
 739     },
 740
 741     FALLBACK => sub {
 742       puke "special op 'in' requires an arrayref (or arrayref-ref)";
 743     },
 744   });
 745
 746   return ($sql, @bind);
 747 }
 748
 749
 750
 751
 752
 753
 754 #======================================================================
 755 # ORDER BY
 756 #======================================================================
 757
 758 sub _order_by {
 759   my ($self, $arg) = @_;
 760
 761   # construct list of ordering instructions
 762   my @order = $self->_SWITCH_refkind($arg, {
 763
 764     ARRAYREF => sub {
 765       map {$self->_SWITCH_refkind($_, {
 766               SCALAR    => sub {$self->_quote($_)},
 767               UNDEF     => sub {},
 768               SCALARREF => sub {$$_}, # literal SQL, no quoting
 769               HASHREF   => sub {$self->_order_by_hash($_)}
 770              }) } @$arg;
 771     },
 772
 773     SCALAR    => sub {$self->_quote($arg)},
 774     UNDEF     => sub {},
 775     SCALARREF => sub {$$arg}, # literal SQL, no quoting
 776     HASHREF   => sub {$self->_order_by_hash($arg)},
 777
 778   });
 779
 780   # build SQL
 781   my $order = join ', ', @order;
 782   return $order ? $self->_sqlcase(' order by')." $order" : '';
 783 }
 784
 785
 786 sub _order_by_hash {
 787   my ($self, $hash) = @_;
 788
 789   # get first pair in hash
 790   my ($key, $val) = each %$hash;
 791
 792   # check if one pair was found and no other pair in hash
 793   $key && !(each %$hash)
 794     or puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
 795
 796   my ($order) = ($key =~ /^-(desc|asc)/i)
 797     or puke "invalid key in _order_by hash : $key";
 798
 799   return $self->_quote($val) ." ". $self->_sqlcase($order);
 800 }
 801
 802
 803
 804 #======================================================================
 805 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
 806 #======================================================================
 807
 808 sub _table  {
 809   my $self = shift;
 810   my $from = shift;
 811   $self->_SWITCH_refkind($from, {
 812     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
 813     SCALAR       => sub {$self->_quote($from)},
 814     SCALARREF    => sub {$$from},
 815     ARRAYREFREF  => sub {join ', ', @$from;},
 816   });
 817 }
 818
 819
 820 #======================================================================
 821 # UTILITY FUNCTIONS
 822 #======================================================================
 823
 824 sub _quote {
 825   my $self  = shift;
 826   my $label = shift;
 827
 828   $label or puke "can't quote an empty label";
 829
 830   # left and right quote characters
 831   my ($ql, $qr, @other) = $self->_SWITCH_refkind($self->{quote_char}, {
 832     SCALAR   => sub {($self->{quote_char}, $self->{quote_char})},
 833     ARRAYREF => sub {@{$self->{quote_char}}},
 834     UNDEF    => sub {()},
 835    });
 836   not @other
 837       or puke "quote_char must be an arrayref of 2 values";
 838
 839   # no quoting if no quoting chars
 840   $ql or return $label;
 841
 842   # no quoting for literal SQL
 843   return $$label if ref($label) eq 'SCALAR';
 844
 845   # separate table / column (if applicable)
 846   my $sep = $self->{name_sep} || '';
 847   my @to_quote = $sep ? split /\Q$sep\E/, $label : ($label);
 848
 849   # do the quoting, except for "*" or for `table`.*
 850   my @quoted = map { $_ eq '*' ? $_: $ql.$_.$qr} @to_quote;
 851
 852   # reassemble and return.
 853   return join $sep, @quoted;
 854 }
 855
 856
 857 # Conversion, if applicable
 858 sub _convert ($) {
 859   my ($self, $arg) = @_;
 860
 861 # LDNOTE : modified the previous implementation below because
 862 # it was not consistent : the first "return" is always an array,
 863 # the second "return" is context-dependent. Anyway, _convert
 864 # seems always used with just a single argument, so make it a
 865 # scalar function.
 866 #     return @_ unless $self->{convert};
 867 #     my $conv = $self->_sqlcase($self->{convert});
 868 #     my @ret = map { $conv.'('.$_.')' } @_;
 869 #     return wantarray ? @ret : $ret[0];
 870   if ($self->{convert}) {
 871     my $conv = $self->_sqlcase($self->{convert});
 872     $arg = $conv.'('.$arg.')';
 873   }
 874   return $arg;
 875 }
 876
 877 # And bindtype
 878 sub _bindtype (@) {
 879   my $self = shift;
 880   my($col, @vals) = @_;
 881
 882   #LDNOTE : changed original implementation below because it did not make
 883   # sense when bindtype eq 'columns' and @vals > 1.
 884 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
 885
 886   return $self->{bindtype} eq 'columns' ? map {[$col, $_]} @vals : @vals;
 887 }
 888
 889 # Dies if any element of @bind is not in [colname => value] format
 890 # if bindtype is 'columns'.
 891 sub _assert_bindval_matches_bindtype {
 892   my ($self, @bind) = @_;
 893
 894   if ($self->{bindtype} eq 'columns') {
 895     foreach my $val (@bind) {
 896       if (!defined $val || ref($val) ne 'ARRAY' || @$val != 2) {
 897         die "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
 898       }
 899     }
 900   }
 901 }
 902
 903 sub _join_sql_clauses {
 904   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
 905
 906   if (@$clauses_aref > 1) {
 907     my $join  = " " . $self->_sqlcase($logic) . " ";
 908     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
 909     return ($sql, @$bind_aref);
 910   }
 911   elsif (@$clauses_aref) {
 912     return ($clauses_aref->[0], @$bind_aref); # no parentheses
 913   }
 914   else {
 915     return (); # if no SQL, ignore @$bind_aref
 916   }
 917 }
 918
 919
 920 # Fix SQL case, if so requested
 921 sub _sqlcase {
 922   my $self = shift;
 923
 924   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
 925   # don't touch the argument ... crooked logic, but let's not change it!
 926   return $self->{case} ? $_[0] : uc($_[0]);
 927 }
 928
 929
 930 #======================================================================
 931 # DISPATCHING FROM REFKIND
 932 #======================================================================
 933
 934 sub _refkind {
 935   my ($self, $data) = @_;
 936   my $suffix = '';
 937   my $ref;
 938   my $n_steps = 0;
 939
 940   while (1) {
 941     # blessed objects are treated like scalars
 942     $ref = (blessed $data) ? '' : ref $data;
 943     $n_steps += 1 if $ref;
 944     last          if $ref ne 'REF';
 945     $data = $$data;
 946   }
 947
 948   my $base = $ref || (defined $data ? 'SCALAR' : 'UNDEF');
 949
 950   return $base . ('REF' x $n_steps);
 951 }
 952
 953
 954
 955 sub _try_refkind {
 956   my ($self, $data) = @_;
 957   my @try = ($self->_refkind($data));
 958   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
 959   push @try, 'FALLBACK';
 960   return @try;
 961 }
 962
 963 sub _METHOD_FOR_refkind {
 964   my ($self, $meth_prefix, $data) = @_;
 965   my $method = first {$_} map {$self->can($meth_prefix."_".$_)}
 966                               $self->_try_refkind($data)
 967     or puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
 968   return $method;
 969 }
 970
 971
 972 sub _SWITCH_refkind {
 973   my ($self, $data, $dispatch_table) = @_;
 974
 975   my $coderef = first {$_} map {$dispatch_table->{$_}}
 976                                $self->_try_refkind($data)
 977     or puke "no dispatch entry for ".$self->_refkind($data);
 978   $coderef->();
 979 }
 980
 981
 982
 983
 984 #======================================================================
 985 # VALUES, GENERATE, AUTOLOAD
 986 #======================================================================
 987
 988 # LDNOTE: original code from nwiger, didn't touch code in that section
 989 # I feel the AUTOLOAD stuff should not be the default, it should
 990 # only be activated on explicit demand by user.
 991
 992 sub values {
 993     my $self = shift;
 994     my $data = shift || return;
 995     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
 996         unless ref $data eq 'HASH';
 997
 998     my @all_bind;
 999     foreach my $k ( sort keys %$data ) {
1000         my $v = $data->{$k};
1001         $self->_SWITCH_refkind($v, {
1002           ARRAYREF => sub {
1003             if ($self->{array_datatypes}) { # array datatype
1004               push @all_bind, $self->_bindtype($k, $v);
1005             }
1006             else {                          # literal SQL with bind
1007               my ($sql, @bind) = @$v;
1008               $self->_assert_bindval_matches_bindtype(@bind);
1009               push @all_bind, @bind;
1010             }
1011           },
1012           ARRAYREFREF => sub { # literal SQL with bind
1013             my ($sql, @bind) = @${$v};
1014             $self->_assert_bindval_matches_bindtype(@bind);
1015             push @all_bind, @bind;
1016           },
1017           SCALARREF => sub {  # literal SQL without bind
1018           },
1019           SCALAR_or_UNDEF => sub {
1020             push @all_bind, $self->_bindtype($k, $v);
1021           },
1022         });
1023     }
1024
1025     return @all_bind;
1026 }
1027
1028 sub generate {
1029     my $self  = shift;
1030
1031     my(@sql, @sqlq, @sqlv);
1032
1033     for (@_) {
1034         my $ref = ref $_;
1035         if ($ref eq 'HASH') {
1036             for my $k (sort keys %$_) {
1037                 my $v = $_->{$k};
1038                 my $r = ref $v;
1039                 my $label = $self->_quote($k);
1040                 if ($r eq 'ARRAY') {
1041                     # literal SQL with bind
1042                     my ($sql, @bind) = @$v;
1043                     $self->_assert_bindval_matches_bindtype(@bind);
1044                     push @sqlq, "$label = $sql";
1045                     push @sqlv, @bind;
1046                 } elsif ($r eq 'SCALAR') {
1047                     # literal SQL without bind
1048                     push @sqlq, "$label = $$v";
1049                 } else {
1050                     push @sqlq, "$label = ?";
1051                     push @sqlv, $self->_bindtype($k, $v);
1052                 }
1053             }
1054             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1055         } elsif ($ref eq 'ARRAY') {
1056             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1057             for my $v (@$_) {
1058                 my $r = ref $v;
1059                 if ($r eq 'ARRAY') {   # literal SQL with bind
1060                     my ($sql, @bind) = @$v;
1061                     $self->_assert_bindval_matches_bindtype(@bind);
1062                     push @sqlq, $sql;
1063                     push @sqlv, @bind;
1064                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1065                     # embedded literal SQL
1066                     push @sqlq, $$v;
1067                 } else {
1068                     push @sqlq, '?';
1069                     push @sqlv, $v;
1070                 }
1071             }
1072             push @sql, '(' . join(', ', @sqlq) . ')';
1073         } elsif ($ref eq 'SCALAR') {
1074             # literal SQL
1075             push @sql, $$_;
1076         } else {
1077             # strings get case twiddled
1078             push @sql, $self->_sqlcase($_);
1079         }
1080     }
1081
1082     my $sql = join ' ', @sql;
1083
1084     # this is pretty tricky
1085     # if ask for an array, return ($stmt, @bind)
1086     # otherwise, s/?/shift @sqlv/ to put it inline
1087     if (wantarray) {
1088         return ($sql, @sqlv);
1089     } else {
1090         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1091                              ref $d ? $d->[1] : $d/e;
1092         return $sql;
1093     }
1094 }
1095
1096
1097 sub DESTROY { 1 }
1098
1099 sub AUTOLOAD {
1100     # This allows us to check for a local, then _form, attr
1101     my $self = shift;
1102     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1103     return $self->generate($name, @_);
1104 }
1105
1106 1;
1107
1108
1109
1110 __END__
1111
1112 =head1 NAME
1113
1114 SQL::Abstract - Generate SQL from Perl data structures
1115
1116 =head1 SYNOPSIS
1117
1118     use SQL::Abstract;
1119
1120     my $sql = SQL::Abstract->new;
1121
1122     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1123
1124     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1125
1126     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1127
1128     my($stmt, @bind) = $sql->delete($table, \%where);
1129
1130     # Then, use these in your DBI statements
1131     my $sth = $dbh->prepare($stmt);
1132     $sth->execute(@bind);
1133
1134     # Just generate the WHERE clause
1135     my($stmt, @bind) = $sql->where(\%where, \@order);
1136
1137     # Return values in the same order, for hashed queries
1138     # See PERFORMANCE section for more details
1139     my @bind = $sql->values(\%fieldvals);
1140
1141 =head1 DESCRIPTION
1142
1143 This module was inspired by the excellent L<DBIx::Abstract>.
1144 However, in using that module I found that what I really wanted
1145 to do was generate SQL, but still retain complete control over my
1146 statement handles and use the DBI interface. So, I set out to
1147 create an abstract SQL generation module.
1148
1149 While based on the concepts used by L<DBIx::Abstract>, there are
1150 several important differences, especially when it comes to WHERE
1151 clauses. I have modified the concepts used to make the SQL easier
1152 to generate from Perl data structures and, IMO, more intuitive.
1153 The underlying idea is for this module to do what you mean, based
1154 on the data structures you provide it. The big advantage is that
1155 you don't have to modify your code every time your data changes,
1156 as this module figures it out.
1157
1158 To begin with, an SQL INSERT is as easy as just specifying a hash
1159 of C<key=value> pairs:
1160
1161     my %data = (
1162         name => 'Jimbo Bobson',
1163         phone => '123-456-7890',
1164         address => '42 Sister Lane',
1165         city => 'St. Louis',
1166         state => 'Louisiana',
1167     );
1168
1169 The SQL can then be generated with this:
1170
1171     my($stmt, @bind) = $sql->insert('people', \%data);
1172
1173 Which would give you something like this:
1174
1175     $stmt = "INSERT INTO people
1176                     (address, city, name, phone, state)
1177                     VALUES (?, ?, ?, ?, ?)";
1178     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1179              '123-456-7890', 'Louisiana');
1180
1181 These are then used directly in your DBI code:
1182
1183     my $sth = $dbh->prepare($stmt);
1184     $sth->execute(@bind);
1185
1186 =head2 Inserting and Updating Arrays
1187
1188 If your database has array types (like for example Postgres),
1189 activate the special option C<< array_datatypes => 1 >>
1190 when creating the C<SQL::Abstract> object.
1191 Then you may use an arrayref to insert and update database array types:
1192
1193     my $sql = SQL::Abstract->new(array_datatypes => 1);
1194     my %data = (
1195         planets => [qw/Mercury Venus Earth Mars/]
1196     );
1197
1198     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1199
1200 This results in:
1201
1202     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1203
1204     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1205
1206
1207 =head2 Inserting and Updating SQL
1208
1209 In order to apply SQL functions to elements of your C<%data> you may
1210 specify a reference to an arrayref for the given hash value. For example,
1211 if you need to execute the Oracle C<to_date> function on a value, you can
1212 say something like this:
1213
1214     my %data = (
1215         name => 'Bill',
1216         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1217     );
1218
1219 The first value in the array is the actual SQL. Any other values are
1220 optional and would be included in the bind values array. This gives
1221 you:
1222
1223     my($stmt, @bind) = $sql->insert('people', \%data);
1224
1225     $stmt = "INSERT INTO people (name, date_entered)
1226                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1227     @bind = ('Bill', '03/02/2003');
1228
1229 An UPDATE is just as easy, all you change is the name of the function:
1230
1231     my($stmt, @bind) = $sql->update('people', \%data);
1232
1233 Notice that your C<%data> isn't touched; the module will generate
1234 the appropriately quirky SQL for you automatically. Usually you'll
1235 want to specify a WHERE clause for your UPDATE, though, which is
1236 where handling C<%where> hashes comes in handy...
1237
1238 =head2 Complex where statements
1239
1240 This module can generate pretty complicated WHERE statements
1241 easily. For example, simple C<key=value> pairs are taken to mean
1242 equality, and if you want to see if a field is within a set
1243 of values, you can use an arrayref. Let's say we wanted to
1244 SELECT some data based on this criteria:
1245
1246     my %where = (
1247        requestor => 'inna',
1248        worker => ['nwiger', 'rcwe', 'sfz'],
1249        status => { '!=', 'completed' }
1250     );
1251
1252     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1253
1254 The above would give you something like this:
1255
1256     $stmt = "SELECT * FROM tickets WHERE
1257                 ( requestor = ? ) AND ( status != ? )
1258                 AND ( worker = ? OR worker = ? OR worker = ? )";
1259     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1260
1261 Which you could then use in DBI code like so:
1262
1263     my $sth = $dbh->prepare($stmt);
1264     $sth->execute(@bind);
1265
1266 Easy, eh?
1267
1268 =head1 FUNCTIONS
1269
1270 The functions are simple. There's one for each major SQL operation,
1271 and a constructor you use first. The arguments are specified in a
1272 similar order to each function (table, then fields, then a where
1273 clause) to try and simplify things.
1274
1275
1276
1277
1278 =head2 new(option => 'value')
1279
1280 The C<new()> function takes a list of options and values, and returns
1281 a new B<SQL::Abstract> object which can then be used to generate SQL
1282 through the methods below. The options accepted are:
1283
1284 =over
1285
1286 =item case
1287
1288 If set to 'lower', then SQL will be generated in all lowercase. By
1289 default SQL is generated in "textbook" case meaning something like:
1290
1291     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1292
1293 Any setting other than 'lower' is ignored.
1294
1295 =item cmp
1296
1297 This determines what the default comparison operator is. By default
1298 it is C<=>, meaning that a hash like this:
1299
1300     %where = (name => 'nwiger', email => 'nate@wiger.org');
1301
1302 Will generate SQL like this:
1303
1304     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1305
1306 However, you may want loose comparisons by default, so if you set
1307 C<cmp> to C<like> you would get SQL such as:
1308
1309     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1310
1311 You can also override the comparsion on an individual basis - see
1312 the huge section on L</"WHERE CLAUSES"> at the bottom.
1313
1314 =item sqltrue, sqlfalse
1315
1316 Expressions for inserting boolean values within SQL statements.
1317 By default these are C<1=1> and C<1=0>.
1318
1319 =item logic
1320
1321 This determines the default logical operator for multiple WHERE
1322 statements in arrays or hashes. If absent, the default logic is "or"
1323 for arrays, and "and" for hashes. This means that a WHERE
1324 array of the form:
1325
1326     @where = (
1327         event_date => {'>=', '2/13/99'},
1328         event_date => {'<=', '4/24/03'},
1329     );
1330
1331 will generate SQL like this:
1332
1333     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1334
1335 This is probably not what you want given this query, though (look
1336 at the dates). To change the "OR" to an "AND", simply specify:
1337
1338     my $sql = SQL::Abstract->new(logic => 'and');
1339
1340 Which will change the above C<WHERE> to:
1341
1342     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1343
1344 The logic can also be changed locally by inserting
1345 a modifier in front of an arrayref :
1346
1347     @where = (-and => [event_date => {'>=', '2/13/99'},
1348                        event_date => {'<=', '4/24/03'} ]);
1349
1350 See the L</"WHERE CLAUSES"> section for explanations.
1351
1352 =item convert
1353
1354 This will automatically convert comparisons using the specified SQL
1355 function for both column and value. This is mostly used with an argument
1356 of C<upper> or C<lower>, so that the SQL will have the effect of
1357 case-insensitive "searches". For example, this:
1358
1359     $sql = SQL::Abstract->new(convert => 'upper');
1360     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1361
1362 Will turn out the following SQL:
1363
1364     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1365
1366 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1367 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1368 not validate this option; it will just pass through what you specify verbatim).
1369
1370 =item bindtype
1371
1372 This is a kludge because many databases suck. For example, you can't
1373 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1374 Instead, you have to use C<bind_param()>:
1375
1376     $sth->bind_param(1, 'reg data');
1377     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1378
1379 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1380 which loses track of which field each slot refers to. Fear not.
1381
1382 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1383 Currently, you can specify either C<normal> (default) or C<columns>. If you
1384 specify C<columns>, you will get an array that looks like this:
1385
1386     my $sql = SQL::Abstract->new(bindtype => 'columns');
1387     my($stmt, @bind) = $sql->insert(...);
1388
1389     @bind = (
1390         [ 'column1', 'value1' ],
1391         [ 'column2', 'value2' ],
1392         [ 'column3', 'value3' ],
1393     );
1394
1395 You can then iterate through this manually, using DBI's C<bind_param()>.
1396
1397     $sth->prepare($stmt);
1398     my $i = 1;
1399     for (@bind) {
1400         my($col, $data) = @$_;
1401         if ($col eq 'details' || $col eq 'comments') {
1402             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1403         } elsif ($col eq 'image') {
1404             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1405         } else {
1406             $sth->bind_param($i, $data);
1407         }
1408         $i++;
1409     }
1410     $sth->execute;      # execute without @bind now
1411
1412 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1413 Basically, the advantage is still that you don't have to care which fields
1414 are or are not included. You could wrap that above C<for> loop in a simple
1415 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1416 get a layer of abstraction over manual SQL specification.
1417
1418 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1419 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1420 will expect the bind values in this format.
1421
1422 =item quote_char
1423
1424 This is the character that a table or column name will be quoted
1425 with.  By default this is an empty string, but you could set it to
1426 the character C<`>, to generate SQL like this:
1427
1428   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1429
1430 Alternatively, you can supply an array ref of two items, the first being the left
1431 hand quote character, and the second the right hand quote character. For
1432 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1433 that generates SQL like this:
1434
1435   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1436
1437 Quoting is useful if you have tables or columns names that are reserved
1438 words in your database's SQL dialect.
1439
1440 =item name_sep
1441
1442 This is the character that separates a table and column name.  It is
1443 necessary to specify this when the C<quote_char> option is selected,
1444 so that tables and column names can be individually quoted like this:
1445
1446   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1447
1448 =item array_datatypes
1449
1450 When this option is true, arrayrefs in INSERT or UPDATE are
1451 interpreted as array datatypes and are passed directly
1452 to the DBI layer.
1453 When this option is false, arrayrefs are interpreted
1454 as literal SQL, just like refs to arrayrefs
1455 (but this behavior is for backwards compatibility; when writing
1456 new queries, use the "reference to arrayref" syntax
1457 for literal SQL).
1458
1459
1460 =item special_ops
1461
1462 Takes a reference to a list of "special operators"
1463 to extend the syntax understood by L<SQL::Abstract>.
1464 See section L</"SPECIAL OPERATORS"> for details.
1465
1466
1467
1468 =back
1469
1470 =head2 insert($table, \@values || \%fieldvals)
1471
1472 This is the simplest function. You simply give it a table name
1473 and either an arrayref of values or hashref of field/value pairs.
1474 It returns an SQL INSERT statement and a list of bind values.
1475 See the sections on L</"Inserting and Updating Arrays"> and
1476 L</"Inserting and Updating SQL"> for information on how to insert
1477 with those data types.
1478
1479 =head2 update($table, \%fieldvals, \%where)
1480
1481 This takes a table, hashref of field/value pairs, and an optional
1482 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1483 of bind values.
1484 See the sections on L</"Inserting and Updating Arrays"> and
1485 L</"Inserting and Updating SQL"> for information on how to insert
1486 with those data types.
1487
1488 =head2 select($source, $fields, $where, $order)
1489
1490 This returns a SQL SELECT statement and associated list of bind values, as
1491 specified by the arguments  :
1492
1493 =over
1494
1495 =item $source
1496
1497 Specification of the 'FROM' part of the statement.
1498 The argument can be either a plain scalar (interpreted as a table
1499 name, will be quoted), or an arrayref (interpreted as a list
1500 of table names, joined by commas, quoted), or a scalarref
1501 (literal table name, not quoted), or a ref to an arrayref
1502 (list of literal table names, joined by commas, not quoted).
1503
1504 =item $fields
1505
1506 Specification of the list of fields to retrieve from
1507 the source.
1508 The argument can be either an arrayref (interpreted as a list
1509 of field names, will be joined by commas and quoted), or a
1510 plain scalar (literal SQL, not quoted).
1511 Please observe that this API is not as flexible as for
1512 the first argument C<$table>, for backwards compatibility reasons.
1513
1514 =item $where
1515
1516 Optional argument to specify the WHERE part of the query.
1517 The argument is most often a hashref, but can also be
1518 an arrayref or plain scalar --
1519 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1520
1521 =item $order
1522
1523 Optional argument to specify the ORDER BY part of the query.
1524 The argument can be a scalar, a hashref or an arrayref
1525 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1526 for details.
1527
1528 =back
1529
1530
1531 =head2 delete($table, \%where)
1532
1533 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1534 It returns an SQL DELETE statement and list of bind values.
1535
1536 =head2 where(\%where, \@order)
1537
1538 This is used to generate just the WHERE clause. For example,
1539 if you have an arbitrary data structure and know what the
1540 rest of your SQL is going to look like, but want an easy way
1541 to produce a WHERE clause, use this. It returns an SQL WHERE
1542 clause and list of bind values.
1543
1544
1545 =head2 values(\%data)
1546
1547 This just returns the values from the hash C<%data>, in the same
1548 order that would be returned from any of the other above queries.
1549 Using this allows you to markedly speed up your queries if you
1550 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1551
1552 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1553
1554 Warning: This is an experimental method and subject to change.
1555
1556 This returns arbitrarily generated SQL. It's a really basic shortcut.
1557 It will return two different things, depending on return context:
1558
1559     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1560     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
1561
1562 These would return the following:
1563
1564     # First calling form
1565     $stmt = "CREATE TABLE test (?, ?)";
1566     @bind = (field1, field2);
1567
1568     # Second calling form
1569     $stmt_and_val = "CREATE TABLE test (field1, field2)";
1570
1571 Depending on what you're trying to do, it's up to you to choose the correct
1572 format. In this example, the second form is what you would want.
1573
1574 By the same token:
1575
1576     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
1577
1578 Might give you:
1579
1580     ALTER SESSION SET nls_date_format = 'MM/YY'
1581
1582 You get the idea. Strings get their case twiddled, but everything
1583 else remains verbatim.
1584
1585
1586
1587
1588 =head1 WHERE CLAUSES
1589
1590 =head2 Introduction
1591
1592 This module uses a variation on the idea from L<DBIx::Abstract>. It
1593 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
1594 module is that things in arrays are OR'ed, and things in hashes
1595 are AND'ed.>
1596
1597 The easiest way to explain is to show lots of examples. After
1598 each C<%where> hash shown, it is assumed you used:
1599
1600     my($stmt, @bind) = $sql->where(\%where);
1601
1602 However, note that the C<%where> hash can be used directly in any
1603 of the other functions as well, as described above.
1604
1605 =head2 Key-value pairs
1606
1607 So, let's get started. To begin, a simple hash:
1608
1609     my %where  = (
1610         user   => 'nwiger',
1611         status => 'completed'
1612     );
1613
1614 Is converted to SQL C<key = val> statements:
1615
1616     $stmt = "WHERE user = ? AND status = ?";
1617     @bind = ('nwiger', 'completed');
1618
1619 One common thing I end up doing is having a list of values that
1620 a field can be in. To do this, simply specify a list inside of
1621 an arrayref:
1622
1623     my %where  = (
1624         user   => 'nwiger',
1625         status => ['assigned', 'in-progress', 'pending'];
1626     );
1627
1628 This simple code will create the following:
1629
1630     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
1631     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
1632
1633 A field associated to an empty arrayref will be considered a
1634 logical false and will generate 0=1.
1635
1636 =head2 Key-value pairs
1637
1638 If you want to specify a different type of operator for your comparison,
1639 you can use a hashref for a given column:
1640
1641     my %where  = (
1642         user   => 'nwiger',
1643         status => { '!=', 'completed' }
1644     );
1645
1646 Which would generate:
1647
1648     $stmt = "WHERE user = ? AND status != ?";
1649     @bind = ('nwiger', 'completed');
1650
1651 To test against multiple values, just enclose the values in an arrayref:
1652
1653     status => { '=', ['assigned', 'in-progress', 'pending'] };
1654
1655 Which would give you:
1656
1657     "WHERE status = ? OR status = ? OR status = ?"
1658
1659
1660 The hashref can also contain multiple pairs, in which case it is expanded
1661 into an C<AND> of its elements:
1662
1663     my %where  = (
1664         user   => 'nwiger',
1665         status => { '!=', 'completed', -not_like => 'pending%' }
1666     );
1667
1668     # Or more dynamically, like from a form
1669     $where{user} = 'nwiger';
1670     $where{status}{'!='} = 'completed';
1671     $where{status}{'-not_like'} = 'pending%';
1672
1673     # Both generate this
1674     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
1675     @bind = ('nwiger', 'completed', 'pending%');
1676
1677
1678 To get an OR instead, you can combine it with the arrayref idea:
1679
1680     my %where => (
1681          user => 'nwiger',
1682          priority => [ {'=', 2}, {'!=', 1} ]
1683     );
1684
1685 Which would generate:
1686
1687     $stmt = "WHERE user = ? AND priority = ? OR priority != ?";
1688     @bind = ('nwiger', '2', '1');
1689
1690 If you want to include literal SQL (with or without bind values), just use a
1691 scalar reference or array reference as the value:
1692
1693     my %where  = (
1694         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
1695         date_expires => { '<' => \"now()" }
1696     );
1697
1698 Which would generate:
1699
1700     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
1701     @bind = ('11/26/2008');
1702
1703
1704 =head2 Logic and nesting operators
1705
1706 In the example above,
1707 there is a subtle trap if you want to say something like
1708 this (notice the C<AND>):
1709
1710     WHERE priority != ? AND priority != ?
1711
1712 Because, in Perl you I<can't> do this:
1713
1714     priority => { '!=', 2, '!=', 1 }
1715
1716 As the second C<!=> key will obliterate the first. The solution
1717 is to use the special C<-modifier> form inside an arrayref:
1718
1719     priority => [ -and => {'!=', 2},
1720                           {'!=', 1} ]
1721
1722
1723 Normally, these would be joined by C<OR>, but the modifier tells it
1724 to use C<AND> instead. (Hint: You can use this in conjunction with the
1725 C<logic> option to C<new()> in order to change the way your queries
1726 work by default.) B<Important:> Note that the C<-modifier> goes
1727 B<INSIDE> the arrayref, as an extra first element. This will
1728 B<NOT> do what you think it might:
1729
1730     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
1731
1732 Here is a quick list of equivalencies, since there is some overlap:
1733
1734     # Same
1735     status => {'!=', 'completed', 'not like', 'pending%' }
1736     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
1737
1738     # Same
1739     status => {'=', ['assigned', 'in-progress']}
1740     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
1741     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
1742
1743 In addition to C<-and> and C<-or>, there is also a special C<-nest>
1744 operator which adds an additional set of parens, to create a subquery.
1745 For example, to get something like this:
1746
1747     $stmt = "WHERE user = ? AND ( workhrs > ? OR geo = ? )";
1748     @bind = ('nwiger', '20', 'ASIA');
1749
1750 You would do:
1751
1752     my %where = (
1753          user => 'nwiger',
1754         -nest => [ workhrs => {'>', 20}, geo => 'ASIA' ],
1755     );
1756
1757 If you need several nested subexpressions, you can number
1758 the C<-nest> branches :
1759
1760     my %where = (
1761          user => 'nwiger',
1762         -nest1 => ...,
1763         -nest2 => ...,
1764         ...
1765     );
1766
1767
1768 =head2 Special operators : IN, BETWEEN, etc.
1769
1770 You can also use the hashref format to compare a list of fields using the
1771 C<IN> comparison operator, by specifying the list as an arrayref:
1772
1773     my %where  = (
1774         status   => 'completed',
1775         reportid => { -in => [567, 2335, 2] }
1776     );
1777
1778 Which would generate:
1779
1780     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
1781     @bind = ('completed', '567', '2335', '2');
1782
1783 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
1784 the same way.
1785
1786 Another pair of operators is C<-between> and C<-not_between>,
1787 used with an arrayref of two values:
1788
1789     my %where  = (
1790         user   => 'nwiger',
1791         completion_date => {
1792            -not_between => ['2002-10-01', '2003-02-06']
1793         }
1794     );
1795
1796 Would give you:
1797
1798     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
1799
1800 These are the two builtin "special operators"; but the
1801 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
1802
1803 =head2 Nested conditions
1804
1805 So far, we've seen how multiple conditions are joined with a top-level
1806 C<AND>.  We can change this by putting the different conditions we want in
1807 hashes and then putting those hashes in an array. For example:
1808
1809     my @where = (
1810         {
1811             user   => 'nwiger',
1812             status => { -like => ['pending%', 'dispatched'] },
1813         },
1814         {
1815             user   => 'robot',
1816             status => 'unassigned',
1817         }
1818     );
1819
1820 This data structure would create the following:
1821
1822     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
1823                 OR ( user = ? AND status = ? ) )";
1824     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
1825
1826 This can be combined with the C<-nest> operator to properly group
1827 SQL statements. Furthermore, hashrefs or arrayrefs can be
1828 prefixed with an C<-and> or C<-or> to change the logic
1829 inside :
1830
1831     my @where = (
1832          -and => [
1833             user => 'nwiger',
1834             -nest => [
1835                 -and => [workhrs => {'>', 20}, geo => 'ASIA' ],
1836                 -and => [workhrs => {'<', 50}, geo => 'EURO' ]
1837             ],
1838         ],
1839     );
1840
1841 That would yield:
1842
1843     WHERE ( user = ? AND
1844           ( ( workhrs > ? AND geo = ? )
1845          OR ( workhrs < ? AND geo = ? ) ) )
1846
1847 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
1848 operator goes C<outside> of the nested structure; whereas when connecting
1849 several constraints on one column, the C<-and> operator goes
1850 C<inside> the arrayref. Here is an example combining both features :
1851
1852    my @where = (
1853      -and => [a => 1, b => 2],
1854      -or  => [c => 3, d => 4],
1855       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
1856    )
1857
1858 yielding
1859
1860   WHERE ( (    ( a = ? AND b = ? )
1861             OR ( c = ? OR d = ? )
1862             OR ( e LIKE ? AND e LIKE ? ) ) )
1863
1864
1865 =head2 Literal SQL
1866
1867 Finally, sometimes only literal SQL will do. If you want to include
1868 literal SQL verbatim, you can specify it as a scalar reference, namely:
1869
1870     my $inn = 'is Not Null';
1871     my %where = (
1872         priority => { '<', 2 },
1873         requestor => \$inn
1874     );
1875
1876 This would create:
1877
1878     $stmt = "WHERE priority < ? AND requestor is Not Null";
1879     @bind = ('2');
1880
1881 Note that in this example, you only get one bind parameter back, since
1882 the verbatim SQL is passed as part of the statement.
1883
1884 Of course, just to prove a point, the above can also be accomplished
1885 with this:
1886
1887     my %where = (
1888         priority  => { '<', 2 },
1889         requestor => { '!=', undef },
1890     );
1891
1892
1893 TMTOWTDI.
1894
1895 Conditions on boolean columns can be expressed in the
1896 same way, passing a reference to an empty string :
1897
1898     my %where = (
1899         priority  => { '<', 2 },
1900         is_ready  => \"";
1901     );
1902
1903 which yields
1904
1905     $stmt = "WHERE priority < ? AND is_ready";
1906     @bind = ('2');
1907
1908
1909 =head2 Literal SQL with placeholders and bind values (subqueries)
1910
1911 If the literal SQL to be inserted has placeholders and bind values,
1912 use a reference to an arrayref (yes this is a double reference --
1913 not so common, but perfectly legal Perl). For example, to find a date
1914 in Postgres you can use something like this:
1915
1916     my %where = (
1917        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
1918     )
1919
1920 This would create:
1921
1922     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
1923     @bind = ('10');
1924
1925 Note that you must pass the bind values in the same format as they are returned
1926 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
1927 provide the bind values in the C<< [ column_meta => value ] >> format, where
1928 C<column_meta> is an opaque scalar value; most commonly the column name, but
1929 you can use any scalar value (including references and blessed references),
1930 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
1931 to C<columns> the above example will look like:
1932
1933     my %where = (
1934        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
1935     )
1936
1937 Literal SQL is especially useful for nesting parenthesized clauses in the
1938 main SQL query. Here is a first example :
1939
1940   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
1941                                100, "foo%");
1942   my %where = (
1943     foo => 1234,
1944     bar => \["IN ($sub_stmt)" => @sub_bind],
1945   );
1946
1947 This yields :
1948
1949   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
1950                                              WHERE c2 < ? AND c3 LIKE ?))";
1951   @bind = (1234, 100, "foo%");
1952
1953 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
1954 are expressed in the same way. Of course the C<$sub_stmt> and
1955 its associated bind values can be generated through a former call
1956 to C<select()> :
1957
1958   my ($sub_stmt, @sub_bind)
1959      = $sql->select("t1", "c1", {c2 => {"<" => 100},
1960                                  c3 => {-like => "foo%"}});
1961   my %where = (
1962     foo => 1234,
1963     bar => \["> ALL ($sub_stmt)" => @sub_bind],
1964   );
1965
1966 In the examples above, the subquery was used as an operator on a column;
1967 but the same principle also applies for a clause within the main C<%where>
1968 hash, like an EXISTS subquery :
1969
1970   my ($sub_stmt, @sub_bind)
1971      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
1972   my %where = (
1973     foo   => 1234,
1974     -nest => \["EXISTS ($sub_stmt)" => @sub_bind],
1975   );
1976
1977 which yields
1978
1979   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
1980                                         WHERE c1 = ? AND c2 > t0.c0))";
1981   @bind = (1234, 1);
1982
1983
1984 Observe that the condition on C<c2> in the subquery refers to
1985 column C<t0.c0> of the main query : this is I<not> a bind
1986 value, so we have to express it through a scalar ref.
1987 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
1988 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
1989 what we wanted here.
1990
1991 Another use of the subquery technique is when some SQL clauses need
1992 parentheses, as it often occurs with some proprietary SQL extensions
1993 like for example fulltext expressions, geospatial expressions,
1994 NATIVE clauses, etc. Here is an example of a fulltext query in MySQL :
1995
1996   my %where = (
1997     -nest => \["MATCH (col1, col2) AGAINST (?)" => qw/apples/]
1998   );
1999
2000 Finally, here is an example where a subquery is used
2001 for expressing unary negation:
2002
2003   my ($sub_stmt, @sub_bind)
2004      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2005   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2006   my %where = (
2007         lname  => {like => '%son%'},
2008         -nest  => \["NOT ($sub_stmt)" => @sub_bind],
2009     );
2010
2011 This yields
2012
2013   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2014   @bind = ('%son%', 10, 20)
2015
2016
2017
2018 =head2 Conclusion
2019
2020 These pages could go on for a while, since the nesting of the data
2021 structures this module can handle are pretty much unlimited (the
2022 module implements the C<WHERE> expansion as a recursive function
2023 internally). Your best bet is to "play around" with the module a
2024 little to see how the data structures behave, and choose the best
2025 format for your data based on that.
2026
2027 And of course, all the values above will probably be replaced with
2028 variables gotten from forms or the command line. After all, if you
2029 knew everything ahead of time, you wouldn't have to worry about
2030 dynamically-generating SQL and could just hardwire it into your
2031 script.
2032
2033
2034
2035
2036 =head1 ORDER BY CLAUSES
2037
2038 Some functions take an order by clause. This can either be a scalar (just a
2039 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2040 or an array of either of the two previous forms. Examples:
2041
2042              Given             |    Will Generate
2043     ----------------------------------------------------------
2044     \'colA DESC'               | ORDER BY colA DESC
2045     'colA'                     | ORDER BY colA
2046     [qw/colA colB/]            | ORDER BY colA, colB
2047     {-asc  => 'colA'}          | ORDER BY colA ASC
2048     {-desc => 'colB'}          | ORDER BY colB DESC
2049     [                          |
2050       {-asc  => 'colA'},       | ORDER BY colA ASC, colB DESC
2051       {-desc => 'colB'}        |
2052     ]                          |
2053     [colA => {-asc => 'colB'}] | ORDER BY colA, colB ASC
2054     ==========================================================
2055
2056
2057
2058 =head1 SPECIAL OPERATORS
2059
2060   my $sqlmaker = SQL::Abstract->new(special_ops => [
2061      {regex => qr/.../,
2062       handler => sub {
2063         my ($self, $field, $op, $arg) = @_;
2064         ...
2065         },
2066      },
2067    ]);
2068
2069 A "special operator" is a SQL syntactic clause that can be
2070 applied to a field, instead of a usual binary operator.
2071 For example :
2072
2073    WHERE field IN (?, ?, ?)
2074    WHERE field BETWEEN ? AND ?
2075    WHERE MATCH(field) AGAINST (?, ?)
2076
2077 Special operators IN and BETWEEN are fairly standard and therefore
2078 are builtin within C<SQL::Abstract>. For other operators,
2079 like the MATCH .. AGAINST example above which is
2080 specific to MySQL, you can write your own operator handlers :
2081 supply a C<special_ops> argument to the C<new> method.
2082 That argument takes an arrayref of operator definitions;
2083 each operator definition is a hashref with two entries
2084
2085 =over
2086
2087 =item regex
2088
2089 the regular expression to match the operator
2090
2091 =item handler
2092
2093 coderef that will be called when meeting that operator
2094 in the input tree. The coderef will be called with
2095 arguments  C<< ($self, $field, $op, $arg) >>, and
2096 should return a C<< ($sql, @bind) >> structure.
2097
2098 =back
2099
2100 For example, here is an implementation
2101 of the MATCH .. AGAINST syntax for MySQL
2102
2103   my $sqlmaker = SQL::Abstract->new(special_ops => [
2104
2105     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2106     {regex => qr/^match$/i,
2107      handler => sub {
2108        my ($self, $field, $op, $arg) = @_;
2109        $arg = [$arg] if not ref $arg;
2110        my $label         = $self->_quote($field);
2111        my ($placeholder) = $self->_convert('?');
2112        my $placeholders  = join ", ", (($placeholder) x @$arg);
2113        my $sql           = $self->_sqlcase('match') . " ($label) "
2114                          . $self->_sqlcase('against') . " ($placeholders) ";
2115        my @bind = $self->_bindtype($field, @$arg);
2116        return ($sql, @bind);
2117        }
2118      },
2119
2120   ]);
2121
2122
2123 =head1 PERFORMANCE
2124
2125 Thanks to some benchmarking by Mark Stosberg, it turns out that
2126 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2127 I must admit this wasn't an intentional design issue, but it's a
2128 byproduct of the fact that you get to control your C<DBI> handles
2129 yourself.
2130
2131 To maximize performance, use a code snippet like the following:
2132
2133     # prepare a statement handle using the first row
2134     # and then reuse it for the rest of the rows
2135     my($sth, $stmt);
2136     for my $href (@array_of_hashrefs) {
2137         $stmt ||= $sql->insert('table', $href);
2138         $sth  ||= $dbh->prepare($stmt);
2139         $sth->execute($sql->values($href));
2140     }
2141
2142 The reason this works is because the keys in your C<$href> are sorted
2143 internally by B<SQL::Abstract>. Thus, as long as your data retains
2144 the same structure, you only have to generate the SQL the first time
2145 around. On subsequent queries, simply use the C<values> function provided
2146 by this module to return your values in the correct order.
2147
2148
2149 =head1 FORMBUILDER
2150
2151 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2152 really like this part (I do, at least). Building up a complex query
2153 can be as simple as the following:
2154
2155     #!/usr/bin/perl
2156
2157     use CGI::FormBuilder;
2158     use SQL::Abstract;
2159
2160     my $form = CGI::FormBuilder->new(...);
2161     my $sql  = SQL::Abstract->new;
2162
2163     if ($form->submitted) {
2164         my $field = $form->field;
2165         my $id = delete $field->{id};
2166         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2167     }
2168
2169 Of course, you would still have to connect using C<DBI> to run the
2170 query, but the point is that if you make your form look like your
2171 table, the actual query script can be extremely simplistic.
2172
2173 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2174 a fast interface to returning and formatting data. I frequently
2175 use these three modules together to write complex database query
2176 apps in under 50 lines.
2177
2178
2179 =head1 CHANGES
2180
2181 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2182 Great care has been taken to preserve the I<published> behavior
2183 documented in previous versions in the 1.* family; however,
2184 some features that were previously undocumented, or behaved
2185 differently from the documentation, had to be changed in order
2186 to clarify the semantics. Hence, client code that was relying
2187 on some dark areas of C<SQL::Abstract> v1.*
2188 B<might behave differently> in v1.50.
2189
2190 The main changes are :
2191
2192 =over
2193
2194 =item *
2195
2196 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2197
2198 =item *
2199
2200 support for the { operator => \"..." } construct (to embed literal SQL)
2201
2202 =item *
2203
2204 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2205
2206 =item *
2207
2208 added official support for -nest1, -nest2 or -nest_1, -nest_2, ...
2209 (undocumented in previous versions)
2210
2211 =item *
2212
2213 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2214
2215 =item *
2216
2217 defensive programming : check arguments
2218
2219 =item *
2220
2221 fixed bug with global logic, which was previously implemented
2222 through global variables yielding side-effects. Prior versions would
2223 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2224 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2225 Now this is interpreted
2226 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2227
2228
2229 =item *
2230
2231 fixed semantics of  _bindtype on array args
2232
2233 =item *
2234
2235 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2236 we just avoid shifting arrays within that tree.
2237
2238 =item *
2239
2240 dropped the C<_modlogic> function
2241
2242 =back
2243
2244
2245
2246 =head1 ACKNOWLEDGEMENTS
2247
2248 There are a number of individuals that have really helped out with
2249 this module. Unfortunately, most of them submitted bugs via CPAN
2250 so I have no idea who they are! But the people I do know are:
2251
2252     Ash Berlin (order_by hash term support)
2253     Matt Trout (DBIx::Class support)
2254     Mark Stosberg (benchmarking)
2255     Chas Owens (initial "IN" operator support)
2256     Philip Collins (per-field SQL functions)
2257     Eric Kolve (hashref "AND" support)
2258     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2259     Dan Kubb (support for "quote_char" and "name_sep")
2260     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2261     Laurent Dami (internal refactoring, multiple -nest, extensible list of special operators, literal SQL)
2262     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2263
2264 Thanks!
2265
2266 =head1 SEE ALSO
2267
2268 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2269
2270 =head1 AUTHOR
2271
2272 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2273
2274 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2275
2276 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2277 While not an official support venue, C<DBIx::Class> makes heavy use of
2278 C<SQL::Abstract>, and as such list members there are very familiar with
2279 how to create queries.
2280
2281 This module is free software; you may copy this under the terms of
2282 the GNU General Public License, or the Artistic License, copies of
2283 which should have accompanied your Perl kit.
2284
2285 =cut
2286