lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4
   5 sub intersperse { my $i = shift; my @i = map +($_, $i), @_; pop @i; @i }
   6
   7 use SQL::ReservedWords;
   8 use Data::Query::ExprHelpers;
   9
  10 use Moo;
  11
  12 has reserved_ident_parts => (
  13   is => 'ro', default => sub {
  14     our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  15   }
  16 );
  17
  18 has quote_chars => (is => 'ro', default => sub { [''] });
  19
  20 has identifier_sep => (is => 'ro', default => sub { '.' });
  21
  22 has simple_ops => (is => 'ro', builder => '_default_simple_ops');
  23
  24 has lc_keywords => (is => 'ro', default => sub { 0 });
  25
  26 has always_quote => (is => 'ro', default => sub { 0 });
  27
  28 has collapse_aliases => (is => 'ro', default => sub { 1 });
  29
  30 sub _default_simple_ops {
  31   +{
  32     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  33     (map +($_ => 'unop'), qw(NOT) ),
  34     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  35     (map +($_ => 'flatten'), qw(AND OR) ),
  36     (map +($_ => 'in'), ('IN', 'NOT IN')),
  37     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN')),
  38     (apply => 'apply'),
  39   }
  40 }
  41
  42 sub render {
  43   my $self = shift;
  44   $self->_flatten_structure($self->_render(@_))
  45 }
  46
  47 sub _flatten_structure {
  48   my ($self, $struct) = @_;
  49   my @bind;
  50   [ do {
  51       my @p = map {
  52         my $r = ref;
  53         if (!$r) { $_ }
  54         elsif ($r eq 'ARRAY') {
  55           my ($sql, @b) = @{$self->_flatten_structure($_)};
  56           push @bind, @b;
  57           $sql;
  58         }
  59         elsif ($r eq 'HASH') { push @bind, $_; () }
  60         else { die "_flatten_structure can't handle ref type $r for $_" }
  61       } @$struct;
  62       join '', map {
  63         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  64       } 0 .. $#p;
  65     },
  66     @bind
  67   ];
  68 }
  69
  70 # I presented this to permit strange people to easily supply a patch to lc()
  71 # their keywords, as I have heard many desire to do, lest they infect me
  72 # with whatever malady caused this desire by their continued proximity for
  73 # want of such a feature.
  74 #
  75 # Then I realised that SQL::Abstract compatibility work required it.
  76 #
  77 # FEH.
  78
  79 sub _format_keyword { $_[0]->lc_keywords ? lc($_[1]) : $_[1] }
  80
  81 sub _render {
  82   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  83 }
  84
  85 sub _render_broken {
  86   my ($self, $dq) = @_;
  87   require Data::Dumper::Concise;
  88   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  89 }
  90
  91 sub _render_identifier {
  92   die "Unidentified identifier (SQL can no has \$_)"
  93     unless my @i = @{$_[1]->{elements}};
  94   # handle single or paired quote chars
  95   my ($q1, $q2) = @{$_[0]->quote_chars}[0,-1];
  96   my $always_quote = $_[0]->always_quote;
  97   my $res_check = $_[0]->reserved_ident_parts;
  98   return [
  99     join
 100       $_[0]->identifier_sep,
 101       map +(
 102         $_ eq '*' # Yes, this means you can't have a column just called '*'.
 103           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
 104           : ( # reserved are stored uc, quote if non-word
 105               ($always_quote and $q1) || $res_check->{+uc} || /\W/
 106                 ? $q1.$_.$q2
 107                 : $_
 108             )
 109       ), @i
 110   ];
 111 }
 112
 113 sub _render_value {
 114   [ '?', $_[1] ]
 115 }
 116
 117 sub _operator_type { 'SQL.Naive' }
 118
 119 sub _render_operator {
 120   my ($self, $dq) = @_;
 121   my $op = $dq->{operator};
 122   unless (exists $op->{$self->_operator_type}) {
 123     $op->{$self->_operator_type} = $self->_convert_op($dq);
 124   }
 125   my $op_name = $op->{$self->_operator_type};
 126   if (my $op_type = $self->simple_ops->{$op_name}) {
 127     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 128   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 129     return $self->$meth($dq);
 130   }
 131   if (my $argc = @{$dq->{args}}) {
 132     if ($argc == 1) {
 133       return $self->_handle_op_type_unop($op_name, $dq);
 134     } elsif ($argc == 2) {
 135       return $self->_handle_op_type_binop($op_name, $dq);
 136     }
 137   }
 138   die "Unsure how to handle ${op_name}";
 139 }
 140
 141 sub _maybe_parenthesise {
 142   my ($self, $dq) = @_;
 143   for ($dq) {
 144     return is_Select() || is_Slice()
 145       ? [ '(', $self->_render($dq), ')' ]
 146       : $self->_render($dq);
 147   }
 148 }
 149
 150 sub _handle_op_type_binop {
 151   my ($self, $op_name, $dq) = @_;
 152   die "${op_name} registered as binary op but args contain "
 153       .scalar(@{$dq->{args}})." entries"
 154     unless @{$dq->{args}} == 2;
 155   [
 156     $self->_maybe_parenthesise($dq->{args}[0]),
 157     $op_name,
 158     $self->_maybe_parenthesise($dq->{args}[1]),
 159   ]
 160 }
 161
 162 sub _handle_op_type_unop {
 163   my ($self, $op_name, $dq) = @_;
 164   die "${op_name} registered as unary op but args contain "
 165       .scalar(@{$dq->{args}})." entries"
 166     unless @{$dq->{args}} == 1;
 167   [
 168     '(',
 169     $op_name,
 170     $self->_render($dq->{args}[0]),
 171     ')',
 172   ]
 173 }
 174
 175 sub _handle_op_type_unop_reverse {
 176   my ($self, $op_name, $dq) = @_;
 177   die "${op_name} registered as unary op but args contain "
 178       .scalar(@{$dq->{args}})." entries"
 179     unless @{$dq->{args}} == 1;
 180   [
 181     $self->_render($dq->{args}[0]),
 182     $op_name,
 183   ]
 184 }
 185
 186 sub _handle_op_type_flatten {
 187   my ($self, $op_name, $dq) = @_;
 188   my @argq = @{$dq->{args}};
 189   my @arg_final;
 190   while (my $arg = shift @argq) {
 191
 192     unless (is_Operator($arg)) {
 193       push @arg_final, $arg;
 194       next;
 195     }
 196
 197     my $op = $arg->{operator};
 198     unless (exists $op->{$self->_operator_type}) {
 199       $op->{$self->_operator_type} = $self->_convert_op($arg);
 200     }
 201
 202     if ($op->{$self->_operator_type} eq $op_name) {
 203       unshift @argq, @{$arg->{args}};
 204     } else {
 205       push @arg_final, $arg;
 206     }
 207   }
 208   [ '(',
 209       intersperse(
 210         $self->_format_keyword($op_name),
 211         map $self->_maybe_parenthesise($_), @arg_final
 212       ),
 213     ')'
 214   ];
 215 }
 216
 217 sub _handle_op_type_in {
 218   my ($self, $op, $dq) = @_;
 219   my ($lhs, @in) = @{$dq->{args}};
 220   [ $self->_render($lhs),
 221     $op,
 222     '(',
 223       intersperse(',', map $self->_render($_), @in),
 224     ')'
 225   ];
 226 }
 227
 228 sub _handle_op_type_between {
 229   my ($self, $op_name, $dq) = @_;
 230   my @args = @{$dq->{args}};
 231   if (@args == 3) {
 232     my ($lhs, $rhs1, $rhs2) = (map $self->_maybe_parenthesise($_), @args);
 233     [ '(', $lhs, $op_name, $rhs1, 'AND', $rhs2, ')' ];
 234   } elsif (@args == 2 and is_Literal $args[1]->{type}) {
 235     my ($lhs, $rhs) = (map $self->_render($_), @args);
 236     [ '(', $lhs, $op_name, $rhs, ')' ];
 237   } else {
 238     die "Invalid args for between: ${\scalar @args} given";
 239   }
 240 }
 241
 242 sub _handle_op_type_apply {
 243   my ($self, $op_name, $dq) = @_;
 244   my ($func, @args) = @{$dq->{args}};
 245   die "Function name must be identifier"
 246     unless is_Identifier $func;
 247   my $ident = do {
 248     # The problem we have here is that built-ins can't be quoted, generally.
 249     # I rather wonder if things like MAX(...) need to -not- be handled as
 250     # an apply and instead of something else, maybe a parenop type - but
 251     # as an explicitly Naive renderer this seems like a reasonable answer.
 252     local @{$self}{qw(reserved_ident_parts always_quote)};
 253     $self->_render_identifier($func)->[0];
 254   };
 255   [
 256     "$ident(",
 257       intersperse(',', map $self->_maybe_parenthesise($_), @args),
 258     ')'
 259   ]
 260 }
 261
 262 sub _convert_op {
 263   my ($self, $dq) = @_;
 264   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 265     for ($perl_op) {
 266       $_ eq '==' and return '=';
 267       $_ eq 'eq' and return '=';
 268       $_ eq '!' and return 'NOT';
 269     }
 270     return uc $perl_op; # hope!
 271   }
 272   die "Can't convert non-perl op yet";
 273 }
 274
 275 sub _render_select {
 276   my ($self, $dq) = @_;
 277   die "Empty select list" unless @{$dq->{select}};
 278
 279   # it is, in fact, completely valid for there to be nothing for us
 280   # to project from since many databases handle 'SELECT 1;' fine
 281
 282   my @select = intersperse(',',
 283     map +(is_Alias()
 284            ? $self->_render_alias($_, $self->_format_keyword('AS'))
 285            : $self->_render($_)), @{$dq->{select}}
 286   );
 287
 288   return [
 289     $self->_format_keyword('SELECT'),
 290     \@select,
 291     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 292     # since we're the SELECT and therefore always come first, we don't care.
 293     ($dq->{from}
 294        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 295        : ()
 296     ),
 297   ];
 298 }
 299
 300 sub _render_alias {
 301   my ($self, $dq, $as) = @_;
 302   # FROM foo foo -> FROM foo
 303   # FROM foo.bar bar -> FROM foo.bar
 304   if ($self->collapse_aliases) {
 305     if (is_Identifier(my $from = $dq->{from})) {
 306       if ($from->{elements}[-1] eq $dq->{to}) {
 307         return $self->_render($from);
 308       }
 309     }
 310   }
 311   return [
 312     $self->_maybe_parenthesise($dq->{from}),
 313     $as || ' ',
 314     $self->_render_identifier({ elements => [ $dq->{to} ] })
 315   ];
 316 }
 317
 318 sub _render_literal {
 319   my ($self, $dq) = @_;
 320   unless ($dq->{subtype} eq 'SQL') {
 321     die "Can't render non-SQL literal";
 322   }
 323   if (defined($dq->{literal})) {
 324     return [
 325       $dq->{literal}, @{$dq->{values}||[]}
 326     ];
 327   } elsif ($dq->{parts}) {
 328     return [ map $self->_render($_), @{$dq->{parts}} ];
 329   } else {
 330     die "Invalid SQL literal - neither 'literal' nor 'parts' found";
 331   }
 332 }
 333
 334 sub _render_join {
 335   my ($self, $dq) = @_;
 336   my ($left, $right) = @{$dq}{qw(left right)};
 337   my $join = do {
 338     if ($dq->{outer}) {
 339       $self->_format_keyword(uc($dq->{outer}).' JOIN');
 340     } elsif ($dq->{on}) {
 341       $self->_format_keyword('JOIN');
 342     } else {
 343       ','
 344     }
 345   };
 346   my $rhs = $self->_render($right);
 347   [
 348     $self->_render($left), $join,
 349     (is_Join($right) ? ('(', $rhs, ')') : $rhs),
 350     ($dq->{on}
 351       ? ($self->_format_keyword('ON'), $self->_render($dq->{on}))
 352       : ())
 353   ];
 354 }
 355
 356 sub _render_where {
 357   my ($self, $dq) = @_;
 358   my ($from, $where) = @{$dq}{qw(from where)};
 359   my $keyword = (is_Group($from) ? 'HAVING' : 'WHERE');
 360   [
 361     ($from ? $self->_render($from) : ()),
 362     $self->_format_keyword($keyword),
 363     $self->_render($where)
 364   ]
 365 }
 366
 367 sub _render_order {
 368   my ($self, $dq) = @_;
 369   my @ret = (
 370     $self->_format_keyword('ORDER BY'),
 371     $self->_render($dq->{by}),
 372     ($dq->{reverse}
 373       ? $self->_format_keyword('DESC')
 374       : ())
 375   );
 376   my $from;
 377   while ($from = $dq->{from}) {
 378     last unless is_Order $from;
 379     $dq = $from;
 380     push @ret, (
 381       ',',
 382       $self->_render($dq->{by}),
 383       ($dq->{reverse}
 384         ? $self->_format_keyword('DESC')
 385         : ())
 386     );
 387   }
 388   unshift @ret, $self->_render($from) if $from;
 389   \@ret;
 390 }
 391
 392 sub _render_group {
 393   my ($self, $dq) = @_;
 394   # this could also squash like order does. but I dunno whether that should
 395   # move somewhere else just yet.
 396   my @ret = (
 397     ($dq->{from} ? $self->_render($dq->{from}) : ()),
 398     (@{$dq->{by}}
 399       ? (
 400           $self->_format_keyword('GROUP BY'),
 401           intersperse(',', map $self->_render($_), @{$dq->{by}})
 402          )
 403       : ())
 404   );
 405   \@ret;
 406 }
 407
 408 sub _render_delete {
 409   my ($self, $dq) = @_;
 410   my ($target, $where) = @{$dq}{qw(target where)};
 411   [ $self->_format_keyword('DELETE FROM'),
 412     $self->_render($target),
 413     ($where
 414       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 415       : ())
 416   ];
 417 }
 418
 419 sub _render_update {
 420   my ($self, $dq) = @_;
 421   my ($target, $set, $where) = @{$dq}{qw(target set where)};
 422   unless ($set) {
 423     die "Must have set key - names+value keys not yet tested";
 424     my ($names, $value) = @{$dq}{qw(names value)};
 425     die "Must have names and value or set" unless $names and $value;
 426     die "names and value must be same size" unless @$names == @$value;
 427     $set = [ map [ $names->[$_], $value->[$_] ], 0..$#$names ];
 428   }
 429   my @rendered_set = intersperse(
 430     ',', map [ intersperse('=', map $self->_render($_), @$_) ], @{$set}
 431   );
 432   [ $self->_format_keyword('UPDATE'),
 433     $self->_render($target),
 434     $self->_format_keyword('SET'),
 435     @rendered_set,
 436     ($where
 437       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 438       : ())
 439   ];
 440 }
 441
 442 sub _render_insert {
 443   my ($self, $dq) = @_;
 444   my ($target, $names, $values, $returning)
 445     = @{$dq}{qw(target names values returning)};
 446   unless ($values) {
 447     die "Must have values key - sets key not yet implemented";
 448   }
 449   [ $self->_format_keyword('INSERT INTO'),
 450     $self->_render($target),
 451     ($names
 452       ? ('(', intersperse(',', map $self->_render($_), @$names), ')')
 453       : ()),
 454     $self->_format_keyword('VALUES'),
 455     intersperse(',',
 456       map [ '(', intersperse(',', map $self->_render($_), @$_), ')' ],
 457         @$values
 458     ),
 459     ($returning
 460       ? ($self->_format_keyword('RETURNING'),
 461          intersperse(',', map $self->_render($_), @$returning))
 462       : ()),
 463   ];
 464 }
 465
 466 1;