lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.981);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #_precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { SIG_HASH   }
 104 sub TYPE_ARRAY  () { SIG_ARRAY  }
 105 sub TYPE_SCALAR () { SIG_SCALAR }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( ref $_[0] ) {
 118         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     # locking implicitly enables autoflush
 176     if ($args->{locking}) { $args->{autoflush} = 1; }
 177
 178     $self->{root} = exists $args->{root}
 179         ? $args->{root}
 180         : DBM::Deep::_::Root->new( $args );
 181
 182     if (!defined($self->_fh)) { $self->_open(); }
 183
 184     return $self;
 185 }
 186
 187 sub TIEHASH {
 188     shift;
 189     require DBM::Deep::Hash;
 190     return DBM::Deep::Hash->TIEHASH( @_ );
 191 }
 192
 193 sub TIEARRAY {
 194     shift;
 195     require DBM::Deep::Array;
 196     return DBM::Deep::Array->TIEARRAY( @_ );
 197 }
 198
 199 #XXX Unneeded now ...
 200 #sub DESTROY {
 201 #}
 202
 203 sub _open {
 204         ##
 205         # Open a fh to the database, create if nonexistent.
 206         # Make sure file signature matches DBM::Deep spec.
 207         ##
 208     my $self = $_[0]->_get_self;
 209
 210         if (defined($self->_fh)) { $self->_close(); }
 211
 212     eval {
 213         local $SIG{'__DIE__'};
 214         # Theoretically, adding O_BINARY should remove the need for the binmode
 215         # Of course, testing it is going to be ... interesting.
 216         my $flags = O_RDWR | O_CREAT | O_BINARY;
 217
 218         my $fh;
 219         sysopen( $fh, $self->_root->{file}, $flags )
 220             or $fh = undef;
 221         $self->_root->{fh} = $fh;
 222     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 223         if (! defined($self->_fh)) {
 224                 return $self->_throw_error("Cannot sysopen file: " . $self->_root->{file} . ": $!");
 225         }
 226
 227     my $fh = $self->_fh;
 228
 229     #XXX Can we remove this by using the right sysopen() flags?
 230     # Maybe ... q.v. above
 231     binmode $fh; # for win32
 232
 233     if ($self->_root->{autoflush}) {
 234         my $old = select $fh;
 235         $|=1;
 236         select $old;
 237     }
 238
 239     seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 240
 241     my $signature;
 242     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 243
 244     ##
 245     # File is empty -- write signature and master index
 246     ##
 247     if (!$bytes_read) {
 248         seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 249         print( $fh SIG_FILE);
 250         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
 251
 252         my $plain_key = "[base]";
 253         print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 254
 255         # Flush the filehandle
 256         my $old_fh = select $fh;
 257         my $old_af = $|; $| = 1; $| = $old_af;
 258         select $old_fh;
 259
 260         my @stats = stat($fh);
 261         $self->_root->{inode} = $stats[1];
 262         $self->_root->{end} = $stats[7];
 263
 264         return 1;
 265     }
 266
 267     ##
 268     # Check signature was valid
 269     ##
 270     unless ($signature eq SIG_FILE) {
 271         $self->_close();
 272         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 273     }
 274
 275         my @stats = stat($fh);
 276         $self->_root->{inode} = $stats[1];
 277     $self->_root->{end} = $stats[7];
 278
 279     ##
 280     # Get our type from master index signature
 281     ##
 282     my $tag = $self->_load_tag($self->_base_offset);
 283
 284 #XXX We probably also want to store the hash algorithm name and not assume anything
 285 #XXX The cool thing would be to allow a different hashing algorithm at every level
 286
 287     if (!$tag) {
 288         return $self->_throw_error("Corrupted file, no master index record");
 289     }
 290     if ($self->{type} ne $tag->{signature}) {
 291         return $self->_throw_error("File type mismatch");
 292     }
 293
 294     return 1;
 295 }
 296
 297 sub _close {
 298         ##
 299         # Close database fh
 300         ##
 301     my $self = $_[0]->_get_self;
 302     close $self->_root->{fh} if $self->_root->{fh};
 303     $self->_root->{fh} = undef;
 304 }
 305
 306 sub _create_tag {
 307         ##
 308         # Given offset, signature and content, create tag and write to disk
 309         ##
 310         my ($self, $offset, $sig, $content) = @_;
 311         my $size = length($content);
 312
 313     my $fh = $self->_fh;
 314
 315         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 316         print( $fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 317
 318         if ($offset == $self->_root->{end}) {
 319                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 320         }
 321
 322         return {
 323                 signature => $sig,
 324                 size => $size,
 325                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 326                 content => $content
 327         };
 328 }
 329
 330 sub _load_tag {
 331         ##
 332         # Given offset, load single tag and return signature, size and data
 333         ##
 334         my $self = shift;
 335         my $offset = shift;
 336
 337     my $fh = $self->_fh;
 338
 339         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 340         if (eof $fh) { return undef; }
 341
 342     my $b;
 343     read( $fh, $b, SIG_SIZE + $DATA_LENGTH_SIZE );
 344     my ($sig, $size) = unpack( "A $DATA_LENGTH_PACK", $b );
 345
 346         my $buffer;
 347         read( $fh, $buffer, $size);
 348
 349         return {
 350                 signature => $sig,
 351                 size => $size,
 352                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 353                 content => $buffer
 354         };
 355 }
 356
 357 sub _index_lookup {
 358         ##
 359         # Given index tag, lookup single entry in index and return .
 360         ##
 361         my $self = shift;
 362         my ($tag, $index) = @_;
 363
 364         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 365         if (!$location) { return; }
 366
 367         return $self->_load_tag( $location );
 368 }
 369
 370 sub _add_bucket {
 371         ##
 372         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 373         # plain (undigested) key and value.
 374         ##
 375         my $self = shift;
 376         my ($tag, $md5, $plain_key, $value) = @_;
 377         my $keys = $tag->{content};
 378         my $location = 0;
 379         my $result = 2;
 380
 381     my $root = $self->_root;
 382
 383     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 384         my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 385
 386     my $fh = $self->_fh;
 387
 388         ##
 389         # Iterate through buckets, seeing if this is a new entry or a replace.
 390         ##
 391         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 392                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 393                 if (!$subloc) {
 394                         ##
 395                         # Found empty bucket (end of list).  Populate and exit loop.
 396                         ##
 397                         $result = 2;
 398
 399             $location = $internal_ref
 400                 ? $value->_base_offset
 401                 : $root->{end};
 402
 403                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 404                         print( $fh $md5 . pack($LONG_PACK, $location) );
 405                         last;
 406                 }
 407
 408                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 409                 if ($md5 eq $key) {
 410                         ##
 411                         # Found existing bucket with same key.  Replace with new value.
 412                         ##
 413                         $result = 1;
 414
 415                         if ($internal_ref) {
 416                                 $location = $value->_base_offset;
 417                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 418                                 print( $fh $md5 . pack($LONG_PACK, $location) );
 419                 return $result;
 420                         }
 421
 422             seek($fh, $subloc + SIG_SIZE + $root->{file_offset}, SEEK_SET);
 423             my $size;
 424             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 425
 426             ##
 427             # If value is a hash, array, or raw value with equal or less size, we can
 428             # reuse the same content area of the database.  Otherwise, we have to create
 429             # a new content area at the EOF.
 430             ##
 431             my $actual_length;
 432             my $r = Scalar::Util::reftype( $value ) || '';
 433             if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 434                 $actual_length = $INDEX_SIZE;
 435
 436                 # if autobless is enabled, must also take into consideration
 437                 # the class name, as it is stored along with key/value.
 438                 if ( $root->{autobless} ) {
 439                     my $value_class = Scalar::Util::blessed($value);
 440                     if ( defined $value_class && !$value->isa('DBM::Deep') ) {
 441                         $actual_length += length($value_class);
 442                     }
 443                 }
 444             }
 445             else { $actual_length = length($value); }
 446
 447             if ($actual_length <= $size) {
 448                 $location = $subloc;
 449             }
 450             else {
 451                 $location = $root->{end};
 452                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $root->{file_offset}, SEEK_SET);
 453                 print( $fh pack($LONG_PACK, $location) );
 454             }
 455
 456                         last;
 457                 }
 458         }
 459
 460         ##
 461         # If this is an internal reference, return now.
 462         # No need to write value or plain key
 463         ##
 464         if ($internal_ref) {
 465         return $result;
 466     }
 467
 468         ##
 469         # If bucket didn't fit into list, split into a new index level
 470         ##
 471         if (!$location) {
 472                 seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 473                 print( $fh pack($LONG_PACK, $root->{end}) );
 474
 475                 my $index_tag = $self->_create_tag($root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 476                 my @offsets = ();
 477
 478                 $keys .= $md5 . pack($LONG_PACK, 0);
 479
 480                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 481                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 482                         if ($key) {
 483                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 484                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 485
 486                                 if ($offsets[$num]) {
 487                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 488                                         seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 489                                         my $subkeys;
 490                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 491
 492                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 493                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 494                                                 if (!$subloc) {
 495                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 496                                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 497                                                         last;
 498                                                 }
 499                                         } # k loop
 500                                 }
 501                                 else {
 502                                         $offsets[$num] = $root->{end};
 503                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $root->{file_offset}, SEEK_SET);
 504                                         print( $fh pack($LONG_PACK, $root->{end}) );
 505
 506                                         my $blist_tag = $self->_create_tag($root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 507
 508                                         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 509                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 510                                 }
 511                         } # key is real
 512                 } # i loop
 513
 514                 $location ||= $root->{end};
 515         } # re-index bucket list
 516
 517         ##
 518         # Seek to content area and store signature, value and plaintext key
 519         ##
 520         if ($location) {
 521                 my $content_length;
 522                 seek($fh, $location + $root->{file_offset}, SEEK_SET);
 523
 524                 ##
 525                 # Write signature based on content type, set content length and write actual value.
 526                 ##
 527         my $r = Scalar::Util::reftype($value) || '';
 528                 if ($r eq 'HASH') {
 529                         print( $fh TYPE_HASH );
 530                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 531                         $content_length = $INDEX_SIZE;
 532                 }
 533                 elsif ($r eq 'ARRAY') {
 534                         print( $fh TYPE_ARRAY );
 535                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 536                         $content_length = $INDEX_SIZE;
 537                 }
 538                 elsif (!defined($value)) {
 539                         print( $fh SIG_NULL );
 540                         print( $fh pack($DATA_LENGTH_PACK, 0) );
 541                         $content_length = 0;
 542                 }
 543                 else {
 544                         print( $fh SIG_DATA );
 545                         print( $fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 546                         $content_length = length($value);
 547                 }
 548
 549                 ##
 550                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 551                 ##
 552                 print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 553
 554                 ##
 555                 # If value is blessed, preserve class name
 556                 ##
 557                 if ( $root->{autobless} ) {
 558             my $value_class = Scalar::Util::blessed($value);
 559             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 560                 ##
 561                 # Blessed ref -- will restore later
 562                 ##
 563                 print( $fh chr(1) );
 564                 print( $fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 565                 $content_length += 1;
 566                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 567             }
 568             else {
 569                 print( $fh chr(0) );
 570                 $content_length += 1;
 571             }
 572         }
 573
 574                 ##
 575                 # If this is a new content area, advance EOF counter
 576                 ##
 577                 if ($location == $root->{end}) {
 578                         $root->{end} += SIG_SIZE;
 579                         $root->{end} += $DATA_LENGTH_SIZE + $content_length;
 580                         $root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 581                 }
 582
 583                 ##
 584                 # If content is a hash or array, create new child DBM::Deep object and
 585                 # pass each key or element to it.
 586                 ##
 587                 if ($r eq 'HASH') {
 588                         my $branch = DBM::Deep->new(
 589                                 type => TYPE_HASH,
 590                                 base_offset => $location,
 591                                 root => $root,
 592                         );
 593                         foreach my $key (keys %{$value}) {
 594                 $branch->STORE( $key, $value->{$key} );
 595                         }
 596                 }
 597                 elsif ($r eq 'ARRAY') {
 598                         my $branch = DBM::Deep->new(
 599                                 type => TYPE_ARRAY,
 600                                 base_offset => $location,
 601                                 root => $root,
 602                         );
 603                         my $index = 0;
 604                         foreach my $element (@{$value}) {
 605                 $branch->STORE( $index, $element );
 606                                 $index++;
 607                         }
 608                 }
 609
 610                 return $result;
 611         }
 612
 613         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 614 }
 615
 616 sub _get_bucket_value {
 617         ##
 618         # Fetch single value given tag and MD5 digested key.
 619         ##
 620         my $self = shift;
 621         my ($tag, $md5) = @_;
 622         my $keys = $tag->{content};
 623
 624     my $fh = $self->_fh;
 625
 626         ##
 627         # Iterate through buckets, looking for a key match
 628         ##
 629     BUCKET:
 630         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 631                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 632                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 633
 634                 if (!$subloc) {
 635                         ##
 636                         # Hit end of list, no match
 637                         ##
 638                         return;
 639                 }
 640
 641         if ( $md5 ne $key ) {
 642             next BUCKET;
 643         }
 644
 645         ##
 646         # Found match -- seek to offset and read signature
 647         ##
 648         my $signature;
 649         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 650         read( $fh, $signature, SIG_SIZE);
 651
 652         ##
 653         # If value is a hash or array, return new DBM::Deep object with correct offset
 654         ##
 655         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 656             my $obj = DBM::Deep->new(
 657                 type => $signature,
 658                 base_offset => $subloc,
 659                 root => $self->_root
 660             );
 661
 662             if ($self->_root->{autobless}) {
 663                 ##
 664                 # Skip over value and plain key to see if object needs
 665                 # to be re-blessed
 666                 ##
 667                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 668
 669                 my $size;
 670                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 671                 if ($size) { seek($fh, $size, SEEK_CUR); }
 672
 673                 my $bless_bit;
 674                 read( $fh, $bless_bit, 1);
 675                 if (ord($bless_bit)) {
 676                     ##
 677                     # Yes, object needs to be re-blessed
 678                     ##
 679                     my $class_name;
 680                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 681                     if ($size) { read( $fh, $class_name, $size); }
 682                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 683                 }
 684             }
 685
 686             return $obj;
 687         }
 688
 689         ##
 690         # Otherwise return actual value
 691         ##
 692         elsif ($signature eq SIG_DATA) {
 693             my $size;
 694             my $value = '';
 695             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 696             if ($size) { read( $fh, $value, $size); }
 697             return $value;
 698         }
 699
 700         ##
 701         # Key exists, but content is null
 702         ##
 703         else { return; }
 704         } # i loop
 705
 706         return;
 707 }
 708
 709 sub _delete_bucket {
 710         ##
 711         # Delete single key/value pair given tag and MD5 digested key.
 712         ##
 713         my $self = shift;
 714         my ($tag, $md5) = @_;
 715         my $keys = $tag->{content};
 716
 717     my $fh = $self->_fh;
 718
 719         ##
 720         # Iterate through buckets, looking for a key match
 721         ##
 722     BUCKET:
 723         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 724                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 725                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 726
 727                 if (!$subloc) {
 728                         ##
 729                         # Hit end of list, no match
 730                         ##
 731                         return;
 732                 }
 733
 734         if ( $md5 ne $key ) {
 735             next BUCKET;
 736         }
 737
 738         ##
 739         # Matched key -- delete bucket and return
 740         ##
 741         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 742         print( $fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 743         print( $fh chr(0) x $BUCKET_SIZE );
 744
 745         return 1;
 746         } # i loop
 747
 748         return;
 749 }
 750
 751 sub _bucket_exists {
 752         ##
 753         # Check existence of single key given tag and MD5 digested key.
 754         ##
 755         my $self = shift;
 756         my ($tag, $md5) = @_;
 757         my $keys = $tag->{content};
 758
 759         ##
 760         # Iterate through buckets, looking for a key match
 761         ##
 762     BUCKET:
 763         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 764                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 765                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 766
 767                 if (!$subloc) {
 768                         ##
 769                         # Hit end of list, no match
 770                         ##
 771                         return;
 772                 }
 773
 774         if ( $md5 ne $key ) {
 775             next BUCKET;
 776         }
 777
 778         ##
 779         # Matched key -- return true
 780         ##
 781         return 1;
 782         } # i loop
 783
 784         return;
 785 }
 786
 787 sub _find_bucket_list {
 788         ##
 789         # Locate offset for bucket list, given digested key
 790         ##
 791         my $self = shift;
 792         my $md5 = shift;
 793
 794         ##
 795         # Locate offset for bucket list using digest index system
 796         ##
 797         my $ch = 0;
 798         my $tag = $self->_load_tag($self->_base_offset);
 799         if (!$tag) { return; }
 800
 801         while ($tag->{signature} ne SIG_BLIST) {
 802                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 803                 if (!$tag) { return; }
 804                 $ch++;
 805         }
 806
 807         return $tag;
 808 }
 809
 810 sub _traverse_index {
 811         ##
 812         # Scan index and recursively step into deeper levels, looking for next key.
 813         ##
 814     my ($self, $offset, $ch, $force_return_next) = @_;
 815     $force_return_next = undef unless $force_return_next;
 816
 817         my $tag = $self->_load_tag( $offset );
 818
 819     my $fh = $self->_fh;
 820
 821         if ($tag->{signature} ne SIG_BLIST) {
 822                 my $content = $tag->{content};
 823                 my $start;
 824                 if ($self->{return_next}) { $start = 0; }
 825                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 826
 827                 for (my $index = $start; $index < 256; $index++) {
 828                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 829                         if ($subloc) {
 830                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 831                                 if (defined($result)) { return $result; }
 832                         }
 833                 } # index loop
 834
 835                 $self->{return_next} = 1;
 836         } # tag is an index
 837
 838         elsif ($tag->{signature} eq SIG_BLIST) {
 839                 my $keys = $tag->{content};
 840                 if ($force_return_next) { $self->{return_next} = 1; }
 841
 842                 ##
 843                 # Iterate through buckets, looking for a key match
 844                 ##
 845                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 846                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 847                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 848
 849                         if (!$subloc) {
 850                                 ##
 851                                 # End of bucket list -- return to outer loop
 852                                 ##
 853                                 $self->{return_next} = 1;
 854                                 last;
 855                         }
 856                         elsif ($key eq $self->{prev_md5}) {
 857                                 ##
 858                                 # Located previous key -- return next one found
 859                                 ##
 860                                 $self->{return_next} = 1;
 861                                 next;
 862                         }
 863                         elsif ($self->{return_next}) {
 864                                 ##
 865                                 # Seek to bucket location and skip over signature
 866                                 ##
 867                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 868
 869                                 ##
 870                                 # Skip over value to get to plain key
 871                                 ##
 872                                 my $size;
 873                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 874                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 875
 876                                 ##
 877                                 # Read in plain key and return as scalar
 878                                 ##
 879                                 my $plain_key;
 880                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 881                                 if ($size) { read( $fh, $plain_key, $size); }
 882
 883                                 return $plain_key;
 884                         }
 885                 } # bucket loop
 886
 887                 $self->{return_next} = 1;
 888         } # tag is a bucket list
 889
 890         return;
 891 }
 892
 893 sub _get_next_key {
 894         ##
 895         # Locate next key, given digested previous one
 896         ##
 897     my $self = $_[0]->_get_self;
 898
 899         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 900         $self->{return_next} = 0;
 901
 902         ##
 903         # If the previous key was not specifed, start at the top and
 904         # return the first one found.
 905         ##
 906         if (!$self->{prev_md5}) {
 907                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 908                 $self->{return_next} = 1;
 909         }
 910
 911         return $self->_traverse_index( $self->_base_offset, 0 );
 912 }
 913
 914 sub lock {
 915         ##
 916         # If db locking is set, flock() the db file.  If called multiple
 917         # times before unlock(), then the same number of unlocks() must
 918         # be called before the lock is released.
 919         ##
 920     my $self = $_[0]->_get_self;
 921         my $type = $_[1];
 922     $type = LOCK_EX unless defined $type;
 923
 924         if (!defined($self->_fh)) { return; }
 925
 926         if ($self->_root->{locking}) {
 927                 if (!$self->_root->{locked}) {
 928                         flock($self->_fh, $type);
 929
 930                         # refresh end counter in case file has changed size
 931                         my @stats = stat($self->_root->{file});
 932                         $self->_root->{end} = $stats[7];
 933
 934                         # double-check file inode, in case another process
 935                         # has optimize()d our file while we were waiting.
 936                         if ($stats[1] != $self->_root->{inode}) {
 937                                 $self->_open(); # re-open
 938                                 flock($self->_fh, $type); # re-lock
 939                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 940                         }
 941                 }
 942                 $self->_root->{locked}++;
 943
 944         return 1;
 945         }
 946
 947     return;
 948 }
 949
 950 sub unlock {
 951         ##
 952         # If db locking is set, unlock the db file.  See note in lock()
 953         # regarding calling lock() multiple times.
 954         ##
 955     my $self = $_[0]->_get_self;
 956
 957         if (!defined($self->_fh)) { return; }
 958
 959         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 960                 $self->_root->{locked}--;
 961                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 962
 963         return 1;
 964         }
 965
 966     return;
 967 }
 968
 969 sub _copy_value {
 970     my $self = shift->_get_self;
 971     my ($spot, $value) = @_;
 972
 973     if ( !ref $value ) {
 974         ${$spot} = $value;
 975     }
 976     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 977         my $type = $value->_type;
 978         ${$spot} = $type eq TYPE_HASH ? {} : [];
 979         $value->_copy_node( ${$spot} );
 980     }
 981     else {
 982         my $r = Scalar::Util::reftype( $value );
 983         my $c = Scalar::Util::blessed( $value );
 984         if ( $r eq 'ARRAY' ) {
 985             ${$spot} = [ @{$value} ];
 986         }
 987         else {
 988             ${$spot} = { %{$value} };
 989         }
 990         ${$spot} = bless ${$spot}, $c
 991             if defined $c;
 992     }
 993
 994     return 1;
 995 }
 996
 997 sub _copy_node {
 998         ##
 999         # Copy single level of keys or elements to new DB handle.
1000         # Recurse for nested structures
1001         ##
1002     my $self = shift->_get_self;
1003         my ($db_temp) = @_;
1004
1005         if ($self->_type eq TYPE_HASH) {
1006                 my $key = $self->first_key();
1007                 while ($key) {
1008                         my $value = $self->get($key);
1009             $self->_copy_value( \$db_temp->{$key}, $value );
1010                         $key = $self->next_key($key);
1011                 }
1012         }
1013         else {
1014                 my $length = $self->length();
1015                 for (my $index = 0; $index < $length; $index++) {
1016                         my $value = $self->get($index);
1017             $self->_copy_value( \$db_temp->[$index], $value );
1018                 }
1019         }
1020
1021     return 1;
1022 }
1023
1024 sub export {
1025         ##
1026         # Recursively export into standard Perl hashes and arrays.
1027         ##
1028     my $self = $_[0]->_get_self;
1029
1030         my $temp;
1031         if ($self->_type eq TYPE_HASH) { $temp = {}; }
1032         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
1033
1034         $self->lock();
1035         $self->_copy_node( $temp );
1036         $self->unlock();
1037
1038         return $temp;
1039 }
1040
1041 sub import {
1042         ##
1043         # Recursively import Perl hash/array structure
1044         ##
1045     #XXX This use of ref() seems to be ok
1046         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1047
1048     my $self = $_[0]->_get_self;
1049         my $struct = $_[1];
1050
1051     #XXX This use of ref() seems to be ok
1052         if (!ref($struct)) {
1053                 ##
1054                 # struct is not a reference, so just import based on our type
1055                 ##
1056                 shift @_;
1057
1058                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
1059                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
1060         }
1061
1062     my $r = Scalar::Util::reftype($struct) || '';
1063         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
1064                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1065         }
1066         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
1067                 $self->push( @$struct );
1068         }
1069         else {
1070                 return $self->_throw_error("Cannot import: type mismatch");
1071         }
1072
1073         return 1;
1074 }
1075
1076 sub optimize {
1077         ##
1078         # Rebuild entire database into new file, then move
1079         # it back on top of original.
1080         ##
1081     my $self = $_[0]->_get_self;
1082
1083 #XXX Need to create a new test for this
1084 #       if ($self->_root->{links} > 1) {
1085 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1086 #       }
1087
1088         my $db_temp = DBM::Deep->new(
1089                 file => $self->_root->{file} . '.tmp',
1090                 type => $self->_type
1091         );
1092         if (!$db_temp) {
1093                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1094         }
1095
1096         $self->lock();
1097         $self->_copy_node( $db_temp );
1098         undef $db_temp;
1099
1100         ##
1101         # Attempt to copy user, group and permissions over to new file
1102         ##
1103         my @stats = stat($self->_fh);
1104         my $perms = $stats[2] & 07777;
1105         my $uid = $stats[4];
1106         my $gid = $stats[5];
1107         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1108         chmod( $perms, $self->_root->{file} . '.tmp' );
1109
1110     # q.v. perlport for more information on this variable
1111     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1112                 ##
1113                 # Potential race condition when optmizing on Win32 with locking.
1114                 # The Windows filesystem requires that the filehandle be closed
1115                 # before it is overwritten with rename().  This could be redone
1116                 # with a soft copy.
1117                 ##
1118                 $self->unlock();
1119                 $self->_close();
1120         }
1121
1122         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1123                 unlink $self->_root->{file} . '.tmp';
1124                 $self->unlock();
1125                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1126         }
1127
1128         $self->unlock();
1129         $self->_close();
1130         $self->_open();
1131
1132         return 1;
1133 }
1134
1135 sub clone {
1136         ##
1137         # Make copy of object and return
1138         ##
1139     my $self = $_[0]->_get_self;
1140
1141         return DBM::Deep->new(
1142                 type => $self->_type,
1143                 base_offset => $self->_base_offset,
1144                 root => $self->_root
1145         );
1146 }
1147
1148 {
1149     my %is_legal_filter = map {
1150         $_ => ~~1,
1151     } qw(
1152         store_key store_value
1153         fetch_key fetch_value
1154     );
1155
1156     sub set_filter {
1157         ##
1158         # Setup filter function for storing or fetching the key or value
1159         ##
1160         my $self = $_[0]->_get_self;
1161         my $type = lc $_[1];
1162         my $func = $_[2] ? $_[2] : undef;
1163
1164         if ( $is_legal_filter{$type} ) {
1165             $self->_root->{"filter_$type"} = $func;
1166             return 1;
1167         }
1168
1169         return;
1170     }
1171 }
1172
1173 ##
1174 # Accessor methods
1175 ##
1176
1177 sub _root {
1178         ##
1179         # Get access to the root structure
1180         ##
1181     my $self = $_[0]->_get_self;
1182         return $self->{root};
1183 }
1184
1185 sub _fh {
1186         ##
1187         # Get access to the raw fh
1188         ##
1189     #XXX It will be useful, though, when we split out HASH and ARRAY
1190     my $self = $_[0]->_get_self;
1191         return $self->_root->{fh};
1192 }
1193
1194 sub _type {
1195         ##
1196         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1197         ##
1198     my $self = $_[0]->_get_self;
1199         return $self->{type};
1200 }
1201
1202 sub _base_offset {
1203         ##
1204         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1205         ##
1206     my $self = $_[0]->_get_self;
1207         return $self->{base_offset};
1208 }
1209
1210 sub error {
1211         ##
1212         # Get last error string, or undef if no error
1213         ##
1214         return $_[0]
1215         ? ( $_[0]->_get_self->{root}->{error} or undef )
1216         : $@;
1217 }
1218
1219 ##
1220 # Utility methods
1221 ##
1222
1223 sub _throw_error {
1224         ##
1225         # Store error string in self
1226         ##
1227         my $error_text = $_[1];
1228
1229     if ( Scalar::Util::blessed $_[0] ) {
1230         my $self = $_[0]->_get_self;
1231         $self->_root->{error} = $error_text;
1232
1233         unless ($self->_root->{debug}) {
1234             die "DBM::Deep: $error_text\n";
1235         }
1236
1237         warn "DBM::Deep: $error_text\n";
1238         return;
1239     }
1240     else {
1241         die "DBM::Deep: $error_text\n";
1242     }
1243 }
1244
1245 sub clear_error {
1246         ##
1247         # Clear error state
1248         ##
1249     my $self = $_[0]->_get_self;
1250
1251         undef $self->_root->{error};
1252 }
1253
1254 sub _precalc_sizes {
1255         ##
1256         # Precalculate index, bucket and bucket list sizes
1257         ##
1258
1259     #XXX I don't like this ...
1260     set_pack() unless defined $LONG_SIZE;
1261
1262         $INDEX_SIZE = 256 * $LONG_SIZE;
1263         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1264         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1265 }
1266
1267 sub set_pack {
1268         ##
1269         # Set pack/unpack modes (see file header for more)
1270         ##
1271     my ($long_s, $long_p, $data_s, $data_p) = @_;
1272
1273     $LONG_SIZE = $long_s ? $long_s : 4;
1274     $LONG_PACK = $long_p ? $long_p : 'N';
1275
1276     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1277     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1278
1279         _precalc_sizes();
1280 }
1281
1282 sub set_digest {
1283         ##
1284         # Set key digest function (default is MD5)
1285         ##
1286     my ($digest_func, $hash_size) = @_;
1287
1288     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1289     $HASH_SIZE = $hash_size ? $hash_size : 16;
1290
1291         _precalc_sizes();
1292 }
1293
1294 sub _is_writable {
1295     my $fh = shift;
1296     (O_WRONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1297 }
1298
1299 #sub _is_readable {
1300 #    my $fh = shift;
1301 #    (O_RDONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1302 #}
1303
1304 ##
1305 # tie() methods (hashes and arrays)
1306 ##
1307
1308 sub STORE {
1309         ##
1310         # Store single hash key/value or array element in database.
1311         ##
1312     my $self = $_[0]->_get_self;
1313         my $key = $_[1];
1314
1315     # User may be storing a hash, in which case we do not want it run
1316     # through the filtering system
1317         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1318         ? $self->_root->{filter_store_value}->($_[2])
1319         : $_[2];
1320
1321         my $md5 = $DIGEST_FUNC->($key);
1322
1323         ##
1324         # Make sure file is open
1325         ##
1326         if (!defined($self->_fh) && !$self->_open()) {
1327                 return;
1328         }
1329
1330     unless ( _is_writable( $self->_fh ) ) {
1331         $self->_throw_error( 'Cannot write to a readonly filehandle' );
1332     }
1333
1334         ##
1335         # Request exclusive lock for writing
1336         ##
1337         $self->lock( LOCK_EX );
1338
1339         my $fh = $self->_fh;
1340
1341         ##
1342         # Locate offset for bucket list using digest index system
1343         ##
1344         my $tag = $self->_load_tag($self->_base_offset);
1345         if (!$tag) {
1346                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1347         }
1348
1349         my $ch = 0;
1350         while ($tag->{signature} ne SIG_BLIST) {
1351                 my $num = ord(substr($md5, $ch, 1));
1352
1353         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1354                 my $new_tag = $self->_index_lookup($tag, $num);
1355
1356                 if (!$new_tag) {
1357                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1358                         print( $fh pack($LONG_PACK, $self->_root->{end}) );
1359
1360                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1361
1362                         $tag->{ref_loc} = $ref_loc;
1363                         $tag->{ch} = $ch;
1364
1365                         last;
1366                 }
1367                 else {
1368                         $tag = $new_tag;
1369
1370                         $tag->{ref_loc} = $ref_loc;
1371                         $tag->{ch} = $ch;
1372                 }
1373                 $ch++;
1374         }
1375
1376         ##
1377         # Add key/value to bucket list
1378         ##
1379         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1380
1381         $self->unlock();
1382
1383         return $result;
1384 }
1385
1386 sub FETCH {
1387         ##
1388         # Fetch single value or element given plain key or array index
1389         ##
1390     my $self = shift->_get_self;
1391     my $key = shift;
1392
1393         ##
1394         # Make sure file is open
1395         ##
1396         if (!defined($self->_fh)) { $self->_open(); }
1397
1398         my $md5 = $DIGEST_FUNC->($key);
1399
1400         ##
1401         # Request shared lock for reading
1402         ##
1403         $self->lock( LOCK_SH );
1404
1405         my $tag = $self->_find_bucket_list( $md5 );
1406         if (!$tag) {
1407                 $self->unlock();
1408                 return;
1409         }
1410
1411         ##
1412         # Get value from bucket list
1413         ##
1414         my $result = $self->_get_bucket_value( $tag, $md5 );
1415
1416         $self->unlock();
1417
1418     #XXX What is ref() checking here?
1419     #YYY Filters only apply on scalar values, so the ref check is making
1420     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1421         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1422         ? $self->_root->{filter_fetch_value}->($result)
1423         : $result;
1424 }
1425
1426 sub DELETE {
1427         ##
1428         # Delete single key/value pair or element given plain key or array index
1429         ##
1430     my $self = $_[0]->_get_self;
1431         my $key = $_[1];
1432
1433         my $md5 = $DIGEST_FUNC->($key);
1434
1435         ##
1436         # Make sure file is open
1437         ##
1438         if (!defined($self->_fh)) { $self->_open(); }
1439
1440         ##
1441         # Request exclusive lock for writing
1442         ##
1443         $self->lock( LOCK_EX );
1444
1445         my $tag = $self->_find_bucket_list( $md5 );
1446         if (!$tag) {
1447                 $self->unlock();
1448                 return;
1449         }
1450
1451         ##
1452         # Delete bucket
1453         ##
1454     my $value = $self->_get_bucket_value( $tag, $md5 );
1455         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1456         $value = $self->_root->{filter_fetch_value}->($value);
1457     }
1458
1459         my $result = $self->_delete_bucket( $tag, $md5 );
1460
1461         ##
1462         # If this object is an array and the key deleted was on the end of the stack,
1463         # decrement the length variable.
1464         ##
1465
1466         $self->unlock();
1467
1468         return $value;
1469 }
1470
1471 sub EXISTS {
1472         ##
1473         # Check if a single key or element exists given plain key or array index
1474         ##
1475     my $self = $_[0]->_get_self;
1476         my $key = $_[1];
1477
1478         my $md5 = $DIGEST_FUNC->($key);
1479
1480         ##
1481         # Make sure file is open
1482         ##
1483         if (!defined($self->_fh)) { $self->_open(); }
1484
1485         ##
1486         # Request shared lock for reading
1487         ##
1488         $self->lock( LOCK_SH );
1489
1490         my $tag = $self->_find_bucket_list( $md5 );
1491
1492         ##
1493         # For some reason, the built-in exists() function returns '' for false
1494         ##
1495         if (!$tag) {
1496                 $self->unlock();
1497                 return '';
1498         }
1499
1500         ##
1501         # Check if bucket exists and return 1 or ''
1502         ##
1503         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1504
1505         $self->unlock();
1506
1507         return $result;
1508 }
1509
1510 sub CLEAR {
1511         ##
1512         # Clear all keys from hash, or all elements from array.
1513         ##
1514     my $self = $_[0]->_get_self;
1515
1516         ##
1517         # Make sure file is open
1518         ##
1519         if (!defined($self->_fh)) { $self->_open(); }
1520
1521         ##
1522         # Request exclusive lock for writing
1523         ##
1524         $self->lock( LOCK_EX );
1525
1526     my $fh = $self->_fh;
1527
1528         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1529         if (eof $fh) {
1530                 $self->unlock();
1531                 return;
1532         }
1533
1534         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1535
1536         $self->unlock();
1537
1538         return 1;
1539 }
1540
1541 ##
1542 # Public method aliases
1543 ##
1544 sub put { (shift)->STORE( @_ ) }
1545 sub store { (shift)->STORE( @_ ) }
1546 sub get { (shift)->FETCH( @_ ) }
1547 sub fetch { (shift)->FETCH( @_ ) }
1548 sub delete { (shift)->DELETE( @_ ) }
1549 sub exists { (shift)->EXISTS( @_ ) }
1550 sub clear { (shift)->CLEAR( @_ ) }
1551
1552 package DBM::Deep::_::Root;
1553
1554 sub new {
1555     my $class = shift;
1556     my ($args) = @_;
1557
1558     my $self = bless {
1559         file => undef,
1560         fh => undef,
1561         file_offset => 0,
1562         end => 0,
1563         autoflush => undef,
1564         locking => undef,
1565         debug => undef,
1566         filter_store_key => undef,
1567         filter_store_value => undef,
1568         filter_fetch_key => undef,
1569         filter_fetch_value => undef,
1570         autobless => undef,
1571         locked => 0,
1572         %$args,
1573     }, $class;
1574
1575     if ( $self->{fh} && !$self->{file_offset} ) {
1576         $self->{file_offset} = tell( $self->{fh} );
1577     }
1578
1579     return $self;
1580 }
1581
1582 sub DESTROY {
1583     my $self = shift;
1584     return unless $self;
1585
1586     close $self->{fh} if $self->{fh};
1587
1588     return;
1589 }
1590
1591 1;
1592
1593 __END__
1594
1595 =head1 NAME
1596
1597 DBM::Deep - A pure perl multi-level hash/array DBM
1598
1599 =head1 SYNOPSIS
1600
1601   use DBM::Deep;
1602   my $db = DBM::Deep->new( "foo.db" );
1603
1604   $db->{key} = 'value'; # tie() style
1605   print $db->{key};
1606
1607   $db->put('key' => 'value'); # OO style
1608   print $db->get('key');
1609
1610   # true multi-level support
1611   $db->{my_complex} = [
1612         'hello', { perl => 'rules' },
1613         42, 99,
1614   ];
1615
1616 =head1 DESCRIPTION
1617
1618 A unique flat-file database module, written in pure perl.  True
1619 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1620 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1621 handle millions of keys and unlimited hash levels without significant
1622 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1623 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1624 Mac OS X and Windows.
1625
1626 =head1 INSTALLATION
1627
1628 Hopefully you are using Perl's excellent CPAN module, which will download
1629 and install the module for you.  If not, get the tarball, and run these
1630 commands:
1631
1632         tar zxf DBM-Deep-*
1633         cd DBM-Deep-*
1634         perl Makefile.PL
1635         make
1636         make test
1637         make install
1638
1639 =head1 SETUP
1640
1641 Construction can be done OO-style (which is the recommended way), or using
1642 Perl's tie() function.  Both are examined here.
1643
1644 =head2 OO CONSTRUCTION
1645
1646 The recommended way to construct a DBM::Deep object is to use the new()
1647 method, which gets you a blessed, tied hash or array reference.
1648
1649         my $db = DBM::Deep->new( "foo.db" );
1650
1651 This opens a new database handle, mapped to the file "foo.db".  If this
1652 file does not exist, it will automatically be created.  DB files are
1653 opened in "r+" (read/write) mode, and the type of object returned is a
1654 hash, unless otherwise specified (see L<OPTIONS> below).
1655
1656 You can pass a number of options to the constructor to specify things like
1657 locking, autoflush, etc.  This is done by passing an inline hash:
1658
1659         my $db = DBM::Deep->new(
1660                 file => "foo.db",
1661                 locking => 1,
1662                 autoflush => 1
1663         );
1664
1665 Notice that the filename is now specified I<inside> the hash with
1666 the "file" parameter, as opposed to being the sole argument to the
1667 constructor.  This is required if any options are specified.
1668 See L<OPTIONS> below for the complete list.
1669
1670
1671
1672 You can also start with an array instead of a hash.  For this, you must
1673 specify the C<type> parameter:
1674
1675         my $db = DBM::Deep->new(
1676                 file => "foo.db",
1677                 type => DBM::Deep->TYPE_ARRAY
1678         );
1679
1680 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1681 a new DB file.  If you create a DBM::Deep object with an existing file, the
1682 C<type> will be loaded from the file header, and an error will be thrown if
1683 the wrong type is passed in.
1684
1685 =head2 TIE CONSTRUCTION
1686
1687 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1688 tie() function.  The object returned from tie() can be used to call methods,
1689 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1690 file (as expected with most tie'd objects).
1691
1692         my %hash;
1693         my $db = tie %hash, "DBM::Deep", "foo.db";
1694
1695         my @array;
1696         my $db = tie @array, "DBM::Deep", "bar.db";
1697
1698 As with the OO constructor, you can replace the DB filename parameter with
1699 a hash containing one or more options (see L<OPTIONS> just below for the
1700 complete list).
1701
1702         tie %hash, "DBM::Deep", {
1703                 file => "foo.db",
1704                 locking => 1,
1705                 autoflush => 1
1706         };
1707
1708 =head2 OPTIONS
1709
1710 There are a number of options that can be passed in when constructing your
1711 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1712
1713 =over
1714
1715 =item * file
1716
1717 Filename of the DB file to link the handle to.  You can pass a full absolute
1718 filesystem path, partial path, or a plain filename if the file is in the
1719 current working directory.  This is a required parameter (though q.v. fh).
1720
1721 =item * fh
1722
1723 If you want, you can pass in the fh instead of the file. This is most useful for doing
1724 something like:
1725
1726   my $db = DBM::Deep->new( { fh => \*DATA } );
1727
1728 You are responsible for making sure that the fh has been opened appropriately for your
1729 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1730 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1731 needs to read from the fh.
1732
1733 =item * file_offset
1734
1735 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1736 not need to set this. However, it's there if you want it.
1737
1738 If you pass in fh and do not set this, it will be set appropriately.
1739
1740 =item * type
1741
1742 This parameter specifies what type of object to create, a hash or array.  Use
1743 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1744 This only takes effect when beginning a new file.  This is an optional
1745 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1746
1747 =item * locking
1748
1749 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1750 function to lock the database in exclusive mode for writes, and shared mode for
1751 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1752 any child hashes or arrays> that use the same DB file.  This is an optional
1753 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1754
1755 =item * autoflush
1756
1757 Specifies whether autoflush is to be enabled on the underlying filehandle.
1758 This obviously slows down write operations, but is required if you may have
1759 multiple processes accessing the same DB file (also consider enable I<locking>).
1760 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1761 (disabled).
1762
1763 =item * autobless
1764
1765 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1766 restore them when fetched.  This is an B<experimental> feature, and does have
1767 side-effects.  Basically, when hashes are re-blessed into their original
1768 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1769 able to call any DBM::Deep methods on them.  You have been warned.
1770 This is an optional parameter, and defaults to 0 (disabled).
1771
1772 =item * filter_*
1773
1774 See L<FILTERS> below.
1775
1776 =item * debug
1777
1778 Setting I<debug> mode will make all errors non-fatal, dump them out to
1779 STDERR, and continue on.  This is for debugging purposes only, and probably
1780 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1781
1782 B<NOTE>: This parameter is considered deprecated and should not be used anymore.
1783
1784 =back
1785
1786 =head1 TIE INTERFACE
1787
1788 With DBM::Deep you can access your databases using Perl's standard hash/array
1789 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1790 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1791 to the right place -- the DB file.  This has nothing to do with the
1792 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1793 using regular hashes and arrays, rather than calling functions like C<get()>
1794 and C<put()> (although those work too).  It is entirely up to you how to want
1795 to access your databases.
1796
1797 =head2 HASHES
1798
1799 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1800 or even nested hashes (or arrays) using standard Perl syntax:
1801
1802         my $db = DBM::Deep->new( "foo.db" );
1803
1804         $db->{mykey} = "myvalue";
1805         $db->{myhash} = {};
1806         $db->{myhash}->{subkey} = "subvalue";
1807
1808         print $db->{myhash}->{subkey} . "\n";
1809
1810 You can even step through hash keys using the normal Perl C<keys()> function:
1811
1812         foreach my $key (keys %$db) {
1813                 print "$key: " . $db->{$key} . "\n";
1814         }
1815
1816 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1817 pushes them onto an array, all before the loop even begins.  If you have an
1818 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1819 Perl's C<each()> function, which pulls keys/values one at a time, using very
1820 little memory:
1821
1822         while (my ($key, $value) = each %$db) {
1823                 print "$key: $value\n";
1824         }
1825
1826 Please note that when using C<each()>, you should always pass a direct
1827 hash reference, not a lookup.  Meaning, you should B<never> do this:
1828
1829         # NEVER DO THIS
1830         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1831
1832 This causes an infinite loop, because for each iteration, Perl is calling
1833 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1834 it effectively keeps returning the first key over and over again. Instead,
1835 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1836
1837 =head2 ARRAYS
1838
1839 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1840 reference.  This includes inserting, removing and manipulating elements,
1841 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1842 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1843 or simply be a nested array reference inside a hash.  Example:
1844
1845         my $db = DBM::Deep->new(
1846                 file => "foo-array.db",
1847                 type => DBM::Deep->TYPE_ARRAY
1848         );
1849
1850         $db->[0] = "foo";
1851         push @$db, "bar", "baz";
1852         unshift @$db, "bah";
1853
1854         my $last_elem = pop @$db; # baz
1855         my $first_elem = shift @$db; # bah
1856         my $second_elem = $db->[1]; # bar
1857
1858         my $num_elements = scalar @$db;
1859
1860 =head1 OO INTERFACE
1861
1862 In addition to the I<tie()> interface, you can also use a standard OO interface
1863 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1864 array) has its own methods, but both types share the following common methods:
1865 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1866
1867 =over
1868
1869 =item * new() / clone()
1870
1871 These are the constructor and copy-functions.
1872
1873 =item * put() / store()
1874
1875 Stores a new hash key/value pair, or sets an array element value.  Takes two
1876 arguments, the hash key or array index, and the new value.  The value can be
1877 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1878
1879         $db->put("foo", "bar"); # for hashes
1880         $db->put(1, "bar"); # for arrays
1881
1882 =item * get() / fetch()
1883
1884 Fetches the value of a hash key or array element.  Takes one argument: the hash
1885 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1886 data type stored.
1887
1888         my $value = $db->get("foo"); # for hashes
1889         my $value = $db->get(1); # for arrays
1890
1891 =item * exists()
1892
1893 Checks if a hash key or array index exists.  Takes one argument: the hash key
1894 or array index.  Returns true if it exists, false if not.
1895
1896         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1897         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1898
1899 =item * delete()
1900
1901 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1902 key or array index.  Returns true on success, false if not found.  For arrays,
1903 the remaining elements located after the deleted element are NOT moved over.
1904 The deleted element is essentially just undefined, which is exactly how Perl's
1905 internal arrays work.  Please note that the space occupied by the deleted
1906 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1907 below for details and workarounds.
1908
1909         $db->delete("foo"); # for hashes
1910         $db->delete(1); # for arrays
1911
1912 =item * clear()
1913
1914 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1915 value.  Please note that the space occupied by the deleted keys/values or
1916 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1917 details and workarounds.
1918
1919         $db->clear(); # hashes or arrays
1920
1921 =item * lock() / unlock()
1922
1923 q.v. Locking.
1924
1925 =item * optimize()
1926
1927 Recover lost disk space.
1928
1929 =item * import() / export()
1930
1931 Data going in and out.
1932
1933 =item * set_digest() / set_pack() / set_filter()
1934
1935 q.v. adjusting the interal parameters.
1936
1937 =item * error() / clear_error()
1938
1939 Error handling methods. These are deprecated and will be removed in 1.00.
1940 .
1941 =back
1942
1943 =head2 HASHES
1944
1945 For hashes, DBM::Deep supports all the common methods described above, and the
1946 following additional methods: C<first_key()> and C<next_key()>.
1947
1948 =over
1949
1950 =item * first_key()
1951
1952 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1953 fetched in an undefined order (which appears random).  Takes no arguments,
1954 returns the key as a scalar value.
1955
1956         my $key = $db->first_key();
1957
1958 =item * next_key()
1959
1960 Returns the "next" key in the hash, given the previous one as the sole argument.
1961 Returns undef if there are no more keys to be fetched.
1962
1963         $key = $db->next_key($key);
1964
1965 =back
1966
1967 Here are some examples of using hashes:
1968
1969         my $db = DBM::Deep->new( "foo.db" );
1970
1971         $db->put("foo", "bar");
1972         print "foo: " . $db->get("foo") . "\n";
1973
1974         $db->put("baz", {}); # new child hash ref
1975         $db->get("baz")->put("buz", "biz");
1976         print "buz: " . $db->get("baz")->get("buz") . "\n";
1977
1978         my $key = $db->first_key();
1979         while ($key) {
1980                 print "$key: " . $db->get($key) . "\n";
1981                 $key = $db->next_key($key);
1982         }
1983
1984         if ($db->exists("foo")) { $db->delete("foo"); }
1985
1986 =head2 ARRAYS
1987
1988 For arrays, DBM::Deep supports all the common methods described above, and the
1989 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1990 C<unshift()> and C<splice()>.
1991
1992 =over
1993
1994 =item * length()
1995
1996 Returns the number of elements in the array.  Takes no arguments.
1997
1998         my $len = $db->length();
1999
2000 =item * push()
2001
2002 Adds one or more elements onto the end of the array.  Accepts scalars, hash
2003 refs or array refs.  No return value.
2004
2005         $db->push("foo", "bar", {});
2006
2007 =item * pop()
2008
2009 Fetches the last element in the array, and deletes it.  Takes no arguments.
2010 Returns undef if array is empty.  Returns the element value.
2011
2012         my $elem = $db->pop();
2013
2014 =item * shift()
2015
2016 Fetches the first element in the array, deletes it, then shifts all the
2017 remaining elements over to take up the space.  Returns the element value.  This
2018 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2019 details.
2020
2021         my $elem = $db->shift();
2022
2023 =item * unshift()
2024
2025 Inserts one or more elements onto the beginning of the array, shifting all
2026 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2027 No return value.  This method is not recommended with large arrays -- see
2028 <LARGE ARRAYS> below for details.
2029
2030         $db->unshift("foo", "bar", {});
2031
2032 =item * splice()
2033
2034 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2035 -f splice> for usage -- it is too complicated to document here.  This method is
2036 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2037
2038 =back
2039
2040 Here are some examples of using arrays:
2041
2042         my $db = DBM::Deep->new(
2043                 file => "foo.db",
2044                 type => DBM::Deep->TYPE_ARRAY
2045         );
2046
2047         $db->push("bar", "baz");
2048         $db->unshift("foo");
2049         $db->put(3, "buz");
2050
2051         my $len = $db->length();
2052         print "length: $len\n"; # 4
2053
2054         for (my $k=0; $k<$len; $k++) {
2055                 print "$k: " . $db->get($k) . "\n";
2056         }
2057
2058         $db->splice(1, 2, "biz", "baf");
2059
2060         while (my $elem = shift @$db) {
2061                 print "shifted: $elem\n";
2062         }
2063
2064 =head1 LOCKING
2065
2066 Enable automatic file locking by passing a true value to the C<locking>
2067 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2068
2069         my $db = DBM::Deep->new(
2070                 file => "foo.db",
2071                 locking => 1
2072         );
2073
2074 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2075 mode for writes, and shared mode for reads.  This is required if you have
2076 multiple processes accessing the same database file, to avoid file corruption.
2077 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2078 NFS> below for more.
2079
2080 =head2 EXPLICIT LOCKING
2081
2082 You can explicitly lock a database, so it remains locked for multiple
2083 transactions.  This is done by calling the C<lock()> method, and passing an
2084 optional lock mode argument (defaults to exclusive mode).  This is particularly
2085 useful for things like counters, where the current value needs to be fetched,
2086 then incremented, then stored again.
2087
2088         $db->lock();
2089         my $counter = $db->get("counter");
2090         $counter++;
2091         $db->put("counter", $counter);
2092         $db->unlock();
2093
2094         # or...
2095
2096         $db->lock();
2097         $db->{counter}++;
2098         $db->unlock();
2099
2100 You can pass C<lock()> an optional argument, which specifies which mode to use
2101 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2102 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2103 same as the constants defined in Perl's C<Fcntl> module.
2104
2105         $db->lock( DBM::Deep->LOCK_SH );
2106         # something here
2107         $db->unlock();
2108
2109 =head1 IMPORTING/EXPORTING
2110
2111 You can import existing complex structures by calling the C<import()> method,
2112 and export an entire database into an in-memory structure using the C<export()>
2113 method.  Both are examined here.
2114
2115 =head2 IMPORTING
2116
2117 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2118 walking the structure and adding keys/elements to the database as you go,
2119 simply pass a reference to the C<import()> method.  This recursively adds
2120 everything to an existing DBM::Deep object for you.  Here is an example:
2121
2122         my $struct = {
2123                 key1 => "value1",
2124                 key2 => "value2",
2125                 array1 => [ "elem0", "elem1", "elem2" ],
2126                 hash1 => {
2127                         subkey1 => "subvalue1",
2128                         subkey2 => "subvalue2"
2129                 }
2130         };
2131
2132         my $db = DBM::Deep->new( "foo.db" );
2133         $db->import( $struct );
2134
2135         print $db->{key1} . "\n"; # prints "value1"
2136
2137 This recursively imports the entire C<$struct> object into C<$db>, including
2138 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2139 keys are merged with the existing ones, replacing if they already exist.
2140 The C<import()> method can be called on any database level (not just the base
2141 level), and works with both hash and array DB types.
2142
2143 B<Note:> Make sure your existing structure has no circular references in it.
2144 These will cause an infinite loop when importing.
2145
2146 =head2 EXPORTING
2147
2148 Calling the C<export()> method on an existing DBM::Deep object will return
2149 a reference to a new in-memory copy of the database.  The export is done
2150 recursively, so all nested hashes/arrays are all exported to standard Perl
2151 objects.  Here is an example:
2152
2153         my $db = DBM::Deep->new( "foo.db" );
2154
2155         $db->{key1} = "value1";
2156         $db->{key2} = "value2";
2157         $db->{hash1} = {};
2158         $db->{hash1}->{subkey1} = "subvalue1";
2159         $db->{hash1}->{subkey2} = "subvalue2";
2160
2161         my $struct = $db->export();
2162
2163         print $struct->{key1} . "\n"; # prints "value1"
2164
2165 This makes a complete copy of the database in memory, and returns a reference
2166 to it.  The C<export()> method can be called on any database level (not just
2167 the base level), and works with both hash and array DB types.  Be careful of
2168 large databases -- you can store a lot more data in a DBM::Deep object than an
2169 in-memory Perl structure.
2170
2171 B<Note:> Make sure your database has no circular references in it.
2172 These will cause an infinite loop when exporting.
2173
2174 =head1 FILTERS
2175
2176 DBM::Deep has a number of hooks where you can specify your own Perl function
2177 to perform filtering on incoming or outgoing data.  This is a perfect
2178 way to extend the engine, and implement things like real-time compression or
2179 encryption.  Filtering applies to the base DB level, and all child hashes /
2180 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2181 constructed, or by calling the C<set_filter()> method at any time.  There are
2182 four available filter hooks, described below:
2183
2184 =over
2185
2186 =item * filter_store_key
2187
2188 This filter is called whenever a hash key is stored.  It
2189 is passed the incoming key, and expected to return a transformed key.
2190
2191 =item * filter_store_value
2192
2193 This filter is called whenever a hash key or array element is stored.  It
2194 is passed the incoming value, and expected to return a transformed value.
2195
2196 =item * filter_fetch_key
2197
2198 This filter is called whenever a hash key is fetched (i.e. via
2199 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2200 and expected to return the plain key.
2201
2202 =item * filter_fetch_value
2203
2204 This filter is called whenever a hash key or array element is fetched.
2205 It is passed the transformed value, and expected to return the plain value.
2206
2207 =back
2208
2209 Here are the two ways to setup a filter hook:
2210
2211         my $db = DBM::Deep->new(
2212                 file => "foo.db",
2213                 filter_store_value => \&my_filter_store,
2214                 filter_fetch_value => \&my_filter_fetch
2215         );
2216
2217         # or...
2218
2219         $db->set_filter( "filter_store_value", \&my_filter_store );
2220         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2221
2222 Your filter function will be called only when dealing with SCALAR keys or
2223 values.  When nested hashes and arrays are being stored/fetched, filtering
2224 is bypassed.  Filters are called as static functions, passed a single SCALAR
2225 argument, and expected to return a single SCALAR value.  If you want to
2226 remove a filter, set the function reference to C<undef>:
2227
2228         $db->set_filter( "filter_store_value", undef );
2229
2230 =head2 REAL-TIME ENCRYPTION EXAMPLE
2231
2232 Here is a working example that uses the I<Crypt::Blowfish> module to
2233 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2234 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2235 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2236
2237         use DBM::Deep;
2238         use Crypt::Blowfish;
2239         use Crypt::CBC;
2240
2241         my $cipher = Crypt::CBC->new({
2242                 'key'             => 'my secret key',
2243                 'cipher'          => 'Blowfish',
2244                 'iv'              => '$KJh#(}q',
2245                 'regenerate_key'  => 0,
2246                 'padding'         => 'space',
2247                 'prepend_iv'      => 0
2248         });
2249
2250         my $db = DBM::Deep->new(
2251                 file => "foo-encrypt.db",
2252                 filter_store_key => \&my_encrypt,
2253                 filter_store_value => \&my_encrypt,
2254                 filter_fetch_key => \&my_decrypt,
2255                 filter_fetch_value => \&my_decrypt,
2256         );
2257
2258         $db->{key1} = "value1";
2259         $db->{key2} = "value2";
2260         print "key1: " . $db->{key1} . "\n";
2261         print "key2: " . $db->{key2} . "\n";
2262
2263         undef $db;
2264         exit;
2265
2266         sub my_encrypt {
2267                 return $cipher->encrypt( $_[0] );
2268         }
2269         sub my_decrypt {
2270                 return $cipher->decrypt( $_[0] );
2271         }
2272
2273 =head2 REAL-TIME COMPRESSION EXAMPLE
2274
2275 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2276 compression / decompression of keys & values with DBM::Deep Filters.
2277 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2278 more on I<Compress::Zlib>.
2279
2280         use DBM::Deep;
2281         use Compress::Zlib;
2282
2283         my $db = DBM::Deep->new(
2284                 file => "foo-compress.db",
2285                 filter_store_key => \&my_compress,
2286                 filter_store_value => \&my_compress,
2287                 filter_fetch_key => \&my_decompress,
2288                 filter_fetch_value => \&my_decompress,
2289         );
2290
2291         $db->{key1} = "value1";
2292         $db->{key2} = "value2";
2293         print "key1: " . $db->{key1} . "\n";
2294         print "key2: " . $db->{key2} . "\n";
2295
2296         undef $db;
2297         exit;
2298
2299         sub my_compress {
2300                 return Compress::Zlib::memGzip( $_[0] ) ;
2301         }
2302         sub my_decompress {
2303                 return Compress::Zlib::memGunzip( $_[0] ) ;
2304         }
2305
2306 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2307 actually numerical index numbers, and are not filtered.
2308
2309 =head1 ERROR HANDLING
2310
2311 Most DBM::Deep methods return a true value for success, and call die() on
2312 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2313 actual error message is stored in an internal scalar, which can be fetched by
2314 calling the C<error()> method.
2315
2316         my $db = DBM::Deep->new( "foo.db" ); # create hash
2317         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2318
2319     print $@;           # prints error message
2320         print $db->error(); # prints error message
2321
2322 You can then call C<clear_error()> to clear the current error state.
2323
2324         $db->clear_error();
2325
2326 If you set the C<debug> option to true when creating your DBM::Deep object,
2327 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2328 be used for debugging purposes and not production work. DBM::Deep expects errors
2329 to be thrown, not propagated back up the stack.
2330
2331 B<NOTE>: error() and clear_error() are considered deprecated and I<will> be removed
2332 in 1.00. Please don't use them. Instead, wrap all your functions with in eval-blocks.
2333
2334 =head1 LARGEFILE SUPPORT
2335
2336 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2337 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2338 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2339 by calling the static C<set_pack()> method before you do anything else.
2340
2341         DBM::Deep::set_pack(8, 'Q');
2342
2343 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2344 instead of 32-bit longs.  After setting these values your DB files have a
2345 theoretical maximum size of 16 XB (exabytes).
2346
2347 B<Note:> Changing these values will B<NOT> work for existing database files.
2348 Only change this for new files, and make sure it stays set consistently
2349 throughout the file's life.  If you do set these values, you can no longer
2350 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2351 back to 32-bit mode.
2352
2353 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2354 only a 32-bit Perl.  However, I have received user reports that this does
2355 indeed work!
2356
2357 =head1 LOW-LEVEL ACCESS
2358
2359 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2360 you can call the C<_fh()> method, which returns the handle:
2361
2362         my $fh = $db->_fh();
2363
2364 This method can be called on the root level of the datbase, or any child
2365 hashes or arrays.  All levels share a I<root> structure, which contains things
2366 like the filehandle, a reference counter, and all the options specified
2367 when you created the object.  You can get access to this root structure by
2368 calling the C<root()> method.
2369
2370         my $root = $db->_root();
2371
2372 This is useful for changing options after the object has already been created,
2373 such as enabling/disabling locking, or debug modes.  You can also
2374 store your own temporary user data in this structure (be wary of name
2375 collision), which is then accessible from any child hash or array.
2376
2377 =head1 CUSTOM DIGEST ALGORITHM
2378
2379 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2380 keys.  However you can override this, and use another algorithm (such as SHA-256)
2381 or even write your own.  But please note that DBM::Deep currently expects zero
2382 collisions, so your algorithm has to be I<perfect>, so to speak.
2383 Collision detection may be introduced in a later version.
2384
2385
2386
2387 You can specify a custom digest algorithm by calling the static C<set_digest()>
2388 function, passing a reference to a subroutine, and the length of the algorithm's
2389 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2390 objects.  Here is a working example that uses a 256-bit hash from the
2391 I<Digest::SHA256> module.  Please see
2392 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2393
2394         use DBM::Deep;
2395         use Digest::SHA256;
2396
2397         my $context = Digest::SHA256::new(256);
2398
2399         DBM::Deep::set_digest( \&my_digest, 32 );
2400
2401         my $db = DBM::Deep->new( "foo-sha.db" );
2402
2403         $db->{key1} = "value1";
2404         $db->{key2} = "value2";
2405         print "key1: " . $db->{key1} . "\n";
2406         print "key2: " . $db->{key2} . "\n";
2407
2408         undef $db;
2409         exit;
2410
2411         sub my_digest {
2412                 return substr( $context->hash($_[0]), 0, 32 );
2413         }
2414
2415 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2416 of bytes you specify in the C<set_digest()> function (in this case 32).
2417
2418 =head1 CIRCULAR REFERENCES
2419
2420 DBM::Deep has B<experimental> support for circular references.  Meaning you
2421 can have a nested hash key or array element that points to a parent object.
2422 This relationship is stored in the DB file, and is preserved between sessions.
2423 Here is an example:
2424
2425         my $db = DBM::Deep->new( "foo.db" );
2426
2427         $db->{foo} = "bar";
2428         $db->{circle} = $db; # ref to self
2429
2430         print $db->{foo} . "\n"; # prints "foo"
2431         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2432
2433 One catch is, passing the object to a function that recursively walks the
2434 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2435 C<export()> methods) will result in an infinite loop.  The other catch is,
2436 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2437 or C<next_key()> methods), you will get the I<target object's key>, not the
2438 ref's key.  This gets even more interesting with the above example, where
2439 the I<circle> key points to the base DB object, which technically doesn't
2440 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2441 special case.
2442
2443 =head1 CAVEATS / ISSUES / BUGS
2444
2445 This section describes all the known issues with DBM::Deep.  It you have found
2446 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2447
2448 =head2 UNUSED SPACE RECOVERY
2449
2450 One major caveat with DBM::Deep is that space occupied by existing keys and
2451 values is not recovered when they are deleted.  Meaning if you keep deleting
2452 and adding new keys, your file will continuously grow.  I am working on this,
2453 but in the meantime you can call the built-in C<optimize()> method from time to
2454 time (perhaps in a crontab or something) to recover all your unused space.
2455
2456         $db->optimize(); # returns true on success
2457
2458 This rebuilds the ENTIRE database into a new file, then moves it on top of
2459 the original.  The new file will have no unused space, thus it will take up as
2460 little disk space as possible.  Please note that this operation can take
2461 a long time for large files, and you need enough disk space to temporarily hold
2462 2 copies of your DB file.  The temporary file is created in the same directory
2463 as the original, named with a ".tmp" extension, and is deleted when the
2464 operation completes.  Oh, and if locking is enabled, the DB is automatically
2465 locked for the entire duration of the copy.
2466
2467 B<WARNING:> Only call optimize() on the top-level node of the database, and
2468 make sure there are no child references lying around.  DBM::Deep keeps a reference
2469 counter, and if it is greater than 1, optimize() will abort and return undef.
2470
2471 =head2 AUTOVIVIFICATION
2472
2473 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2474 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2475 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2476 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2477 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2478 this does not work:
2479
2480         $db->{foo}->{bar} = "hello";
2481
2482 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2483 being an empty hash.  Try this instead, which works fine:
2484
2485         $db->{foo} = { bar => "hello" };
2486
2487 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2488 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2489 Probably a bug in Perl.
2490
2491 =head2 FILE CORRUPTION
2492
2493 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2494 for a 32-bit signature when opened, but other corruption in files can cause
2495 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2496 stuck in an infinite loop depending on the level of corruption.  File write
2497 operations are not checked for failure (for speed), so if you happen to run
2498 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2499 be addressed in a later version of DBM::Deep.
2500
2501 =head2 DB OVER NFS
2502
2503 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2504 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2505 about setting up your NFS server with a locking daemon, then using lockf() to
2506 lock your files, but your mileage may vary there as well.  From what I
2507 understand, there is no real way to do it.  However, if you need access to the
2508 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2509 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2510
2511 =head2 COPYING OBJECTS
2512
2513 Beware of copying tied objects in Perl.  Very strange things can happen.
2514 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2515 returns a new, blessed, tied hash or array to the same level in the DB.
2516
2517         my $copy = $db->clone();
2518
2519 B<Note>: Since clone() here is cloning the object, not the database location, any
2520 modifications to either $db or $copy will be visible in both.
2521
2522 =head2 LARGE ARRAYS
2523
2524 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2525 These functions cause every element in the array to move, which can be murder
2526 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2527 a different location.  This will be addressed in the forthcoming version 1.00.
2528
2529 =head2 WRITEONLY FILES
2530
2531 If you pass in a filehandle to new(), you may have opened it in either a readonly or
2532 writeonly mode. STORE will verify that the filehandle is writable. However, there
2533 doesn't seem to be a good way to determine if a filehandle is readable. And, if the
2534 filehandle isn't readable, it's not clear what will happen. So, don't do that.
2535
2536 =head1 PERFORMANCE
2537
2538 This section discusses DBM::Deep's speed and memory usage.
2539
2540 =head2 SPEED
2541
2542 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2543 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2544 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2545 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2546 with huge databases.  Here is some test data:
2547
2548         Adding 1,000,000 keys to new DB file...
2549
2550         At 100 keys, avg. speed is 2,703 keys/sec
2551         At 200 keys, avg. speed is 2,642 keys/sec
2552         At 300 keys, avg. speed is 2,598 keys/sec
2553         At 400 keys, avg. speed is 2,578 keys/sec
2554         At 500 keys, avg. speed is 2,722 keys/sec
2555         At 600 keys, avg. speed is 2,628 keys/sec
2556         At 700 keys, avg. speed is 2,700 keys/sec
2557         At 800 keys, avg. speed is 2,607 keys/sec
2558         At 900 keys, avg. speed is 2,190 keys/sec
2559         At 1,000 keys, avg. speed is 2,570 keys/sec
2560         At 2,000 keys, avg. speed is 2,417 keys/sec
2561         At 3,000 keys, avg. speed is 1,982 keys/sec
2562         At 4,000 keys, avg. speed is 1,568 keys/sec
2563         At 5,000 keys, avg. speed is 1,533 keys/sec
2564         At 6,000 keys, avg. speed is 1,787 keys/sec
2565         At 7,000 keys, avg. speed is 1,977 keys/sec
2566         At 8,000 keys, avg. speed is 2,028 keys/sec
2567         At 9,000 keys, avg. speed is 2,077 keys/sec
2568         At 10,000 keys, avg. speed is 2,031 keys/sec
2569         At 20,000 keys, avg. speed is 1,970 keys/sec
2570         At 30,000 keys, avg. speed is 2,050 keys/sec
2571         At 40,000 keys, avg. speed is 2,073 keys/sec
2572         At 50,000 keys, avg. speed is 1,973 keys/sec
2573         At 60,000 keys, avg. speed is 1,914 keys/sec
2574         At 70,000 keys, avg. speed is 2,091 keys/sec
2575         At 80,000 keys, avg. speed is 2,103 keys/sec
2576         At 90,000 keys, avg. speed is 1,886 keys/sec
2577         At 100,000 keys, avg. speed is 1,970 keys/sec
2578         At 200,000 keys, avg. speed is 2,053 keys/sec
2579         At 300,000 keys, avg. speed is 1,697 keys/sec
2580         At 400,000 keys, avg. speed is 1,838 keys/sec
2581         At 500,000 keys, avg. speed is 1,941 keys/sec
2582         At 600,000 keys, avg. speed is 1,930 keys/sec
2583         At 700,000 keys, avg. speed is 1,735 keys/sec
2584         At 800,000 keys, avg. speed is 1,795 keys/sec
2585         At 900,000 keys, avg. speed is 1,221 keys/sec
2586         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2587
2588 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2589 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2590 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2591 Run time was 12 min 3 sec.
2592
2593 =head2 MEMORY USAGE
2594
2595 One of the great things about DBM::Deep is that it uses very little memory.
2596 Even with huge databases (1,000,000+ keys) you will not see much increased
2597 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2598 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2599 database handle:
2600
2601           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2602         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2603
2604 Basically the process is taking 2,716K of memory.  And here is the same
2605 process after storing and fetching 1,000,000 keys:
2606
2607           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2608         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2609
2610 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2611 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2612
2613 =head1 DB FILE FORMAT
2614
2615 In case you were interested in the underlying DB file format, it is documented
2616 here in this section.  You don't need to know this to use the module, it's just
2617 included for reference.
2618
2619 =head2 SIGNATURE
2620
2621 DBM::Deep files always start with a 32-bit signature to identify the file type.
2622 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2623 checked for when the file is opened and an error will be thrown if it's not found.
2624
2625 =head2 TAG
2626
2627 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2628 has a standard header containing the type of data, the length of data, and then
2629 the data itself.  The type is a single character (1 byte), the length is a
2630 32-bit unsigned long in network byte order, and the data is, well, the data.
2631 Here is how it unfolds:
2632
2633 =head2 MASTER INDEX
2634
2635 Immediately after the 32-bit file signature is the I<Master Index> record.
2636 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2637 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2638 depending on how the DBM::Deep object was constructed.
2639
2640 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2641 number).  The first 8-bit char of the MD5 signature is the offset into the
2642 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2643 index element is a file offset of the next tag for the key/element in question,
2644 which is usually a I<Bucket List> tag (see below).
2645
2646 The next tag I<could> be another index, depending on how many keys/elements
2647 exist.  See L<RE-INDEXING> below for details.
2648
2649 =head2 BUCKET LIST
2650
2651 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2652 file offsets to where the actual data is stored.  It starts with a standard
2653 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2654 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2655 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2656 When the list fills up, a I<Re-Index> operation is performed (See
2657 L<RE-INDEXING> below).
2658
2659 =head2 BUCKET
2660
2661 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2662 index/value pair (in array mode).  It starts with a standard tag header with
2663 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2664 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2665 header.  The size reported in the tag header is only for the value, but then,
2666 just after the value is another size (32-bit unsigned long) and then the plain
2667 key itself.  Since the value is likely to be fetched more often than the plain
2668 key, I figured it would be I<slightly> faster to store the value first.
2669
2670 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2671 record for the nested structure, where the process begins all over again.
2672
2673 =head2 RE-INDEXING
2674
2675 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2676 exhausted.  Then, when another key/element comes in, the list is converted to a
2677 new index record.  However, this index will look at the next char in the MD5
2678 hash, and arrange new Bucket List pointers accordingly.  This process is called
2679 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2680 17 (16 + new one) keys/elements are removed from the old Bucket List and
2681 inserted into the new index.  Several new Bucket Lists are created in the
2682 process, as a new MD5 char from the key is being examined (it is unlikely that
2683 the keys will all share the same next char of their MD5s).
2684
2685 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2686 when the Bucket Lists will turn into indexes, but the first round tends to
2687 happen right around 4,000 keys.  You will see a I<slight> decrease in
2688 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2689 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2690 right around 900,000 keys.  This process can continue nearly indefinitely --
2691 right up until the point the I<MD5> signatures start colliding with each other,
2692 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2693 getting struck by lightning while you are walking to cash in your tickets.
2694 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2695 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2696 this is 340 unodecillion, but don't quote me).
2697
2698 =head2 STORING
2699
2700 When a new key/element is stored, the key (or index number) is first run through
2701 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2702 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2703 for the first char of the signature (in this case I<b0>).  If it does not exist,
2704 a new I<Bucket List> is created for our key (and the next 15 future keys that
2705 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2706 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2707 this point, unless we are replacing an existing I<Bucket>), where the actual
2708 data will be stored.
2709
2710 =head2 FETCHING
2711
2712 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2713 (or index number), then walking along the indexes.  If there are enough
2714 keys/elements in this DB level, there might be nested indexes, each linked to
2715 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2716 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2717 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2718 plain key are stored.
2719
2720 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2721 methods.  In this process the indexes are walked systematically, and each key
2722 fetched in increasing MD5 order (which is why it appears random).   Once the
2723 I<Bucket> is found, the value is skipped and the plain key returned instead.
2724 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2725 alphabetically sorted.  This only happens on an index-level -- as soon as the
2726 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2727 so it's pretty much undefined how the keys will come out -- just like Perl's
2728 built-in hashes.
2729
2730 =head1 CODE COVERAGE
2731
2732 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2733 B<Devel::Cover> report on this module's test suite.
2734
2735   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2736   File                           stmt   bran   cond    sub    pod   time  total
2737   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2738   blib/lib/DBM/Deep.pm           95.2   83.8   70.0   98.2  100.0   58.0   91.0
2739   blib/lib/DBM/Deep/Array.pm    100.0   91.1  100.0  100.0    n/a   26.7   98.0
2740   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   15.3   92.4
2741   Total                          96.2   84.8   74.4   98.8  100.0  100.0   92.4
2742   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2743
2744 =head1 MORE INFORMATION
2745
2746 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2747 or send email to L<DBM-Deep@googlegroups.com>.
2748
2749 =head1 AUTHORS
2750
2751 Joseph Huckaby, L<jhuckaby@cpan.org>
2752
2753 Rob Kinyon, L<rkinyon@cpan.org>
2754
2755 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2756
2757 =head1 SEE ALSO
2758
2759 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2760 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2761
2762 =head1 LICENSE
2763
2764 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2765 This is free software, you may use it and distribute it under the
2766 same terms as Perl itself.
2767
2768 =cut