mass update and delete

[dbsrgits/DBIx-Data-Store-old.git] / t / 03set_updates.t

use strict;
use warnings FATAL => 'all';
use Test::More;

BEGIN {
  package BasicCollection;
  require 't/01basic_collection.t';
}

sub setup_dbh { BasicCollection::setup_dbh }

my $dbh;

sub setup_db {
  $dbh = setup_dbh;
  $dbh->do("CREATE TABLE spoon (
    id INTEGER NOT NULL PRIMARY KEY,
    last_frobnicated DATE NOT NULL
  )");
  $dbh->do("INSERT INTO spoon (last_frobnicated) VALUES ('2009-03-30')")
    for 1 .. 5;
}

setup_db;

my $store = DBIx::Data::Store::CRUD->new(
  raw_store => BasicCollection::raw_store,
  select_sql => 'SELECT id, last_frobnicated FROM spoon',
  select_column_order => [ qw(id last_frobbed) ],
  update_sql => 'UPDATE spoon SET last_frobnicated = ?',
  update_argument_order => [ qw(last_frobbed) ],
  delete_sql => 'DELETE FROM spoon',
);

sub make_set {
  DBIx::Data::Collection::Set->new(
    store => $store,
    set_over => [ 'id' ],
  );
}

sub sort_set { sort { $a->{id} <=> $b->{id} } @_ }

my $set = make_set;

my $x = 0;

my @expected = map +{ id => ++$x, last_frobbed => '2009-03-30' }, 1 .. 5;

my @data = $set->flatten;

is_deeply(
  \@data,
  \@expected,
  'Simple fetch'
);

$set->_update_set_in_store({ last_frobbed => '2009-04-01' });

$_->{last_frobbed} = '2009-04-01' for @expected;

is_deeply(
  \@data,
  \@expected,
  'After update'
);

is_deeply(
  [ sort_set make_set->flatten ],
  \@expected,
  'Refetch'
);

$set->_remove_set_from_store;

@expected = ();

@data = $set->flatten;

is_deeply(
  \@data,
  \@expected,
  'After delete'
);

is_deeply(
  [ sort_set make_set->flatten ],
  \@expected,
  'Refetch'
);

done_testing;