lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use DBIx::Class::Exception;
   8 use Data::Page;
   9 use DBIx::Class::ResultSetColumn;
  10 use DBIx::Class::ResultSourceHandle;
  11 use Hash::Merge ();
  12 use Scalar::Util qw/blessed weaken/;
  13 use Try::Tiny;
  14 use Storable qw/nfreeze thaw/;
  15
  16 # not importing first() as it will clash with our own method
  17 use List::Util ();
  18
  19 use namespace::clean;
  20
  21
  22 BEGIN {
  23   # De-duplication in _merge_attr() is disabled, but left in for reference
  24   # (the merger is used for other things that ought not to be de-duped)
  25   *__HM_DEDUP = sub () { 0 };
  26 }
  27
  28 use overload
  29         '0+'     => "count",
  30         'bool'   => "_bool",
  31         fallback => 1;
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  34
  35 =head1 NAME
  36
  37 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  38
  39 =head1 SYNOPSIS
  40
  41   my $users_rs   = $schema->resultset('User');
  42   while( $user = $users_rs->next) {
  43     print $user->username;
  44   }
  45
  46   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  47   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  48
  49 =head1 DESCRIPTION
  50
  51 A ResultSet is an object which stores a set of conditions representing
  52 a query. It is the backbone of DBIx::Class (i.e. the really
  53 important/useful bit).
  54
  55 No SQL is executed on the database when a ResultSet is created, it
  56 just stores all the conditions needed to create the query.
  57
  58 A basic ResultSet representing the data of an entire table is returned
  59 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  60 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  61
  62   my $users_rs = $schema->resultset('User');
  63
  64 A new ResultSet is returned from calling L</search> on an existing
  65 ResultSet. The new one will contain all the conditions of the
  66 original, plus any new conditions added in the C<search> call.
  67
  68 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  69 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  70 represents.
  71
  72 The query that the ResultSet represents is B<only> executed against
  73 the database when these methods are called:
  74 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  75
  76 If a resultset is used in a numeric context it returns the L</count>.
  77 However, if it is used in a boolean context it is B<always> true.  So if
  78 you want to check if a resultset has any results, you must use C<if $rs
  79 != 0>.
  80
  81 =head1 EXAMPLES
  82
  83 =head2 Chaining resultsets
  84
  85 Let's say you've got a query that needs to be run to return some data
  86 to the user. But, you have an authorization system in place that
  87 prevents certain users from seeing certain information. So, you want
  88 to construct the basic query in one method, but add constraints to it in
  89 another.
  90
  91   sub get_data {
  92     my $self = shift;
  93     my $request = $self->get_request; # Get a request object somehow.
  94     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  95
  96     my $cd_rs = $schema->resultset('CD')->search({
  97       title => $request->param('title'),
  98       year => $request->param('year'),
  99     });
 100
 101     $self->apply_security_policy( $cd_rs );
 102
 103     return $cd_rs->all();
 104   }
 105
 106   sub apply_security_policy {
 107     my $self = shift;
 108     my ($rs) = @_;
 109
 110     return $rs->search({
 111       subversive => 0,
 112     });
 113   }
 114
 115 =head3 Resolving conditions and attributes
 116
 117 When a resultset is chained from another resultset, conditions and
 118 attributes with the same keys need resolving.
 119
 120 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 121 into the existing ones from the original resultset.
 122
 123 The L</where> and L</having> attributes, and any search conditions, are
 124 merged with an SQL C<AND> to the existing condition from the original
 125 resultset.
 126
 127 All other attributes are overridden by any new ones supplied in the
 128 search attributes.
 129
 130 =head2 Multiple queries
 131
 132 Since a resultset just defines a query, you can do all sorts of
 133 things with it with the same object.
 134
 135   # Don't hit the DB yet.
 136   my $cd_rs = $schema->resultset('CD')->search({
 137     title => 'something',
 138     year => 2009,
 139   });
 140
 141   # Each of these hits the DB individually.
 142   my $count = $cd_rs->count;
 143   my $most_recent = $cd_rs->get_column('date_released')->max();
 144   my @records = $cd_rs->all;
 145
 146 And it's not just limited to SELECT statements.
 147
 148   $cd_rs->delete();
 149
 150 This is even cooler:
 151
 152   $cd_rs->create({ artist => 'Fred' });
 153
 154 Which is the same as:
 155
 156   $schema->resultset('CD')->create({
 157     title => 'something',
 158     year => 2009,
 159     artist => 'Fred'
 160   });
 161
 162 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 163
 164 =head1 METHODS
 165
 166 =head2 new
 167
 168 =over 4
 169
 170 =item Arguments: $source, \%$attrs
 171
 172 =item Return Value: $rs
 173
 174 =back
 175
 176 The resultset constructor. Takes a source object (usually a
 177 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 178 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 179 executed as needed by the other methods.
 180
 181 Generally you won't need to construct a resultset manually.  You'll
 182 automatically get one from e.g. a L</search> called in scalar context:
 183
 184   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 185
 186 IMPORTANT: If called on an object, proxies to new_result instead so
 187
 188   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 189
 190 will return a CD object, not a ResultSet.
 191
 192 =cut
 193
 194 sub new {
 195   my $class = shift;
 196   return $class->new_result(@_) if ref $class;
 197
 198   my ($source, $attrs) = @_;
 199   $source = $source->resolve
 200     if $source->isa('DBIx::Class::ResultSourceHandle');
 201   $attrs = { %{$attrs||{}} };
 202
 203   if ($attrs->{page}) {
 204     $attrs->{rows} ||= 10;
 205   }
 206
 207   $attrs->{alias} ||= 'me';
 208
 209   my $self = bless {
 210     result_source => $source,
 211     cond => $attrs->{where},
 212     pager => undef,
 213     attrs => $attrs,
 214   }, $class;
 215
 216   $self->result_class(
 217     $attrs->{result_class} || $source->result_class
 218   );
 219
 220   $self;
 221 }
 222
 223 =head2 search
 224
 225 =over 4
 226
 227 =item Arguments: $cond, \%attrs?
 228
 229 =item Return Value: $resultset (scalar context), @row_objs (list context)
 230
 231 =back
 232
 233   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 234   my $new_rs = $cd_rs->search({ year => 2005 });
 235
 236   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 237                  # year = 2005 OR year = 2004
 238
 239 If you need to pass in additional attributes but no additional condition,
 240 call it as C<search(undef, \%attrs)>.
 241
 242   # "SELECT name, artistid FROM $artist_table"
 243   my @all_artists = $schema->resultset('Artist')->search(undef, {
 244     columns => [qw/name artistid/],
 245   });
 246
 247 For a list of attributes that can be passed to C<search>, see
 248 L</ATTRIBUTES>. For more examples of using this function, see
 249 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 250 documentation for the first argument, see L<SQL::Abstract>.
 251
 252 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 253
 254 =head3 CAVEAT
 255
 256 Note that L</search> does not process/deflate any of the values passed in the
 257 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 258 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 259 manually that any value passed to this method will stringify to something the
 260 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 261 objects, for more info see:
 262 L<DBIx::Class::Manual::Cookbook/Formatting_DateTime_objects_in_queries>.
 263
 264 =cut
 265
 266 sub search {
 267   my $self = shift;
 268   my $rs = $self->search_rs( @_ );
 269
 270   if (wantarray) {
 271     return $rs->all;
 272   }
 273   elsif (defined wantarray) {
 274     return $rs;
 275   }
 276   else {
 277     # we can be called by a relationship helper, which in
 278     # turn may be called in void context due to some braindead
 279     # overload or whatever else the user decided to be clever
 280     # at this particular day. Thus limit the exception to
 281     # external code calls only
 282     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 283       if (caller)[0] !~ /^\QDBIx::Class::/;
 284
 285     return ();
 286   }
 287 }
 288
 289 =head2 search_rs
 290
 291 =over 4
 292
 293 =item Arguments: $cond, \%attrs?
 294
 295 =item Return Value: $resultset
 296
 297 =back
 298
 299 This method does the same exact thing as search() except it will
 300 always return a resultset, even in list context.
 301
 302 =cut
 303
 304 my $callsites_warned;
 305 sub search_rs {
 306   my $self = shift;
 307
 308   # Special-case handling for (undef, undef).
 309   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 310     @_ = ();
 311   }
 312
 313   my $call_attrs = {};
 314   if (@_ > 1) {
 315     if (ref $_[-1] eq 'HASH') {
 316       # copy for _normalize_selection
 317       $call_attrs = { %{ pop @_ } };
 318     }
 319     elsif (! defined $_[-1] ) {
 320       pop @_;   # search({}, undef)
 321     }
 322   }
 323
 324   # see if we can keep the cache (no $rs changes)
 325   my $cache;
 326   my %safe = (alias => 1, cache => 1);
 327   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 328     ! defined $_[0]
 329       or
 330     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 331       or
 332     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 333   )) {
 334     $cache = $self->get_cache;
 335   }
 336
 337   my $rsrc = $self->result_source;
 338
 339   my $old_attrs = { %{$self->{attrs}} };
 340   my $old_having = delete $old_attrs->{having};
 341   my $old_where = delete $old_attrs->{where};
 342
 343   my $new_attrs = { %$old_attrs };
 344
 345   # take care of call attrs (only if anything is changing)
 346   if (keys %$call_attrs) {
 347
 348     $self->throw_exception ('_trailing_select is not a public attribute - do not use it in search()')
 349       if ( exists $call_attrs->{_trailing_select} or exists $call_attrs->{'+_trailing_select'} );
 350
 351     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns _trailing_select +_trailing_select/;
 352
 353     # Normalize the selector list (operates on the passed-in attr structure)
 354     # Need to do it on every chain instead of only once on _resolved_attrs, in
 355     # order to separate 'as'-ed from blind 'select's
 356     $self->_normalize_selection ($call_attrs);
 357
 358     # start with blind overwriting merge, exclude selector attrs
 359     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 360     delete @{$new_attrs}{@selector_attrs};
 361
 362     # reset the current selector list if new selectors are supplied
 363     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 364       delete @{$old_attrs}{@selector_attrs};
 365     }
 366
 367     for (@selector_attrs) {
 368       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 369         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 370     }
 371
 372     # older deprecated name, use only if {columns} is not there
 373     if (my $c = delete $new_attrs->{cols}) {
 374       if ($new_attrs->{columns}) {
 375         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 376       }
 377       else {
 378         $new_attrs->{columns} = $c;
 379       }
 380     }
 381
 382
 383     # join/prefetch use their own crazy merging heuristics
 384     foreach my $key (qw/join prefetch/) {
 385       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 386         if exists $call_attrs->{$key};
 387     }
 388
 389     # stack binds together
 390     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 391   }
 392
 393
 394   # rip apart the rest of @_, parse a condition
 395   my $call_cond = do {
 396
 397     if (ref $_[0] eq 'HASH') {
 398       (keys %{$_[0]}) ? $_[0] : undef
 399     }
 400     elsif (@_ == 1) {
 401       $_[0]
 402     }
 403     elsif (@_ % 2) {
 404       $self->throw_exception('Odd number of arguments to search')
 405     }
 406     else {
 407       +{ @_ }
 408     }
 409
 410   } if @_;
 411
 412   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 413     # determine callsite obeying Carp::Clan rules (fucking ugly but don't have better ideas)
 414     my $callsite = do {
 415       my $w;
 416       local $SIG{__WARN__} = sub { $w = shift };
 417       carp;
 418       $w
 419     };
 420     carp 'search( %condition ) is deprecated, use search( \%condition ) instead'
 421       unless $callsites_warned->{$callsite}++;
 422   }
 423
 424   for ($old_where, $call_cond) {
 425     if (defined $_) {
 426       $new_attrs->{where} = $self->_stack_cond (
 427         $_, $new_attrs->{where}
 428       );
 429     }
 430   }
 431
 432   if (defined $old_having) {
 433     $new_attrs->{having} = $self->_stack_cond (
 434       $old_having, $new_attrs->{having}
 435     )
 436   }
 437
 438   my $rs = (ref $self)->new($rsrc, $new_attrs);
 439
 440   $rs->set_cache($cache) if ($cache);
 441
 442   return $rs;
 443 }
 444
 445 sub _normalize_selection {
 446   my ($self, $attrs) = @_;
 447
 448   # legacy syntax
 449   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 450     if exists $attrs->{include_columns};
 451
 452   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 453   # delay the decision on whether to use a default select list ($rsrc->columns)
 454   # allowing stuff like the remove_columns helper to work
 455   #
 456   # select/as +select/+as pairs need special handling - the amount of select/as
 457   # elements in each pair does *not* have to be equal (think multicolumn
 458   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 459   # supplied at all) - try to infer the alias, either from the -as parameter
 460   # of the selector spec, or use the parameter whole if it looks like a column
 461   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 462   # is ok as well), but transport it over a separate attribute to make sure it is
 463   # the last thing in the select list, thus unable to throw off the corresponding
 464   # 'as' chain
 465   for my $pref ('', '+') {
 466
 467     my ($sel, $as) = map {
 468       my $key = "${pref}${_}";
 469
 470       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 471         ? @{$attrs->{$key}}
 472         : $attrs->{$key} || ()
 473       ];
 474       delete $attrs->{$key};
 475       $val;
 476     } qw/select as/;
 477
 478     if (! @$as and ! @$sel ) {
 479       next;
 480     }
 481     elsif (@$as and ! @$sel) {
 482       $self->throw_exception(
 483         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 484       );
 485     }
 486     elsif( ! @$as ) {
 487       # no as part supplied at all - try to deduce
 488       # if any @$as has been supplied we assume the user knows what (s)he is doing
 489       # and blindly keep stacking up pieces
 490       my (@new_sel, @new_trailing);
 491       for (@$sel) {
 492         if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 493           push @$as, $_->{-as};
 494           push @new_sel, $_;
 495         }
 496         # assume any plain no-space, no-parenthesis string to be a column spec
 497         # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 498         elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 499           push @$as, $_;
 500           push @new_sel, $_;
 501         }
 502         # if all else fails - shove the selection to the trailing stack and move on
 503         else {
 504           push @new_trailing, $_;
 505         }
 506       }
 507
 508       @$sel = @new_sel;
 509       $attrs->{"${pref}_trailing_select"} = $self->_merge_attr($attrs->{"${pref}_trailing_select"}, \@new_trailing)
 510         if @new_trailing;
 511     }
 512     elsif (@$as < @$sel) {
 513       $self->throw_exception(
 514         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 515       );
 516     }
 517
 518     # now see what the result for this pair looks like:
 519     if (@$as == @$sel) {
 520
 521       # if balanced - treat as a columns entry
 522       $attrs->{"${pref}columns"} = $self->_merge_attr(
 523         $attrs->{"${pref}columns"},
 524         [ map { +{ $as->[$_] => $sel->[$_] } } ( 0 .. $#$as ) ]
 525       );
 526     }
 527     else {
 528       # unbalanced - shove in select/as, not subject to deduplication in _resolved_attrs
 529       $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 530       $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 531     }
 532   }
 533
 534 }
 535
 536 sub _stack_cond {
 537   my ($self, $left, $right) = @_;
 538   if (defined $left xor defined $right) {
 539     return defined $left ? $left : $right;
 540   }
 541   elsif (defined $left) {
 542     return { -and => [ map
 543       { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 544       ($left, $right)
 545     ]};
 546   }
 547
 548   return undef;
 549 }
 550
 551 =head2 search_literal
 552
 553 =over 4
 554
 555 =item Arguments: $sql_fragment, @bind_values
 556
 557 =item Return Value: $resultset (scalar context), @row_objs (list context)
 558
 559 =back
 560
 561   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 562   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 563
 564 Pass a literal chunk of SQL to be added to the conditional part of the
 565 resultset query.
 566
 567 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 568 only be used in that context. C<search_literal> is a convenience method.
 569 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 570 columns are bound correctly, use C<search>.
 571
 572 Example of how to use C<search> instead of C<search_literal>
 573
 574   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 575   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 576
 577
 578 See L<DBIx::Class::Manual::Cookbook/Searching> and
 579 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 580 require C<search_literal>.
 581
 582 =cut
 583
 584 sub search_literal {
 585   my ($self, $sql, @bind) = @_;
 586   my $attr;
 587   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 588     $attr = pop @bind;
 589   }
 590   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 591 }
 592
 593 =head2 find
 594
 595 =over 4
 596
 597 =item Arguments: \%columns_values | @pk_values, \%attrs?
 598
 599 =item Return Value: $row_object | undef
 600
 601 =back
 602
 603 Finds and returns a single row based on supplied criteria. Takes either a
 604 hashref with the same format as L</create> (including inference of foreign
 605 keys from related objects), or a list of primary key values in the same
 606 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 607 declaration on the L</result_source>.
 608
 609 In either case an attempt is made to combine conditions already existing on
 610 the resultset with the condition passed to this method.
 611
 612 To aid with preparing the correct query for the storage you may supply the
 613 C<key> attribute, which is the name of a
 614 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 615 unique constraint corresponding to the
 616 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 617 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 618 to construct a query that satisfies the named unique constraint fully (
 619 non-NULL values for each column member of the constraint) an exception is
 620 thrown.
 621
 622 If no C<key> is specified, the search is carried over all unique constraints
 623 which are fully defined by the available condition.
 624
 625 If no such constraint is found, C<find> currently defaults to a simple
 626 C<< search->(\%column_values) >> which may or may not do what you expect.
 627 Note that this fallback behavior may be deprecated in further versions. If
 628 you need to search with arbitrary conditions - use L</search>. If the query
 629 resulting from this fallback produces more than one row, a warning to the
 630 effect is issued, though only the first row is constructed and returned as
 631 C<$row_object>.
 632
 633 In addition to C<key>, L</find> recognizes and applies standard
 634 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 635
 636 Note that if you have extra concerns about the correctness of the resulting
 637 query you need to specify the C<key> attribute and supply the entire condition
 638 as an argument to find (since it is not always possible to perform the
 639 combination of the resultset condition with the supplied one, especially if
 640 the resultset condition contains literal sql).
 641
 642 For example, to find a row by its primary key:
 643
 644   my $cd = $schema->resultset('CD')->find(5);
 645
 646 You can also find a row by a specific unique constraint:
 647
 648   my $cd = $schema->resultset('CD')->find(
 649     {
 650       artist => 'Massive Attack',
 651       title  => 'Mezzanine',
 652     },
 653     { key => 'cd_artist_title' }
 654   );
 655
 656 See also L</find_or_create> and L</update_or_create>.
 657
 658 =cut
 659
 660 sub find {
 661   my $self = shift;
 662   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 663
 664   my $rsrc = $self->result_source;
 665
 666   # Parse out the condition from input
 667   my $call_cond;
 668   if (ref $_[0] eq 'HASH') {
 669     $call_cond = { %{$_[0]} };
 670   }
 671   else {
 672     my $constraint = exists $attrs->{key} ? $attrs->{key} : 'primary';
 673     my @c_cols = $rsrc->unique_constraint_columns($constraint);
 674
 675     $self->throw_exception(
 676       "No constraint columns, maybe a malformed '$constraint' constraint?"
 677     ) unless @c_cols;
 678
 679     $self->throw_exception (
 680       'find() expects either a column/value hashref, or a list of values '
 681     . "corresponding to the columns of the specified unique constraint '$constraint'"
 682     ) unless @c_cols == @_;
 683
 684     $call_cond = {};
 685     @{$call_cond}{@c_cols} = @_;
 686   }
 687
 688   my %related;
 689   for my $key (keys %$call_cond) {
 690     if (
 691       my $keyref = ref($call_cond->{$key})
 692         and
 693       my $relinfo = $rsrc->relationship_info($key)
 694     ) {
 695       my $val = delete $call_cond->{$key};
 696
 697       next if $keyref eq 'ARRAY'; # has_many for multi_create
 698
 699       my $rel_q = $rsrc->_resolve_condition(
 700         $relinfo->{cond}, $val, $key
 701       );
 702       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 703       @related{keys %$rel_q} = values %$rel_q;
 704     }
 705   }
 706
 707   # relationship conditions take precedence (?)
 708   @{$call_cond}{keys %related} = values %related;
 709
 710   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 711   my $final_cond;
 712   if (exists $attrs->{key}) {
 713     $final_cond = $self->_qualify_cond_columns (
 714
 715       $self->_build_unique_cond (
 716         $attrs->{key},
 717         $call_cond,
 718       ),
 719
 720       $alias,
 721     );
 722   }
 723   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 724     # This means that we got here after a merger of relationship conditions
 725     # in ::Relationship::Base::search_related (the row method), and furthermore
 726     # the relationship is of the 'single' type. This means that the condition
 727     # provided by the relationship (already attached to $self) is sufficient,
 728     # as there can be only one row in the database that would satisfy the
 729     # relationship
 730   }
 731   else {
 732     # no key was specified - fall down to heuristics mode:
 733     # run through all unique queries registered on the resultset, and
 734     # 'OR' all qualifying queries together
 735     my (@unique_queries, %seen_column_combinations);
 736     for my $c_name ($rsrc->unique_constraint_names) {
 737       next if $seen_column_combinations{
 738         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 739       }++;
 740
 741       push @unique_queries, try {
 742         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 743       } || ();
 744     }
 745
 746     $final_cond = @unique_queries
 747       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 748       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 749     ;
 750   }
 751
 752   # Run the query, passing the result_class since it should propagate for find
 753   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 754   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 755     my $row = $rs->next;
 756     carp "Query returned more than one row" if $rs->next;
 757     return $row;
 758   }
 759   else {
 760     return $rs->single;
 761   }
 762 }
 763
 764 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 765 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 766 #
 767 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 768 # condition. It is provided for overrides until a saner way forward is devised
 769 #
 770 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 771 # the road. Please adjust your tests accordingly to catch this situation early
 772 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 773 #
 774 # The method will not be removed without an adequately complete replacement
 775 # for strict-mode enforcement
 776 sub _non_unique_find_fallback {
 777   my ($self, $cond, $attrs) = @_;
 778
 779   return $self->_qualify_cond_columns(
 780     $cond,
 781     exists $attrs->{alias}
 782       ? $attrs->{alias}
 783       : $self->{attrs}{alias}
 784   );
 785 }
 786
 787
 788 sub _qualify_cond_columns {
 789   my ($self, $cond, $alias) = @_;
 790
 791   my %aliased = %$cond;
 792   for (keys %aliased) {
 793     $aliased{"$alias.$_"} = delete $aliased{$_}
 794       if $_ !~ /\./;
 795   }
 796
 797   return \%aliased;
 798 }
 799
 800 my $callsites_warned_ucond;
 801 sub _build_unique_cond {
 802   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 803
 804   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 805
 806   # combination may fail if $self->{cond} is non-trivial
 807   my ($final_cond) = try {
 808     $self->_merge_with_rscond ($extra_cond)
 809   } catch {
 810     +{ %$extra_cond }
 811   };
 812
 813   # trim out everything not in $columns
 814   $final_cond = { map {
 815     exists $final_cond->{$_}
 816       ? ( $_ => $final_cond->{$_} )
 817       : ()
 818   } @c_cols };
 819
 820   if (my @missing = grep
 821     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 822     (@c_cols)
 823   ) {
 824     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 825       $constraint_name,
 826       join (', ', map { "'$_'" } @missing),
 827     ) );
 828   }
 829
 830   if (
 831     !$croak_on_null
 832       and
 833     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 834       and
 835     my @undefs = grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 836   ) {
 837     my $callsite = do {
 838       my $w;
 839       local $SIG{__WARN__} = sub { $w = shift };
 840       carp;
 841       $w
 842     };
 843
 844     carp ( sprintf (
 845       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 846     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 847     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 848       $constraint_name,
 849       join (', ', map { "'$_'" } @undefs),
 850     )) unless $callsites_warned_ucond->{$callsite}++;
 851   }
 852
 853   return $final_cond;
 854 }
 855
 856 =head2 search_related
 857
 858 =over 4
 859
 860 =item Arguments: $rel, $cond, \%attrs?
 861
 862 =item Return Value: $new_resultset
 863
 864 =back
 865
 866   $new_rs = $cd_rs->search_related('artist', {
 867     name => 'Emo-R-Us',
 868   });
 869
 870 Searches the specified relationship, optionally specifying a condition and
 871 attributes for matching records. See L</ATTRIBUTES> for more information.
 872
 873 =cut
 874
 875 sub search_related {
 876   return shift->related_resultset(shift)->search(@_);
 877 }
 878
 879 =head2 search_related_rs
 880
 881 This method works exactly the same as search_related, except that
 882 it guarantees a resultset, even in list context.
 883
 884 =cut
 885
 886 sub search_related_rs {
 887   return shift->related_resultset(shift)->search_rs(@_);
 888 }
 889
 890 =head2 cursor
 891
 892 =over 4
 893
 894 =item Arguments: none
 895
 896 =item Return Value: $cursor
 897
 898 =back
 899
 900 Returns a storage-driven cursor to the given resultset. See
 901 L<DBIx::Class::Cursor> for more information.
 902
 903 =cut
 904
 905 sub cursor {
 906   my ($self) = @_;
 907
 908   my $attrs = $self->_resolved_attrs_copy;
 909
 910   return $self->{cursor}
 911     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 912           $attrs->{where},$attrs);
 913 }
 914
 915 =head2 single
 916
 917 =over 4
 918
 919 =item Arguments: $cond?
 920
 921 =item Return Value: $row_object | undef
 922
 923 =back
 924
 925   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 926
 927 Inflates the first result without creating a cursor if the resultset has
 928 any records in it; if not returns C<undef>. Used by L</find> as a lean version
 929 of L</search>.
 930
 931 While this method can take an optional search condition (just like L</search>)
 932 being a fast-code-path it does not recognize search attributes. If you need to
 933 add extra joins or similar, call L</search> and then chain-call L</single> on the
 934 L<DBIx::Class::ResultSet> returned.
 935
 936 =over
 937
 938 =item B<Note>
 939
 940 As of 0.08100, this method enforces the assumption that the preceding
 941 query returns only one row. If more than one row is returned, you will receive
 942 a warning:
 943
 944   Query returned more than one row
 945
 946 In this case, you should be using L</next> or L</find> instead, or if you really
 947 know what you are doing, use the L</rows> attribute to explicitly limit the size
 948 of the resultset.
 949
 950 This method will also throw an exception if it is called on a resultset prefetching
 951 has_many, as such a prefetch implies fetching multiple rows from the database in
 952 order to assemble the resulting object.
 953
 954 =back
 955
 956 =cut
 957
 958 sub single {
 959   my ($self, $where) = @_;
 960   if(@_ > 2) {
 961       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 962   }
 963
 964   my $attrs = $self->_resolved_attrs_copy;
 965
 966   if (keys %{$attrs->{collapse}}) {
 967     $self->throw_exception(
 968       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 969     );
 970   }
 971
 972   if ($where) {
 973     if (defined $attrs->{where}) {
 974       $attrs->{where} = {
 975         '-and' =>
 976             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 977                $where, delete $attrs->{where} ]
 978       };
 979     } else {
 980       $attrs->{where} = $where;
 981     }
 982   }
 983
 984   my @data = $self->result_source->storage->select_single(
 985     $attrs->{from}, $attrs->{select},
 986     $attrs->{where}, $attrs
 987   );
 988
 989   return (@data ? ($self->_construct_object(@data))[0] : undef);
 990 }
 991
 992
 993 # _collapse_query
 994 #
 995 # Recursively collapse the query, accumulating values for each column.
 996
 997 sub _collapse_query {
 998   my ($self, $query, $collapsed) = @_;
 999
1000   $collapsed ||= {};
1001
1002   if (ref $query eq 'ARRAY') {
1003     foreach my $subquery (@$query) {
1004       next unless ref $subquery;  # -or
1005       $collapsed = $self->_collapse_query($subquery, $collapsed);
1006     }
1007   }
1008   elsif (ref $query eq 'HASH') {
1009     if (keys %$query and (keys %$query)[0] eq '-and') {
1010       foreach my $subquery (@{$query->{-and}}) {
1011         $collapsed = $self->_collapse_query($subquery, $collapsed);
1012       }
1013     }
1014     else {
1015       foreach my $col (keys %$query) {
1016         my $value = $query->{$col};
1017         $collapsed->{$col}{$value}++;
1018       }
1019     }
1020   }
1021
1022   return $collapsed;
1023 }
1024
1025 =head2 get_column
1026
1027 =over 4
1028
1029 =item Arguments: $cond?
1030
1031 =item Return Value: $resultsetcolumn
1032
1033 =back
1034
1035   my $max_length = $rs->get_column('length')->max;
1036
1037 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1038
1039 =cut
1040
1041 sub get_column {
1042   my ($self, $column) = @_;
1043   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1044   return $new;
1045 }
1046
1047 =head2 search_like
1048
1049 =over 4
1050
1051 =item Arguments: $cond, \%attrs?
1052
1053 =item Return Value: $resultset (scalar context), @row_objs (list context)
1054
1055 =back
1056
1057   # WHERE title LIKE '%blue%'
1058   $cd_rs = $rs->search_like({ title => '%blue%'});
1059
1060 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1061 that this is simply a convenience method retained for ex Class::DBI users.
1062 You most likely want to use L</search> with specific operators.
1063
1064 For more information, see L<DBIx::Class::Manual::Cookbook>.
1065
1066 This method is deprecated and will be removed in 0.09. Use L</search()>
1067 instead. An example conversion is:
1068
1069   ->search_like({ foo => 'bar' });
1070
1071   # Becomes
1072
1073   ->search({ foo => { like => 'bar' } });
1074
1075 =cut
1076
1077 sub search_like {
1078   my $class = shift;
1079   carp (
1080     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1081    .' Instead use ->search({ x => { -like => "y%" } })'
1082    .' (note the outer pair of {}s - they are important!)'
1083   );
1084   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1085   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1086   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1087   return $class->search($query, { %$attrs });
1088 }
1089
1090 =head2 slice
1091
1092 =over 4
1093
1094 =item Arguments: $first, $last
1095
1096 =item Return Value: $resultset (scalar context), @row_objs (list context)
1097
1098 =back
1099
1100 Returns a resultset or object list representing a subset of elements from the
1101 resultset slice is called on. Indexes are from 0, i.e., to get the first
1102 three records, call:
1103
1104   my ($one, $two, $three) = $rs->slice(0, 2);
1105
1106 =cut
1107
1108 sub slice {
1109   my ($self, $min, $max) = @_;
1110   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1111   $attrs->{offset} = $self->{attrs}{offset} || 0;
1112   $attrs->{offset} += $min;
1113   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1114   return $self->search(undef, $attrs);
1115   #my $slice = (ref $self)->new($self->result_source, $attrs);
1116   #return (wantarray ? $slice->all : $slice);
1117 }
1118
1119 =head2 next
1120
1121 =over 4
1122
1123 =item Arguments: none
1124
1125 =item Return Value: $result | undef
1126
1127 =back
1128
1129 Returns the next element in the resultset (C<undef> is there is none).
1130
1131 Can be used to efficiently iterate over records in the resultset:
1132
1133   my $rs = $schema->resultset('CD')->search;
1134   while (my $cd = $rs->next) {
1135     print $cd->title;
1136   }
1137
1138 Note that you need to store the resultset object, and call C<next> on it.
1139 Calling C<< resultset('Table')->next >> repeatedly will always return the
1140 first record from the resultset.
1141
1142 =cut
1143
1144 sub next {
1145   my ($self) = @_;
1146   if (my $cache = $self->get_cache) {
1147     $self->{all_cache_position} ||= 0;
1148     return $cache->[$self->{all_cache_position}++];
1149   }
1150   if ($self->{attrs}{cache}) {
1151     delete $self->{pager};
1152     $self->{all_cache_position} = 1;
1153     return ($self->all)[0];
1154   }
1155   if ($self->{stashed_objects}) {
1156     my $obj = shift(@{$self->{stashed_objects}});
1157     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1158     return $obj;
1159   }
1160   my @row = (
1161     exists $self->{stashed_row}
1162       ? @{delete $self->{stashed_row}}
1163       : $self->cursor->next
1164   );
1165   return undef unless (@row);
1166   my ($row, @more) = $self->_construct_object(@row);
1167   $self->{stashed_objects} = \@more if @more;
1168   return $row;
1169 }
1170
1171 sub _construct_object {
1172   my ($self, @row) = @_;
1173
1174   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1175     or return ();
1176   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1177   @new = $self->{_attrs}{record_filter}->(@new)
1178     if exists $self->{_attrs}{record_filter};
1179   return @new;
1180 }
1181
1182 sub _collapse_result {
1183   my ($self, $as_proto, $row) = @_;
1184
1185   my @copy = @$row;
1186
1187   # 'foo'         => [ undef, 'foo' ]
1188   # 'foo.bar'     => [ 'foo', 'bar' ]
1189   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1190
1191   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1192
1193   my %collapse = %{$self->{_attrs}{collapse}||{}};
1194
1195   my @pri_index;
1196
1197   # if we're doing collapsing (has_many prefetch) we need to grab records
1198   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1199   # we know we don't have to bother.
1200
1201   # the reason for not using the collapse stuff directly is because if you
1202   # had for e.g. two artists in a row with no cds, the collapse info for
1203   # both would be NULL (undef) so you'd lose the second artist
1204
1205   # store just the index so we can check the array positions from the row
1206   # without having to contruct the full hash
1207
1208   if (keys %collapse) {
1209     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1210     foreach my $i (0 .. $#construct_as) {
1211       next if defined($construct_as[$i][0]); # only self table
1212       if (delete $pri{$construct_as[$i][1]}) {
1213         push(@pri_index, $i);
1214       }
1215       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1216     }
1217   }
1218
1219   # no need to do an if, it'll be empty if @pri_index is empty anyway
1220
1221   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1222
1223   my @const_rows;
1224
1225   do { # no need to check anything at the front, we always want the first row
1226
1227     my %const;
1228
1229     foreach my $this_as (@construct_as) {
1230       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1231     }
1232
1233     push(@const_rows, \%const);
1234
1235   } until ( # no pri_index => no collapse => drop straight out
1236       !@pri_index
1237     or
1238       do { # get another row, stash it, drop out if different PK
1239
1240         @copy = $self->cursor->next;
1241         $self->{stashed_row} = \@copy;
1242
1243         # last thing in do block, counts as true if anything doesn't match
1244
1245         # check xor defined first for NULL vs. NOT NULL then if one is
1246         # defined the other must be so check string equality
1247
1248         grep {
1249           (defined $pri_vals{$_} ^ defined $copy[$_])
1250           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1251         } @pri_index;
1252       }
1253   );
1254
1255   my $alias = $self->{attrs}{alias};
1256   my $info = [];
1257
1258   my %collapse_pos;
1259
1260   my @const_keys;
1261
1262   foreach my $const (@const_rows) {
1263     scalar @const_keys or do {
1264       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1265     };
1266     foreach my $key (@const_keys) {
1267       if (length $key) {
1268         my $target = $info;
1269         my @parts = split(/\./, $key);
1270         my $cur = '';
1271         my $data = $const->{$key};
1272         foreach my $p (@parts) {
1273           $target = $target->[1]->{$p} ||= [];
1274           $cur .= ".${p}";
1275           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1276             # collapsing at this point and on final part
1277             my $pos = $collapse_pos{$cur};
1278             CK: foreach my $ck (@ckey) {
1279               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1280                 $collapse_pos{$cur} = $data;
1281                 delete @collapse_pos{ # clear all positioning for sub-entries
1282                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1283                 };
1284                 push(@$target, []);
1285                 last CK;
1286               }
1287             }
1288           }
1289           if (exists $collapse{$cur}) {
1290             $target = $target->[-1];
1291           }
1292         }
1293         $target->[0] = $data;
1294       } else {
1295         $info->[0] = $const->{$key};
1296       }
1297     }
1298   }
1299
1300   return $info;
1301 }
1302
1303 =head2 result_source
1304
1305 =over 4
1306
1307 =item Arguments: $result_source?
1308
1309 =item Return Value: $result_source
1310
1311 =back
1312
1313 An accessor for the primary ResultSource object from which this ResultSet
1314 is derived.
1315
1316 =head2 result_class
1317
1318 =over 4
1319
1320 =item Arguments: $result_class?
1321
1322 =item Return Value: $result_class
1323
1324 =back
1325
1326 An accessor for the class to use when creating row objects. Defaults to
1327 C<< result_source->result_class >> - which in most cases is the name of the
1328 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1329
1330 Note that changing the result_class will also remove any components
1331 that were originally loaded in the source class via
1332 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1333 in the original source class will not run.
1334
1335 =cut
1336
1337 sub result_class {
1338   my ($self, $result_class) = @_;
1339   if ($result_class) {
1340     unless (ref $result_class) { # don't fire this for an object
1341       $self->ensure_class_loaded($result_class);
1342     }
1343     $self->_result_class($result_class);
1344     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1345     # permit the user to set result class on one result set only; it only
1346     # chains if provided to search()
1347     #$self->{attrs}{result_class} = $result_class if ref $self;
1348   }
1349   $self->_result_class;
1350 }
1351
1352 =head2 count
1353
1354 =over 4
1355
1356 =item Arguments: $cond, \%attrs??
1357
1358 =item Return Value: $count
1359
1360 =back
1361
1362 Performs an SQL C<COUNT> with the same query as the resultset was built
1363 with to find the number of elements. Passing arguments is equivalent to
1364 C<< $rs->search ($cond, \%attrs)->count >>
1365
1366 =cut
1367
1368 sub count {
1369   my $self = shift;
1370   return $self->search(@_)->count if @_ and defined $_[0];
1371   return scalar @{ $self->get_cache } if $self->get_cache;
1372
1373   my $attrs = $self->_resolved_attrs_copy;
1374
1375   # this is a little optimization - it is faster to do the limit
1376   # adjustments in software, instead of a subquery
1377   my $rows = delete $attrs->{rows};
1378   my $offset = delete $attrs->{offset};
1379
1380   my $crs;
1381   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1382     $crs = $self->_count_subq_rs ($attrs);
1383   }
1384   else {
1385     $crs = $self->_count_rs ($attrs);
1386   }
1387   my $count = $crs->next;
1388
1389   $count -= $offset if $offset;
1390   $count = $rows if $rows and $rows < $count;
1391   $count = 0 if ($count < 0);
1392
1393   return $count;
1394 }
1395
1396 =head2 count_rs
1397
1398 =over 4
1399
1400 =item Arguments: $cond, \%attrs??
1401
1402 =item Return Value: $count_rs
1403
1404 =back
1405
1406 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1407 This can be very handy for subqueries:
1408
1409   ->search( { amount => $some_rs->count_rs->as_query } )
1410
1411 As with regular resultsets the SQL query will be executed only after
1412 the resultset is accessed via L</next> or L</all>. That would return
1413 the same single value obtainable via L</count>.
1414
1415 =cut
1416
1417 sub count_rs {
1418   my $self = shift;
1419   return $self->search(@_)->count_rs if @_;
1420
1421   # this may look like a lack of abstraction (count() does about the same)
1422   # but in fact an _rs *must* use a subquery for the limits, as the
1423   # software based limiting can not be ported if this $rs is to be used
1424   # in a subquery itself (i.e. ->as_query)
1425   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1426     return $self->_count_subq_rs;
1427   }
1428   else {
1429     return $self->_count_rs;
1430   }
1431 }
1432
1433 #
1434 # returns a ResultSetColumn object tied to the count query
1435 #
1436 sub _count_rs {
1437   my ($self, $attrs) = @_;
1438
1439   my $rsrc = $self->result_source;
1440   $attrs ||= $self->_resolved_attrs;
1441
1442   my $tmp_attrs = { %$attrs };
1443   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1444   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1445
1446   # overwrite the selector (supplied by the storage)
1447   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1448   $tmp_attrs->{as} = 'count';
1449   delete @{$tmp_attrs}{qw/columns _trailing_select/};
1450
1451   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1452
1453   return $tmp_rs;
1454 }
1455
1456 #
1457 # same as above but uses a subquery
1458 #
1459 sub _count_subq_rs {
1460   my ($self, $attrs) = @_;
1461
1462   my $rsrc = $self->result_source;
1463   $attrs ||= $self->_resolved_attrs;
1464
1465   my $sub_attrs = { %$attrs };
1466   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1467   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range _trailing_select order_by for/};
1468
1469   # if we multi-prefetch we group_by primary keys only as this is what we would
1470   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1471   if ( keys %{$attrs->{collapse}}  ) {
1472     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1473   }
1474
1475   # Calculate subquery selector
1476   if (my $g = $sub_attrs->{group_by}) {
1477
1478     my $sql_maker = $rsrc->storage->sql_maker;
1479
1480     # necessary as the group_by may refer to aliased functions
1481     my $sel_index;
1482     for my $sel (@{$attrs->{select}}) {
1483       $sel_index->{$sel->{-as}} = $sel
1484         if (ref $sel eq 'HASH' and $sel->{-as});
1485     }
1486
1487     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1488     # also look for named aggregates referred in the having clause
1489     # having often contains scalarrefs - thus parse it out entirely
1490     my @parts = @$g;
1491     if ($attrs->{having}) {
1492       local $sql_maker->{having_bind};
1493       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1494       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1495       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1496         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1497         # if we don't unset it we screw up retarded but unfortunately working
1498         # 'MAX(foo.bar)' => { '>', 3 }
1499         $sql_maker->{name_sep} = '';
1500       }
1501
1502       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1503
1504       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1505
1506       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1507       # and if all fails for an utterly naive quoted scalar-with-function
1508       while ($sql =~ /
1509         $rquote $sep $lquote (.+?) $rquote
1510           |
1511         [\s,] \w+ \. (\w+) [\s,]
1512           |
1513         [\s,] $lquote (.+?) $rquote [\s,]
1514       /gx) {
1515         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1516       }
1517     }
1518
1519     for (@parts) {
1520       my $colpiece = $sel_index->{$_} || $_;
1521
1522       # unqualify join-based group_by's. Arcane but possible query
1523       # also horrible horrible hack to alias a column (not a func.)
1524       # (probably need to introduce SQLA syntax)
1525       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1526         my $as = $colpiece;
1527         $as =~ s/\./__/;
1528         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1529       }
1530       push @{$sub_attrs->{select}}, $colpiece;
1531     }
1532   }
1533   else {
1534     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1535     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1536   }
1537
1538   return $rsrc->resultset_class
1539                ->new ($rsrc, $sub_attrs)
1540                 ->as_subselect_rs
1541                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1542                   ->get_column ('count');
1543 }
1544
1545 sub _bool {
1546   return 1;
1547 }
1548
1549 =head2 count_literal
1550
1551 =over 4
1552
1553 =item Arguments: $sql_fragment, @bind_values
1554
1555 =item Return Value: $count
1556
1557 =back
1558
1559 Counts the results in a literal query. Equivalent to calling L</search_literal>
1560 with the passed arguments, then L</count>.
1561
1562 =cut
1563
1564 sub count_literal { shift->search_literal(@_)->count; }
1565
1566 =head2 all
1567
1568 =over 4
1569
1570 =item Arguments: none
1571
1572 =item Return Value: @objects
1573
1574 =back
1575
1576 Returns all elements in the resultset. Called implicitly if the resultset
1577 is returned in list context.
1578
1579 =cut
1580
1581 sub all {
1582   my $self = shift;
1583   if(@_) {
1584       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1585   }
1586
1587   return @{ $self->get_cache } if $self->get_cache;
1588
1589   my @obj;
1590
1591   if (keys %{$self->_resolved_attrs->{collapse}}) {
1592     # Using $self->cursor->all is really just an optimisation.
1593     # If we're collapsing has_many prefetches it probably makes
1594     # very little difference, and this is cleaner than hacking
1595     # _construct_object to survive the approach
1596     $self->cursor->reset;
1597     my @row = $self->cursor->next;
1598     while (@row) {
1599       push(@obj, $self->_construct_object(@row));
1600       @row = (exists $self->{stashed_row}
1601                ? @{delete $self->{stashed_row}}
1602                : $self->cursor->next);
1603     }
1604   } else {
1605     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1606   }
1607
1608   $self->set_cache(\@obj) if $self->{attrs}{cache};
1609
1610   return @obj;
1611 }
1612
1613 =head2 reset
1614
1615 =over 4
1616
1617 =item Arguments: none
1618
1619 =item Return Value: $self
1620
1621 =back
1622
1623 Resets the resultset's cursor, so you can iterate through the elements again.
1624 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1625 another query.
1626
1627 =cut
1628
1629 sub reset {
1630   my ($self) = @_;
1631   delete $self->{_attrs} if exists $self->{_attrs};
1632   $self->{all_cache_position} = 0;
1633   $self->cursor->reset;
1634   return $self;
1635 }
1636
1637 =head2 first
1638
1639 =over 4
1640
1641 =item Arguments: none
1642
1643 =item Return Value: $object | undef
1644
1645 =back
1646
1647 Resets the resultset and returns an object for the first result (or C<undef>
1648 if the resultset is empty).
1649
1650 =cut
1651
1652 sub first {
1653   return $_[0]->reset->next;
1654 }
1655
1656
1657 # _rs_update_delete
1658 #
1659 # Determines whether and what type of subquery is required for the $rs operation.
1660 # If grouping is necessary either supplies its own, or verifies the current one
1661 # After all is done delegates to the proper storage method.
1662
1663 sub _rs_update_delete {
1664   my ($self, $op, $values) = @_;
1665
1666   my $rsrc = $self->result_source;
1667
1668   # if a condition exists we need to strip all table qualifiers
1669   # if this is not possible we'll force a subquery below
1670   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1671
1672   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1673   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/rows offset/);
1674
1675   if ($needs_group_by_subq or $needs_subq) {
1676
1677     # make a new $rs selecting only the PKs (that's all we really need)
1678     my $attrs = $self->_resolved_attrs_copy;
1679
1680
1681     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1682     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->_pri_cols) ];
1683
1684     if ($needs_group_by_subq) {
1685       # make sure no group_by was supplied, or if there is one - make sure it matches
1686       # the columns compiled above perfectly. Anything else can not be sanely executed
1687       # on most databases so croak right then and there
1688
1689       if (my $g = $attrs->{group_by}) {
1690         my @current_group_by = map
1691           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1692           @$g
1693         ;
1694
1695         if (
1696           join ("\x00", sort @current_group_by)
1697             ne
1698           join ("\x00", sort @{$attrs->{columns}} )
1699         ) {
1700           $self->throw_exception (
1701             "You have just attempted a $op operation on a resultset which does group_by"
1702             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1703             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1704             . ' kind of queries. Please retry the operation with a modified group_by or'
1705             . ' without using one at all.'
1706           );
1707         }
1708       }
1709       else {
1710         $attrs->{group_by} = $attrs->{columns};
1711       }
1712     }
1713
1714     my $subrs = (ref $self)->new($rsrc, $attrs);
1715     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1716   }
1717   else {
1718     return $rsrc->storage->$op(
1719       $rsrc,
1720       $op eq 'update' ? $values : (),
1721       $cond,
1722     );
1723   }
1724 }
1725
1726 =head2 update
1727
1728 =over 4
1729
1730 =item Arguments: \%values
1731
1732 =item Return Value: $storage_rv
1733
1734 =back
1735
1736 Sets the specified columns in the resultset to the supplied values in a
1737 single query. Note that this will not run any accessor/set_column/update
1738 triggers, nor will it update any row object instances derived from this
1739 resultset (this includes the contents of the L<resultset cache|/set_cache>
1740 if any). See L</update_all> if you need to execute any on-update
1741 triggers or cascades defined either by you or a
1742 L<result component|DBIx::Class::Manual::Component/WHAT_IS_A_COMPONENT>.
1743
1744 The return value is a pass through of what the underlying
1745 storage backend returned, and may vary. See L<DBI/execute> for the most
1746 common case.
1747
1748 =head3 CAVEAT
1749
1750 Note that L</update> does not process/deflate any of the values passed in.
1751 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1752 ensure manually that any value passed to this method will stringify to
1753 something the RDBMS knows how to deal with. A notable example is the
1754 handling of L<DateTime> objects, for more info see:
1755 L<DBIx::Class::Manual::Cookbook/Formatting_DateTime_objects_in_queries>.
1756
1757 =cut
1758
1759 sub update {
1760   my ($self, $values) = @_;
1761   $self->throw_exception('Values for update must be a hash')
1762     unless ref $values eq 'HASH';
1763
1764   return $self->_rs_update_delete ('update', $values);
1765 }
1766
1767 =head2 update_all
1768
1769 =over 4
1770
1771 =item Arguments: \%values
1772
1773 =item Return Value: 1
1774
1775 =back
1776
1777 Fetches all objects and updates them one at a time via
1778 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1779 triggers, while L</update> will not.
1780
1781 =cut
1782
1783 sub update_all {
1784   my ($self, $values) = @_;
1785   $self->throw_exception('Values for update_all must be a hash')
1786     unless ref $values eq 'HASH';
1787
1788   my $guard = $self->result_source->schema->txn_scope_guard;
1789   $_->update($values) for $self->all;
1790   $guard->commit;
1791   return 1;
1792 }
1793
1794 =head2 delete
1795
1796 =over 4
1797
1798 =item Arguments: none
1799
1800 =item Return Value: $storage_rv
1801
1802 =back
1803
1804 Deletes the rows matching this resultset in a single query. Note that this
1805 will not run any delete triggers, nor will it alter the
1806 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1807 derived from this resultset (this includes the contents of the
1808 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1809 execute any on-delete triggers or cascades defined either by you or a
1810 L<result component|DBIx::Class::Manual::Component/WHAT_IS_A_COMPONENT>.
1811
1812 The return value is a pass through of what the underlying storage backend
1813 returned, and may vary. See L<DBI/execute> for the most common case.
1814
1815 =cut
1816
1817 sub delete {
1818   my $self = shift;
1819   $self->throw_exception('delete does not accept any arguments')
1820     if @_;
1821
1822   return $self->_rs_update_delete ('delete');
1823 }
1824
1825 =head2 delete_all
1826
1827 =over 4
1828
1829 =item Arguments: none
1830
1831 =item Return Value: 1
1832
1833 =back
1834
1835 Fetches all objects and deletes them one at a time via
1836 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
1837 triggers, while L</delete> will not.
1838
1839 =cut
1840
1841 sub delete_all {
1842   my $self = shift;
1843   $self->throw_exception('delete_all does not accept any arguments')
1844     if @_;
1845
1846   my $guard = $self->result_source->schema->txn_scope_guard;
1847   $_->delete for $self->all;
1848   $guard->commit;
1849   return 1;
1850 }
1851
1852 =head2 populate
1853
1854 =over 4
1855
1856 =item Arguments: \@data;
1857
1858 =back
1859
1860 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1861 For the arrayref of hashrefs style each hashref should be a structure suitable
1862 forsubmitting to a $resultset->create(...) method.
1863
1864 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1865 to insert the data, as this is a faster method.
1866
1867 Otherwise, each set of data is inserted into the database using
1868 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1869 accumulated into an array. The array itself, or an array reference
1870 is returned depending on scalar or list context.
1871
1872 Example:  Assuming an Artist Class that has many CDs Classes relating:
1873
1874   my $Artist_rs = $schema->resultset("Artist");
1875
1876   ## Void Context Example
1877   $Artist_rs->populate([
1878      { artistid => 4, name => 'Manufactured Crap', cds => [
1879         { title => 'My First CD', year => 2006 },
1880         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1881       ],
1882      },
1883      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1884         { title => 'My parents sold me to a record company', year => 2005 },
1885         { title => 'Why Am I So Ugly?', year => 2006 },
1886         { title => 'I Got Surgery and am now Popular', year => 2007 }
1887       ],
1888      },
1889   ]);
1890
1891   ## Array Context Example
1892   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1893     { name => "Artist One"},
1894     { name => "Artist Two"},
1895     { name => "Artist Three", cds=> [
1896     { title => "First CD", year => 2007},
1897     { title => "Second CD", year => 2008},
1898   ]}
1899   ]);
1900
1901   print $ArtistOne->name; ## response is 'Artist One'
1902   print $ArtistThree->cds->count ## reponse is '2'
1903
1904 For the arrayref of arrayrefs style,  the first element should be a list of the
1905 fieldsnames to which the remaining elements are rows being inserted.  For
1906 example:
1907
1908   $Arstist_rs->populate([
1909     [qw/artistid name/],
1910     [100, 'A Formally Unknown Singer'],
1911     [101, 'A singer that jumped the shark two albums ago'],
1912     [102, 'An actually cool singer'],
1913   ]);
1914
1915 Please note an important effect on your data when choosing between void and
1916 wantarray context. Since void context goes straight to C<insert_bulk> in
1917 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1918 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1919 create primary keys for you, you will find that your PKs are empty.  In this
1920 case you will have to use the wantarray context in order to create those
1921 values.
1922
1923 =cut
1924
1925 sub populate {
1926   my $self = shift;
1927
1928   # cruft placed in standalone method
1929   my $data = $self->_normalize_populate_args(@_);
1930
1931   if(defined wantarray) {
1932     my @created;
1933     foreach my $item (@$data) {
1934       push(@created, $self->create($item));
1935     }
1936     return wantarray ? @created : \@created;
1937   }
1938   else {
1939     my $first = $data->[0];
1940
1941     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1942     # it relationship data
1943     my (@rels, @columns);
1944     my $rsrc = $self->result_source;
1945     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
1946     for (keys %$first) {
1947       my $ref = ref $first->{$_};
1948       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
1949         ? push @rels, $_
1950         : push @columns, $_
1951       ;
1952     }
1953
1954     my @pks = $rsrc->primary_columns;
1955
1956     ## do the belongs_to relationships
1957     foreach my $index (0..$#$data) {
1958
1959       # delegate to create() for any dataset without primary keys with specified relationships
1960       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1961         for my $r (@rels) {
1962           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1963             my @ret = $self->populate($data);
1964             return;
1965           }
1966         }
1967       }
1968
1969       foreach my $rel (@rels) {
1970         next unless ref $data->[$index]->{$rel} eq "HASH";
1971         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1972         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
1973         my $related = $result->result_source->_resolve_condition(
1974           $reverse_relinfo->{cond},
1975           $self,
1976           $result,
1977         );
1978
1979         delete $data->[$index]->{$rel};
1980         $data->[$index] = {%{$data->[$index]}, %$related};
1981
1982         push @columns, keys %$related if $index == 0;
1983       }
1984     }
1985
1986     ## inherit the data locked in the conditions of the resultset
1987     my ($rs_data) = $self->_merge_with_rscond({});
1988     delete @{$rs_data}{@columns};
1989     my @inherit_cols = keys %$rs_data;
1990     my @inherit_data = values %$rs_data;
1991
1992     ## do bulk insert on current row
1993     $rsrc->storage->insert_bulk(
1994       $rsrc,
1995       [@columns, @inherit_cols],
1996       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1997     );
1998
1999     ## do the has_many relationships
2000     foreach my $item (@$data) {
2001
2002       my $main_row;
2003
2004       foreach my $rel (@rels) {
2005         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2006
2007         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2008
2009         my $child = $main_row->$rel;
2010
2011         my $related = $child->result_source->_resolve_condition(
2012           $rels->{$rel}{cond},
2013           $child,
2014           $main_row,
2015         );
2016
2017         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2018         my @populate = map { {%$_, %$related} } @rows_to_add;
2019
2020         $child->populate( \@populate );
2021       }
2022     }
2023   }
2024 }
2025
2026
2027 # populate() argumnets went over several incarnations
2028 # What we ultimately support is AoH
2029 sub _normalize_populate_args {
2030   my ($self, $arg) = @_;
2031
2032   if (ref $arg eq 'ARRAY') {
2033     if (ref $arg->[0] eq 'HASH') {
2034       return $arg;
2035     }
2036     elsif (ref $arg->[0] eq 'ARRAY') {
2037       my @ret;
2038       my @colnames = @{$arg->[0]};
2039       foreach my $values (@{$arg}[1 .. $#$arg]) {
2040         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2041       }
2042       return \@ret;
2043     }
2044   }
2045
2046   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2047 }
2048
2049 =head2 pager
2050
2051 =over 4
2052
2053 =item Arguments: none
2054
2055 =item Return Value: $pager
2056
2057 =back
2058
2059 Return Value a L<Data::Page> object for the current resultset. Only makes
2060 sense for queries with a C<page> attribute.
2061
2062 To get the full count of entries for a paged resultset, call
2063 C<total_entries> on the L<Data::Page> object.
2064
2065 =cut
2066
2067 # make a wizard good for both a scalar and a hashref
2068 my $mk_lazy_count_wizard = sub {
2069   require Variable::Magic;
2070
2071   my $stash = { total_rs => shift };
2072   my $slot = shift; # only used by the hashref magic
2073
2074   my $magic = Variable::Magic::wizard (
2075     data => sub { $stash },
2076
2077     (!$slot)
2078     ? (
2079       # the scalar magic
2080       get => sub {
2081         # set value lazily, and dispell for good
2082         ${$_[0]} = $_[1]{total_rs}->count;
2083         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref});
2084         return 1;
2085       },
2086       set => sub {
2087         # an explicit set implies dispell as well
2088         # the unless() is to work around "fun and giggles" below
2089         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref})
2090           unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
2091         return 1;
2092       },
2093     )
2094     : (
2095       # the uvar magic
2096       fetch => sub {
2097         if ($_[2] eq $slot and !$_[1]{inactive}) {
2098           my $cnt = $_[1]{total_rs}->count;
2099           $_[0]->{$slot} = $cnt;
2100
2101           # attempting to dispell in a fetch handle (works in store), seems
2102           # to invariable segfault on 5.10, 5.12, 5.13 :(
2103           # so use an inactivator instead
2104           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
2105           $_[1]{inactive}++;
2106         }
2107         return 1;
2108       },
2109       store => sub {
2110         if (! $_[1]{inactive} and $_[2] eq $slot) {
2111           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
2112           $_[1]{inactive}++
2113             unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
2114         }
2115         return 1;
2116       },
2117     ),
2118   );
2119
2120   $stash->{magic_selfref} = $magic;
2121   weaken ($stash->{magic_selfref}); # this fails on 5.8.1
2122
2123   return $magic;
2124 };
2125
2126 # the tie class for 5.8.1
2127 {
2128   package # hide from pause
2129     DBIx::Class::__DBIC_LAZY_RS_COUNT__;
2130   use base qw/Tie::Hash/;
2131
2132   sub FIRSTKEY { my $dummy = scalar keys %{$_[0]{data}}; each %{$_[0]{data}} }
2133   sub NEXTKEY  { each %{$_[0]{data}} }
2134   sub EXISTS   { exists $_[0]{data}{$_[1]} }
2135   sub DELETE   { delete $_[0]{data}{$_[1]} }
2136   sub CLEAR    { %{$_[0]{data}} = () }
2137   sub SCALAR   { scalar %{$_[0]{data}} }
2138
2139   sub TIEHASH {
2140     $_[1]{data} = {%{$_[1]{selfref}}};
2141     %{$_[1]{selfref}} = ();
2142     Scalar::Util::weaken ($_[1]{selfref});
2143     return bless ($_[1], $_[0]);
2144   };
2145
2146   sub FETCH {
2147     if ($_[1] eq $_[0]{slot}) {
2148       my $cnt = $_[0]{data}{$_[1]} = $_[0]{total_rs}->count;
2149       untie %{$_[0]{selfref}};
2150       %{$_[0]{selfref}} = %{$_[0]{data}};
2151       return $cnt;
2152     }
2153     else {
2154       $_[0]{data}{$_[1]};
2155     }
2156   }
2157
2158   sub STORE {
2159     $_[0]{data}{$_[1]} = $_[2];
2160     if ($_[1] eq $_[0]{slot}) {
2161       untie %{$_[0]{selfref}};
2162       %{$_[0]{selfref}} = %{$_[0]{data}};
2163     }
2164     $_[2];
2165   }
2166 }
2167
2168 sub pager {
2169   my ($self) = @_;
2170
2171   return $self->{pager} if $self->{pager};
2172
2173   if ($self->get_cache) {
2174     $self->throw_exception ('Pagers on cached resultsets are not supported');
2175   }
2176
2177   my $attrs = $self->{attrs};
2178   if (!defined $attrs->{page}) {
2179     $self->throw_exception("Can't create pager for non-paged rs");
2180   }
2181   elsif ($attrs->{page} <= 0) {
2182     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2183   }
2184   $attrs->{rows} ||= 10;
2185
2186   # throw away the paging flags and re-run the count (possibly
2187   # with a subselect) to get the real total count
2188   my $count_attrs = { %$attrs };
2189   delete $count_attrs->{$_} for qw/rows offset page pager/;
2190   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2191
2192
2193 ### the following may seem awkward and dirty, but it's a thought-experiment
2194 ### necessary for future development of DBIx::DS. Do *NOT* change this code
2195 ### before talking to ribasushi/mst
2196
2197   my $pager = Data::Page->new(
2198     0,  #start with an empty set
2199     $attrs->{rows},
2200     $self->{attrs}{page},
2201   );
2202
2203   my $data_slot = 'total_entries';
2204
2205   # Since we are interested in a cached value (once it's set - it's set), every
2206   # technique will detach from the magic-host once the time comes to fire the
2207   # ->count (or in the segfaulting case of >= 5.10 it will deactivate itself)
2208
2209   if ($] < 5.008003) {
2210     # 5.8.1 throws 'Modification of a read-only value attempted' when one tries
2211     # to weakref the magic container :(
2212     # tested on 5.8.1
2213     tie (%$pager, 'DBIx::Class::__DBIC_LAZY_RS_COUNT__',
2214       { slot => $data_slot, total_rs => $total_rs, selfref => $pager }
2215     );
2216   }
2217   elsif ($] < 5.010) {
2218     # We can use magic on the hash value slot. It's interesting that the magic is
2219     # attached to the hash-slot, and does *not* stop working once I do the dummy
2220     # assignments after the cast()
2221     # tested on 5.8.3 and 5.8.9
2222     my $magic = $mk_lazy_count_wizard->($total_rs);
2223     Variable::Magic::cast ( $pager->{$data_slot}, $magic );
2224
2225     # this is for fun and giggles
2226     $pager->{$data_slot} = -1;
2227     $pager->{$data_slot} = 0;
2228
2229     # this does not work for scalars, but works with
2230     # uvar magic below
2231     #my %vals = %$pager;
2232     #%$pager = ();
2233     #%{$pager} = %vals;
2234   }
2235   else {
2236     # And the uvar magic
2237     # works on 5.10.1, 5.12.1 and 5.13.4 in its current form,
2238     # however see the wizard maker for more notes
2239     my $magic = $mk_lazy_count_wizard->($total_rs, $data_slot);
2240     Variable::Magic::cast ( %$pager, $magic );
2241
2242     # still works
2243     $pager->{$data_slot} = -1;
2244     $pager->{$data_slot} = 0;
2245
2246     # this now works
2247     my %vals = %$pager;
2248     %$pager = ();
2249     %{$pager} = %vals;
2250   }
2251
2252   return $self->{pager} = $pager;
2253 }
2254
2255 =head2 page
2256
2257 =over 4
2258
2259 =item Arguments: $page_number
2260
2261 =item Return Value: $rs
2262
2263 =back
2264
2265 Returns a resultset for the $page_number page of the resultset on which page
2266 is called, where each page contains a number of rows equal to the 'rows'
2267 attribute set on the resultset (10 by default).
2268
2269 =cut
2270
2271 sub page {
2272   my ($self, $page) = @_;
2273   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2274 }
2275
2276 =head2 new_result
2277
2278 =over 4
2279
2280 =item Arguments: \%vals
2281
2282 =item Return Value: $rowobject
2283
2284 =back
2285
2286 Creates a new row object in the resultset's result class and returns
2287 it. The row is not inserted into the database at this point, call
2288 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2289 will tell you whether the row object has been inserted or not.
2290
2291 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2292
2293 =cut
2294
2295 sub new_result {
2296   my ($self, $values) = @_;
2297   $self->throw_exception( "new_result needs a hash" )
2298     unless (ref $values eq 'HASH');
2299
2300   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2301
2302   my %new = (
2303     %$merged_cond,
2304     @$cols_from_relations
2305       ? (-cols_from_relations => $cols_from_relations)
2306       : (),
2307     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2308   );
2309
2310   return $self->result_class->new(\%new);
2311 }
2312
2313 # _merge_with_rscond
2314 #
2315 # Takes a simple hash of K/V data and returns its copy merged with the
2316 # condition already present on the resultset. Additionally returns an
2317 # arrayref of value/condition names, which were inferred from related
2318 # objects (this is needed for in-memory related objects)
2319 sub _merge_with_rscond {
2320   my ($self, $data) = @_;
2321
2322   my (%new_data, @cols_from_relations);
2323
2324   my $alias = $self->{attrs}{alias};
2325
2326   if (! defined $self->{cond}) {
2327     # just massage $data below
2328   }
2329   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2330     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2331     @cols_from_relations = keys %new_data;
2332   }
2333   elsif (ref $self->{cond} ne 'HASH') {
2334     $self->throw_exception(
2335       "Can't abstract implicit construct, resultset condition not a hash"
2336     );
2337   }
2338   else {
2339     # precendence must be given to passed values over values inherited from
2340     # the cond, so the order here is important.
2341     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2342     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2343
2344     while ( my($col, $value) = each %implied ) {
2345       my $vref = ref $value;
2346       if ($vref eq 'HASH') {
2347         if (keys(%$value) && (keys %$value)[0] eq '=') {
2348           $new_data{$col} = $value->{'='};
2349         }
2350         # in a complex condition, set_from_related needs to override
2351         # the columns that are involved.
2352         elsif (!exists $data->{$col} &&
2353                !exists $data->{"$alias.$col"}) {
2354           $self->throw_exception("unable to set_from_related via complex condition on column(s): '$col'");
2355         }
2356       }
2357       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2358         $new_data{$col} = $value;
2359       }
2360     }
2361   }
2362
2363   %new_data = (
2364     %new_data,
2365     %{ $self->_remove_alias($data, $alias) },
2366   );
2367
2368   return (\%new_data, \@cols_from_relations);
2369 }
2370
2371 # _has_resolved_attr
2372 #
2373 # determines if the resultset defines at least one
2374 # of the attributes supplied
2375 #
2376 # used to determine if a subquery is neccessary
2377 #
2378 # supports some virtual attributes:
2379 #   -join
2380 #     This will scan for any joins being present on the resultset.
2381 #     It is not a mere key-search but a deep inspection of {from}
2382 #
2383
2384 sub _has_resolved_attr {
2385   my ($self, @attr_names) = @_;
2386
2387   my $attrs = $self->_resolved_attrs;
2388
2389   my %extra_checks;
2390
2391   for my $n (@attr_names) {
2392     if (grep { $n eq $_ } (qw/-join/) ) {
2393       $extra_checks{$n}++;
2394       next;
2395     }
2396
2397     my $attr =  $attrs->{$n};
2398
2399     next if not defined $attr;
2400
2401     if (ref $attr eq 'HASH') {
2402       return 1 if keys %$attr;
2403     }
2404     elsif (ref $attr eq 'ARRAY') {
2405       return 1 if @$attr;
2406     }
2407     else {
2408       return 1 if $attr;
2409     }
2410   }
2411
2412   # a resolved join is expressed as a multi-level from
2413   return 1 if (
2414     $extra_checks{-join}
2415       and
2416     ref $attrs->{from} eq 'ARRAY'
2417       and
2418     @{$attrs->{from}} > 1
2419   );
2420
2421   return 0;
2422 }
2423
2424 # _collapse_cond
2425 #
2426 # Recursively collapse the condition.
2427
2428 sub _collapse_cond {
2429   my ($self, $cond, $collapsed) = @_;
2430
2431   $collapsed ||= {};
2432
2433   if (ref $cond eq 'ARRAY') {
2434     foreach my $subcond (@$cond) {
2435       next unless ref $subcond;  # -or
2436       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2437     }
2438   }
2439   elsif (ref $cond eq 'HASH') {
2440     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2441       foreach my $subcond (@{$cond->{-and}}) {
2442         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2443       }
2444     }
2445     else {
2446       foreach my $col (keys %$cond) {
2447         my $value = $cond->{$col};
2448         $collapsed->{$col} = $value;
2449       }
2450     }
2451   }
2452
2453   return $collapsed;
2454 }
2455
2456 # _remove_alias
2457 #
2458 # Remove the specified alias from the specified query hash. A copy is made so
2459 # the original query is not modified.
2460
2461 sub _remove_alias {
2462   my ($self, $query, $alias) = @_;
2463
2464   my %orig = %{ $query || {} };
2465   my %unaliased;
2466
2467   foreach my $key (keys %orig) {
2468     if ($key !~ /\./) {
2469       $unaliased{$key} = $orig{$key};
2470       next;
2471     }
2472     $unaliased{$1} = $orig{$key}
2473       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2474   }
2475
2476   return \%unaliased;
2477 }
2478
2479 =head2 as_query
2480
2481 =over 4
2482
2483 =item Arguments: none
2484
2485 =item Return Value: \[ $sql, @bind ]
2486
2487 =back
2488
2489 Returns the SQL query and bind vars associated with the invocant.
2490
2491 This is generally used as the RHS for a subquery.
2492
2493 =cut
2494
2495 sub as_query {
2496   my $self = shift;
2497
2498   my $attrs = $self->_resolved_attrs_copy;
2499
2500   # For future use:
2501   #
2502   # in list ctx:
2503   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2504   # $sql also has no wrapping parenthesis in list ctx
2505   #
2506   my $sqlbind = $self->result_source->storage
2507     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2508
2509   return $sqlbind;
2510 }
2511
2512 =head2 find_or_new
2513
2514 =over 4
2515
2516 =item Arguments: \%vals, \%attrs?
2517
2518 =item Return Value: $rowobject
2519
2520 =back
2521
2522   my $artist = $schema->resultset('Artist')->find_or_new(
2523     { artist => 'fred' }, { key => 'artists' });
2524
2525   $cd->cd_to_producer->find_or_new({ producer => $producer },
2526                                    { key => 'primary });
2527
2528 Find an existing record from this resultset using L</find>. if none exists,
2529 instantiate a new result object and return it. The object will not be saved
2530 into your storage until you call L<DBIx::Class::Row/insert> on it.
2531
2532 You most likely want this method when looking for existing rows using a unique
2533 constraint that is not the primary key, or looking for related rows.
2534
2535 If you want objects to be saved immediately, use L</find_or_create> instead.
2536
2537 B<Note>: Make sure to read the documentation of L</find> and understand the
2538 significance of the C<key> attribute, as its lack may skew your search, and
2539 subsequently result in spurious new objects.
2540
2541 B<Note>: Take care when using C<find_or_new> with a table having
2542 columns with default values that you intend to be automatically
2543 supplied by the database (e.g. an auto_increment primary key column).
2544 In normal usage, the value of such columns should NOT be included at
2545 all in the call to C<find_or_new>, even when set to C<undef>.
2546
2547 =cut
2548
2549 sub find_or_new {
2550   my $self     = shift;
2551   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2552   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2553   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2554     return $row;
2555   }
2556   return $self->new_result($hash);
2557 }
2558
2559 =head2 create
2560
2561 =over 4
2562
2563 =item Arguments: \%vals
2564
2565 =item Return Value: a L<DBIx::Class::Row> $object
2566
2567 =back
2568
2569 Attempt to create a single new row or a row with multiple related rows
2570 in the table represented by the resultset (and related tables). This
2571 will not check for duplicate rows before inserting, use
2572 L</find_or_create> to do that.
2573
2574 To create one row for this resultset, pass a hashref of key/value
2575 pairs representing the columns of the table and the values you wish to
2576 store. If the appropriate relationships are set up, foreign key fields
2577 can also be passed an object representing the foreign row, and the
2578 value will be set to its primary key.
2579
2580 To create related objects, pass a hashref of related-object column values
2581 B<keyed on the relationship name>. If the relationship is of type C<multi>
2582 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2583 The process will correctly identify columns holding foreign keys, and will
2584 transparently populate them from the keys of the corresponding relation.
2585 This can be applied recursively, and will work correctly for a structure
2586 with an arbitrary depth and width, as long as the relationships actually
2587 exists and the correct column data has been supplied.
2588
2589
2590 Instead of hashrefs of plain related data (key/value pairs), you may
2591 also pass new or inserted objects. New objects (not inserted yet, see
2592 L</new>), will be inserted into their appropriate tables.
2593
2594 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2595
2596 Example of creating a new row.
2597
2598   $person_rs->create({
2599     name=>"Some Person",
2600     email=>"somebody@someplace.com"
2601   });
2602
2603 Example of creating a new row and also creating rows in a related C<has_many>
2604 or C<has_one> resultset.  Note Arrayref.
2605
2606   $artist_rs->create(
2607      { artistid => 4, name => 'Manufactured Crap', cds => [
2608         { title => 'My First CD', year => 2006 },
2609         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2610       ],
2611      },
2612   );
2613
2614 Example of creating a new row and also creating a row in a related
2615 C<belongs_to> resultset. Note Hashref.
2616
2617   $cd_rs->create({
2618     title=>"Music for Silly Walks",
2619     year=>2000,
2620     artist => {
2621       name=>"Silly Musician",
2622     }
2623   });
2624
2625 =over
2626
2627 =item WARNING
2628
2629 When subclassing ResultSet never attempt to override this method. Since
2630 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2631 lot of the internals simply never call it, so your override will be
2632 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2633 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2634 L</create> process you need to intervene.
2635
2636 =back
2637
2638 =cut
2639
2640 sub create {
2641   my ($self, $attrs) = @_;
2642   $self->throw_exception( "create needs a hashref" )
2643     unless ref $attrs eq 'HASH';
2644   return $self->new_result($attrs)->insert;
2645 }
2646
2647 =head2 find_or_create
2648
2649 =over 4
2650
2651 =item Arguments: \%vals, \%attrs?
2652
2653 =item Return Value: $rowobject
2654
2655 =back
2656
2657   $cd->cd_to_producer->find_or_create({ producer => $producer },
2658                                       { key => 'primary' });
2659
2660 Tries to find a record based on its primary key or unique constraints; if none
2661 is found, creates one and returns that instead.
2662
2663   my $cd = $schema->resultset('CD')->find_or_create({
2664     cdid   => 5,
2665     artist => 'Massive Attack',
2666     title  => 'Mezzanine',
2667     year   => 2005,
2668   });
2669
2670 Also takes an optional C<key> attribute, to search by a specific key or unique
2671 constraint. For example:
2672
2673   my $cd = $schema->resultset('CD')->find_or_create(
2674     {
2675       artist => 'Massive Attack',
2676       title  => 'Mezzanine',
2677     },
2678     { key => 'cd_artist_title' }
2679   );
2680
2681 B<Note>: Make sure to read the documentation of L</find> and understand the
2682 significance of the C<key> attribute, as its lack may skew your search, and
2683 subsequently result in spurious row creation.
2684
2685 B<Note>: Because find_or_create() reads from the database and then
2686 possibly inserts based on the result, this method is subject to a race
2687 condition. Another process could create a record in the table after
2688 the find has completed and before the create has started. To avoid
2689 this problem, use find_or_create() inside a transaction.
2690
2691 B<Note>: Take care when using C<find_or_create> with a table having
2692 columns with default values that you intend to be automatically
2693 supplied by the database (e.g. an auto_increment primary key column).
2694 In normal usage, the value of such columns should NOT be included at
2695 all in the call to C<find_or_create>, even when set to C<undef>.
2696
2697 See also L</find> and L</update_or_create>. For information on how to declare
2698 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2699
2700 =cut
2701
2702 sub find_or_create {
2703   my $self     = shift;
2704   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2705   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2706   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2707     return $row;
2708   }
2709   return $self->create($hash);
2710 }
2711
2712 =head2 update_or_create
2713
2714 =over 4
2715
2716 =item Arguments: \%col_values, { key => $unique_constraint }?
2717
2718 =item Return Value: $row_object
2719
2720 =back
2721
2722   $resultset->update_or_create({ col => $val, ... });
2723
2724 Like L</find_or_create>, but if a row is found it is immediately updated via
2725 C<< $found_row->update (\%col_values) >>.
2726
2727
2728 Takes an optional C<key> attribute to search on a specific unique constraint.
2729 For example:
2730
2731   # In your application
2732   my $cd = $schema->resultset('CD')->update_or_create(
2733     {
2734       artist => 'Massive Attack',
2735       title  => 'Mezzanine',
2736       year   => 1998,
2737     },
2738     { key => 'cd_artist_title' }
2739   );
2740
2741   $cd->cd_to_producer->update_or_create({
2742     producer => $producer,
2743     name => 'harry',
2744   }, {
2745     key => 'primary',
2746   });
2747
2748 B<Note>: Make sure to read the documentation of L</find> and understand the
2749 significance of the C<key> attribute, as its lack may skew your search, and
2750 subsequently result in spurious row creation.
2751
2752 B<Note>: Take care when using C<update_or_create> with a table having
2753 columns with default values that you intend to be automatically
2754 supplied by the database (e.g. an auto_increment primary key column).
2755 In normal usage, the value of such columns should NOT be included at
2756 all in the call to C<update_or_create>, even when set to C<undef>.
2757
2758 See also L</find> and L</find_or_create>. For information on how to declare
2759 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2760
2761 =cut
2762
2763 sub update_or_create {
2764   my $self = shift;
2765   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2766   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2767
2768   my $row = $self->find($cond, $attrs);
2769   if (defined $row) {
2770     $row->update($cond);
2771     return $row;
2772   }
2773
2774   return $self->create($cond);
2775 }
2776
2777 =head2 update_or_new
2778
2779 =over 4
2780
2781 =item Arguments: \%col_values, { key => $unique_constraint }?
2782
2783 =item Return Value: $rowobject
2784
2785 =back
2786
2787   $resultset->update_or_new({ col => $val, ... });
2788
2789 Like L</find_or_new> but if a row is found it is immediately updated via
2790 C<< $found_row->update (\%col_values) >>.
2791
2792 For example:
2793
2794   # In your application
2795   my $cd = $schema->resultset('CD')->update_or_new(
2796     {
2797       artist => 'Massive Attack',
2798       title  => 'Mezzanine',
2799       year   => 1998,
2800     },
2801     { key => 'cd_artist_title' }
2802   );
2803
2804   if ($cd->in_storage) {
2805       # the cd was updated
2806   }
2807   else {
2808       # the cd is not yet in the database, let's insert it
2809       $cd->insert;
2810   }
2811
2812 B<Note>: Make sure to read the documentation of L</find> and understand the
2813 significance of the C<key> attribute, as its lack may skew your search, and
2814 subsequently result in spurious new objects.
2815
2816 B<Note>: Take care when using C<update_or_new> with a table having
2817 columns with default values that you intend to be automatically
2818 supplied by the database (e.g. an auto_increment primary key column).
2819 In normal usage, the value of such columns should NOT be included at
2820 all in the call to C<update_or_new>, even when set to C<undef>.
2821
2822 See also L</find>, L</find_or_create> and L</find_or_new>.
2823
2824 =cut
2825
2826 sub update_or_new {
2827     my $self  = shift;
2828     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2829     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2830
2831     my $row = $self->find( $cond, $attrs );
2832     if ( defined $row ) {
2833         $row->update($cond);
2834         return $row;
2835     }
2836
2837     return $self->new_result($cond);
2838 }
2839
2840 =head2 get_cache
2841
2842 =over 4
2843
2844 =item Arguments: none
2845
2846 =item Return Value: \@cache_objects | undef
2847
2848 =back
2849
2850 Gets the contents of the cache for the resultset, if the cache is set.
2851
2852 The cache is populated either by using the L</prefetch> attribute to
2853 L</search> or by calling L</set_cache>.
2854
2855 =cut
2856
2857 sub get_cache {
2858   shift->{all_cache};
2859 }
2860
2861 =head2 set_cache
2862
2863 =over 4
2864
2865 =item Arguments: \@cache_objects
2866
2867 =item Return Value: \@cache_objects
2868
2869 =back
2870
2871 Sets the contents of the cache for the resultset. Expects an arrayref
2872 of objects of the same class as those produced by the resultset. Note that
2873 if the cache is set the resultset will return the cached objects rather
2874 than re-querying the database even if the cache attr is not set.
2875
2876 The contents of the cache can also be populated by using the
2877 L</prefetch> attribute to L</search>.
2878
2879 =cut
2880
2881 sub set_cache {
2882   my ( $self, $data ) = @_;
2883   $self->throw_exception("set_cache requires an arrayref")
2884       if defined($data) && (ref $data ne 'ARRAY');
2885   $self->{all_cache} = $data;
2886 }
2887
2888 =head2 clear_cache
2889
2890 =over 4
2891
2892 =item Arguments: none
2893
2894 =item Return Value: undef
2895
2896 =back
2897
2898 Clears the cache for the resultset.
2899
2900 =cut
2901
2902 sub clear_cache {
2903   shift->set_cache(undef);
2904 }
2905
2906 =head2 is_paged
2907
2908 =over 4
2909
2910 =item Arguments: none
2911
2912 =item Return Value: true, if the resultset has been paginated
2913
2914 =back
2915
2916 =cut
2917
2918 sub is_paged {
2919   my ($self) = @_;
2920   return !!$self->{attrs}{page};
2921 }
2922
2923 =head2 is_ordered
2924
2925 =over 4
2926
2927 =item Arguments: none
2928
2929 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2930
2931 =back
2932
2933 =cut
2934
2935 sub is_ordered {
2936   my ($self) = @_;
2937   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2938 }
2939
2940 =head2 related_resultset
2941
2942 =over 4
2943
2944 =item Arguments: $relationship_name
2945
2946 =item Return Value: $resultset
2947
2948 =back
2949
2950 Returns a related resultset for the supplied relationship name.
2951
2952   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2953
2954 =cut
2955
2956 sub related_resultset {
2957   my ($self, $rel) = @_;
2958
2959   $self->{related_resultsets} ||= {};
2960   return $self->{related_resultsets}{$rel} ||= do {
2961     my $rsrc = $self->result_source;
2962     my $rel_info = $rsrc->relationship_info($rel);
2963
2964     $self->throw_exception(
2965       "search_related: result source '" . $rsrc->source_name .
2966         "' has no such relationship $rel")
2967       unless $rel_info;
2968
2969     my $attrs = $self->_chain_relationship($rel);
2970
2971     my $join_count = $attrs->{seen_join}{$rel};
2972
2973     my $alias = $self->result_source->storage
2974         ->relname_to_table_alias($rel, $join_count);
2975
2976     # since this is search_related, and we already slid the select window inwards
2977     # (the select/as attrs were deleted in the beginning), we need to flip all
2978     # left joins to inner, so we get the expected results
2979     # read the comment on top of the actual function to see what this does
2980     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
2981
2982
2983     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2984     delete @{$attrs}{qw(result_class alias)};
2985
2986     my $new_cache;
2987
2988     if (my $cache = $self->get_cache) {
2989       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2990         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2991                         @$cache ];
2992       }
2993     }
2994
2995     my $rel_source = $rsrc->related_source($rel);
2996
2997     my $new = do {
2998
2999       # The reason we do this now instead of passing the alias to the
3000       # search_rs below is that if you wrap/overload resultset on the
3001       # source you need to know what alias it's -going- to have for things
3002       # to work sanely (e.g. RestrictWithObject wants to be able to add
3003       # extra query restrictions, and these may need to be $alias.)
3004
3005       my $rel_attrs = $rel_source->resultset_attributes;
3006       local $rel_attrs->{alias} = $alias;
3007
3008       $rel_source->resultset
3009                  ->search_rs(
3010                      undef, {
3011                        %$attrs,
3012                        where => $attrs->{where},
3013                    });
3014     };
3015     $new->set_cache($new_cache) if $new_cache;
3016     $new;
3017   };
3018 }
3019
3020 =head2 current_source_alias
3021
3022 =over 4
3023
3024 =item Arguments: none
3025
3026 =item Return Value: $source_alias
3027
3028 =back
3029
3030 Returns the current table alias for the result source this resultset is built
3031 on, that will be used in the SQL query. Usually it is C<me>.
3032
3033 Currently the source alias that refers to the result set returned by a
3034 L</search>/L</find> family method depends on how you got to the resultset: it's
3035 C<me> by default, but eg. L</search_related> aliases it to the related result
3036 source name (and keeps C<me> referring to the original result set). The long
3037 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3038 (and make this method unnecessary).
3039
3040 Thus it's currently necessary to use this method in predefined queries (see
3041 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3042 source alias of the current result set:
3043
3044   # in a result set class
3045   sub modified_by {
3046     my ($self, $user) = @_;
3047
3048     my $me = $self->current_source_alias;
3049
3050     return $self->search(
3051       "$me.modified" => $user->id,
3052     );
3053   }
3054
3055 =cut
3056
3057 sub current_source_alias {
3058   my ($self) = @_;
3059
3060   return ($self->{attrs} || {})->{alias} || 'me';
3061 }
3062
3063 =head2 as_subselect_rs
3064
3065 =over 4
3066
3067 =item Arguments: none
3068
3069 =item Return Value: $resultset
3070
3071 =back
3072
3073 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3074 "virtual view" by including it as a subquery within the from clause.  From this
3075 point on, any joined tables are inaccessible to ->search on the resultset (as if
3076 it were simply where-filtered without joins).  For example:
3077
3078  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3079
3080  # 'x' now pollutes the query namespace
3081
3082  # So the following works as expected
3083  my $ok_rs = $rs->search({'x.other' => 1});
3084
3085  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3086  # def) we look for one row with contradictory terms and join in another table
3087  # (aliased 'x_2') which we never use
3088  my $broken_rs = $rs->search({'x.name' => 'def'});
3089
3090  my $rs2 = $rs->as_subselect_rs;
3091
3092  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3093  my $not_joined_rs = $rs2->search({'x.other' => 1});
3094
3095  # works as expected: finds a 'table' row related to two x rows (abc and def)
3096  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3097
3098 Another example of when one might use this would be to select a subset of
3099 columns in a group by clause:
3100
3101  my $rs = $schema->resultset('Bar')->search(undef, {
3102    group_by => [qw{ id foo_id baz_id }],
3103  })->as_subselect_rs->search(undef, {
3104    columns => [qw{ id foo_id }]
3105  });
3106
3107 In the above example normally columns would have to be equal to the group by,
3108 but because we isolated the group by into a subselect the above works.
3109
3110 =cut
3111
3112 sub as_subselect_rs {
3113   my $self = shift;
3114
3115   my $attrs = $self->_resolved_attrs;
3116
3117   my $fresh_rs = (ref $self)->new (
3118     $self->result_source
3119   );
3120
3121   # these pieces will be locked in the subquery
3122   delete $fresh_rs->{cond};
3123   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3124
3125   return $fresh_rs->search( {}, {
3126     from => [{
3127       $attrs->{alias} => $self->as_query,
3128       -alias  => $attrs->{alias},
3129       -rsrc   => $self->result_source,
3130     }],
3131     alias => $attrs->{alias},
3132   });
3133 }
3134
3135 # This code is called by search_related, and makes sure there
3136 # is clear separation between the joins before, during, and
3137 # after the relationship. This information is needed later
3138 # in order to properly resolve prefetch aliases (any alias
3139 # with a relation_chain_depth less than the depth of the
3140 # current prefetch is not considered)
3141 #
3142 # The increments happen twice per join. An even number means a
3143 # relationship specified via a search_related, whereas an odd
3144 # number indicates a join/prefetch added via attributes
3145 #
3146 # Also this code will wrap the current resultset (the one we
3147 # chain to) in a subselect IFF it contains limiting attributes
3148 sub _chain_relationship {
3149   my ($self, $rel) = @_;
3150   my $source = $self->result_source;
3151   my $attrs = { %{$self->{attrs}||{}} };
3152
3153   # we need to take the prefetch the attrs into account before we
3154   # ->_resolve_join as otherwise they get lost - captainL
3155   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3156
3157   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3158
3159   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3160
3161   my $from;
3162   my @force_subq_attrs = qw/offset rows group_by having/;
3163
3164   if (
3165     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3166       ||
3167     $self->_has_resolved_attr (@force_subq_attrs)
3168   ) {
3169     # Nuke the prefetch (if any) before the new $rs attrs
3170     # are resolved (prefetch is useless - we are wrapping
3171     # a subquery anyway).
3172     my $rs_copy = $self->search;
3173     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3174       $rs_copy->{attrs}{join},
3175       delete $rs_copy->{attrs}{prefetch},
3176     );
3177
3178     $from = [{
3179       -rsrc   => $source,
3180       -alias  => $attrs->{alias},
3181       $attrs->{alias} => $rs_copy->as_query,
3182     }];
3183     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3184     $seen->{-relation_chain_depth} = 0;
3185   }
3186   elsif ($attrs->{from}) {  #shallow copy suffices
3187     $from = [ @{$attrs->{from}} ];
3188   }
3189   else {
3190     $from = [{
3191       -rsrc  => $source,
3192       -alias => $attrs->{alias},
3193       $attrs->{alias} => $source->from,
3194     }];
3195   }
3196
3197   my $jpath = ($seen->{-relation_chain_depth})
3198     ? $from->[-1][0]{-join_path}
3199     : [];
3200
3201   my @requested_joins = $source->_resolve_join(
3202     $join,
3203     $attrs->{alias},
3204     $seen,
3205     $jpath,
3206   );
3207
3208   push @$from, @requested_joins;
3209
3210   $seen->{-relation_chain_depth}++;
3211
3212   # if $self already had a join/prefetch specified on it, the requested
3213   # $rel might very well be already included. What we do in this case
3214   # is effectively a no-op (except that we bump up the chain_depth on
3215   # the join in question so we could tell it *is* the search_related)
3216   my $already_joined;
3217
3218   # we consider the last one thus reverse
3219   for my $j (reverse @requested_joins) {
3220     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3221     if ($rel eq $last_j) {
3222       $j->[0]{-relation_chain_depth}++;
3223       $already_joined++;
3224       last;
3225     }
3226   }
3227
3228   unless ($already_joined) {
3229     push @$from, $source->_resolve_join(
3230       $rel,
3231       $attrs->{alias},
3232       $seen,
3233       $jpath,
3234     );
3235   }
3236
3237   $seen->{-relation_chain_depth}++;
3238
3239   return {%$attrs, from => $from, seen_join => $seen};
3240 }
3241
3242 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3243 sub _resolved_attrs_copy {
3244   my $self = shift;
3245   return { %{$self->_resolved_attrs (@_)} };
3246 }
3247
3248 sub _resolved_attrs {
3249   my $self = shift;
3250   return $self->{_attrs} if $self->{_attrs};
3251
3252   my $attrs  = { %{ $self->{attrs} || {} } };
3253   my $source = $self->result_source;
3254   my $alias  = $attrs->{alias};
3255
3256   # one last pass of normalization
3257   $self->_normalize_selection($attrs);
3258
3259   # default selection list
3260   $attrs->{columns} = [ $source->columns ]
3261     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as _trailing_select/;
3262
3263   # merge selectors together
3264   for (qw/columns select as _trailing_select/) {
3265     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, $attrs->{"+$_"})
3266       if $attrs->{$_} or $attrs->{"+$_"};
3267   }
3268
3269   # disassemble columns
3270   my (@sel, @as);
3271   if (my $cols = delete $attrs->{columns}) {
3272     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3273       if (ref $c eq 'HASH') {
3274         for my $as (keys %$c) {
3275           push @sel, $c->{$as};
3276           push @as, $as;
3277         }
3278       }
3279       else {
3280         push @sel, $c;
3281         push @as, $c;
3282       }
3283     }
3284   }
3285
3286   # when trying to weed off duplicates later do not go past this point -
3287   # everything added from here on is unbalanced "anyone's guess" stuff
3288   my $dedup_stop_idx = $#as;
3289
3290   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3291     if $attrs->{as};
3292   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3293     if $attrs->{select};
3294
3295   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3296   for (@sel) {
3297     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3298   }
3299
3300   # disqualify all $alias.col as-bits (collapser mandated)
3301   for (@as) {
3302     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3303   }
3304
3305   # de-duplicate the result (remove *identical* select/as pairs)
3306   # and also die on duplicate {as} pointing to different {select}s
3307   # not using a c-style for as the condition is prone to shrinkage
3308   my $seen;
3309   my $i = 0;
3310   while ($i <= $dedup_stop_idx) {
3311     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3312       splice @sel, $i, 1;
3313       splice @as, $i, 1;
3314       $dedup_stop_idx--;
3315     }
3316     elsif ($seen->{$as[$i]}++) {
3317       $self->throw_exception(
3318         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3319       );
3320     }
3321     else {
3322       $i++;
3323     }
3324   }
3325
3326   $attrs->{select} = \@sel;
3327   $attrs->{as} = \@as;
3328
3329   $attrs->{from} ||= [{
3330     -rsrc   => $source,
3331     -alias  => $self->{attrs}{alias},
3332     $self->{attrs}{alias} => $source->from,
3333   }];
3334
3335   if ( $attrs->{join} || $attrs->{prefetch} ) {
3336
3337     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3338       if ref $attrs->{from} ne 'ARRAY';
3339
3340     my $join = (delete $attrs->{join}) || {};
3341
3342     if ( defined $attrs->{prefetch} ) {
3343       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3344     }
3345
3346     $attrs->{from} =    # have to copy here to avoid corrupting the original
3347       [
3348         @{ $attrs->{from} },
3349         $source->_resolve_join(
3350           $join,
3351           $alias,
3352           { %{ $attrs->{seen_join} || {} } },
3353           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3354             ? $attrs->{from}[-1][0]{-join_path}
3355             : []
3356           ,
3357         )
3358       ];
3359   }
3360
3361   if ( defined $attrs->{order_by} ) {
3362     $attrs->{order_by} = (
3363       ref( $attrs->{order_by} ) eq 'ARRAY'
3364       ? [ @{ $attrs->{order_by} } ]
3365       : [ $attrs->{order_by} || () ]
3366     );
3367   }
3368
3369   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3370     $attrs->{group_by} = [ $attrs->{group_by} ];
3371   }
3372
3373   # generate the distinct induced group_by early, as prefetch will be carried via a
3374   # subquery (since a group_by is present)
3375   if (delete $attrs->{distinct}) {
3376     if ($attrs->{group_by}) {
3377       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3378     }
3379     else {
3380       # distinct affects only the main selection part, not what prefetch may
3381       # add below. However trailing is not yet a part of the selection as
3382       # prefetch must insert before it
3383       $attrs->{group_by} = $source->storage->_group_over_selection (
3384         $attrs->{from},
3385         [ @{$attrs->{select}||[]}, @{$attrs->{_trailing_select}||[]} ],
3386         $attrs->{order_by},
3387       );
3388     }
3389   }
3390
3391   $attrs->{collapse} ||= {};
3392   if ($attrs->{prefetch}) {
3393     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3394
3395     my $prefetch_ordering = [];
3396
3397     # this is a separate structure (we don't look in {from} directly)
3398     # as the resolver needs to shift things off the lists to work
3399     # properly (identical-prefetches on different branches)
3400     my $join_map = {};
3401     if (ref $attrs->{from} eq 'ARRAY') {
3402
3403       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3404
3405       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3406         next unless $j->[0]{-alias};
3407         next unless $j->[0]{-join_path};
3408         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3409
3410         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3411
3412         my $p = $join_map;
3413         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3414         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3415       }
3416     }
3417
3418     my @prefetch =
3419       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3420
3421     # we need to somehow mark which columns came from prefetch
3422     if (@prefetch) {
3423       my $sel_end = $#{$attrs->{select}};
3424       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3425     }
3426
3427     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3428     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3429
3430     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3431     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3432   }
3433
3434
3435   push @{ $attrs->{select} }, @{$attrs->{_trailing_select}}
3436     if $attrs->{_trailing_select};
3437
3438   # if both page and offset are specified, produce a combined offset
3439   # even though it doesn't make much sense, this is what pre 081xx has
3440   # been doing
3441   if (my $page = delete $attrs->{page}) {
3442     $attrs->{offset} =
3443       ($attrs->{rows} * ($page - 1))
3444             +
3445       ($attrs->{offset} || 0)
3446     ;
3447   }
3448
3449   return $self->{_attrs} = $attrs;
3450 }
3451
3452 sub _rollout_attr {
3453   my ($self, $attr) = @_;
3454
3455   if (ref $attr eq 'HASH') {
3456     return $self->_rollout_hash($attr);
3457   } elsif (ref $attr eq 'ARRAY') {
3458     return $self->_rollout_array($attr);
3459   } else {
3460     return [$attr];
3461   }
3462 }
3463
3464 sub _rollout_array {
3465   my ($self, $attr) = @_;
3466
3467   my @rolled_array;
3468   foreach my $element (@{$attr}) {
3469     if (ref $element eq 'HASH') {
3470       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3471     } elsif (ref $element eq 'ARRAY') {
3472       #  XXX - should probably recurse here
3473       push( @rolled_array, @{$self->_rollout_array($element)} );
3474     } else {
3475       push( @rolled_array, $element );
3476     }
3477   }
3478   return \@rolled_array;
3479 }
3480
3481 sub _rollout_hash {
3482   my ($self, $attr) = @_;
3483
3484   my @rolled_array;
3485   foreach my $key (keys %{$attr}) {
3486     push( @rolled_array, { $key => $attr->{$key} } );
3487   }
3488   return \@rolled_array;
3489 }
3490
3491 sub _calculate_score {
3492   my ($self, $a, $b) = @_;
3493
3494   if (defined $a xor defined $b) {
3495     return 0;
3496   }
3497   elsif (not defined $a) {
3498     return 1;
3499   }
3500
3501   if (ref $b eq 'HASH') {
3502     my ($b_key) = keys %{$b};
3503     if (ref $a eq 'HASH') {
3504       my ($a_key) = keys %{$a};
3505       if ($a_key eq $b_key) {
3506         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3507       } else {
3508         return 0;
3509       }
3510     } else {
3511       return ($a eq $b_key) ? 1 : 0;
3512     }
3513   } else {
3514     if (ref $a eq 'HASH') {
3515       my ($a_key) = keys %{$a};
3516       return ($b eq $a_key) ? 1 : 0;
3517     } else {
3518       return ($b eq $a) ? 1 : 0;
3519     }
3520   }
3521 }
3522
3523 sub _merge_joinpref_attr {
3524   my ($self, $orig, $import) = @_;
3525
3526   return $import unless defined($orig);
3527   return $orig unless defined($import);
3528
3529   $orig = $self->_rollout_attr($orig);
3530   $import = $self->_rollout_attr($import);
3531
3532   my $seen_keys;
3533   foreach my $import_element ( @{$import} ) {
3534     # find best candidate from $orig to merge $b_element into
3535     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3536     foreach my $orig_element ( @{$orig} ) {
3537       my $score = $self->_calculate_score( $orig_element, $import_element );
3538       if ($score > $best_candidate->{score}) {
3539         $best_candidate->{position} = $position;
3540         $best_candidate->{score} = $score;
3541       }
3542       $position++;
3543     }
3544     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3545
3546     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3547       push( @{$orig}, $import_element );
3548     } else {
3549       my $orig_best = $orig->[$best_candidate->{position}];
3550       # merge orig_best and b_element together and replace original with merged
3551       if (ref $orig_best ne 'HASH') {
3552         $orig->[$best_candidate->{position}] = $import_element;
3553       } elsif (ref $import_element eq 'HASH') {
3554         my ($key) = keys %{$orig_best};
3555         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3556       }
3557     }
3558     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3559   }
3560
3561   return $orig;
3562 }
3563
3564 {
3565   my $hm;
3566
3567   sub _merge_attr {
3568     $hm ||= do {
3569       my $hm = Hash::Merge->new;
3570
3571       $hm->specify_behavior({
3572         SCALAR => {
3573           SCALAR => sub {
3574             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3575
3576             if ($defl xor $defr) {
3577               return [ $defl ? $_[0] : $_[1] ];
3578             }
3579             elsif (! $defl) {
3580               return [];
3581             }
3582             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3583               return [ $_[0] ];
3584             }
3585             else {
3586               return [$_[0], $_[1]];
3587             }
3588           },
3589           ARRAY => sub {
3590             return $_[1] if !defined $_[0];
3591             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3592             return [$_[0], @{$_[1]}]
3593           },
3594           HASH  => sub {
3595             return [] if !defined $_[0] and !keys %{$_[1]};
3596             return [ $_[1] ] if !defined $_[0];
3597             return [ $_[0] ] if !keys %{$_[1]};
3598             return [$_[0], $_[1]]
3599           },
3600         },
3601         ARRAY => {
3602           SCALAR => sub {
3603             return $_[0] if !defined $_[1];
3604             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3605             return [@{$_[0]}, $_[1]]
3606           },
3607           ARRAY => sub {
3608             my @ret = @{$_[0]} or return $_[1];
3609             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3610             my %idx = map { $_ => 1 } @ret;
3611             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3612             \@ret;
3613           },
3614           HASH => sub {
3615             return [ $_[1] ] if ! @{$_[0]};
3616             return $_[0] if !keys %{$_[1]};
3617             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3618             return [ @{$_[0]}, $_[1] ];
3619           },
3620         },
3621         HASH => {
3622           SCALAR => sub {
3623             return [] if !keys %{$_[0]} and !defined $_[1];
3624             return [ $_[0] ] if !defined $_[1];
3625             return [ $_[1] ] if !keys %{$_[0]};
3626             return [$_[0], $_[1]]
3627           },
3628           ARRAY => sub {
3629             return [] if !keys %{$_[0]} and !@{$_[1]};
3630             return [ $_[0] ] if !@{$_[1]};
3631             return $_[1] if !keys %{$_[0]};
3632             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3633             return [ $_[0], @{$_[1]} ];
3634           },
3635           HASH => sub {
3636             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3637             return [ $_[0] ] if !keys %{$_[1]};
3638             return [ $_[1] ] if !keys %{$_[0]};
3639             return [ $_[0] ] if $_[0] eq $_[1];
3640             return [ $_[0], $_[1] ];
3641           },
3642         }
3643       } => 'DBIC_RS_ATTR_MERGER');
3644       $hm;
3645     };
3646
3647     return $hm->merge ($_[1], $_[2]);
3648   }
3649 }
3650
3651 sub STORABLE_freeze {
3652   my ($self, $cloning) = @_;
3653   my $to_serialize = { %$self };
3654
3655   # A cursor in progress can't be serialized (and would make little sense anyway)
3656   delete $to_serialize->{cursor};
3657
3658   nfreeze($to_serialize);
3659 }
3660
3661 # need this hook for symmetry
3662 sub STORABLE_thaw {
3663   my ($self, $cloning, $serialized) = @_;
3664
3665   %$self = %{ thaw($serialized) };
3666
3667   $self;
3668 }
3669
3670
3671 =head2 throw_exception
3672
3673 See L<DBIx::Class::Schema/throw_exception> for details.
3674
3675 =cut
3676
3677 sub throw_exception {
3678   my $self=shift;
3679
3680   if (ref $self and my $rsrc = $self->result_source) {
3681     $rsrc->throw_exception(@_)
3682   }
3683   else {
3684     DBIx::Class::Exception->throw(@_);
3685   }
3686 }
3687
3688 # XXX: FIXME: Attributes docs need clearing up
3689
3690 =head1 ATTRIBUTES
3691
3692 Attributes are used to refine a ResultSet in various ways when
3693 searching for data. They can be passed to any method which takes an
3694 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3695 L</count>.
3696
3697 These are in no particular order:
3698
3699 =head2 order_by
3700
3701 =over 4
3702
3703 =item Value: ( $order_by | \@order_by | \%order_by )
3704
3705 =back
3706
3707 Which column(s) to order the results by.
3708
3709 [The full list of suitable values is documented in
3710 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3711 common options.]
3712
3713 If a single column name, or an arrayref of names is supplied, the
3714 argument is passed through directly to SQL. The hashref syntax allows
3715 for connection-agnostic specification of ordering direction:
3716
3717  For descending order:
3718
3719   order_by => { -desc => [qw/col1 col2 col3/] }
3720
3721  For explicit ascending order:
3722
3723   order_by => { -asc => 'col' }
3724
3725 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3726 supported, although you are strongly encouraged to use the hashref
3727 syntax as outlined above.
3728
3729 =head2 columns
3730
3731 =over 4
3732
3733 =item Value: \@columns
3734
3735 =back
3736
3737 Shortcut to request a particular set of columns to be retrieved. Each
3738 column spec may be a string (a table column name), or a hash (in which
3739 case the key is the C<as> value, and the value is used as the C<select>
3740 expression). Adds C<me.> onto the start of any column without a C<.> in
3741 it and sets C<select> from that, then auto-populates C<as> from
3742 C<select> as normal. (You may also use the C<cols> attribute, as in
3743 earlier versions of DBIC.)
3744
3745 Essentially C<columns> does the same as L</select> and L</as>.
3746
3747     columns => [ 'foo', { bar => 'baz' } ]
3748
3749 is the same as
3750
3751     select => [qw/foo baz/],
3752     as => [qw/foo bar/]
3753
3754 =head2 +columns
3755
3756 =over 4
3757
3758 =item Value: \@columns
3759
3760 =back
3761
3762 Indicates additional columns to be selected from storage. Works the same
3763 as L</columns> but adds columns to the selection. (You may also use the
3764 C<include_columns> attribute, as in earlier versions of DBIC). For
3765 example:-
3766
3767   $schema->resultset('CD')->search(undef, {
3768     '+columns' => ['artist.name'],
3769     join => ['artist']
3770   });
3771
3772 would return all CDs and include a 'name' column to the information
3773 passed to object inflation. Note that the 'artist' is the name of the
3774 column (or relationship) accessor, and 'name' is the name of the column
3775 accessor in the related table.
3776
3777 =head2 include_columns
3778
3779 =over 4
3780
3781 =item Value: \@columns
3782
3783 =back
3784
3785 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3786
3787 =head2 select
3788
3789 =over 4
3790
3791 =item Value: \@select_columns
3792
3793 =back
3794
3795 Indicates which columns should be selected from the storage. You can use
3796 column names, or in the case of RDBMS back ends, function or stored procedure
3797 names:
3798
3799   $rs = $schema->resultset('Employee')->search(undef, {
3800     select => [
3801       'name',
3802       { count => 'employeeid' },
3803       { max => { length => 'name' }, -as => 'longest_name' }
3804     ]
3805   });
3806
3807   # Equivalent SQL
3808   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3809
3810 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3811 use L</select>, to instruct DBIx::Class how to store the result of the column.
3812 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3813 identifier aliasing. You can however alias a function, so you can use it in
3814 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3815 attribute> supplied as shown in the example above.
3816
3817 =head2 +select
3818
3819 =over 4
3820
3821 Indicates additional columns to be selected from storage.  Works the same as
3822 L</select> but adds columns to the default selection, instead of specifying
3823 an explicit list.
3824
3825 =back
3826
3827 =head2 +as
3828
3829 =over 4
3830
3831 Indicates additional column names for those added via L</+select>. See L</as>.
3832
3833 =back
3834
3835 =head2 as
3836
3837 =over 4
3838
3839 =item Value: \@inflation_names
3840
3841 =back
3842
3843 Indicates column names for object inflation. That is L</as> indicates the
3844 slot name in which the column value will be stored within the
3845 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3846 identifier by the C<get_column> method (or via the object accessor B<if one
3847 with the same name already exists>) as shown below. The L</as> attribute has
3848 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3849
3850   $rs = $schema->resultset('Employee')->search(undef, {
3851     select => [
3852       'name',
3853       { count => 'employeeid' },
3854       { max => { length => 'name' }, -as => 'longest_name' }
3855     ],
3856     as => [qw/
3857       name
3858       employee_count
3859       max_name_length
3860     /],
3861   });
3862
3863 If the object against which the search is performed already has an accessor
3864 matching a column name specified in C<as>, the value can be retrieved using
3865 the accessor as normal:
3866
3867   my $name = $employee->name();
3868
3869 If on the other hand an accessor does not exist in the object, you need to
3870 use C<get_column> instead:
3871
3872   my $employee_count = $employee->get_column('employee_count');
3873
3874 You can create your own accessors if required - see
3875 L<DBIx::Class::Manual::Cookbook> for details.
3876
3877 =head2 join
3878
3879 =over 4
3880
3881 =item Value: ($rel_name | \@rel_names | \%rel_names)
3882
3883 =back
3884
3885 Contains a list of relationships that should be joined for this query.  For
3886 example:
3887
3888   # Get CDs by Nine Inch Nails
3889   my $rs = $schema->resultset('CD')->search(
3890     { 'artist.name' => 'Nine Inch Nails' },
3891     { join => 'artist' }
3892   );
3893
3894 Can also contain a hash reference to refer to the other relation's relations.
3895 For example:
3896
3897   package MyApp::Schema::Track;
3898   use base qw/DBIx::Class/;
3899   __PACKAGE__->table('track');
3900   __PACKAGE__->add_columns(qw/trackid cd position title/);
3901   __PACKAGE__->set_primary_key('trackid');
3902   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3903   1;
3904
3905   # In your application
3906   my $rs = $schema->resultset('Artist')->search(
3907     { 'track.title' => 'Teardrop' },
3908     {
3909       join     => { cd => 'track' },
3910       order_by => 'artist.name',
3911     }
3912   );
3913
3914 You need to use the relationship (not the table) name in  conditions,
3915 because they are aliased as such. The current table is aliased as "me", so
3916 you need to use me.column_name in order to avoid ambiguity. For example:
3917
3918   # Get CDs from 1984 with a 'Foo' track
3919   my $rs = $schema->resultset('CD')->search(
3920     {
3921       'me.year' => 1984,
3922       'tracks.name' => 'Foo'
3923     },
3924     { join => 'tracks' }
3925   );
3926
3927 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3928 similarly for a third time). For e.g.
3929
3930   my $rs = $schema->resultset('Artist')->search({
3931     'cds.title'   => 'Down to Earth',
3932     'cds_2.title' => 'Popular',
3933   }, {
3934     join => [ qw/cds cds/ ],
3935   });
3936
3937 will return a set of all artists that have both a cd with title 'Down
3938 to Earth' and a cd with title 'Popular'.
3939
3940 If you want to fetch related objects from other tables as well, see C<prefetch>
3941 below.
3942
3943 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3944
3945 =head2 prefetch
3946
3947 =over 4
3948
3949 =item Value: ($rel_name | \@rel_names | \%rel_names)
3950
3951 =back
3952
3953 Contains one or more relationships that should be fetched along with
3954 the main query (when they are accessed afterwards the data will
3955 already be available, without extra queries to the database).  This is
3956 useful for when you know you will need the related objects, because it
3957 saves at least one query:
3958
3959   my $rs = $schema->resultset('Tag')->search(
3960     undef,
3961     {
3962       prefetch => {
3963         cd => 'artist'
3964       }
3965     }
3966   );
3967
3968 The initial search results in SQL like the following:
3969
3970   SELECT tag.*, cd.*, artist.* FROM tag
3971   JOIN cd ON tag.cd = cd.cdid
3972   JOIN artist ON cd.artist = artist.artistid
3973
3974 L<DBIx::Class> has no need to go back to the database when we access the
3975 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3976 case.
3977
3978 Simple prefetches will be joined automatically, so there is no need
3979 for a C<join> attribute in the above search.
3980
3981 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3982 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3983 with an accessor type of 'single' or 'filter'). A more complex example that
3984 prefetches an artists cds, the tracks on those cds, and the tags associated
3985 with that artist is given below (assuming many-to-many from artists to tags):
3986
3987  my $rs = $schema->resultset('Artist')->search(
3988    undef,
3989    {
3990      prefetch => [
3991        { cds => 'tracks' },
3992        { artist_tags => 'tags' }
3993      ]
3994    }
3995  );
3996
3997
3998 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3999 attributes will be ignored.
4000
4001 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
4002 exactly as you might expect.
4003
4004 =over 4
4005
4006 =item *
4007
4008 Prefetch uses the L</cache> to populate the prefetched relationships. This
4009 may or may not be what you want.
4010
4011 =item *
4012
4013 If you specify a condition on a prefetched relationship, ONLY those
4014 rows that match the prefetched condition will be fetched into that relationship.
4015 This means that adding prefetch to a search() B<may alter> what is returned by
4016 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4017
4018   my $artist_rs = $schema->resultset('Artist')->search({
4019       'cds.year' => 2008,
4020   }, {
4021       join => 'cds',
4022   });
4023
4024   my $count = $artist_rs->first->cds->count;
4025
4026   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4027
4028   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4029
4030   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4031
4032 that cmp_ok() may or may not pass depending on the datasets involved. This
4033 behavior may or may not survive the 0.09 transition.
4034
4035 =back
4036
4037 =head2 page
4038
4039 =over 4
4040
4041 =item Value: $page
4042
4043 =back
4044
4045 Makes the resultset paged and specifies the page to retrieve. Effectively
4046 identical to creating a non-pages resultset and then calling ->page($page)
4047 on it.
4048
4049 If L<rows> attribute is not specified it defaults to 10 rows per page.
4050
4051 When you have a paged resultset, L</count> will only return the number
4052 of rows in the page. To get the total, use the L</pager> and call
4053 C<total_entries> on it.
4054
4055 =head2 rows
4056
4057 =over 4
4058
4059 =item Value: $rows
4060
4061 =back
4062
4063 Specifies the maximum number of rows for direct retrieval or the number of
4064 rows per page if the page attribute or method is used.
4065
4066 =head2 offset
4067
4068 =over 4
4069
4070 =item Value: $offset
4071
4072 =back
4073
4074 Specifies the (zero-based) row number for the  first row to be returned, or the
4075 of the first row of the first page if paging is used.
4076
4077 =head2 group_by
4078
4079 =over 4
4080
4081 =item Value: \@columns
4082
4083 =back
4084
4085 A arrayref of columns to group by. Can include columns of joined tables.
4086
4087   group_by => [qw/ column1 column2 ... /]
4088
4089 =head2 having
4090
4091 =over 4
4092
4093 =item Value: $condition
4094
4095 =back
4096
4097 HAVING is a select statement attribute that is applied between GROUP BY and
4098 ORDER BY. It is applied to the after the grouping calculations have been
4099 done.
4100
4101   having => { 'count_employee' => { '>=', 100 } }
4102
4103 or with an in-place function in which case literal SQL is required:
4104
4105   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4106
4107 =head2 distinct
4108
4109 =over 4
4110
4111 =item Value: (0 | 1)
4112
4113 =back
4114
4115 Set to 1 to group by all columns. If the resultset already has a group_by
4116 attribute, this setting is ignored and an appropriate warning is issued.
4117
4118 =head2 where
4119
4120 =over 4
4121
4122 Adds to the WHERE clause.
4123
4124   # only return rows WHERE deleted IS NULL for all searches
4125   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
4126
4127 Can be overridden by passing C<< { where => undef } >> as an attribute
4128 to a resultset.
4129
4130 =back
4131
4132 =head2 cache
4133
4134 Set to 1 to cache search results. This prevents extra SQL queries if you
4135 revisit rows in your ResultSet:
4136
4137   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4138
4139   while( my $artist = $resultset->next ) {
4140     ... do stuff ...
4141   }
4142
4143   $rs->first; # without cache, this would issue a query
4144
4145 By default, searches are not cached.
4146
4147 For more examples of using these attributes, see
4148 L<DBIx::Class::Manual::Cookbook>.
4149
4150 =head2 for
4151
4152 =over 4
4153
4154 =item Value: ( 'update' | 'shared' )
4155
4156 =back
4157
4158 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4159 ... FOR SHARED.
4160
4161 =cut
4162
4163 1;