lib/DBIx/Class/Storage/DBI/Oracle/Generic.pm

   1 package DBIx::Class::Storage::DBI::Oracle::Generic;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Storage::DBI/;
   6 use mro 'c3';
   7 use DBIx::Class::Carp;
   8 use Scope::Guard ();
   9 use Context::Preserve 'preserve_context';
  10 use Try::Tiny;
  11 use List::Util 'first';
  12 use namespace::clean;
  13
  14 __PACKAGE__->sql_limit_dialect ('RowNum');
  15 __PACKAGE__->sql_quote_char ('"');
  16 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker::Oracle');
  17 __PACKAGE__->datetime_parser_type('DateTime::Format::Oracle');
  18
  19 sub __cache_queries_with_max_lob_parts { 2 }
  20
  21 =head1 NAME
  22
  23 DBIx::Class::Storage::DBI::Oracle::Generic - Oracle Support for DBIx::Class
  24
  25 =head1 SYNOPSIS
  26
  27   # In your result (table) classes
  28   use base 'DBIx::Class::Core';
  29   __PACKAGE__->add_columns({ id => { sequence => 'mysequence', auto_nextval => 1 } });
  30   __PACKAGE__->set_primary_key('id');
  31
  32   # Somewhere in your Code
  33   # add some data to a table with a hierarchical relationship
  34   $schema->resultset('Person')->create ({
  35         firstname => 'foo',
  36         lastname => 'bar',
  37         children => [
  38             {
  39                 firstname => 'child1',
  40                 lastname => 'bar',
  41                 children => [
  42                     {
  43                         firstname => 'grandchild',
  44                         lastname => 'bar',
  45                     }
  46                 ],
  47             },
  48             {
  49                 firstname => 'child2',
  50                 lastname => 'bar',
  51             },
  52         ],
  53     });
  54
  55   # select from the hierarchical relationship
  56   my $rs = $schema->resultset('Person')->search({},
  57     {
  58       'start_with' => { 'firstname' => 'foo', 'lastname' => 'bar' },
  59       'connect_by' => { 'parentid' => { '-prior' => { -ident => 'personid' } },
  60       'order_siblings_by' => { -asc => 'name' },
  61     };
  62   );
  63
  64   # this will select the whole tree starting from person "foo bar", creating
  65   # following query:
  66   # SELECT
  67   #     me.persionid me.firstname, me.lastname, me.parentid
  68   # FROM
  69   #     person me
  70   # START WITH
  71   #     firstname = 'foo' and lastname = 'bar'
  72   # CONNECT BY
  73   #     parentid = prior personid
  74   # ORDER SIBLINGS BY
  75   #     firstname ASC
  76
  77 =head1 DESCRIPTION
  78
  79 This class implements base Oracle support. The subclass
  80 L<DBIx::Class::Storage::DBI::Oracle::WhereJoins> is for C<(+)> joins in Oracle
  81 versions before 9.0.
  82
  83 =head1 METHODS
  84
  85 =cut
  86
  87 sub _determine_supports_insert_returning {
  88   my $self = shift;
  89
  90 # TODO find out which version supports the RETURNING syntax
  91 # 8i has it and earlier docs are a 404 on oracle.com
  92
  93   return 1
  94     if $self->_server_info->{normalized_dbms_version} >= 8.001;
  95
  96   return 0;
  97 }
  98
  99 __PACKAGE__->_use_insert_returning_bound (1);
 100
 101 sub deployment_statements {
 102   my $self = shift;;
 103   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 104
 105   $sqltargs ||= {};
 106   my $quote_char = $self->schema->storage->sql_maker->quote_char;
 107   $sqltargs->{quote_table_names} = $quote_char ? 1 : 0;
 108   $sqltargs->{quote_field_names} = $quote_char ? 1 : 0;
 109
 110   if (
 111     ! exists $sqltargs->{producer_args}{oracle_version}
 112       and
 113     my $dver = $self->_server_info->{dbms_version}
 114   ) {
 115     $sqltargs->{producer_args}{oracle_version} = $dver;
 116   }
 117
 118   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 119 }
 120
 121 sub _dbh_last_insert_id {
 122   my ($self, $dbh, $source, @columns) = @_;
 123   my @ids = ();
 124   foreach my $col (@columns) {
 125     my $seq = ($source->column_info($col)->{sequence} ||= $self->get_autoinc_seq($source,$col));
 126     my $id = $self->_sequence_fetch( 'CURRVAL', $seq );
 127     push @ids, $id;
 128   }
 129   return @ids;
 130 }
 131
 132 sub _dbh_get_autoinc_seq {
 133   my ($self, $dbh, $source, $col) = @_;
 134
 135   my $sql_maker = $self->sql_maker;
 136   my ($ql, $qr) = map { $_ ? (quotemeta $_) : '' } $sql_maker->_quote_chars;
 137
 138   my $source_name;
 139   if ( ref $source->name eq 'SCALAR' ) {
 140     $source_name = ${$source->name};
 141
 142     # the ALL_TRIGGERS match further on is case sensitive - thus uppercase
 143     # stuff unless it is already quoted
 144     $source_name = uc ($source_name) if $source_name !~ /\"/;
 145   }
 146   else {
 147     $source_name = $source->name;
 148     $source_name = uc($source_name) unless $ql;
 149   }
 150
 151   # trigger_body is a LONG
 152   local $dbh->{LongReadLen} = 64 * 1024 if ($dbh->{LongReadLen} < 64 * 1024);
 153
 154   # disable default bindtype
 155   local $sql_maker->{bindtype} = 'normal';
 156
 157   # look up the correct sequence automatically
 158   my ( $schema, $table ) = $source_name =~ /( (?:${ql})? \w+ (?:${qr})? ) \. ( (?:${ql})? \w+ (?:${qr})? )/x;
 159
 160   # if no explicit schema was requested - use the default schema (which in the case of Oracle is the db user)
 161   $schema ||= \'= USER';
 162
 163   my ($sql, @bind) = $sql_maker->select (
 164     'ALL_TRIGGERS',
 165     [qw/TRIGGER_BODY TABLE_OWNER TRIGGER_NAME/],
 166     {
 167       $schema ? (OWNER => $schema) : (),
 168       TABLE_NAME => $table || $source_name,
 169       TRIGGERING_EVENT => { -like => '%INSERT%' },  # this will also catch insert_or_update
 170       TRIGGER_TYPE => { -like => '%BEFORE%' },      # we care only about 'before' triggers
 171       STATUS => 'ENABLED',
 172      },
 173   );
 174
 175   # to find all the triggers that mention the column in question a simple
 176   # regex grep since the trigger_body above is a LONG and hence not searchable
 177   my @triggers = ( map
 178     { my %inf; @inf{qw/body schema name/} = @$_; \%inf }
 179     ( grep
 180       { $_->[0] =~ /\:new\.${ql}${col}${qr} | \:new\.$col/xi }
 181       @{ $dbh->selectall_arrayref( $sql, {}, @bind ) }
 182     )
 183   );
 184
 185   # extract all sequence names mentioned in each trigger
 186   for (@triggers) {
 187     $_->{sequences} = [ $_->{body} =~ / ( "? [\.\w\"\-]+ "? ) \. nextval /xig ];
 188   }
 189
 190   my $chosen_trigger;
 191
 192   # if only one trigger matched things are easy
 193   if (@triggers == 1) {
 194
 195     if ( @{$triggers[0]{sequences}} == 1 ) {
 196       $chosen_trigger = $triggers[0];
 197     }
 198     else {
 199       $self->throw_exception( sprintf (
 200         "Unable to introspect trigger '%s' for column %s.%s (references multiple sequences). "
 201       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 202         $triggers[0]{name},
 203         $source_name,
 204         $col,
 205         $col,
 206       ) );
 207     }
 208   }
 209   # got more than one matching trigger - see if we can narrow it down
 210   elsif (@triggers > 1) {
 211
 212     my @candidates = grep
 213       { $_->{body} =~ / into \s+ \:new\.$col /xi }
 214       @triggers
 215     ;
 216
 217     if (@candidates == 1 && @{$candidates[0]{sequences}} == 1) {
 218       $chosen_trigger = $candidates[0];
 219     }
 220     else {
 221       $self->throw_exception( sprintf (
 222         "Unable to reliably select a BEFORE INSERT trigger for column %s.%s (possibilities: %s). "
 223       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 224         $source_name,
 225         $col,
 226         ( join ', ', map { "'$_->{name}'" } @triggers ),
 227         $col,
 228       ) );
 229     }
 230   }
 231
 232   if ($chosen_trigger) {
 233     my $seq_name = $chosen_trigger->{sequences}[0];
 234
 235     $seq_name = "$chosen_trigger->{schema}.$seq_name"
 236       unless $seq_name =~ /\./;
 237
 238     return \$seq_name if $seq_name =~ /\"/; # may already be quoted in-trigger
 239     return $seq_name;
 240   }
 241
 242   $self->throw_exception( sprintf (
 243     "No suitable BEFORE INSERT triggers found for column %s.%s. "
 244   . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 245     $source_name,
 246     $col,
 247     $col,
 248   ));
 249 }
 250
 251 sub _sequence_fetch {
 252   my ( $self, $type, $seq ) = @_;
 253
 254   # use the maker to leverage quoting settings
 255   my $sql_maker = $self->sql_maker;
 256   my ($id) = $self->_get_dbh->selectrow_array ($sql_maker->select('DUAL', [ ref $seq ? \"$$seq.$type" : "$seq.$type" ] ) );
 257   return $id;
 258 }
 259
 260 sub _ping {
 261   my $self = shift;
 262
 263   my $dbh = $self->_dbh or return 0;
 264
 265   local $dbh->{RaiseError} = 1;
 266   local $dbh->{PrintError} = 0;
 267
 268   return try {
 269     $dbh->do('select 1 from dual');
 270     1;
 271   } catch {
 272     0;
 273   };
 274 }
 275
 276 sub _dbh_execute {
 277   my ($self, $dbh, $sql, @args) = @_;
 278
 279   my (@res, $tried);
 280   my $want = wantarray;
 281   my $next = $self->next::can;
 282   do {
 283     try {
 284       my $exec = sub {
 285         # Turn off sth caching for multi-part LOBs. See _prep_for_execute above.
 286         local $self->{disable_sth_caching} = 1
 287           if first {
 288             ($_->[0]{_ora_lob_autosplit_part}||0)
 289               > (__cache_queries_with_max_lob_parts-1)
 290           } @{ $args[0] };
 291
 292         $self->$next($dbh, $sql, @args)
 293       };
 294
 295       if (!defined $want) {
 296         $exec->();
 297       }
 298       elsif (! $want) {
 299         $res[0] = $exec->();
 300       }
 301       else {
 302         @res = $exec->();
 303       }
 304
 305       $tried++;
 306     }
 307     catch {
 308       if (! $tried and $_ =~ /ORA-01003/) {
 309         # ORA-01003: no statement parsed (someone changed the table somehow,
 310         # invalidating your cursor.)
 311         delete $dbh->{CachedKids}{$sql};
 312       }
 313       else {
 314         $self->throw_exception($_);
 315       }
 316     };
 317   } while (! $tried++);
 318
 319   return wantarray ? @res : $res[0];
 320 }
 321
 322 sub _dbh_execute_array {
 323   #my ($self, $sth, $tuple_status, @extra) = @_;
 324
 325   # DBD::Oracle warns loudly on partial execute_array failures
 326   local $_[1]->{PrintWarn} = 0;
 327
 328   shift->next::method(@_);
 329 }
 330
 331 =head2 get_autoinc_seq
 332
 333 Returns the sequence name for an autoincrement column
 334
 335 =cut
 336
 337 sub get_autoinc_seq {
 338   my ($self, $source, $col) = @_;
 339
 340   $self->dbh_do('_dbh_get_autoinc_seq', $source, $col);
 341 }
 342
 343 =head2 datetime_parser_type
 344
 345 This sets the proper DateTime::Format module for use with
 346 L<DBIx::Class::InflateColumn::DateTime>.
 347
 348 =head2 connect_call_datetime_setup
 349
 350 Used as:
 351
 352     on_connect_call => 'datetime_setup'
 353
 354 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set the session nls
 355 date, and timestamp values for use with L<DBIx::Class::InflateColumn::DateTime>
 356 and the necessary environment variables for L<DateTime::Format::Oracle>, which
 357 is used by it.
 358
 359 Maximum allowable precision is used, unless the environment variables have
 360 already been set.
 361
 362 These are the defaults used:
 363
 364   $ENV{NLS_DATE_FORMAT}         ||= 'YYYY-MM-DD HH24:MI:SS';
 365   $ENV{NLS_TIMESTAMP_FORMAT}    ||= 'YYYY-MM-DD HH24:MI:SS.FF';
 366   $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 367
 368 To get more than second precision with L<DBIx::Class::InflateColumn::DateTime>
 369 for your timestamps, use something like this:
 370
 371   use Time::HiRes 'time';
 372   my $ts = DateTime->from_epoch(epoch => time);
 373
 374 =cut
 375
 376 sub connect_call_datetime_setup {
 377   my $self = shift;
 378
 379   my $date_format = $ENV{NLS_DATE_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS';
 380   my $timestamp_format = $ENV{NLS_TIMESTAMP_FORMAT} ||=
 381     'YYYY-MM-DD HH24:MI:SS.FF';
 382   my $timestamp_tz_format = $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||=
 383     'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 384
 385   $self->_do_query(
 386     "alter session set nls_date_format = '$date_format'"
 387   );
 388   $self->_do_query(
 389     "alter session set nls_timestamp_format = '$timestamp_format'"
 390   );
 391   $self->_do_query(
 392     "alter session set nls_timestamp_tz_format='$timestamp_tz_format'"
 393   );
 394 }
 395
 396 ### Note originally by Ron "Quinn" Straight <quinnfazigu@gmail.org>
 397 ### http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/DBIx-Class.git;a=commitdiff;h=5db2758de644d53e07cd3e05f0e9037bf40116fc
 398 #
 399 # Handle LOB types in Oracle.  Under a certain size (4k?), you can get away
 400 # with the driver assuming your input is the deprecated LONG type if you
 401 # encode it as a hex string.  That ain't gonna fly at larger values, where
 402 # you'll discover you have to do what this does.
 403 #
 404 # This method had to be overridden because we need to set ora_field to the
 405 # actual column, and that isn't passed to the call (provided by Storage) to
 406 # bind_attribute_by_data_type.
 407 #
 408 # According to L<DBD::Oracle>, the ora_field isn't always necessary, but
 409 # adding it doesn't hurt, and will save your bacon if you're modifying a
 410 # table with more than one LOB column.
 411 #
 412 sub _dbi_attrs_for_bind {
 413   my ($self, $ident, $bind) = @_;
 414
 415   my $attrs = $self->next::method($ident, $bind);
 416
 417   for my $i (0 .. $#$attrs) {
 418     if (keys %{$attrs->[$i]||{}} and my $col = $bind->[$i][0]{dbic_colname}) {
 419       $attrs->[$i]{ora_field} = $col;
 420     }
 421   }
 422
 423   $attrs;
 424 }
 425
 426 my $dbd_loaded;
 427 sub bind_attribute_by_data_type {
 428   my ($self, $dt) = @_;
 429
 430   $dbd_loaded ||= do {
 431     require DBD::Oracle;
 432     if ($DBD::Oracle::VERSION eq '1.23') {
 433       $self->throw_exception(
 434         "BLOB/CLOB support in DBD::Oracle == 1.23 is broken, use an earlier or later ".
 435         "version.\n\nSee: https://rt.cpan.org/Public/Bug/Display.html?id=46016\n"
 436       );
 437     }
 438     1;
 439   };
 440
 441   if ($self->_is_lob_type($dt)) {
 442     return {
 443       ora_type => $self->_is_text_lob_type($dt)
 444         ? DBD::Oracle::ORA_CLOB()
 445         : DBD::Oracle::ORA_BLOB()
 446     };
 447   }
 448 }
 449
 450 # Handle blob columns in WHERE.
 451 #
 452 # For equality comparisons:
 453 #
 454 # We split data intended for comparing to a LOB into 2000 character chunks and
 455 # compare them using dbms_lob.substr on the LOB column.
 456 #
 457 # We turn off DBD::Oracle LOB binds for these partial LOB comparisons by passing
 458 # dbd_attrs => undef, because these are regular varchar2 comparisons and
 459 # otherwise the query will fail.
 460 #
 461 # Since the most common comparison size is likely to be under 4000 characters
 462 # (TEXT comparisons previously deployed to other RDBMSes) we disable
 463 # prepare_cached for queries with more than two part comparisons to a LOB
 464 # column. This is done in _dbh_execute (above) which was previously overridden
 465 # to gracefully recover from an Oracle error. This is to be careful to not
 466 # exhaust your application's open cursor limit.
 467 #
 468 # See:
 469 # http://itcareershift.com/blog1/2011/02/21/oracle-max-number-of-open-cursors-complete-reference-for-the-new-oracle-dba/
 470 # on the open_cursor limit.
 471 #
 472 # For everything else:
 473 #
 474 # We assume that everything that is not a LOB comparison, will most likely be a
 475 # LIKE query or some sort of function invocation. This may prove to be a naive
 476 # assumption in the future, but for now it should cover the two most likely
 477 # things users would want to do with a BLOB or CLOB, an equality test or a LIKE
 478 # query (on a CLOB.)
 479 #
 480 # For these expressions, the bind must NOT have the attributes of a LOB bind for
 481 # DBD::Oracle, otherwise the query will fail. This is done by passing
 482 # dbd_attrs => undef.
 483
 484 sub _prep_for_execute {
 485   my $self = shift;
 486   my ($op) = @_;
 487
 488   my ($sql, $bind) = $self->next::method(@_);
 489
 490   return ($sql, $bind) if $op eq 'insert';
 491
 492   my $blob_bind_index;
 493   for (0 .. $#$bind) {
 494     $blob_bind_index->{$_} = 1 if $self->_is_lob_type(
 495       $bind->[$_][0]{sqlt_datatype}
 496     );
 497   }
 498
 499   return ($sql, $bind) unless $blob_bind_index;
 500
 501   my (@sql_parts, $new_sql, @new_binds);
 502
 503   if ($op eq 'select' || $op eq 'delete') {
 504     @sql_parts = split /\?/, $sql;
 505   }
 506   elsif ($op eq 'update') {
 507     $self->throw_exception('Update with complex WHERE clauses currently not supported')
 508       if $sql =~ /\bWHERE\b .+ \bWHERE\b/xs;
 509
 510     my ($set_part, $where_part) = $sql =~ /^ (.+?) ( \bWHERE\b .+) /xs;
 511
 512     my $set_bind_count = $set_part =~ y/?//;
 513     @new_binds = splice @$bind, 0, $set_bind_count;
 514
 515     @sql_parts = split /\?/, $where_part;
 516     $new_sql  = $set_part;
 517   }
 518   else {
 519     $self->throw_exception("Unsupported \$op: $op");
 520   }
 521
 522   my $col_equality_re = qr/ (?<=\s) ([\w."]+) (\s*=\s*) $/x;
 523
 524   for my $b_idx (0 .. $#$bind) {
 525     my $bound = $bind->[$b_idx];
 526
 527     if ($blob_bind_index->{$b_idx}) {
 528       if (my ($col, $eq) = $sql_parts[0] =~ $col_equality_re) {
 529         my $data = $bound->[1];
 530
 531         $data = "$data" if ref $data;
 532
 533         my @parts = unpack '(a2000)*', $data;
 534
 535         my @sql_frag;
 536
 537         for my $idx (0..$#parts) {
 538           push @sql_frag, sprintf (
 539             'UTL_RAW.CAST_TO_VARCHAR2(RAWTOHEX(DBMS_LOB.SUBSTR(%s, 2000, %d))) = ?',
 540             $col, ($idx*2000 + 1),
 541           );
 542         }
 543
 544         my $sql_frag = '( ' . (join ' AND ', @sql_frag) . ' )';
 545
 546         $sql_parts[0] =~ s/$col_equality_re/$sql_frag/;
 547
 548         $new_sql .= shift @sql_parts;
 549
 550         for my $idx (0..$#parts) {
 551           push @new_binds, [
 552             {
 553               %{ $bound->[0] },
 554               _ora_lob_autosplit_part => $idx,
 555               dbd_attrs => undef,
 556             },
 557             $parts[$idx]
 558           ];
 559         }
 560       }
 561       else {
 562         $new_sql .= shift(@sql_parts) . '?';
 563
 564         push @new_binds, [
 565           {
 566             %{ $bound->[0] },
 567             dbd_attrs => undef,
 568           },
 569           $bound->[1],
 570         ];
 571       }
 572     }
 573     else {
 574       $new_sql .= shift(@sql_parts) . '?';
 575       push @new_binds, $bound;
 576     }
 577   }
 578
 579   if (@sql_parts > 1) {
 580     carp "There are more placeholders than binds, this should not happen!";
 581     @sql_parts = join ('?', @sql_parts);
 582   }
 583
 584   $new_sql .= $sql_parts[0];
 585
 586   return ($new_sql, \@new_binds);
 587 }
 588
 589 # Savepoints stuff.
 590
 591 sub _exec_svp_begin {
 592   my ($self, $name) = @_;
 593   $self->_dbh->do("SAVEPOINT $name");
 594 }
 595
 596 # Oracle automatically releases a savepoint when you start another one with the
 597 # same name.
 598 sub _exec_svp_release { 1 }
 599
 600 sub _exec_svp_rollback {
 601   my ($self, $name) = @_;
 602   $self->_dbh->do("ROLLBACK TO SAVEPOINT $name")
 603 }
 604
 605 =head2 relname_to_table_alias
 606
 607 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
 608 queries.
 609
 610 Unfortunately, Oracle doesn't support identifiers over 30 chars in length, so
 611 the L<DBIx::Class::Relationship> name is shortened and appended with half of an
 612 MD5 hash.
 613
 614 See L<DBIx::Class::Storage/"relname_to_table_alias">.
 615
 616 =cut
 617
 618 sub relname_to_table_alias {
 619   my $self = shift;
 620   my ($relname, $join_count) = @_;
 621
 622   my $alias = $self->next::method(@_);
 623
 624   # we need to shorten here in addition to the shortening in SQLA itself,
 625   # since the final relnames are a crucial for the join optimizer
 626   return $self->sql_maker->_shorten_identifier($alias);
 627 }
 628
 629 =head2 with_deferred_fk_checks
 630
 631 Runs a coderef between:
 632
 633   alter session set constraints = deferred
 634   ...
 635   alter session set constraints = immediate
 636
 637 to defer foreign key checks.
 638
 639 Constraints must be declared C<DEFERRABLE> for this to work.
 640
 641 =cut
 642
 643 sub with_deferred_fk_checks {
 644   my ($self, $sub) = @_;
 645
 646   my $txn_scope_guard = $self->txn_scope_guard;
 647
 648   $self->_do_query('alter session set constraints = deferred');
 649
 650   my $sg = Scope::Guard->new(sub {
 651     $self->_do_query('alter session set constraints = immediate');
 652   });
 653
 654   return
 655     preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
 656 }
 657
 658 =head1 ATTRIBUTES
 659
 660 Following additional attributes can be used in resultsets.
 661
 662 =head2 connect_by or connect_by_nocycle
 663
 664 =over 4
 665
 666 =item Value: \%connect_by
 667
 668 =back
 669
 670 A hashref of conditions used to specify the relationship between parent rows
 671 and child rows of the hierarchy.
 672
 673
 674   connect_by => { parentid => 'prior personid' }
 675
 676   # adds a connect by statement to the query:
 677   # SELECT
 678   #     me.persionid me.firstname, me.lastname, me.parentid
 679   # FROM
 680   #     person me
 681   # CONNECT BY
 682   #     parentid = prior persionid
 683
 684
 685   connect_by_nocycle => { parentid => 'prior personid' }
 686
 687   # adds a connect by statement to the query:
 688   # SELECT
 689   #     me.persionid me.firstname, me.lastname, me.parentid
 690   # FROM
 691   #     person me
 692   # CONNECT BY NOCYCLE
 693   #     parentid = prior persionid
 694
 695
 696 =head2 start_with
 697
 698 =over 4
 699
 700 =item Value: \%condition
 701
 702 =back
 703
 704 A hashref of conditions which specify the root row(s) of the hierarchy.
 705
 706 It uses the same syntax as L<DBIx::Class::ResultSet/search>
 707
 708   start_with => { firstname => 'Foo', lastname => 'Bar' }
 709
 710   # SELECT
 711   #     me.persionid me.firstname, me.lastname, me.parentid
 712   # FROM
 713   #     person me
 714   # START WITH
 715   #     firstname = 'foo' and lastname = 'bar'
 716   # CONNECT BY
 717   #     parentid = prior persionid
 718
 719 =head2 order_siblings_by
 720
 721 =over 4
 722
 723 =item Value: ($order_siblings_by | \@order_siblings_by)
 724
 725 =back
 726
 727 Which column(s) to order the siblings by.
 728
 729 It uses the same syntax as L<DBIx::Class::ResultSet/order_by>
 730
 731   'order_siblings_by' => 'firstname ASC'
 732
 733   # SELECT
 734   #     me.persionid me.firstname, me.lastname, me.parentid
 735   # FROM
 736   #     person me
 737   # CONNECT BY
 738   #     parentid = prior persionid
 739   # ORDER SIBLINGS BY
 740   #     firstname ASC
 741
 742 =head1 AUTHOR
 743
 744 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
 745
 746 =head1 LICENSE
 747
 748 You may distribute this code under the same terms as Perl itself.
 749
 750 =cut
 751
 752 1;
 753 # vim:sts=2 sw=2: