lib/SQL/Abstract/AST/v1.pm

   1 use MooseX::Declare;
   2
   3 class SQL::Abstract::AST::v1 extends SQL::Abstract {
   4
   5   use Carp qw/croak/;
   6   use Data::Dump qw/pp/;
   7
   8   use Moose::Util::TypeConstraints;
   9   use MooseX::Types::Moose qw/ArrayRef Str Int Ref HashRef/;
  10   use MooseX::AttributeHelpers;
  11   use SQL::Abstract::Types qw/AST/;
  12   use Devel::PartialDump qw/dump/;
  13
  14   clean;
  15
  16   # set things that are valid in where clauses
  17   override _build_expr_dispatch_table {
  18     return {
  19       %{super()},
  20       in => $self->can('_in'),
  21       not_in => $self->can('_in'),
  22       between => $self->can('_between'),
  23       not_between => $self->can('_between'),
  24       and => $self->can('_recurse_where'),
  25       or => $self->can('_recurse_where'),
  26       map { +"$_" => $self->can("_$_") } qw/
  27         value
  28         name
  29         true
  30         false
  31         expr
  32       /
  33     };
  34   }
  35
  36   method _select(AST $ast) {
  37     # Default to requiring columns and from.
  38     # DB specific ones (i.e. mysql/Pg) can not require the FROM part with a bit
  39     # of refactoring
  40
  41     for (qw/columns tablespec/) {
  42       confess "'$_' is required in select AST with " . dump ($ast)
  43         unless exists $ast->{$_};
  44     }
  45
  46     # Check that columns is a -list
  47     confess "'columns' should be an array ref, not " . dump($ast->{columns})
  48       unless is_ArrayRef($ast->{columns});
  49
  50     my $cols = $self->_list({-type => 'list', args => $ast->{columns} });
  51
  52     my @output = (
  53       SELECT => $cols
  54     );
  55
  56     push @output, FROM => $self->dispatch($ast->{tablespec})
  57       if exists $ast->{tablespec};
  58
  59     if (exists $ast->{where}) {
  60       my $sub_ast = $ast->{where};
  61
  62       confess "$_ option is not an AST: " . dump($sub_ast)
  63         unless is_AST($sub_ast);
  64
  65       push @output, "WHERE", $self->_expr($sub_ast);
  66     }
  67
  68     for (qw/group_by having order_by/) {
  69       if (exists $ast->{$_}) {
  70         my $sub_ast = $ast->{$_};
  71
  72         confess "$_ option is not an AST or an ArrayRef: " . dump($sub_ast)
  73           unless is_AST($sub_ast) || is_ArrayRef($sub_ast);;
  74
  75         my $meth = "__$_";
  76         push @output, $self->$meth($sub_ast);
  77       }
  78     }
  79
  80     return join(' ', @output);
  81   }
  82
  83   method _join(HashRef $ast) {
  84
  85     # TODO: Validate join type
  86     my $type = $ast->{join_type} || "";
  87
  88     my @output = $self->dispatch($ast->{lhs});
  89
  90     push @output, uc $type if $type;
  91     push @output, "JOIN", $self->dispatch($ast->{rhs});
  92
  93     push @output,
  94         exists $ast->{on}
  95       ? ('ON', '(' . $self->_expr( $ast->{on} ) . ')' )
  96       : ('USING', '(' .$self->dispatch($ast->{using}
  97                         || croak "No 'on' or 'uinsg' clause passed to join cluase: " .
  98                                  dump($ast)
  99                         ) .
 100                   ')' );
 101
 102     return join(" ", @output);
 103
 104   }
 105
 106   method _ordering(AST $ast) {
 107
 108     my $output = $self->_expr($ast->{expr});
 109
 110     $output .= " " . uc $1
 111       if $ast->{direction} &&
 112          ( $ast->{direction} =~ /^(asc|desc)$/i
 113            || confess "Unknown ordering direction " . dump($ast)
 114          );
 115
 116     return $output;
 117   }
 118
 119   method _name(AST $ast) {
 120     my @names = @{$ast->{args}};
 121
 122     my $sep = $self->name_separator;
 123     my $quote = $self->is_quoting
 124               ? $self->quote_chars
 125               : [ '' ];
 126
 127     my $join = $quote->[-1] . $sep . $quote->[0];
 128
 129     # We dont want to quote * in [qw/me */]: `me`.* is the desired output there
 130     # This means you can't have a field called `*`. I am willing to accept this
 131     # situation, cos thats a really stupid thing to want.
 132     my $post;
 133     $post = pop @names if $names[-1] eq '*';
 134
 135     my $ret;
 136     $ret = $quote->[0] .
 137            join( $join, @names ) .
 138            $quote->[-1]
 139       if @names;
 140
 141     $ret = $ret
 142          ? $ret . $sep . $post
 143          : $post
 144       if defined $post;
 145
 146
 147     return $ret;
 148   }
 149
 150
 151   method _list(AST $ast) {
 152     return "" unless $ast->{args};
 153
 154     my @items = is_ArrayRef($ast->{args})
 155               ? @{$ast->{args}}
 156               : $ast->{args};
 157
 158     return join(
 159       $self->list_separator,
 160       map { $self->dispatch($_) } @items);
 161   }
 162
 163   # TODO: I think i want to parameterized AST type to get better validation
 164   method _alias(AST $ast) {
 165
 166     # TODO: Maybe we want qq{ AS "$as"} here
 167     return $self->dispatch($ast->{ident}) . " AS " . $ast->{as};
 168
 169   }
 170
 171   method _value(AST $ast) {
 172
 173     $self->add_bind($ast->{value});
 174     return "?";
 175   }
 176
 177   # Not dispatchable to.
 178   method __having($args) {
 179     return "HAVING " . $self->_list({-type => 'list', args => $args});
 180   }
 181
 182   method __group_by($args) {
 183     return "GROUP BY " . $self->_list({-type => 'list', args => $args});
 184   }
 185
 186   method __order_by($args) {
 187     return "ORDER BY " . $self->_list({-type => 'list', args => $args});
 188   }
 189
 190
 191   # Perhaps badly named. handles 'and' and 'or' clauses
 192   method _recurse_where(AST $ast) {
 193
 194     my $op = $ast->{op};
 195
 196     my $OP = uc $op;
 197     my $prio = $SQL::Abstract::PRIO{$op};
 198
 199     my $dispatch_table = $self->expr_dispatch_table;
 200
 201     my @output;
 202     foreach ( @{$ast->{args}} ) {
 203       croak "invalid component in where clause: $_" unless is_AST($_);
 204
 205       if ($_->{-type} eq 'expr' && $_->{op} =~ /^(and|or)$/) {
 206         my $sub_prio = $SQL::Abstract::PRIO{$1};
 207
 208         if ($sub_prio <= $prio) {
 209           push @output, $self->_recurse_where($_);
 210         } else {
 211           push @output, '(' . $self->_recurse_where($_) . ')';
 212         }
 213       } else {
 214         push @output, $self->_expr($_);
 215       }
 216     }
 217
 218     return join(" $OP ", @output);
 219   }
 220
 221   method _expr(AST $ast) {
 222     my $op = $ast->{-type};
 223
 224     $op = $ast->{op} if $op eq 'expr';
 225
 226     if (my $code = $self->lookup_expr_dispatch($op)) {
 227
 228       return $code->($self, $ast);
 229
 230     }
 231     croak "'$op' is not a valid AST type in an expression with " . dump($ast)
 232       if $ast->{-type} ne 'expr';
 233
 234     # This is an attempt to do some form of validation on function names. This
 235     # might end up being a bad thing.
 236     croak "'$op' is not a valid operator in an expression with " . dump($ast)
 237       if $op =~ /\W/;
 238
 239     return $self->_generic_function_op($ast);
 240
 241   }
 242
 243   method _binop(AST $ast) {
 244     my ($lhs, $rhs) = @{$ast->{args}};
 245     my $op = $ast->{op};
 246
 247     join (' ', $self->_expr($lhs),
 248                $self->binop_mapping($op) || croak("Unknown binary operator $op"),
 249                $self->_expr($rhs)
 250     );
 251   }
 252
 253   method _generic_function_op(AST $ast) {
 254     my $op = $ast->{op};
 255
 256     return "$op(" . $self->_list($ast) . ")";
 257   }
 258
 259   method _in(AST $ast) {
 260
 261     my ($field,@values) = @{$ast->{args}};
 262
 263     my $not = ($ast->{op} =~ /^not_/) ? " NOT" : "";
 264
 265     return $self->_false unless @values;
 266
 267     return $self->_expr($field) .
 268            $not .
 269            " IN (" .
 270            join(", ", map { $self->dispatch($_) } @values ) .
 271            ")";
 272   }
 273
 274   method _between(AST $ast) {
 275
 276     my ($field,@values) = @{$ast->{args}};
 277
 278     my $not = ($ast->{op} =~ /^not_/) ? " NOT" : "";
 279     croak "between requires 3 arguments: " . dump($ast)
 280       unless @values == 2;
 281
 282     return $self->_expr($field) .
 283            $not .
 284            " BETWEEN " .
 285            join(" AND ", map { $self->dispatch($_) } @values );
 286   }
 287
 288   # 'constants' that are portable across DBs
 289   method _false($ast?) { "0 = 1" }
 290   method _true($ast?) { "1 = 1" }
 291
 292 }