lib/SQL/Abstract/AST/v1.pm

   1 use MooseX::Declare;
   2
   3 class SQL::Abstract::AST::v1 extends SQL::Abstract {
   4
   5   use Carp qw/croak/;
   6   use Data::Dump qw/pp/;
   7
   8   use Moose::Util::TypeConstraints;
   9   use MooseX::Types::Moose qw/ArrayRef Str Int Ref HashRef/;
  10   use MooseX::AttributeHelpers;
  11   use SQL::Abstract::Types qw/AST/;
  12   use Devel::PartialDump qw/dump/;
  13
  14   clean;
  15
  16   # set things that are valid in where clauses
  17   override _build_expr_dispatch_table {
  18     return {
  19       %{super()},
  20       in => $self->can('_in'),
  21       not_in => $self->can('_in'),
  22       between => $self->can('_between'),
  23       not_between => $self->can('_between'),
  24       and => $self->can('_recurse_where'),
  25       or => $self->can('_recurse_where'),
  26       map { +"$_" => $self->can("_$_") } qw/
  27         value
  28         identifier
  29         true
  30         false
  31         expr
  32       /
  33     };
  34   }
  35
  36   method _select(AST $ast) {
  37     # Default to requiring columns and from.
  38     # DB specific ones (i.e. mysql/Pg) can not require the FROM part with a bit
  39     # of refactoring
  40
  41     for (qw/columns tablespec/) {
  42       confess "'$_' is required in select AST with " . dump ($ast)
  43         unless exists $ast->{$_};
  44     }
  45
  46     # Check that columns is a -list
  47     confess "'columns' should be an array ref, not " . dump($ast->{columns})
  48       unless is_ArrayRef($ast->{columns});
  49
  50     my $cols = $self->_list({-type => 'list', args => $ast->{columns} });
  51
  52     my @output = (
  53       SELECT => $cols
  54     );
  55
  56     push @output, FROM => $self->dispatch($ast->{tablespec})
  57       if exists $ast->{tablespec};
  58
  59     if (exists $ast->{where}) {
  60       my $sub_ast = $ast->{where};
  61
  62       confess "$_ option is not an AST: " . dump($sub_ast)
  63         unless is_AST($sub_ast);
  64
  65       push @output, "WHERE", $self->_expr($sub_ast);
  66     }
  67
  68     for (qw/group_by having order_by/) {
  69       if (exists $ast->{$_}) {
  70         my $sub_ast = $ast->{$_};
  71
  72         confess "$_ option is not an AST or an ArrayRef: " . dump($sub_ast)
  73           unless is_AST($sub_ast) || is_ArrayRef($sub_ast);;
  74
  75         my $meth = "__$_";
  76         push @output, $self->$meth($sub_ast);
  77       }
  78     }
  79
  80     return join(' ', @output);
  81   }
  82
  83   method _update(AST $ast) {
  84
  85     for (qw/columns values tablespec/) {
  86       confess "'$_' is required in update AST with " . dump ($ast)
  87         unless exists $ast->{$_};
  88     }
  89
  90     my $table = $ast->{tablespec};
  91     confess 'update: tablespec must be an ident or an alias in ' . dump($ast)
  92       unless $table->{-type} =~ /^identifier|alias$/;
  93
  94     my @output = (
  95         'UPDATE',
  96         $self->dispatch($table),
  97         'SET'
  98     );
  99
 100     confess 'update: Number of values does not match columns: ' . dump($ast)
 101       if @{$ast->{columns}} != @{$ast->{values}};
 102
 103     my $list = {
 104       -type => 'list',
 105       args => [ map {
 106         { -type => 'expr',
 107           op => '==', # This should really be '=' but hmmmmmmmm
 108           args => [
 109             $ast->{columns}[$_],
 110             $ast->{values}[$_]
 111           ]
 112         }
 113       } 0..$#{$ast->{columns}} ]
 114     };
 115
 116     push @output, $self->dispatch($list);
 117
 118     return join(' ', @output);
 119
 120   }
 121
 122   method _join(HashRef $ast) {
 123
 124     # TODO: Validate join type
 125     my $type = $ast->{join_type} || "";
 126
 127     my @output = $self->dispatch($ast->{lhs});
 128
 129     push @output, uc $type if $type;
 130     push @output, "JOIN", $self->dispatch($ast->{rhs});
 131
 132     push @output,
 133         exists $ast->{on}
 134       ? ('ON', '(' . $self->_expr( $ast->{on} ) . ')' )
 135       : ('USING', '(' .$self->dispatch($ast->{using}
 136                         || croak "No 'on' or 'uinsg' clause passed to join cluase: " .
 137                                  dump($ast)
 138                         ) .
 139                   ')' );
 140
 141     return join(" ", @output);
 142
 143   }
 144
 145   method _ordering(AST $ast) {
 146
 147     my $output = $self->_expr($ast->{expr});
 148
 149     $output .= " " . uc $1
 150       if $ast->{direction} &&
 151          ( $ast->{direction} =~ /^(asc|desc)$/i
 152            || confess "Unknown ordering direction " . dump($ast)
 153          );
 154
 155     return $output;
 156   }
 157
 158   method _identifier(AST $ast) {
 159     my @names = @{$ast->{elements}};
 160
 161     my $sep = $self->ident_separator;
 162     my $quote = $self->is_quoting
 163               ? $self->quote_chars
 164               : [ '' ];
 165
 166     my $join = $quote->[-1] . $sep . $quote->[0];
 167
 168     # We dont want to quote * in [qw/me */]: `me`.* is the desired output there
 169     # This means you can't have a field called `*`. I am willing to accept this
 170     # situation, cos thats a really stupid thing to want.
 171     my $post;
 172     $post = pop @names if $names[-1] eq '*';
 173
 174     my $ret;
 175     $ret = $quote->[0] .
 176            join( $join, @names ) .
 177            $quote->[-1]
 178       if @names;
 179
 180     $ret = $ret
 181          ? $ret . $sep . $post
 182          : $post
 183       if defined $post;
 184
 185
 186     return $ret;
 187   }
 188
 189
 190   method _list(AST $ast) {
 191     return "" unless $ast->{args};
 192
 193     my @items = is_ArrayRef($ast->{args})
 194               ? @{$ast->{args}}
 195               : $ast->{args};
 196
 197     return join(
 198       $self->list_separator,
 199       map { $self->dispatch($_) } @items);
 200   }
 201
 202   # TODO: I think i want to parameterized AST type to get better validation
 203   method _alias(AST $ast) {
 204
 205     # TODO: Maybe we want qq{ AS "$as"} here
 206     return $self->dispatch($ast->{ident}) . " AS " . $ast->{as};
 207
 208   }
 209
 210   method _value(AST $ast) {
 211
 212     $self->add_bind($ast->{value});
 213     return "?";
 214   }
 215
 216   # Not dispatchable to.
 217   method __having($args) {
 218     return "HAVING " . $self->_list({-type => 'list', args => $args});
 219   }
 220
 221   method __group_by($args) {
 222     return "GROUP BY " . $self->_list({-type => 'list', args => $args});
 223   }
 224
 225   method __order_by($args) {
 226     return "ORDER BY " . $self->_list({-type => 'list', args => $args});
 227   }
 228
 229
 230   # Perhaps badly named. handles 'and' and 'or' clauses
 231   method _recurse_where(AST $ast) {
 232
 233     my $op = $ast->{op};
 234
 235     my $OP = uc $op;
 236     my $prio = $SQL::Abstract::PRIO{$op};
 237
 238     my $dispatch_table = $self->expr_dispatch_table;
 239
 240     my @output;
 241     foreach ( @{$ast->{args}} ) {
 242       croak "invalid component in where clause: $_" unless is_AST($_);
 243
 244       if ($_->{-type} eq 'expr' && $_->{op} =~ /^(and|or)$/) {
 245         my $sub_prio = $SQL::Abstract::PRIO{$1};
 246
 247         if ($sub_prio == $prio) {
 248           # When the element below has same priority, i.e. 'or' as a child of
 249           # 'or', dont produce extra brackets
 250           push @output, $self->_recurse_where($_);
 251         } else {
 252           push @output, '(' . $self->_recurse_where($_) . ')';
 253         }
 254       } else {
 255         push @output, $self->_expr($_);
 256       }
 257     }
 258
 259     return join(" $OP ", @output);
 260   }
 261
 262   method _expr(AST $ast) {
 263     my $op = $ast->{-type};
 264
 265     $op = $ast->{op} if $op eq 'expr';
 266
 267     if (my $code = $self->lookup_expr_dispatch($op)) {
 268
 269       return $code->($self, $ast);
 270
 271     }
 272     croak "'$op' is not a valid AST type in an expression with " . dump($ast)
 273       if $ast->{-type} ne 'expr';
 274
 275     # This is an attempt to do some form of validation on function names. This
 276     # might end up being a bad thing.
 277     croak "'$op' is not a valid operator in an expression with " . dump($ast)
 278       if $op =~ /\W/;
 279
 280     return $self->_generic_function_op($ast);
 281
 282   }
 283
 284   method _binop(AST $ast) {
 285     my ($lhs, $rhs) = @{$ast->{args}};
 286     my $op = $ast->{op};
 287
 288     # IS NOT? NULL
 289     if ($rhs->{-type} eq 'value' && !defined $rhs->{value} &&
 290         ($op eq '==' || $op eq '!='))
 291     {
 292       return $self->_expr($lhs) .
 293              ($op eq '==' ? " IS " : " IS NOT ") .
 294              "NULL";
 295     }
 296
 297     join (' ', $self->_expr($lhs),
 298                $self->binop_mapping($op) || croak("Unknown binary operator $op"),
 299                $self->_expr($rhs)
 300     );
 301   }
 302
 303   method _generic_function_op(AST $ast) {
 304     my $op = $ast->{op};
 305
 306     return "$op(" . $self->_list($ast) . ")";
 307   }
 308
 309   method _in(AST $ast) {
 310
 311     my ($field,@values) = @{$ast->{args}};
 312
 313     my $not = ($ast->{op} =~ /^not_/) ? " NOT" : "";
 314
 315     return $self->_false unless @values;
 316
 317     return $self->_expr($field) .
 318            $not .
 319            " IN (" .
 320            join(", ", map { $self->dispatch($_) } @values ) .
 321            ")";
 322   }
 323
 324   method _between(AST $ast) {
 325
 326     my ($field,@values) = @{$ast->{args}};
 327
 328     my $not = ($ast->{op} =~ /^not_/) ? " NOT" : "";
 329     croak "between requires 3 arguments: " . dump($ast)
 330       unless @values == 2;
 331
 332     # The brackets are to work round an issue with SQL::A::Test
 333     return "(" .
 334            $self->_expr($field) .
 335            $not .
 336            " BETWEEN " .
 337            join(" AND ", map { $self->dispatch($_) } @values ) .
 338            ")";
 339   }
 340
 341   # 'constants' that are portable across DBs
 342   method _false($ast?) { "0 = 1" }
 343   method _true($ast?) { "1 = 1" }
 344
 345 }