add class attribute test

[dbsrgits/DBIx-Data-Store-old.git] / t / 01basic_collection.t

use Test::More;
use DBIx::Data::Store;
use DBIx::Data::Store::CRUD;
use DBIx::Data::Collection::Set;
use DBI;

use strict;
use warnings FATAL => 'all';

my $dsn = 'dbi:SQLite:tmp.db';

my @expect;

{
  unlink('tmp.db');
  my $dbh = DBI->connect($dsn);
  $dbh->do(q{
    CREATE TABLE person (
      id INTEGER NOT NULL PRIMARY KEY,
      name VARCHAR(255) NOT NULL
    )
  });
  my $pop = $dbh->prepare(q{INSERT INTO person (name) VALUES (?)});
  my @names = qw(Joe Jim Bob Pterry);
  $pop->execute($_) for @names;
  @expect = do { my $id = 0; map +{ id => ++$id, name => $_ }, @names };
}

sub make_set {
  my ($set, $crud) = @_;
  DBIx::Data::Collection::Set->new(
    store => DBIx::Data::Store::CRUD->new(
      raw_store => DBIx::Data::Store->connect($dsn),
      select_sql => q{SELECT id, name FROM person},
      select_column_order => [ qw(id name) ],
      %$crud,
    ),
    %$set
  );
}

my $set = make_set;

is_deeply([ $set->flatten ], \@expect, 'Basic data out ok (flatten)');

{
  my $stream = $set->as_stream;

  my @got; while (my ($next) = $stream->next) { push @got, $next }

  is_deeply(\@got, \@expect, 'Basic data out ok (stream)');
}

$set = make_set { class => 'Spoon' };

is_deeply(
  [ $set->flatten ],
  [ map { bless({ %$_ }, 'Spoon') } @expect ],
  'Basic data with class out ok'
);

done_testing;