lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs   = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: $source, \%$attrs
 195
 196 =item Return Value: $rs
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you won't need to construct a resultset manually.  You'll
 206 automatically get one from e.g. a L</search> called in scalar context:
 207
 208   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 209
 210 IMPORTANT: If called on an object, proxies to new_result instead so
 211
 212   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 213
 214 will return a CD object, not a ResultSet.
 215
 216 =cut
 217
 218 sub new {
 219   my $class = shift;
 220   return $class->new_result(@_) if ref $class;
 221
 222   my ($source, $attrs) = @_;
 223   $source = $source->resolve
 224     if $source->isa('DBIx::Class::ResultSourceHandle');
 225   $attrs = { %{$attrs||{}} };
 226
 227   if ($attrs->{page}) {
 228     $attrs->{rows} ||= 10;
 229   }
 230
 231   $attrs->{alias} ||= 'me';
 232
 233   my $self = bless {
 234     result_source => $source,
 235     cond => $attrs->{where},
 236     pager => undef,
 237     attrs => $attrs,
 238   }, $class;
 239
 240   # if there is a dark selector, this means we are already in a
 241   # chain and the cleanup/sanification was taken care of by
 242   # _search_rs already
 243   $self->_normalize_selection($attrs)
 244     unless $attrs->{_dark_selector};
 245
 246   $self->result_class(
 247     $attrs->{result_class} || $source->result_class
 248   );
 249
 250   $self;
 251 }
 252
 253 =head2 search
 254
 255 =over 4
 256
 257 =item Arguments: $cond, \%attrs?
 258
 259 =item Return Value: $resultset (scalar context) ||  @row_objs (list context)
 260
 261 =back
 262
 263   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 264   my $new_rs = $cd_rs->search({ year => 2005 });
 265
 266   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 267                  # year = 2005 OR year = 2004
 268
 269 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 270 returning a list of row objects instead. To avoid that, use L</search_rs>.
 271
 272 If you need to pass in additional attributes but no additional condition,
 273 call it as C<search(undef, \%attrs)>.
 274
 275   # "SELECT name, artistid FROM $artist_table"
 276   my @all_artists = $schema->resultset('Artist')->search(undef, {
 277     columns => [qw/name artistid/],
 278   });
 279
 280 For a list of attributes that can be passed to C<search>, see
 281 L</ATTRIBUTES>. For more examples of using this function, see
 282 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 283 documentation for the first argument, see L<SQL::Abstract>
 284 and its extension L<DBIx::Class::SQLMaker>.
 285
 286 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 287
 288 =head3 CAVEAT
 289
 290 Note that L</search> does not process/deflate any of the values passed in the
 291 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 292 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 293 manually that any value passed to this method will stringify to something the
 294 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 295 objects, for more info see:
 296 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 297
 298 =cut
 299
 300 sub search {
 301   my $self = shift;
 302   my $rs = $self->search_rs( @_ );
 303
 304   if (wantarray) {
 305     return $rs->all;
 306   }
 307   elsif (defined wantarray) {
 308     return $rs;
 309   }
 310   else {
 311     # we can be called by a relationship helper, which in
 312     # turn may be called in void context due to some braindead
 313     # overload or whatever else the user decided to be clever
 314     # at this particular day. Thus limit the exception to
 315     # external code calls only
 316     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 317       if (caller)[0] !~ /^\QDBIx::Class::/;
 318
 319     return ();
 320   }
 321 }
 322
 323 =head2 search_rs
 324
 325 =over 4
 326
 327 =item Arguments: $cond, \%attrs?
 328
 329 =item Return Value: $resultset
 330
 331 =back
 332
 333 This method does the same exact thing as search() except it will
 334 always return a resultset, even in list context.
 335
 336 =cut
 337
 338 sub search_rs {
 339   my $self = shift;
 340
 341   # Special-case handling for (undef, undef).
 342   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 343     @_ = ();
 344   }
 345
 346   my $call_attrs = {};
 347   if (@_ > 1) {
 348     if (ref $_[-1] eq 'HASH') {
 349       # copy for _normalize_selection
 350       $call_attrs = { %{ pop @_ } };
 351     }
 352     elsif (! defined $_[-1] ) {
 353       pop @_;   # search({}, undef)
 354     }
 355   }
 356
 357   # see if we can keep the cache (no $rs changes)
 358   my $cache;
 359   my %safe = (alias => 1, cache => 1);
 360   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 361     ! defined $_[0]
 362       or
 363     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 364       or
 365     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 366   )) {
 367     $cache = $self->get_cache;
 368   }
 369
 370   my $rsrc = $self->result_source;
 371
 372   my $old_attrs = { %{$self->{attrs}} };
 373   my $old_having = delete $old_attrs->{having};
 374   my $old_where = delete $old_attrs->{where};
 375
 376   my $new_attrs = { %$old_attrs };
 377
 378   # take care of call attrs (only if anything is changing)
 379   if (keys %$call_attrs) {
 380
 381     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 382
 383     # reset the current selector list if new selectors are supplied
 384     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 385       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 386     }
 387
 388     # Normalize the new selector list (operates on the passed-in attr structure)
 389     # Need to do it on every chain instead of only once on _resolved_attrs, in
 390     # order to allow detection of empty vs partial 'as'
 391     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 392       if $old_attrs->{_dark_selector};
 393     $self->_normalize_selection ($call_attrs);
 394
 395     # start with blind overwriting merge, exclude selector attrs
 396     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 397     delete @{$new_attrs}{@selector_attrs};
 398
 399     for (@selector_attrs) {
 400       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 401         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 402     }
 403
 404     # older deprecated name, use only if {columns} is not there
 405     if (my $c = delete $new_attrs->{cols}) {
 406       if ($new_attrs->{columns}) {
 407         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 408       }
 409       else {
 410         $new_attrs->{columns} = $c;
 411       }
 412     }
 413
 414
 415     # join/prefetch use their own crazy merging heuristics
 416     foreach my $key (qw/join prefetch/) {
 417       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 418         if exists $call_attrs->{$key};
 419     }
 420
 421     # stack binds together
 422     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 423   }
 424
 425
 426   # rip apart the rest of @_, parse a condition
 427   my $call_cond = do {
 428
 429     if (ref $_[0] eq 'HASH') {
 430       (keys %{$_[0]}) ? $_[0] : undef
 431     }
 432     elsif (@_ == 1) {
 433       $_[0]
 434     }
 435     elsif (@_ % 2) {
 436       $self->throw_exception('Odd number of arguments to search')
 437     }
 438     else {
 439       +{ @_ }
 440     }
 441
 442   } if @_;
 443
 444   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 445     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead';
 446   }
 447
 448   for ($old_where, $call_cond) {
 449     if (defined $_) {
 450       $new_attrs->{where} = $self->_stack_cond (
 451         $_, $new_attrs->{where}
 452       );
 453     }
 454   }
 455
 456   if (defined $old_having) {
 457     $new_attrs->{having} = $self->_stack_cond (
 458       $old_having, $new_attrs->{having}
 459     )
 460   }
 461
 462   my $rs = (ref $self)->new($rsrc, $new_attrs);
 463
 464   $rs->set_cache($cache) if ($cache);
 465
 466   return $rs;
 467 }
 468
 469 my $dark_sel_dumper;
 470 sub _normalize_selection {
 471   my ($self, $attrs) = @_;
 472
 473   # legacy syntax
 474   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 475     if exists $attrs->{include_columns};
 476
 477   # columns are always placed first, however
 478
 479   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 480   # delay the decision on whether to use a default select list ($rsrc->columns)
 481   # allowing stuff like the remove_columns helper to work
 482   #
 483   # select/as +select/+as pairs need special handling - the amount of select/as
 484   # elements in each pair does *not* have to be equal (think multicolumn
 485   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 486   # supplied at all) - try to infer the alias, either from the -as parameter
 487   # of the selector spec, or use the parameter whole if it looks like a column
 488   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 489   # is ok as well), but make sure no more additions to the 'as' chain take place
 490   for my $pref ('', '+') {
 491
 492     my ($sel, $as) = map {
 493       my $key = "${pref}${_}";
 494
 495       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 496         ? @{$attrs->{$key}}
 497         : $attrs->{$key} || ()
 498       ];
 499       delete $attrs->{$key};
 500       $val;
 501     } qw/select as/;
 502
 503     if (! @$as and ! @$sel ) {
 504       next;
 505     }
 506     elsif (@$as and ! @$sel) {
 507       $self->throw_exception(
 508         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 509       );
 510     }
 511     elsif( ! @$as ) {
 512       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 513       # if any @$as has been supplied we assume the user knows what (s)he is doing
 514       # and blindly keep stacking up pieces
 515       unless ($attrs->{_dark_selector}) {
 516         SELECTOR:
 517         for (@$sel) {
 518           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 519             push @$as, $_->{-as};
 520           }
 521           # assume any plain no-space, no-parenthesis string to be a column spec
 522           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 523           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 524             push @$as, $_;
 525           }
 526           # if all else fails - raise a flag that no more aliasing will be allowed
 527           else {
 528             $attrs->{_dark_selector} = {
 529               plus_stage => $pref,
 530               string => ($dark_sel_dumper ||= do {
 531                   require Data::Dumper::Concise;
 532                   Data::Dumper::Concise::DumperObject()->Indent(0);
 533                 })->Values([$_])->Dump
 534               ,
 535             };
 536             last SELECTOR;
 537           }
 538         }
 539       }
 540     }
 541     elsif (@$as < @$sel) {
 542       $self->throw_exception(
 543         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 544       );
 545     }
 546     elsif ($pref and $attrs->{_dark_selector}) {
 547       $self->throw_exception(
 548         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 549       );
 550     }
 551
 552
 553     # merge result
 554     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 555     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 556   }
 557 }
 558
 559 sub _stack_cond {
 560   my ($self, $left, $right) = @_;
 561
 562   # collapse single element top-level conditions
 563   # (single pass only, unlikely to need recursion)
 564   for ($left, $right) {
 565     if (ref $_ eq 'ARRAY') {
 566       if (@$_ == 0) {
 567         $_ = undef;
 568       }
 569       elsif (@$_ == 1) {
 570         $_ = $_->[0];
 571       }
 572     }
 573     elsif (ref $_ eq 'HASH') {
 574       my ($first, $more) = keys %$_;
 575
 576       # empty hash
 577       if (! defined $first) {
 578         $_ = undef;
 579       }
 580       # one element hash
 581       elsif (! defined $more) {
 582         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 583           $_ = $_->{'-and'};
 584         }
 585         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 586           $_ = $_->{'-or'};
 587         }
 588       }
 589     }
 590   }
 591
 592   # merge hashes with weeding out of duplicates (simple cases only)
 593   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 594
 595     # shallow copy to destroy
 596     $right = { %$right };
 597     for (grep { exists $right->{$_} } keys %$left) {
 598       # the use of eq_deeply here is justified - the rhs of an
 599       # expression can contain a lot of twisted weird stuff
 600       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 601     }
 602
 603     $right = undef unless keys %$right;
 604   }
 605
 606
 607   if (defined $left xor defined $right) {
 608     return defined $left ? $left : $right;
 609   }
 610   elsif (! defined $left) {
 611     return undef;
 612   }
 613   else {
 614     return { -and => [ $left, $right ] };
 615   }
 616 }
 617
 618 =head2 search_literal
 619
 620 =over 4
 621
 622 =item Arguments: $sql_fragment, @bind_values
 623
 624 =item Return Value: $resultset (scalar context) || @row_objs (list context)
 625
 626 =back
 627
 628   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 629   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 630
 631 Pass a literal chunk of SQL to be added to the conditional part of the
 632 resultset query.
 633
 634 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 635 only be used in that context. C<search_literal> is a convenience method.
 636 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 637 columns are bound correctly, use C<search>.
 638
 639 Example of how to use C<search> instead of C<search_literal>
 640
 641   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 642   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 643
 644
 645 See L<DBIx::Class::Manual::Cookbook/Searching> and
 646 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 647 require C<search_literal>.
 648
 649 =cut
 650
 651 sub search_literal {
 652   my ($self, $sql, @bind) = @_;
 653   my $attr;
 654   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 655     $attr = pop @bind;
 656   }
 657   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 658 }
 659
 660 =head2 find
 661
 662 =over 4
 663
 664 =item Arguments: \%columns_values | @pk_values, \%attrs?
 665
 666 =item Return Value: $row_object | undef
 667
 668 =back
 669
 670 Finds and returns a single row based on supplied criteria. Takes either a
 671 hashref with the same format as L</create> (including inference of foreign
 672 keys from related objects), or a list of primary key values in the same
 673 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 674 declaration on the L</result_source>.
 675
 676 In either case an attempt is made to combine conditions already existing on
 677 the resultset with the condition passed to this method.
 678
 679 To aid with preparing the correct query for the storage you may supply the
 680 C<key> attribute, which is the name of a
 681 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 682 unique constraint corresponding to the
 683 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 684 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 685 to construct a query that satisfies the named unique constraint fully (
 686 non-NULL values for each column member of the constraint) an exception is
 687 thrown.
 688
 689 If no C<key> is specified, the search is carried over all unique constraints
 690 which are fully defined by the available condition.
 691
 692 If no such constraint is found, C<find> currently defaults to a simple
 693 C<< search->(\%column_values) >> which may or may not do what you expect.
 694 Note that this fallback behavior may be deprecated in further versions. If
 695 you need to search with arbitrary conditions - use L</search>. If the query
 696 resulting from this fallback produces more than one row, a warning to the
 697 effect is issued, though only the first row is constructed and returned as
 698 C<$row_object>.
 699
 700 In addition to C<key>, L</find> recognizes and applies standard
 701 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 702
 703 Note that if you have extra concerns about the correctness of the resulting
 704 query you need to specify the C<key> attribute and supply the entire condition
 705 as an argument to find (since it is not always possible to perform the
 706 combination of the resultset condition with the supplied one, especially if
 707 the resultset condition contains literal sql).
 708
 709 For example, to find a row by its primary key:
 710
 711   my $cd = $schema->resultset('CD')->find(5);
 712
 713 You can also find a row by a specific unique constraint:
 714
 715   my $cd = $schema->resultset('CD')->find(
 716     {
 717       artist => 'Massive Attack',
 718       title  => 'Mezzanine',
 719     },
 720     { key => 'cd_artist_title' }
 721   );
 722
 723 See also L</find_or_create> and L</update_or_create>.
 724
 725 =cut
 726
 727 sub find {
 728   my $self = shift;
 729   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 730
 731   my $rsrc = $self->result_source;
 732
 733   my $constraint_name;
 734   if (exists $attrs->{key}) {
 735     $constraint_name = defined $attrs->{key}
 736       ? $attrs->{key}
 737       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 738     ;
 739   }
 740
 741   # Parse out the condition from input
 742   my $call_cond;
 743
 744   if (ref $_[0] eq 'HASH') {
 745     $call_cond = { %{$_[0]} };
 746   }
 747   else {
 748     # if only values are supplied we need to default to 'primary'
 749     $constraint_name = 'primary' unless defined $constraint_name;
 750
 751     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 752
 753     $self->throw_exception(
 754       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 755     ) unless @c_cols;
 756
 757     $self->throw_exception (
 758       'find() expects either a column/value hashref, or a list of values '
 759     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 760     ) unless @c_cols == @_;
 761
 762     $call_cond = {};
 763     @{$call_cond}{@c_cols} = @_;
 764   }
 765
 766   my %related;
 767   for my $key (keys %$call_cond) {
 768     if (
 769       my $keyref = ref($call_cond->{$key})
 770         and
 771       my $relinfo = $rsrc->relationship_info($key)
 772     ) {
 773       my $val = delete $call_cond->{$key};
 774
 775       next if $keyref eq 'ARRAY'; # has_many for multi_create
 776
 777       my $rel_q = $rsrc->_resolve_condition(
 778         $relinfo->{cond}, $val, $key, $key
 779       );
 780       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 781       @related{keys %$rel_q} = values %$rel_q;
 782     }
 783   }
 784
 785   # relationship conditions take precedence (?)
 786   @{$call_cond}{keys %related} = values %related;
 787
 788   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 789   my $final_cond;
 790   if (defined $constraint_name) {
 791     $final_cond = $self->_qualify_cond_columns (
 792
 793       $self->_build_unique_cond (
 794         $constraint_name,
 795         $call_cond,
 796       ),
 797
 798       $alias,
 799     );
 800   }
 801   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 802     # This means that we got here after a merger of relationship conditions
 803     # in ::Relationship::Base::search_related (the row method), and furthermore
 804     # the relationship is of the 'single' type. This means that the condition
 805     # provided by the relationship (already attached to $self) is sufficient,
 806     # as there can be only one row in the database that would satisfy the
 807     # relationship
 808   }
 809   else {
 810     # no key was specified - fall down to heuristics mode:
 811     # run through all unique queries registered on the resultset, and
 812     # 'OR' all qualifying queries together
 813     my (@unique_queries, %seen_column_combinations);
 814     for my $c_name ($rsrc->unique_constraint_names) {
 815       next if $seen_column_combinations{
 816         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 817       }++;
 818
 819       push @unique_queries, try {
 820         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 821       } || ();
 822     }
 823
 824     $final_cond = @unique_queries
 825       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 826       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 827     ;
 828   }
 829
 830   # Run the query, passing the result_class since it should propagate for find
 831   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 832   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 833     my $row = $rs->next;
 834     carp "Query returned more than one row" if $rs->next;
 835     return $row;
 836   }
 837   else {
 838     return $rs->single;
 839   }
 840 }
 841
 842 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 843 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 844 #
 845 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 846 # condition. It is provided for overrides until a saner way forward is devised
 847 #
 848 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 849 # the road. Please adjust your tests accordingly to catch this situation early
 850 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 851 #
 852 # The method will not be removed without an adequately complete replacement
 853 # for strict-mode enforcement
 854 sub _non_unique_find_fallback {
 855   my ($self, $cond, $attrs) = @_;
 856
 857   return $self->_qualify_cond_columns(
 858     $cond,
 859     exists $attrs->{alias}
 860       ? $attrs->{alias}
 861       : $self->{attrs}{alias}
 862   );
 863 }
 864
 865
 866 sub _qualify_cond_columns {
 867   my ($self, $cond, $alias) = @_;
 868
 869   my %aliased = %$cond;
 870   for (keys %aliased) {
 871     $aliased{"$alias.$_"} = delete $aliased{$_}
 872       if $_ !~ /\./;
 873   }
 874
 875   return \%aliased;
 876 }
 877
 878 sub _build_unique_cond {
 879   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 880
 881   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 882
 883   # combination may fail if $self->{cond} is non-trivial
 884   my ($final_cond) = try {
 885     $self->_merge_with_rscond ($extra_cond)
 886   } catch {
 887     +{ %$extra_cond }
 888   };
 889
 890   # trim out everything not in $columns
 891   $final_cond = { map {
 892     exists $final_cond->{$_}
 893       ? ( $_ => $final_cond->{$_} )
 894       : ()
 895   } @c_cols };
 896
 897   if (my @missing = grep
 898     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 899     (@c_cols)
 900   ) {
 901     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 902       $constraint_name,
 903       join (', ', map { "'$_'" } @missing),
 904     ) );
 905   }
 906
 907   if (
 908     !$croak_on_null
 909       and
 910     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 911       and
 912     my @undefs = grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 913   ) {
 914     carp_unique ( sprintf (
 915       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 916     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 917     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 918       $constraint_name,
 919       join (', ', map { "'$_'" } @undefs),
 920     ));
 921   }
 922
 923   return $final_cond;
 924 }
 925
 926 =head2 search_related
 927
 928 =over 4
 929
 930 =item Arguments: $rel, $cond, \%attrs?
 931
 932 =item Return Value: $new_resultset (scalar context) || @row_objs (list context)
 933
 934 =back
 935
 936   $new_rs = $cd_rs->search_related('artist', {
 937     name => 'Emo-R-Us',
 938   });
 939
 940 Searches the specified relationship, optionally specifying a condition and
 941 attributes for matching records. See L</ATTRIBUTES> for more information.
 942
 943 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 944 returning a list of row objects instead. To avoid that, use L</search_related_rs>.
 945
 946 See also L</search_related_rs>.
 947
 948 =cut
 949
 950 sub search_related {
 951   return shift->related_resultset(shift)->search(@_);
 952 }
 953
 954 =head2 search_related_rs
 955
 956 This method works exactly the same as search_related, except that
 957 it guarantees a resultset, even in list context.
 958
 959 =cut
 960
 961 sub search_related_rs {
 962   return shift->related_resultset(shift)->search_rs(@_);
 963 }
 964
 965 =head2 cursor
 966
 967 =over 4
 968
 969 =item Arguments: none
 970
 971 =item Return Value: $cursor
 972
 973 =back
 974
 975 Returns a storage-driven cursor to the given resultset. See
 976 L<DBIx::Class::Cursor> for more information.
 977
 978 =cut
 979
 980 sub cursor {
 981   my ($self) = @_;
 982
 983   my $attrs = $self->_resolved_attrs_copy;
 984
 985   return $self->{cursor}
 986     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 987           $attrs->{where},$attrs);
 988 }
 989
 990 =head2 single
 991
 992 =over 4
 993
 994 =item Arguments: $cond?
 995
 996 =item Return Value: $row_object | undef
 997
 998 =back
 999
