lib/DBM/Deep/Engine.pm

   1 package DBM::Deep::Engine;
   2
   3 use 5.006_000;
   4
   5 use strict;
   6 use warnings FATAL => 'all';
   7
   8 # Never import symbols into our namespace. We are a class, not a library.
   9 # -RobK, 2008-05-27
  10 use Scalar::Util ();
  11
  12 #use Data::Dumper ();
  13
  14 # File-wide notes:
  15 # * Every method in here assumes that the storage has been appropriately
  16 #   safeguarded. This can be anything from flock() to some sort of manual
  17 #   mutex. But, it's the caller's responsability to make sure that this has
  18 #   been done.
  19
  20 # Setup file and tag signatures.  These should never change.
  21 sub SIG_FILE     () { 'DPDB' }
  22 sub SIG_HEADER   () { 'h'    }
  23 sub SIG_HASH     () { 'H'    }
  24 sub SIG_ARRAY    () { 'A'    }
  25 sub SIG_NULL     () { 'N'    }
  26 sub SIG_DATA     () { 'D'    }
  27 sub SIG_INDEX    () { 'I'    }
  28 sub SIG_BLIST    () { 'B'    }
  29 sub SIG_FREE     () { 'F'    }
  30 sub SIG_SIZE     () {  1     }
  31
  32 our $STALE_SIZE = 2;
  33
  34 # Please refer to the pack() documentation for further information
  35 my %StP = (
  36     1 => 'C', # Unsigned char value (no order needed as it's just one byte)
  37     2 => 'n', # Unsigned short in "network" (big-endian) order
  38     4 => 'N', # Unsigned long in "network" (big-endian) order
  39     8 => 'Q', # Usigned quad (no order specified, presumably machine-dependent)
  40 );
  41 sub StP { $StP{$_[1]} }
  42
  43 # Import these after the SIG_* definitions because those definitions are used
  44 # in the headers of these classes. -RobK, 2008-06-20
  45 use DBM::Deep::Engine::Sector::BucketList;
  46 use DBM::Deep::Engine::Sector::FileHeader;
  47 use DBM::Deep::Engine::Sector::Index;
  48 use DBM::Deep::Engine::Sector::Null;
  49 use DBM::Deep::Engine::Sector::Reference;
  50 use DBM::Deep::Engine::Sector::Scalar;
  51 use DBM::Deep::Iterator;
  52
  53 ################################################################################
  54
  55 sub new {
  56     my $class = shift;
  57     my ($args) = @_;
  58
  59     $args->{storage} = DBM::Deep::File->new( $args )
  60         unless exists $args->{storage};
  61
  62     my $self = bless {
  63         byte_size   => 4,
  64
  65         digest      => undef,
  66         hash_size   => 16,  # In bytes
  67         hash_chars  => 256, # Number of chars the algorithm uses per byte
  68         max_buckets => 16,
  69         num_txns    => 1,   # The HEAD
  70         trans_id    => 0,   # Default to the HEAD
  71
  72         data_sector_size => 64, # Size in bytes of each data sector
  73
  74         entries => {}, # This is the list of entries for transactions
  75         storage => undef,
  76     }, $class;
  77
  78     # Never allow byte_size to be set directly.
  79     delete $args->{byte_size};
  80     if ( defined $args->{pack_size} ) {
  81         if ( lc $args->{pack_size} eq 'small' ) {
  82             $args->{byte_size} = 2;
  83         }
  84         elsif ( lc $args->{pack_size} eq 'medium' ) {
  85             $args->{byte_size} = 4;
  86         }
  87         elsif ( lc $args->{pack_size} eq 'large' ) {
  88             $args->{byte_size} = 8;
  89         }
  90         else {
  91             DBM::Deep->_throw_error( "Unknown pack_size value: '$args->{pack_size}'" );
  92         }
  93     }
  94
  95     # Grab the parameters we want to use
  96     foreach my $param ( keys %$self ) {
  97         next unless exists $args->{$param};
  98         $self->{$param} = $args->{$param};
  99     }
 100
 101     my %validations = (
 102         max_buckets      => { floor => 16, ceil => 256 },
 103         num_txns         => { floor => 1,  ceil => 255 },
 104         data_sector_size => { floor => 32, ceil => 256 },
 105     );
 106
 107     while ( my ($attr, $c) = each %validations ) {
 108         if (   !defined $self->{$attr}
 109             || !length $self->{$attr}
 110             || $self->{$attr} =~ /\D/
 111             || $self->{$attr} < $c->{floor}
 112         ) {
 113             $self->{$attr} = '(undef)' if !defined $self->{$attr};
 114             warn "Floor of $attr is $c->{floor}. Setting it to $c->{floor} from '$self->{$attr}'\n";
 115             $self->{$attr} = $c->{floor};
 116         }
 117         elsif ( $self->{$attr} > $c->{ceil} ) {
 118             warn "Ceiling of $attr is $c->{ceil}. Setting it to $c->{ceil} from '$self->{$attr}'\n";
 119             $self->{$attr} = $c->{ceil};
 120         }
 121     }
 122
 123     if ( !$self->{digest} ) {
 124         require Digest::MD5;
 125         $self->{digest} = \&Digest::MD5::md5;
 126     }
 127
 128     return $self;
 129 }
 130
 131 ################################################################################
 132
 133 sub read_value {
 134     my $self = shift;
 135     my ($obj, $key) = @_;
 136
 137     # This will be a Reference sector
 138     my $sector = $self->_load_sector( $obj->_base_offset )
 139         or return;
 140
 141     if ( $sector->staleness != $obj->_staleness ) {
 142         return;
 143     }
 144
 145     my $key_md5 = $self->_apply_digest( $key );
 146
 147     my $value_sector = $sector->get_data_for({
 148         key_md5    => $key_md5,
 149         allow_head => 1,
 150     });
 151
 152     unless ( $value_sector ) {
 153         $value_sector = DBM::Deep::Engine::Sector::Null->new({
 154             engine => $self,
 155             data   => undef,
 156         });
 157
 158         $sector->write_data({
 159             key_md5 => $key_md5,
 160             key     => $key,
 161             value   => $value_sector,
 162         });
 163     }
 164
 165     return $value_sector->data;
 166 }
 167
 168 sub get_classname {
 169     my $self = shift;
 170     my ($obj) = @_;
 171
 172     # This will be a Reference sector
 173     my $sector = $self->_load_sector( $obj->_base_offset )
 174         or DBM::Deep->_throw_error( "How did get_classname fail (no sector for '$obj')?!" );
 175
 176     if ( $sector->staleness != $obj->_staleness ) {
 177         return;
 178     }
 179
 180     return $sector->get_classname;
 181 }
 182
 183 sub make_reference {
 184     my $self = shift;
 185     my ($obj, $old_key, $new_key) = @_;
 186
 187     # This will be a Reference sector
 188     my $sector = $self->_load_sector( $obj->_base_offset )
 189         or DBM::Deep->_throw_error( "How did make_reference fail (no sector for '$obj')?!" );
 190
 191     if ( $sector->staleness != $obj->_staleness ) {
 192         return;
 193     }
 194
 195     my $old_md5 = $self->_apply_digest( $old_key );
 196
 197     my $value_sector = $sector->get_data_for({
 198         key_md5    => $old_md5,
 199         allow_head => 1,
 200     });
 201
 202     unless ( $value_sector ) {
 203         $value_sector = DBM::Deep::Engine::Sector::Null->new({
 204             engine => $self,
 205             data   => undef,
 206         });
 207
 208         $sector->write_data({
 209             key_md5 => $old_md5,
 210             key     => $old_key,
 211             value   => $value_sector,
 212         });
 213     }
 214
 215     if ( $value_sector->isa( 'DBM::Deep::Engine::Sector::Reference' ) ) {
 216         $sector->write_data({
 217             key     => $new_key,
 218             key_md5 => $self->_apply_digest( $new_key ),
 219             value   => $value_sector,
 220         });
 221         $value_sector->increment_refcount;
 222     }
 223     else {
 224         $sector->write_data({
 225             key     => $new_key,
 226             key_md5 => $self->_apply_digest( $new_key ),
 227             value   => $value_sector->clone,
 228         });
 229     }
 230 }
 231
 232 sub key_exists {
 233     my $self = shift;
 234     my ($obj, $key) = @_;
 235
 236     # This will be a Reference sector
 237     my $sector = $self->_load_sector( $obj->_base_offset )
 238         or return '';
 239
 240     if ( $sector->staleness != $obj->_staleness ) {
 241         return '';
 242     }
 243
 244     my $data = $sector->get_data_for({
 245         key_md5    => $self->_apply_digest( $key ),
 246         allow_head => 1,
 247     });
 248
 249     # exists() returns 1 or '' for true/false.
 250     return $data ? 1 : '';
 251 }
 252
 253 sub delete_key {
 254     my $self = shift;
 255     my ($obj, $key) = @_;
 256
 257     my $sector = $self->_load_sector( $obj->_base_offset )
 258         or return;
 259
 260     if ( $sector->staleness != $obj->_staleness ) {
 261         return;
 262     }
 263
 264     return $sector->delete_key({
 265         key_md5    => $self->_apply_digest( $key ),
 266         allow_head => 0,
 267     });
 268 }
 269
 270 sub write_value {
 271     my $self = shift;
 272     my ($obj, $key, $value) = @_;
 273
 274     my $r = Scalar::Util::reftype( $value ) || '';
 275     {
 276         last if $r eq '';
 277         last if $r eq 'HASH';
 278         last if $r eq 'ARRAY';
 279
 280         DBM::Deep->_throw_error(
 281             "Storage of references of type '$r' is not supported."
 282         );
 283     }
 284
 285     # This will be a Reference sector
 286     my $sector = $self->_load_sector( $obj->_base_offset )
 287         or DBM::Deep->_throw_error( "1: Cannot write to a deleted spot in DBM::Deep." );
 288
 289     if ( $sector->staleness != $obj->_staleness ) {
 290         DBM::Deep->_throw_error( "2: Cannot write to a deleted spot in DBM::Deep." );
 291     }
 292
 293     my ($class, $type);
 294     if ( !defined $value ) {
 295         $class = 'DBM::Deep::Engine::Sector::Null';
 296     }
 297     elsif ( $r eq 'ARRAY' || $r eq 'HASH' ) {
 298         my $tmpvar;
 299         if ( $r eq 'ARRAY' ) {
 300             $tmpvar = tied @$value;
 301         } elsif ( $r eq 'HASH' ) {
 302             $tmpvar = tied %$value;
 303         }
 304
 305         if ( $tmpvar ) {
 306             my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $tmpvar->isa( 'DBM::Deep' ); };
 307
 308             unless ( $is_dbm_deep ) {
 309                 DBM::Deep->_throw_error( "Cannot store something that is tied." );
 310             }
 311
 312             unless ( $tmpvar->_engine->storage == $self->storage ) {
 313                 DBM::Deep->_throw_error( "Cannot store values across DBM::Deep files. Please use export() instead." );
 314             }
 315
 316             # First, verify if we're storing the same thing to this spot. If we are, then
 317             # this should be a no-op. -EJS, 2008-05-19
 318             my $loc = $sector->get_data_location_for({
 319                 key_md5 => $self->_apply_digest( $key ),
 320                 allow_head => 1,
 321             });
 322
 323             if ( defined($loc) && $loc == $tmpvar->_base_offset ) {
 324                 return 1;
 325             }
 326
 327             #XXX Can this use $loc?
 328             my $value_sector = $self->_load_sector( $tmpvar->_base_offset );
 329             $sector->write_data({
 330                 key     => $key,
 331                 key_md5 => $self->_apply_digest( $key ),
 332                 value   => $value_sector,
 333             });
 334             $value_sector->increment_refcount;
 335
 336             return 1;
 337         }
 338
 339         $class = 'DBM::Deep::Engine::Sector::Reference';
 340         $type = substr( $r, 0, 1 );
 341     }
 342     else {
 343         if ( tied($value) ) {
 344             DBM::Deep->_throw_error( "Cannot store something that is tied." );
 345         }
 346         $class = 'DBM::Deep::Engine::Sector::Scalar';
 347     }
 348
 349     # Create this after loading the reference sector in case something bad happens.
 350     # This way, we won't allocate value sector(s) needlessly.
 351     my $value_sector = $class->new({
 352         engine => $self,
 353         data   => $value,
 354         type   => $type,
 355     });
 356
 357     $sector->write_data({
 358         key     => $key,
 359         key_md5 => $self->_apply_digest( $key ),
 360         value   => $value_sector,
 361     });
 362
 363     # This code is to make sure we write all the values in the $value to the disk
 364     # and to make sure all changes to $value after the assignment are reflected
 365     # on disk. This may be counter-intuitive at first, but it is correct dwimmery.
 366     #   NOTE - simply tying $value won't perform a STORE on each value. Hence, the
 367     # copy to a temp value.
 368     if ( $r eq 'ARRAY' ) {
 369         my @temp = @$value;
 370         tie @$value, 'DBM::Deep', {
 371             base_offset => $value_sector->offset,
 372             staleness   => $value_sector->staleness,
 373             storage     => $self->storage,
 374             engine      => $self,
 375         };
 376         @$value = @temp;
 377         bless $value, 'DBM::Deep::Array' unless Scalar::Util::blessed( $value );
 378     }
 379     elsif ( $r eq 'HASH' ) {
 380         my %temp = %$value;
 381         tie %$value, 'DBM::Deep', {
 382             base_offset => $value_sector->offset,
 383             staleness   => $value_sector->staleness,
 384             storage     => $self->storage,
 385             engine      => $self,
 386         };
 387
 388         %$value = %temp;
 389         bless $value, 'DBM::Deep::Hash' unless Scalar::Util::blessed( $value );
 390     }
 391
 392     return 1;
 393 }
 394
 395 # XXX Add staleness here
 396 sub get_next_key {
 397     my $self = shift;
 398     my ($obj, $prev_key) = @_;
 399
 400     # XXX Need to add logic about resetting the iterator if any key in the reference has changed
 401     unless ( $prev_key ) {
 402         $obj->{iterator} = DBM::Deep::Iterator->new({
 403             base_offset => $obj->_base_offset,
 404             engine      => $self,
 405         });
 406     }
 407
 408     return $obj->{iterator}->get_next_key( $obj );
 409 }
 410
 411 ################################################################################
 412
 413 sub setup_fh {
 414     my $self = shift;
 415     my ($obj) = @_;
 416
 417     return 1 if $obj->_base_offset;
 418
 419     my $header = $self->_load_header;
 420
 421     # Creating a new file
 422     if ( $header->is_new ) {
 423         # 1) Create Array/Hash entry
 424         my $sector = DBM::Deep::Engine::Sector::Reference->new({
 425             engine => $self,
 426             type   => $obj->_type,
 427         });
 428         $obj->{base_offset} = $sector->offset;
 429         $obj->{staleness} = $sector->staleness;
 430
 431         $self->flush;
 432     }
 433     # Reading from an existing file
 434     else {
 435         $obj->{base_offset} = $header->size;
 436         my $sector = DBM::Deep::Engine::Sector::Reference->new({
 437             engine => $self,
 438             offset => $obj->_base_offset,
 439         });
 440         unless ( $sector ) {
 441             DBM::Deep->_throw_error("Corrupted file, no master index record");
 442         }
 443
 444         unless ($obj->_type eq $sector->type) {
 445             DBM::Deep->_throw_error("File type mismatch");
 446         }
 447
 448         $obj->{staleness} = $sector->staleness;
 449     }
 450
 451     $self->storage->set_inode;
 452
 453     return 1;
 454 }
 455
 456 sub begin_work {
 457     my $self = shift;
 458     my ($obj) = @_;
 459
 460     if ( $self->trans_id ) {
 461         DBM::Deep->_throw_error( "Cannot begin_work within an active transaction" );
 462     }
 463
 464     my @slots = $self->read_txn_slots;
 465     my $found;
 466     for my $i ( 0 .. $#slots ) {
 467         next if $slots[$i];
 468
 469         $slots[$i] = 1;
 470         $self->set_trans_id( $i + 1 );
 471         $found = 1;
 472         last;
 473     }
 474     unless ( $found ) {
 475         DBM::Deep->_throw_error( "Cannot allocate transaction ID" );
 476     }
 477     $self->write_txn_slots( @slots );
 478
 479     if ( !$self->trans_id ) {
 480         DBM::Deep->_throw_error( "Cannot begin_work - no available transactions" );
 481     }
 482
 483     return;
 484 }
 485
 486 sub rollback {
 487     my $self = shift;
 488     my ($obj) = @_;
 489
 490     if ( !$self->trans_id ) {
 491         DBM::Deep->_throw_error( "Cannot rollback without an active transaction" );
 492     }
 493
 494     foreach my $entry ( @{ $self->get_entries } ) {
 495         my ($sector, $idx) = split ':', $entry;
 496         $self->_load_sector( $sector )->rollback( $idx );
 497     }
 498
 499 =pod
 500     # Each entry is the file location for a bucket that has a modification for
 501     # this transaction. The entries need to be expunged.
 502     foreach my $entry (@{ $self->get_entries } ) {
 503         # Remove the entry here
 504         my $read_loc = $entry
 505           + $self->hash_size
 506           + $self->byte_size
 507           + $self->byte_size
 508           + ($self->trans_id - 1) * ( $self->byte_size + $STALE_SIZE );
 509
 510         my $data_loc = $self->storage->read_at( $read_loc, $self->byte_size );
 511         $data_loc = unpack( $StP{$self->byte_size}, $data_loc );
 512         $self->storage->print_at( $read_loc, pack( $StP{$self->byte_size}, 0 ) );
 513
 514         if ( $data_loc > 1 ) {
 515             $self->_load_sector( $data_loc )->free;
 516         }
 517     }
 518 =cut
 519
 520     $self->clear_entries;
 521
 522     my @slots = $self->read_txn_slots;
 523     $slots[$self->trans_id-1] = 0;
 524     $self->write_txn_slots( @slots );
 525     $self->inc_txn_staleness_counter( $self->trans_id );
 526     $self->set_trans_id( 0 );
 527
 528     return 1;
 529 }
 530
 531 sub commit {
 532     my $self = shift;
 533     my ($obj) = @_;
 534
 535     if ( !$self->trans_id ) {
 536         DBM::Deep->_throw_error( "Cannot commit without an active transaction" );
 537     }
 538
 539     foreach my $entry ( @{ $self->get_entries } ) {
 540         my ($sector, $idx) = split ':', $entry;
 541         $self->_load_sector( $sector )->commit( $idx );
 542     }
 543
 544 =pod
 545     foreach my $entry (@{ $self->get_entries } ) {
 546         # Overwrite the entry in head with the entry in trans_id
 547         my $base = $entry
 548           + $self->hash_size
 549           + $self->byte_size;
 550
 551         my $head_loc = $self->storage->read_at( $base, $self->byte_size );
 552         $head_loc = unpack( $StP{$self->byte_size}, $head_loc );
 553
 554         my $spot = $base + $self->byte_size + ($self->trans_id - 1) * ( $self->byte_size + $STALE_SIZE );
 555         my $trans_loc = $self->storage->read_at(
 556             $spot, $self->byte_size,
 557         );
 558
 559         $self->storage->print_at( $base, $trans_loc );
 560         $self->storage->print_at(
 561             $spot,
 562             pack( $StP{$self->byte_size} . ' ' . $StP{$STALE_SIZE}, (0) x 2 ),
 563         );
 564
 565         if ( $head_loc > 1 ) {
 566             $self->_load_sector( $head_loc )->free;
 567         }
 568     }
 569 =cut
 570
 571     $self->clear_entries;
 572
 573     my @slots = $self->read_txn_slots;
 574     $slots[$self->trans_id-1] = 0;
 575     $self->write_txn_slots( @slots );
 576     $self->inc_txn_staleness_counter( $self->trans_id );
 577     $self->set_trans_id( 0 );
 578
 579     return 1;
 580 }
 581
 582 sub read_txn_slots {
 583     my $self = shift;
 584     return $self->_load_header->read_txn_slots(@_);
 585 }
 586
 587 sub write_txn_slots {
 588     my $self = shift;
 589     return $self->_load_header->write_txn_slots(@_);
 590 }
 591
 592 sub get_running_txn_ids {
 593     my $self = shift;
 594     my @transactions = $self->read_txn_slots;
 595     my @trans_ids = map { $_+1} grep { $transactions[$_] } 0 .. $#transactions;
 596 }
 597
 598 sub get_txn_staleness_counter {
 599     my $self = shift;
 600     return $self->_load_header->get_txn_staleness_counter(@_);
 601 }
 602
 603 sub inc_txn_staleness_counter {
 604     my $self = shift;
 605     return $self->_load_header->inc_txn_staleness_counter(@_);
 606 }
 607
 608 sub get_entries {
 609     my $self = shift;
 610     return [ keys %{ $self->{entries}{$self->trans_id} ||= {} } ];
 611 }
 612
 613 sub add_entry {
 614     my $self = shift;
 615     my ($trans_id, $loc, $idx) = @_;
 616
 617     $self->{entries}{$trans_id} ||= {};
 618     $self->{entries}{$trans_id}{"$loc:$idx"} = undef;
 619 }
 620
 621 # If the buckets are being relocated because of a reindexing, the entries
 622 # mechanism needs to be made aware of it.
 623 sub reindex_entry {
 624     my $self = shift;
 625     my ($old_loc, $old_idx, $new_loc, $new_idx) = @_;
 626
 627     TRANS:
 628     while ( my ($trans_id, $locs) = each %{ $self->{entries} } ) {
 629         if ( exists $locs->{"$old_loc:$old_idx"} ) {
 630             delete $locs->{"$old_loc:$old_idx"};
 631             $locs->{"$new_loc:$new_idx"} = undef;
 632             next TRANS;
 633         }
 634     }
 635 }
 636
 637 sub clear_entries {
 638     my $self = shift;
 639     delete $self->{entries}{$self->trans_id};
 640 }
 641
 642 ################################################################################
 643
 644 sub _apply_digest {
 645     my $self = shift;
 646     return $self->{digest}->(@_);
 647 }
 648
 649 sub _add_free_blist_sector { shift->_add_free_sector( 0, @_ ) }
 650 sub _add_free_data_sector  { shift->_add_free_sector( 1, @_ ) }
 651 sub _add_free_index_sector { shift->_add_free_sector( 2, @_ ) }
 652 sub _add_free_sector       { shift->_load_header->add_free_sector( @_ ) }
 653
 654 sub _request_blist_sector { shift->_request_sector( 0, @_ ) }
 655 sub _request_data_sector  { shift->_request_sector( 1, @_ ) }
 656 sub _request_index_sector { shift->_request_sector( 2, @_ ) }
 657 sub _request_sector       { shift->_load_header->request_sector( @_ ) }
 658
 659 ################################################################################
 660
 661 {
 662     my %t = (
 663         SIG_ARRAY => 'Reference',
 664         SIG_HASH  => 'Reference',
 665         SIG_BLIST => 'BucketList',
 666         SIG_INDEX => 'Index',
 667         SIG_NULL  => 'Null',
 668         SIG_DATA  => 'Scalar',
 669     );
 670
 671     my %class_for;
 672     while ( my ($k,$v) = each %t ) {
 673         $class_for{ DBM::Deep::Engine->$k } = "DBM::Deep::Engine::Sector::$v";
 674     }
 675
 676     sub load_sector {
 677         my $self = shift;
 678         my ($offset) = @_;
 679
 680         my $data = $self->get_data( $offset )
 681             or return;#die "Cannot read from '$offset'\n";
 682         my $type = substr( $$data, 0, 1 );
 683         my $class = $class_for{ $type };
 684         return $class->new({
 685             engine => $self,
 686             type   => $type,
 687             offset => $offset,
 688         });
 689     }
 690     *_load_sector = \&load_sector;
 691
 692     sub load_header {
 693         my $self = shift;
 694
 695         #XXX Does this mean we make too many objects? -RobK, 2008-06-23
 696         return DBM::Deep::Engine::Sector::FileHeader->new({
 697             engine => $self,
 698             offset => 0,
 699         });
 700     }
 701     *_load_header = \&load_header;
 702
 703     sub get_data {
 704         my $self = shift;
 705         my ($offset, $size) = @_;
 706         return unless defined $offset;
 707
 708         unless ( exists $self->sector_cache->{$offset} ) {
 709             # Don't worry about the header sector. It will manage itself.
 710             return unless $offset;
 711
 712             if ( !defined $size ) {
 713                 my $type = $self->storage->read_at( $offset, 1 )
 714                     or die "($offset): Cannot read from '$offset' to find the type\n";
 715
 716                 if ( $type eq $self->SIG_FREE ) {
 717                     return;
 718                 }
 719
 720                 my $class = $class_for{$type}
 721                     or die "($offset): Cannot find class for '$type'\n";
 722                 $size = $class->size( $self )
 723                     or die "($offset): '$class' doesn't return a size\n";
 724                 $self->sector_cache->{$offset} = $type . $self->storage->read_at( undef, $size - 1 );
 725             }
 726             else {
 727                 $self->sector_cache->{$offset} = $self->storage->read_at( $offset, $size )
 728                     or return;
 729             }
 730         }
 731
 732         return \$self->sector_cache->{$offset};
 733     }
 734 }
 735
 736 sub sector_cache {
 737     my $self = shift;
 738     return $self->{sector_cache} ||= {};
 739 }
 740
 741 sub clear_sector_cache {
 742     my $self = shift;
 743     $self->{sector_cache} = {};
 744 }
 745
 746 sub dirty_sectors {
 747     my $self = shift;
 748     return $self->{dirty_sectors} ||= {};
 749 }
 750
 751 sub clear_dirty_sectors {
 752     my $self = shift;
 753     $self->{dirty_sectors} = {};
 754 }
 755
 756 sub add_dirty_sector {
 757     my $self = shift;
 758     my ($offset) = @_;
 759
 760     $self->dirty_sectors->{ $offset } = undef;
 761 }
 762
 763 sub flush {
 764     my $self = shift;
 765
 766     my $sectors = $self->dirty_sectors;
 767     for my $offset (sort { $a <=> $b } keys %{ $sectors }) {
 768         $self->storage->print_at( $offset, $self->sector_cache->{$offset} );
 769     }
 770
 771     # Why do we need to have the storage flush? Shouldn't autoflush take care of things?
 772     # -RobK, 2008-06-26
 773     $self->storage->flush;
 774
 775     $self->clear_dirty_sectors;
 776
 777     $self->clear_sector_cache;
 778 }
 779
 780 ################################################################################
 781
 782 sub lock_exclusive {
 783     my $self = shift;
 784     my ($obj) = @_;
 785     return $self->storage->lock_exclusive( $obj );
 786 }
 787
 788 sub lock_shared {
 789     my $self = shift;
 790     my ($obj) = @_;
 791     return $self->storage->lock_shared( $obj );
 792 }
 793
 794 sub unlock {
 795     my $self = shift;
 796     my ($obj) = @_;
 797
 798     my $rv = $self->storage->unlock( $obj );
 799
 800     $self->flush if $rv;
 801
 802     return $rv;
 803 }
 804
 805 ################################################################################
 806
 807 sub storage     { $_[0]{storage} }
 808 sub byte_size   { $_[0]{byte_size} }
 809 sub hash_size   { $_[0]{hash_size} }
 810 sub hash_chars  { $_[0]{hash_chars} }
 811 sub num_txns    { $_[0]{num_txns} }
 812 sub max_buckets { $_[0]{max_buckets} }
 813 sub blank_md5   { chr(0) x $_[0]->hash_size }
 814 sub data_sector_size { $_[0]{data_sector_size} }
 815
 816 # This is a calculated value
 817 sub txn_bitfield_len {
 818     my $self = shift;
 819     unless ( exists $self->{txn_bitfield_len} ) {
 820         my $temp = ($self->num_txns) / 8;
 821         if ( $temp > int( $temp ) ) {
 822             $temp = int( $temp ) + 1;
 823         }
 824         $self->{txn_bitfield_len} = $temp;
 825     }
 826     return $self->{txn_bitfield_len};
 827 }
 828
 829 sub trans_id     { $_[0]{trans_id} }
 830 sub set_trans_id { $_[0]{trans_id} = $_[1] }
 831
 832 sub trans_loc     { $_[0]{trans_loc} }
 833 sub set_trans_loc { $_[0]{trans_loc} = $_[1] }
 834
 835 sub chains_loc     { $_[0]{chains_loc} }
 836 sub set_chains_loc { $_[0]{chains_loc} = $_[1] }
 837
 838 sub cache       { $_[0]{cache} ||= {} }
 839 sub clear_cache { %{$_[0]->cache} = () }
 840
 841 sub _dump_file {
 842     my $self = shift;
 843     $self->flush;
 844
 845     # Read the header
 846     my $header_sector = DBM::Deep::Engine::Sector::FileHeader->new({
 847         engine => $self,
 848     });
 849
 850     my %types = (
 851         0 => 'B',
 852         1 => 'D',
 853         2 => 'I',
 854     );
 855
 856     my %sizes = (
 857         'D' => $self->data_sector_size,
 858         'B' => DBM::Deep::Engine::Sector::BucketList->new({engine=>$self,offset=>1})->size,
 859         'I' => DBM::Deep::Engine::Sector::Index->new({engine=>$self,offset=>1})->size,
 860     );
 861
 862     my $return = "";
 863
 864     # Filesize
 865     $return .= "Size: " . (-s $self->storage->{fh}) . $/;
 866
 867     # Header values
 868     $return .= "NumTxns: " . $self->num_txns . $/;
 869
 870     # Read the free sector chains
 871     my %sectors;
 872     foreach my $multiple ( 0 .. 2 ) {
 873         $return .= "Chains($types{$multiple}):";
 874         my $old_loc = $self->chains_loc + $multiple * $self->byte_size;
 875         while ( 1 ) {
 876             my $loc = unpack(
 877                 $StP{$self->byte_size},
 878                 $self->storage->read_at( $old_loc, $self->byte_size ),
 879             );
 880
 881             # We're now out of free sectors of this kind.
 882             unless ( $loc ) {
 883                 last;
 884             }
 885
 886             $sectors{ $types{$multiple} }{ $loc } = undef;
 887             $old_loc = $loc + SIG_SIZE + $STALE_SIZE;
 888             $return .= " $loc";
 889         }
 890         $return .= $/;
 891     }
 892
 893     my $spot = $header_sector->size;
 894     SECTOR:
 895     while ( $spot < $self->storage->{end} ) {
 896         # Read each sector in order.
 897         my $sector = $self->_load_sector( $spot );
 898         if ( !$sector ) {
 899             # Find it in the free-sectors that were found already
 900             foreach my $type ( keys %sectors ) {
 901                 if ( exists $sectors{$type}{$spot} ) {
 902                     my $size = $sizes{$type};
 903                     $return .= sprintf "%08d: %s %04d\n", $spot, 'F' . $type, $size;
 904                     $spot += $size;
 905                     next SECTOR;
 906                 }
 907             }
 908
 909             die "********\n$return\nDidn't find free sector for $spot in chains\n********\n";
 910         }
 911         else {
 912             $return .= sprintf "%08d: %s  %04d", $spot, $sector->type, $sector->size;
 913             if ( $sector->type eq 'D' ) {
 914                 $return .= ' ' . $sector->data;
 915             }
 916             elsif ( $sector->type eq 'A' || $sector->type eq 'H' ) {
 917                 $return .= ' REF: ' . $sector->get_refcount;
 918             }
 919             elsif ( $sector->type eq 'B' ) {
 920                 foreach my $bucket ( $sector->chopped_up ) {
 921                     $return .= "\n    ";
 922                     $return .= sprintf "%08d", unpack($StP{$self->byte_size},
 923                         substr( $bucket->[-1], $self->hash_size, $self->byte_size),
 924                     );
 925                     my $l = unpack( $StP{$self->byte_size},
 926                         substr( $bucket->[-1],
 927                             $self->hash_size + $self->byte_size,
 928                             $self->byte_size,
 929                         ),
 930                     );
 931                     $return .= sprintf " %08d", $l;
 932                     foreach my $txn ( 0 .. $self->num_txns - 2 ) {
 933                         my $l = unpack( $StP{$self->byte_size},
 934                             substr( $bucket->[-1],
 935                                 $self->hash_size + 2 * $self->byte_size + $txn * ($self->byte_size + $STALE_SIZE),
 936                                 $self->byte_size,
 937                             ),
 938                         );
 939                         $return .= sprintf " %08d", $l;
 940                     }
 941                 }
 942             }
 943             $return .= $/;
 944
 945             $spot += $sector->size;
 946         }
 947     }
 948
 949     return $return;
 950 }
 951
 952 1;
 953 __END__