lib/SQL/Abstract/AST/v1.pm

   1 use MooseX::Declare;
   2
   3 class SQL::Abstract::AST::v1 extends SQL::Abstract {
   4
   5   use Carp qw/croak/;
   6   use Data::Dump qw/pp/;
   7
   8   use Moose::Util::TypeConstraints;
   9   use MooseX::Types::Moose qw/ArrayRef Str Int Ref HashRef/;
  10   use MooseX::AttributeHelpers;
  11   use SQL::Abstract::Types qw/AST ArrayAST HashAST/;
  12   use Devel::PartialDump qw/dump/;
  13
  14   clean;
  15
  16   # set things that are valid in where clauses
  17   override _build_expr_dispatch_table {
  18     return {
  19       %{super()},
  20       in => $self->can('_in'),
  21       not_in => $self->can('_in'),
  22       and => $self->can('_recurse_where'),
  23       or => $self->can('_recurse_where'),
  24       map { +"$_" => $self->can("_$_") } qw/
  25         value
  26         name
  27         true
  28         false
  29         expr
  30       /
  31     };
  32   }
  33
  34   method _select(HashAST $ast) {
  35     # Default to requiring columns and from.
  36     # DB specific ones (i.e. mysql/Pg) can not require the FROM part with a bit
  37     # of refactoring
  38
  39     for (qw/columns tablespec/) {
  40       confess "'$_' is required in select AST with " . dump ($ast)
  41         unless exists $ast->{$_};
  42     }
  43
  44     # Check that columns is a -list
  45     confess "'columns' should be an array ref, not " . dump($ast->{columns})
  46       unless is_ArrayRef($ast->{columns});
  47
  48     my $cols = $self->_list({-type => 'list', args => $ast->{columns} });
  49
  50     my @output = (
  51       SELECT => $cols
  52     );
  53
  54     push @output, FROM => $self->dispatch($ast->{tablespec})
  55       if exists $ast->{tablespec};
  56
  57     for (qw/where having group_by/) {
  58       if (exists $ast->{$_}) {
  59         my $sub_ast = $ast->{$_};
  60
  61         confess "$_ option is not an AST: " . dump($sub_ast)
  62           unless is_AST($sub_ast);
  63
  64         my $meth = "__$_";
  65         push @output, $self->$meth($sub_ast);
  66       }
  67     }
  68
  69     return join(' ', @output);
  70   }
  71
  72   method _join(HashRef $ast) {
  73
  74     # TODO: Validate join type
  75     my $type = $ast->{join_type} || "";
  76
  77     my @output = $self->dispatch($ast->{lhs});
  78
  79     push @output, uc $type if $type;
  80     push @output, "JOIN", $self->dispatch($ast->{rhs});
  81
  82     push @output,
  83         exists $ast->{on}
  84       ? ('ON', '(' . $self->_expr( $ast->{on} ) . ')' )
  85       : ('USING', '(' .$self->dispatch($ast->{using} || croak "No 'on' or 'join' clause passed to -join").
  86                   ')' );
  87
  88     return join(" ", @output);
  89
  90   }
  91
  92   method _order_by(AST $ast) {
  93     my @clauses = @{$ast->{order_by}};
  94
  95     my @output;
  96
  97     for (@clauses) {
  98       if (is_ArrayRef($_) && $_->[0] =~ /^-(asc|desc)$/) {
  99         my $o = $1;
 100         push @output, $self->dispatch($_->[1]) . " " . uc($o);
 101         next;
 102       }
 103       push @output, $self->dispatch($_);
 104     }
 105
 106     return "ORDER BY " . join(", ", @output);
 107   }
 108
 109   method _name(HashAST $ast) {
 110     my @names = @{$ast->{args}};
 111
 112     my $sep = $self->name_separator;
 113     my $quote = $self->is_quoting
 114               ? $self->quote_chars
 115               : [ '' ];
 116
 117     my $join = $quote->[-1] . $sep . $quote->[0];
 118
 119     # We dont want to quote * in [qw/me */]: `me`.* is the desired output there
 120     # This means you can't have a field called `*`. I am willing to accept this
 121     # situation, cos thats a really stupid thing to want.
 122     my $post;
 123     $post = pop @names if $names[-1] eq '*';
 124
 125     my $ret =
 126       $quote->[0] .
 127       join( $join, @names ) .
 128       $quote->[-1];
 129
 130     $ret .= $sep . $post if defined $post;
 131     return $ret;
 132   }
 133
 134
 135   method _list(AST $ast) {
 136     my @items = @{$ast->{args}};
 137
 138     return join(
 139       $self->list_separator,
 140       map { $self->dispatch($_) } @items);
 141   }
 142
 143   # TODO: I think i want to parameterized AST type to get better validation
 144   method _alias(AST $ast) {
 145
 146     # TODO: Maybe we want qq{ AS "$as"} here
 147     return $self->dispatch($ast->{ident}) . " AS " . $ast->{as};
 148
 149   }
 150
 151   method _value(HashAST $ast) {
 152
 153     $self->add_bind($ast->{value});
 154     return "?";
 155   }
 156
 157   # Not dispatchable to.
 158   method __where(HashAST $ast) {
 159     return "WHERE " . $self->_expr($ast);
 160   }
 161
 162   # Perhaps badly named. handles 'and' and 'or' clauses
 163   method _recurse_where(HashAST $ast) {
 164
 165     my $op = $ast->{op};
 166
 167     my $OP = uc $op;
 168     my $prio = $SQL::Abstract::PRIO{$op};
 169
 170     my $dispatch_table = $self->expr_dispatch_table;
 171
 172     my @output;
 173     foreach ( @{$ast->{args}} ) {
 174       croak "invalid component in where clause: $_" unless is_HashAST($_);
 175
 176       if ($_->{-type} eq 'expr' && $_->{op} =~ /^(and|or)$/) {
 177         my $sub_prio = $SQL::Abstract::PRIO{$1};
 178
 179         if ($sub_prio <= $prio) {
 180           push @output, $self->_recurse_where($_);
 181         } else {
 182           push @output, '(' . $self->_recurse_where($_) . ')';
 183         }
 184       } else {
 185         push @output, $self->_expr($_);
 186       }
 187     }
 188
 189     return join(" $OP ", @output);
 190   }
 191
 192   method _expr(HashAST $ast) {
 193     my $op = $ast->{-type};
 194
 195     $op = $ast->{op} if $op eq 'expr';
 196
 197     if (my $code = $self->lookup_expr_dispatch($op)) {
 198
 199       return $code->($self, $ast);
 200
 201     }
 202     croak "'$op' is not a valid AST type in an expression with " . dump($ast)
 203       if $ast->{-type} ne 'expr';
 204
 205     croak "'$op' is not a valid operator in an expression with " . dump($ast);
 206
 207   }
 208
 209   method _binop(HashAST $ast) {
 210     my ($lhs, $rhs) = @{$ast->{args}};
 211     my $op = $ast->{op};
 212
 213     join (' ', $self->_expr($lhs),
 214                $self->binop_mapping($op) || croak("Unknown binary operator $op"),
 215                $self->_expr($rhs)
 216     );
 217   }
 218
 219   method _in(HashAST $ast) {
 220
 221     my ($field,@values) = @{$ast->{args}};
 222
 223     my $not = ($ast->{op} =~ /^not_/) ? " NOT" : "";
 224
 225     return $self->_false unless @values;
 226
 227     return $self->_expr($field) .
 228            $not .
 229            " IN (" .
 230            join(", ", map { $self->dispatch($_) } @values ) .
 231            ")";
 232   }
 233
 234   method _generic_func(ArrayRef $ast) {
 235   }
 236
 237   # 'constants' that are portable across DBs
 238   method _false($ast?) { "0 = 1" }
 239   method _true($ast?) { "1 = 1" }
 240
 241 }