lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs   = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: $source, \%$attrs
 195
 196 =item Return Value: $rs
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you won't need to construct a resultset manually.  You'll
 206 automatically get one from e.g. a L</search> called in scalar context:
 207
 208   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 209
 210 IMPORTANT: If called on an object, proxies to new_result instead so
 211
 212   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 213
 214 will return a CD object, not a ResultSet.
 215
 216 =cut
 217
 218 sub new {
 219   my $class = shift;
 220   return $class->new_result(@_) if ref $class;
 221
 222   my ($source, $attrs) = @_;
 223   $source = $source->resolve
 224     if $source->isa('DBIx::Class::ResultSourceHandle');
 225   $attrs = { %{$attrs||{}} };
 226
 227   if ($attrs->{page}) {
 228     $attrs->{rows} ||= 10;
 229   }
 230
 231   $attrs->{alias} ||= 'me';
 232
 233   my $self = bless {
 234     result_source => $source,
 235     cond => $attrs->{where},
 236     pager => undef,
 237     attrs => $attrs,
 238   }, $class;
 239
 240   # if there is a dark selector, this means we are already in a
 241   # chain and the cleanup/sanification was taken care of by
 242   # _search_rs already
 243   $self->_normalize_selection($attrs)
 244     unless $attrs->{_dark_selector};
 245
 246   $self->result_class(
 247     $attrs->{result_class} || $source->result_class
 248   );
 249
 250   $self;
 251 }
 252
 253 =head2 search
 254
 255 =over 4
 256
 257 =item Arguments: $cond, \%attrs?
 258
 259 =item Return Value: $resultset (scalar context) ||  @row_objs (list context)
 260
 261 =back
 262
 263   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 264   my $new_rs = $cd_rs->search({ year => 2005 });
 265
 266   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 267                  # year = 2005 OR year = 2004
 268
 269 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 270 returning a list of row objects instead. To avoid that, use L</search_rs>.
 271
 272 If you need to pass in additional attributes but no additional condition,
 273 call it as C<search(undef, \%attrs)>.
 274
 275   # "SELECT name, artistid FROM $artist_table"
 276   my @all_artists = $schema->resultset('Artist')->search(undef, {
 277     columns => [qw/name artistid/],
 278   });
 279
 280 For a list of attributes that can be passed to C<search>, see
 281 L</ATTRIBUTES>. For more examples of using this function, see
 282 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 283 documentation for the first argument, see L<SQL::Abstract>
 284 and its extension L<DBIx::Class::SQLMaker>.
 285
 286 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 287
 288 =head3 CAVEAT
 289
 290 Note that L</search> does not process/deflate any of the values passed in the
 291 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 292 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 293 manually that any value passed to this method will stringify to something the
 294 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 295 objects, for more info see:
 296 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 297
 298 =cut
 299
 300 sub search {
 301   my $self = shift;
 302   my $rs = $self->search_rs( @_ );
 303
 304   if (wantarray) {
 305     return $rs->all;
 306   }
 307   elsif (defined wantarray) {
 308     return $rs;
 309   }
 310   else {
 311     # we can be called by a relationship helper, which in
 312     # turn may be called in void context due to some braindead
 313     # overload or whatever else the user decided to be clever
 314     # at this particular day. Thus limit the exception to
 315     # external code calls only
 316     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 317       if (caller)[0] !~ /^\QDBIx::Class::/;
 318
 319     return ();
 320   }
 321 }
 322
 323 =head2 search_rs
 324
 325 =over 4
 326
 327 =item Arguments: $cond, \%attrs?
 328
 329 =item Return Value: $resultset
 330
 331 =back
 332
 333 This method does the same exact thing as search() except it will
 334 always return a resultset, even in list context.
 335
 336 =cut
 337
 338 sub search_rs {
 339   my $self = shift;
 340
 341   # Special-case handling for (undef, undef).
 342   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 343     @_ = ();
 344   }
 345
 346   my $call_attrs = {};
 347   if (@_ > 1) {
 348     if (ref $_[-1] eq 'HASH') {
 349       # copy for _normalize_selection
 350       $call_attrs = { %{ pop @_ } };
 351     }
 352     elsif (! defined $_[-1] ) {
 353       pop @_;   # search({}, undef)
 354     }
 355   }
 356
 357   # see if we can keep the cache (no $rs changes)
 358   my $cache;
 359   my %safe = (alias => 1, cache => 1);
 360   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 361     ! defined $_[0]
 362       or
 363     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 364       or
 365     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 366   )) {
 367     $cache = $self->get_cache;
 368   }
 369
 370   my $rsrc = $self->result_source;
 371
 372   my $old_attrs = { %{$self->{attrs}} };
 373   my $old_having = delete $old_attrs->{having};
 374   my $old_where = delete $old_attrs->{where};
 375
 376   my $new_attrs = { %$old_attrs };
 377
 378   # take care of call attrs (only if anything is changing)
 379   if (keys %$call_attrs) {
 380
 381     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 382
 383     # reset the current selector list if new selectors are supplied
 384     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 385       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 386     }
 387
 388     # Normalize the new selector list (operates on the passed-in attr structure)
 389     # Need to do it on every chain instead of only once on _resolved_attrs, in
 390     # order to allow detection of empty vs partial 'as'
 391     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 392       if $old_attrs->{_dark_selector};
 393     $self->_normalize_selection ($call_attrs);
 394
 395     # start with blind overwriting merge, exclude selector attrs
 396     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 397     delete @{$new_attrs}{@selector_attrs};
 398
 399     for (@selector_attrs) {
 400       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 401         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 402     }
 403
 404     # older deprecated name, use only if {columns} is not there
 405     if (my $c = delete $new_attrs->{cols}) {
 406       if ($new_attrs->{columns}) {
 407         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 408       }
 409       else {
 410         $new_attrs->{columns} = $c;
 411       }
 412     }
 413
 414
 415     # join/prefetch use their own crazy merging heuristics
 416     foreach my $key (qw/join prefetch/) {
 417       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 418         if exists $call_attrs->{$key};
 419     }
 420
 421     # stack binds together
 422     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 423   }
 424
 425
 426   # rip apart the rest of @_, parse a condition
 427   my $call_cond = do {
 428
 429     if (ref $_[0] eq 'HASH') {
 430       (keys %{$_[0]}) ? $_[0] : undef
 431     }
 432     elsif (@_ == 1) {
 433       $_[0]
 434     }
 435     elsif (@_ % 2) {
 436       $self->throw_exception('Odd number of arguments to search')
 437     }
 438     else {
 439       +{ @_ }
 440     }
 441
 442   } if @_;
 443
 444   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 445     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead';
 446   }
 447
 448   for ($old_where, $call_cond) {
 449     if (defined $_) {
 450       $new_attrs->{where} = $self->_stack_cond (
 451         $_, $new_attrs->{where}
 452       );
 453     }
 454   }
 455
 456   if (defined $old_having) {
 457     $new_attrs->{having} = $self->_stack_cond (
 458       $old_having, $new_attrs->{having}
 459     )
 460   }
 461
 462   my $rs = (ref $self)->new($rsrc, $new_attrs);
 463
 464   $rs->set_cache($cache) if ($cache);
 465
 466   return $rs;
 467 }
 468
 469 my $dark_sel_dumper;
 470 sub _normalize_selection {
 471   my ($self, $attrs) = @_;
 472
 473   # legacy syntax
 474   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 475     if exists $attrs->{include_columns};
 476
 477   # columns are always placed first, however
 478
 479   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 480   # delay the decision on whether to use a default select list ($rsrc->columns)
 481   # allowing stuff like the remove_columns helper to work
 482   #
 483   # select/as +select/+as pairs need special handling - the amount of select/as
 484   # elements in each pair does *not* have to be equal (think multicolumn
 485   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 486   # supplied at all) - try to infer the alias, either from the -as parameter
 487   # of the selector spec, or use the parameter whole if it looks like a column
 488   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 489   # is ok as well), but make sure no more additions to the 'as' chain take place
 490   for my $pref ('', '+') {
 491
 492     my ($sel, $as) = map {
 493       my $key = "${pref}${_}";
 494
 495       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 496         ? @{$attrs->{$key}}
 497         : $attrs->{$key} || ()
 498       ];
 499       delete $attrs->{$key};
 500       $val;
 501     } qw/select as/;
 502
 503     if (! @$as and ! @$sel ) {
 504       next;
 505     }
 506     elsif (@$as and ! @$sel) {
 507       $self->throw_exception(
 508         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 509       );
 510     }
 511     elsif( ! @$as ) {
 512       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 513       # if any @$as has been supplied we assume the user knows what (s)he is doing
 514       # and blindly keep stacking up pieces
 515       unless ($attrs->{_dark_selector}) {
 516         SELECTOR:
 517         for (@$sel) {
 518           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 519             push @$as, $_->{-as};
 520           }
 521           # assume any plain no-space, no-parenthesis string to be a column spec
 522           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 523           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 524             push @$as, $_;
 525           }
 526           # if all else fails - raise a flag that no more aliasing will be allowed
 527           else {
 528             $attrs->{_dark_selector} = {
 529               plus_stage => $pref,
 530               string => ($dark_sel_dumper ||= do {
 531                   require Data::Dumper::Concise;
 532                   Data::Dumper::Concise::DumperObject()->Indent(0);
 533                 })->Values([$_])->Dump
 534               ,
 535             };
 536             last SELECTOR;
 537           }
 538         }
 539       }
 540     }
 541     elsif (@$as < @$sel) {
 542       $self->throw_exception(
 543         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 544       );
 545     }
 546     elsif ($pref and $attrs->{_dark_selector}) {
 547       $self->throw_exception(
 548         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 549       );
 550     }
 551
 552
 553     # merge result
 554     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 555     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 556   }
 557 }
 558
 559 sub _stack_cond {
 560   my ($self, $left, $right) = @_;
 561
 562   # collapse single element top-level conditions
 563   # (single pass only, unlikely to need recursion)
 564   for ($left, $right) {
 565     if (ref $_ eq 'ARRAY') {
 566       if (@$_ == 0) {
 567         $_ = undef;
 568       }
 569       elsif (@$_ == 1) {
 570         $_ = $_->[0];
 571       }
 572     }
 573     elsif (ref $_ eq 'HASH') {
 574       my ($first, $more) = keys %$_;
 575
 576       # empty hash
 577       if (! defined $first) {
 578         $_ = undef;
 579       }
 580       # one element hash
 581       elsif (! defined $more) {
 582         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 583           $_ = $_->{'-and'};
 584         }
 585         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 586           $_ = $_->{'-or'};
 587         }
 588       }
 589     }
 590   }
 591
 592   # merge hashes with weeding out of duplicates (simple cases only)
 593   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 594
 595     # shallow copy to destroy
 596     $right = { %$right };
 597     for (grep { exists $right->{$_} } keys %$left) {
 598       # the use of eq_deeply here is justified - the rhs of an
 599       # expression can contain a lot of twisted weird stuff
 600       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 601     }
 602
 603     $right = undef unless keys %$right;
 604   }
 605
 606
 607   if (defined $left xor defined $right) {
 608     return defined $left ? $left : $right;
 609   }
 610   elsif (! defined $left) {
 611     return undef;
 612   }
 613   else {
 614     return { -and => [ $left, $right ] };
 615   }
 616 }
 617
 618 =head2 search_literal
 619
 620 =over 4
 621
 622 =item Arguments: $sql_fragment, @bind_values
 623
 624 =item Return Value: $resultset (scalar context) || @row_objs (list context)
 625
 626 =back
 627
 628   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 629   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 630
 631 Pass a literal chunk of SQL to be added to the conditional part of the
 632 resultset query.
 633
 634 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 635 only be used in that context. C<search_literal> is a convenience method.
 636 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 637 columns are bound correctly, use C<search>.
 638
 639 Example of how to use C<search> instead of C<search_literal>
 640
 641   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 642   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 643
 644
 645 See L<DBIx::Class::Manual::Cookbook/Searching> and
 646 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 647 require C<search_literal>.
 648
 649 =cut
 650
 651 sub search_literal {
 652   my ($self, $sql, @bind) = @_;
 653   my $attr;
 654   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 655     $attr = pop @bind;
 656   }
 657   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 658 }
 659
 660 =head2 find
 661
 662 =over 4
 663
 664 =item Arguments: \%columns_values | @pk_values, \%attrs?
 665
 666 =item Return Value: $row_object | undef
 667
 668 =back
 669
 670 Finds and returns a single row based on supplied criteria. Takes either a
 671 hashref with the same format as L</create> (including inference of foreign
 672 keys from related objects), or a list of primary key values in the same
 673 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 674 declaration on the L</result_source>.
 675
 676 In either case an attempt is made to combine conditions already existing on
 677 the resultset with the condition passed to this method.
 678
 679 To aid with preparing the correct query for the storage you may supply the
 680 C<key> attribute, which is the name of a
 681 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 682 unique constraint corresponding to the
 683 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 684 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 685 to construct a query that satisfies the named unique constraint fully (
 686 non-NULL values for each column member of the constraint) an exception is
 687 thrown.
 688
 689 If no C<key> is specified, the search is carried over all unique constraints
 690 which are fully defined by the available condition.
 691
 692 If no such constraint is found, C<find> currently defaults to a simple
 693 C<< search->(\%column_values) >> which may or may not do what you expect.
 694 Note that this fallback behavior may be deprecated in further versions. If
 695 you need to search with arbitrary conditions - use L</search>. If the query
 696 resulting from this fallback produces more than one row, a warning to the
 697 effect is issued, though only the first row is constructed and returned as
 698 C<$row_object>.
 699
 700 In addition to C<key>, L</find> recognizes and applies standard
 701 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 702
 703 Note that if you have extra concerns about the correctness of the resulting
 704 query you need to specify the C<key> attribute and supply the entire condition
 705 as an argument to find (since it is not always possible to perform the
 706 combination of the resultset condition with the supplied one, especially if
 707 the resultset condition contains literal sql).
 708
 709 For example, to find a row by its primary key:
 710
 711   my $cd = $schema->resultset('CD')->find(5);
 712
 713 You can also find a row by a specific unique constraint:
 714
 715   my $cd = $schema->resultset('CD')->find(
 716     {
 717       artist => 'Massive Attack',
 718       title  => 'Mezzanine',
 719     },
 720     { key => 'cd_artist_title' }
 721   );
 722
 723 See also L</find_or_create> and L</update_or_create>.
 724
 725 =cut
 726
 727 sub find {
 728   my $self = shift;
 729   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 730
 731   my $rsrc = $self->result_source;
 732
 733   my $constraint_name;
 734   if (exists $attrs->{key}) {
 735     $constraint_name = defined $attrs->{key}
 736       ? $attrs->{key}
 737       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 738     ;
 739   }
 740
 741   # Parse out the condition from input
 742   my $call_cond;
 743
 744   if (ref $_[0] eq 'HASH') {
 745     $call_cond = { %{$_[0]} };
 746   }
 747   else {
 748     # if only values are supplied we need to default to 'primary'
 749     $constraint_name = 'primary' unless defined $constraint_name;
 750
 751     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 752
 753     $self->throw_exception(
 754       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 755     ) unless @c_cols;
 756
 757     $self->throw_exception (
 758       'find() expects either a column/value hashref, or a list of values '
 759     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 760     ) unless @c_cols == @_;
 761
 762     $call_cond = {};
 763     @{$call_cond}{@c_cols} = @_;
 764   }
 765
 766   my %related;
 767   for my $key (keys %$call_cond) {
 768     if (
 769       my $keyref = ref($call_cond->{$key})
 770         and
 771       my $relinfo = $rsrc->relationship_info($key)
 772     ) {
 773       my $val = delete $call_cond->{$key};
 774
 775       next if $keyref eq 'ARRAY'; # has_many for multi_create
 776
 777       my $rel_q = $rsrc->_resolve_condition(
 778         $relinfo->{cond}, $val, $key, $key
 779       );
 780       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 781       @related{keys %$rel_q} = values %$rel_q;
 782     }
 783   }
 784
 785   # relationship conditions take precedence (?)
 786   @{$call_cond}{keys %related} = values %related;
 787
 788   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 789   my $final_cond;
 790   if (defined $constraint_name) {
 791     $final_cond = $self->_qualify_cond_columns (
 792
 793       $self->_build_unique_cond (
 794         $constraint_name,
 795         $call_cond,
 796       ),
 797
 798       $alias,
 799     );
 800   }
 801   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 802     # This means that we got here after a merger of relationship conditions
 803     # in ::Relationship::Base::search_related (the row method), and furthermore
 804     # the relationship is of the 'single' type. This means that the condition
 805     # provided by the relationship (already attached to $self) is sufficient,
 806     # as there can be only one row in the database that would satisfy the
 807     # relationship
 808   }
 809   else {
 810     # no key was specified - fall down to heuristics mode:
 811     # run through all unique queries registered on the resultset, and
 812     # 'OR' all qualifying queries together
 813     my (@unique_queries, %seen_column_combinations);
 814     for my $c_name ($rsrc->unique_constraint_names) {
 815       next if $seen_column_combinations{
 816         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 817       }++;
 818
 819       push @unique_queries, try {
 820         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 821       } || ();
 822     }
 823
 824     $final_cond = @unique_queries
 825       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 826       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 827     ;
 828   }
 829
 830   # Run the query, passing the result_class since it should propagate for find
 831   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 832   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 833     my $row = $rs->next;
 834     carp "Query returned more than one row" if $rs->next;
 835     return $row;
 836   }
 837   else {
 838     return $rs->single;
 839   }
 840 }
 841
 842 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 843 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 844 #
 845 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 846 # condition. It is provided for overrides until a saner way forward is devised
 847 #
 848 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 849 # the road. Please adjust your tests accordingly to catch this situation early
 850 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 851 #
 852 # The method will not be removed without an adequately complete replacement
 853 # for strict-mode enforcement
 854 sub _non_unique_find_fallback {
 855   my ($self, $cond, $attrs) = @_;
 856
 857   return $self->_qualify_cond_columns(
 858     $cond,
 859     exists $attrs->{alias}
 860       ? $attrs->{alias}
 861       : $self->{attrs}{alias}
 862   );
 863 }
 864
 865
 866 sub _qualify_cond_columns {
 867   my ($self, $cond, $alias) = @_;
 868
 869   my %aliased = %$cond;
 870   for (keys %aliased) {
 871     $aliased{"$alias.$_"} = delete $aliased{$_}
 872       if $_ !~ /\./;
 873   }
 874
 875   return \%aliased;
 876 }
 877
 878 sub _build_unique_cond {
 879   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 880
 881   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 882
 883   # combination may fail if $self->{cond} is non-trivial
 884   my ($final_cond) = try {
 885     $self->_merge_with_rscond ($extra_cond)
 886   } catch {
 887     +{ %$extra_cond }
 888   };
 889
 890   # trim out everything not in $columns
 891   $final_cond = { map {
 892     exists $final_cond->{$_}
 893       ? ( $_ => $final_cond->{$_} )
 894       : ()
 895   } @c_cols };
 896
 897   if (my @missing = grep
 898     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 899     (@c_cols)
 900   ) {
 901     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 902       $constraint_name,
 903       join (', ', map { "'$_'" } @missing),
 904     ) );
 905   }
 906
 907   if (
 908     !$croak_on_null
 909       and
 910     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 911       and
 912     my @undefs = grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 913   ) {
 914     carp_unique ( sprintf (
 915       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 916     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 917     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 918       $constraint_name,
 919       join (', ', map { "'$_'" } @undefs),
 920     ));
 921   }
 922
 923   return $final_cond;
 924 }
 925
 926 =head2 search_related
 927
 928 =over 4
 929
 930 =item Arguments: $rel, $cond, \%attrs?
 931
 932 =item Return Value: $new_resultset (scalar context) || @row_objs (list context)
 933
 934 =back
 935
 936   $new_rs = $cd_rs->search_related('artist', {
 937     name => 'Emo-R-Us',
 938   });
 939
 940 Searches the specified relationship, optionally specifying a condition and
 941 attributes for matching records. See L</ATTRIBUTES> for more information.
 942
 943 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 944 returning a list of row objects instead. To avoid that, use L</search_related_rs>.
 945
 946 See also L</search_related_rs>.
 947
 948 =cut
 949
 950 sub search_related {
 951   return shift->related_resultset(shift)->search(@_);
 952 }
 953
 954 =head2 search_related_rs
 955
 956 This method works exactly the same as search_related, except that
 957 it guarantees a resultset, even in list context.
 958
 959 =cut
 960
 961 sub search_related_rs {
 962   return shift->related_resultset(shift)->search_rs(@_);
 963 }
 964
 965 =head2 cursor
 966
 967 =over 4
 968
 969 =item Arguments: none
 970
 971 =item Return Value: $cursor
 972
 973 =back
 974
 975 Returns a storage-driven cursor to the given resultset. See
 976 L<DBIx::Class::Cursor> for more information.
 977
 978 =cut
 979
 980 sub cursor {
 981   my ($self) = @_;
 982
 983   my $attrs = $self->_resolved_attrs_copy;
 984
 985   return $self->{cursor}
 986     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 987           $attrs->{where},$attrs);
 988 }
 989
 990 =head2 single
 991
 992 =over 4
 993
 994 =item Arguments: $cond?
 995
 996 =item Return Value: $row_object | undef
 997
 998 =back
 999
