lib/DBIx/Data/Store/CRUD.pm

   1 package DBIx::Data::Store::CRUD;
   2
   3 use Moose;
   4 use Method::Signatures::Simple;
   5
   6 has raw_store => (is => 'ro', required => 1); # DBIx::Data::Store object
   7
   8 foreach my $type (qw(select insert update delete)) {
   9   has "${type}_sql" => (is => 'ro', predicate => "has_${type}_sql");
  10   has "${type}_argument_order" => (is => 'ro', default => sub { [] });
  11 }
  12
  13 has 'insert_command_constructor' => (is => 'ro');
  14
  15 has "select_column_order" => (is => 'ro');
  16
  17 method new_select_command ($args) {
  18   die "$self->has_select_sql" unless $self->has_select_sql;
  19   $self->raw_store->new_stream_command(
  20     $self->select_sql,
  21     $self->_unwrap_args_for(select => $args),
  22     $self->select_column_order
  23   );
  24 }
  25
  26 method _unwrap_args_for ($type, $args) {
  27   [ @{$args}{@{$self->${\"${type}_argument_order"}}} ]
  28 }
  29
  30 method _new_command ($builder, $type, $args) {
  31   my $has_meth = "has_${type}_sql";
  32   die "${self}->${has_meth}" unless $self->$has_meth;
  33   $self->$builder(
  34     $self->${\"${type}_sql"},
  35     $self->_unwrap_args_for($type => $args),
  36   );
  37 }
  38
  39 method _new_call_command ($type, $args) {
  40   $self->_new_command(
  41     sub { shift->raw_store->new_call_command(@_) },
  42     $type => $args,
  43   );
  44 }
  45
  46 method new_insert_command ($args) {
  47   my $builder = $self->insert_command_constructor;
  48   $builder
  49     ? $self->_new_command($builder => insert => $args)
  50     : $self->_new_call_command(insert => $args);
  51 }
  52
  53 method new_update_command ($args) {
  54   $self->_new_call_command(update => $args);
  55 }
  56
  57 method new_delete_command ($args) {
  58   $self->_new_call_command(delete => $args);
  59 }
  60
  61 __PACKAGE__->meta->make_immutable;
  62
  63 1;