remove Dwarn calls

[dbsrgits/DBIx-Data-Store-old.git] / t / dbix-data-set / 02indexed_by.t

use strict;
use warnings FATAL => 'all';
use Test::More;
use DBIx::Data::Collection::Set::IndexableBy;

BEGIN {
  package BasicCollection;
  require 't/dbix-data-set/01basic_collection.t'
}

sub setup_db { BasicCollection::setup_db @_ }

sub make_store { BasicCollection::make_store @_ }

sub sort_set { BasicCollection::sort_set @_ }

sub make_set {
  BasicCollection::make_set({
      indexable_by => {
        name => {
          set_over => [ 'name' ],
          store => make_store({
            select_single_sql => q{SELECT id, name FROM person WHERE name = ?},
            select_single_argument_order => [ qw(name) ],
          }),
        },
      },
    },
    {
      select_single_sql => q{SELECT id, name FROM person WHERE id = ?},
      select_single_argument_order => [ qw(id) ],
    },
    'DBIx::Data::Collection::Set::IndexableBy'
  )
}


sub run_tests {
  my @expect = setup_db;
  my $by_id = make_set;
  my $id_1 = $by_id->get({ id => 1 });
  my $by_name = $by_id->indexed_by('name');
  ok(scalar($by_name->_key_cache_get_object($id_1), 'key cache transfer'));
  cmp_ok(
    $id_1, '==', $by_name->get({ name => $id_1->{name} }),
    'get returns same object'
  );
  my $name_pterry = $by_name->get({ name => 'Pterry' });
  ok(
    scalar($by_id->_key_cache_get_object($name_pterry)),
    'key cache reverse transfer'
  );
  cmp_ok(
    $name_pterry, '==', $by_id->get({ id => $name_pterry->{id} }),
    'get returns same object'
  );
  ok(
    !$by_id->_member_cache_built && !$by_name->_member_cache_built,
    'No caches yet'
  );
  is_deeply(
    [ sort_set $by_id->flatten ], \@expect,
    'flatten set',
  );
  ok(
    $by_id->_member_cache_built && $by_name->_member_cache_built,
    'Both caches filled'
  );
  ok(
    $by_id->_member_cache != $by_name->_member_cache,
    'Caches are separate arrayrefs'
  );
  done_testing;
}

run_tests unless caller;