1000   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1001
1002 Inflates the first result without creating a cursor if the resultset has
1003 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1004 of L</search>.
1005
1006 While this method can take an optional search condition (just like L</search>)
1007 being a fast-code-path it does not recognize search attributes. If you need to
1008 add extra joins or similar, call L</search> and then chain-call L</single> on the
1009 L<DBIx::Class::ResultSet> returned.
1010
1011 =over
1012
1013 =item B<Note>
1014
1015 As of 0.08100, this method enforces the assumption that the preceding
1016 query returns only one row. If more than one row is returned, you will receive
1017 a warning:
1018
1019   Query returned more than one row
1020
1021 In this case, you should be using L</next> or L</find> instead, or if you really
1022 know what you are doing, use the L</rows> attribute to explicitly limit the size
1023 of the resultset.
1024
1025 This method will also throw an exception if it is called on a resultset prefetching
1026 has_many, as such a prefetch implies fetching multiple rows from the database in
1027 order to assemble the resulting object.
1028
1029 =back
1030
1031 =cut
1032
1033 sub single {
1034   my ($self, $where) = @_;
1035   if(@_ > 2) {
1036       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1037   }
1038
1039   my $attrs = $self->_resolved_attrs_copy;
1040
1041   if (keys %{$attrs->{collapse}}) {
1042     $self->throw_exception(
1043       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1044     );
1045   }
1046
1047   if ($where) {
1048     if (defined $attrs->{where}) {
1049       $attrs->{where} = {
1050         '-and' =>
1051             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1052                $where, delete $attrs->{where} ]
1053       };
1054     } else {
1055       $attrs->{where} = $where;
1056     }
1057   }
1058
1059   my @data = $self->result_source->storage->select_single(
1060     $attrs->{from}, $attrs->{select},
1061     $attrs->{where}, $attrs
1062   );
1063
1064   return (@data ? ($self->_construct_object(@data))[0] : undef);
1065 }
1066
1067
1068 # _collapse_query
1069 #
1070 # Recursively collapse the query, accumulating values for each column.
1071
1072 sub _collapse_query {
1073   my ($self, $query, $collapsed) = @_;
1074
1075   $collapsed ||= {};
1076
1077   if (ref $query eq 'ARRAY') {
1078     foreach my $subquery (@$query) {
1079       next unless ref $subquery;  # -or
1080       $collapsed = $self->_collapse_query($subquery, $collapsed);
1081     }
1082   }
1083   elsif (ref $query eq 'HASH') {
1084     if (keys %$query and (keys %$query)[0] eq '-and') {
1085       foreach my $subquery (@{$query->{-and}}) {
1086         $collapsed = $self->_collapse_query($subquery, $collapsed);
1087       }
1088     }
1089     else {
1090       foreach my $col (keys %$query) {
1091         my $value = $query->{$col};
1092         $collapsed->{$col}{$value}++;
1093       }
1094     }
1095   }
1096
1097   return $collapsed;
1098 }
1099
1100 =head2 get_column
1101
1102 =over 4
1103
1104 =item Arguments: $cond?
1105
1106 =item Return Value: $resultsetcolumn
1107
1108 =back
1109
1110   my $max_length = $rs->get_column('length')->max;
1111
1112 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1113
1114 =cut
1115
1116 sub get_column {
1117   my ($self, $column) = @_;
1118   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1119   return $new;
1120 }
1121
1122 =head2 search_like
1123
1124 =over 4
1125
1126 =item Arguments: $cond, \%attrs?
1127
1128 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1129
1130 =back
1131
1132   # WHERE title LIKE '%blue%'
1133   $cd_rs = $rs->search_like({ title => '%blue%'});
1134
1135 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1136 that this is simply a convenience method retained for ex Class::DBI users.
1137 You most likely want to use L</search> with specific operators.
1138
1139 For more information, see L<DBIx::Class::Manual::Cookbook>.
1140
1141 This method is deprecated and will be removed in 0.09. Use L</search()>
1142 instead. An example conversion is:
1143
1144   ->search_like({ foo => 'bar' });
1145
1146   # Becomes
1147
1148   ->search({ foo => { like => 'bar' } });
1149
1150 =cut
1151
1152 sub search_like {
1153   my $class = shift;
1154   carp_unique (
1155     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1156    .' Instead use ->search({ x => { -like => "y%" } })'
1157    .' (note the outer pair of {}s - they are important!)'
1158   );
1159   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1160   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1161   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1162   return $class->search($query, { %$attrs });
1163 }
1164
1165 =head2 slice
1166
1167 =over 4
1168
1169 =item Arguments: $first, $last
1170
1171 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1172
1173 =back
1174
1175 Returns a resultset or object list representing a subset of elements from the
1176 resultset slice is called on. Indexes are from 0, i.e., to get the first
1177 three records, call:
1178
1179   my ($one, $two, $three) = $rs->slice(0, 2);
1180
1181 =cut
1182
1183 sub slice {
1184   my ($self, $min, $max) = @_;
1185   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1186   $attrs->{offset} = $self->{attrs}{offset} || 0;
1187   $attrs->{offset} += $min;
1188   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1189   return $self->search(undef, $attrs);
1190   #my $slice = (ref $self)->new($self->result_source, $attrs);
1191   #return (wantarray ? $slice->all : $slice);
1192 }
1193
1194 =head2 next
1195
1196 =over 4
1197
1198 =item Arguments: none
1199
1200 =item Return Value: $result | undef
1201
1202 =back
1203
1204 Returns the next element in the resultset (C<undef> is there is none).
1205
1206 Can be used to efficiently iterate over records in the resultset:
1207
1208   my $rs = $schema->resultset('CD')->search;
1209   while (my $cd = $rs->next) {
1210     print $cd->title;
1211   }
1212
1213 Note that you need to store the resultset object, and call C<next> on it.
1214 Calling C<< resultset('Table')->next >> repeatedly will always return the
1215 first record from the resultset.
1216
1217 =cut
1218
1219 sub next {
1220   my ($self) = @_;
1221   if (my $cache = $self->get_cache) {
1222     $self->{all_cache_position} ||= 0;
1223     return $cache->[$self->{all_cache_position}++];
1224   }
1225   if ($self->{attrs}{cache}) {
1226     delete $self->{pager};
1227     $self->{all_cache_position} = 1;
1228     return ($self->all)[0];
1229   }
1230   if ($self->{stashed_objects}) {
1231     my $obj = shift(@{$self->{stashed_objects}});
1232     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1233     return $obj;
1234   }
1235   my @row = (
1236     exists $self->{stashed_row}
1237       ? @{delete $self->{stashed_row}}
1238       : $self->cursor->next
1239   );
1240   return undef unless (@row);
1241   my ($row, @more) = $self->_construct_object(@row);
1242   $self->{stashed_objects} = \@more if @more;
1243   return $row;
1244 }
1245
1246 sub _construct_object {
1247   my ($self, @row) = @_;
1248
1249   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1250     or return ();
1251   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1252   @new = $self->{_attrs}{record_filter}->(@new)
1253     if exists $self->{_attrs}{record_filter};
1254   return @new;
1255 }
1256
1257 sub _collapse_result {
1258   my ($self, $as_proto, $row) = @_;
1259
1260   my @copy = @$row;
1261
1262   # 'foo'         => [ undef, 'foo' ]
1263   # 'foo.bar'     => [ 'foo', 'bar' ]
1264   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1265
1266   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1267
1268   my %collapse = %{$self->{_attrs}{collapse}||{}};
1269
1270   my @pri_index;
1271
1272   # if we're doing collapsing (has_many prefetch) we need to grab records
1273   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1274   # we know we don't have to bother.
1275
1276   # the reason for not using the collapse stuff directly is because if you
1277   # had for e.g. two artists in a row with no cds, the collapse info for
1278   # both would be NULL (undef) so you'd lose the second artist
1279
1280   # store just the index so we can check the array positions from the row
1281   # without having to contruct the full hash
1282
1283   if (keys %collapse) {
1284     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1285     foreach my $i (0 .. $#construct_as) {
1286       next if defined($construct_as[$i][0]); # only self table
1287       if (delete $pri{$construct_as[$i][1]}) {
1288         push(@pri_index, $i);
1289       }
1290       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1291     }
1292   }
1293
1294   # no need to do an if, it'll be empty if @pri_index is empty anyway
1295
1296   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1297
1298   my @const_rows;
1299
1300   do { # no need to check anything at the front, we always want the first row
1301
1302     my %const;
1303
1304     foreach my $this_as (@construct_as) {
1305       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1306     }
1307
1308     push(@const_rows, \%const);
1309
1310   } until ( # no pri_index => no collapse => drop straight out
1311       !@pri_index
1312     or
1313       do { # get another row, stash it, drop out if different PK
1314
1315         @copy = $self->cursor->next;
1316         $self->{stashed_row} = \@copy;
1317
1318         # last thing in do block, counts as true if anything doesn't match
1319
1320         # check xor defined first for NULL vs. NOT NULL then if one is
1321         # defined the other must be so check string equality
1322
1323         grep {
1324           (defined $pri_vals{$_} ^ defined $copy[$_])
1325           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1326         } @pri_index;
1327       }
1328   );
1329
1330   my $alias = $self->{attrs}{alias};
1331   my $info = [];
1332
1333   my %collapse_pos;
1334
1335   my @const_keys;
1336
1337   foreach my $const (@const_rows) {
1338     scalar @const_keys or do {
1339       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1340     };
1341     foreach my $key (@const_keys) {
1342       if (length $key) {
1343         my $target = $info;
1344         my @parts = split(/\./, $key);
1345         my $cur = '';
1346         my $data = $const->{$key};
1347         foreach my $p (@parts) {
1348           $target = $target->[1]->{$p} ||= [];
1349           $cur .= ".${p}";
1350           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1351             # collapsing at this point and on final part
1352             my $pos = $collapse_pos{$cur};
1353             CK: foreach my $ck (@ckey) {
1354               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1355                 $collapse_pos{$cur} = $data;
1356                 delete @collapse_pos{ # clear all positioning for sub-entries
1357                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1358                 };
1359                 push(@$target, []);
1360                 last CK;
1361               }
1362             }
1363           }
1364           if (exists $collapse{$cur}) {
1365             $target = $target->[-1];
1366           }
1367         }
1368         $target->[0] = $data;
1369       } else {
1370         $info->[0] = $const->{$key};
1371       }
1372     }
1373   }
1374
1375   return $info;
1376 }
1377
1378 =head2 result_source
1379
1380 =over 4
1381
1382 =item Arguments: $result_source?
1383
1384 =item Return Value: $result_source
1385
1386 =back
1387
1388 An accessor for the primary ResultSource object from which this ResultSet
1389 is derived.
1390
1391 =head2 result_class
1392
1393 =over 4
1394
1395 =item Arguments: $result_class?
1396
1397 =item Return Value: $result_class
1398
1399 =back
1400
1401 An accessor for the class to use when creating row objects. Defaults to
1402 C<< result_source->result_class >> - which in most cases is the name of the
1403 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1404
1405 Note that changing the result_class will also remove any components
1406 that were originally loaded in the source class via
1407 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1408 in the original source class will not run.
1409
1410 =cut
1411
1412 sub result_class {
1413   my ($self, $result_class) = @_;
1414   if ($result_class) {
1415     unless (ref $result_class) { # don't fire this for an object
1416       $self->ensure_class_loaded($result_class);
1417     }
1418     $self->_result_class($result_class);
1419     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1420     # permit the user to set result class on one result set only; it only
1421     # chains if provided to search()
1422     #$self->{attrs}{result_class} = $result_class if ref $self;
1423   }
1424   $self->_result_class;
1425 }
1426
1427 =head2 count
1428
1429 =over 4
1430
1431 =item Arguments: $cond, \%attrs??
1432
1433 =item Return Value: $count
1434
1435 =back
1436
1437 Performs an SQL C<COUNT> with the same query as the resultset was built
1438 with to find the number of elements. Passing arguments is equivalent to
1439 C<< $rs->search ($cond, \%attrs)->count >>
1440
1441 =cut
1442
1443 sub count {
1444   my $self = shift;
1445   return $self->search(@_)->count if @_ and defined $_[0];
1446   return scalar @{ $self->get_cache } if $self->get_cache;
1447
1448   my $attrs = $self->_resolved_attrs_copy;
1449
1450   # this is a little optimization - it is faster to do the limit
1451   # adjustments in software, instead of a subquery
1452   my $rows = delete $attrs->{rows};
1453   my $offset = delete $attrs->{offset};
1454
1455   my $crs;
1456   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1457     $crs = $self->_count_subq_rs ($attrs);
1458   }
1459   else {
1460     $crs = $self->_count_rs ($attrs);
1461   }
1462   my $count = $crs->next;
1463
1464   $count -= $offset if $offset;
1465   $count = $rows if $rows and $rows < $count;
1466   $count = 0 if ($count < 0);
1467
1468   return $count;
1469 }
1470
1471 =head2 count_rs
1472
1473 =over 4
1474
1475 =item Arguments: $cond, \%attrs??
1476
1477 =item Return Value: $count_rs
1478
1479 =back
1480
1481 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1482 This can be very handy for subqueries:
1483
1484   ->search( { amount => $some_rs->count_rs->as_query } )
1485
1486 As with regular resultsets the SQL query will be executed only after
1487 the resultset is accessed via L</next> or L</all>. That would return
1488 the same single value obtainable via L</count>.
1489
1490 =cut
1491
1492 sub count_rs {
1493   my $self = shift;
1494   return $self->search(@_)->count_rs if @_;
1495
1496   # this may look like a lack of abstraction (count() does about the same)
1497   # but in fact an _rs *must* use a subquery for the limits, as the
1498   # software based limiting can not be ported if this $rs is to be used
1499   # in a subquery itself (i.e. ->as_query)
1500   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1501     return $self->_count_subq_rs;
1502   }
1503   else {
1504     return $self->_count_rs;
1505   }
1506 }
1507
1508 #
1509 # returns a ResultSetColumn object tied to the count query
1510 #
1511 sub _count_rs {
1512   my ($self, $attrs) = @_;
1513
1514   my $rsrc = $self->result_source;
1515   $attrs ||= $self->_resolved_attrs;
1516
1517   my $tmp_attrs = { %$attrs };
1518   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1519   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1520
1521   # overwrite the selector (supplied by the storage)
1522   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1523   $tmp_attrs->{as} = 'count';
1524   delete @{$tmp_attrs}{qw/columns/};
1525
1526   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1527
1528   return $tmp_rs;
1529 }
1530
1531 #
1532 # same as above but uses a subquery
1533 #
1534 sub _count_subq_rs {
1535   my ($self, $attrs) = @_;
1536
1537   my $rsrc = $self->result_source;
1538   $attrs ||= $self->_resolved_attrs;
1539
1540   my $sub_attrs = { %$attrs };
1541   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1542   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1543
1544   # if we multi-prefetch we group_by primary keys only as this is what we would
1545   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1546   if ( keys %{$attrs->{collapse}}  ) {
1547     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1548   }
1549
1550   # Calculate subquery selector
1551   if (my $g = $sub_attrs->{group_by}) {
1552
1553     my $sql_maker = $rsrc->storage->sql_maker;
1554
1555     # necessary as the group_by may refer to aliased functions
1556     my $sel_index;
1557     for my $sel (@{$attrs->{select}}) {
1558       $sel_index->{$sel->{-as}} = $sel
1559         if (ref $sel eq 'HASH' and $sel->{-as});
1560     }
1561
1562     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1563     # also look for named aggregates referred in the having clause
1564     # having often contains scalarrefs - thus parse it out entirely
1565     my @parts = @$g;
1566     if ($attrs->{having}) {
1567       local $sql_maker->{having_bind};
1568       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1569       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1570       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1571         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1572         # if we don't unset it we screw up retarded but unfortunately working
1573         # 'MAX(foo.bar)' => { '>', 3 }
1574         $sql_maker->{name_sep} = '';
1575       }
1576
1577       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1578
1579       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1580
1581       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1582       # and if all fails for an utterly naive quoted scalar-with-function
1583       while ($sql =~ /
1584         $rquote $sep $lquote (.+?) $rquote
1585           |
1586         [\s,] \w+ \. (\w+) [\s,]
1587           |
1588         [\s,] $lquote (.+?) $rquote [\s,]
1589       /gx) {
1590         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1591       }
1592     }
1593
1594     for (@parts) {
1595       my $colpiece = $sel_index->{$_} || $_;
1596
1597       # unqualify join-based group_by's. Arcane but possible query
1598       # also horrible horrible hack to alias a column (not a func.)
1599       # (probably need to introduce SQLA syntax)
1600       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1601         my $as = $colpiece;
1602         $as =~ s/\./__/;
1603         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1604       }
1605       push @{$sub_attrs->{select}}, $colpiece;
1606     }
1607   }
1608   else {
1609     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1610     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1611   }
1612
1613   return $rsrc->resultset_class
1614                ->new ($rsrc, $sub_attrs)
1615                 ->as_subselect_rs
1616                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1617                   ->get_column ('count');
1618 }
1619
1620 sub _bool {
1621   return 1;
1622 }
1623
1624 =head2 count_literal
1625
1626 =over 4
1627
1628 =item Arguments: $sql_fragment, @bind_values
1629
1630 =item Return Value: $count
1631
1632 =back
1633
1634 Counts the results in a literal query. Equivalent to calling L</search_literal>
1635 with the passed arguments, then L</count>.
1636
1637 =cut
1638
1639 sub count_literal { shift->search_literal(@_)->count; }
1640
1641 =head2 all
1642
1643 =over 4
1644
1645 =item Arguments: none
1646
1647 =item Return Value: @objects
1648
1649 =back
1650
1651 Returns all elements in the resultset.
1652
1653 =cut
1654
1655 sub all {
1656   my $self = shift;
1657   if(@_) {
1658       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1659   }
1660
1661   return @{ $self->get_cache } if $self->get_cache;
1662
1663   my @obj;
1664
1665   if (keys %{$self->_resolved_attrs->{collapse}}) {
1666     # Using $self->cursor->all is really just an optimisation.
1667     # If we're collapsing has_many prefetches it probably makes
1668     # very little difference, and this is cleaner than hacking
1669     # _construct_object to survive the approach
1670     $self->cursor->reset;
1671     my @row = $self->cursor->next;
1672     while (@row) {
1673       push(@obj, $self->_construct_object(@row));
1674       @row = (exists $self->{stashed_row}
1675                ? @{delete $self->{stashed_row}}
1676                : $self->cursor->next);
1677     }
1678   } else {
1679     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1680   }
1681
1682   $self->set_cache(\@obj) if $self->{attrs}{cache};
1683
1684   return @obj;
1685 }
1686
1687 =head2 reset
1688
1689 =over 4
1690
1691 =item Arguments: none
1692
1693 =item Return Value: $self
1694
1695 =back
1696
1697 Resets the resultset's cursor, so you can iterate through the elements again.
1698 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1699 another query.
1700
1701 =cut
1702
1703 sub reset {
1704   my ($self) = @_;
1705   delete $self->{_attrs} if exists $self->{_attrs};
1706   $self->{all_cache_position} = 0;
1707   $self->cursor->reset;
1708   return $self;
1709 }
1710
1711 =head2 first
1712
1713 =over 4
1714
1715 =item Arguments: none
1716
1717 =item Return Value: $object | undef
1718
1719 =back
1720
1721 Resets the resultset and returns an object for the first result (or C<undef>
1722 if the resultset is empty).
1723
1724 =cut
1725
1726 sub first {
1727   return $_[0]->reset->next;
1728 }
1729
1730
1731 # _rs_update_delete
1732 #
1733 # Determines whether and what type of subquery is required for the $rs operation.
1734 # If grouping is necessary either supplies its own, or verifies the current one
1735 # After all is done delegates to the proper storage method.
1736
1737 sub _rs_update_delete {
1738   my ($self, $op, $values) = @_;
1739
1740   my $rsrc = $self->result_source;
1741
1742   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1743   my $needs_subq = $needs_group_by_subq || $self->_has_resolved_attr(qw/rows offset/);
1744
1745   if ($needs_group_by_subq or $needs_subq) {
1746
1747     # make a new $rs selecting only the PKs (that's all we really need)
1748     my $attrs = $self->_resolved_attrs_copy;
1749
1750
1751     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1752     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->_pri_cols) ];
1753
1754     if ($needs_group_by_subq) {
1755       # make sure no group_by was supplied, or if there is one - make sure it matches
1756       # the columns compiled above perfectly. Anything else can not be sanely executed
1757       # on most databases so croak right then and there
1758
1759       if (my $g = $attrs->{group_by}) {
1760         my @current_group_by = map
1761           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1762           @$g
1763         ;
1764
1765         if (
1766           join ("\x00", sort @current_group_by)
1767             ne
1768           join ("\x00", sort @{$attrs->{columns}} )
1769         ) {
1770           $self->throw_exception (
1771             "You have just attempted a $op operation on a resultset which does group_by"
1772             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1773             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1774             . ' kind of queries. Please retry the operation with a modified group_by or'
1775             . ' without using one at all.'
1776           );
1777         }
1778       }
1779       else {
1780         $attrs->{group_by} = $attrs->{columns};
1781       }
1782     }
1783
1784     my $subrs = (ref $self)->new($rsrc, $attrs);
1785     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1786   }
1787   else {
1788     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1789     # a condition containing 'me' or other table prefixes will not work
1790     # at all. What this code tries to do (badly) is to generate a condition
1791     # with the qualifiers removed, by exploiting the quote mechanism of sqla
1792     #
1793     # this is atrocious and should be replaced by normal sqla introspection
1794     # one sunny day
1795     my ($sql, @bind) = do {
1796       my $sqla = $rsrc->storage->sql_maker;
1797       local $sqla->{_dequalify_idents} = 1;
1798       $sqla->_recurse_where($self->{cond});
1799     } if $self->{cond};
1800
1801     return $rsrc->storage->$op(
1802       $rsrc,
1803       $op eq 'update' ? $values : (),
1804       $self->{cond} ? \[$sql, @bind] : (),
1805     );
1806   }
1807 }
1808
1809 =head2 update
1810
1811 =over 4
1812
1813 =item Arguments: \%values
1814
1815 =item Return Value: $storage_rv
1816
1817 =back
1818
1819 Sets the specified columns in the resultset to the supplied values in a
1820 single query. Note that this will not run any accessor/set_column/update
1821 triggers, nor will it update any row object instances derived from this
1822 resultset (this includes the contents of the L<resultset cache|/set_cache>
1823 if any). See L</update_all> if you need to execute any on-update
1824 triggers or cascades defined either by you or a
1825 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1826
1827 The return value is a pass through of what the underlying
1828 storage backend returned, and may vary. See L<DBI/execute> for the most
1829 common case.
1830
1831 =head3 CAVEAT
1832
1833 Note that L</update> does not process/deflate any of the values passed in.
1834 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1835 ensure manually that any value passed to this method will stringify to
1836 something the RDBMS knows how to deal with. A notable example is the
1837 handling of L<DateTime> objects, for more info see:
1838 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1839
1840 =cut
1841
1842 sub update {
1843   my ($self, $values) = @_;
1844   $self->throw_exception('Values for update must be a hash')
1845     unless ref $values eq 'HASH';
1846
1847   return $self->_rs_update_delete ('update', $values);
1848 }
1849
1850 =head2 update_all
1851
1852 =over 4
1853
1854 =item Arguments: \%values
1855
1856 =item Return Value: 1
1857
1858 =back
1859
1860 Fetches all objects and updates them one at a time via
1861 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1862 triggers, while L</update> will not.
1863
1864 =cut
1865
1866 sub update_all {
1867   my ($self, $values) = @_;
1868   $self->throw_exception('Values for update_all must be a hash')
1869     unless ref $values eq 'HASH';
1870
1871   my $guard = $self->result_source->schema->txn_scope_guard;
1872   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1873   $guard->commit;
1874   return 1;
1875 }
1876
1877 =head2 delete
1878
1879 =over 4
1880
1881 =item Arguments: none
1882
1883 =item Return Value: $storage_rv
1884
1885 =back
1886
1887 Deletes the rows matching this resultset in a single query. Note that this
1888 will not run any delete triggers, nor will it alter the
1889 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1890 derived from this resultset (this includes the contents of the
1891 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1892 execute any on-delete triggers or cascades defined either by you or a
1893 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1894
1895 The return value is a pass through of what the underlying storage backend
1896 returned, and may vary. See L<DBI/execute> for the most common case.
1897
1898 =cut
1899
1900 sub delete {
1901   my $self = shift;
1902   $self->throw_exception('delete does not accept any arguments')
1903     if @_;
1904
1905   return $self->_rs_update_delete ('delete');
1906 }
1907
1908 =head2 delete_all
1909
1910 =over 4
1911
1912 =item Arguments: none
1913
1914 =item Return Value: 1
1915
1916 =back
1917
1918 Fetches all objects and deletes them one at a time via
1919 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
1920 triggers, while L</delete> will not.
1921
1922 =cut
1923
1924 sub delete_all {
1925   my $self = shift;
1926   $self->throw_exception('delete_all does not accept any arguments')
1927     if @_;
1928
1929   my $guard = $self->result_source->schema->txn_scope_guard;
1930   $_->delete for $self->all;
1931   $guard->commit;
1932   return 1;
1933 }
1934
1935 =head2 populate
1936
1937 =over 4
1938
1939 =item Arguments: \@data;
1940
1941 =back
1942
1943 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1944 For the arrayref of hashrefs style each hashref should be a structure suitable
1945 for submitting to a $resultset->create(...) method.
1946
1947 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1948 to insert the data, as this is a faster method.
1949
1950 Otherwise, each set of data is inserted into the database using
1951 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1952 accumulated into an array. The array itself, or an array reference
1953 is returned depending on scalar or list context.
1954
1955 Example:  Assuming an Artist Class that has many CDs Classes relating:
1956
1957   my $Artist_rs = $schema->resultset("Artist");
1958
1959   ## Void Context Example
1960   $Artist_rs->populate([
1961      { artistid => 4, name => 'Manufactured Crap', cds => [
1962         { title => 'My First CD', year => 2006 },
1963         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1964       ],
1965      },
1966      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1967         { title => 'My parents sold me to a record company', year => 2005 },
1968         { title => 'Why Am I So Ugly?', year => 2006 },
1969         { title => 'I Got Surgery and am now Popular', year => 2007 }
1970       ],
1971      },
1972   ]);
1973
1974   ## Array Context Example
1975   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1976     { name => "Artist One"},
1977     { name => "Artist Two"},
1978     { name => "Artist Three", cds=> [
1979     { title => "First CD", year => 2007},
1980     { title => "Second CD", year => 2008},
1981   ]}
1982   ]);
1983
1984   print $ArtistOne->name; ## response is 'Artist One'
1985   print $ArtistThree->cds->count ## reponse is '2'
1986
1987 For the arrayref of arrayrefs style,  the first element should be a list of the
1988 fieldsnames to which the remaining elements are rows being inserted.  For
1989 example:
1990
1991   $Arstist_rs->populate([
1992     [qw/artistid name/],
1993     [100, 'A Formally Unknown Singer'],
1994     [101, 'A singer that jumped the shark two albums ago'],
1995     [102, 'An actually cool singer'],
1996   ]);
1997
1998 Please note an important effect on your data when choosing between void and
1999 wantarray context. Since void context goes straight to C<insert_bulk> in
2000 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
2001 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
2002 create primary keys for you, you will find that your PKs are empty.  In this
2003 case you will have to use the wantarray context in order to create those
2004 values.
2005
2006 =cut
2007
2008 sub populate {
2009   my $self = shift;
2010
2011   # cruft placed in standalone method
2012   my $data = $self->_normalize_populate_args(@_);
2013
2014   return unless @$data;
2015
2016   if(defined wantarray) {
2017     my @created;
2018     foreach my $item (@$data) {
2019       push(@created, $self->create($item));
2020     }
2021     return wantarray ? @created : \@created;
2022   }
2023   else {
2024     my $first = $data->[0];
2025
2026     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2027     # it relationship data
2028     my (@rels, @columns);
2029     my $rsrc = $self->result_source;
2030     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2031     for (keys %$first) {
2032       my $ref = ref $first->{$_};
2033       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2034         ? push @rels, $_
2035         : push @columns, $_
2036       ;
2037     }
2038
2039     my @pks = $rsrc->primary_columns;
2040
2041     ## do the belongs_to relationships
2042     foreach my $index (0..$#$data) {
2043
2044       # delegate to create() for any dataset without primary keys with specified relationships
2045       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2046         for my $r (@rels) {
2047           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2048             my @ret = $self->populate($data);
2049             return;
2050           }
2051         }
2052       }
2053
2054       foreach my $rel (@rels) {
2055         next unless ref $data->[$index]->{$rel} eq "HASH";
2056         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2057         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2058         my $related = $result->result_source->_resolve_condition(
2059           $reverse_relinfo->{cond},
2060           $self,
2061           $result,
2062           $rel,
2063         );
2064
2065         delete $data->[$index]->{$rel};
2066         $data->[$index] = {%{$data->[$index]}, %$related};
2067
2068         push @columns, keys %$related if $index == 0;
2069       }
2070     }
2071
2072     ## inherit the data locked in the conditions of the resultset
2073     my ($rs_data) = $self->_merge_with_rscond({});
2074     delete @{$rs_data}{@columns};
2075     my @inherit_cols = keys %$rs_data;
2076     my @inherit_data = values %$rs_data;
2077
2078     ## do bulk insert on current row
2079     $rsrc->storage->insert_bulk(
2080       $rsrc,
2081       [@columns, @inherit_cols],
2082       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
2083     );
2084
2085     ## do the has_many relationships
2086     foreach my $item (@$data) {
2087
2088       my $main_row;
2089
2090       foreach my $rel (@rels) {
2091         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2092
2093         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2094
2095         my $child = $main_row->$rel;
2096
2097         my $related = $child->result_source->_resolve_condition(
2098           $rels->{$rel}{cond},
2099           $child,
2100           $main_row,
2101           $rel,
2102         );
2103
2104         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2105         my @populate = map { {%$_, %$related} } @rows_to_add;
2106
2107         $child->populate( \@populate );
2108       }
2109     }
2110   }
2111 }
2112
2113
2114 # populate() argumnets went over several incarnations
2115 # What we ultimately support is AoH
2116 sub _normalize_populate_args {
2117   my ($self, $arg) = @_;
2118
2119   if (ref $arg eq 'ARRAY') {
2120     if (!@$arg) {
2121       return [];
2122     }
2123     elsif (ref $arg->[0] eq 'HASH') {
2124       return $arg;
2125     }
2126     elsif (ref $arg->[0] eq 'ARRAY') {
2127       my @ret;
2128       my @colnames = @{$arg->[0]};
2129       foreach my $values (@{$arg}[1 .. $#$arg]) {
2130         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2131       }
2132       return \@ret;
2133     }
2134   }
2135
2136   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2137 }
2138
2139 =head2 pager
2140
2141 =over 4
2142
2143 =item Arguments: none
2144
2145 =item Return Value: $pager
2146
2147 =back
2148
2149 Return Value a L<Data::Page> object for the current resultset. Only makes
2150 sense for queries with a C<page> attribute.
2151
2152 To get the full count of entries for a paged resultset, call
2153 C<total_entries> on the L<Data::Page> object.
2154
2155 =cut
2156
2157 sub pager {
2158   my ($self) = @_;
2159
2160   return $self->{pager} if $self->{pager};
2161
2162   my $attrs = $self->{attrs};
2163   if (!defined $attrs->{page}) {
2164     $self->throw_exception("Can't create pager for non-paged rs");
2165   }
2166   elsif ($attrs->{page} <= 0) {
2167     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2168   }
2169   $attrs->{rows} ||= 10;
2170
2171   # throw away the paging flags and re-run the count (possibly
2172   # with a subselect) to get the real total count
2173   my $count_attrs = { %$attrs };
2174   delete $count_attrs->{$_} for qw/rows offset page pager/;
2175
2176   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2177
2178   require DBIx::Class::ResultSet::Pager;
2179   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2180     sub { $total_rs->count },  #lazy-get the total
2181     $attrs->{rows},
2182     $self->{attrs}{page},
2183   );
2184 }
2185
2186 =head2 page
2187
2188 =over 4
2189
2190 =item Arguments: $page_number
2191
2192 =item Return Value: $rs
2193
2194 =back
2195
2196 Returns a resultset for the $page_number page of the resultset on which page
2197 is called, where each page contains a number of rows equal to the 'rows'
2198 attribute set on the resultset (10 by default).
2199
2200 =cut
2201
2202 sub page {
2203   my ($self, $page) = @_;
2204   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2205 }
2206
2207 =head2 new_result
2208
2209 =over 4
2210
2211 =item Arguments: \%vals
2212
2213 =item Return Value: $rowobject
2214
2215 =back
2216
2217 Creates a new row object in the resultset's result class and returns
2218 it. The row is not inserted into the database at this point, call
2219 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2220 will tell you whether the row object has been inserted or not.
2221
2222 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2223
2224 =cut
2225
2226 sub new_result {
2227   my ($self, $values) = @_;
2228   $self->throw_exception( "new_result needs a hash" )
2229     unless (ref $values eq 'HASH');
2230
2231   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2232
2233   my %new = (
2234     %$merged_cond,
2235     @$cols_from_relations
2236       ? (-cols_from_relations => $cols_from_relations)
2237       : (),
2238     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2239   );
2240
2241   return $self->result_class->new(\%new);
2242 }
2243
2244 # _merge_with_rscond
2245 #
2246 # Takes a simple hash of K/V data and returns its copy merged with the
2247 # condition already present on the resultset. Additionally returns an
2248 # arrayref of value/condition names, which were inferred from related
2249 # objects (this is needed for in-memory related objects)
2250 sub _merge_with_rscond {
2251   my ($self, $data) = @_;
2252
2253   my (%new_data, @cols_from_relations);
2254
2255   my $alias = $self->{attrs}{alias};
2256
2257   if (! defined $self->{cond}) {
2258     # just massage $data below
2259   }
2260   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2261     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2262     @cols_from_relations = keys %new_data;
2263   }
2264   elsif (ref $self->{cond} ne 'HASH') {
2265     $self->throw_exception(
2266       "Can't abstract implicit construct, resultset condition not a hash"
2267     );
2268   }
2269   else {
2270     # precendence must be given to passed values over values inherited from
2271     # the cond, so the order here is important.
2272     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2273     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2274
2275     while ( my($col, $value) = each %implied ) {
2276       my $vref = ref $value;
2277       if (
2278         $vref eq 'HASH'
2279           and
2280         keys(%$value) == 1
2281           and
2282         (keys %$value)[0] eq '='
2283       ) {
2284         $new_data{$col} = $value->{'='};
2285       }
2286       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2287         $new_data{$col} = $value;
2288       }
2289     }
2290   }
2291
2292   %new_data = (
2293     %new_data,
2294     %{ $self->_remove_alias($data, $alias) },
2295   );
2296
2297   return (\%new_data, \@cols_from_relations);
2298 }
2299
2300 # _has_resolved_attr
2301 #
2302 # determines if the resultset defines at least one
2303 # of the attributes supplied
2304 #
2305 # used to determine if a subquery is neccessary
2306 #
2307 # supports some virtual attributes:
2308 #   -join
2309 #     This will scan for any joins being present on the resultset.
2310 #     It is not a mere key-search but a deep inspection of {from}
2311 #
2312
2313 sub _has_resolved_attr {
2314   my ($self, @attr_names) = @_;
2315
2316   my $attrs = $self->_resolved_attrs;
2317
2318   my %extra_checks;
2319
2320   for my $n (@attr_names) {
2321     if (grep { $n eq $_ } (qw/-join/) ) {
2322       $extra_checks{$n}++;
2323       next;
2324     }
2325
2326     my $attr =  $attrs->{$n};
2327
2328     next if not defined $attr;
2329
2330     if (ref $attr eq 'HASH') {
2331       return 1 if keys %$attr;
2332     }
2333     elsif (ref $attr eq 'ARRAY') {
2334       return 1 if @$attr;
2335     }
2336     else {
2337       return 1 if $attr;
2338     }
2339   }
2340
2341   # a resolved join is expressed as a multi-level from
2342   return 1 if (
2343     $extra_checks{-join}
2344       and
2345     ref $attrs->{from} eq 'ARRAY'
2346       and
2347     @{$attrs->{from}} > 1
2348   );
2349
2350   return 0;
2351 }
2352
2353 # _collapse_cond
2354 #
2355 # Recursively collapse the condition.
2356
2357 sub _collapse_cond {
2358   my ($self, $cond, $collapsed) = @_;
2359
2360   $collapsed ||= {};
2361
2362   if (ref $cond eq 'ARRAY') {
2363     foreach my $subcond (@$cond) {
2364       next unless ref $subcond;  # -or
2365       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2366     }
2367   }
2368   elsif (ref $cond eq 'HASH') {
2369     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2370       foreach my $subcond (@{$cond->{-and}}) {
2371         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2372       }
2373     }
2374     else {
2375       foreach my $col (keys %$cond) {
2376         my $value = $cond->{$col};
2377         $collapsed->{$col} = $value;
2378       }
2379     }
2380   }
2381
2382   return $collapsed;
2383 }
2384
2385 # _remove_alias
2386 #
2387 # Remove the specified alias from the specified query hash. A copy is made so
2388 # the original query is not modified.
2389
2390 sub _remove_alias {
2391   my ($self, $query, $alias) = @_;
2392
2393   my %orig = %{ $query || {} };
2394   my %unaliased;
2395
2396   foreach my $key (keys %orig) {
2397     if ($key !~ /\./) {
2398       $unaliased{$key} = $orig{$key};
2399       next;
2400     }
2401     $unaliased{$1} = $orig{$key}
2402       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2403   }
2404
2405   return \%unaliased;
2406 }
2407
2408 =head2 as_query
2409
2410 =over 4
2411
2412 =item Arguments: none
2413
2414 =item Return Value: \[ $sql, @bind ]
2415
2416 =back
2417
2418 Returns the SQL query and bind vars associated with the invocant.
2419
2420 This is generally used as the RHS for a subquery.
2421
2422 =cut
2423
2424 sub as_query {
2425   my $self = shift;
2426
2427   my $attrs = $self->_resolved_attrs_copy;
2428
2429   # For future use:
2430   #
2431   # in list ctx:
2432   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2433   # $sql also has no wrapping parenthesis in list ctx
2434   #
2435   my $sqlbind = $self->result_source->storage
2436     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2437
2438   return $sqlbind;
2439 }
2440
2441 =head2 find_or_new
2442
2443 =over 4
2444
2445 =item Arguments: \%vals, \%attrs?
2446
2447 =item Return Value: $rowobject
2448
2449 =back
2450
2451   my $artist = $schema->resultset('Artist')->find_or_new(
2452     { artist => 'fred' }, { key => 'artists' });
2453
2454   $cd->cd_to_producer->find_or_new({ producer => $producer },
2455                                    { key => 'primary });
2456
2457 Find an existing record from this resultset using L</find>. if none exists,
2458 instantiate a new result object and return it. The object will not be saved
2459 into your storage until you call L<DBIx::Class::Row/insert> on it.
2460
2461 You most likely want this method when looking for existing rows using a unique
2462 constraint that is not the primary key, or looking for related rows.
2463
2464 If you want objects to be saved immediately, use L</find_or_create> instead.
2465
2466 B<Note>: Make sure to read the documentation of L</find> and understand the
2467 significance of the C<key> attribute, as its lack may skew your search, and
2468 subsequently result in spurious new objects.
2469
2470 B<Note>: Take care when using C<find_or_new> with a table having
2471 columns with default values that you intend to be automatically
2472 supplied by the database (e.g. an auto_increment primary key column).
2473 In normal usage, the value of such columns should NOT be included at
2474 all in the call to C<find_or_new>, even when set to C<undef>.
2475
2476 =cut
2477
2478 sub find_or_new {
2479   my $self     = shift;
2480   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2481   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2482   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2483     return $row;
2484   }
2485   return $self->new_result($hash);
2486 }
2487
2488 =head2 create
2489
2490 =over 4
2491
2492 =item Arguments: \%vals
2493
2494 =item Return Value: a L<DBIx::Class::Row> $object
2495
2496 =back
2497
2498 Attempt to create a single new row or a row with multiple related rows
2499 in the table represented by the resultset (and related tables). This
2500 will not check for duplicate rows before inserting, use
2501 L</find_or_create> to do that.
2502
2503 To create one row for this resultset, pass a hashref of key/value
2504 pairs representing the columns of the table and the values you wish to
2505 store. If the appropriate relationships are set up, foreign key fields
2506 can also be passed an object representing the foreign row, and the
2507 value will be set to its primary key.
2508
2509 To create related objects, pass a hashref of related-object column values
2510 B<keyed on the relationship name>. If the relationship is of type C<multi>
2511 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2512 The process will correctly identify columns holding foreign keys, and will
2513 transparently populate them from the keys of the corresponding relation.
2514 This can be applied recursively, and will work correctly for a structure
2515 with an arbitrary depth and width, as long as the relationships actually
2516 exists and the correct column data has been supplied.
2517
2518
2519 Instead of hashrefs of plain related data (key/value pairs), you may
2520 also pass new or inserted objects. New objects (not inserted yet, see
2521 L</new>), will be inserted into their appropriate tables.
2522
2523 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2524
2525 Example of creating a new row.
2526
2527   $person_rs->create({
2528     name=>"Some Person",
2529     email=>"somebody@someplace.com"
2530   });
2531
2532 Example of creating a new row and also creating rows in a related C<has_many>
2533 or C<has_one> resultset.  Note Arrayref.
2534
2535   $artist_rs->create(
2536      { artistid => 4, name => 'Manufactured Crap', cds => [
2537         { title => 'My First CD', year => 2006 },
2538         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2539       ],
2540      },
2541   );
2542
2543 Example of creating a new row and also creating a row in a related
2544 C<belongs_to> resultset. Note Hashref.
2545
2546   $cd_rs->create({
2547     title=>"Music for Silly Walks",
2548     year=>2000,
2549     artist => {
2550       name=>"Silly Musician",
2551     }
2552   });
2553
2554 =over
2555
2556 =item WARNING
2557
2558 When subclassing ResultSet never attempt to override this method. Since
2559 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2560 lot of the internals simply never call it, so your override will be
2561 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2562 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2563 L</create> process you need to intervene.
2564
2565 =back
2566
2567 =cut
2568
2569 sub create {
2570   my ($self, $attrs) = @_;
2571   $self->throw_exception( "create needs a hashref" )
2572     unless ref $attrs eq 'HASH';
2573   return $self->new_result($attrs)->insert;
2574 }
2575
2576 =head2 find_or_create
2577
2578 =over 4
2579
2580 =item Arguments: \%vals, \%attrs?
2581
2582 =item Return Value: $rowobject
2583
2584 =back
2585
2586   $cd->cd_to_producer->find_or_create({ producer => $producer },
2587                                       { key => 'primary' });
2588
2589 Tries to find a record based on its primary key or unique constraints; if none
2590 is found, creates one and returns that instead.
2591
2592   my $cd = $schema->resultset('CD')->find_or_create({
2593     cdid   => 5,
2594     artist => 'Massive Attack',
2595     title  => 'Mezzanine',
2596     year   => 2005,
2597   });
2598
2599 Also takes an optional C<key> attribute, to search by a specific key or unique
2600 constraint. For example:
2601
2602   my $cd = $schema->resultset('CD')->find_or_create(
2603     {
2604       artist => 'Massive Attack',
2605       title  => 'Mezzanine',
2606     },
2607     { key => 'cd_artist_title' }
2608   );
2609
2610 B<Note>: Make sure to read the documentation of L</find> and understand the
2611 significance of the C<key> attribute, as its lack may skew your search, and
2612 subsequently result in spurious row creation.
2613
2614 B<Note>: Because find_or_create() reads from the database and then
2615 possibly inserts based on the result, this method is subject to a race
2616 condition. Another process could create a record in the table after
2617 the find has completed and before the create has started. To avoid
2618 this problem, use find_or_create() inside a transaction.
2619
2620 B<Note>: Take care when using C<find_or_create> with a table having
2621 columns with default values that you intend to be automatically
2622 supplied by the database (e.g. an auto_increment primary key column).
2623 In normal usage, the value of such columns should NOT be included at
2624 all in the call to C<find_or_create>, even when set to C<undef>.
2625
2626 See also L</find> and L</update_or_create>. For information on how to declare
2627 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2628
2629 =cut
2630
2631 sub find_or_create {
2632   my $self     = shift;
2633   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2634   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2635   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2636     return $row;
2637   }
2638   return $self->create($hash);
2639 }
2640
2641 =head2 update_or_create
2642
2643 =over 4
2644
2645 =item Arguments: \%col_values, { key => $unique_constraint }?
2646
2647 =item Return Value: $row_object
2648
2649 =back
2650
2651   $resultset->update_or_create({ col => $val, ... });
2652
2653 Like L</find_or_create>, but if a row is found it is immediately updated via
2654 C<< $found_row->update (\%col_values) >>.
2655
2656
2657 Takes an optional C<key> attribute to search on a specific unique constraint.
2658 For example:
2659
2660   # In your application
2661   my $cd = $schema->resultset('CD')->update_or_create(
2662     {
2663       artist => 'Massive Attack',
2664       title  => 'Mezzanine',
2665       year   => 1998,
2666     },
2667     { key => 'cd_artist_title' }
2668   );
2669
2670   $cd->cd_to_producer->update_or_create({
2671     producer => $producer,
2672     name => 'harry',
2673   }, {
2674     key => 'primary',
2675   });
2676
2677 B<Note>: Make sure to read the documentation of L</find> and understand the
2678 significance of the C<key> attribute, as its lack may skew your search, and
2679 subsequently result in spurious row creation.
2680
2681 B<Note>: Take care when using C<update_or_create> with a table having
2682 columns with default values that you intend to be automatically
2683 supplied by the database (e.g. an auto_increment primary key column).
2684 In normal usage, the value of such columns should NOT be included at
2685 all in the call to C<update_or_create>, even when set to C<undef>.
2686
2687 See also L</find> and L</find_or_create>. For information on how to declare
2688 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2689
2690 =cut
2691
2692 sub update_or_create {
2693   my $self = shift;
2694   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2695   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2696
2697   my $row = $self->find($cond, $attrs);
2698   if (defined $row) {
2699     $row->update($cond);
2700     return $row;
2701   }
2702
2703   return $self->create($cond);
2704 }
2705
2706 =head2 update_or_new
2707
2708 =over 4
2709
2710 =item Arguments: \%col_values, { key => $unique_constraint }?
2711
2712 =item Return Value: $rowobject
2713
2714 =back
2715
2716   $resultset->update_or_new({ col => $val, ... });
2717
2718 Like L</find_or_new> but if a row is found it is immediately updated via
2719 C<< $found_row->update (\%col_values) >>.
2720
2721 For example:
2722
2723   # In your application
2724   my $cd = $schema->resultset('CD')->update_or_new(
2725     {
2726       artist => 'Massive Attack',
2727       title  => 'Mezzanine',
2728       year   => 1998,
2729     },
2730     { key => 'cd_artist_title' }
2731   );
2732
2733   if ($cd->in_storage) {
2734       # the cd was updated
2735   }
2736   else {
2737       # the cd is not yet in the database, let's insert it
2738       $cd->insert;
2739   }
2740
2741 B<Note>: Make sure to read the documentation of L</find> and understand the
2742 significance of the C<key> attribute, as its lack may skew your search, and
2743 subsequently result in spurious new objects.
2744
2745 B<Note>: Take care when using C<update_or_new> with a table having
2746 columns with default values that you intend to be automatically
2747 supplied by the database (e.g. an auto_increment primary key column).
2748 In normal usage, the value of such columns should NOT be included at
2749 all in the call to C<update_or_new>, even when set to C<undef>.
2750
2751 See also L</find>, L</find_or_create> and L</find_or_new>.
2752
2753 =cut
2754
2755 sub update_or_new {
2756     my $self  = shift;
2757     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2758     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2759
2760     my $row = $self->find( $cond, $attrs );
2761     if ( defined $row ) {
2762         $row->update($cond);
2763         return $row;
2764     }
2765
2766     return $self->new_result($cond);
2767 }
2768
2769 =head2 get_cache
2770
2771 =over 4
2772
2773 =item Arguments: none
2774
2775 =item Return Value: \@cache_objects | undef
2776
2777 =back
2778
2779 Gets the contents of the cache for the resultset, if the cache is set.
2780
2781 The cache is populated either by using the L</prefetch> attribute to
2782 L</search> or by calling L</set_cache>.
2783
2784 =cut
2785
2786 sub get_cache {
2787   shift->{all_cache};
2788 }
2789
2790 =head2 set_cache
2791
2792 =over 4
2793
2794 =item Arguments: \@cache_objects
2795
2796 =item Return Value: \@cache_objects
2797
2798 =back
2799
2800 Sets the contents of the cache for the resultset. Expects an arrayref
2801 of objects of the same class as those produced by the resultset. Note that
2802 if the cache is set the resultset will return the cached objects rather
2803 than re-querying the database even if the cache attr is not set.
2804
2805 The contents of the cache can also be populated by using the
2806 L</prefetch> attribute to L</search>.
2807
2808 =cut
2809
2810 sub set_cache {
2811   my ( $self, $data ) = @_;
2812   $self->throw_exception("set_cache requires an arrayref")
2813       if defined($data) && (ref $data ne 'ARRAY');
2814   $self->{all_cache} = $data;
2815 }
2816
2817 =head2 clear_cache
2818
2819 =over 4
2820
2821 =item Arguments: none
2822
2823 =item Return Value: undef
2824
2825 =back
2826
2827 Clears the cache for the resultset.
2828
2829 =cut
2830
2831 sub clear_cache {
2832   shift->set_cache(undef);
2833 }
2834
2835 =head2 is_paged
2836
2837 =over 4
2838
2839 =item Arguments: none
2840
2841 =item Return Value: true, if the resultset has been paginated
2842
2843 =back
2844
2845 =cut
2846
2847 sub is_paged {
2848   my ($self) = @_;
2849   return !!$self->{attrs}{page};
2850 }
2851
2852 =head2 is_ordered
2853
2854 =over 4
2855
2856 =item Arguments: none
2857
2858 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2859
2860 =back
2861
2862 =cut
2863
2864 sub is_ordered {
2865   my ($self) = @_;
2866   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2867 }
2868
2869 =head2 related_resultset
2870
2871 =over 4
2872
2873 =item Arguments: $relationship_name
2874
2875 =item Return Value: $resultset
2876
2877 =back
2878
2879 Returns a related resultset for the supplied relationship name.
2880
2881   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2882
2883 =cut
2884
2885 sub related_resultset {
2886   my ($self, $rel) = @_;
2887
2888   $self->{related_resultsets} ||= {};
2889   return $self->{related_resultsets}{$rel} ||= do {
2890     my $rsrc = $self->result_source;
2891     my $rel_info = $rsrc->relationship_info($rel);
2892
2893     $self->throw_exception(
2894       "search_related: result source '" . $rsrc->source_name .
2895         "' has no such relationship $rel")
2896       unless $rel_info;
2897
2898     my $attrs = $self->_chain_relationship($rel);
2899
2900     my $join_count = $attrs->{seen_join}{$rel};
2901
2902     my $alias = $self->result_source->storage
2903         ->relname_to_table_alias($rel, $join_count);
2904
2905     # since this is search_related, and we already slid the select window inwards
2906     # (the select/as attrs were deleted in the beginning), we need to flip all
2907     # left joins to inner, so we get the expected results
2908     # read the comment on top of the actual function to see what this does
2909     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
2910
2911
2912     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2913     delete @{$attrs}{qw(result_class alias)};
2914
2915     my $new_cache;
2916
2917     if (my $cache = $self->get_cache) {
2918       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2919         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2920                         @$cache ];
2921       }
2922     }
2923
2924     my $rel_source = $rsrc->related_source($rel);
2925
2926     my $new = do {
2927
2928       # The reason we do this now instead of passing the alias to the
2929       # search_rs below is that if you wrap/overload resultset on the
2930       # source you need to know what alias it's -going- to have for things
2931       # to work sanely (e.g. RestrictWithObject wants to be able to add
2932       # extra query restrictions, and these may need to be $alias.)
2933
2934       my $rel_attrs = $rel_source->resultset_attributes;
2935       local $rel_attrs->{alias} = $alias;
2936
2937       $rel_source->resultset
2938                  ->search_rs(
2939                      undef, {
2940                        %$attrs,
2941                        where => $attrs->{where},
2942                    });
2943     };
2944     $new->set_cache($new_cache) if $new_cache;
2945     $new;
2946   };
2947 }
2948
2949 =head2 current_source_alias
2950
2951 =over 4
2952
2953 =item Arguments: none
2954
2955 =item Return Value: $source_alias
2956
2957 =back
2958
2959 Returns the current table alias for the result source this resultset is built
2960 on, that will be used in the SQL query. Usually it is C<me>.
2961
2962 Currently the source alias that refers to the result set returned by a
2963 L</search>/L</find> family method depends on how you got to the resultset: it's
2964 C<me> by default, but eg. L</search_related> aliases it to the related result
2965 source name (and keeps C<me> referring to the original result set). The long
2966 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2967 (and make this method unnecessary).
2968
2969 Thus it's currently necessary to use this method in predefined queries (see
2970 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2971 source alias of the current result set:
2972
2973   # in a result set class
2974   sub modified_by {
2975     my ($self, $user) = @_;
2976
2977     my $me = $self->current_source_alias;
2978
2979     return $self->search(
2980       "$me.modified" => $user->id,
2981     );
2982   }
2983
2984 =cut
2985
2986 sub current_source_alias {
2987   my ($self) = @_;
2988
2989   return ($self->{attrs} || {})->{alias} || 'me';
2990 }
2991
2992 =head2 as_subselect_rs
2993
2994 =over 4
2995
2996 =item Arguments: none
2997
2998 =item Return Value: $resultset
2999
3000 =back
3001
3002 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3003 "virtual view" by including it as a subquery within the from clause.  From this
3004 point on, any joined tables are inaccessible to ->search on the resultset (as if
3005 it were simply where-filtered without joins).  For example:
3006
3007  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3008
3009  # 'x' now pollutes the query namespace
3010
3011  # So the following works as expected
3012  my $ok_rs = $rs->search({'x.other' => 1});
3013
3014  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3015  # def) we look for one row with contradictory terms and join in another table
3016  # (aliased 'x_2') which we never use
3017  my $broken_rs = $rs->search({'x.name' => 'def'});
3018
3019  my $rs2 = $rs->as_subselect_rs;
3020
3021  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3022  my $not_joined_rs = $rs2->search({'x.other' => 1});
3023
3024  # works as expected: finds a 'table' row related to two x rows (abc and def)
3025  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3026
3027 Another example of when one might use this would be to select a subset of
3028 columns in a group by clause:
3029
3030  my $rs = $schema->resultset('Bar')->search(undef, {
3031    group_by => [qw{ id foo_id baz_id }],
3032  })->as_subselect_rs->search(undef, {
3033    columns => [qw{ id foo_id }]
3034  });
3035
3036 In the above example normally columns would have to be equal to the group by,
3037 but because we isolated the group by into a subselect the above works.
3038
3039 =cut
3040
3041 sub as_subselect_rs {
3042   my $self = shift;
3043
3044   my $attrs = $self->_resolved_attrs;
3045
3046   my $fresh_rs = (ref $self)->new (
3047     $self->result_source
3048   );
3049
3050   # these pieces will be locked in the subquery
3051   delete $fresh_rs->{cond};
3052   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3053
3054   return $fresh_rs->search( {}, {
3055     from => [{
3056       $attrs->{alias} => $self->as_query,
3057       -alias  => $attrs->{alias},
3058       -rsrc   => $self->result_source,
3059     }],
3060     alias => $attrs->{alias},
3061   });
3062 }
3063
3064 # This code is called by search_related, and makes sure there
3065 # is clear separation between the joins before, during, and
3066 # after the relationship. This information is needed later
3067 # in order to properly resolve prefetch aliases (any alias
3068 # with a relation_chain_depth less than the depth of the
3069 # current prefetch is not considered)
3070 #
3071 # The increments happen twice per join. An even number means a
3072 # relationship specified via a search_related, whereas an odd
3073 # number indicates a join/prefetch added via attributes
3074 #
3075 # Also this code will wrap the current resultset (the one we
3076 # chain to) in a subselect IFF it contains limiting attributes
3077 sub _chain_relationship {
3078   my ($self, $rel) = @_;
3079   my $source = $self->result_source;
3080   my $attrs = { %{$self->{attrs}||{}} };
3081
3082   # we need to take the prefetch the attrs into account before we
3083   # ->_resolve_join as otherwise they get lost - captainL
3084   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3085
3086   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3087
3088   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3089
3090   my $from;
3091   my @force_subq_attrs = qw/offset rows group_by having/;
3092
3093   if (
3094     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3095       ||
3096     $self->_has_resolved_attr (@force_subq_attrs)
3097   ) {
3098     # Nuke the prefetch (if any) before the new $rs attrs
3099     # are resolved (prefetch is useless - we are wrapping
3100     # a subquery anyway).
3101     my $rs_copy = $self->search;
3102     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3103       $rs_copy->{attrs}{join},
3104       delete $rs_copy->{attrs}{prefetch},
3105     );
3106
3107     $from = [{
3108       -rsrc   => $source,
3109       -alias  => $attrs->{alias},
3110       $attrs->{alias} => $rs_copy->as_query,
3111     }];
3112     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3113     $seen->{-relation_chain_depth} = 0;
3114   }
3115   elsif ($attrs->{from}) {  #shallow copy suffices
3116     $from = [ @{$attrs->{from}} ];
3117   }
3118   else {
3119     $from = [{
3120       -rsrc  => $source,
3121       -alias => $attrs->{alias},
3122       $attrs->{alias} => $source->from,
3123     }];
3124   }
3125
3126   my $jpath = ($seen->{-relation_chain_depth})
3127     ? $from->[-1][0]{-join_path}
3128     : [];
3129
3130   my @requested_joins = $source->_resolve_join(
3131     $join,
3132     $attrs->{alias},
3133     $seen,
3134     $jpath,
3135   );
3136
3137   push @$from, @requested_joins;
3138
3139   $seen->{-relation_chain_depth}++;
3140
3141   # if $self already had a join/prefetch specified on it, the requested
3142   # $rel might very well be already included. What we do in this case
3143   # is effectively a no-op (except that we bump up the chain_depth on
3144   # the join in question so we could tell it *is* the search_related)
3145   my $already_joined;
3146
3147   # we consider the last one thus reverse
3148   for my $j (reverse @requested_joins) {
3149     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3150     if ($rel eq $last_j) {
3151       $j->[0]{-relation_chain_depth}++;
3152       $already_joined++;
3153       last;
3154     }
3155   }
3156
3157   unless ($already_joined) {
3158     push @$from, $source->_resolve_join(
3159       $rel,
3160       $attrs->{alias},
3161       $seen,
3162       $jpath,
3163     );
3164   }
3165
3166   $seen->{-relation_chain_depth}++;
3167
3168   return {%$attrs, from => $from, seen_join => $seen};
3169 }
3170
3171 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3172 sub _resolved_attrs_copy {
3173   my $self = shift;
3174   return { %{$self->_resolved_attrs (@_)} };
3175 }
3176
3177 sub _resolved_attrs {
3178   my $self = shift;
3179   return $self->{_attrs} if $self->{_attrs};
3180
3181   my $attrs  = { %{ $self->{attrs} || {} } };
3182   my $source = $self->result_source;
3183   my $alias  = $attrs->{alias};
3184
3185   # default selection list
3186   $attrs->{columns} = [ $source->columns ]
3187     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3188
3189   # merge selectors together
3190   for (qw/columns select as/) {
3191     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3192       if $attrs->{$_} or $attrs->{"+$_"};
3193   }
3194
3195   # disassemble columns
3196   my (@sel, @as);
3197   if (my $cols = delete $attrs->{columns}) {
3198     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3199       if (ref $c eq 'HASH') {
3200         for my $as (keys %$c) {
3201           push @sel, $c->{$as};
3202           push @as, $as;
3203         }
3204       }
3205       else {
3206         push @sel, $c;
3207         push @as, $c;
3208       }
3209     }
3210   }
3211
3212   # when trying to weed off duplicates later do not go past this point -
3213   # everything added from here on is unbalanced "anyone's guess" stuff
3214   my $dedup_stop_idx = $#as;
3215
3216   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3217     if $attrs->{as};
3218   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3219     if $attrs->{select};
3220
3221   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3222   for (@sel) {
3223     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3224   }
3225
3226   # disqualify all $alias.col as-bits (collapser mandated)
3227   for (@as) {
3228     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3229   }
3230
3231   # de-duplicate the result (remove *identical* select/as pairs)
3232   # and also die on duplicate {as} pointing to different {select}s
3233   # not using a c-style for as the condition is prone to shrinkage
3234   my $seen;
3235   my $i = 0;
3236   while ($i <= $dedup_stop_idx) {
3237     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3238       splice @sel, $i, 1;
3239       splice @as, $i, 1;
3240       $dedup_stop_idx--;
3241     }
3242     elsif ($seen->{$as[$i]}++) {
3243       $self->throw_exception(
3244         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3245       );
3246     }
3247     else {
3248       $i++;
3249     }
3250   }
3251
3252   $attrs->{select} = \@sel;
3253   $attrs->{as} = \@as;
3254
3255   $attrs->{from} ||= [{
3256     -rsrc   => $source,
3257     -alias  => $self->{attrs}{alias},
3258     $self->{attrs}{alias} => $source->from,
3259   }];
3260
3261   if ( $attrs->{join} || $attrs->{prefetch} ) {
3262
3263     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3264       if ref $attrs->{from} ne 'ARRAY';
3265
3266     my $join = (delete $attrs->{join}) || {};
3267
3268     if ( defined $attrs->{prefetch} ) {
3269       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3270     }
3271
3272     $attrs->{from} =    # have to copy here to avoid corrupting the original
3273       [
3274         @{ $attrs->{from} },
3275         $source->_resolve_join(
3276           $join,
3277           $alias,
3278           { %{ $attrs->{seen_join} || {} } },
3279           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3280             ? $attrs->{from}[-1][0]{-join_path}
3281             : []
3282           ,
3283         )
3284       ];
3285   }
3286
3287   if ( defined $attrs->{order_by} ) {
3288     $attrs->{order_by} = (
3289       ref( $attrs->{order_by} ) eq 'ARRAY'
3290       ? [ @{ $attrs->{order_by} } ]
3291       : [ $attrs->{order_by} || () ]
3292     );
3293   }
3294
3295   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3296     $attrs->{group_by} = [ $attrs->{group_by} ];
3297   }
3298
3299   # generate the distinct induced group_by early, as prefetch will be carried via a
3300   # subquery (since a group_by is present)
3301   if (delete $attrs->{distinct}) {
3302     if ($attrs->{group_by}) {
3303       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3304     }
3305     else {
3306       # distinct affects only the main selection part, not what prefetch may
3307       # add below.
3308       $attrs->{group_by} = $source->storage->_group_over_selection (
3309         $attrs->{from},
3310         $attrs->{select},
3311         $attrs->{order_by},
3312       );
3313     }
3314   }
3315
3316   $attrs->{collapse} ||= {};
3317   if ($attrs->{prefetch}) {
3318
3319     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3320       if $attrs->{_dark_selector};
3321
3322     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3323
3324     my $prefetch_ordering = [];
3325
3326     # this is a separate structure (we don't look in {from} directly)
3327     # as the resolver needs to shift things off the lists to work
3328     # properly (identical-prefetches on different branches)
3329     my $join_map = {};
3330     if (ref $attrs->{from} eq 'ARRAY') {
3331
3332       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3333
3334       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3335         next unless $j->[0]{-alias};
3336         next unless $j->[0]{-join_path};
3337         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3338
3339         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3340
3341         my $p = $join_map;
3342         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3343         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3344       }
3345     }
3346
3347     my @prefetch =
3348       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3349
3350     # we need to somehow mark which columns came from prefetch
3351     if (@prefetch) {
3352       my $sel_end = $#{$attrs->{select}};
3353       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3354     }
3355
3356     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3357     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3358
3359     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3360     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3361   }
3362
3363
3364   # if both page and offset are specified, produce a combined offset
3365   # even though it doesn't make much sense, this is what pre 081xx has
3366   # been doing
3367   if (my $page = delete $attrs->{page}) {
3368     $attrs->{offset} =
3369       ($attrs->{rows} * ($page - 1))
3370             +
3371       ($attrs->{offset} || 0)
3372     ;
3373   }
3374
3375   return $self->{_attrs} = $attrs;
3376 }
3377
3378 sub _rollout_attr {
3379   my ($self, $attr) = @_;
3380
3381   if (ref $attr eq 'HASH') {
3382     return $self->_rollout_hash($attr);
3383   } elsif (ref $attr eq 'ARRAY') {
3384     return $self->_rollout_array($attr);
3385   } else {
3386     return [$attr];
3387   }
3388 }
3389
3390 sub _rollout_array {
3391   my ($self, $attr) = @_;
3392
3393   my @rolled_array;
3394   foreach my $element (@{$attr}) {
3395     if (ref $element eq 'HASH') {
3396       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3397     } elsif (ref $element eq 'ARRAY') {
3398       #  XXX - should probably recurse here
3399       push( @rolled_array, @{$self->_rollout_array($element)} );
3400     } else {
3401       push( @rolled_array, $element );
3402     }
3403   }
3404   return \@rolled_array;
3405 }
3406
3407 sub _rollout_hash {
3408   my ($self, $attr) = @_;
3409
3410   my @rolled_array;
3411   foreach my $key (keys %{$attr}) {
3412     push( @rolled_array, { $key => $attr->{$key} } );
3413   }
3414   return \@rolled_array;
3415 }
3416
3417 sub _calculate_score {
3418   my ($self, $a, $b) = @_;
3419
3420   if (defined $a xor defined $b) {
3421     return 0;
3422   }
3423   elsif (not defined $a) {
3424     return 1;
3425   }
3426
3427   if (ref $b eq 'HASH') {
3428     my ($b_key) = keys %{$b};
3429     if (ref $a eq 'HASH') {
3430       my ($a_key) = keys %{$a};
3431       if ($a_key eq $b_key) {
3432         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3433       } else {
3434         return 0;
3435       }
3436     } else {
3437       return ($a eq $b_key) ? 1 : 0;
3438     }
3439   } else {
3440     if (ref $a eq 'HASH') {
3441       my ($a_key) = keys %{$a};
3442       return ($b eq $a_key) ? 1 : 0;
3443     } else {
3444       return ($b eq $a) ? 1 : 0;
3445     }
3446   }
3447 }
3448
3449 sub _merge_joinpref_attr {
3450   my ($self, $orig, $import) = @_;
3451
3452   return $import unless defined($orig);
3453   return $orig unless defined($import);
3454
3455   $orig = $self->_rollout_attr($orig);
3456   $import = $self->_rollout_attr($import);
3457
3458   my $seen_keys;
3459   foreach my $import_element ( @{$import} ) {
3460     # find best candidate from $orig to merge $b_element into
3461     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3462     foreach my $orig_element ( @{$orig} ) {
3463       my $score = $self->_calculate_score( $orig_element, $import_element );
3464       if ($score > $best_candidate->{score}) {
3465         $best_candidate->{position} = $position;
3466         $best_candidate->{score} = $score;
3467       }
3468       $position++;
3469     }
3470     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3471     $import_key = '' if not defined $import_key;
3472
3473     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3474       push( @{$orig}, $import_element );
3475     } else {
3476       my $orig_best = $orig->[$best_candidate->{position}];
3477       # merge orig_best and b_element together and replace original with merged
3478       if (ref $orig_best ne 'HASH') {
3479         $orig->[$best_candidate->{position}] = $import_element;
3480       } elsif (ref $import_element eq 'HASH') {
3481         my ($key) = keys %{$orig_best};
3482         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3483       }
3484     }
3485     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3486   }
3487
3488   return $orig;
3489 }
3490
3491 {
3492   my $hm;
3493
3494   sub _merge_attr {
3495     $hm ||= do {
3496       require Hash::Merge;
3497       my $hm = Hash::Merge->new;
3498
3499       $hm->specify_behavior({
3500         SCALAR => {
3501           SCALAR => sub {
3502             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3503
3504             if ($defl xor $defr) {
3505               return [ $defl ? $_[0] : $_[1] ];
3506             }
3507             elsif (! $defl) {
3508               return [];
3509             }
3510             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3511               return [ $_[0] ];
3512             }
3513             else {
3514               return [$_[0], $_[1]];
3515             }
3516           },
3517           ARRAY => sub {
3518             return $_[1] if !defined $_[0];
3519             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3520             return [$_[0], @{$_[1]}]
3521           },
3522           HASH  => sub {
3523             return [] if !defined $_[0] and !keys %{$_[1]};
3524             return [ $_[1] ] if !defined $_[0];
3525             return [ $_[0] ] if !keys %{$_[1]};
3526             return [$_[0], $_[1]]
3527           },
3528         },
3529         ARRAY => {
3530           SCALAR => sub {
3531             return $_[0] if !defined $_[1];
3532             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3533             return [@{$_[0]}, $_[1]]
3534           },
3535           ARRAY => sub {
3536             my @ret = @{$_[0]} or return $_[1];
3537             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3538             my %idx = map { $_ => 1 } @ret;
3539             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3540             \@ret;
3541           },
3542           HASH => sub {
3543             return [ $_[1] ] if ! @{$_[0]};
3544             return $_[0] if !keys %{$_[1]};
3545             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3546             return [ @{$_[0]}, $_[1] ];
3547           },
3548         },
3549         HASH => {
3550           SCALAR => sub {
3551             return [] if !keys %{$_[0]} and !defined $_[1];
3552             return [ $_[0] ] if !defined $_[1];
3553             return [ $_[1] ] if !keys %{$_[0]};
3554             return [$_[0], $_[1]]
3555           },
3556           ARRAY => sub {
3557             return [] if !keys %{$_[0]} and !@{$_[1]};
3558             return [ $_[0] ] if !@{$_[1]};
3559             return $_[1] if !keys %{$_[0]};
3560             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3561             return [ $_[0], @{$_[1]} ];
3562           },
3563           HASH => sub {
3564             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3565             return [ $_[0] ] if !keys %{$_[1]};
3566             return [ $_[1] ] if !keys %{$_[0]};
3567             return [ $_[0] ] if $_[0] eq $_[1];
3568             return [ $_[0], $_[1] ];
3569           },
3570         }
3571       } => 'DBIC_RS_ATTR_MERGER');
3572       $hm;
3573     };
3574
3575     return $hm->merge ($_[1], $_[2]);
3576   }
3577 }
3578
3579 sub STORABLE_freeze {
3580   my ($self, $cloning) = @_;
3581   my $to_serialize = { %$self };
3582
3583   # A cursor in progress can't be serialized (and would make little sense anyway)
3584   delete $to_serialize->{cursor};
3585
3586   # nor is it sensical to store a not-yet-fired-count pager
3587   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3588     delete $to_serialize->{pager};
3589   }
3590
3591   Storable::nfreeze($to_serialize);
3592 }
3593
3594 # need this hook for symmetry
3595 sub STORABLE_thaw {
3596   my ($self, $cloning, $serialized) = @_;
3597
3598   %$self = %{ Storable::thaw($serialized) };
3599
3600   $self;
3601 }
3602
3603
3604 =head2 throw_exception
3605
3606 See L<DBIx::Class::Schema/throw_exception> for details.
3607
3608 =cut
3609
3610 sub throw_exception {
3611   my $self=shift;
3612
3613   if (ref $self and my $rsrc = $self->result_source) {
3614     $rsrc->throw_exception(@_)
3615   }
3616   else {
3617     DBIx::Class::Exception->throw(@_);
3618   }
3619 }
3620
3621 # XXX: FIXME: Attributes docs need clearing up
3622
3623 =head1 ATTRIBUTES
3624
3625 Attributes are used to refine a ResultSet in various ways when
3626 searching for data. They can be passed to any method which takes an
3627 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3628 L</count>.
3629
3630 These are in no particular order:
3631
3632 =head2 order_by
3633
3634 =over 4
3635
3636 =item Value: ( $order_by | \@order_by | \%order_by )
3637
3638 =back
3639
3640 Which column(s) to order the results by.
3641
3642 [The full list of suitable values is documented in
3643 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3644 common options.]
3645
3646 If a single column name, or an arrayref of names is supplied, the
3647 argument is passed through directly to SQL. The hashref syntax allows
3648 for connection-agnostic specification of ordering direction:
3649
3650  For descending order:
3651
3652   order_by => { -desc => [qw/col1 col2 col3/] }
3653
3654  For explicit ascending order:
3655
3656   order_by => { -asc => 'col' }
3657
3658 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3659 supported, although you are strongly encouraged to use the hashref
3660 syntax as outlined above.
3661
3662 =head2 columns
3663
3664 =over 4
3665
3666 =item Value: \@columns
3667
3668 =back
3669
3670 Shortcut to request a particular set of columns to be retrieved. Each
3671 column spec may be a string (a table column name), or a hash (in which
3672 case the key is the C<as> value, and the value is used as the C<select>
3673 expression). Adds C<me.> onto the start of any column without a C<.> in
3674 it and sets C<select> from that, then auto-populates C<as> from
3675 C<select> as normal. (You may also use the C<cols> attribute, as in
3676 earlier versions of DBIC.)
3677
3678 Essentially C<columns> does the same as L</select> and L</as>.
3679
3680     columns => [ 'foo', { bar => 'baz' } ]
3681
3682 is the same as
3683
3684     select => [qw/foo baz/],
3685     as => [qw/foo bar/]
3686
3687 =head2 +columns
3688
3689 =over 4
3690
3691 =item Value: \@columns
3692
3693 =back
3694
3695 Indicates additional columns to be selected from storage. Works the same
3696 as L</columns> but adds columns to the selection. (You may also use the
3697 C<include_columns> attribute, as in earlier versions of DBIC). For
3698 example:-
3699
3700   $schema->resultset('CD')->search(undef, {
3701     '+columns' => ['artist.name'],
3702     join => ['artist']
3703   });
3704
3705 would return all CDs and include a 'name' column to the information
3706 passed to object inflation. Note that the 'artist' is the name of the
3707 column (or relationship) accessor, and 'name' is the name of the column
3708 accessor in the related table.
3709
3710 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3711 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3712 unary plus operator before it.
3713
3714 =head2 include_columns
3715
3716 =over 4
3717
3718 =item Value: \@columns
3719
3720 =back
3721
3722 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3723
3724 =head2 select
3725
3726 =over 4
3727
3728 =item Value: \@select_columns
3729
3730 =back
3731
3732 Indicates which columns should be selected from the storage. You can use
3733 column names, or in the case of RDBMS back ends, function or stored procedure
3734 names:
3735
3736   $rs = $schema->resultset('Employee')->search(undef, {
3737     select => [
3738       'name',
3739       { count => 'employeeid' },
3740       { max => { length => 'name' }, -as => 'longest_name' }
3741     ]
3742   });
3743
3744   # Equivalent SQL
3745   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3746
3747 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3748 use L</select>, to instruct DBIx::Class how to store the result of the column.
3749 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3750 identifier aliasing. You can however alias a function, so you can use it in
3751 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3752 attribute> supplied as shown in the example above.
3753
3754 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3755 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3756 unary plus operator before it.
3757
3758 =head2 +select
3759
3760 =over 4
3761
3762 Indicates additional columns to be selected from storage.  Works the same as
3763 L</select> but adds columns to the default selection, instead of specifying
3764 an explicit list.
3765
3766 =back
3767
3768 =head2 +as
3769
3770 =over 4
3771
3772 Indicates additional column names for those added via L</+select>. See L</as>.
3773
3774 =back
3775
3776 =head2 as
3777
3778 =over 4
3779
3780 =item Value: \@inflation_names
3781
3782 =back
3783
3784 Indicates column names for object inflation. That is L</as> indicates the
3785 slot name in which the column value will be stored within the
3786 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3787 identifier by the C<get_column> method (or via the object accessor B<if one
3788 with the same name already exists>) as shown below. The L</as> attribute has
3789 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3790
3791   $rs = $schema->resultset('Employee')->search(undef, {
3792     select => [
3793       'name',
3794       { count => 'employeeid' },
3795       { max => { length => 'name' }, -as => 'longest_name' }
3796     ],
3797     as => [qw/
3798       name
3799       employee_count
3800       max_name_length
3801     /],
3802   });
3803
3804 If the object against which the search is performed already has an accessor
3805 matching a column name specified in C<as>, the value can be retrieved using
3806 the accessor as normal:
3807
3808   my $name = $employee->name();
3809
3810 If on the other hand an accessor does not exist in the object, you need to
3811 use C<get_column> instead:
3812
3813   my $employee_count = $employee->get_column('employee_count');
3814
3815 You can create your own accessors if required - see
3816 L<DBIx::Class::Manual::Cookbook> for details.
3817
3818 =head2 join
3819
3820 =over 4
3821
3822 =item Value: ($rel_name | \@rel_names | \%rel_names)
3823
3824 =back
3825
3826 Contains a list of relationships that should be joined for this query.  For
3827 example:
3828
3829   # Get CDs by Nine Inch Nails
3830   my $rs = $schema->resultset('CD')->search(
3831     { 'artist.name' => 'Nine Inch Nails' },
3832     { join => 'artist' }
3833   );
3834
3835 Can also contain a hash reference to refer to the other relation's relations.
3836 For example:
3837
3838   package MyApp::Schema::Track;
3839   use base qw/DBIx::Class/;
3840   __PACKAGE__->table('track');
3841   __PACKAGE__->add_columns(qw/trackid cd position title/);
3842   __PACKAGE__->set_primary_key('trackid');
3843   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3844   1;
3845
3846   # In your application
3847   my $rs = $schema->resultset('Artist')->search(
3848     { 'track.title' => 'Teardrop' },
3849     {
3850       join     => { cd => 'track' },
3851       order_by => 'artist.name',
3852     }
3853   );
3854
3855 You need to use the relationship (not the table) name in  conditions,
3856 because they are aliased as such. The current table is aliased as "me", so
3857 you need to use me.column_name in order to avoid ambiguity. For example:
3858
3859   # Get CDs from 1984 with a 'Foo' track
3860   my $rs = $schema->resultset('CD')->search(
3861     {
3862       'me.year' => 1984,
3863       'tracks.name' => 'Foo'
3864     },
3865     { join => 'tracks' }
3866   );
3867
3868 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3869 similarly for a third time). For e.g.
3870
3871   my $rs = $schema->resultset('Artist')->search({
3872     'cds.title'   => 'Down to Earth',
3873     'cds_2.title' => 'Popular',
3874   }, {
3875     join => [ qw/cds cds/ ],
3876   });
3877
3878 will return a set of all artists that have both a cd with title 'Down
3879 to Earth' and a cd with title 'Popular'.
3880
3881 If you want to fetch related objects from other tables as well, see C<prefetch>
3882 below.
3883
3884 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3885
3886 =head2 prefetch
3887
3888 =over 4
3889
3890 =item Value: ($rel_name | \@rel_names | \%rel_names)
3891
3892 =back
3893
3894 Contains one or more relationships that should be fetched along with
3895 the main query (when they are accessed afterwards the data will
3896 already be available, without extra queries to the database).  This is
3897 useful for when you know you will need the related objects, because it
3898 saves at least one query:
3899
3900   my $rs = $schema->resultset('Tag')->search(
3901     undef,
3902     {
3903       prefetch => {
3904         cd => 'artist'
3905       }
3906     }
3907   );
3908
3909 The initial search results in SQL like the following:
3910
3911   SELECT tag.*, cd.*, artist.* FROM tag
3912   JOIN cd ON tag.cd = cd.cdid
3913   JOIN artist ON cd.artist = artist.artistid
3914
3915 L<DBIx::Class> has no need to go back to the database when we access the
3916 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3917 case.
3918
3919 Simple prefetches will be joined automatically, so there is no need
3920 for a C<join> attribute in the above search.
3921
3922 L</prefetch> can be used with the any of the relationship types and
3923 multiple prefetches can be specified together. Below is a more complex
3924 example that prefetches a CD's artist, its liner notes (if present),
3925 the cover image, the tracks on that cd, and the guests on those
3926 tracks.
3927
3928  # Assuming:
3929  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
3930  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
3931  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
3932  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
3933
3934  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
3935
3936  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
3937
3938
3939  my $rs = $schema->resultset('CD')->search(
3940    undef,
3941    {
3942      prefetch => [
3943        { artist => 'record_label'},  # belongs_to => belongs_to
3944        'liner_note',                 # might_have
3945        'cover_image',                # has_one
3946        { tracks => 'guests' },       # has_many => has_many
3947      ]
3948    }
3949  );
3950
3951 This will produce SQL like the following:
3952
3953  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
3954         tracks.*, guests.*
3955    FROM cd me
3956    JOIN artist artist
3957      ON artist.artistid = me.artistid
3958    JOIN record_label record_label
3959      ON record_label.labelid = artist.labelid
3960    LEFT JOIN track tracks
3961      ON tracks.cdid = me.cdid
3962    LEFT JOIN guest guests
3963      ON guests.trackid = track.trackid
3964    LEFT JOIN liner_notes liner_note
3965      ON liner_note.cdid = me.cdid
3966    JOIN cd_artwork cover_image
3967      ON cover_image.cdid = me.cdid
3968  ORDER BY tracks.cd
3969
3970 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
3971 C<tracks>, and C<guests> of the CD will all be available through the
3972 relationship accessors without the need for additional queries to the
3973 database.
3974
3975 However, there is one caveat to be observed: it can be dangerous to
3976 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
3977 relationship on a given level. e.g.:
3978
3979  my $rs = $schema->resultset('CD')->search(
3980    undef,
3981    {
3982      prefetch => [
3983        'tracks',                         # has_many
3984        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
3985      ]
3986    }
3987  );
3988
3989 In fact, C<DBIx::Class> will emit the following warning:
3990
3991  Prefetching multiple has_many rels tracks and cd_to_producer at top
3992  level will explode the number of row objects retrievable via ->next
3993  or ->all. Use at your own risk.
3994
3995 The collapser currently can't identify duplicate tuples for multiple
3996 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
3997 result the second L<has_many|DBIx::Class::Relationship/has_many>
3998 relation could contain redundant objects.
3999
4000 =head3 Using L</prefetch> with L</join>
4001
4002 L</prefetch> implies a L</join> with the equivalent argument, and is
4003 properly merged with any existing L</join> specification. So the
4004 following:
4005
4006   my $rs = $schema->resultset('CD')->search(
4007    {'record_label.name' => 'Music Product Ltd.'},
4008    {
4009      join     => {artist => 'record_label'},
4010      prefetch => 'artist',
4011    }
4012  );
4013
4014 ... will work, searching on the record label's name, but only
4015 prefetching the C<artist>.
4016
4017 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4018
4019 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4020 prefetched relations.  So given:
4021
4022   my $rs = $schema->resultset('CD')->search(
4023    undef,
4024    {
4025      select   => ['cd.title'],
4026      as       => ['cd_title'],
4027      prefetch => 'artist',
4028    }
4029  );
4030
4031 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4032 becomes: C<'cd_title', 'artist.*'>.
4033
4034 =head3 CAVEATS
4035
4036 Prefetch does a lot of deep magic. As such, it may not behave exactly
4037 as you might expect.
4038
4039 =over 4
4040
4041 =item *
4042
4043 Prefetch uses the L</cache> to populate the prefetched relationships. This
4044 may or may not be what you want.
4045
4046 =item *
4047
4048 If you specify a condition on a prefetched relationship, ONLY those
4049 rows that match the prefetched condition will be fetched into that relationship.
4050 This means that adding prefetch to a search() B<may alter> what is returned by
4051 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4052
4053   my $artist_rs = $schema->resultset('Artist')->search({
4054       'cds.year' => 2008,
4055   }, {
4056       join => 'cds',
4057   });
4058
4059   my $count = $artist_rs->first->cds->count;
4060
4061   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4062
4063   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4064
4065   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4066
4067 that cmp_ok() may or may not pass depending on the datasets involved. This
4068 behavior may or may not survive the 0.09 transition.
4069
4070 =back
4071
4072 =head2 page
4073
4074 =over 4
4075
4076 =item Value: $page
4077
4078 =back
4079
4080 Makes the resultset paged and specifies the page to retrieve. Effectively
4081 identical to creating a non-pages resultset and then calling ->page($page)
4082 on it.
4083
4084 If L</rows> attribute is not specified it defaults to 10 rows per page.
4085
4086 When you have a paged resultset, L</count> will only return the number
4087 of rows in the page. To get the total, use the L</pager> and call
4088 C<total_entries> on it.
4089
4090 =head2 rows
4091
4092 =over 4
4093
4094 =item Value: $rows
4095
4096 =back
4097
4098 Specifies the maximum number of rows for direct retrieval or the number of
4099 rows per page if the page attribute or method is used.
4100
4101 =head2 offset
4102
4103 =over 4
4104
4105 =item Value: $offset
4106
4107 =back
4108
4109 Specifies the (zero-based) row number for the  first row to be returned, or the
4110 of the first row of the first page if paging is used.
4111
4112 =head2 group_by
4113
4114 =over 4
4115
4116 =item Value: \@columns
4117
4118 =back
4119
4120 A arrayref of columns to group by. Can include columns of joined tables.
4121
4122   group_by => [qw/ column1 column2 ... /]
4123
4124 =head2 having
4125
4126 =over 4
4127
4128 =item Value: $condition
4129
4130 =back
4131
4132 HAVING is a select statement attribute that is applied between GROUP BY and
4133 ORDER BY. It is applied to the after the grouping calculations have been
4134 done.
4135
4136   having => { 'count_employee' => { '>=', 100 } }
4137
4138 or with an in-place function in which case literal SQL is required:
4139
4140   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4141
4142 =head2 distinct
4143
4144 =over 4
4145
4146 =item Value: (0 | 1)
4147
4148 =back
4149
4150 Set to 1 to group by all columns. If the resultset already has a group_by
4151 attribute, this setting is ignored and an appropriate warning is issued.
4152
4153 =head2 where
4154
4155 =over 4
4156
4157 Adds to the WHERE clause.
4158
4159   # only return rows WHERE deleted IS NULL for all searches
4160   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
4161
4162 Can be overridden by passing C<< { where => undef } >> as an attribute
4163 to a resultset.
4164
4165 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4166
4167 =back
4168
4169 =head2 cache
4170
4171 Set to 1 to cache search results. This prevents extra SQL queries if you
4172 revisit rows in your ResultSet:
4173
4174   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4175
4176   while( my $artist = $resultset->next ) {
4177     ... do stuff ...
4178   }
4179
4180   $rs->first; # without cache, this would issue a query
4181
4182 By default, searches are not cached.
4183
4184 For more examples of using these attributes, see
4185 L<DBIx::Class::Manual::Cookbook>.
4186
4187 =head2 for
4188
4189 =over 4
4190
4191 =item Value: ( 'update' | 'shared' )
4192
4193 =back
4194
4195 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4196 ... FOR SHARED.
4197
4198 =cut
4199
4200 1;