lib/DBIx/Data/Collection/Set.pm

   1 package DBIx::Data::Collection::Set;
   2
   3 use Moose;
   4 use Method::Signatures::Simple;
   5 use Data::Perl::Stream::Array;
   6
   7 has _store => (is => 'ro', required => 1, init_arg => 'store');
   8
   9 has _class => (is => 'ro', predicate => '_has_class');
  10
  11 has _set_over => (is => 'ro', required => 1, init_arg => 'set_over');
  12
  13 ## member cache (all members)
  14
  15 has _member_cache => (
  16   is => 'rw', lazy_build => 1,
  17   predicate => '_member_cache_built',
  18 );
  19
  20 method _build__member_cache {
  21   my $stream = $self->_new_raw_stream;
  22   my @cache;
  23   while (my ($raw) = $stream->next) {
  24     my $obj = do {
  25       if (my ($obj) = $self->_key_cache_get_raw($raw)) {
  26         $self->_merge($obj, $raw)
  27       } else {
  28         $self->_add_to_key_cache($self->_inflate($raw))
  29       }
  30     };
  31     push @cache, $obj;
  32   }
  33   \@cache
  34 }
  35
  36 method _add_to_member_cache ($to_add) {
  37   return $to_add unless $self->_member_cache_built;
  38   push @{$self->_member_cache}, $to_add;
  39   $to_add
  40 }
  41
  42 method _remove_from_member_cache ($to_remove) {
  43   return $to_remove unless $self->_member_cache_built;
  44   @{$self->_member_cache} = grep $_ ne $to_remove, @{$self->_member_cache};
  45   $to_remove
  46 }
  47
  48 ## key cache - by primary/unique key
  49
  50 has _key_cache => (is => 'ro', default => sub { {} });
  51
  52 method _add_to_key_cache ($to_add) {
  53   $self->_key_cache->{$self->_object_to_id($to_add)} = $to_add;
  54   $to_add
  55 }
  56
  57 method _remove_from_key_cache ($to_remove) {
  58   # should return $to_remove
  59   delete $self->_key_cache->{$self->_object_to_id($to_remove)}
  60 }
  61
  62 method _key_cache_has_raw ($raw) {
  63   exists $self->_key_cache->{$self->_raw_to_id($raw)}
  64 }
  65
  66 method _key_cache_has_object ($obj) {
  67   exists $self->_key_cache->{$self->_object_to_id($obj)}
  68 }
  69
  70 method _key_cache_get_raw ($raw) {
  71   my $id = $self->_raw_to_id($raw);
  72   exists $self->_key_cache->{$id}
  73     ? ($self->_key_cache->{$id})
  74     : ()
  75 }
  76
  77 method _key_cache_get_object ($obj) {
  78   $self->_key_cache_get_raw($self->_deflate($obj))
  79 }
  80
  81 ## loading data
  82
  83 method _new_raw_stream {
  84   $self->_store->new_select_command([])->execute
  85 }
  86
  87 ## thunking between the store representation and the set representation
  88 #
  89 # _inflate is raw data -> final repr
  90 # _deflate is final repr -> raw data
  91 # _merge takes final repr + raw data and updates the repr
  92 #    (this is used for pk-generated values and later lazy loading)
  93
  94 method _inflate ($raw) {
  95   bless($raw, $self->_class) if $self->_has_class;
  96   $raw
  97 }
  98
  99 method _deflate ($obj) {
 100   +{ %$obj }
 101 }
 102
 103 method _merge ($obj, $raw) {
 104   @{$obj}{keys %$raw} = values %$raw;
 105   $obj
 106 }
 107
 108 ## methods to get ids
 109
 110 method _raw_to_id ($raw) {
 111   # XXX must escape this. or do something else.
 112   join ';', map $raw->{$_}, @{$self->_set_over}
 113 }
 114
 115 method _object_to_id ($obj) {
 116   $self->_raw_to_id($self->_deflate($obj))
 117 }
 118
 119 ## array-ish operations - i.e. get all members
 120
 121 method flatten {
 122   @{$self->_member_cache};
 123 }
 124
 125 method as_stream {
 126   Data::Perl::Stream::Array->new(array => $self->_member_cache);
 127 }
 128
 129 ## add to set
 130
 131 method add ($new) {
 132   $self->_add_to_store($new);
 133   $self->_add_to_caches($new);
 134   $new
 135 }
 136
 137 method _add_to_store ($new) {
 138   my $new_raw = $self->_deflate($new);
 139   $self->_merge($new, $self->_store->new_insert_command($new_raw)->execute);
 140   $new
 141 }
 142
 143 method _add_to_caches ($new) {
 144   $self->_add_to_member_cache($new);
 145   $self->_add_to_key_cache($new);
 146   $new
 147 }
 148
 149 ## remove from set
 150
 151 method remove ($old) {
 152   $self->_remove_from_store($old);
 153   $self->_remove_from_caches($old);
 154   $old
 155 }
 156
 157 method _remove_from_store ($old) {
 158   $self->_store->new_delete_command($self->_deflate($old))->execute;
 159 }
 160
 161 method _remove_from_caches ($old) {
 162   $self->_remove_from_member_cache($old);
 163   $self->_remove_from_key_cache($old);
 164   $old
 165 }
 166
 167 1;