lib/DBIx/Class/Storage/DBI/Replicated.pm

   1 package DBIx::Class::Storage::DBI::Replicated;
   2
   3 BEGIN {
   4   use Carp::Clan qw/^DBIx::Class/;
   5
   6   ## Modules required for Replication support not required for general DBIC
   7   ## use, so we explicitly test for these.
   8
   9   my %replication_required = (
  10     Moose => '0.77',
  11     MooseX::AttributeHelpers => '0.12',
  12     MooseX::Types => '0.10',
  13     namespace::clean => '0.11',
  14     Hash::Merge => '0.11'
  15   );
  16
  17   my @didnt_load;
  18
  19   for my $module (keys %replication_required) {
  20         eval "use $module $replication_required{$module}";
  21         push @didnt_load, "$module $replication_required{$module}"
  22          if $@;
  23   }
  24
  25   croak("@{[ join ', ', @didnt_load ]} are missing and are required for Replication")
  26     if @didnt_load;
  27 }
  28
  29 use Moose;
  30 use DBIx::Class::Storage::DBI;
  31 use DBIx::Class::Storage::DBI::Replicated::Pool;
  32 use DBIx::Class::Storage::DBI::Replicated::Balancer;
  33 use DBIx::Class::Storage::DBI::Replicated::Types 'BalancerClassNamePart';
  34 use MooseX::Types::Moose qw/ClassName HashRef Object/;
  35 use Scalar::Util 'reftype';
  36 use Carp::Clan qw/^DBIx::Class/;
  37 use Hash::Merge 'merge';
  38
  39 use namespace::clean -except => 'meta';
  40
  41 =head1 NAME
  42
  43 DBIx::Class::Storage::DBI::Replicated - BETA Replicated database support
  44
  45 =head1 SYNOPSIS
  46
  47 The Following example shows how to change an existing $schema to a replicated
  48 storage type, add some replicated (readonly) databases, and perform reporting
  49 tasks.
  50
  51   ## Change storage_type in your schema class
  52   $schema->storage_type( ['::DBI::Replicated', {balancer=>'::Random'}] );
  53
  54   ## Add some slaves.  Basically this is an array of arrayrefs, where each
  55   ## arrayref is database connect information
  56
  57   $schema->storage->connect_replicants(
  58     [$dsn1, $user, $pass, \%opts],
  59     [$dsn2, $user, $pass, \%opts],
  60     [$dsn3, $user, $pass, \%opts],
  61   );
  62
  63   ## Now, just use the $schema as normal
  64   $schema->resultset('Source')->search({name=>'etc'});
  65
  66   ## You can force a given query to use a particular storage using the search
  67   ### attribute 'force_pool'.  For example:
  68
  69   my $RS = $schema->resultset('Source')->search(undef, {force_pool=>'master'});
  70
  71   ## Now $RS will force everything (both reads and writes) to use whatever was
  72   ## setup as the master storage.  'master' is hardcoded to always point to the
  73   ## Master, but you can also use any Replicant name.  Please see:
  74   ## L<DBIx::Class::Storage::Replicated::Pool> and the replicants attribute for
  75   ## More. Also see transactions and L</execute_reliably> for alternative ways
  76   ## to force read traffic to the master.
  77
  78 =head1 DESCRIPTION
  79
  80 Warning: This class is marked BETA.  This has been running a production
  81 website using MySQL native replication as its backend and we have some decent
  82 test coverage but the code hasn't yet been stressed by a variety of databases.
  83 Individual DB's may have quirks we are not aware of.  Please use this in first
  84 development and pass along your experiences/bug fixes.
  85
  86 This class implements replicated data store for DBI. Currently you can define
  87 one master and numerous slave database connections. All write-type queries
  88 (INSERT, UPDATE, DELETE and even LAST_INSERT_ID) are routed to master
  89 database, all read-type queries (SELECTs) go to the slave database.
  90
  91 Basically, any method request that L<DBIx::Class::Storage::DBI> would normally
  92 handle gets delegated to one of the two attributes: L</read_handler> or to
  93 L</write_handler>.  Additionally, some methods need to be distributed
  94 to all existing storages.  This way our storage class is a drop in replacement
  95 for L<DBIx::Class::Storage::DBI>.
  96
  97 Read traffic is spread across the replicants (slaves) occuring to a user
  98 selected algorithm.  The default algorithm is random weighted.
  99
 100 =head1 NOTES
 101
 102 The consistancy betweeen master and replicants is database specific.  The Pool
 103 gives you a method to validate it's replicants, removing and replacing them
 104 when they fail/pass predefined criteria.  Please make careful use of the ways
 105 to force a query to run against Master when needed.
 106
 107 =head1 REQUIREMENTS
 108
 109 Replicated Storage has additional requirements not currently part of L<DBIx::Class>
 110
 111   Moose => 0.77
 112   MooseX::AttributeHelpers => 0.12
 113   MooseX::Types => 0.10
 114   namespace::clean => 0.11
 115   Hash::Merge => 0.11
 116
 117 You will need to install these modules manually via CPAN or make them part of the
 118 Makefile for your distribution.
 119
 120 =head1 ATTRIBUTES
 121
 122 This class defines the following attributes.
 123
 124 =head2 schema
 125
 126 The underlying L<DBIx::Class::Schema> object this storage is attaching
 127
 128 =cut
 129
 130 has 'schema' => (
 131     is=>'rw',
 132     isa=>'DBIx::Class::Schema',
 133     weak_ref=>1,
 134     required=>1,
 135 );
 136
 137 =head2 pool_type
 138
 139 Contains the classname which will instantiate the L</pool> object.  Defaults
 140 to: L<DBIx::Class::Storage::DBI::Replicated::Pool>.
 141
 142 =cut
 143
 144 has 'pool_type' => (
 145   is=>'rw',
 146   isa=>ClassName,
 147   default=>'DBIx::Class::Storage::DBI::Replicated::Pool',
 148   handles=>{
 149     'create_pool' => 'new',
 150   },
 151 );
 152
 153 =head2 pool_args
 154
 155 Contains a hashref of initialized information to pass to the Balancer object.
 156 See L<DBIx::Class::Storage::Replicated::Pool> for available arguments.
 157
 158 =cut
 159
 160 has 'pool_args' => (
 161   is=>'rw',
 162   isa=>HashRef,
 163   lazy=>1,
 164   default=>sub { {} },
 165 );
 166
 167
 168 =head2 balancer_type
 169
 170 The replication pool requires a balance class to provider the methods for
 171 choose how to spread the query load across each replicant in the pool.
 172
 173 =cut
 174
 175 has 'balancer_type' => (
 176   is=>'rw',
 177   isa=>BalancerClassNamePart,
 178   coerce=>1,
 179   required=>1,
 180   default=> 'DBIx::Class::Storage::DBI::Replicated::Balancer::First',
 181   handles=>{
 182     'create_balancer' => 'new',
 183   },
 184 );
 185
 186 =head2 balancer_args
 187
 188 Contains a hashref of initialized information to pass to the Balancer object.
 189 See L<DBIx::Class::Storage::Replicated::Balancer> for available arguments.
 190
 191 =cut
 192
 193 has 'balancer_args' => (
 194   is=>'rw',
 195   isa=>HashRef,
 196   lazy=>1,
 197   required=>1,
 198   default=>sub { {} },
 199 );
 200
 201 =head2 pool
 202
 203 Is a <DBIx::Class::Storage::DBI::Replicated::Pool> or derived class.  This is a
 204 container class for one or more replicated databases.
 205
 206 =cut
 207
 208 has 'pool' => (
 209   is=>'ro',
 210   isa=>'DBIx::Class::Storage::DBI::Replicated::Pool',
 211   lazy_build=>1,
 212   handles=>[qw/
 213     connect_replicants
 214     replicants
 215     has_replicants
 216   /],
 217 );
 218
 219 =head2 balancer
 220
 221 Is a <DBIx::Class::Storage::DBI::Replicated::Balancer> or derived class.  This
 222 is a class that takes a pool (<DBIx::Class::Storage::DBI::Replicated::Pool>)
 223
 224 =cut
 225
 226 has 'balancer' => (
 227   is=>'rw',
 228   isa=>'DBIx::Class::Storage::DBI::Replicated::Balancer',
 229   lazy_build=>1,
 230   handles=>[qw/auto_validate_every/],
 231 );
 232
 233 =head2 master
 234
 235 The master defines the canonical state for a pool of connected databases.  All
 236 the replicants are expected to match this databases state.  Thus, in a classic
 237 Master / Slaves distributed system, all the slaves are expected to replicate
 238 the Master's state as quick as possible.  This is the only database in the
 239 pool of databases that is allowed to handle write traffic.
 240
 241 =cut
 242
 243 has 'master' => (
 244   is=> 'ro',
 245   isa=>'DBIx::Class::Storage::DBI',
 246   lazy_build=>1,
 247 );
 248
 249 =head1 ATTRIBUTES IMPLEMENTING THE DBIx::Storage::DBI INTERFACE
 250
 251 The following methods are delegated all the methods required for the
 252 L<DBIx::Class::Storage::DBI> interface.
 253
 254 =head2 read_handler
 255
 256 Defines an object that implements the read side of L<BIx::Class::Storage::DBI>.
 257
 258 =cut
 259
 260 has 'read_handler' => (
 261   is=>'rw',
 262   isa=>Object,
 263   lazy_build=>1,
 264   handles=>[qw/
 265     select
 266     select_single
 267     columns_info_for
 268   /],
 269 );
 270
 271 =head2 write_handler
 272
 273 Defines an object that implements the write side of L<BIx::Class::Storage::DBI>.
 274
 275 =cut
 276
 277 has 'write_handler' => (
 278   is=>'ro',
 279   isa=>Object,
 280   lazy_build=>1,
 281   handles=>[qw/
 282     on_connect_do
 283     on_disconnect_do
 284     connect_info
 285     throw_exception
 286     sql_maker
 287     sqlt_type
 288     create_ddl_dir
 289     deployment_statements
 290     datetime_parser
 291     datetime_parser_type
 292     last_insert_id
 293     insert
 294     insert_bulk
 295     update
 296     delete
 297     dbh
 298     txn_begin
 299     txn_do
 300     txn_commit
 301     txn_rollback
 302     txn_scope_guard
 303     sth
 304     deploy
 305     with_deferred_fk_checks
 306
 307     reload_row
 308     _prep_for_execute
 309
 310   /],
 311 );
 312
 313 has _master_connect_info_opts =>
 314   (is => 'rw', isa => HashRef, default => sub { {} });
 315
 316 =head2 around: connect_info
 317
 318 Preserve master's C<connect_info> options (for merging with replicants.)
 319 Also set any Replicated related options from connect_info, such as
 320 C<pool_type>, C<pool_args>, C<balancer_type> and C<balancer_args>.
 321
 322 =cut
 323
 324 around connect_info => sub {
 325   my ($next, $self, $info, @extra) = @_;
 326
 327   my %opts;
 328   for my $arg (@$info) {
 329     next unless (reftype($arg)||'') eq 'HASH';
 330     %opts = %{ merge($arg, \%opts) };
 331   }
 332   delete $opts{dsn};
 333
 334   if (@opts{qw/pool_type pool_args/}) {
 335     $self->pool_type(delete $opts{pool_type})
 336       if $opts{pool_type};
 337
 338     $self->pool_args(
 339       merge((delete $opts{pool_args} || {}), $self->pool_args)
 340     );
 341
 342     $self->pool($self->_build_pool)
 343         if $self->pool;
 344   }
 345
 346   if (@opts{qw/balancer_type balancer_args/}) {
 347     $self->balancer_type(delete $opts{balancer_type})
 348       if $opts{balancer_type};
 349
 350     $self->balancer_args(
 351       merge((delete $opts{balancer_args} || {}), $self->balancer_args)
 352     );
 353
 354     $self->balancer($self->_build_balancer)
 355         if $self->balancer;
 356   }
 357
 358   $self->_master_connect_info_opts(\%opts);
 359
 360   $self->$next($info, @extra);
 361 };
 362
 363 =head1 METHODS
 364
 365 This class defines the following methods.
 366
 367 =head2 BUILDARGS
 368
 369 L<DBIx::Class::Schema> when instantiating it's storage passed itself as the
 370 first argument.  So we need to massage the arguments a bit so that all the
 371 bits get put into the correct places.
 372
 373 =cut
 374
 375 sub BUILDARGS {
 376   my ($class, $schema, $storage_type_args, @args) = @_;
 377
 378   return {
 379         schema=>$schema,
 380         %$storage_type_args,
 381         @args
 382   }
 383 }
 384
 385 =head2 _build_master
 386
 387 Lazy builder for the L</master> attribute.
 388
 389 =cut
 390
 391 sub _build_master {
 392   my $self = shift @_;
 393   my $master = DBIx::Class::Storage::DBI->new($self->schema);
 394   DBIx::Class::Storage::DBI::Replicated::WithDSN->meta->apply($master);
 395   $master
 396 }
 397
 398 =head2 _build_pool
 399
 400 Lazy builder for the L</pool> attribute.
 401
 402 =cut
 403
 404 sub _build_pool {
 405   my $self = shift @_;
 406   $self->create_pool(%{$self->pool_args});
 407 }
 408
 409 =head2 _build_balancer
 410
 411 Lazy builder for the L</balancer> attribute.  This takes a Pool object so that
 412 the balancer knows which pool it's balancing.
 413
 414 =cut
 415
 416 sub _build_balancer {
 417   my $self = shift @_;
 418   $self->create_balancer(
 419     pool=>$self->pool,
 420     master=>$self->master,
 421     %{$self->balancer_args},
 422   );
 423 }
 424
 425 =head2 _build_write_handler
 426
 427 Lazy builder for the L</write_handler> attribute.  The default is to set this to
 428 the L</master>.
 429
 430 =cut
 431
 432 sub _build_write_handler {
 433   return shift->master;
 434 }
 435
 436 =head2 _build_read_handler
 437
 438 Lazy builder for the L</read_handler> attribute.  The default is to set this to
 439 the L</balancer>.
 440
 441 =cut
 442
 443 sub _build_read_handler {
 444   return shift->balancer;
 445 }
 446
 447 =head2 around: connect_replicants
 448
 449 All calls to connect_replicants needs to have an existing $schema tacked onto
 450 top of the args, since L<DBIx::Storage::DBI> needs it, and any C<connect_info>
 451 options merged with the master, with replicant opts having higher priority.
 452
 453 =cut
 454
 455 around connect_replicants => sub {
 456   my ($next, $self, @args) = @_;
 457
 458   for my $r (@args) {
 459     $r = [ $r ] unless reftype $r eq 'ARRAY';
 460
 461     croak "coderef replicant connect_info not supported"
 462       if ref $r->[0] && reftype $r->[0] eq 'CODE';
 463
 464 # any connect_info options?
 465     my $i = 0;
 466     $i++ while $i < @$r && (reftype($r->[$i])||'') ne 'HASH';
 467
 468 # make one if none
 469     $r->[$i] = {} unless $r->[$i];
 470
 471 # merge if two hashes
 472     my @hashes = @$r[$i .. $#{$r}];
 473
 474     croak "invalid connect_info options"
 475       if (grep { reftype($_) eq 'HASH' } @hashes) != @hashes;
 476
 477     croak "too many hashrefs in connect_info"
 478       if @hashes > 2;
 479
 480     my %opts = %{ merge(reverse @hashes) };
 481
 482 # delete them
 483     splice @$r, $i+1, ($#{$r} - $i), ();
 484
 485 # merge with master
 486     %opts = %{ merge(\%opts, $self->_master_connect_info_opts) };
 487
 488 # update
 489     $r->[$i] = \%opts;
 490   }
 491
 492   $self->$next($self->schema, @args);
 493 };
 494
 495 =head2 all_storages
 496
 497 Returns an array of of all the connected storage backends.  The first element
 498 in the returned array is the master, and the remainings are each of the
 499 replicants.
 500
 501 =cut
 502
 503 sub all_storages {
 504   my $self = shift @_;
 505   return grep {defined $_ && blessed $_} (
 506      $self->master,
 507      values %{ $self->replicants },
 508   );
 509 }
 510
 511 =head2 execute_reliably ($coderef, ?@args)
 512
 513 Given a coderef, saves the current state of the L</read_handler>, forces it to
 514 use reliable storage (ie sets it to the master), executes a coderef and then
 515 restores the original state.
 516
 517 Example:
 518
 519   my $reliably = sub {
 520     my $name = shift @_;
 521     $schema->resultset('User')->create({name=>$name});
 522     my $user_rs = $schema->resultset('User')->find({name=>$name});
 523     return $user_rs;
 524   };
 525
 526   my $user_rs = $schema->storage->execute_reliably($reliably, 'John');
 527
 528 Use this when you must be certain of your database state, such as when you just
 529 inserted something and need to get a resultset including it, etc.
 530
 531 =cut
 532
 533 sub execute_reliably {
 534   my ($self, $coderef, @args) = @_;
 535
 536   unless( ref $coderef eq 'CODE') {
 537     $self->throw_exception('Second argument must be a coderef');
 538   }
 539
 540   ##Get copy of master storage
 541   my $master = $self->master;
 542
 543   ##Get whatever the current read hander is
 544   my $current = $self->read_handler;
 545
 546   ##Set the read handler to master
 547   $self->read_handler($master);
 548
 549   ## do whatever the caller needs
 550   my @result;
 551   my $want_array = wantarray;
 552
 553   eval {
 554     if($want_array) {
 555       @result = $coderef->(@args);
 556     } elsif(defined $want_array) {
 557       ($result[0]) = ($coderef->(@args));
 558     } else {
 559       $coderef->(@args);
 560     }
 561   };
 562
 563   ##Reset to the original state
 564   $self->read_handler($current);
 565
 566   ##Exception testing has to come last, otherwise you might leave the
 567   ##read_handler set to master.
 568
 569   if($@) {
 570     $self->throw_exception("coderef returned an error: $@");
 571   } else {
 572     return $want_array ? @result : $result[0];
 573   }
 574 }
 575
 576 =head2 set_reliable_storage
 577
 578 Sets the current $schema to be 'reliable', that is all queries, both read and
 579 write are sent to the master
 580
 581 =cut
 582
 583 sub set_reliable_storage {
 584   my $self = shift @_;
 585   my $schema = $self->schema;
 586   my $write_handler = $self->schema->storage->write_handler;
 587
 588   $schema->storage->read_handler($write_handler);
 589 }
 590
 591 =head2 set_balanced_storage
 592
 593 Sets the current $schema to be use the </balancer> for all reads, while all
 594 writea are sent to the master only
 595
 596 =cut
 597
 598 sub set_balanced_storage {
 599   my $self = shift @_;
 600   my $schema = $self->schema;
 601   my $write_handler = $self->schema->storage->balancer;
 602
 603   $schema->storage->read_handler($write_handler);
 604 }
 605
 606 =head2 around: txn_do ($coderef)
 607
 608 Overload to the txn_do method, which is delegated to whatever the
 609 L<write_handler> is set to.  We overload this in order to wrap in inside a
 610 L</execute_reliably> method.
 611
 612 =cut
 613
 614 around 'txn_do' => sub {
 615   my($txn_do, $self, $coderef, @args) = @_;
 616   $self->execute_reliably(sub {$self->$txn_do($coderef, @args)});
 617 };
 618
 619 =head2 connected
 620
 621 Check that the master and at least one of the replicants is connected.
 622
 623 =cut
 624
 625 sub connected {
 626   my $self = shift @_;
 627   return
 628     $self->master->connected &&
 629     $self->pool->connected_replicants;
 630 }
 631
 632 =head2 ensure_connected
 633
 634 Make sure all the storages are connected.
 635
 636 =cut
 637
 638 sub ensure_connected {
 639   my $self = shift @_;
 640   foreach my $source ($self->all_storages) {
 641     $source->ensure_connected(@_);
 642   }
 643 }
 644
 645 =head2 limit_dialect
 646
 647 Set the limit_dialect for all existing storages
 648
 649 =cut
 650
 651 sub limit_dialect {
 652   my $self = shift @_;
 653   foreach my $source ($self->all_storages) {
 654     $source->limit_dialect(@_);
 655   }
 656   return $self->master->quote_char;
 657 }
 658
 659 =head2 quote_char
 660
 661 Set the quote_char for all existing storages
 662
 663 =cut
 664
 665 sub quote_char {
 666   my $self = shift @_;
 667   foreach my $source ($self->all_storages) {
 668     $source->quote_char(@_);
 669   }
 670   return $self->master->quote_char;
 671 }
 672
 673 =head2 name_sep
 674
 675 Set the name_sep for all existing storages
 676
 677 =cut
 678
 679 sub name_sep {
 680   my $self = shift @_;
 681   foreach my $source ($self->all_storages) {
 682     $source->name_sep(@_);
 683   }
 684   return $self->master->name_sep;
 685 }
 686
 687 =head2 set_schema
 688
 689 Set the schema object for all existing storages
 690
 691 =cut
 692
 693 sub set_schema {
 694   my $self = shift @_;
 695   foreach my $source ($self->all_storages) {
 696     $source->set_schema(@_);
 697   }
 698 }
 699
 700 =head2 debug
 701
 702 set a debug flag across all storages
 703
 704 =cut
 705
 706 sub debug {
 707   my $self = shift @_;
 708   if(@_) {
 709     foreach my $source ($self->all_storages) {
 710       $source->debug(@_);
 711     }
 712   }
 713   return $self->master->debug;
 714 }
 715
 716 =head2 debugobj
 717
 718 set a debug object across all storages
 719
 720 =cut
 721
 722 sub debugobj {
 723   my $self = shift @_;
 724   if(@_) {
 725     foreach my $source ($self->all_storages) {
 726       $source->debugobj(@_);
 727     }
 728   }
 729   return $self->master->debugobj;
 730 }
 731
 732 =head2 debugfh
 733
 734 set a debugfh object across all storages
 735
 736 =cut
 737
 738 sub debugfh {
 739   my $self = shift @_;
 740   if(@_) {
 741     foreach my $source ($self->all_storages) {
 742       $source->debugfh(@_);
 743     }
 744   }
 745   return $self->master->debugfh;
 746 }
 747
 748 =head2 debugcb
 749
 750 set a debug callback across all storages
 751
 752 =cut
 753
 754 sub debugcb {
 755   my $self = shift @_;
 756   if(@_) {
 757     foreach my $source ($self->all_storages) {
 758       $source->debugcb(@_);
 759     }
 760   }
 761   return $self->master->debugcb;
 762 }
 763
 764 =head2 disconnect
 765
 766 disconnect everything
 767
 768 =cut
 769
 770 sub disconnect {
 771   my $self = shift @_;
 772   foreach my $source ($self->all_storages) {
 773     $source->disconnect(@_);
 774   }
 775 }
 776
 777 =head2 cursor_class
 778
 779 set cursor class on all storages, or return master's
 780
 781 =cut
 782
 783 sub cursor_class {
 784   my ($self, $cursor_class) = @_;
 785
 786   if ($cursor_class) {
 787     $_->cursor_class($cursor_class) for $self->all_storages;
 788   }
 789   $self->master->cursor_class;
 790 }
 791
 792 =head1 GOTCHAS
 793
 794 Due to the fact that replicants can lag behind a master, you must take care to
 795 make sure you use one of the methods to force read queries to a master should
 796 you need realtime data integrity.  For example, if you insert a row, and then
 797 immediately re-read it from the database (say, by doing $row->discard_changes)
 798 or you insert a row and then immediately build a query that expects that row
 799 to be an item, you should force the master to handle reads.  Otherwise, due to
 800 the lag, there is no certainty your data will be in the expected state.
 801
 802 For data integrity, all transactions automatically use the master storage for
 803 all read and write queries.  Using a transaction is the preferred and recommended
 804 method to force the master to handle all read queries.
 805
 806 Otherwise, you can force a single query to use the master with the 'force_pool'
 807 attribute:
 808
 809   my $row = $resultset->search(undef, {force_pool=>'master'})->find($pk);
 810
 811 This attribute will safely be ignore by non replicated storages, so you can use
 812 the same code for both types of systems.
 813
 814 Lastly, you can use the L</execute_reliably> method, which works very much like
 815 a transaction.
 816
 817 For debugging, you can turn replication on/off with the methods L</set_reliable_storage>
 818 and L</set_balanced_storage>, however this operates at a global level and is not
 819 suitable if you have a shared Schema object being used by multiple processes,
 820 such as on a web application server.  You can get around this limitation by
 821 using the Schema clone method.
 822
 823   my $new_schema = $schema->clone;
 824   $new_schema->set_reliable_storage;
 825
 826   ## $new_schema will use only the Master storage for all reads/writes while
 827   ## the $schema object will use replicated storage.
 828
 829 =head1 AUTHOR
 830
 831   John Napiorkowski <john.napiorkowski@takkle.com>
 832
 833 Based on code originated by:
 834
 835   Norbert Csongrádi <bert@cpan.org>
 836   Peter Siklósi <einon@einon.hu>
 837
 838 =head1 LICENSE
 839
 840 You may distribute this code under the same terms as Perl itself.
 841
 842 =cut
 843
 844 __PACKAGE__->meta->make_immutable;
 845
 846 1;