lib/SQL/Abstract/AST/v1.pm

   1 use MooseX::Declare;
   2
   3 class SQL::Abstract::AST::v1 extends SQL::Abstract {
   4
   5   use Carp qw/croak/;
   6   use Data::Dump qw/pp/;
   7
   8   use Moose::Util::TypeConstraints;
   9   use MooseX::Types::Moose qw/ArrayRef Str Int Ref HashRef/;
  10   use MooseX::AttributeHelpers;
  11   use SQL::Abstract::Types qw/AST ArrayAST HashAST/;
  12   use Devel::PartialDump qw/dump/;
  13
  14   clean;
  15
  16   # set things that are valid in where clauses
  17   override _build_expr_dispatch_table {
  18     return {
  19       %{super()},
  20       in => $self->can('_in'),
  21       not_in => $self->can('_in'),
  22       and => $self->can('_recurse_where'),
  23       or => $self->can('_recurse_where'),
  24       map { +"$_" => $self->can("_$_") } qw/
  25         value
  26         name
  27         true
  28         false
  29         expr
  30       /
  31     };
  32   }
  33
  34   method _select(HashAST $ast) {
  35     # Default to requiring columns and from.
  36     # DB specific ones (i.e. mysql/Pg) can not require the FROM part with a bit
  37     # of refactoring
  38
  39     for (qw/columns tablespec/) {
  40       confess "'$_' is required in select AST with " . dump ($ast)
  41         unless exists $ast->{$_};
  42     }
  43
  44     # Check that columns is a -list
  45     confess "'columns' should be an array ref, not " . dump($ast->{columns})
  46       unless is_ArrayRef($ast->{columns});
  47
  48     my $cols = $self->_list({-type => 'list', args => $ast->{columns} });
  49
  50     my @output = (
  51       SELECT => $cols
  52     );
  53
  54     push @output, FROM => $self->dispatch($ast->{tablespec})
  55       if exists $ast->{tablespec};
  56
  57     for (qw//) {
  58       if (exists $ast->{$_}) {
  59         my $sub_ast = $ast->{$_};
  60         $sub_ast->{-type} = "$_" if is_HashRef($sub_ast);
  61         confess "$_ option is not an AST"
  62           unless is_AST($sub_ast);
  63
  64         push @output, $self->dispatch($sub_ast);
  65       }
  66     }
  67
  68     return join(' ', @output);
  69   }
  70
  71   method _join(HashRef $ast) {
  72
  73     # TODO: Validate join type
  74     my $type = $ast->{join_type} || "";
  75
  76     my @output = $self->dispatch($ast->{lhs});
  77
  78     push @output, uc $type if $type;
  79     push @output, "JOIN", $self->dispatch($ast->{rhs});
  80
  81     push @output,
  82         exists $ast->{on}
  83       ? ('ON', '(' . $self->_expr( $ast->{on} ) . ')' )
  84       : ('USING', '(' .$self->dispatch($ast->{using} || croak "No 'on' or 'join' clause passed to -join").
  85                   ')' );
  86
  87     return join(" ", @output);
  88
  89   }
  90
  91   method _order_by(AST $ast) {
  92     my @clauses = @{$ast->{order_by}};
  93
  94     my @output;
  95
  96     for (@clauses) {
  97       if (is_ArrayRef($_) && $_->[0] =~ /^-(asc|desc)$/) {
  98         my $o = $1;
  99         push @output, $self->dispatch($_->[1]) . " " . uc($o);
 100         next;
 101       }
 102       push @output, $self->dispatch($_);
 103     }
 104
 105     return "ORDER BY " . join(", ", @output);
 106   }
 107
 108   method _name(HashAST $ast) {
 109     my @names = @{$ast->{args}};
 110
 111     my $sep = $self->name_separator;
 112     my $quote = $self->is_quoting
 113               ? $self->quote_chars
 114               : [ '' ];
 115
 116     my $join = $quote->[-1] . $sep . $quote->[0];
 117
 118     # We dont want to quote * in [qw/me */]: `me`.* is the desired output there
 119     # This means you can't have a field called `*`. I am willing to accept this
 120     # situation, cos thats a really stupid thing to want.
 121     my $post;
 122     $post = pop @names if $names[-1] eq '*';
 123
 124     my $ret =
 125       $quote->[0] .
 126       join( $join, @names ) .
 127       $quote->[-1];
 128
 129     $ret .= $sep . $post if defined $post;
 130     return $ret;
 131   }
 132
 133
 134   method _list(AST $ast) {
 135     my @items = @{$ast->{args}};
 136
 137     return join(
 138       $self->list_separator,
 139       map { $self->dispatch($_) } @items);
 140   }
 141
 142   # TODO: I think i want to parameterized AST type to get better validation
 143   method _alias(AST $ast) {
 144
 145     # TODO: Maybe we want qq{ AS "$as"} here
 146     return $self->dispatch($ast->{ident}) . " AS " . $ast->{as};
 147
 148   }
 149
 150   method _value(HashAST $ast) {
 151
 152     $self->add_bind($ast->{value});
 153     return "?";
 154   }
 155
 156   # Perhaps badly named. handles 'and' and 'or' clauses
 157   method _recurse_where(HashAST $ast) {
 158
 159     my $op = $ast->{op};
 160
 161     my $OP = uc $op;
 162     my $prio = $SQL::Abstract::PRIO{$op};
 163
 164     my $dispatch_table = $self->expr_dispatch_table;
 165
 166     my @output;
 167     foreach ( @{$ast->{args}} ) {
 168       croak "invalid component in where clause: $_" unless is_HashAST($_);
 169
 170       if ($_->{-type} eq 'expr' && $_->{op} =~ /^(and|or)$/) {
 171         my $sub_prio = $SQL::Abstract::PRIO{$1};
 172
 173         if ($sub_prio <= $prio) {
 174           push @output, $self->_recurse_where($_);
 175         } else {
 176           push @output, '(' . $self->_recurse_where($_) . ')';
 177         }
 178       } else {
 179         push @output, $self->_expr($_);
 180       }
 181     }
 182
 183     return join(" $OP ", @output);
 184   }
 185
 186   method _expr(HashAST $ast) {
 187     my $op = $ast->{-type};
 188
 189     $op = $ast->{op} if $op eq 'expr';
 190
 191     if (my $code = $self->lookup_expr_dispatch($op)) {
 192
 193       return $code->($self, $ast);
 194
 195     }
 196     croak "'$op' is not a valid AST type in an expression with " . dump($ast)
 197       if $ast->{-type} ne 'expr';
 198
 199     croak "'$op' is not a valid operator in an expression with " . dump($ast);
 200
 201   }
 202
 203   method _binop(HashAST $ast) {
 204     my ($lhs, $rhs) = @{$ast->{args}};
 205     my $op = $ast->{op};
 206
 207     join (' ', $self->_expr($lhs),
 208                $self->binop_mapping($op) || croak("Unknown binary operator $op"),
 209                $self->_expr($rhs)
 210     );
 211   }
 212
 213   method _in(HashAST $ast) {
 214
 215     my ($field,@values) = @{$ast->{args}};
 216
 217     my $not = ($ast->{op} =~ /^not_/) ? " NOT" : "";
 218
 219     return $self->_false unless @values;
 220
 221     return $self->_expr($field) .
 222            $not .
 223            " IN (" .
 224            join(", ", map { $self->dispatch($_) } @values ) .
 225            ")";
 226   }
 227
 228   method _generic_func(ArrayRef $ast) {
 229   }
 230
 231   # 'constants' that are portable across DBs
 232   method _false($ast?) { "0 = 1" }
 233   method _true($ast?) { "1 = 1" }
 234
 235 }