1000   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1001
1002 Inflates the first result without creating a cursor if the resultset has
1003 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1004 of L</search>.
1005
1006 While this method can take an optional search condition (just like L</search>)
1007 being a fast-code-path it does not recognize search attributes. If you need to
1008 add extra joins or similar, call L</search> and then chain-call L</single> on the
1009 L<DBIx::Class::ResultSet> returned.
1010
1011 =over
1012
1013 =item B<Note>
1014
1015 As of 0.08100, this method enforces the assumption that the preceding
1016 query returns only one row. If more than one row is returned, you will receive
1017 a warning:
1018
1019   Query returned more than one row
1020
1021 In this case, you should be using L</next> or L</find> instead, or if you really
1022 know what you are doing, use the L</rows> attribute to explicitly limit the size
1023 of the resultset.
1024
1025 This method will also throw an exception if it is called on a resultset prefetching
1026 has_many, as such a prefetch implies fetching multiple rows from the database in
1027 order to assemble the resulting object.
1028
1029 =back
1030
1031 =cut
1032
1033 sub single {
1034   my ($self, $where) = @_;
1035   if(@_ > 2) {
1036       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1037   }
1038
1039   my $attrs = $self->_resolved_attrs_copy;
1040
1041   if (keys %{$attrs->{collapse}}) {
1042     $self->throw_exception(
1043       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1044     );
1045   }
1046
1047   if ($where) {
1048     if (defined $attrs->{where}) {
1049       $attrs->{where} = {
1050         '-and' =>
1051             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1052                $where, delete $attrs->{where} ]
1053       };
1054     } else {
1055       $attrs->{where} = $where;
1056     }
1057   }
1058
1059   my @data = $self->result_source->storage->select_single(
1060     $attrs->{from}, $attrs->{select},
1061     $attrs->{where}, $attrs
1062   );
1063
1064   return (@data ? ($self->_construct_object(@data))[0] : undef);
1065 }
1066
1067
1068 # _collapse_query
1069 #
1070 # Recursively collapse the query, accumulating values for each column.
1071
1072 sub _collapse_query {
1073   my ($self, $query, $collapsed) = @_;
1074
1075   $collapsed ||= {};
1076
1077   if (ref $query eq 'ARRAY') {
1078     foreach my $subquery (@$query) {
1079       next unless ref $subquery;  # -or
1080       $collapsed = $self->_collapse_query($subquery, $collapsed);
1081     }
1082   }
1083   elsif (ref $query eq 'HASH') {
1084     if (keys %$query and (keys %$query)[0] eq '-and') {
1085       foreach my $subquery (@{$query->{-and}}) {
1086         $collapsed = $self->_collapse_query($subquery, $collapsed);
1087       }
1088     }
1089     else {
1090       foreach my $col (keys %$query) {
1091         my $value = $query->{$col};
1092         $collapsed->{$col}{$value}++;
1093       }
1094     }
1095   }
1096
1097   return $collapsed;
1098 }
1099
1100 =head2 get_column
1101
1102 =over 4
1103
1104 =item Arguments: $cond?
1105
1106 =item Return Value: $resultsetcolumn
1107
1108 =back
1109
1110   my $max_length = $rs->get_column('length')->max;
1111
1112 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1113
1114 =cut
1115
1116 sub get_column {
1117   my ($self, $column) = @_;
1118   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1119   return $new;
1120 }
1121
1122 =head2 search_like
1123
1124 =over 4
1125
1126 =item Arguments: $cond, \%attrs?
1127
1128 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1129
1130 =back
1131
1132   # WHERE title LIKE '%blue%'
1133   $cd_rs = $rs->search_like({ title => '%blue%'});
1134
1135 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1136 that this is simply a convenience method retained for ex Class::DBI users.
1137 You most likely want to use L</search> with specific operators.
1138
1139 For more information, see L<DBIx::Class::Manual::Cookbook>.
1140
1141 This method is deprecated and will be removed in 0.09. Use L</search()>
1142 instead. An example conversion is:
1143
1144   ->search_like({ foo => 'bar' });
1145
1146   # Becomes
1147
1148   ->search({ foo => { like => 'bar' } });
1149
1150 =cut
1151
1152 sub search_like {
1153   my $class = shift;
1154   carp_unique (
1155     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1156    .' Instead use ->search({ x => { -like => "y%" } })'
1157    .' (note the outer pair of {}s - they are important!)'
1158   );
1159   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1160   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1161   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1162   return $class->search($query, { %$attrs });
1163 }
1164
1165 =head2 slice
1166
1167 =over 4
1168
1169 =item Arguments: $first, $last
1170
1171 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1172
1173 =back
1174
1175 Returns a resultset or object list representing a subset of elements from the
1176 resultset slice is called on. Indexes are from 0, i.e., to get the first
1177 three records, call:
1178
1179   my ($one, $two, $three) = $rs->slice(0, 2);
1180
1181 =cut
1182
1183 sub slice {
1184   my ($self, $min, $max) = @_;
1185   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1186   $attrs->{offset} = $self->{attrs}{offset} || 0;
1187   $attrs->{offset} += $min;
1188   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1189   return $self->search(undef, $attrs);
1190   #my $slice = (ref $self)->new($self->result_source, $attrs);
1191   #return (wantarray ? $slice->all : $slice);
1192 }
1193
1194 =head2 next
1195
1196 =over 4
1197
1198 =item Arguments: none
1199
1200 =item Return Value: $result | undef
1201
1202 =back
1203
1204 Returns the next element in the resultset (C<undef> is there is none).
1205
1206 Can be used to efficiently iterate over records in the resultset:
1207
1208   my $rs = $schema->resultset('CD')->search;
1209   while (my $cd = $rs->next) {
1210     print $cd->title;
1211   }
1212
1213 Note that you need to store the resultset object, and call C<next> on it.
1214 Calling C<< resultset('Table')->next >> repeatedly will always return the
1215 first record from the resultset.
1216
1217 =cut
1218
1219 sub next {
1220   my ($self) = @_;
1221   if (my $cache = $self->get_cache) {
1222     $self->{all_cache_position} ||= 0;
1223     return $cache->[$self->{all_cache_position}++];
1224   }
1225   if ($self->{attrs}{cache}) {
1226     delete $self->{pager};
1227     $self->{all_cache_position} = 1;
1228     return ($self->all)[0];
1229   }
1230   if ($self->{stashed_objects}) {
1231     my $obj = shift(@{$self->{stashed_objects}});
1232     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1233     return $obj;
1234   }
1235   my @row = (
1236     exists $self->{stashed_row}
1237       ? @{delete $self->{stashed_row}}
1238       : $self->cursor->next
1239   );
1240   return undef unless (@row);
1241   my ($row, @more) = $self->_construct_object(@row);
1242   $self->{stashed_objects} = \@more if @more;
1243   return $row;
1244 }
1245
1246 sub _construct_object {
1247   my ($self, @row) = @_;
1248
1249   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1250     or return ();
1251   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1252   @new = $self->{_attrs}{record_filter}->(@new)
1253     if exists $self->{_attrs}{record_filter};
1254   return @new;
1255 }
1256
1257 sub _collapse_result {
1258   my ($self, $as_proto, $row) = @_;
1259
1260   my @copy = @$row;
1261
1262   # 'foo'         => [ undef, 'foo' ]
1263   # 'foo.bar'     => [ 'foo', 'bar' ]
1264   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1265
1266   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1267
1268   my %collapse = %{$self->{_attrs}{collapse}||{}};
1269
1270   my @pri_index;
1271
1272   # if we're doing collapsing (has_many prefetch) we need to grab records
1273   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1274   # we know we don't have to bother.
1275
1276   # the reason for not using the collapse stuff directly is because if you
1277   # had for e.g. two artists in a row with no cds, the collapse info for
1278   # both would be NULL (undef) so you'd lose the second artist
1279
1280   # store just the index so we can check the array positions from the row
1281   # without having to contruct the full hash
1282
1283   if (keys %collapse) {
1284     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1285     foreach my $i (0 .. $#construct_as) {
1286       next if defined($construct_as[$i][0]); # only self table
1287       if (delete $pri{$construct_as[$i][1]}) {
1288         push(@pri_index, $i);
1289       }
1290       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1291     }
1292   }
1293
1294   # no need to do an if, it'll be empty if @pri_index is empty anyway
1295
1296   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1297
1298   my @const_rows;
1299
1300   do { # no need to check anything at the front, we always want the first row
1301
1302     my %const;
1303
1304     foreach my $this_as (@construct_as) {
1305       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1306     }
1307
1308     push(@const_rows, \%const);
1309
1310   } until ( # no pri_index => no collapse => drop straight out
1311       !@pri_index
1312     or
1313       do { # get another row, stash it, drop out if different PK
1314
1315         @copy = $self->cursor->next;
1316         $self->{stashed_row} = \@copy;
1317
1318         # last thing in do block, counts as true if anything doesn't match
1319
1320         # check xor defined first for NULL vs. NOT NULL then if one is
1321         # defined the other must be so check string equality
1322
1323         grep {
1324           (defined $pri_vals{$_} ^ defined $copy[$_])
1325           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1326         } @pri_index;
1327       }
1328   );
1329
1330   my $alias = $self->{attrs}{alias};
1331   my $info = [];
1332
1333   my %collapse_pos;
1334
1335   my @const_keys;
1336
1337   foreach my $const (@const_rows) {
1338     scalar @const_keys or do {
1339       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1340     };
1341     foreach my $key (@const_keys) {
1342       if (length $key) {
1343         my $target = $info;
1344         my @parts = split(/\./, $key);
1345         my $cur = '';
1346         my $data = $const->{$key};
1347         foreach my $p (@parts) {
1348           $target = $target->[1]->{$p} ||= [];
1349           $cur .= ".${p}";
1350           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1351             # collapsing at this point and on final part
1352             my $pos = $collapse_pos{$cur};
1353             CK: foreach my $ck (@ckey) {
1354               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1355                 $collapse_pos{$cur} = $data;
1356                 delete @collapse_pos{ # clear all positioning for sub-entries
1357                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1358                 };
1359                 push(@$target, []);
1360                 last CK;
1361               }
1362             }
1363           }
1364           if (exists $collapse{$cur}) {
1365             $target = $target->[-1];
1366           }
1367         }
1368         $target->[0] = $data;
1369       } else {
1370         $info->[0] = $const->{$key};
1371       }
1372     }
1373   }
1374
1375   return $info;
1376 }
1377
1378 =head2 result_source
1379
1380 =over 4
1381
1382 =item Arguments: $result_source?
1383
1384 =item Return Value: $result_source
1385
1386 =back
1387
1388 An accessor for the primary ResultSource object from which this ResultSet
1389 is derived.
1390
1391 =head2 result_class
1392
1393 =over 4
1394
1395 =item Arguments: $result_class?
1396
1397 =item Return Value: $result_class
1398
1399 =back
1400
1401 An accessor for the class to use when creating row objects. Defaults to
1402 C<< result_source->result_class >> - which in most cases is the name of the
1403 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1404
1405 Note that changing the result_class will also remove any components
1406 that were originally loaded in the source class via
1407 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1408 in the original source class will not run.
1409
1410 =cut
1411
1412 sub result_class {
1413   my ($self, $result_class) = @_;
1414   if ($result_class) {
1415     unless (ref $result_class) { # don't fire this for an object
1416       $self->ensure_class_loaded($result_class);
1417     }
1418     $self->_result_class($result_class);
1419     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1420     # permit the user to set result class on one result set only; it only
1421     # chains if provided to search()
1422     #$self->{attrs}{result_class} = $result_class if ref $self;
1423   }
1424   $self->_result_class;
1425 }
1426
1427 =head2 count
1428
1429 =over 4
1430
1431 =item Arguments: $cond, \%attrs??
1432
1433 =item Return Value: $count
1434
1435 =back
1436
1437 Performs an SQL C<COUNT> with the same query as the resultset was built
1438 with to find the number of elements. Passing arguments is equivalent to
1439 C<< $rs->search ($cond, \%attrs)->count >>
1440
1441 =cut
1442
1443 sub count {
1444   my $self = shift;
1445   return $self->search(@_)->count if @_ and defined $_[0];
1446   return scalar @{ $self->get_cache } if $self->get_cache;
1447
1448   my $attrs = $self->_resolved_attrs_copy;
1449
1450   # this is a little optimization - it is faster to do the limit
1451   # adjustments in software, instead of a subquery
1452   my $rows = delete $attrs->{rows};
1453   my $offset = delete $attrs->{offset};
1454
1455   my $crs;
1456   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1457     $crs = $self->_count_subq_rs ($attrs);
1458   }
1459   else {
1460     $crs = $self->_count_rs ($attrs);
1461   }
1462   my $count = $crs->next;
1463
1464   $count -= $offset if $offset;
1465   $count = $rows if $rows and $rows < $count;
1466   $count = 0 if ($count < 0);
1467
1468   return $count;
1469 }
1470
1471 =head2 count_rs
1472
1473 =over 4
1474
1475 =item Arguments: $cond, \%attrs??
1476
1477 =item Return Value: $count_rs
1478
1479 =back
1480
1481 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1482 This can be very handy for subqueries:
1483
1484   ->search( { amount => $some_rs->count_rs->as_query } )
1485
1486 As with regular resultsets the SQL query will be executed only after
1487 the resultset is accessed via L</next> or L</all>. That would return
1488 the same single value obtainable via L</count>.
1489
1490 =cut
1491
1492 sub count_rs {
1493   my $self = shift;
1494   return $self->search(@_)->count_rs if @_;
1495
1496   # this may look like a lack of abstraction (count() does about the same)
1497   # but in fact an _rs *must* use a subquery for the limits, as the
1498   # software based limiting can not be ported if this $rs is to be used
1499   # in a subquery itself (i.e. ->as_query)
1500   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1501     return $self->_count_subq_rs;
1502   }
1503   else {
1504     return $self->_count_rs;
1505   }
1506 }
1507
1508 #
1509 # returns a ResultSetColumn object tied to the count query
1510 #
1511 sub _count_rs {
1512   my ($self, $attrs) = @_;
1513
1514   my $rsrc = $self->result_source;
1515   $attrs ||= $self->_resolved_attrs;
1516
1517   my $tmp_attrs = { %$attrs };
1518   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1519   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1520
1521   # overwrite the selector (supplied by the storage)
1522   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1523   $tmp_attrs->{as} = 'count';
1524   delete @{$tmp_attrs}{qw/columns/};
1525
1526   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1527
1528   return $tmp_rs;
1529 }
1530
1531 #
1532 # same as above but uses a subquery
1533 #
1534 sub _count_subq_rs {
1535   my ($self, $attrs) = @_;
1536
1537   my $rsrc = $self->result_source;
1538   $attrs ||= $self->_resolved_attrs;
1539
1540   my $sub_attrs = { %$attrs };
1541   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1542   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1543
1544   # if we multi-prefetch we group_by something unique, as this is what we would
1545   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1546   if ( keys %{$attrs->{collapse}}  ) {
1547     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1548       $rsrc->_identifying_column_set || $self->throw_exception(
1549         'Unable to construct a unique group_by criteria properly collapsing the '
1550       . 'has_many prefetch before count()'
1551       );
1552     } ]
1553   }
1554
1555   # Calculate subquery selector
1556   if (my $g = $sub_attrs->{group_by}) {
1557
1558     my $sql_maker = $rsrc->storage->sql_maker;
1559
1560     # necessary as the group_by may refer to aliased functions
1561     my $sel_index;
1562     for my $sel (@{$attrs->{select}}) {
1563       $sel_index->{$sel->{-as}} = $sel
1564         if (ref $sel eq 'HASH' and $sel->{-as});
1565     }
1566
1567     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1568     # also look for named aggregates referred in the having clause
1569     # having often contains scalarrefs - thus parse it out entirely
1570     my @parts = @$g;
1571     if ($attrs->{having}) {
1572       local $sql_maker->{having_bind};
1573       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1574       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1575       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1576         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1577         # if we don't unset it we screw up retarded but unfortunately working
1578         # 'MAX(foo.bar)' => { '>', 3 }
1579         $sql_maker->{name_sep} = '';
1580       }
1581
1582       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1583
1584       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1585
1586       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1587       # and if all fails for an utterly naive quoted scalar-with-function
1588       while ($sql =~ /
1589         $rquote $sep $lquote (.+?) $rquote
1590           |
1591         [\s,] \w+ \. (\w+) [\s,]
1592           |
1593         [\s,] $lquote (.+?) $rquote [\s,]
1594       /gx) {
1595         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1596       }
1597     }
1598
1599     for (@parts) {
1600       my $colpiece = $sel_index->{$_} || $_;
1601
1602       # unqualify join-based group_by's. Arcane but possible query
1603       # also horrible horrible hack to alias a column (not a func.)
1604       # (probably need to introduce SQLA syntax)
1605       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1606         my $as = $colpiece;
1607         $as =~ s/\./__/;
1608         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1609       }
1610       push @{$sub_attrs->{select}}, $colpiece;
1611     }
1612   }
1613   else {
1614     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1615     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1616   }
1617
1618   return $rsrc->resultset_class
1619                ->new ($rsrc, $sub_attrs)
1620                 ->as_subselect_rs
1621                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1622                   ->get_column ('count');
1623 }
1624
1625 sub _bool {
1626   return 1;
1627 }
1628
1629 =head2 count_literal
1630
1631 =over 4
1632
1633 =item Arguments: $sql_fragment, @bind_values
1634
1635 =item Return Value: $count
1636
1637 =back
1638
1639 Counts the results in a literal query. Equivalent to calling L</search_literal>
1640 with the passed arguments, then L</count>.
1641
1642 =cut
1643
1644 sub count_literal { shift->search_literal(@_)->count; }
1645
1646 =head2 all
1647
1648 =over 4
1649
1650 =item Arguments: none
1651
1652 =item Return Value: @objects
1653
1654 =back
1655
1656 Returns all elements in the resultset.
1657
1658 =cut
1659
1660 sub all {
1661   my $self = shift;
1662   if(@_) {
1663       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1664   }
1665
1666   return @{ $self->get_cache } if $self->get_cache;
1667
1668   my @obj;
1669
1670   if (keys %{$self->_resolved_attrs->{collapse}}) {
1671     # Using $self->cursor->all is really just an optimisation.
1672     # If we're collapsing has_many prefetches it probably makes
1673     # very little difference, and this is cleaner than hacking
1674     # _construct_object to survive the approach
1675     $self->cursor->reset;
1676     my @row = $self->cursor->next;
1677     while (@row) {
1678       push(@obj, $self->_construct_object(@row));
1679       @row = (exists $self->{stashed_row}
1680                ? @{delete $self->{stashed_row}}
1681                : $self->cursor->next);
1682     }
1683   } else {
1684     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1685   }
1686
1687   $self->set_cache(\@obj) if $self->{attrs}{cache};
1688
1689   return @obj;
1690 }
1691
1692 =head2 reset
1693
1694 =over 4
1695
1696 =item Arguments: none
1697
1698 =item Return Value: $self
1699
1700 =back
1701
1702 Resets the resultset's cursor, so you can iterate through the elements again.
1703 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1704 another query.
1705
1706 =cut
1707
1708 sub reset {
1709   my ($self) = @_;
1710   delete $self->{_attrs} if exists $self->{_attrs};
1711   $self->{all_cache_position} = 0;
1712   $self->cursor->reset;
1713   return $self;
1714 }
1715
1716 =head2 first
1717
1718 =over 4
1719
1720 =item Arguments: none
1721
1722 =item Return Value: $object | undef
1723
1724 =back
1725
1726 Resets the resultset and returns an object for the first result (or C<undef>
1727 if the resultset is empty).
1728
1729 =cut
1730
1731 sub first {
1732   return $_[0]->reset->next;
1733 }
1734
1735
1736 # _rs_update_delete
1737 #
1738 # Determines whether and what type of subquery is required for the $rs operation.
1739 # If grouping is necessary either supplies its own, or verifies the current one
1740 # After all is done delegates to the proper storage method.
1741
1742 sub _rs_update_delete {
1743   my ($self, $op, $values) = @_;
1744
1745   my $cond = $self->{cond};
1746   my $rsrc = $self->result_source;
1747   my $storage = $rsrc->schema->storage;
1748
1749   my $attrs = { %{$self->_resolved_attrs} };
1750
1751   # "needs" is a strong word here - if the subquery is part of an IN clause - no point of
1752   # even adding the group_by. It will really be used only when composing a poor-man's
1753   # multicolumn-IN equivalent OR set
1754   my $needs_group_by_subq = defined $attrs->{group_by};
1755
1756   # simplify the joinmap and maybe decide if a grouping (and thus subquery) is necessary
1757   my $relation_classifications;
1758   if (ref($attrs->{from}) eq 'ARRAY') {
1759     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $cond, $attrs);
1760
1761     $relation_classifications = $storage->_resolve_aliastypes_from_select_args (
1762       [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1763       $attrs->{select},
1764       $cond,
1765       $attrs
1766     ) unless $needs_group_by_subq;  # we already know we need a group, no point of resolving them
1767   }
1768   else {
1769     $needs_group_by_subq ||= 1; # if {from} is unparseable assume the worst
1770   }
1771
1772   $needs_group_by_subq ||= exists $relation_classifications->{multiplying};
1773
1774   # if no subquery - life is easy-ish
1775   unless (
1776     $needs_group_by_subq
1777       or
1778     keys %$relation_classifications # if any joins at all - need to wrap a subq
1779       or
1780     $self->_has_resolved_attr(qw/rows offset/) # limits call for a subq
1781   ) {
1782     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1783     # a condition containing 'me' or other table prefixes will not work
1784     # at all. What this code tries to do (badly) is to generate a condition
1785     # with the qualifiers removed, by exploiting the quote mechanism of sqla
1786     #
1787     # this is atrocious and should be replaced by normal sqla introspection
1788     # one sunny day
1789     my ($sql, @bind) = do {
1790       my $sqla = $rsrc->storage->sql_maker;
1791       local $sqla->{_dequalify_idents} = 1;
1792       $sqla->_recurse_where($self->{cond});
1793     } if $self->{cond};
1794
1795     return $rsrc->storage->$op(
1796       $rsrc,
1797       $op eq 'update' ? $values : (),
1798       $self->{cond} ? \[$sql, @bind] : (),
1799     );
1800   }
1801
1802   # we got this far - means it is time to wrap a subquery
1803   my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1804     sprintf(
1805       "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1806       $op,
1807       $rsrc->source_name,
1808     )
1809   );
1810   my $existing_group_by = delete $attrs->{group_by};
1811
1812   # make a new $rs selecting only the PKs (that's all we really need for the subq)
1813   delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1814   $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1815   $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1816   my $subrs = (ref $self)->new($rsrc, $attrs);
1817
1818   if (@$idcols == 1) {
1819     return $storage->$op (
1820       $rsrc,
1821       $op eq 'update' ? $values : (),
1822       { $idcols->[0] => { -in => $subrs->as_query } },
1823     );
1824   }
1825   elsif ($storage->_use_multicolumn_in) {
1826     # This is hideously ugly, but SQLA does not understand multicol IN expressions
1827     my $sql_maker = $storage->sql_maker;
1828     my ($sql, @bind) = @${$subrs->as_query};
1829     $sql = sprintf ('(%s) IN %s', # the as_query already comes with a set of parenthesis
1830       join (', ', map { $sql_maker->_quote ($_) } @$idcols),
1831       $sql,
1832     );
1833
1834     return $storage->$op (
1835       $rsrc,
1836       $op eq 'update' ? $values : (),
1837       \[$sql, @bind],
1838     );
1839   }
1840   else {
1841     # if all else fails - get all primary keys and operate over a ORed set
1842     # wrap in a transaction for consistency
1843     # this is where the group_by starts to matter
1844     my $subq_group_by;
1845     if ($needs_group_by_subq) {
1846       $subq_group_by = $attrs->{columns};
1847
1848       # make sure if there is a supplied group_by it matches the columns compiled above
1849       # perfectly. Anything else can not be sanely executed on most databases so croak
1850       # right then and there
1851       if ($existing_group_by) {
1852         my @current_group_by = map
1853           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1854           @$existing_group_by
1855         ;
1856
1857         if (
1858           join ("\x00", sort @current_group_by)
1859             ne
1860           join ("\x00", sort @$subq_group_by )
1861         ) {
1862           $self->throw_exception (
1863             "You have just attempted a $op operation on a resultset which does group_by"
1864             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1865             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1866             . ' kind of queries. Please retry the operation with a modified group_by or'
1867             . ' without using one at all.'
1868           );
1869         }
1870       }
1871     }
1872
1873     my $guard = $storage->txn_scope_guard;
1874
1875     my @op_condition;
1876     for my $row ($subrs->search({}, { group_by => $subq_group_by })->cursor->all) {
1877       push @op_condition, { map
1878         { $idcols->[$_] => $row->[$_] }
1879         (0 .. $#$idcols)
1880       };
1881     }
1882
1883     my $res = $storage->$op (
1884       $rsrc,
1885       $op eq 'update' ? $values : (),
1886       \@op_condition,
1887     );
1888
1889     $guard->commit;
1890
1891     return $res;
1892   }
1893 }
1894
1895 =head2 update
1896
1897 =over 4
1898
1899 =item Arguments: \%values
1900
1901 =item Return Value: $storage_rv
1902
1903 =back
1904
1905 Sets the specified columns in the resultset to the supplied values in a
1906 single query. Note that this will not run any accessor/set_column/update
1907 triggers, nor will it update any row object instances derived from this
1908 resultset (this includes the contents of the L<resultset cache|/set_cache>
1909 if any). See L</update_all> if you need to execute any on-update
1910 triggers or cascades defined either by you or a
1911 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1912
1913 The return value is a pass through of what the underlying
1914 storage backend returned, and may vary. See L<DBI/execute> for the most
1915 common case.
1916
1917 =head3 CAVEAT
1918
1919 Note that L</update> does not process/deflate any of the values passed in.
1920 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1921 ensure manually that any value passed to this method will stringify to
1922 something the RDBMS knows how to deal with. A notable example is the
1923 handling of L<DateTime> objects, for more info see:
1924 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1925
1926 =cut
1927
1928 sub update {
1929   my ($self, $values) = @_;
1930   $self->throw_exception('Values for update must be a hash')
1931     unless ref $values eq 'HASH';
1932
1933   return $self->_rs_update_delete ('update', $values);
1934 }
1935
1936 =head2 update_all
1937
1938 =over 4
1939
1940 =item Arguments: \%values
1941
1942 =item Return Value: 1
1943
1944 =back
1945
1946 Fetches all objects and updates them one at a time via
1947 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1948 triggers, while L</update> will not.
1949
1950 =cut
1951
1952 sub update_all {
1953   my ($self, $values) = @_;
1954   $self->throw_exception('Values for update_all must be a hash')
1955     unless ref $values eq 'HASH';
1956
1957   my $guard = $self->result_source->schema->txn_scope_guard;
1958   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1959   $guard->commit;
1960   return 1;
1961 }
1962
1963 =head2 delete
1964
1965 =over 4
1966
1967 =item Arguments: none
1968
1969 =item Return Value: $storage_rv
1970
1971 =back
1972
1973 Deletes the rows matching this resultset in a single query. Note that this
1974 will not run any delete triggers, nor will it alter the
1975 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1976 derived from this resultset (this includes the contents of the
1977 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1978 execute any on-delete triggers or cascades defined either by you or a
1979 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1980
1981 The return value is a pass through of what the underlying storage backend
1982 returned, and may vary. See L<DBI/execute> for the most common case.
1983
1984 =cut
1985
1986 sub delete {
1987   my $self = shift;
1988   $self->throw_exception('delete does not accept any arguments')
1989     if @_;
1990
1991   return $self->_rs_update_delete ('delete');
1992 }
1993
1994 =head2 delete_all
1995
1996 =over 4
1997
1998 =item Arguments: none
1999
2000 =item Return Value: 1
2001
2002 =back
2003
2004 Fetches all objects and deletes them one at a time via
2005 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2006 triggers, while L</delete> will not.
2007
2008 =cut
2009
2010 sub delete_all {
2011   my $self = shift;
2012   $self->throw_exception('delete_all does not accept any arguments')
2013     if @_;
2014
2015   my $guard = $self->result_source->schema->txn_scope_guard;
2016   $_->delete for $self->all;
2017   $guard->commit;
2018   return 1;
2019 }
2020
2021 =head2 populate
2022
2023 =over 4
2024
2025 =item Arguments: \@data;
2026
2027 =back
2028
2029 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
2030 For the arrayref of hashrefs style each hashref should be a structure suitable
2031 for submitting to a $resultset->create(...) method.
2032
2033 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
2034 to insert the data, as this is a faster method.
2035
2036 Otherwise, each set of data is inserted into the database using
2037 L<DBIx::Class::ResultSet/create>, and the resulting objects are
2038 accumulated into an array. The array itself, or an array reference
2039 is returned depending on scalar or list context.
2040
2041 Example:  Assuming an Artist Class that has many CDs Classes relating:
2042
2043   my $Artist_rs = $schema->resultset("Artist");
2044
2045   ## Void Context Example
2046   $Artist_rs->populate([
2047      { artistid => 4, name => 'Manufactured Crap', cds => [
2048         { title => 'My First CD', year => 2006 },
2049         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2050       ],
2051      },
2052      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2053         { title => 'My parents sold me to a record company', year => 2005 },
2054         { title => 'Why Am I So Ugly?', year => 2006 },
2055         { title => 'I Got Surgery and am now Popular', year => 2007 }
2056       ],
2057      },
2058   ]);
2059
2060   ## Array Context Example
2061   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
2062     { name => "Artist One"},
2063     { name => "Artist Two"},
2064     { name => "Artist Three", cds=> [
2065     { title => "First CD", year => 2007},
2066     { title => "Second CD", year => 2008},
2067   ]}
2068   ]);
2069
2070   print $ArtistOne->name; ## response is 'Artist One'
2071   print $ArtistThree->cds->count ## reponse is '2'
2072
2073 For the arrayref of arrayrefs style,  the first element should be a list of the
2074 fieldsnames to which the remaining elements are rows being inserted.  For
2075 example:
2076
2077   $Arstist_rs->populate([
2078     [qw/artistid name/],
2079     [100, 'A Formally Unknown Singer'],
2080     [101, 'A singer that jumped the shark two albums ago'],
2081     [102, 'An actually cool singer'],
2082   ]);
2083
2084 Please note an important effect on your data when choosing between void and
2085 wantarray context. Since void context goes straight to C<insert_bulk> in
2086 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
2087 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
2088 create primary keys for you, you will find that your PKs are empty.  In this
2089 case you will have to use the wantarray context in order to create those
2090 values.
2091
2092 =cut
2093
2094 sub populate {
2095   my $self = shift;
2096
2097   # cruft placed in standalone method
2098   my $data = $self->_normalize_populate_args(@_);
2099
2100   return unless @$data;
2101
2102   if(defined wantarray) {
2103     my @created;
2104     foreach my $item (@$data) {
2105       push(@created, $self->create($item));
2106     }
2107     return wantarray ? @created : \@created;
2108   }
2109   else {
2110     my $first = $data->[0];
2111
2112     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2113     # it relationship data
2114     my (@rels, @columns);
2115     my $rsrc = $self->result_source;
2116     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2117     for (keys %$first) {
2118       my $ref = ref $first->{$_};
2119       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2120         ? push @rels, $_
2121         : push @columns, $_
2122       ;
2123     }
2124
2125     my @pks = $rsrc->primary_columns;
2126
2127     ## do the belongs_to relationships
2128     foreach my $index (0..$#$data) {
2129
2130       # delegate to create() for any dataset without primary keys with specified relationships
2131       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2132         for my $r (@rels) {
2133           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2134             my @ret = $self->populate($data);
2135             return;
2136           }
2137         }
2138       }
2139
2140       foreach my $rel (@rels) {
2141         next unless ref $data->[$index]->{$rel} eq "HASH";
2142         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2143         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2144         my $related = $result->result_source->_resolve_condition(
2145           $reverse_relinfo->{cond},
2146           $self,
2147           $result,
2148           $rel,
2149         );
2150
2151         delete $data->[$index]->{$rel};
2152         $data->[$index] = {%{$data->[$index]}, %$related};
2153
2154         push @columns, keys %$related if $index == 0;
2155       }
2156     }
2157
2158     ## inherit the data locked in the conditions of the resultset
2159     my ($rs_data) = $self->_merge_with_rscond({});
2160     delete @{$rs_data}{@columns};
2161     my @inherit_cols = keys %$rs_data;
2162     my @inherit_data = values %$rs_data;
2163
2164     ## do bulk insert on current row
2165     $rsrc->storage->insert_bulk(
2166       $rsrc,
2167       [@columns, @inherit_cols],
2168       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
2169     );
2170
2171     ## do the has_many relationships
2172     foreach my $item (@$data) {
2173
2174       my $main_row;
2175
2176       foreach my $rel (@rels) {
2177         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2178
2179         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2180
2181         my $child = $main_row->$rel;
2182
2183         my $related = $child->result_source->_resolve_condition(
2184           $rels->{$rel}{cond},
2185           $child,
2186           $main_row,
2187           $rel,
2188         );
2189
2190         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2191         my @populate = map { {%$_, %$related} } @rows_to_add;
2192
2193         $child->populate( \@populate );
2194       }
2195     }
2196   }
2197 }
2198
2199
2200 # populate() argumnets went over several incarnations
2201 # What we ultimately support is AoH
2202 sub _normalize_populate_args {
2203   my ($self, $arg) = @_;
2204
2205   if (ref $arg eq 'ARRAY') {
2206     if (!@$arg) {
2207       return [];
2208     }
2209     elsif (ref $arg->[0] eq 'HASH') {
2210       return $arg;
2211     }
2212     elsif (ref $arg->[0] eq 'ARRAY') {
2213       my @ret;
2214       my @colnames = @{$arg->[0]};
2215       foreach my $values (@{$arg}[1 .. $#$arg]) {
2216         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2217       }
2218       return \@ret;
2219     }
2220   }
2221
2222   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2223 }
2224
2225 =head2 pager
2226
2227 =over 4
2228
2229 =item Arguments: none
2230
2231 =item Return Value: $pager
2232
2233 =back
2234
2235 Return Value a L<Data::Page> object for the current resultset. Only makes
2236 sense for queries with a C<page> attribute.
2237
2238 To get the full count of entries for a paged resultset, call
2239 C<total_entries> on the L<Data::Page> object.
2240
2241 =cut
2242
2243 sub pager {
2244   my ($self) = @_;
2245
2246   return $self->{pager} if $self->{pager};
2247
2248   my $attrs = $self->{attrs};
2249   if (!defined $attrs->{page}) {
2250     $self->throw_exception("Can't create pager for non-paged rs");
2251   }
2252   elsif ($attrs->{page} <= 0) {
2253     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2254   }
2255   $attrs->{rows} ||= 10;
2256
2257   # throw away the paging flags and re-run the count (possibly
2258   # with a subselect) to get the real total count
2259   my $count_attrs = { %$attrs };
2260   delete $count_attrs->{$_} for qw/rows offset page pager/;
2261
2262   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2263
2264   require DBIx::Class::ResultSet::Pager;
2265   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2266     sub { $total_rs->count },  #lazy-get the total
2267     $attrs->{rows},
2268     $self->{attrs}{page},
2269   );
2270 }
2271
2272 =head2 page
2273
2274 =over 4
2275
2276 =item Arguments: $page_number
2277
2278 =item Return Value: $rs
2279
2280 =back
2281
2282 Returns a resultset for the $page_number page of the resultset on which page
2283 is called, where each page contains a number of rows equal to the 'rows'
2284 attribute set on the resultset (10 by default).
2285
2286 =cut
2287
2288 sub page {
2289   my ($self, $page) = @_;
2290   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2291 }
2292
2293 =head2 new_result
2294
2295 =over 4
2296
2297 =item Arguments: \%vals
2298
2299 =item Return Value: $rowobject
2300
2301 =back
2302
2303 Creates a new row object in the resultset's result class and returns
2304 it. The row is not inserted into the database at this point, call
2305 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2306 will tell you whether the row object has been inserted or not.
2307
2308 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2309
2310 =cut
2311
2312 sub new_result {
2313   my ($self, $values) = @_;
2314   $self->throw_exception( "new_result needs a hash" )
2315     unless (ref $values eq 'HASH');
2316
2317   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2318
2319   my %new = (
2320     %$merged_cond,
2321     @$cols_from_relations
2322       ? (-cols_from_relations => $cols_from_relations)
2323       : (),
2324     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2325   );
2326
2327   return $self->result_class->new(\%new);
2328 }
2329
2330 # _merge_with_rscond
2331 #
2332 # Takes a simple hash of K/V data and returns its copy merged with the
2333 # condition already present on the resultset. Additionally returns an
2334 # arrayref of value/condition names, which were inferred from related
2335 # objects (this is needed for in-memory related objects)
2336 sub _merge_with_rscond {
2337   my ($self, $data) = @_;
2338
2339   my (%new_data, @cols_from_relations);
2340
2341   my $alias = $self->{attrs}{alias};
2342
2343   if (! defined $self->{cond}) {
2344     # just massage $data below
2345   }
2346   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2347     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2348     @cols_from_relations = keys %new_data;
2349   }
2350   elsif (ref $self->{cond} ne 'HASH') {
2351     $self->throw_exception(
2352       "Can't abstract implicit construct, resultset condition not a hash"
2353     );
2354   }
2355   else {
2356     # precendence must be given to passed values over values inherited from
2357     # the cond, so the order here is important.
2358     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2359     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2360
2361     while ( my($col, $value) = each %implied ) {
2362       my $vref = ref $value;
2363       if (
2364         $vref eq 'HASH'
2365           and
2366         keys(%$value) == 1
2367           and
2368         (keys %$value)[0] eq '='
2369       ) {
2370         $new_data{$col} = $value->{'='};
2371       }
2372       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2373         $new_data{$col} = $value;
2374       }
2375     }
2376   }
2377
2378   %new_data = (
2379     %new_data,
2380     %{ $self->_remove_alias($data, $alias) },
2381   );
2382
2383   return (\%new_data, \@cols_from_relations);
2384 }
2385
2386 # _has_resolved_attr
2387 #
2388 # determines if the resultset defines at least one
2389 # of the attributes supplied
2390 #
2391 # used to determine if a subquery is neccessary
2392 #
2393 # supports some virtual attributes:
2394 #   -join
2395 #     This will scan for any joins being present on the resultset.
2396 #     It is not a mere key-search but a deep inspection of {from}
2397 #
2398
2399 sub _has_resolved_attr {
2400   my ($self, @attr_names) = @_;
2401
2402   my $attrs = $self->_resolved_attrs;
2403
2404   my %extra_checks;
2405
2406   for my $n (@attr_names) {
2407     if (grep { $n eq $_ } (qw/-join/) ) {
2408       $extra_checks{$n}++;
2409       next;
2410     }
2411
2412     my $attr =  $attrs->{$n};
2413
2414     next if not defined $attr;
2415
2416     if (ref $attr eq 'HASH') {
2417       return 1 if keys %$attr;
2418     }
2419     elsif (ref $attr eq 'ARRAY') {
2420       return 1 if @$attr;
2421     }
2422     else {
2423       return 1 if $attr;
2424     }
2425   }
2426
2427   # a resolved join is expressed as a multi-level from
2428   return 1 if (
2429     $extra_checks{-join}
2430       and
2431     ref $attrs->{from} eq 'ARRAY'
2432       and
2433     @{$attrs->{from}} > 1
2434   );
2435
2436   return 0;
2437 }
2438
2439 # _collapse_cond
2440 #
2441 # Recursively collapse the condition.
2442
2443 sub _collapse_cond {
2444   my ($self, $cond, $collapsed) = @_;
2445
2446   $collapsed ||= {};
2447
2448   if (ref $cond eq 'ARRAY') {
2449     foreach my $subcond (@$cond) {
2450       next unless ref $subcond;  # -or
2451       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2452     }
2453   }
2454   elsif (ref $cond eq 'HASH') {
2455     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2456       foreach my $subcond (@{$cond->{-and}}) {
2457         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2458       }
2459     }
2460     else {
2461       foreach my $col (keys %$cond) {
2462         my $value = $cond->{$col};
2463         $collapsed->{$col} = $value;
2464       }
2465     }
2466   }
2467
2468   return $collapsed;
2469 }
2470
2471 # _remove_alias
2472 #
2473 # Remove the specified alias from the specified query hash. A copy is made so
2474 # the original query is not modified.
2475
2476 sub _remove_alias {
2477   my ($self, $query, $alias) = @_;
2478
2479   my %orig = %{ $query || {} };
2480   my %unaliased;
2481
2482   foreach my $key (keys %orig) {
2483     if ($key !~ /\./) {
2484       $unaliased{$key} = $orig{$key};
2485       next;
2486     }
2487     $unaliased{$1} = $orig{$key}
2488       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2489   }
2490
2491   return \%unaliased;
2492 }
2493
2494 =head2 as_query
2495
2496 =over 4
2497
2498 =item Arguments: none
2499
2500 =item Return Value: \[ $sql, @bind ]
2501
2502 =back
2503
2504 Returns the SQL query and bind vars associated with the invocant.
2505
2506 This is generally used as the RHS for a subquery.
2507
2508 =cut
2509
2510 sub as_query {
2511   my $self = shift;
2512
2513   my $attrs = $self->_resolved_attrs_copy;
2514
2515   # For future use:
2516   #
2517   # in list ctx:
2518   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2519   # $sql also has no wrapping parenthesis in list ctx
2520   #
2521   my $sqlbind = $self->result_source->storage
2522     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2523
2524   return $sqlbind;
2525 }
2526
2527 =head2 find_or_new
2528
2529 =over 4
2530
2531 =item Arguments: \%vals, \%attrs?
2532
2533 =item Return Value: $rowobject
2534
2535 =back
2536
2537   my $artist = $schema->resultset('Artist')->find_or_new(
2538     { artist => 'fred' }, { key => 'artists' });
2539
2540   $cd->cd_to_producer->find_or_new({ producer => $producer },
2541                                    { key => 'primary });
2542
2543 Find an existing record from this resultset using L</find>. if none exists,
2544 instantiate a new result object and return it. The object will not be saved
2545 into your storage until you call L<DBIx::Class::Row/insert> on it.
2546
2547 You most likely want this method when looking for existing rows using a unique
2548 constraint that is not the primary key, or looking for related rows.
2549
2550 If you want objects to be saved immediately, use L</find_or_create> instead.
2551
2552 B<Note>: Make sure to read the documentation of L</find> and understand the
2553 significance of the C<key> attribute, as its lack may skew your search, and
2554 subsequently result in spurious new objects.
2555
2556 B<Note>: Take care when using C<find_or_new> with a table having
2557 columns with default values that you intend to be automatically
2558 supplied by the database (e.g. an auto_increment primary key column).
2559 In normal usage, the value of such columns should NOT be included at
2560 all in the call to C<find_or_new>, even when set to C<undef>.
2561
2562 =cut
2563
2564 sub find_or_new {
2565   my $self     = shift;
2566   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2567   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2568   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2569     return $row;
2570   }
2571   return $self->new_result($hash);
2572 }
2573
2574 =head2 create
2575
2576 =over 4
2577
2578 =item Arguments: \%vals
2579
2580 =item Return Value: a L<DBIx::Class::Row> $object
2581
2582 =back
2583
2584 Attempt to create a single new row or a row with multiple related rows
2585 in the table represented by the resultset (and related tables). This
2586 will not check for duplicate rows before inserting, use
2587 L</find_or_create> to do that.
2588
2589 To create one row for this resultset, pass a hashref of key/value
2590 pairs representing the columns of the table and the values you wish to
2591 store. If the appropriate relationships are set up, foreign key fields
2592 can also be passed an object representing the foreign row, and the
2593 value will be set to its primary key.
2594
2595 To create related objects, pass a hashref of related-object column values
2596 B<keyed on the relationship name>. If the relationship is of type C<multi>
2597 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2598 The process will correctly identify columns holding foreign keys, and will
2599 transparently populate them from the keys of the corresponding relation.
2600 This can be applied recursively, and will work correctly for a structure
2601 with an arbitrary depth and width, as long as the relationships actually
2602 exists and the correct column data has been supplied.
2603
2604
2605 Instead of hashrefs of plain related data (key/value pairs), you may
2606 also pass new or inserted objects. New objects (not inserted yet, see
2607 L</new>), will be inserted into their appropriate tables.
2608
2609 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2610
2611 Example of creating a new row.
2612
2613   $person_rs->create({
2614     name=>"Some Person",
2615     email=>"somebody@someplace.com"
2616   });
2617
2618 Example of creating a new row and also creating rows in a related C<has_many>
2619 or C<has_one> resultset.  Note Arrayref.
2620
2621   $artist_rs->create(
2622      { artistid => 4, name => 'Manufactured Crap', cds => [
2623         { title => 'My First CD', year => 2006 },
2624         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2625       ],
2626      },
2627   );
2628
2629 Example of creating a new row and also creating a row in a related
2630 C<belongs_to> resultset. Note Hashref.
2631
2632   $cd_rs->create({
2633     title=>"Music for Silly Walks",
2634     year=>2000,
2635     artist => {
2636       name=>"Silly Musician",
2637     }
2638   });
2639
2640 =over
2641
2642 =item WARNING
2643
2644 When subclassing ResultSet never attempt to override this method. Since
2645 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2646 lot of the internals simply never call it, so your override will be
2647 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2648 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2649 L</create> process you need to intervene.
2650
2651 =back
2652
2653 =cut
2654
2655 sub create {
2656   my ($self, $attrs) = @_;
2657   $self->throw_exception( "create needs a hashref" )
2658     unless ref $attrs eq 'HASH';
2659   return $self->new_result($attrs)->insert;
2660 }
2661
2662 =head2 find_or_create
2663
2664 =over 4
2665
2666 =item Arguments: \%vals, \%attrs?
2667
2668 =item Return Value: $rowobject
2669
2670 =back
2671
2672   $cd->cd_to_producer->find_or_create({ producer => $producer },
2673                                       { key => 'primary' });
2674
2675 Tries to find a record based on its primary key or unique constraints; if none
2676 is found, creates one and returns that instead.
2677
2678   my $cd = $schema->resultset('CD')->find_or_create({
2679     cdid   => 5,
2680     artist => 'Massive Attack',
2681     title  => 'Mezzanine',
2682     year   => 2005,
2683   });
2684
2685 Also takes an optional C<key> attribute, to search by a specific key or unique
2686 constraint. For example:
2687
2688   my $cd = $schema->resultset('CD')->find_or_create(
2689     {
2690       artist => 'Massive Attack',
2691       title  => 'Mezzanine',
2692     },
2693     { key => 'cd_artist_title' }
2694   );
2695
2696 B<Note>: Make sure to read the documentation of L</find> and understand the
2697 significance of the C<key> attribute, as its lack may skew your search, and
2698 subsequently result in spurious row creation.
2699
2700 B<Note>: Because find_or_create() reads from the database and then
2701 possibly inserts based on the result, this method is subject to a race
2702 condition. Another process could create a record in the table after
2703 the find has completed and before the create has started. To avoid
2704 this problem, use find_or_create() inside a transaction.
2705
2706 B<Note>: Take care when using C<find_or_create> with a table having
2707 columns with default values that you intend to be automatically
2708 supplied by the database (e.g. an auto_increment primary key column).
2709 In normal usage, the value of such columns should NOT be included at
2710 all in the call to C<find_or_create>, even when set to C<undef>.
2711
2712 See also L</find> and L</update_or_create>. For information on how to declare
2713 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2714
2715 =cut
2716
2717 sub find_or_create {
2718   my $self     = shift;
2719   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2720   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2721   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2722     return $row;
2723   }
2724   return $self->create($hash);
2725 }
2726
2727 =head2 update_or_create
2728
2729 =over 4
2730
2731 =item Arguments: \%col_values, { key => $unique_constraint }?
2732
2733 =item Return Value: $row_object
2734
2735 =back
2736
2737   $resultset->update_or_create({ col => $val, ... });
2738
2739 Like L</find_or_create>, but if a row is found it is immediately updated via
2740 C<< $found_row->update (\%col_values) >>.
2741
2742
2743 Takes an optional C<key> attribute to search on a specific unique constraint.
2744 For example:
2745
2746   # In your application
2747   my $cd = $schema->resultset('CD')->update_or_create(
2748     {
2749       artist => 'Massive Attack',
2750       title  => 'Mezzanine',
2751       year   => 1998,
2752     },
2753     { key => 'cd_artist_title' }
2754   );
2755
2756   $cd->cd_to_producer->update_or_create({
2757     producer => $producer,
2758     name => 'harry',
2759   }, {
2760     key => 'primary',
2761   });
2762
2763 B<Note>: Make sure to read the documentation of L</find> and understand the
2764 significance of the C<key> attribute, as its lack may skew your search, and
2765 subsequently result in spurious row creation.
2766
2767 B<Note>: Take care when using C<update_or_create> with a table having
2768 columns with default values that you intend to be automatically
2769 supplied by the database (e.g. an auto_increment primary key column).
2770 In normal usage, the value of such columns should NOT be included at
2771 all in the call to C<update_or_create>, even when set to C<undef>.
2772
2773 See also L</find> and L</find_or_create>. For information on how to declare
2774 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2775
2776 =cut
2777
2778 sub update_or_create {
2779   my $self = shift;
2780   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2781   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2782
2783   my $row = $self->find($cond, $attrs);
2784   if (defined $row) {
2785     $row->update($cond);
2786     return $row;
2787   }
2788
2789   return $self->create($cond);
2790 }
2791
2792 =head2 update_or_new
2793
2794 =over 4
2795
2796 =item Arguments: \%col_values, { key => $unique_constraint }?
2797
2798 =item Return Value: $rowobject
2799
2800 =back
2801
2802   $resultset->update_or_new({ col => $val, ... });
2803
2804 Like L</find_or_new> but if a row is found it is immediately updated via
2805 C<< $found_row->update (\%col_values) >>.
2806
2807 For example:
2808
2809   # In your application
2810   my $cd = $schema->resultset('CD')->update_or_new(
2811     {
2812       artist => 'Massive Attack',
2813       title  => 'Mezzanine',
2814       year   => 1998,
2815     },
2816     { key => 'cd_artist_title' }
2817   );
2818
2819   if ($cd->in_storage) {
2820       # the cd was updated
2821   }
2822   else {
2823       # the cd is not yet in the database, let's insert it
2824       $cd->insert;
2825   }
2826
2827 B<Note>: Make sure to read the documentation of L</find> and understand the
2828 significance of the C<key> attribute, as its lack may skew your search, and
2829 subsequently result in spurious new objects.
2830
2831 B<Note>: Take care when using C<update_or_new> with a table having
2832 columns with default values that you intend to be automatically
2833 supplied by the database (e.g. an auto_increment primary key column).
2834 In normal usage, the value of such columns should NOT be included at
2835 all in the call to C<update_or_new>, even when set to C<undef>.
2836
2837 See also L</find>, L</find_or_create> and L</find_or_new>.
2838
2839 =cut
2840
2841 sub update_or_new {
2842     my $self  = shift;
2843     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2844     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2845
2846     my $row = $self->find( $cond, $attrs );
2847     if ( defined $row ) {
2848         $row->update($cond);
2849         return $row;
2850     }
2851
2852     return $self->new_result($cond);
2853 }
2854
2855 =head2 get_cache
2856
2857 =over 4
2858
2859 =item Arguments: none
2860
2861 =item Return Value: \@cache_objects | undef
2862
2863 =back
2864
2865 Gets the contents of the cache for the resultset, if the cache is set.
2866
2867 The cache is populated either by using the L</prefetch> attribute to
2868 L</search> or by calling L</set_cache>.
2869
2870 =cut
2871
2872 sub get_cache {
2873   shift->{all_cache};
2874 }
2875
2876 =head2 set_cache
2877
2878 =over 4
2879
2880 =item Arguments: \@cache_objects
2881
2882 =item Return Value: \@cache_objects
2883
2884 =back
2885
2886 Sets the contents of the cache for the resultset. Expects an arrayref
2887 of objects of the same class as those produced by the resultset. Note that
2888 if the cache is set the resultset will return the cached objects rather
2889 than re-querying the database even if the cache attr is not set.
2890
2891 The contents of the cache can also be populated by using the
2892 L</prefetch> attribute to L</search>.
2893
2894 =cut
2895
2896 sub set_cache {
2897   my ( $self, $data ) = @_;
2898   $self->throw_exception("set_cache requires an arrayref")
2899       if defined($data) && (ref $data ne 'ARRAY');
2900   $self->{all_cache} = $data;
2901 }
2902
2903 =head2 clear_cache
2904
2905 =over 4
2906
2907 =item Arguments: none
2908
2909 =item Return Value: undef
2910
2911 =back
2912
2913 Clears the cache for the resultset.
2914
2915 =cut
2916
2917 sub clear_cache {
2918   shift->set_cache(undef);
2919 }
2920
2921 =head2 is_paged
2922
2923 =over 4
2924
2925 =item Arguments: none
2926
2927 =item Return Value: true, if the resultset has been paginated
2928
2929 =back
2930
2931 =cut
2932
2933 sub is_paged {
2934   my ($self) = @_;
2935   return !!$self->{attrs}{page};
2936 }
2937
2938 =head2 is_ordered
2939
2940 =over 4
2941
2942 =item Arguments: none
2943
2944 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2945
2946 =back
2947
2948 =cut
2949
2950 sub is_ordered {
2951   my ($self) = @_;
2952   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2953 }
2954
2955 =head2 related_resultset
2956
2957 =over 4
2958
2959 =item Arguments: $relationship_name
2960
2961 =item Return Value: $resultset
2962
2963 =back
2964
2965 Returns a related resultset for the supplied relationship name.
2966
2967   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2968
2969 =cut
2970
2971 sub related_resultset {
2972   my ($self, $rel) = @_;
2973
2974   $self->{related_resultsets} ||= {};
2975   return $self->{related_resultsets}{$rel} ||= do {
2976     my $rsrc = $self->result_source;
2977     my $rel_info = $rsrc->relationship_info($rel);
2978
2979     $self->throw_exception(
2980       "search_related: result source '" . $rsrc->source_name .
2981         "' has no such relationship $rel")
2982       unless $rel_info;
2983
2984     my $attrs = $self->_chain_relationship($rel);
2985
2986     my $join_count = $attrs->{seen_join}{$rel};
2987
2988     my $alias = $self->result_source->storage
2989         ->relname_to_table_alias($rel, $join_count);
2990
2991     # since this is search_related, and we already slid the select window inwards
2992     # (the select/as attrs were deleted in the beginning), we need to flip all
2993     # left joins to inner, so we get the expected results
2994     # read the comment on top of the actual function to see what this does
2995     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
2996
2997
2998     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2999     delete @{$attrs}{qw(result_class alias)};
3000
3001     my $new_cache;
3002
3003     if (my $cache = $self->get_cache) {
3004       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3005         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3006                         @$cache ];
3007       }
3008     }
3009
3010     my $rel_source = $rsrc->related_source($rel);
3011
3012     my $new = do {
3013
3014       # The reason we do this now instead of passing the alias to the
3015       # search_rs below is that if you wrap/overload resultset on the
3016       # source you need to know what alias it's -going- to have for things
3017       # to work sanely (e.g. RestrictWithObject wants to be able to add
3018       # extra query restrictions, and these may need to be $alias.)
3019
3020       my $rel_attrs = $rel_source->resultset_attributes;
3021       local $rel_attrs->{alias} = $alias;
3022
3023       $rel_source->resultset
3024                  ->search_rs(
3025                      undef, {
3026                        %$attrs,
3027                        where => $attrs->{where},
3028                    });
3029     };
3030     $new->set_cache($new_cache) if $new_cache;
3031     $new;
3032   };
3033 }
3034
3035 =head2 current_source_alias
3036
3037 =over 4
3038
3039 =item Arguments: none
3040
3041 =item Return Value: $source_alias
3042
3043 =back
3044
3045 Returns the current table alias for the result source this resultset is built
3046 on, that will be used in the SQL query. Usually it is C<me>.
3047
3048 Currently the source alias that refers to the result set returned by a
3049 L</search>/L</find> family method depends on how you got to the resultset: it's
3050 C<me> by default, but eg. L</search_related> aliases it to the related result
3051 source name (and keeps C<me> referring to the original result set). The long
3052 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3053 (and make this method unnecessary).
3054
3055 Thus it's currently necessary to use this method in predefined queries (see
3056 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3057 source alias of the current result set:
3058
3059   # in a result set class
3060   sub modified_by {
3061     my ($self, $user) = @_;
3062
3063     my $me = $self->current_source_alias;
3064
3065     return $self->search(
3066       "$me.modified" => $user->id,
3067     );
3068   }
3069
3070 =cut
3071
3072 sub current_source_alias {
3073   my ($self) = @_;
3074
3075   return ($self->{attrs} || {})->{alias} || 'me';
3076 }
3077
3078 =head2 as_subselect_rs
3079
3080 =over 4
3081
3082 =item Arguments: none
3083
3084 =item Return Value: $resultset
3085
3086 =back
3087
3088 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3089 "virtual view" by including it as a subquery within the from clause.  From this
3090 point on, any joined tables are inaccessible to ->search on the resultset (as if
3091 it were simply where-filtered without joins).  For example:
3092
3093  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3094
3095  # 'x' now pollutes the query namespace
3096
3097  # So the following works as expected
3098  my $ok_rs = $rs->search({'x.other' => 1});
3099
3100  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3101  # def) we look for one row with contradictory terms and join in another table
3102  # (aliased 'x_2') which we never use
3103  my $broken_rs = $rs->search({'x.name' => 'def'});
3104
3105  my $rs2 = $rs->as_subselect_rs;
3106
3107  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3108  my $not_joined_rs = $rs2->search({'x.other' => 1});
3109
3110  # works as expected: finds a 'table' row related to two x rows (abc and def)
3111  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3112
3113 Another example of when one might use this would be to select a subset of
3114 columns in a group by clause:
3115
3116  my $rs = $schema->resultset('Bar')->search(undef, {
3117    group_by => [qw{ id foo_id baz_id }],
3118  })->as_subselect_rs->search(undef, {
3119    columns => [qw{ id foo_id }]
3120  });
3121
3122 In the above example normally columns would have to be equal to the group by,
3123 but because we isolated the group by into a subselect the above works.
3124
3125 =cut
3126
3127 sub as_subselect_rs {
3128   my $self = shift;
3129
3130   my $attrs = $self->_resolved_attrs;
3131
3132   my $fresh_rs = (ref $self)->new (
3133     $self->result_source
3134   );
3135
3136   # these pieces will be locked in the subquery
3137   delete $fresh_rs->{cond};
3138   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3139
3140   return $fresh_rs->search( {}, {
3141     from => [{
3142       $attrs->{alias} => $self->as_query,
3143       -alias  => $attrs->{alias},
3144       -rsrc   => $self->result_source,
3145     }],
3146     alias => $attrs->{alias},
3147   });
3148 }
3149
3150 # This code is called by search_related, and makes sure there
3151 # is clear separation between the joins before, during, and
3152 # after the relationship. This information is needed later
3153 # in order to properly resolve prefetch aliases (any alias
3154 # with a relation_chain_depth less than the depth of the
3155 # current prefetch is not considered)
3156 #
3157 # The increments happen twice per join. An even number means a
3158 # relationship specified via a search_related, whereas an odd
3159 # number indicates a join/prefetch added via attributes
3160 #
3161 # Also this code will wrap the current resultset (the one we
3162 # chain to) in a subselect IFF it contains limiting attributes
3163 sub _chain_relationship {
3164   my ($self, $rel) = @_;
3165   my $source = $self->result_source;
3166   my $attrs = { %{$self->{attrs}||{}} };
3167
3168   # we need to take the prefetch the attrs into account before we
3169   # ->_resolve_join as otherwise they get lost - captainL
3170   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3171
3172   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3173
3174   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3175
3176   my $from;
3177   my @force_subq_attrs = qw/offset rows group_by having/;
3178
3179   if (
3180     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3181       ||
3182     $self->_has_resolved_attr (@force_subq_attrs)
3183   ) {
3184     # Nuke the prefetch (if any) before the new $rs attrs
3185     # are resolved (prefetch is useless - we are wrapping
3186     # a subquery anyway).
3187     my $rs_copy = $self->search;
3188     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3189       $rs_copy->{attrs}{join},
3190       delete $rs_copy->{attrs}{prefetch},
3191     );
3192
3193     $from = [{
3194       -rsrc   => $source,
3195       -alias  => $attrs->{alias},
3196       $attrs->{alias} => $rs_copy->as_query,
3197     }];
3198     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3199     $seen->{-relation_chain_depth} = 0;
3200   }
3201   elsif ($attrs->{from}) {  #shallow copy suffices
3202     $from = [ @{$attrs->{from}} ];
3203   }
3204   else {
3205     $from = [{
3206       -rsrc  => $source,
3207       -alias => $attrs->{alias},
3208       $attrs->{alias} => $source->from,
3209     }];
3210   }
3211
3212   my $jpath = ($seen->{-relation_chain_depth})
3213     ? $from->[-1][0]{-join_path}
3214     : [];
3215
3216   my @requested_joins = $source->_resolve_join(
3217     $join,
3218     $attrs->{alias},
3219     $seen,
3220     $jpath,
3221   );
3222
3223   push @$from, @requested_joins;
3224
3225   $seen->{-relation_chain_depth}++;
3226
3227   # if $self already had a join/prefetch specified on it, the requested
3228   # $rel might very well be already included. What we do in this case
3229   # is effectively a no-op (except that we bump up the chain_depth on
3230   # the join in question so we could tell it *is* the search_related)
3231   my $already_joined;
3232
3233   # we consider the last one thus reverse
3234   for my $j (reverse @requested_joins) {
3235     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3236     if ($rel eq $last_j) {
3237       $j->[0]{-relation_chain_depth}++;
3238       $already_joined++;
3239       last;
3240     }
3241   }
3242
3243   unless ($already_joined) {
3244     push @$from, $source->_resolve_join(
3245       $rel,
3246       $attrs->{alias},
3247       $seen,
3248       $jpath,
3249     );
3250   }
3251
3252   $seen->{-relation_chain_depth}++;
3253
3254   return {%$attrs, from => $from, seen_join => $seen};
3255 }
3256
3257 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3258 sub _resolved_attrs_copy {
3259   my $self = shift;
3260   return { %{$self->_resolved_attrs (@_)} };
3261 }
3262
3263 sub _resolved_attrs {
3264   my $self = shift;
3265   return $self->{_attrs} if $self->{_attrs};
3266
3267   my $attrs  = { %{ $self->{attrs} || {} } };
3268   my $source = $self->result_source;
3269   my $alias  = $attrs->{alias};
3270
3271   # default selection list
3272   $attrs->{columns} = [ $source->columns ]
3273     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3274
3275   # merge selectors together
3276   for (qw/columns select as/) {
3277     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3278       if $attrs->{$_} or $attrs->{"+$_"};
3279   }
3280
3281   # disassemble columns
3282   my (@sel, @as);
3283   if (my $cols = delete $attrs->{columns}) {
3284     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3285       if (ref $c eq 'HASH') {
3286         for my $as (keys %$c) {
3287           push @sel, $c->{$as};
3288           push @as, $as;
3289         }
3290       }
3291       else {
3292         push @sel, $c;
3293         push @as, $c;
3294       }
3295     }
3296   }
3297
3298   # when trying to weed off duplicates later do not go past this point -
3299   # everything added from here on is unbalanced "anyone's guess" stuff
3300   my $dedup_stop_idx = $#as;
3301
3302   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3303     if $attrs->{as};
3304   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3305     if $attrs->{select};
3306
3307   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3308   for (@sel) {
3309     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3310   }
3311
3312   # disqualify all $alias.col as-bits (collapser mandated)
3313   for (@as) {
3314     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3315   }
3316
3317   # de-duplicate the result (remove *identical* select/as pairs)
3318   # and also die on duplicate {as} pointing to different {select}s
3319   # not using a c-style for as the condition is prone to shrinkage
3320   my $seen;
3321   my $i = 0;
3322   while ($i <= $dedup_stop_idx) {
3323     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3324       splice @sel, $i, 1;
3325       splice @as, $i, 1;
3326       $dedup_stop_idx--;
3327     }
3328     elsif ($seen->{$as[$i]}++) {
3329       $self->throw_exception(
3330         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3331       );
3332     }
3333     else {
3334       $i++;
3335     }
3336   }
3337
3338   $attrs->{select} = \@sel;
3339   $attrs->{as} = \@as;
3340
3341   $attrs->{from} ||= [{
3342     -rsrc   => $source,
3343     -alias  => $self->{attrs}{alias},
3344     $self->{attrs}{alias} => $source->from,
3345   }];
3346
3347   if ( $attrs->{join} || $attrs->{prefetch} ) {
3348
3349     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3350       if ref $attrs->{from} ne 'ARRAY';
3351
3352     my $join = (delete $attrs->{join}) || {};
3353
3354     if ( defined $attrs->{prefetch} ) {
3355       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3356     }
3357
3358     $attrs->{from} =    # have to copy here to avoid corrupting the original
3359       [
3360         @{ $attrs->{from} },
3361         $source->_resolve_join(
3362           $join,
3363           $alias,
3364           { %{ $attrs->{seen_join} || {} } },
3365           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3366             ? $attrs->{from}[-1][0]{-join_path}
3367             : []
3368           ,
3369         )
3370       ];
3371   }
3372
3373   if ( defined $attrs->{order_by} ) {
3374     $attrs->{order_by} = (
3375       ref( $attrs->{order_by} ) eq 'ARRAY'
3376       ? [ @{ $attrs->{order_by} } ]
3377       : [ $attrs->{order_by} || () ]
3378     );
3379   }
3380
3381   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3382     $attrs->{group_by} = [ $attrs->{group_by} ];
3383   }
3384
3385   # generate the distinct induced group_by early, as prefetch will be carried via a
3386   # subquery (since a group_by is present)
3387   if (delete $attrs->{distinct}) {
3388     if ($attrs->{group_by}) {
3389       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3390     }
3391     else {
3392       # distinct affects only the main selection part, not what prefetch may
3393       # add below.
3394       $attrs->{group_by} = $source->storage->_group_over_selection (
3395         $attrs->{from},
3396         $attrs->{select},
3397         $attrs->{order_by},
3398       );
3399     }
3400   }
3401
3402   $attrs->{collapse} ||= {};
3403   if ($attrs->{prefetch}) {
3404
3405     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3406       if $attrs->{_dark_selector};
3407
3408     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3409
3410     my $prefetch_ordering = [];
3411
3412     # this is a separate structure (we don't look in {from} directly)
3413     # as the resolver needs to shift things off the lists to work
3414     # properly (identical-prefetches on different branches)
3415     my $join_map = {};
3416     if (ref $attrs->{from} eq 'ARRAY') {
3417
3418       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3419
3420       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3421         next unless $j->[0]{-alias};
3422         next unless $j->[0]{-join_path};
3423         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3424
3425         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3426
3427         my $p = $join_map;
3428         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3429         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3430       }
3431     }
3432
3433     my @prefetch =
3434       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3435
3436     # we need to somehow mark which columns came from prefetch
3437     if (@prefetch) {
3438       my $sel_end = $#{$attrs->{select}};
3439       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3440     }
3441
3442     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3443     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3444
3445     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3446     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3447   }
3448
3449
3450   # if both page and offset are specified, produce a combined offset
3451   # even though it doesn't make much sense, this is what pre 081xx has
3452   # been doing
3453   if (my $page = delete $attrs->{page}) {
3454     $attrs->{offset} =
3455       ($attrs->{rows} * ($page - 1))
3456             +
3457       ($attrs->{offset} || 0)
3458     ;
3459   }
3460
3461   return $self->{_attrs} = $attrs;
3462 }
3463
3464 sub _rollout_attr {
3465   my ($self, $attr) = @_;
3466
3467   if (ref $attr eq 'HASH') {
3468     return $self->_rollout_hash($attr);
3469   } elsif (ref $attr eq 'ARRAY') {
3470     return $self->_rollout_array($attr);
3471   } else {
3472     return [$attr];
3473   }
3474 }
3475
3476 sub _rollout_array {
3477   my ($self, $attr) = @_;
3478
3479   my @rolled_array;
3480   foreach my $element (@{$attr}) {
3481     if (ref $element eq 'HASH') {
3482       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3483     } elsif (ref $element eq 'ARRAY') {
3484       #  XXX - should probably recurse here
3485       push( @rolled_array, @{$self->_rollout_array($element)} );
3486     } else {
3487       push( @rolled_array, $element );
3488     }
3489   }
3490   return \@rolled_array;
3491 }
3492
3493 sub _rollout_hash {
3494   my ($self, $attr) = @_;
3495
3496   my @rolled_array;
3497   foreach my $key (keys %{$attr}) {
3498     push( @rolled_array, { $key => $attr->{$key} } );
3499   }
3500   return \@rolled_array;
3501 }
3502
3503 sub _calculate_score {
3504   my ($self, $a, $b) = @_;
3505
3506   if (defined $a xor defined $b) {
3507     return 0;
3508   }
3509   elsif (not defined $a) {
3510     return 1;
3511   }
3512
3513   if (ref $b eq 'HASH') {
3514     my ($b_key) = keys %{$b};
3515     if (ref $a eq 'HASH') {
3516       my ($a_key) = keys %{$a};
3517       if ($a_key eq $b_key) {
3518         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3519       } else {
3520         return 0;
3521       }
3522     } else {
3523       return ($a eq $b_key) ? 1 : 0;
3524     }
3525   } else {
3526     if (ref $a eq 'HASH') {
3527       my ($a_key) = keys %{$a};
3528       return ($b eq $a_key) ? 1 : 0;
3529     } else {
3530       return ($b eq $a) ? 1 : 0;
3531     }
3532   }
3533 }
3534
3535 sub _merge_joinpref_attr {
3536   my ($self, $orig, $import) = @_;
3537
3538   return $import unless defined($orig);
3539   return $orig unless defined($import);
3540
3541   $orig = $self->_rollout_attr($orig);
3542   $import = $self->_rollout_attr($import);
3543
3544   my $seen_keys;
3545   foreach my $import_element ( @{$import} ) {
3546     # find best candidate from $orig to merge $b_element into
3547     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3548     foreach my $orig_element ( @{$orig} ) {
3549       my $score = $self->_calculate_score( $orig_element, $import_element );
3550       if ($score > $best_candidate->{score}) {
3551         $best_candidate->{position} = $position;
3552         $best_candidate->{score} = $score;
3553       }
3554       $position++;
3555     }
3556     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3557     $import_key = '' if not defined $import_key;
3558
3559     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3560       push( @{$orig}, $import_element );
3561     } else {
3562       my $orig_best = $orig->[$best_candidate->{position}];
3563       # merge orig_best and b_element together and replace original with merged
3564       if (ref $orig_best ne 'HASH') {
3565         $orig->[$best_candidate->{position}] = $import_element;
3566       } elsif (ref $import_element eq 'HASH') {
3567         my ($key) = keys %{$orig_best};
3568         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3569       }
3570     }
3571     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3572   }
3573
3574   return $orig;
3575 }
3576
3577 {
3578   my $hm;
3579
3580   sub _merge_attr {
3581     $hm ||= do {
3582       require Hash::Merge;
3583       my $hm = Hash::Merge->new;
3584
3585       $hm->specify_behavior({
3586         SCALAR => {
3587           SCALAR => sub {
3588             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3589
3590             if ($defl xor $defr) {
3591               return [ $defl ? $_[0] : $_[1] ];
3592             }
3593             elsif (! $defl) {
3594               return [];
3595             }
3596             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3597               return [ $_[0] ];
3598             }
3599             else {
3600               return [$_[0], $_[1]];
3601             }
3602           },
3603           ARRAY => sub {
3604             return $_[1] if !defined $_[0];
3605             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3606             return [$_[0], @{$_[1]}]
3607           },
3608           HASH  => sub {
3609             return [] if !defined $_[0] and !keys %{$_[1]};
3610             return [ $_[1] ] if !defined $_[0];
3611             return [ $_[0] ] if !keys %{$_[1]};
3612             return [$_[0], $_[1]]
3613           },
3614         },
3615         ARRAY => {
3616           SCALAR => sub {
3617             return $_[0] if !defined $_[1];
3618             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3619             return [@{$_[0]}, $_[1]]
3620           },
3621           ARRAY => sub {
3622             my @ret = @{$_[0]} or return $_[1];
3623             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3624             my %idx = map { $_ => 1 } @ret;
3625             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3626             \@ret;
3627           },
3628           HASH => sub {
3629             return [ $_[1] ] if ! @{$_[0]};
3630             return $_[0] if !keys %{$_[1]};
3631             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3632             return [ @{$_[0]}, $_[1] ];
3633           },
3634         },
3635         HASH => {
3636           SCALAR => sub {
3637             return [] if !keys %{$_[0]} and !defined $_[1];
3638             return [ $_[0] ] if !defined $_[1];
3639             return [ $_[1] ] if !keys %{$_[0]};
3640             return [$_[0], $_[1]]
3641           },
3642           ARRAY => sub {
3643             return [] if !keys %{$_[0]} and !@{$_[1]};
3644             return [ $_[0] ] if !@{$_[1]};
3645             return $_[1] if !keys %{$_[0]};
3646             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3647             return [ $_[0], @{$_[1]} ];
3648           },
3649           HASH => sub {
3650             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3651             return [ $_[0] ] if !keys %{$_[1]};
3652             return [ $_[1] ] if !keys %{$_[0]};
3653             return [ $_[0] ] if $_[0] eq $_[1];
3654             return [ $_[0], $_[1] ];
3655           },
3656         }
3657       } => 'DBIC_RS_ATTR_MERGER');
3658       $hm;
3659     };
3660
3661     return $hm->merge ($_[1], $_[2]);
3662   }
3663 }
3664
3665 sub STORABLE_freeze {
3666   my ($self, $cloning) = @_;
3667   my $to_serialize = { %$self };
3668
3669   # A cursor in progress can't be serialized (and would make little sense anyway)
3670   delete $to_serialize->{cursor};
3671
3672   # nor is it sensical to store a not-yet-fired-count pager
3673   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3674     delete $to_serialize->{pager};
3675   }
3676
3677   Storable::nfreeze($to_serialize);
3678 }
3679
3680 # need this hook for symmetry
3681 sub STORABLE_thaw {
3682   my ($self, $cloning, $serialized) = @_;
3683
3684   %$self = %{ Storable::thaw($serialized) };
3685
3686   $self;
3687 }
3688
3689
3690 =head2 throw_exception
3691
3692 See L<DBIx::Class::Schema/throw_exception> for details.
3693
3694 =cut
3695
3696 sub throw_exception {
3697   my $self=shift;
3698
3699   if (ref $self and my $rsrc = $self->result_source) {
3700     $rsrc->throw_exception(@_)
3701   }
3702   else {
3703     DBIx::Class::Exception->throw(@_);
3704   }
3705 }
3706
3707 # XXX: FIXME: Attributes docs need clearing up
3708
3709 =head1 ATTRIBUTES
3710
3711 Attributes are used to refine a ResultSet in various ways when
3712 searching for data. They can be passed to any method which takes an
3713 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3714 L</count>.
3715
3716 These are in no particular order:
3717
3718 =head2 order_by
3719
3720 =over 4
3721
3722 =item Value: ( $order_by | \@order_by | \%order_by )
3723
3724 =back
3725
3726 Which column(s) to order the results by.
3727
3728 [The full list of suitable values is documented in
3729 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3730 common options.]
3731
3732 If a single column name, or an arrayref of names is supplied, the
3733 argument is passed through directly to SQL. The hashref syntax allows
3734 for connection-agnostic specification of ordering direction:
3735
3736  For descending order:
3737
3738   order_by => { -desc => [qw/col1 col2 col3/] }
3739
3740  For explicit ascending order:
3741
3742   order_by => { -asc => 'col' }
3743
3744 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3745 supported, although you are strongly encouraged to use the hashref
3746 syntax as outlined above.
3747
3748 =head2 columns
3749
3750 =over 4
3751
3752 =item Value: \@columns
3753
3754 =back
3755
3756 Shortcut to request a particular set of columns to be retrieved. Each
3757 column spec may be a string (a table column name), or a hash (in which
3758 case the key is the C<as> value, and the value is used as the C<select>
3759 expression). Adds C<me.> onto the start of any column without a C<.> in
3760 it and sets C<select> from that, then auto-populates C<as> from
3761 C<select> as normal. (You may also use the C<cols> attribute, as in
3762 earlier versions of DBIC.)
3763
3764 Essentially C<columns> does the same as L</select> and L</as>.
3765
3766     columns => [ 'foo', { bar => 'baz' } ]
3767
3768 is the same as
3769
3770     select => [qw/foo baz/],
3771     as => [qw/foo bar/]
3772
3773 =head2 +columns
3774
3775 =over 4
3776
3777 =item Value: \@columns
3778
3779 =back
3780
3781 Indicates additional columns to be selected from storage. Works the same
3782 as L</columns> but adds columns to the selection. (You may also use the
3783 C<include_columns> attribute, as in earlier versions of DBIC). For
3784 example:-
3785
3786   $schema->resultset('CD')->search(undef, {
3787     '+columns' => ['artist.name'],
3788     join => ['artist']
3789   });
3790
3791 would return all CDs and include a 'name' column to the information
3792 passed to object inflation. Note that the 'artist' is the name of the
3793 column (or relationship) accessor, and 'name' is the name of the column
3794 accessor in the related table.
3795
3796 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3797 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3798 unary plus operator before it.
3799
3800 =head2 include_columns
3801
3802 =over 4
3803
3804 =item Value: \@columns
3805
3806 =back
3807
3808 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3809
3810 =head2 select
3811
3812 =over 4
3813
3814 =item Value: \@select_columns
3815
3816 =back
3817
3818 Indicates which columns should be selected from the storage. You can use
3819 column names, or in the case of RDBMS back ends, function or stored procedure
3820 names:
3821
3822   $rs = $schema->resultset('Employee')->search(undef, {
3823     select => [
3824       'name',
3825       { count => 'employeeid' },
3826       { max => { length => 'name' }, -as => 'longest_name' }
3827     ]
3828   });
3829
3830   # Equivalent SQL
3831   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3832
3833 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3834 use L</select>, to instruct DBIx::Class how to store the result of the column.
3835 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3836 identifier aliasing. You can however alias a function, so you can use it in
3837 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3838 attribute> supplied as shown in the example above.
3839
3840 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3841 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3842 unary plus operator before it.
3843
3844 =head2 +select
3845
3846 =over 4
3847
3848 Indicates additional columns to be selected from storage.  Works the same as
3849 L</select> but adds columns to the default selection, instead of specifying
3850 an explicit list.
3851
3852 =back
3853
3854 =head2 +as
3855
3856 =over 4
3857
3858 Indicates additional column names for those added via L</+select>. See L</as>.
3859
3860 =back
3861
3862 =head2 as
3863
3864 =over 4
3865
3866 =item Value: \@inflation_names
3867
3868 =back
3869
3870 Indicates column names for object inflation. That is L</as> indicates the
3871 slot name in which the column value will be stored within the
3872 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3873 identifier by the C<get_column> method (or via the object accessor B<if one
3874 with the same name already exists>) as shown below. The L</as> attribute has
3875 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3876
3877   $rs = $schema->resultset('Employee')->search(undef, {
3878     select => [
3879       'name',
3880       { count => 'employeeid' },
3881       { max => { length => 'name' }, -as => 'longest_name' }
3882     ],
3883     as => [qw/
3884       name
3885       employee_count
3886       max_name_length
3887     /],
3888   });
3889
3890 If the object against which the search is performed already has an accessor
3891 matching a column name specified in C<as>, the value can be retrieved using
3892 the accessor as normal:
3893
3894   my $name = $employee->name();
3895
3896 If on the other hand an accessor does not exist in the object, you need to
3897 use C<get_column> instead:
3898
3899   my $employee_count = $employee->get_column('employee_count');
3900
3901 You can create your own accessors if required - see
3902 L<DBIx::Class::Manual::Cookbook> for details.
3903
3904 =head2 join
3905
3906 =over 4
3907
3908 =item Value: ($rel_name | \@rel_names | \%rel_names)
3909
3910 =back
3911
3912 Contains a list of relationships that should be joined for this query.  For
3913 example:
3914
3915   # Get CDs by Nine Inch Nails
3916   my $rs = $schema->resultset('CD')->search(
3917     { 'artist.name' => 'Nine Inch Nails' },
3918     { join => 'artist' }
3919   );
3920
3921 Can also contain a hash reference to refer to the other relation's relations.
3922 For example:
3923
3924   package MyApp::Schema::Track;
3925   use base qw/DBIx::Class/;
3926   __PACKAGE__->table('track');
3927   __PACKAGE__->add_columns(qw/trackid cd position title/);
3928   __PACKAGE__->set_primary_key('trackid');
3929   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3930   1;
3931
3932   # In your application
3933   my $rs = $schema->resultset('Artist')->search(
3934     { 'track.title' => 'Teardrop' },
3935     {
3936       join     => { cd => 'track' },
3937       order_by => 'artist.name',
3938     }
3939   );
3940
3941 You need to use the relationship (not the table) name in  conditions,
3942 because they are aliased as such. The current table is aliased as "me", so
3943 you need to use me.column_name in order to avoid ambiguity. For example:
3944
3945   # Get CDs from 1984 with a 'Foo' track
3946   my $rs = $schema->resultset('CD')->search(
3947     {
3948       'me.year' => 1984,
3949       'tracks.name' => 'Foo'
3950     },
3951     { join => 'tracks' }
3952   );
3953
3954 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3955 similarly for a third time). For e.g.
3956
3957   my $rs = $schema->resultset('Artist')->search({
3958     'cds.title'   => 'Down to Earth',
3959     'cds_2.title' => 'Popular',
3960   }, {
3961     join => [ qw/cds cds/ ],
3962   });
3963
3964 will return a set of all artists that have both a cd with title 'Down
3965 to Earth' and a cd with title 'Popular'.
3966
3967 If you want to fetch related objects from other tables as well, see C<prefetch>
3968 below.
3969
3970 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3971
3972 =head2 prefetch
3973
3974 =over 4
3975
3976 =item Value: ($rel_name | \@rel_names | \%rel_names)
3977
3978 =back
3979
3980 Contains one or more relationships that should be fetched along with
3981 the main query (when they are accessed afterwards the data will
3982 already be available, without extra queries to the database).  This is
3983 useful for when you know you will need the related objects, because it
3984 saves at least one query:
3985
3986   my $rs = $schema->resultset('Tag')->search(
3987     undef,
3988     {
3989       prefetch => {
3990         cd => 'artist'
3991       }
3992     }
3993   );
3994
3995 The initial search results in SQL like the following:
3996
3997   SELECT tag.*, cd.*, artist.* FROM tag
3998   JOIN cd ON tag.cd = cd.cdid
3999   JOIN artist ON cd.artist = artist.artistid
4000
4001 L<DBIx::Class> has no need to go back to the database when we access the
4002 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4003 case.
4004
4005 Simple prefetches will be joined automatically, so there is no need
4006 for a C<join> attribute in the above search.
4007
4008 L</prefetch> can be used with the any of the relationship types and
4009 multiple prefetches can be specified together. Below is a more complex
4010 example that prefetches a CD's artist, its liner notes (if present),
4011 the cover image, the tracks on that cd, and the guests on those
4012 tracks.
4013
4014  # Assuming:
4015  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4016  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4017  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4018  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4019
4020  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4021
4022  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4023
4024
4025  my $rs = $schema->resultset('CD')->search(
4026    undef,
4027    {
4028      prefetch => [
4029        { artist => 'record_label'},  # belongs_to => belongs_to
4030        'liner_note',                 # might_have
4031        'cover_image',                # has_one
4032        { tracks => 'guests' },       # has_many => has_many
4033      ]
4034    }
4035  );
4036
4037 This will produce SQL like the following:
4038
4039  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4040         tracks.*, guests.*
4041    FROM cd me
4042    JOIN artist artist
4043      ON artist.artistid = me.artistid
4044    JOIN record_label record_label
4045      ON record_label.labelid = artist.labelid
4046    LEFT JOIN track tracks
4047      ON tracks.cdid = me.cdid
4048    LEFT JOIN guest guests
4049      ON guests.trackid = track.trackid
4050    LEFT JOIN liner_notes liner_note
4051      ON liner_note.cdid = me.cdid
4052    JOIN cd_artwork cover_image
4053      ON cover_image.cdid = me.cdid
4054  ORDER BY tracks.cd
4055
4056 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4057 C<tracks>, and C<guests> of the CD will all be available through the
4058 relationship accessors without the need for additional queries to the
4059 database.
4060
4061 However, there is one caveat to be observed: it can be dangerous to
4062 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4063 relationship on a given level. e.g.:
4064
4065  my $rs = $schema->resultset('CD')->search(
4066    undef,
4067    {
4068      prefetch => [
4069        'tracks',                         # has_many
4070        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4071      ]
4072    }
4073  );
4074
4075 In fact, C<DBIx::Class> will emit the following warning:
4076
4077  Prefetching multiple has_many rels tracks and cd_to_producer at top
4078  level will explode the number of row objects retrievable via ->next
4079  or ->all. Use at your own risk.
4080
4081 The collapser currently can't identify duplicate tuples for multiple
4082 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4083 result the second L<has_many|DBIx::Class::Relationship/has_many>
4084 relation could contain redundant objects.
4085
4086 =head3 Using L</prefetch> with L</join>
4087
4088 L</prefetch> implies a L</join> with the equivalent argument, and is
4089 properly merged with any existing L</join> specification. So the
4090 following:
4091
4092   my $rs = $schema->resultset('CD')->search(
4093    {'record_label.name' => 'Music Product Ltd.'},
4094    {
4095      join     => {artist => 'record_label'},
4096      prefetch => 'artist',
4097    }
4098  );
4099
4100 ... will work, searching on the record label's name, but only
4101 prefetching the C<artist>.
4102
4103 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4104
4105 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4106 prefetched relations.  So given:
4107
4108   my $rs = $schema->resultset('CD')->search(
4109    undef,
4110    {
4111      select   => ['cd.title'],
4112      as       => ['cd_title'],
4113      prefetch => 'artist',
4114    }
4115  );
4116
4117 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4118 becomes: C<'cd_title', 'artist.*'>.
4119
4120 =head3 CAVEATS
4121
4122 Prefetch does a lot of deep magic. As such, it may not behave exactly
4123 as you might expect.
4124
4125 =over 4
4126
4127 =item *
4128
4129 Prefetch uses the L</cache> to populate the prefetched relationships. This
4130 may or may not be what you want.
4131
4132 =item *
4133
4134 If you specify a condition on a prefetched relationship, ONLY those
4135 rows that match the prefetched condition will be fetched into that relationship.
4136 This means that adding prefetch to a search() B<may alter> what is returned by
4137 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4138
4139   my $artist_rs = $schema->resultset('Artist')->search({
4140       'cds.year' => 2008,
4141   }, {
4142       join => 'cds',
4143   });
4144
4145   my $count = $artist_rs->first->cds->count;
4146
4147   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4148
4149   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4150
4151   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4152
4153 that cmp_ok() may or may not pass depending on the datasets involved. This
4154 behavior may or may not survive the 0.09 transition.
4155
4156 =back
4157
4158 =head2 page
4159
4160 =over 4
4161
4162 =item Value: $page
4163
4164 =back
4165
4166 Makes the resultset paged and specifies the page to retrieve. Effectively
4167 identical to creating a non-pages resultset and then calling ->page($page)
4168 on it.
4169
4170 If L</rows> attribute is not specified it defaults to 10 rows per page.
4171
4172 When you have a paged resultset, L</count> will only return the number
4173 of rows in the page. To get the total, use the L</pager> and call
4174 C<total_entries> on it.
4175
4176 =head2 rows
4177
4178 =over 4
4179
4180 =item Value: $rows
4181
4182 =back
4183
4184 Specifies the maximum number of rows for direct retrieval or the number of
4185 rows per page if the page attribute or method is used.
4186
4187 =head2 offset
4188
4189 =over 4
4190
4191 =item Value: $offset
4192
4193 =back
4194
4195 Specifies the (zero-based) row number for the  first row to be returned, or the
4196 of the first row of the first page if paging is used.
4197
4198 =head2 group_by
4199
4200 =over 4
4201
4202 =item Value: \@columns
4203
4204 =back
4205
4206 A arrayref of columns to group by. Can include columns of joined tables.
4207
4208   group_by => [qw/ column1 column2 ... /]
4209
4210 =head2 having
4211
4212 =over 4
4213
4214 =item Value: $condition
4215
4216 =back
4217
4218 HAVING is a select statement attribute that is applied between GROUP BY and
4219 ORDER BY. It is applied to the after the grouping calculations have been
4220 done.
4221
4222   having => { 'count_employee' => { '>=', 100 } }
4223
4224 or with an in-place function in which case literal SQL is required:
4225
4226   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4227
4228 =head2 distinct
4229
4230 =over 4
4231
4232 =item Value: (0 | 1)
4233
4234 =back
4235
4236 Set to 1 to group by all columns. If the resultset already has a group_by
4237 attribute, this setting is ignored and an appropriate warning is issued.
4238
4239 =head2 where
4240
4241 =over 4
4242
4243 Adds to the WHERE clause.
4244
4245   # only return rows WHERE deleted IS NULL for all searches
4246   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
4247
4248 Can be overridden by passing C<< { where => undef } >> as an attribute
4249 to a resultset.
4250
4251 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4252
4253 =back
4254
4255 =head2 cache
4256
4257 Set to 1 to cache search results. This prevents extra SQL queries if you
4258 revisit rows in your ResultSet:
4259
4260   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4261
4262   while( my $artist = $resultset->next ) {
4263     ... do stuff ...
4264   }
4265
4266   $rs->first; # without cache, this would issue a query
4267
4268 By default, searches are not cached.
4269
4270 For more examples of using these attributes, see
4271 L<DBIx::Class::Manual::Cookbook>.
4272
4273 =head2 for
4274
4275 =over 4
4276
4277 =item Value: ( 'update' | 'shared' )
4278
4279 =back
4280
4281 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4282 ... FOR SHARED.
4283
4284 =cut
4285
4286 1;