t/22_internal_copy.t

   1 ##
   2 # DBM::Deep Test
   3 ##
   4 use strict;
   5 use Test::More tests => 13;
   6 use t::common qw( new_fh );
   7
   8 use_ok( 'DBM::Deep' );
   9
  10 my ($fh, $filename) = new_fh();
  11 my $db = DBM::Deep->new( file => $filename, fh => $fh, );
  12
  13 ##
  14 # Create structure in $db
  15 ##
  16 $db->import({
  17     hash1 => {
  18         subkey1 => "subvalue1",
  19         subkey2 => "subvalue2",
  20     },
  21     hash2 => {
  22         subkey3 => 'subvalue3',
  23     },
  24 });
  25
  26 is( $db->{hash1}{subkey1}, 'subvalue1', "Value imported correctly" );
  27 is( $db->{hash1}{subkey2}, 'subvalue2', "Value imported correctly" );
  28
  29 $db->{copy} = $db->{hash1};
  30
  31 is( $db->{copy}{subkey1}, 'subvalue1', "Value copied correctly" );
  32 is( $db->{copy}{subkey2}, 'subvalue2', "Value copied correctly" );
  33
  34 $db->{copy}{subkey1} = "another value";
  35 is( $db->{copy}{subkey1}, 'another value', "New value is set correctly" );
  36 is( $db->{hash1}{subkey1}, 'another value', "Old value is set to the new one" );
  37
  38 is( scalar(keys %{$db->{hash1}}), 2, "Start with 2 keys in the original" );
  39 is( scalar(keys %{$db->{copy}}), 2, "Start with 2 keys in the copy" );
  40
  41 delete $db->{copy}{subkey2};
  42
  43 is( scalar(keys %{$db->{copy}}), 1, "Now only have 1 key in the copy" );
  44 is( scalar(keys %{$db->{hash1}}), 1, "... and only 1 key in the original" );
  45
  46 $db->{copy} = $db->{hash2};
  47 is( $db->{copy}{subkey3}, 'subvalue3', "After the second copy, we're still good" );
  48 my $max_keys = 1000;
  49
  50 my ($fh2, $filename2) = new_fh();
  51 {
  52     my $db = DBM::Deep->new( file => $filename2, fh => $fh2, );
  53
  54     $db->{foo} = [ 1 .. 3 ];
  55     for ( 0 .. $max_keys ) {
  56         $db->{'foo' . $_} = $db->{foo};
  57     }
  58     ## Rewind handle otherwise the signature is not recognised below.
  59     ## The signature check should probably rewind the fh?
  60     seek $db->_get_self->_engine->storage->{fh}, 0, 0;
  61 }
  62
  63 {
  64     my $db = DBM::Deep->new( fh => $fh2, );
  65
  66     my $base_offset = $db->{foo}->_base_offset;
  67     my $count = -1;
  68     for ( 0 .. $max_keys ) {
  69         $count = $_;
  70         unless ( $base_offset == $db->{'foo'.$_}->_base_offset ) {
  71             last;
  72         }
  73     }
  74     is( $count, $max_keys, "We read $count keys" );
  75 }