lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util 'fail_on_internal_wantarray';
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 # this is real - CDBICompat overrides it with insanity
  30 # yes, prototype won't matter, but that's for now ;)
  31 sub _bool () { 1 }
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  34
  35 =head1 NAME
  36
  37 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  38
  39 =head1 SYNOPSIS
  40
  41   my $users_rs = $schema->resultset('User');
  42   while( $user = $users_rs->next) {
  43     print $user->username;
  44   }
  45
  46   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  47   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  48
  49 =head1 DESCRIPTION
  50
  51 A ResultSet is an object which stores a set of conditions representing
  52 a query. It is the backbone of DBIx::Class (i.e. the really
  53 important/useful bit).
  54
  55 No SQL is executed on the database when a ResultSet is created, it
  56 just stores all the conditions needed to create the query.
  57
  58 A basic ResultSet representing the data of an entire table is returned
  59 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  60 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  61
  62   my $users_rs = $schema->resultset('User');
  63
  64 A new ResultSet is returned from calling L</search> on an existing
  65 ResultSet. The new one will contain all the conditions of the
  66 original, plus any new conditions added in the C<search> call.
  67
  68 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  69 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  70 represents.
  71
  72 The query that the ResultSet represents is B<only> executed against
  73 the database when these methods are called:
  74 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  75
  76 If a resultset is used in a numeric context it returns the L</count>.
  77 However, if it is used in a boolean context it is B<always> true.  So if
  78 you want to check if a resultset has any results, you must use C<if $rs
  79 != 0>.
  80
  81 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  82
  83 If you want to make your custom ResultSet classes with L<Moose>, use a template
  84 similar to:
  85
  86     package MyApp::Schema::ResultSet::User;
  87
  88     use Moose;
  89     use namespace::autoclean;
  90     use MooseX::NonMoose;
  91     extends 'DBIx::Class::ResultSet';
  92
  93     sub BUILDARGS { $_[2] }
  94
  95     ...your code...
  96
  97     __PACKAGE__->meta->make_immutable;
  98
  99     1;
 100
 101 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 102 clash with the regular ResultSet constructor. Alternatively, you can use:
 103
 104     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 105
 106 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 107 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 108
 109 =head1 EXAMPLES
 110
 111 =head2 Chaining resultsets
 112
 113 Let's say you've got a query that needs to be run to return some data
 114 to the user. But, you have an authorization system in place that
 115 prevents certain users from seeing certain information. So, you want
 116 to construct the basic query in one method, but add constraints to it in
 117 another.
 118
 119   sub get_data {
 120     my $self = shift;
 121     my $request = $self->get_request; # Get a request object somehow.
 122     my $schema = $self->result_source->schema;
 123
 124     my $cd_rs = $schema->resultset('CD')->search({
 125       title => $request->param('title'),
 126       year => $request->param('year'),
 127     });
 128
 129     $cd_rs = $self->apply_security_policy( $cd_rs );
 130
 131     return $cd_rs->all();
 132   }
 133
 134   sub apply_security_policy {
 135     my $self = shift;
 136     my ($rs) = @_;
 137
 138     return $rs->search({
 139       subversive => 0,
 140     });
 141   }
 142
 143 =head3 Resolving conditions and attributes
 144
 145 When a resultset is chained from another resultset (e.g.:
 146 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 147 and attributes with the same keys need resolving.
 148
 149 If any of L</columns>, L</select>, L</as> are present, they reset the
 150 original selection, and start the selection "clean".
 151
 152 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 153 are merged into the existing ones from the original resultset.
 154
 155 The L</where> and L</having> attributes, and any search conditions, are
 156 merged with an SQL C<AND> to the existing condition from the original
 157 resultset.
 158
 159 All other attributes are overridden by any new ones supplied in the
 160 search attributes.
 161
 162 =head2 Multiple queries
 163
 164 Since a resultset just defines a query, you can do all sorts of
 165 things with it with the same object.
 166
 167   # Don't hit the DB yet.
 168   my $cd_rs = $schema->resultset('CD')->search({
 169     title => 'something',
 170     year => 2009,
 171   });
 172
 173   # Each of these hits the DB individually.
 174   my $count = $cd_rs->count;
 175   my $most_recent = $cd_rs->get_column('date_released')->max();
 176   my @records = $cd_rs->all;
 177
 178 And it's not just limited to SELECT statements.
 179
 180   $cd_rs->delete();
 181
 182 This is even cooler:
 183
 184   $cd_rs->create({ artist => 'Fred' });
 185
 186 Which is the same as:
 187
 188   $schema->resultset('CD')->create({
 189     title => 'something',
 190     year => 2009,
 191     artist => 'Fred'
 192   });
 193
 194 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 195
 196 =head1 METHODS
 197
 198 =head2 new
 199
 200 =over 4
 201
 202 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 203
 204 =item Return Value: L<$resultset|/search>
 205
 206 =back
 207
 208 The resultset constructor. Takes a source object (usually a
 209 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 210 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 211 executed as needed by the other methods.
 212
 213 Generally you never construct a resultset manually. Instead you get one
 214 from e.g. a
 215 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 216 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 217 scalar context):
 218
 219   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 220
 221 =over
 222
 223 =item WARNING
 224
 225 If called on an object, proxies to L</new_result> instead, so
 226
 227   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 228
 229 will return a CD object, not a ResultSet, and is equivalent to:
 230
 231   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 232
 233 Please also keep in mind that many internals call L</new_result> directly,
 234 so overloading this method with the idea of intercepting new result object
 235 creation B<will not work>. See also warning pertaining to L</create>.
 236
 237 =back
 238
 239 =cut
 240
 241 sub new {
 242   my $class = shift;
 243   return $class->new_result(@_) if ref $class;
 244
 245   my ($source, $attrs) = @_;
 246   $source = $source->resolve
 247     if $source->isa('DBIx::Class::ResultSourceHandle');
 248
 249   $attrs = { %{$attrs||{}} };
 250   delete @{$attrs}{qw(_sqlmaker_select_args _related_results_construction)};
 251
 252   if ($attrs->{page}) {
 253     $attrs->{rows} ||= 10;
 254   }
 255
 256   $attrs->{alias} ||= 'me';
 257
 258   my $self = bless {
 259     result_source => $source,
 260     cond => $attrs->{where},
 261     pager => undef,
 262     attrs => $attrs,
 263   }, $class;
 264
 265   # if there is a dark selector, this means we are already in a
 266   # chain and the cleanup/sanification was taken care of by
 267   # _search_rs already
 268   $self->_normalize_selection($attrs)
 269     unless $attrs->{_dark_selector};
 270
 271   $self->result_class(
 272     $attrs->{result_class} || $source->result_class
 273   );
 274
 275   $self;
 276 }
 277
 278 =head2 search
 279
 280 =over 4
 281
 282 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 283
 284 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 285
 286 =back
 287
 288   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 289   my $new_rs = $cd_rs->search({ year => 2005 });
 290
 291   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 292                  # year = 2005 OR year = 2004
 293
 294 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 295 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 296 To avoid that, use L</search_rs>.
 297
 298 If you need to pass in additional attributes but no additional condition,
 299 call it as C<search(undef, \%attrs)>.
 300
 301   # "SELECT name, artistid FROM $artist_table"
 302   my @all_artists = $schema->resultset('Artist')->search(undef, {
 303     columns => [qw/name artistid/],
 304   });
 305
 306 For a list of attributes that can be passed to C<search>, see
 307 L</ATTRIBUTES>. For more examples of using this function, see
 308 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 309 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 310 and its extension L<DBIx::Class::SQLMaker>.
 311
 312 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 313
 314 =head3 CAVEAT
 315
 316 Note that L</search> does not process/deflate any of the values passed in the
 317 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 318 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 319 manually that any value passed to this method will stringify to something the
 320 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 321 objects, for more info see:
 322 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 323
 324 =cut
 325
 326 sub search {
 327   my $self = shift;
 328   my $rs = $self->search_rs( @_ );
 329
 330   if (wantarray) {
 331     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray($rs);
 332     return $rs->all;
 333   }
 334   elsif (defined wantarray) {
 335     return $rs;
 336   }
 337   else {
 338     # we can be called by a relationship helper, which in
 339     # turn may be called in void context due to some braindead
 340     # overload or whatever else the user decided to be clever
 341     # at this particular day. Thus limit the exception to
 342     # external code calls only
 343     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 344       if (caller)[0] !~ /^\QDBIx::Class::/;
 345
 346     return ();
 347   }
 348 }
 349
 350 =head2 search_rs
 351
 352 =over 4
 353
 354 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 355
 356 =item Return Value: L<$resultset|/search>
 357
 358 =back
 359
 360 This method does the same exact thing as search() except it will
 361 always return a resultset, even in list context.
 362
 363 =cut
 364
 365 sub search_rs {
 366   my $self = shift;
 367
 368   my $rsrc = $self->result_source;
 369   my ($call_cond, $call_attrs);
 370
 371   # Special-case handling for (undef, undef) or (undef)
 372   # Note that (foo => undef) is valid deprecated syntax
 373   @_ = () if not scalar grep { defined $_ } @_;
 374
 375   # just a cond
 376   if (@_ == 1) {
 377     $call_cond = shift;
 378   }
 379   # fish out attrs in the ($condref, $attr) case
 380   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 381     ($call_cond, $call_attrs) = @_;
 382   }
 383   elsif (@_ % 2) {
 384     $self->throw_exception('Odd number of arguments to search')
 385   }
 386   # legacy search
 387   elsif (@_) {
 388     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 389       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 390
 391     for my $i (0 .. $#_) {
 392       next if $i % 2;
 393       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 394         if (! defined $_[$i] or ref $_[$i] ne '');
 395     }
 396
 397     $call_cond = { @_ };
 398   }
 399
 400   # see if we can keep the cache (no $rs changes)
 401   my $cache;
 402   my %safe = (alias => 1, cache => 1);
 403   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 404     ! defined $call_cond
 405       or
 406     ref $call_cond eq 'HASH' && ! keys %$call_cond
 407       or
 408     ref $call_cond eq 'ARRAY' && ! @$call_cond
 409   )) {
 410     $cache = $self->get_cache;
 411   }
 412
 413   my $old_attrs = { %{$self->{attrs}} };
 414   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 415
 416   my $new_attrs = { %$old_attrs };
 417
 418   # take care of call attrs (only if anything is changing)
 419   if ($call_attrs and keys %$call_attrs) {
 420
 421     # copy for _normalize_selection
 422     $call_attrs = { %$call_attrs };
 423
 424     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 425
 426     # reset the current selector list if new selectors are supplied
 427     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 428       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 429     }
 430
 431     # Normalize the new selector list (operates on the passed-in attr structure)
 432     # Need to do it on every chain instead of only once on _resolved_attrs, in
 433     # order to allow detection of empty vs partial 'as'
 434     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 435       if $old_attrs->{_dark_selector};
 436     $self->_normalize_selection ($call_attrs);
 437
 438     # start with blind overwriting merge, exclude selector attrs
 439     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 440     delete @{$new_attrs}{@selector_attrs};
 441
 442     for (@selector_attrs) {
 443       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 444         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 445     }
 446
 447     # older deprecated name, use only if {columns} is not there
 448     if (my $c = delete $new_attrs->{cols}) {
 449       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 450       if ($new_attrs->{columns}) {
 451         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 452       }
 453       else {
 454         $new_attrs->{columns} = $c;
 455       }
 456     }
 457
 458
 459     # join/prefetch use their own crazy merging heuristics
 460     foreach my $key (qw/join prefetch/) {
 461       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 462         if exists $call_attrs->{$key};
 463     }
 464
 465     # stack binds together
 466     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 467   }
 468
 469
 470   for ($old_where, $call_cond) {
 471     if (defined $_) {
 472       $new_attrs->{where} = $self->_stack_cond (
 473         $_, $new_attrs->{where}
 474       );
 475     }
 476   }
 477
 478   if (defined $old_having) {
 479     $new_attrs->{having} = $self->_stack_cond (
 480       $old_having, $new_attrs->{having}
 481     )
 482   }
 483
 484   my $rs = (ref $self)->new($rsrc, $new_attrs);
 485
 486   $rs->set_cache($cache) if ($cache);
 487
 488   return $rs;
 489 }
 490
 491 my $dark_sel_dumper;
 492 sub _normalize_selection {
 493   my ($self, $attrs) = @_;
 494
 495   # legacy syntax
 496   if ( exists $attrs->{include_columns} ) {
 497     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 498     $attrs->{'+columns'} = $self->_merge_attr(
 499       $attrs->{'+columns'}, delete $attrs->{include_columns}
 500     );
 501   }
 502
 503   # columns are always placed first, however
 504
 505   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 506   # delay the decision on whether to use a default select list ($rsrc->columns)
 507   # allowing stuff like the remove_columns helper to work
 508   #
 509   # select/as +select/+as pairs need special handling - the amount of select/as
 510   # elements in each pair does *not* have to be equal (think multicolumn
 511   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 512   # supplied at all) - try to infer the alias, either from the -as parameter
 513   # of the selector spec, or use the parameter whole if it looks like a column
 514   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 515   # is ok as well), but make sure no more additions to the 'as' chain take place
 516   for my $pref ('', '+') {
 517
 518     my ($sel, $as) = map {
 519       my $key = "${pref}${_}";
 520
 521       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 522         ? @{$attrs->{$key}}
 523         : $attrs->{$key} || ()
 524       ];
 525       delete $attrs->{$key};
 526       $val;
 527     } qw/select as/;
 528
 529     if (! @$as and ! @$sel ) {
 530       next;
 531     }
 532     elsif (@$as and ! @$sel) {
 533       $self->throw_exception(
 534         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 535       );
 536     }
 537     elsif( ! @$as ) {
 538       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 539       # if any @$as has been supplied we assume the user knows what (s)he is doing
 540       # and blindly keep stacking up pieces
 541       unless ($attrs->{_dark_selector}) {
 542         SELECTOR:
 543         for (@$sel) {
 544           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 545             push @$as, $_->{-as};
 546           }
 547           # assume any plain no-space, no-parenthesis string to be a column spec
 548           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 549           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 550             push @$as, $_;
 551           }
 552           # if all else fails - raise a flag that no more aliasing will be allowed
 553           else {
 554             $attrs->{_dark_selector} = {
 555               plus_stage => $pref,
 556               string => ($dark_sel_dumper ||= do {
 557                   require Data::Dumper::Concise;
 558                   Data::Dumper::Concise::DumperObject()->Indent(0);
 559                 })->Values([$_])->Dump
 560               ,
 561             };
 562             last SELECTOR;
 563           }
 564         }
 565       }
 566     }
 567     elsif (@$as < @$sel) {
 568       $self->throw_exception(
 569         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 570       );
 571     }
 572     elsif ($pref and $attrs->{_dark_selector}) {
 573       $self->throw_exception(
 574         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 575       );
 576     }
 577
 578
 579     # merge result
 580     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 581     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 582   }
 583 }
 584
 585 sub _stack_cond {
 586   my ($self, $left, $right) = @_;
 587
 588   # collapse single element top-level conditions
 589   # (single pass only, unlikely to need recursion)
 590   for ($left, $right) {
 591     if (ref $_ eq 'ARRAY') {
 592       if (@$_ == 0) {
 593         $_ = undef;
 594       }
 595       elsif (@$_ == 1) {
 596         $_ = $_->[0];
 597       }
 598     }
 599     elsif (ref $_ eq 'HASH') {
 600       my ($first, $more) = keys %$_;
 601
 602       # empty hash
 603       if (! defined $first) {
 604         $_ = undef;
 605       }
 606       # one element hash
 607       elsif (! defined $more) {
 608         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 609           $_ = $_->{'-and'};
 610         }
 611         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 612           $_ = $_->{'-or'};
 613         }
 614       }
 615     }
 616   }
 617
 618   # merge hashes with weeding out of duplicates (simple cases only)
 619   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 620
 621     # shallow copy to destroy
 622     $right = { %$right };
 623     for (grep { exists $right->{$_} } keys %$left) {
 624       # the use of eq_deeply here is justified - the rhs of an
 625       # expression can contain a lot of twisted weird stuff
 626       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 627     }
 628
 629     $right = undef unless keys %$right;
 630   }
 631
 632
 633   if (defined $left xor defined $right) {
 634     return defined $left ? $left : $right;
 635   }
 636   elsif (! defined $left) {
 637     return undef;
 638   }
 639   else {
 640     return { -and => [ $left, $right ] };
 641   }
 642 }
 643
 644 =head2 search_literal
 645
 646 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 647 should only be used in that context. C<search_literal> is a convenience
 648 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 649 want to ensure columns are bound correctly, use L</search>.
 650
 651 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 652 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 653 require C<search_literal>.
 654
 655 =over 4
 656
 657 =item Arguments: $sql_fragment, @standalone_bind_values
 658
 659 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 660
 661 =back
 662
 663   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 664   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 665
 666 Pass a literal chunk of SQL to be added to the conditional part of the
 667 resultset query.
 668
 669 Example of how to use C<search> instead of C<search_literal>
 670
 671   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 672   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 673
 674 =cut
 675
 676 sub search_literal {
 677   my ($self, $sql, @bind) = @_;
 678   my $attr;
 679   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 680     $attr = pop @bind;
 681   }
 682   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 683 }
 684
 685 =head2 find
 686
 687 =over 4
 688
 689 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 690
 691 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 692
 693 =back
 694
 695 Finds and returns a single row based on supplied criteria. Takes either a
 696 hashref with the same format as L</create> (including inference of foreign
 697 keys from related objects), or a list of primary key values in the same
 698 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 699 declaration on the L</result_source>.
 700
 701 In either case an attempt is made to combine conditions already existing on
 702 the resultset with the condition passed to this method.
 703
 704 To aid with preparing the correct query for the storage you may supply the
 705 C<key> attribute, which is the name of a
 706 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 707 unique constraint corresponding to the
 708 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 709 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 710 to construct a query that satisfies the named unique constraint fully (
 711 non-NULL values for each column member of the constraint) an exception is
 712 thrown.
 713
 714 If no C<key> is specified, the search is carried over all unique constraints
 715 which are fully defined by the available condition.
 716
 717 If no such constraint is found, C<find> currently defaults to a simple
 718 C<< search->(\%column_values) >> which may or may not do what you expect.
 719 Note that this fallback behavior may be deprecated in further versions. If
 720 you need to search with arbitrary conditions - use L</search>. If the query
 721 resulting from this fallback produces more than one row, a warning to the
 722 effect is issued, though only the first row is constructed and returned as
 723 C<$result_object>.
 724
 725 In addition to C<key>, L</find> recognizes and applies standard
 726 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 727
 728 Note that if you have extra concerns about the correctness of the resulting
 729 query you need to specify the C<key> attribute and supply the entire condition
 730 as an argument to find (since it is not always possible to perform the
 731 combination of the resultset condition with the supplied one, especially if
 732 the resultset condition contains literal sql).
 733
 734 For example, to find a row by its primary key:
 735
 736   my $cd = $schema->resultset('CD')->find(5);
 737
 738 You can also find a row by a specific unique constraint:
 739
 740   my $cd = $schema->resultset('CD')->find(
 741     {
 742       artist => 'Massive Attack',
 743       title  => 'Mezzanine',
 744     },
 745     { key => 'cd_artist_title' }
 746   );
 747
 748 See also L</find_or_create> and L</update_or_create>.
 749
 750 =cut
 751
 752 sub find {
 753   my $self = shift;
 754   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 755
 756   my $rsrc = $self->result_source;
 757
 758   my $constraint_name;
 759   if (exists $attrs->{key}) {
 760     $constraint_name = defined $attrs->{key}
 761       ? $attrs->{key}
 762       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 763     ;
 764   }
 765
 766   # Parse out the condition from input
 767   my $call_cond;
 768
 769   if (ref $_[0] eq 'HASH') {
 770     $call_cond = { %{$_[0]} };
 771   }
 772   else {
 773     # if only values are supplied we need to default to 'primary'
 774     $constraint_name = 'primary' unless defined $constraint_name;
 775
 776     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 777
 778     $self->throw_exception(
 779       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 780     ) unless @c_cols;
 781
 782     $self->throw_exception (
 783       'find() expects either a column/value hashref, or a list of values '
 784     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 785     ) unless @c_cols == @_;
 786
 787     $call_cond = {};
 788     @{$call_cond}{@c_cols} = @_;
 789   }
 790
 791   my %related;
 792   for my $key (keys %$call_cond) {
 793     if (
 794       my $keyref = ref($call_cond->{$key})
 795         and
 796       my $relinfo = $rsrc->relationship_info($key)
 797     ) {
 798       my $val = delete $call_cond->{$key};
 799
 800       next if $keyref eq 'ARRAY'; # has_many for multi_create
 801
 802       my $rel_q = $rsrc->_resolve_condition(
 803         $relinfo->{cond}, $val, $key, $key
 804       );
 805       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 806       @related{keys %$rel_q} = values %$rel_q;
 807     }
 808   }
 809
 810   # relationship conditions take precedence (?)
 811   @{$call_cond}{keys %related} = values %related;
 812
 813   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 814   my $final_cond;
 815   if (defined $constraint_name) {
 816     $final_cond = $self->_qualify_cond_columns (
 817
 818       $self->_build_unique_cond (
 819         $constraint_name,
 820         $call_cond,
 821       ),
 822
 823       $alias,
 824     );
 825   }
 826   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 827     # This means that we got here after a merger of relationship conditions
 828     # in ::Relationship::Base::search_related (the row method), and furthermore
 829     # the relationship is of the 'single' type. This means that the condition
 830     # provided by the relationship (already attached to $self) is sufficient,
 831     # as there can be only one row in the database that would satisfy the
 832     # relationship
 833   }
 834   else {
 835     # no key was specified - fall down to heuristics mode:
 836     # run through all unique queries registered on the resultset, and
 837     # 'OR' all qualifying queries together
 838     my (@unique_queries, %seen_column_combinations);
 839     for my $c_name ($rsrc->unique_constraint_names) {
 840       next if $seen_column_combinations{
 841         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 842       }++;
 843
 844       push @unique_queries, try {
 845         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 846       } || ();
 847     }
 848
 849     $final_cond = @unique_queries
 850       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 851       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 852     ;
 853   }
 854
 855   # Run the query, passing the result_class since it should propagate for find
 856   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 857   if ($rs->_resolved_attrs->{collapse}) {
 858     my $row = $rs->next;
 859     carp "Query returned more than one row" if $rs->next;
 860     return $row;
 861   }
 862   else {
 863     return $rs->single;
 864   }
 865 }
 866
 867 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 868 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 869 #
 870 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 871 # condition. It is provided for overrides until a saner way forward is devised
 872 #
 873 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 874 # the road. Please adjust your tests accordingly to catch this situation early
 875 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 876 #
 877 # The method will not be removed without an adequately complete replacement
 878 # for strict-mode enforcement
 879 sub _non_unique_find_fallback {
 880   my ($self, $cond, $attrs) = @_;
 881
 882   return $self->_qualify_cond_columns(
 883     $cond,
 884     exists $attrs->{alias}
 885       ? $attrs->{alias}
 886       : $self->{attrs}{alias}
 887   );
 888 }
 889
 890
 891 sub _qualify_cond_columns {
 892   my ($self, $cond, $alias) = @_;
 893
 894   my %aliased = %$cond;
 895   for (keys %aliased) {
 896     $aliased{"$alias.$_"} = delete $aliased{$_}
 897       if $_ !~ /\./;
 898   }
 899
 900   return \%aliased;
 901 }
 902
 903 sub _build_unique_cond {
 904   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 905
 906   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 907
 908   # combination may fail if $self->{cond} is non-trivial
 909   my ($final_cond) = try {
 910     $self->_merge_with_rscond ($extra_cond)
 911   } catch {
 912     +{ %$extra_cond }
 913   };
 914
 915   # trim out everything not in $columns
 916   $final_cond = { map {
 917     exists $final_cond->{$_}
 918       ? ( $_ => $final_cond->{$_} )
 919       : ()
 920   } @c_cols };
 921
 922   if (my @missing = grep
 923     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 924     (@c_cols)
 925   ) {
 926     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 927       $constraint_name,
 928       join (', ', map { "'$_'" } @missing),
 929     ) );
 930   }
 931
 932   if (
 933     !$croak_on_null
 934       and
 935     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 936       and
 937     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 938   ) {
 939     carp_unique ( sprintf (
 940       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 941     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 942     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 943       $constraint_name,
 944       join (', ', map { "'$_'" } @undefs),
 945     ));
 946   }
 947
 948   return $final_cond;
 949 }
 950
 951 =head2 search_related
 952
 953 =over 4
 954
 955 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 956
 957 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 958
 959 =back
 960
 961   $new_rs = $cd_rs->search_related('artist', {
 962     name => 'Emo-R-Us',
 963   });
 964
 965 Searches the specified relationship, optionally specifying a condition and
 966 attributes for matching records. See L</ATTRIBUTES> for more information.
 967
 968 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 969 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 970
 971 See also L</search_related_rs>.
 972
 973 =cut
 974
 975 sub search_related {
 976   return shift->related_resultset(shift)->search(@_);
 977 }
 978
 979 =head2 search_related_rs
 980
 981 This method works exactly the same as search_related, except that
 982 it guarantees a resultset, even in list context.
 983
 984 =cut
 985
 986 sub search_related_rs {
 987   return shift->related_resultset(shift)->search_rs(@_);
 988 }
 989
 990 =head2 cursor
 991
 992 =over 4
 993
 994 =item Arguments: none
 995
 996 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 997
 998 =back
 999
1000 Returns a storage-driven cursor to the given resultset. See
1001 L<DBIx::Class::Cursor> for more information.
1002
1003 =cut
1004
1005 sub cursor {
1006   my $self = shift;
1007
1008   return $self->{cursor} ||= do {
1009     my $attrs = $self->_resolved_attrs;
1010     $self->result_source->storage->select(
1011       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1012     );
1013   };
1014 }
1015
1016 =head2 single
1017
1018 =over 4
1019
1020 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1021
1022 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1023
1024 =back
1025
1026   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1027
1028 Inflates the first result without creating a cursor if the resultset has
1029 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1030 of L</search>.
1031
1032 While this method can take an optional search condition (just like L</search>)
1033 being a fast-code-path it does not recognize search attributes. If you need to
1034 add extra joins or similar, call L</search> and then chain-call L</single> on the
1035 L<DBIx::Class::ResultSet> returned.
1036
1037 =over
1038
1039 =item B<Note>
1040
1041 As of 0.08100, this method enforces the assumption that the preceding
1042 query returns only one row. If more than one row is returned, you will receive
1043 a warning:
1044
1045   Query returned more than one row
1046
1047 In this case, you should be using L</next> or L</find> instead, or if you really
1048 know what you are doing, use the L</rows> attribute to explicitly limit the size
1049 of the resultset.
1050
1051 This method will also throw an exception if it is called on a resultset prefetching
1052 has_many, as such a prefetch implies fetching multiple rows from the database in
1053 order to assemble the resulting object.
1054
1055 =back
1056
1057 =cut
1058
1059 sub single {
1060   my ($self, $where) = @_;
1061   if(@_ > 2) {
1062       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1063   }
1064
1065   my $attrs = { %{$self->_resolved_attrs} };
1066
1067   $self->throw_exception(
1068     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1069   ) if $attrs->{collapse};
1070
1071   if ($where) {
1072     if (defined $attrs->{where}) {
1073       $attrs->{where} = {
1074         '-and' =>
1075             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1076                $where, delete $attrs->{where} ]
1077       };
1078     } else {
1079       $attrs->{where} = $where;
1080     }
1081   }
1082
1083   my $data = [ $self->result_source->storage->select_single(
1084     $attrs->{from}, $attrs->{select},
1085     $attrs->{where}, $attrs
1086   )];
1087
1088   return undef unless @$data;
1089   $self->{_stashed_rows} = [ $data ];
1090   $self->_construct_results->[0];
1091 }
1092
1093
1094 # _collapse_query
1095 #
1096 # Recursively collapse the query, accumulating values for each column.
1097
1098 sub _collapse_query {
1099   my ($self, $query, $collapsed) = @_;
1100
1101   $collapsed ||= {};
1102
1103   if (ref $query eq 'ARRAY') {
1104     foreach my $subquery (@$query) {
1105       next unless ref $subquery;  # -or
1106       $collapsed = $self->_collapse_query($subquery, $collapsed);
1107     }
1108   }
1109   elsif (ref $query eq 'HASH') {
1110     if (keys %$query and (keys %$query)[0] eq '-and') {
1111       foreach my $subquery (@{$query->{-and}}) {
1112         $collapsed = $self->_collapse_query($subquery, $collapsed);
1113       }
1114     }
1115     else {
1116       foreach my $col (keys %$query) {
1117         my $value = $query->{$col};
1118         $collapsed->{$col}{$value}++;
1119       }
1120     }
1121   }
1122
1123   return $collapsed;
1124 }
1125
1126 =head2 get_column
1127
1128 =over 4
1129
1130 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1131
1132 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1133
1134 =back
1135
1136   my $max_length = $rs->get_column('length')->max;
1137
1138 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1139
1140 =cut
1141
1142 sub get_column {
1143   my ($self, $column) = @_;
1144   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1145   return $new;
1146 }
1147
1148 =head2 search_like
1149
1150 =over 4
1151
1152 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1153
1154 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1155
1156 =back
1157
1158   # WHERE title LIKE '%blue%'
1159   $cd_rs = $rs->search_like({ title => '%blue%'});
1160
1161 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1162 that this is simply a convenience method retained for ex Class::DBI users.
1163 You most likely want to use L</search> with specific operators.
1164
1165 For more information, see L<DBIx::Class::Manual::Cookbook>.
1166
1167 This method is deprecated and will be removed in 0.09. Use L</search()>
1168 instead. An example conversion is:
1169
1170   ->search_like({ foo => 'bar' });
1171
1172   # Becomes
1173
1174   ->search({ foo => { like => 'bar' } });
1175
1176 =cut
1177
1178 sub search_like {
1179   my $class = shift;
1180   carp_unique (
1181     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1182    .' Instead use ->search({ x => { -like => "y%" } })'
1183    .' (note the outer pair of {}s - they are important!)'
1184   );
1185   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1186   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1187   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1188   return $class->search($query, { %$attrs });
1189 }
1190
1191 =head2 slice
1192
1193 =over 4
1194
1195 =item Arguments: $first, $last
1196
1197 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1198
1199 =back
1200
1201 Returns a resultset or object list representing a subset of elements from the
1202 resultset slice is called on. Indexes are from 0, i.e., to get the first
1203 three records, call:
1204
1205   my ($one, $two, $three) = $rs->slice(0, 2);
1206
1207 =cut
1208
1209 sub slice {
1210   my ($self, $min, $max) = @_;
1211   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1212   $attrs->{offset} = $self->{attrs}{offset} || 0;
1213   $attrs->{offset} += $min;
1214   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1215   return $self->search(undef, $attrs);
1216 }
1217
1218 =head2 next
1219
1220 =over 4
1221
1222 =item Arguments: none
1223
1224 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1225
1226 =back
1227
1228 Returns the next element in the resultset (C<undef> is there is none).
1229
1230 Can be used to efficiently iterate over records in the resultset:
1231
1232   my $rs = $schema->resultset('CD')->search;
1233   while (my $cd = $rs->next) {
1234     print $cd->title;
1235   }
1236
1237 Note that you need to store the resultset object, and call C<next> on it.
1238 Calling C<< resultset('Table')->next >> repeatedly will always return the
1239 first record from the resultset.
1240
1241 =cut
1242
1243 sub next {
1244   my ($self) = @_;
1245
1246   if (my $cache = $self->get_cache) {
1247     $self->{all_cache_position} ||= 0;
1248     return $cache->[$self->{all_cache_position}++];
1249   }
1250
1251   if ($self->{attrs}{cache}) {
1252     delete $self->{pager};
1253     $self->{all_cache_position} = 1;
1254     return ($self->all)[0];
1255   }
1256
1257   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1258
1259   $self->{_stashed_results} = $self->_construct_results
1260     or return undef;
1261
1262   return shift @{$self->{_stashed_results}};
1263 }
1264
1265 # Constructs as many results as it can in one pass while respecting
1266 # cursor laziness. Several modes of operation:
1267 #
1268 # * Always builds everything present in @{$self->{_stashed_rows}}
1269 # * If called with $fetch_all true - pulls everything off the cursor and
1270 #   builds all result structures (or objects) in one pass
1271 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1272 #   and if the resultset is ordered properly by the left side:
1273 #   * Fetches stuff off the cursor until the "master object" changes,
1274 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1275 #   OR
1276 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1277 #     was requested (there is no other way to collapse except for an
1278 #     eager cursor)
1279 # * If no collapse is requested - just get the next row, construct and
1280 #   return
1281 sub _construct_results {
1282   my ($self, $fetch_all) = @_;
1283
1284   my $rsrc = $self->result_source;
1285   my $attrs = $self->_resolved_attrs;
1286
1287   if (
1288     ! $fetch_all
1289       and
1290     ! $attrs->{order_by}
1291       and
1292     $attrs->{collapse}
1293       and
1294     my @pcols = $rsrc->primary_columns
1295   ) {
1296     # default order for collapsing unless the user asked for something
1297     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1298     $attrs->{_ordered_for_collapse} = 1;
1299     $attrs->{_order_is_artificial} = 1;
1300   }
1301
1302   # this will be used as both initial raw-row collector AND as a RV of
1303   # _construct_results. Not regrowing the array twice matters a lot...
1304   # a surprising amount actually
1305   my $rows = delete $self->{_stashed_rows};
1306
1307   my $cursor; # we may not need one at all
1308
1309   my $did_fetch_all = $fetch_all;
1310
1311   if ($fetch_all) {
1312     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1313     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1314   }
1315   elsif( $attrs->{collapse} ) {
1316
1317     # a cursor will need to be closed over in case of collapse
1318     $cursor = $self->cursor;
1319
1320     $attrs->{_ordered_for_collapse} = (
1321       (
1322         $attrs->{order_by}
1323           and
1324         $rsrc->schema
1325               ->storage
1326                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1327       ) ? 1 : 0
1328     ) unless defined $attrs->{_ordered_for_collapse};
1329
1330     if (! $attrs->{_ordered_for_collapse}) {
1331       $did_fetch_all = 1;
1332
1333       # instead of looping over ->next, use ->all in stealth mode
1334       # *without* calling a ->reset afterwards
1335       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1336       if (! $cursor->{_done}) {
1337         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1338         $cursor->{_done} = 1;
1339       }
1340     }
1341   }
1342
1343   if (! $did_fetch_all and ! @{$rows||[]} ) {
1344     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1345     $cursor ||= $self->cursor;
1346     if (scalar (my @r = $cursor->next) ) {
1347       $rows = [ \@r ];
1348     }
1349   }
1350
1351   return undef unless @{$rows||[]};
1352
1353   # sanity check - people are too clever for their own good
1354   if ($attrs->{collapse} and my $aliastypes = $attrs->{_sqlmaker_select_args}[3]{_aliastypes} ) {
1355
1356     my $multiplied_selectors;
1357     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1358       if (
1359         $aliastypes->{multiplying}{$sel_alias}
1360           or
1361         scalar grep { $aliastypes->{multiplying}{(values %$_)[0]} } @{ $aliastypes->{selecting}{$sel_alias}{-parents} }
1362       ) {
1363         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1364       }
1365     }
1366
1367     for my $i (0 .. $#{$attrs->{as}} ) {
1368       my $sel = $attrs->{select}[$i];
1369
1370       if (ref $sel eq 'SCALAR') {
1371         $sel = $$sel;
1372       }
1373       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1374         $sel = $$sel->[0];
1375       }
1376
1377       $self->throw_exception(
1378         'Result collapse not possible - selection from a has_many source redirected to the main object'
1379       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1380     }
1381   }
1382
1383   # hotspot - skip the setter
1384   my $res_class = $self->_result_class;
1385
1386   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1387     $res_class->can ('inflate_result')
1388       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1389   };
1390
1391   my $infmap = $attrs->{as};
1392
1393   $self->{_result_inflator}{is_core_row} = ( (
1394     $inflator_cref
1395       ==
1396     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1397   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1398
1399   $self->{_result_inflator}{is_hri} = ( (
1400     ! $self->{_result_inflator}{is_core_row}
1401       and
1402     $inflator_cref == (
1403       require DBIx::Class::ResultClass::HashRefInflator
1404         &&
1405       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1406     )
1407   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1408
1409
1410   if (! $attrs->{_related_results_construction}) {
1411     # construct a much simpler array->hash folder for the one-table cases right here
1412     if ($self->{_result_inflator}{is_hri}) {
1413       for my $r (@$rows) {
1414         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1415       }
1416     }
1417     # FIXME SUBOPTIMAL this is a very very very hot spot
1418     # while rather optimal we can *still* do much better, by
1419     # building a smarter Row::inflate_result(), and
1420     # switch to feeding it data via a much leaner interface
1421     #
1422     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1423     # this particular resultset size
1424     elsif (@$rows < 60) {
1425       for my $r (@$rows) {
1426         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1427       }
1428     }
1429     else {
1430       eval sprintf (
1431         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1432         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1433       );
1434     }
1435   }
1436   else {
1437     my $parser_type =
1438         $self->{_result_inflator}{is_hri}       ? 'hri'
1439       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1440       :                                           'classic_nonpruning'
1441     ;
1442
1443     # $args and $attrs to _mk_row_parser are separated to delineate what is
1444     # core collapser stuff and what is dbic $rs specific
1445     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1446       eval => 1,
1447       inflate_map => $infmap,
1448       collapse => $attrs->{collapse},
1449       premultiplied => $attrs->{_main_source_premultiplied},
1450       hri_style => $self->{_result_inflator}{is_hri},
1451       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1452     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1453
1454     # column_info metadata historically hasn't been too reliable.
1455     # We need to start fixing this somehow (the collapse resolver
1456     # can't work without it). Add an explicit check for the *main*
1457     # result, hopefully this will gradually weed out such errors
1458     #
1459     # FIXME - this is a temporary kludge that reduces performance
1460     # It is however necessary for the time being
1461     my ($unrolled_non_null_cols_to_check, $err);
1462
1463     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1464
1465       $err =
1466         'Collapse aborted due to invalid ResultSource metadata - the following '
1467       . 'selections are declared non-nullable but NULLs were retrieved: '
1468       ;
1469
1470       my @violating_idx;
1471       COL: for my $i (@$check_non_null_cols) {
1472         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1473       }
1474
1475       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1476         if @violating_idx;
1477
1478       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1479     }
1480
1481     my $next_cref =
1482       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1483     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1484 sub {
1485   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1486   my @r = $cursor->next or return;
1487   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1488     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1489   }
1490   \@r
1491 }
1492 EOS
1493     : sub {
1494         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1495         my @r = $cursor->next or return;
1496         \@r
1497       }
1498     ;
1499
1500     $self->{_row_parser}{$parser_type}{cref}->(
1501       $rows,
1502       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1503     );
1504
1505     # Special-case multi-object HRI - there is no $inflator_cref pass
1506     unless ($self->{_result_inflator}{is_hri}) {
1507       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1508     }
1509   }
1510
1511   # The @$rows check seems odd at first - why wouldn't we want to warn
1512   # regardless? The issue is things like find() etc, where the user
1513   # *knows* only one result will come back. In these cases the ->all
1514   # is not a pessimization, but rather something we actually want
1515   carp_unique(
1516     'Unable to properly collapse has_many results in iterator mode due '
1517   . 'to order criteria - performed an eager cursor slurp underneath. '
1518   . 'Consider using ->all() instead'
1519   ) if ( ! $fetch_all and @$rows > 1 );
1520
1521   return $rows;
1522 }
1523
1524 =head2 result_source
1525
1526 =over 4
1527
1528 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1529
1530 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1531
1532 =back
1533
1534 An accessor for the primary ResultSource object from which this ResultSet
1535 is derived.
1536
1537 =head2 result_class
1538
1539 =over 4
1540
1541 =item Arguments: $result_class?
1542
1543 =item Return Value: $result_class
1544
1545 =back
1546
1547 An accessor for the class to use when creating result objects. Defaults to
1548 C<< result_source->result_class >> - which in most cases is the name of the
1549 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1550
1551 Note that changing the result_class will also remove any components
1552 that were originally loaded in the source class via
1553 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1554 in the original source class will not run.
1555
1556 =cut
1557
1558 sub result_class {
1559   my ($self, $result_class) = @_;
1560   if ($result_class) {
1561
1562     # don't fire this for an object
1563     $self->ensure_class_loaded($result_class)
1564       unless ref($result_class);
1565
1566     if ($self->get_cache) {
1567       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1568     }
1569     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1570     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1571       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1572     }
1573
1574     $self->_result_class($result_class);
1575
1576     delete $self->{_result_inflator};
1577   }
1578   $self->_result_class;
1579 }
1580
1581 =head2 count
1582
1583 =over 4
1584
1585 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1586
1587 =item Return Value: $count
1588
1589 =back
1590
1591 Performs an SQL C<COUNT> with the same query as the resultset was built
1592 with to find the number of elements. Passing arguments is equivalent to
1593 C<< $rs->search ($cond, \%attrs)->count >>
1594
1595 =cut
1596
1597 sub count {
1598   my $self = shift;
1599   return $self->search(@_)->count if @_ and defined $_[0];
1600   return scalar @{ $self->get_cache } if $self->get_cache;
1601
1602   my $attrs = { %{ $self->_resolved_attrs } };
1603
1604   # this is a little optimization - it is faster to do the limit
1605   # adjustments in software, instead of a subquery
1606   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1607
1608   my $crs;
1609   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1610     $crs = $self->_count_subq_rs ($attrs);
1611   }
1612   else {
1613     $crs = $self->_count_rs ($attrs);
1614   }
1615   my $count = $crs->next;
1616
1617   $count -= $offset if $offset;
1618   $count = $rows if $rows and $rows < $count;
1619   $count = 0 if ($count < 0);
1620
1621   return $count;
1622 }
1623
1624 =head2 count_rs
1625
1626 =over 4
1627
1628 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1629
1630 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1631
1632 =back
1633
1634 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1635 This can be very handy for subqueries:
1636
1637   ->search( { amount => $some_rs->count_rs->as_query } )
1638
1639 As with regular resultsets the SQL query will be executed only after
1640 the resultset is accessed via L</next> or L</all>. That would return
1641 the same single value obtainable via L</count>.
1642
1643 =cut
1644
1645 sub count_rs {
1646   my $self = shift;
1647   return $self->search(@_)->count_rs if @_;
1648
1649   # this may look like a lack of abstraction (count() does about the same)
1650   # but in fact an _rs *must* use a subquery for the limits, as the
1651   # software based limiting can not be ported if this $rs is to be used
1652   # in a subquery itself (i.e. ->as_query)
1653   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1654     return $self->_count_subq_rs($self->{_attrs});
1655   }
1656   else {
1657     return $self->_count_rs($self->{_attrs});
1658   }
1659 }
1660
1661 #
1662 # returns a ResultSetColumn object tied to the count query
1663 #
1664 sub _count_rs {
1665   my ($self, $attrs) = @_;
1666
1667   my $rsrc = $self->result_source;
1668
1669   my $tmp_attrs = { %$attrs };
1670   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1671   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1672
1673   # overwrite the selector (supplied by the storage)
1674   $rsrc->resultset_class->new($rsrc, {
1675     %$tmp_attrs,
1676     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1677     as => 'count',
1678   })->get_column ('count');
1679 }
1680
1681 #
1682 # same as above but uses a subquery
1683 #
1684 sub _count_subq_rs {
1685   my ($self, $attrs) = @_;
1686
1687   my $rsrc = $self->result_source;
1688
1689   my $sub_attrs = { %$attrs };
1690   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1691   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1692
1693   # if we multi-prefetch we group_by something unique, as this is what we would
1694   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1695   if ( $attrs->{collapse}  ) {
1696     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1697       $rsrc->_identifying_column_set || $self->throw_exception(
1698         'Unable to construct a unique group_by criteria properly collapsing the '
1699       . 'has_many prefetch before count()'
1700       );
1701     } ]
1702   }
1703
1704   # Calculate subquery selector
1705   if (my $g = $sub_attrs->{group_by}) {
1706
1707     my $sql_maker = $rsrc->storage->sql_maker;
1708
1709     # necessary as the group_by may refer to aliased functions
1710     my $sel_index;
1711     for my $sel (@{$attrs->{select}}) {
1712       $sel_index->{$sel->{-as}} = $sel
1713         if (ref $sel eq 'HASH' and $sel->{-as});
1714     }
1715
1716     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1717     # also look for named aggregates referred in the having clause
1718     # having often contains scalarrefs - thus parse it out entirely
1719     my @parts = @$g;
1720     if ($attrs->{having}) {
1721       local $sql_maker->{having_bind};
1722       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1723       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1724       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1725         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1726         # if we don't unset it we screw up retarded but unfortunately working
1727         # 'MAX(foo.bar)' => { '>', 3 }
1728         $sql_maker->{name_sep} = '';
1729       }
1730
1731       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1732
1733       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1734       my %seen_having;
1735
1736       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1737       # and if all fails for an utterly naive quoted scalar-with-function
1738       while ($having_sql =~ /
1739         $rquote $sep $lquote (.+?) $rquote
1740           |
1741         [\s,] \w+ \. (\w+) [\s,]
1742           |
1743         [\s,] $lquote (.+?) $rquote [\s,]
1744       /gx) {
1745         my $part = $1 || $2 || $3;  # one of them matched if we got here
1746         unless ($seen_having{$part}++) {
1747           push @parts, $part;
1748         }
1749       }
1750     }
1751
1752     for (@parts) {
1753       my $colpiece = $sel_index->{$_} || $_;
1754
1755       # unqualify join-based group_by's. Arcane but possible query
1756       # also horrible horrible hack to alias a column (not a func.)
1757       # (probably need to introduce SQLA syntax)
1758       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1759         my $as = $colpiece;
1760         $as =~ s/\./__/;
1761         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1762       }
1763       push @{$sub_attrs->{select}}, $colpiece;
1764     }
1765   }
1766   else {
1767     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1768     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1769   }
1770
1771   return $rsrc->resultset_class
1772                ->new ($rsrc, $sub_attrs)
1773                 ->as_subselect_rs
1774                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1775                   ->get_column ('count');
1776 }
1777
1778
1779 =head2 count_literal
1780
1781 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1782 should only be used in that context. See L</search_literal> for further info.
1783
1784 =over 4
1785
1786 =item Arguments: $sql_fragment, @standalone_bind_values
1787
1788 =item Return Value: $count
1789
1790 =back
1791
1792 Counts the results in a literal query. Equivalent to calling L</search_literal>
1793 with the passed arguments, then L</count>.
1794
1795 =cut
1796
1797 sub count_literal { shift->search_literal(@_)->count; }
1798
1799 =head2 all
1800
1801 =over 4
1802
1803 =item Arguments: none
1804
1805 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1806
1807 =back
1808
1809 Returns all elements in the resultset.
1810
1811 =cut
1812
1813 sub all {
1814   my $self = shift;
1815   if(@_) {
1816     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1817   }
1818
1819   delete @{$self}{qw/_stashed_rows _stashed_results/};
1820
1821   if (my $c = $self->get_cache) {
1822     return @$c;
1823   }
1824
1825   $self->cursor->reset;
1826
1827   my $objs = $self->_construct_results('fetch_all') || [];
1828
1829   $self->set_cache($objs) if $self->{attrs}{cache};
1830
1831   return @$objs;
1832 }
1833
1834 =head2 reset
1835
1836 =over 4
1837
1838 =item Arguments: none
1839
1840 =item Return Value: $self
1841
1842 =back
1843
1844 Resets the resultset's cursor, so you can iterate through the elements again.
1845 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1846 another query.
1847
1848 =cut
1849
1850 sub reset {
1851   my ($self) = @_;
1852
1853   delete @{$self}{qw/_stashed_rows _stashed_results/};
1854   $self->{all_cache_position} = 0;
1855   $self->cursor->reset;
1856   return $self;
1857 }
1858
1859 =head2 first
1860
1861 =over 4
1862
1863 =item Arguments: none
1864
1865 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1866
1867 =back
1868
1869 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1870 an object for the first result (or C<undef> if the resultset is empty).
1871
1872 =cut
1873
1874 sub first {
1875   return $_[0]->reset->next;
1876 }
1877
1878
1879 # _rs_update_delete
1880 #
1881 # Determines whether and what type of subquery is required for the $rs operation.
1882 # If grouping is necessary either supplies its own, or verifies the current one
1883 # After all is done delegates to the proper storage method.
1884
1885 sub _rs_update_delete {
1886   my ($self, $op, $values) = @_;
1887
1888   my $rsrc = $self->result_source;
1889   my $storage = $rsrc->schema->storage;
1890
1891   my $attrs = { %{$self->_resolved_attrs} };
1892
1893   my $join_classifications;
1894   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1895
1896   # do we need a subquery for any reason?
1897   my $needs_subq = (
1898     defined $existing_group_by
1899       or
1900     # if {from} is unparseable wrap a subq
1901     ref($attrs->{from}) ne 'ARRAY'
1902       or
1903     # limits call for a subq
1904     $self->_has_resolved_attr(qw/rows offset/)
1905   );
1906
1907   # simplify the joinmap, so we can further decide if a subq is necessary
1908   if (!$needs_subq and @{$attrs->{from}} > 1) {
1909
1910     ($attrs->{from}, $join_classifications) =
1911       $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1912
1913     # any non-pruneable non-local restricting joins imply subq
1914     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1915   }
1916
1917   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1918   $needs_subq ||= (
1919     (ref $attrs->{from}[0]) ne 'HASH'
1920       or
1921     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1922   );
1923
1924   my ($cond, $guard);
1925   # do we need anything like a subquery?
1926   if (! $needs_subq) {
1927     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1928     # a condition containing 'me' or other table prefixes will not work
1929     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1930     $cond = do {
1931       my $sqla = $rsrc->storage->sql_maker;
1932       local $sqla->{_dequalify_idents} = 1;
1933       \[ $sqla->_recurse_where($self->{cond}) ];
1934     };
1935   }
1936   else {
1937     # we got this far - means it is time to wrap a subquery
1938     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1939       sprintf(
1940         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1941         $op,
1942         $rsrc->source_name,
1943       )
1944     );
1945
1946     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1947     delete $attrs->{$_} for qw/select as collapse/;
1948     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1949
1950     # this will be consumed by the pruner waaaaay down the stack
1951     $attrs->{_force_prune_multiplying_joins} = 1;
1952
1953     my $subrs = (ref $self)->new($rsrc, $attrs);
1954
1955     if (@$idcols == 1) {
1956       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1957     }
1958     elsif ($storage->_use_multicolumn_in) {
1959       # no syntax for calling this properly yet
1960       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1961       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1962         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1963         $subrs->as_query
1964       ),
1965     }
1966     else {
1967       # if all else fails - get all primary keys and operate over a ORed set
1968       # wrap in a transaction for consistency
1969       # this is where the group_by/multiplication starts to matter
1970       if (
1971         $existing_group_by
1972           or
1973         keys %{ $join_classifications->{multiplying} || {} }
1974       ) {
1975         # make sure if there is a supplied group_by it matches the columns compiled above
1976         # perfectly. Anything else can not be sanely executed on most databases so croak
1977         # right then and there
1978         if ($existing_group_by) {
1979           my @current_group_by = map
1980             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1981             @$existing_group_by
1982           ;
1983
1984           if (
1985             join ("\x00", sort @current_group_by)
1986               ne
1987             join ("\x00", sort @{$attrs->{columns}} )
1988           ) {
1989             $self->throw_exception (
1990               "You have just attempted a $op operation on a resultset which does group_by"
1991               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1992               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1993               . ' kind of queries. Please retry the operation with a modified group_by or'
1994               . ' without using one at all.'
1995             );
1996           }
1997         }
1998
1999         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2000       }
2001
2002       $guard = $storage->txn_scope_guard;
2003
2004       $cond = [];
2005       for my $row ($subrs->cursor->all) {
2006         push @$cond, { map
2007           { $idcols->[$_] => $row->[$_] }
2008           (0 .. $#$idcols)
2009         };
2010       }
2011     }
2012   }
2013
2014   my $res = $storage->$op (
2015     $rsrc,
2016     $op eq 'update' ? $values : (),
2017     $cond,
2018   );
2019
2020   $guard->commit if $guard;
2021
2022   return $res;
2023 }
2024
2025 =head2 update
2026
2027 =over 4
2028
2029 =item Arguments: \%values
2030
2031 =item Return Value: $underlying_storage_rv
2032
2033 =back
2034
2035 Sets the specified columns in the resultset to the supplied values in a
2036 single query. Note that this will not run any accessor/set_column/update
2037 triggers, nor will it update any result object instances derived from this
2038 resultset (this includes the contents of the L<resultset cache|/set_cache>
2039 if any). See L</update_all> if you need to execute any on-update
2040 triggers or cascades defined either by you or a
2041 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2042
2043 The return value is a pass through of what the underlying
2044 storage backend returned, and may vary. See L<DBI/execute> for the most
2045 common case.
2046
2047 =head3 CAVEAT
2048
2049 Note that L</update> does not process/deflate any of the values passed in.
2050 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2051 ensure manually that any value passed to this method will stringify to
2052 something the RDBMS knows how to deal with. A notable example is the
2053 handling of L<DateTime> objects, for more info see:
2054 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2055
2056 =cut
2057
2058 sub update {
2059   my ($self, $values) = @_;
2060   $self->throw_exception('Values for update must be a hash')
2061     unless ref $values eq 'HASH';
2062
2063   return $self->_rs_update_delete ('update', $values);
2064 }
2065
2066 =head2 update_all
2067
2068 =over 4
2069
2070 =item Arguments: \%values
2071
2072 =item Return Value: 1
2073
2074 =back
2075
2076 Fetches all objects and updates them one at a time via
2077 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2078 triggers, while L</update> will not.
2079
2080 =cut
2081
2082 sub update_all {
2083   my ($self, $values) = @_;
2084   $self->throw_exception('Values for update_all must be a hash')
2085     unless ref $values eq 'HASH';
2086
2087   my $guard = $self->result_source->schema->txn_scope_guard;
2088   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2089   $guard->commit;
2090   return 1;
2091 }
2092
2093 =head2 delete
2094
2095 =over 4
2096
2097 =item Arguments: none
2098
2099 =item Return Value: $underlying_storage_rv
2100
2101 =back
2102
2103 Deletes the rows matching this resultset in a single query. Note that this
2104 will not run any delete triggers, nor will it alter the
2105 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2106 derived from this resultset (this includes the contents of the
2107 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2108 execute any on-delete triggers or cascades defined either by you or a
2109 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2110
2111 The return value is a pass through of what the underlying storage backend
2112 returned, and may vary. See L<DBI/execute> for the most common case.
2113
2114 =cut
2115
2116 sub delete {
2117   my $self = shift;
2118   $self->throw_exception('delete does not accept any arguments')
2119     if @_;
2120
2121   return $self->_rs_update_delete ('delete');
2122 }
2123
2124 =head2 delete_all
2125
2126 =over 4
2127
2128 =item Arguments: none
2129
2130 =item Return Value: 1
2131
2132 =back
2133
2134 Fetches all objects and deletes them one at a time via
2135 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2136 triggers, while L</delete> will not.
2137
2138 =cut
2139
2140 sub delete_all {
2141   my $self = shift;
2142   $self->throw_exception('delete_all does not accept any arguments')
2143     if @_;
2144
2145   my $guard = $self->result_source->schema->txn_scope_guard;
2146   $_->delete for $self->all;
2147   $guard->commit;
2148   return 1;
2149 }
2150
2151 =head2 populate
2152
2153 =over 4
2154
2155 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2156
2157 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2158
2159 =back
2160
2161 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2162 arrayrefs.
2163
2164 =over
2165
2166 =item NOTE
2167
2168 The context of this method call has an important effect on what is
2169 submitted to storage. In void context data is fed directly to fastpath
2170 insertion routines provided by the underlying storage (most often
2171 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2172 L<insert|DBIx::Class::Row/insert> calls on the
2173 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2174 augmentation of these methods provided by components. For example if you
2175 are using something like L<DBIx::Class::UUIDColumns> to create primary
2176 keys for you, you will find that your PKs are empty.  In this case you
2177 will have to explicitly force scalar or list context in order to create
2178 those values.
2179
2180 =back
2181
2182 In non-void (scalar or list) context, this method is simply a wrapper
2183 for L</create>. Depending on list or scalar context either a list of
2184 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2185 containing these objects is returned.
2186
2187 When supplying data in "arrayref of arrayrefs" invocation style, the
2188 first element should be a list of column names and each subsequent
2189 element should be a data value in the earlier specified column order.
2190 For example:
2191
2192   $schema->resultset("Artist")->populate([
2193     [ qw( artistid name ) ],
2194     [ 100, 'A Formally Unknown Singer' ],
2195     [ 101, 'A singer that jumped the shark two albums ago' ],
2196     [ 102, 'An actually cool singer' ],
2197   ]);
2198
2199 For the arrayref of hashrefs style each hashref should be a structure
2200 suitable for passing to L</create>. Multi-create is also permitted with
2201 this syntax.
2202
2203   $schema->resultset("Artist")->populate([
2204      { artistid => 4, name => 'Manufactured Crap', cds => [
2205         { title => 'My First CD', year => 2006 },
2206         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2207       ],
2208      },
2209      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2210         { title => 'My parents sold me to a record company', year => 2005 },
2211         { title => 'Why Am I So Ugly?', year => 2006 },
2212         { title => 'I Got Surgery and am now Popular', year => 2007 }
2213       ],
2214      },
2215   ]);
2216
2217 If you attempt a void-context multi-create as in the example above (each
2218 Artist also has the related list of CDs), and B<do not> supply the
2219 necessary autoinc foreign key information, this method will proxy to the
2220 less efficient L</create>, and then throw the Result objects away. In this
2221 case there are obviously no benefits to using this method over L</create>.
2222
2223 =cut
2224
2225 sub populate {
2226   my $self = shift;
2227
2228   # cruft placed in standalone method
2229   my $data = $self->_normalize_populate_args(@_);
2230
2231   return unless @$data;
2232
2233   if(defined wantarray) {
2234     my @created = map { $self->create($_) } @$data;
2235     return wantarray ? @created : \@created;
2236   }
2237   else {
2238     my $first = $data->[0];
2239
2240     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2241     # it relationship data
2242     my (@rels, @columns);
2243     my $rsrc = $self->result_source;
2244     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2245     for (keys %$first) {
2246       my $ref = ref $first->{$_};
2247       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2248         ? push @rels, $_
2249         : push @columns, $_
2250       ;
2251     }
2252
2253     my @pks = $rsrc->primary_columns;
2254
2255     ## do the belongs_to relationships
2256     foreach my $index (0..$#$data) {
2257
2258       # delegate to create() for any dataset without primary keys with specified relationships
2259       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2260         for my $r (@rels) {
2261           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2262             my @ret = $self->populate($data);
2263             return;
2264           }
2265         }
2266       }
2267
2268       foreach my $rel (@rels) {
2269         next unless ref $data->[$index]->{$rel} eq "HASH";
2270         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2271         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2272         my $related = $result->result_source->_resolve_condition(
2273           $reverse_relinfo->{cond},
2274           $self,
2275           $result,
2276           $rel,
2277         );
2278
2279         delete $data->[$index]->{$rel};
2280         $data->[$index] = {%{$data->[$index]}, %$related};
2281
2282         push @columns, keys %$related if $index == 0;
2283       }
2284     }
2285
2286     ## inherit the data locked in the conditions of the resultset
2287     my ($rs_data) = $self->_merge_with_rscond({});
2288     delete @{$rs_data}{@columns};
2289
2290     ## do bulk insert on current row
2291     $rsrc->storage->insert_bulk(
2292       $rsrc,
2293       [@columns, keys %$rs_data],
2294       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2295     );
2296
2297     ## do the has_many relationships
2298     foreach my $item (@$data) {
2299
2300       my $main_row;
2301
2302       foreach my $rel (@rels) {
2303         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2304
2305         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2306
2307         my $child = $main_row->$rel;
2308
2309         my $related = $child->result_source->_resolve_condition(
2310           $rels->{$rel}{cond},
2311           $child,
2312           $main_row,
2313           $rel,
2314         );
2315
2316         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2317         my @populate = map { {%$_, %$related} } @rows_to_add;
2318
2319         $child->populate( \@populate );
2320       }
2321     }
2322   }
2323 }
2324
2325
2326 # populate() arguments went over several incarnations
2327 # What we ultimately support is AoH
2328 sub _normalize_populate_args {
2329   my ($self, $arg) = @_;
2330
2331   if (ref $arg eq 'ARRAY') {
2332     if (!@$arg) {
2333       return [];
2334     }
2335     elsif (ref $arg->[0] eq 'HASH') {
2336       return $arg;
2337     }
2338     elsif (ref $arg->[0] eq 'ARRAY') {
2339       my @ret;
2340       my @colnames = @{$arg->[0]};
2341       foreach my $values (@{$arg}[1 .. $#$arg]) {
2342         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2343       }
2344       return \@ret;
2345     }
2346   }
2347
2348   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2349 }
2350
2351 =head2 pager
2352
2353 =over 4
2354
2355 =item Arguments: none
2356
2357 =item Return Value: L<$pager|Data::Page>
2358
2359 =back
2360
2361 Returns a L<Data::Page> object for the current resultset. Only makes
2362 sense for queries with a C<page> attribute.
2363
2364 To get the full count of entries for a paged resultset, call
2365 C<total_entries> on the L<Data::Page> object.
2366
2367 =cut
2368
2369 sub pager {
2370   my ($self) = @_;
2371
2372   return $self->{pager} if $self->{pager};
2373
2374   my $attrs = $self->{attrs};
2375   if (!defined $attrs->{page}) {
2376     $self->throw_exception("Can't create pager for non-paged rs");
2377   }
2378   elsif ($attrs->{page} <= 0) {
2379     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2380   }
2381   $attrs->{rows} ||= 10;
2382
2383   # throw away the paging flags and re-run the count (possibly
2384   # with a subselect) to get the real total count
2385   my $count_attrs = { %$attrs };
2386   delete @{$count_attrs}{qw/rows offset page pager/};
2387
2388   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2389
2390   require DBIx::Class::ResultSet::Pager;
2391   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2392     sub { $total_rs->count },  #lazy-get the total
2393     $attrs->{rows},
2394     $self->{attrs}{page},
2395   );
2396 }
2397
2398 =head2 page
2399
2400 =over 4
2401
2402 =item Arguments: $page_number
2403
2404 =item Return Value: L<$resultset|/search>
2405
2406 =back
2407
2408 Returns a resultset for the $page_number page of the resultset on which page
2409 is called, where each page contains a number of rows equal to the 'rows'
2410 attribute set on the resultset (10 by default).
2411
2412 =cut
2413
2414 sub page {
2415   my ($self, $page) = @_;
2416   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2417 }
2418
2419 =head2 new_result
2420
2421 =over 4
2422
2423 =item Arguments: \%col_data
2424
2425 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2426
2427 =back
2428
2429 Creates a new result object in the resultset's result class and returns
2430 it. The row is not inserted into the database at this point, call
2431 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2432 will tell you whether the result object has been inserted or not.
2433
2434 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2435
2436 =cut
2437
2438 sub new_result {
2439   my ($self, $values) = @_;
2440
2441   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2442     if @_ > 2;
2443
2444   $self->throw_exception( "new_result expects a hashref" )
2445     unless (ref $values eq 'HASH');
2446
2447   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2448
2449   my $new = $self->result_class->new({
2450     %$merged_cond,
2451     ( @$cols_from_relations
2452       ? (-cols_from_relations => $cols_from_relations)
2453       : ()
2454     ),
2455     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2456   });
2457
2458   if (
2459     reftype($new) eq 'HASH'
2460       and
2461     ! keys %$new
2462       and
2463     blessed($new)
2464   ) {
2465     carp_unique (sprintf (
2466       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2467       $self->result_class,
2468     ));
2469   }
2470
2471   $new;
2472 }
2473
2474 # _merge_with_rscond
2475 #
2476 # Takes a simple hash of K/V data and returns its copy merged with the
2477 # condition already present on the resultset. Additionally returns an
2478 # arrayref of value/condition names, which were inferred from related
2479 # objects (this is needed for in-memory related objects)
2480 sub _merge_with_rscond {
2481   my ($self, $data) = @_;
2482
2483   my (%new_data, @cols_from_relations);
2484
2485   my $alias = $self->{attrs}{alias};
2486
2487   if (! defined $self->{cond}) {
2488     # just massage $data below
2489   }
2490   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2491     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2492     @cols_from_relations = keys %new_data;
2493   }
2494   elsif (ref $self->{cond} ne 'HASH') {
2495     $self->throw_exception(
2496       "Can't abstract implicit construct, resultset condition not a hash"
2497     );
2498   }
2499   else {
2500     # precedence must be given to passed values over values inherited from
2501     # the cond, so the order here is important.
2502     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2503     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2504
2505     while ( my($col, $value) = each %implied ) {
2506       my $vref = ref $value;
2507       if (
2508         $vref eq 'HASH'
2509           and
2510         keys(%$value) == 1
2511           and
2512         (keys %$value)[0] eq '='
2513       ) {
2514         $new_data{$col} = $value->{'='};
2515       }
2516       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2517         $new_data{$col} = $value;
2518       }
2519     }
2520   }
2521
2522   %new_data = (
2523     %new_data,
2524     %{ $self->_remove_alias($data, $alias) },
2525   );
2526
2527   return (\%new_data, \@cols_from_relations);
2528 }
2529
2530 # _has_resolved_attr
2531 #
2532 # determines if the resultset defines at least one
2533 # of the attributes supplied
2534 #
2535 # used to determine if a subquery is necessary
2536 #
2537 # supports some virtual attributes:
2538 #   -join
2539 #     This will scan for any joins being present on the resultset.
2540 #     It is not a mere key-search but a deep inspection of {from}
2541 #
2542
2543 sub _has_resolved_attr {
2544   my ($self, @attr_names) = @_;
2545
2546   my $attrs = $self->_resolved_attrs;
2547
2548   my %extra_checks;
2549
2550   for my $n (@attr_names) {
2551     if (grep { $n eq $_ } (qw/-join/) ) {
2552       $extra_checks{$n}++;
2553       next;
2554     }
2555
2556     my $attr =  $attrs->{$n};
2557
2558     next if not defined $attr;
2559
2560     if (ref $attr eq 'HASH') {
2561       return 1 if keys %$attr;
2562     }
2563     elsif (ref $attr eq 'ARRAY') {
2564       return 1 if @$attr;
2565     }
2566     else {
2567       return 1 if $attr;
2568     }
2569   }
2570
2571   # a resolved join is expressed as a multi-level from
2572   return 1 if (
2573     $extra_checks{-join}
2574       and
2575     ref $attrs->{from} eq 'ARRAY'
2576       and
2577     @{$attrs->{from}} > 1
2578   );
2579
2580   return 0;
2581 }
2582
2583 # _collapse_cond
2584 #
2585 # Recursively collapse the condition.
2586
2587 sub _collapse_cond {
2588   my ($self, $cond, $collapsed) = @_;
2589
2590   $collapsed ||= {};
2591
2592   if (ref $cond eq 'ARRAY') {
2593     foreach my $subcond (@$cond) {
2594       next unless ref $subcond;  # -or
2595       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2596     }
2597   }
2598   elsif (ref $cond eq 'HASH') {
2599     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2600       foreach my $subcond (@{$cond->{-and}}) {
2601         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2602       }
2603     }
2604     else {
2605       foreach my $col (keys %$cond) {
2606         my $value = $cond->{$col};
2607         $collapsed->{$col} = $value;
2608       }
2609     }
2610   }
2611
2612   return $collapsed;
2613 }
2614
2615 # _remove_alias
2616 #
2617 # Remove the specified alias from the specified query hash. A copy is made so
2618 # the original query is not modified.
2619
2620 sub _remove_alias {
2621   my ($self, $query, $alias) = @_;
2622
2623   my %orig = %{ $query || {} };
2624   my %unaliased;
2625
2626   foreach my $key (keys %orig) {
2627     if ($key !~ /\./) {
2628       $unaliased{$key} = $orig{$key};
2629       next;
2630     }
2631     $unaliased{$1} = $orig{$key}
2632       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2633   }
2634
2635   return \%unaliased;
2636 }
2637
2638 =head2 as_query
2639
2640 =over 4
2641
2642 =item Arguments: none
2643
2644 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2645
2646 =back
2647
2648 Returns the SQL query and bind vars associated with the invocant.
2649
2650 This is generally used as the RHS for a subquery.
2651
2652 =cut
2653
2654 sub as_query {
2655   my $self = shift;
2656
2657   my $attrs = { %{ $self->_resolved_attrs } };
2658
2659   my $aq = $self->result_source->storage->_select_args_to_query (
2660     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2661   );
2662
2663   $self->{_attrs}{_sqlmaker_select_args} = $attrs->{_sqlmaker_select_args};
2664
2665   $aq;
2666 }
2667
2668 =head2 find_or_new
2669
2670 =over 4
2671
2672 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2673
2674 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2675
2676 =back
2677
2678   my $artist = $schema->resultset('Artist')->find_or_new(
2679     { artist => 'fred' }, { key => 'artists' });
2680
2681   $cd->cd_to_producer->find_or_new({ producer => $producer },
2682                                    { key => 'primary' });
2683
2684 Find an existing record from this resultset using L</find>. if none exists,
2685 instantiate a new result object and return it. The object will not be saved
2686 into your storage until you call L<DBIx::Class::Row/insert> on it.
2687
2688 You most likely want this method when looking for existing rows using a unique
2689 constraint that is not the primary key, or looking for related rows.
2690
2691 If you want objects to be saved immediately, use L</find_or_create> instead.
2692
2693 B<Note>: Make sure to read the documentation of L</find> and understand the
2694 significance of the C<key> attribute, as its lack may skew your search, and
2695 subsequently result in spurious new objects.
2696
2697 B<Note>: Take care when using C<find_or_new> with a table having
2698 columns with default values that you intend to be automatically
2699 supplied by the database (e.g. an auto_increment primary key column).
2700 In normal usage, the value of such columns should NOT be included at
2701 all in the call to C<find_or_new>, even when set to C<undef>.
2702
2703 =cut
2704
2705 sub find_or_new {
2706   my $self     = shift;
2707   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2708   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2709   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2710     return $row;
2711   }
2712   return $self->new_result($hash);
2713 }
2714
2715 =head2 create
2716
2717 =over 4
2718
2719 =item Arguments: \%col_data
2720
2721 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2722
2723 =back
2724
2725 Attempt to create a single new row or a row with multiple related rows
2726 in the table represented by the resultset (and related tables). This
2727 will not check for duplicate rows before inserting, use
2728 L</find_or_create> to do that.
2729
2730 To create one row for this resultset, pass a hashref of key/value
2731 pairs representing the columns of the table and the values you wish to
2732 store. If the appropriate relationships are set up, foreign key fields
2733 can also be passed an object representing the foreign row, and the
2734 value will be set to its primary key.
2735
2736 To create related objects, pass a hashref of related-object column values
2737 B<keyed on the relationship name>. If the relationship is of type C<multi>
2738 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2739 The process will correctly identify columns holding foreign keys, and will
2740 transparently populate them from the keys of the corresponding relation.
2741 This can be applied recursively, and will work correctly for a structure
2742 with an arbitrary depth and width, as long as the relationships actually
2743 exists and the correct column data has been supplied.
2744
2745 Instead of hashrefs of plain related data (key/value pairs), you may
2746 also pass new or inserted objects. New objects (not inserted yet, see
2747 L</new_result>), will be inserted into their appropriate tables.
2748
2749 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2750
2751 Example of creating a new row.
2752
2753   $person_rs->create({
2754     name=>"Some Person",
2755     email=>"somebody@someplace.com"
2756   });
2757
2758 Example of creating a new row and also creating rows in a related C<has_many>
2759 or C<has_one> resultset.  Note Arrayref.
2760
2761   $artist_rs->create(
2762      { artistid => 4, name => 'Manufactured Crap', cds => [
2763         { title => 'My First CD', year => 2006 },
2764         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2765       ],
2766      },
2767   );
2768
2769 Example of creating a new row and also creating a row in a related
2770 C<belongs_to> resultset. Note Hashref.
2771
2772   $cd_rs->create({
2773     title=>"Music for Silly Walks",
2774     year=>2000,
2775     artist => {
2776       name=>"Silly Musician",
2777     }
2778   });
2779
2780 =over
2781
2782 =item WARNING
2783
2784 When subclassing ResultSet never attempt to override this method. Since
2785 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2786 lot of the internals simply never call it, so your override will be
2787 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2788 or L<DBIx::Class::Row/insert> depending on how early in the
2789 L</create> process you need to intervene. See also warning pertaining to
2790 L</new>.
2791
2792 =back
2793
2794 =cut
2795
2796 sub create {
2797   my ($self, $col_data) = @_;
2798   $self->throw_exception( "create needs a hashref" )
2799     unless ref $col_data eq 'HASH';
2800   return $self->new_result($col_data)->insert;
2801 }
2802
2803 =head2 find_or_create
2804
2805 =over 4
2806
2807 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2808
2809 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2810
2811 =back
2812
2813   $cd->cd_to_producer->find_or_create({ producer => $producer },
2814                                       { key => 'primary' });
2815
2816 Tries to find a record based on its primary key or unique constraints; if none
2817 is found, creates one and returns that instead.
2818
2819   my $cd = $schema->resultset('CD')->find_or_create({
2820     cdid   => 5,
2821     artist => 'Massive Attack',
2822     title  => 'Mezzanine',
2823     year   => 2005,
2824   });
2825
2826 Also takes an optional C<key> attribute, to search by a specific key or unique
2827 constraint. For example:
2828
2829   my $cd = $schema->resultset('CD')->find_or_create(
2830     {
2831       artist => 'Massive Attack',
2832       title  => 'Mezzanine',
2833     },
2834     { key => 'cd_artist_title' }
2835   );
2836
2837 B<Note>: Make sure to read the documentation of L</find> and understand the
2838 significance of the C<key> attribute, as its lack may skew your search, and
2839 subsequently result in spurious row creation.
2840
2841 B<Note>: Because find_or_create() reads from the database and then
2842 possibly inserts based on the result, this method is subject to a race
2843 condition. Another process could create a record in the table after
2844 the find has completed and before the create has started. To avoid
2845 this problem, use find_or_create() inside a transaction.
2846
2847 B<Note>: Take care when using C<find_or_create> with a table having
2848 columns with default values that you intend to be automatically
2849 supplied by the database (e.g. an auto_increment primary key column).
2850 In normal usage, the value of such columns should NOT be included at
2851 all in the call to C<find_or_create>, even when set to C<undef>.
2852
2853 See also L</find> and L</update_or_create>. For information on how to declare
2854 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2855
2856 If you need to know if an existing row was found or a new one created use
2857 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2858 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2859 database!
2860
2861   my $cd = $schema->resultset('CD')->find_or_new({
2862     cdid   => 5,
2863     artist => 'Massive Attack',
2864     title  => 'Mezzanine',
2865     year   => 2005,
2866   });
2867
2868   if( !$cd->in_storage ) {
2869       # do some stuff
2870       $cd->insert;
2871   }
2872
2873 =cut
2874
2875 sub find_or_create {
2876   my $self     = shift;
2877   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2878   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2879   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2880     return $row;
2881   }
2882   return $self->create($hash);
2883 }
2884
2885 =head2 update_or_create
2886
2887 =over 4
2888
2889 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2890
2891 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2892
2893 =back
2894
2895   $resultset->update_or_create({ col => $val, ... });
2896
2897 Like L</find_or_create>, but if a row is found it is immediately updated via
2898 C<< $found_row->update (\%col_data) >>.
2899
2900
2901 Takes an optional C<key> attribute to search on a specific unique constraint.
2902 For example:
2903
2904   # In your application
2905   my $cd = $schema->resultset('CD')->update_or_create(
2906     {
2907       artist => 'Massive Attack',
2908       title  => 'Mezzanine',
2909       year   => 1998,
2910     },
2911     { key => 'cd_artist_title' }
2912   );
2913
2914   $cd->cd_to_producer->update_or_create({
2915     producer => $producer,
2916     name => 'harry',
2917   }, {
2918     key => 'primary',
2919   });
2920
2921 B<Note>: Make sure to read the documentation of L</find> and understand the
2922 significance of the C<key> attribute, as its lack may skew your search, and
2923 subsequently result in spurious row creation.
2924
2925 B<Note>: Take care when using C<update_or_create> with a table having
2926 columns with default values that you intend to be automatically
2927 supplied by the database (e.g. an auto_increment primary key column).
2928 In normal usage, the value of such columns should NOT be included at
2929 all in the call to C<update_or_create>, even when set to C<undef>.
2930
2931 See also L</find> and L</find_or_create>. For information on how to declare
2932 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2933
2934 If you need to know if an existing row was updated or a new one created use
2935 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2936 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2937 database!
2938
2939 =cut
2940
2941 sub update_or_create {
2942   my $self = shift;
2943   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2944   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2945
2946   my $row = $self->find($cond, $attrs);
2947   if (defined $row) {
2948     $row->update($cond);
2949     return $row;
2950   }
2951
2952   return $self->create($cond);
2953 }
2954
2955 =head2 update_or_new
2956
2957 =over 4
2958
2959 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2960
2961 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2962
2963 =back
2964
2965   $resultset->update_or_new({ col => $val, ... });
2966
2967 Like L</find_or_new> but if a row is found it is immediately updated via
2968 C<< $found_row->update (\%col_data) >>.
2969
2970 For example:
2971
2972   # In your application
2973   my $cd = $schema->resultset('CD')->update_or_new(
2974     {
2975       artist => 'Massive Attack',
2976       title  => 'Mezzanine',
2977       year   => 1998,
2978     },
2979     { key => 'cd_artist_title' }
2980   );
2981
2982   if ($cd->in_storage) {
2983       # the cd was updated
2984   }
2985   else {
2986       # the cd is not yet in the database, let's insert it
2987       $cd->insert;
2988   }
2989
2990 B<Note>: Make sure to read the documentation of L</find> and understand the
2991 significance of the C<key> attribute, as its lack may skew your search, and
2992 subsequently result in spurious new objects.
2993
2994 B<Note>: Take care when using C<update_or_new> with a table having
2995 columns with default values that you intend to be automatically
2996 supplied by the database (e.g. an auto_increment primary key column).
2997 In normal usage, the value of such columns should NOT be included at
2998 all in the call to C<update_or_new>, even when set to C<undef>.
2999
3000 See also L</find>, L</find_or_create> and L</find_or_new>.
3001
3002 =cut
3003
3004 sub update_or_new {
3005     my $self  = shift;
3006     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3007     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3008
3009     my $row = $self->find( $cond, $attrs );
3010     if ( defined $row ) {
3011         $row->update($cond);
3012         return $row;
3013     }
3014
3015     return $self->new_result($cond);
3016 }
3017
3018 =head2 get_cache
3019
3020 =over 4
3021
3022 =item Arguments: none
3023
3024 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3025
3026 =back
3027
3028 Gets the contents of the cache for the resultset, if the cache is set.
3029
3030 The cache is populated either by using the L</prefetch> attribute to
3031 L</search> or by calling L</set_cache>.
3032
3033 =cut
3034
3035 sub get_cache {
3036   shift->{all_cache};
3037 }
3038
3039 =head2 set_cache
3040
3041 =over 4
3042
3043 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3044
3045 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3046
3047 =back
3048
3049 Sets the contents of the cache for the resultset. Expects an arrayref
3050 of objects of the same class as those produced by the resultset. Note that
3051 if the cache is set, the resultset will return the cached objects rather
3052 than re-querying the database even if the cache attr is not set.
3053
3054 The contents of the cache can also be populated by using the
3055 L</prefetch> attribute to L</search>.
3056
3057 =cut
3058
3059 sub set_cache {
3060   my ( $self, $data ) = @_;
3061   $self->throw_exception("set_cache requires an arrayref")
3062       if defined($data) && (ref $data ne 'ARRAY');
3063   $self->{all_cache} = $data;
3064 }
3065
3066 =head2 clear_cache
3067
3068 =over 4
3069
3070 =item Arguments: none
3071
3072 =item Return Value: undef
3073
3074 =back
3075
3076 Clears the cache for the resultset.
3077
3078 =cut
3079
3080 sub clear_cache {
3081   shift->set_cache(undef);
3082 }
3083
3084 =head2 is_paged
3085
3086 =over 4
3087
3088 =item Arguments: none
3089
3090 =item Return Value: true, if the resultset has been paginated
3091
3092 =back
3093
3094 =cut
3095
3096 sub is_paged {
3097   my ($self) = @_;
3098   return !!$self->{attrs}{page};
3099 }
3100
3101 =head2 is_ordered
3102
3103 =over 4
3104
3105 =item Arguments: none
3106
3107 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3108
3109 =back
3110
3111 =cut
3112
3113 sub is_ordered {
3114   my ($self) = @_;
3115   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3116 }
3117
3118 =head2 related_resultset
3119
3120 =over 4
3121
3122 =item Arguments: $rel_name
3123
3124 =item Return Value: L<$resultset|/search>
3125
3126 =back
3127
3128 Returns a related resultset for the supplied relationship name.
3129
3130   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3131
3132 =cut
3133
3134 sub related_resultset {
3135   my ($self, $rel) = @_;
3136
3137   return $self->{related_resultsets}{$rel}
3138     if defined $self->{related_resultsets}{$rel};
3139
3140   return $self->{related_resultsets}{$rel} = do {
3141     my $rsrc = $self->result_source;
3142     my $rel_info = $rsrc->relationship_info($rel);
3143
3144     $self->throw_exception(
3145       "search_related: result source '" . $rsrc->source_name .
3146         "' has no such relationship $rel")
3147       unless $rel_info;
3148
3149     my $attrs = $self->_chain_relationship($rel);
3150
3151     my $join_count = $attrs->{seen_join}{$rel};
3152
3153     my $alias = $self->result_source->storage
3154         ->relname_to_table_alias($rel, $join_count);
3155
3156     # since this is search_related, and we already slid the select window inwards
3157     # (the select/as attrs were deleted in the beginning), we need to flip all
3158     # left joins to inner, so we get the expected results
3159     # read the comment on top of the actual function to see what this does
3160     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3161
3162
3163     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3164     delete @{$attrs}{qw(result_class alias)};
3165
3166     my $rel_source = $rsrc->related_source($rel);
3167
3168     my $new = do {
3169
3170       # The reason we do this now instead of passing the alias to the
3171       # search_rs below is that if you wrap/overload resultset on the
3172       # source you need to know what alias it's -going- to have for things
3173       # to work sanely (e.g. RestrictWithObject wants to be able to add
3174       # extra query restrictions, and these may need to be $alias.)
3175
3176       my $rel_attrs = $rel_source->resultset_attributes;
3177       local $rel_attrs->{alias} = $alias;
3178
3179       $rel_source->resultset
3180                  ->search_rs(
3181                      undef, {
3182                        %$attrs,
3183                        where => $attrs->{where},
3184                    });
3185     };
3186
3187     if (my $cache = $self->get_cache) {
3188       my @related_cache = map
3189         { @{$_->related_resultset($rel)->get_cache||[]} }
3190         @$cache
3191       ;
3192
3193       $new->set_cache(\@related_cache) if @related_cache;
3194     }
3195
3196     $new;
3197   };
3198 }
3199
3200 =head2 current_source_alias
3201
3202 =over 4
3203
3204 =item Arguments: none
3205
3206 =item Return Value: $source_alias
3207
3208 =back
3209
3210 Returns the current table alias for the result source this resultset is built
3211 on, that will be used in the SQL query. Usually it is C<me>.
3212
3213 Currently the source alias that refers to the result set returned by a
3214 L</search>/L</find> family method depends on how you got to the resultset: it's
3215 C<me> by default, but eg. L</search_related> aliases it to the related result
3216 source name (and keeps C<me> referring to the original result set). The long
3217 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3218 (and make this method unnecessary).
3219
3220 Thus it's currently necessary to use this method in predefined queries (see
3221 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3222 source alias of the current result set:
3223
3224   # in a result set class
3225   sub modified_by {
3226     my ($self, $user) = @_;
3227
3228     my $me = $self->current_source_alias;
3229
3230     return $self->search({
3231       "$me.modified" => $user->id,
3232     });
3233   }
3234
3235 =cut
3236
3237 sub current_source_alias {
3238   return (shift->{attrs} || {})->{alias} || 'me';
3239 }
3240
3241 =head2 as_subselect_rs
3242
3243 =over 4
3244
3245 =item Arguments: none
3246
3247 =item Return Value: L<$resultset|/search>
3248
3249 =back
3250
3251 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3252 "virtual view" by including it as a subquery within the from clause.  From this
3253 point on, any joined tables are inaccessible to ->search on the resultset (as if
3254 it were simply where-filtered without joins).  For example:
3255
3256  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3257
3258  # 'x' now pollutes the query namespace
3259
3260  # So the following works as expected
3261  my $ok_rs = $rs->search({'x.other' => 1});
3262
3263  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3264  # def) we look for one row with contradictory terms and join in another table
3265  # (aliased 'x_2') which we never use
3266  my $broken_rs = $rs->search({'x.name' => 'def'});
3267
3268  my $rs2 = $rs->as_subselect_rs;
3269
3270  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3271  my $not_joined_rs = $rs2->search({'x.other' => 1});
3272
3273  # works as expected: finds a 'table' row related to two x rows (abc and def)
3274  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3275
3276 Another example of when one might use this would be to select a subset of
3277 columns in a group by clause:
3278
3279  my $rs = $schema->resultset('Bar')->search(undef, {
3280    group_by => [qw{ id foo_id baz_id }],
3281  })->as_subselect_rs->search(undef, {
3282    columns => [qw{ id foo_id }]
3283  });
3284
3285 In the above example normally columns would have to be equal to the group by,
3286 but because we isolated the group by into a subselect the above works.
3287
3288 =cut
3289
3290 sub as_subselect_rs {
3291   my $self = shift;
3292
3293   my $attrs = $self->_resolved_attrs;
3294
3295   my $fresh_rs = (ref $self)->new (
3296     $self->result_source
3297   );
3298
3299   # these pieces will be locked in the subquery
3300   delete $fresh_rs->{cond};
3301   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3302
3303   return $fresh_rs->search( {}, {
3304     from => [{
3305       $attrs->{alias} => $self->as_query,
3306       -alias  => $attrs->{alias},
3307       -rsrc   => $self->result_source,
3308     }],
3309     alias => $attrs->{alias},
3310   });
3311 }
3312
3313 # This code is called by search_related, and makes sure there
3314 # is clear separation between the joins before, during, and
3315 # after the relationship. This information is needed later
3316 # in order to properly resolve prefetch aliases (any alias
3317 # with a relation_chain_depth less than the depth of the
3318 # current prefetch is not considered)
3319 #
3320 # The increments happen twice per join. An even number means a
3321 # relationship specified via a search_related, whereas an odd
3322 # number indicates a join/prefetch added via attributes
3323 #
3324 # Also this code will wrap the current resultset (the one we
3325 # chain to) in a subselect IFF it contains limiting attributes
3326 sub _chain_relationship {
3327   my ($self, $rel) = @_;
3328   my $source = $self->result_source;
3329   my $attrs = { %{$self->{attrs}||{}} };
3330
3331   # we need to take the prefetch the attrs into account before we
3332   # ->_resolve_join as otherwise they get lost - captainL
3333   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3334
3335   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3336
3337   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3338
3339   my $from;
3340   my @force_subq_attrs = qw/offset rows group_by having/;
3341
3342   if (
3343     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3344       ||
3345     $self->_has_resolved_attr (@force_subq_attrs)
3346   ) {
3347     # Nuke the prefetch (if any) before the new $rs attrs
3348     # are resolved (prefetch is useless - we are wrapping
3349     # a subquery anyway).
3350     my $rs_copy = $self->search;
3351     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3352       $rs_copy->{attrs}{join},
3353       delete $rs_copy->{attrs}{prefetch},
3354     );
3355
3356     $from = [{
3357       -rsrc   => $source,
3358       -alias  => $attrs->{alias},
3359       $attrs->{alias} => $rs_copy->as_query,
3360     }];
3361     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3362     $seen->{-relation_chain_depth} = 0;
3363   }
3364   elsif ($attrs->{from}) {  #shallow copy suffices
3365     $from = [ @{$attrs->{from}} ];
3366   }
3367   else {
3368     $from = [{
3369       -rsrc  => $source,
3370       -alias => $attrs->{alias},
3371       $attrs->{alias} => $source->from,
3372     }];
3373   }
3374
3375   my $jpath = ($seen->{-relation_chain_depth})
3376     ? $from->[-1][0]{-join_path}
3377     : [];
3378
3379   my @requested_joins = $source->_resolve_join(
3380     $join,
3381     $attrs->{alias},
3382     $seen,
3383     $jpath,
3384   );
3385
3386   push @$from, @requested_joins;
3387
3388   $seen->{-relation_chain_depth}++;
3389
3390   # if $self already had a join/prefetch specified on it, the requested
3391   # $rel might very well be already included. What we do in this case
3392   # is effectively a no-op (except that we bump up the chain_depth on
3393   # the join in question so we could tell it *is* the search_related)
3394   my $already_joined;
3395
3396   # we consider the last one thus reverse
3397   for my $j (reverse @requested_joins) {
3398     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3399     if ($rel eq $last_j) {
3400       $j->[0]{-relation_chain_depth}++;
3401       $already_joined++;
3402       last;
3403     }
3404   }
3405
3406   unless ($already_joined) {
3407     push @$from, $source->_resolve_join(
3408       $rel,
3409       $attrs->{alias},
3410       $seen,
3411       $jpath,
3412     );
3413   }
3414
3415   $seen->{-relation_chain_depth}++;
3416
3417   return {%$attrs, from => $from, seen_join => $seen};
3418 }
3419
3420 sub _resolved_attrs {
3421   my $self = shift;
3422   return $self->{_attrs} if $self->{_attrs};
3423
3424   my $attrs  = { %{ $self->{attrs} || {} } };
3425   my $source = $self->result_source;
3426   my $alias  = $attrs->{alias};
3427
3428   # default selection list
3429   $attrs->{columns} = [ $source->columns ]
3430     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3431
3432   # merge selectors together
3433   for (qw/columns select as/) {
3434     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3435       if $attrs->{$_} or $attrs->{"+$_"};
3436   }
3437
3438   # disassemble columns
3439   my (@sel, @as);
3440   if (my $cols = delete $attrs->{columns}) {
3441     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3442       if (ref $c eq 'HASH') {
3443         for my $as (sort keys %$c) {
3444           push @sel, $c->{$as};
3445           push @as, $as;
3446         }
3447       }
3448       else {
3449         push @sel, $c;
3450         push @as, $c;
3451       }
3452     }
3453   }
3454
3455   # when trying to weed off duplicates later do not go past this point -
3456   # everything added from here on is unbalanced "anyone's guess" stuff
3457   my $dedup_stop_idx = $#as;
3458
3459   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3460     if $attrs->{as};
3461   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3462     if $attrs->{select};
3463
3464   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3465   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3466
3467   # disqualify all $alias.col as-bits (inflate-map mandated)
3468   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3469
3470   # de-duplicate the result (remove *identical* select/as pairs)
3471   # and also die on duplicate {as} pointing to different {select}s
3472   # not using a c-style for as the condition is prone to shrinkage
3473   my $seen;
3474   my $i = 0;
3475   while ($i <= $dedup_stop_idx) {
3476     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3477       splice @sel, $i, 1;
3478       splice @as, $i, 1;
3479       $dedup_stop_idx--;
3480     }
3481     elsif ($seen->{$as[$i]}++) {
3482       $self->throw_exception(
3483         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3484       );
3485     }
3486     else {
3487       $i++;
3488     }
3489   }
3490
3491   $attrs->{select} = \@sel;
3492   $attrs->{as} = \@as;
3493
3494   $attrs->{from} ||= [{
3495     -rsrc   => $source,
3496     -alias  => $self->{attrs}{alias},
3497     $self->{attrs}{alias} => $source->from,
3498   }];
3499
3500   if ( $attrs->{join} || $attrs->{prefetch} ) {
3501
3502     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3503       if ref $attrs->{from} ne 'ARRAY';
3504
3505     my $join = (delete $attrs->{join}) || {};
3506
3507     if ( defined $attrs->{prefetch} ) {
3508       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3509     }
3510
3511     $attrs->{from} =    # have to copy here to avoid corrupting the original
3512       [
3513         @{ $attrs->{from} },
3514         $source->_resolve_join(
3515           $join,
3516           $alias,
3517           { %{ $attrs->{seen_join} || {} } },
3518           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3519             ? $attrs->{from}[-1][0]{-join_path}
3520             : []
3521           ,
3522         )
3523       ];
3524   }
3525
3526   if ( defined $attrs->{order_by} ) {
3527     $attrs->{order_by} = (
3528       ref( $attrs->{order_by} ) eq 'ARRAY'
3529       ? [ @{ $attrs->{order_by} } ]
3530       : [ $attrs->{order_by} || () ]
3531     );
3532   }
3533
3534   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3535     $attrs->{group_by} = [ $attrs->{group_by} ];
3536   }
3537
3538   # generate the distinct induced group_by early, as prefetch will be carried via a
3539   # subquery (since a group_by is present)
3540   if (delete $attrs->{distinct}) {
3541     if ($attrs->{group_by}) {
3542       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3543     }
3544     else {
3545       $attrs->{_grouped_by_distinct} = 1;
3546       # distinct affects only the main selection part, not what prefetch may
3547       # add below.
3548       $attrs->{group_by} = $source->storage->_group_over_selection($attrs);
3549     }
3550   }
3551
3552   # generate selections based on the prefetch helper
3553   my $prefetch;
3554   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3555     if defined $attrs->{prefetch};
3556
3557   if ($prefetch) {
3558
3559     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3560       if $attrs->{_dark_selector};
3561
3562     $attrs->{collapse} = 1;
3563
3564     # this is a separate structure (we don't look in {from} directly)
3565     # as the resolver needs to shift things off the lists to work
3566     # properly (identical-prefetches on different branches)
3567     my $join_map = {};
3568     if (ref $attrs->{from} eq 'ARRAY') {
3569
3570       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3571
3572       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3573         next unless $j->[0]{-alias};
3574         next unless $j->[0]{-join_path};
3575         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3576
3577         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3578
3579         my $p = $join_map;
3580         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3581         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3582       }
3583     }
3584
3585     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3586
3587     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3588     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3589   }
3590
3591   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3592     $attrs->{_related_results_construction} = 1;
3593   }
3594
3595   # run through the resulting joinstructure (starting from our current slot)
3596   # and unset collapse if proven unnecessary
3597   #
3598   # also while we are at it find out if the current root source has
3599   # been premultiplied by previous related_source chaining
3600   #
3601   # this allows to predict whether a root object with all other relation
3602   # data set to NULL is in fact unique
3603   if ($attrs->{collapse}) {
3604
3605     if (ref $attrs->{from} eq 'ARRAY') {
3606
3607       if (@{$attrs->{from}} == 1) {
3608         # no joins - no collapse
3609         $attrs->{collapse} = 0;
3610       }
3611       else {
3612         # find where our table-spec starts
3613         my @fromlist = @{$attrs->{from}};
3614         while (@fromlist) {
3615           my $t = shift @fromlist;
3616
3617           my $is_multi;
3618           # me vs join from-spec distinction - a ref means non-root
3619           if (ref $t eq 'ARRAY') {
3620             $t = $t->[0];
3621             $is_multi ||= ! $t->{-is_single};
3622           }
3623           last if ($t->{-alias} && $t->{-alias} eq $alias);
3624           $attrs->{_main_source_premultiplied} ||= $is_multi;
3625         }
3626
3627         # no non-singles remaining, nor any premultiplication - nothing to collapse
3628         if (
3629           ! $attrs->{_main_source_premultiplied}
3630             and
3631           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3632         ) {
3633           $attrs->{collapse} = 0;
3634         }
3635       }
3636     }
3637
3638     else {
3639       # if we can not analyze the from - err on the side of safety
3640       $attrs->{_main_source_premultiplied} = 1;
3641     }
3642   }
3643
3644   # if both page and offset are specified, produce a combined offset
3645   # even though it doesn't make much sense, this is what pre 081xx has
3646   # been doing
3647   if (my $page = delete $attrs->{page}) {
3648     $attrs->{offset} =
3649       ($attrs->{rows} * ($page - 1))
3650             +
3651       ($attrs->{offset} || 0)
3652     ;
3653   }
3654
3655   return $self->{_attrs} = $attrs;
3656 }
3657
3658 sub _rollout_attr {
3659   my ($self, $attr) = @_;
3660
3661   if (ref $attr eq 'HASH') {
3662     return $self->_rollout_hash($attr);
3663   } elsif (ref $attr eq 'ARRAY') {
3664     return $self->_rollout_array($attr);
3665   } else {
3666     return [$attr];
3667   }
3668 }
3669
3670 sub _rollout_array {
3671   my ($self, $attr) = @_;
3672
3673   my @rolled_array;
3674   foreach my $element (@{$attr}) {
3675     if (ref $element eq 'HASH') {
3676       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3677     } elsif (ref $element eq 'ARRAY') {
3678       #  XXX - should probably recurse here
3679       push( @rolled_array, @{$self->_rollout_array($element)} );
3680     } else {
3681       push( @rolled_array, $element );
3682     }
3683   }
3684   return \@rolled_array;
3685 }
3686
3687 sub _rollout_hash {
3688   my ($self, $attr) = @_;
3689
3690   my @rolled_array;
3691   foreach my $key (keys %{$attr}) {
3692     push( @rolled_array, { $key => $attr->{$key} } );
3693   }
3694   return \@rolled_array;
3695 }
3696
3697 sub _calculate_score {
3698   my ($self, $a, $b) = @_;
3699
3700   if (defined $a xor defined $b) {
3701     return 0;
3702   }
3703   elsif (not defined $a) {
3704     return 1;
3705   }
3706
3707   if (ref $b eq 'HASH') {
3708     my ($b_key) = keys %{$b};
3709     if (ref $a eq 'HASH') {
3710       my ($a_key) = keys %{$a};
3711       if ($a_key eq $b_key) {
3712         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3713       } else {
3714         return 0;
3715       }
3716     } else {
3717       return ($a eq $b_key) ? 1 : 0;
3718     }
3719   } else {
3720     if (ref $a eq 'HASH') {
3721       my ($a_key) = keys %{$a};
3722       return ($b eq $a_key) ? 1 : 0;
3723     } else {
3724       return ($b eq $a) ? 1 : 0;
3725     }
3726   }
3727 }
3728
3729 sub _merge_joinpref_attr {
3730   my ($self, $orig, $import) = @_;
3731
3732   return $import unless defined($orig);
3733   return $orig unless defined($import);
3734
3735   $orig = $self->_rollout_attr($orig);
3736   $import = $self->_rollout_attr($import);
3737
3738   my $seen_keys;
3739   foreach my $import_element ( @{$import} ) {
3740     # find best candidate from $orig to merge $b_element into
3741     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3742     foreach my $orig_element ( @{$orig} ) {
3743       my $score = $self->_calculate_score( $orig_element, $import_element );
3744       if ($score > $best_candidate->{score}) {
3745         $best_candidate->{position} = $position;
3746         $best_candidate->{score} = $score;
3747       }
3748       $position++;
3749     }
3750     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3751     $import_key = '' if not defined $import_key;
3752
3753     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3754       push( @{$orig}, $import_element );
3755     } else {
3756       my $orig_best = $orig->[$best_candidate->{position}];
3757       # merge orig_best and b_element together and replace original with merged
3758       if (ref $orig_best ne 'HASH') {
3759         $orig->[$best_candidate->{position}] = $import_element;
3760       } elsif (ref $import_element eq 'HASH') {
3761         my ($key) = keys %{$orig_best};
3762         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3763       }
3764     }
3765     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3766   }
3767
3768   return @$orig ? $orig : ();
3769 }
3770
3771 {
3772   my $hm;
3773
3774   sub _merge_attr {
3775     $hm ||= do {
3776       require Hash::Merge;
3777       my $hm = Hash::Merge->new;
3778
3779       $hm->specify_behavior({
3780         SCALAR => {
3781           SCALAR => sub {
3782             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3783
3784             if ($defl xor $defr) {
3785               return [ $defl ? $_[0] : $_[1] ];
3786             }
3787             elsif (! $defl) {
3788               return [];
3789             }
3790             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3791               return [ $_[0] ];
3792             }
3793             else {
3794               return [$_[0], $_[1]];
3795             }
3796           },
3797           ARRAY => sub {
3798             return $_[1] if !defined $_[0];
3799             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3800             return [$_[0], @{$_[1]}]
3801           },
3802           HASH  => sub {
3803             return [] if !defined $_[0] and !keys %{$_[1]};
3804             return [ $_[1] ] if !defined $_[0];
3805             return [ $_[0] ] if !keys %{$_[1]};
3806             return [$_[0], $_[1]]
3807           },
3808         },
3809         ARRAY => {
3810           SCALAR => sub {
3811             return $_[0] if !defined $_[1];
3812             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3813             return [@{$_[0]}, $_[1]]
3814           },
3815           ARRAY => sub {
3816             my @ret = @{$_[0]} or return $_[1];
3817             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3818             my %idx = map { $_ => 1 } @ret;
3819             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3820             \@ret;
3821           },
3822           HASH => sub {
3823             return [ $_[1] ] if ! @{$_[0]};
3824             return $_[0] if !keys %{$_[1]};
3825             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3826             return [ @{$_[0]}, $_[1] ];
3827           },
3828         },
3829         HASH => {
3830           SCALAR => sub {
3831             return [] if !keys %{$_[0]} and !defined $_[1];
3832             return [ $_[0] ] if !defined $_[1];
3833             return [ $_[1] ] if !keys %{$_[0]};
3834             return [$_[0], $_[1]]
3835           },
3836           ARRAY => sub {
3837             return [] if !keys %{$_[0]} and !@{$_[1]};
3838             return [ $_[0] ] if !@{$_[1]};
3839             return $_[1] if !keys %{$_[0]};
3840             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3841             return [ $_[0], @{$_[1]} ];
3842           },
3843           HASH => sub {
3844             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3845             return [ $_[0] ] if !keys %{$_[1]};
3846             return [ $_[1] ] if !keys %{$_[0]};
3847             return [ $_[0] ] if $_[0] eq $_[1];
3848             return [ $_[0], $_[1] ];
3849           },
3850         }
3851       } => 'DBIC_RS_ATTR_MERGER');
3852       $hm;
3853     };
3854
3855     return $hm->merge ($_[1], $_[2]);
3856   }
3857 }
3858
3859 sub STORABLE_freeze {
3860   my ($self, $cloning) = @_;
3861   my $to_serialize = { %$self };
3862
3863   # A cursor in progress can't be serialized (and would make little sense anyway)
3864   # the parser can be regenerated (and can't be serialized)
3865   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3866
3867   # nor is it sensical to store a not-yet-fired-count pager
3868   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3869     delete $to_serialize->{pager};
3870   }
3871
3872   Storable::nfreeze($to_serialize);
3873 }
3874
3875 # need this hook for symmetry
3876 sub STORABLE_thaw {
3877   my ($self, $cloning, $serialized) = @_;
3878
3879   %$self = %{ Storable::thaw($serialized) };
3880
3881   $self;
3882 }
3883
3884
3885 =head2 throw_exception
3886
3887 See L<DBIx::Class::Schema/throw_exception> for details.
3888
3889 =cut
3890
3891 sub throw_exception {
3892   my $self=shift;
3893
3894   if (ref $self and my $rsrc = $self->result_source) {
3895     $rsrc->throw_exception(@_)
3896   }
3897   else {
3898     DBIx::Class::Exception->throw(@_);
3899   }
3900 }
3901
3902 1;
3903
3904 __END__
3905
3906 # XXX: FIXME: Attributes docs need clearing up
3907
3908 =head1 ATTRIBUTES
3909
3910 Attributes are used to refine a ResultSet in various ways when
3911 searching for data. They can be passed to any method which takes an
3912 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3913 L</count>.
3914
3915 Default attributes can be set on the result class using
3916 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3917 the CAVEATS on that feature before using it!)
3918
3919 These are in no particular order:
3920
3921 =head2 order_by
3922
3923 =over 4
3924
3925 =item Value: ( $order_by | \@order_by | \%order_by )
3926
3927 =back
3928
3929 Which column(s) to order the results by.
3930
3931 [The full list of suitable values is documented in
3932 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3933 common options.]
3934
3935 If a single column name, or an arrayref of names is supplied, the
3936 argument is passed through directly to SQL. The hashref syntax allows
3937 for connection-agnostic specification of ordering direction:
3938
3939  For descending order:
3940
3941   order_by => { -desc => [qw/col1 col2 col3/] }
3942
3943  For explicit ascending order:
3944
3945   order_by => { -asc => 'col' }
3946
3947 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3948 supported, although you are strongly encouraged to use the hashref
3949 syntax as outlined above.
3950
3951 =head2 columns
3952
3953 =over 4
3954
3955 =item Value: \@columns | \%columns | $column
3956
3957 =back
3958
3959 Shortcut to request a particular set of columns to be retrieved. Each
3960 column spec may be a string (a table column name), or a hash (in which
3961 case the key is the C<as> value, and the value is used as the C<select>
3962 expression). Adds C<me.> onto the start of any column without a C<.> in
3963 it and sets C<select> from that, then auto-populates C<as> from
3964 C<select> as normal. (You may also use the C<cols> attribute, as in
3965 earlier versions of DBIC, but this is deprecated.)
3966
3967 Essentially C<columns> does the same as L</select> and L</as>.
3968
3969     columns => [ 'foo', { bar => 'baz' } ]
3970
3971 is the same as
3972
3973     select => [qw/foo baz/],
3974     as => [qw/foo bar/]
3975
3976 =head2 +columns
3977
3978 =over 4
3979
3980 =item Value: \@columns
3981
3982 =back
3983
3984 Indicates additional columns to be selected from storage. Works the same as
3985 L</columns> but adds columns to the selection. (You may also use the
3986 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3987 deprecated). For example:-
3988
3989   $schema->resultset('CD')->search(undef, {
3990     '+columns' => ['artist.name'],
3991     join => ['artist']
3992   });
3993
3994 would return all CDs and include a 'name' column to the information
3995 passed to object inflation. Note that the 'artist' is the name of the
3996 column (or relationship) accessor, and 'name' is the name of the column
3997 accessor in the related table.
3998
3999 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
4000 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
4001 unary plus operator before it.
4002
4003 =head2 include_columns
4004
4005 =over 4
4006
4007 =item Value: \@columns
4008
4009 =back
4010
4011 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
4012
4013 =head2 select
4014
4015 =over 4
4016
4017 =item Value: \@select_columns
4018
4019 =back
4020
4021 Indicates which columns should be selected from the storage. You can use
4022 column names, or in the case of RDBMS back ends, function or stored procedure
4023 names:
4024
4025   $rs = $schema->resultset('Employee')->search(undef, {
4026     select => [
4027       'name',
4028       { count => 'employeeid' },
4029       { max => { length => 'name' }, -as => 'longest_name' }
4030     ]
4031   });
4032
4033   # Equivalent SQL
4034   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4035
4036 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4037 use L</select>, to instruct DBIx::Class how to store the result of the column.
4038 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4039 identifier aliasing. You can however alias a function, so you can use it in
4040 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4041 attribute> supplied as shown in the example above.
4042
4043 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4044 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4045 unary plus operator before it.
4046
4047 =head2 +select
4048
4049 =over 4
4050
4051 Indicates additional columns to be selected from storage.  Works the same as
4052 L</select> but adds columns to the default selection, instead of specifying
4053 an explicit list.
4054
4055 =back
4056
4057 =head2 as
4058
4059 =over 4
4060
4061 =item Value: \@inflation_names
4062
4063 =back
4064
4065 Indicates column names for object inflation. That is L</as> indicates the
4066 slot name in which the column value will be stored within the
4067 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4068 identifier by the C<get_column> method (or via the object accessor B<if one
4069 with the same name already exists>) as shown below. The L</as> attribute has
4070 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4071
4072   $rs = $schema->resultset('Employee')->search(undef, {
4073     select => [
4074       'name',
4075       { count => 'employeeid' },
4076       { max => { length => 'name' }, -as => 'longest_name' }
4077     ],
4078     as => [qw/
4079       name
4080       employee_count
4081       max_name_length
4082     /],
4083   });
4084
4085 If the object against which the search is performed already has an accessor
4086 matching a column name specified in C<as>, the value can be retrieved using
4087 the accessor as normal:
4088
4089   my $name = $employee->name();
4090
4091 If on the other hand an accessor does not exist in the object, you need to
4092 use C<get_column> instead:
4093
4094   my $employee_count = $employee->get_column('employee_count');
4095
4096 You can create your own accessors if required - see
4097 L<DBIx::Class::Manual::Cookbook> for details.
4098
4099 =head2 +as
4100
4101 =over 4
4102
4103 Indicates additional column names for those added via L</+select>. See L</as>.
4104
4105 =back
4106
4107 =head2 join
4108
4109 =over 4
4110
4111 =item Value: ($rel_name | \@rel_names | \%rel_names)
4112
4113 =back
4114
4115 Contains a list of relationships that should be joined for this query.  For
4116 example:
4117
4118   # Get CDs by Nine Inch Nails
4119   my $rs = $schema->resultset('CD')->search(
4120     { 'artist.name' => 'Nine Inch Nails' },
4121     { join => 'artist' }
4122   );
4123
4124 Can also contain a hash reference to refer to the other relation's relations.
4125 For example:
4126
4127   package MyApp::Schema::Track;
4128   use base qw/DBIx::Class/;
4129   __PACKAGE__->table('track');
4130   __PACKAGE__->add_columns(qw/trackid cd position title/);
4131   __PACKAGE__->set_primary_key('trackid');
4132   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4133   1;
4134
4135   # In your application
4136   my $rs = $schema->resultset('Artist')->search(
4137     { 'track.title' => 'Teardrop' },
4138     {
4139       join     => { cd => 'track' },
4140       order_by => 'artist.name',
4141     }
4142   );
4143
4144 You need to use the relationship (not the table) name in  conditions,
4145 because they are aliased as such. The current table is aliased as "me", so
4146 you need to use me.column_name in order to avoid ambiguity. For example:
4147
4148   # Get CDs from 1984 with a 'Foo' track
4149   my $rs = $schema->resultset('CD')->search(
4150     {
4151       'me.year' => 1984,
4152       'tracks.name' => 'Foo'
4153     },
4154     { join => 'tracks' }
4155   );
4156
4157 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4158 similarly for a third time). For e.g.
4159
4160   my $rs = $schema->resultset('Artist')->search({
4161     'cds.title'   => 'Down to Earth',
4162     'cds_2.title' => 'Popular',
4163   }, {
4164     join => [ qw/cds cds/ ],
4165   });
4166
4167 will return a set of all artists that have both a cd with title 'Down
4168 to Earth' and a cd with title 'Popular'.
4169
4170 If you want to fetch related objects from other tables as well, see L</prefetch>
4171 below.
4172
4173  NOTE: An internal join-chain pruner will discard certain joins while
4174  constructing the actual SQL query, as long as the joins in question do not
4175  affect the retrieved result. This for example includes 1:1 left joins
4176  that are not part of the restriction specification (WHERE/HAVING) nor are
4177  a part of the query selection.
4178
4179 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4180
4181 =head2 collapse
4182
4183 =over 4
4184
4185 =item Value: (0 | 1)
4186
4187 =back
4188
4189 When set to a true value, indicates that any rows fetched from joined has_many
4190 relationships are to be aggregated into the corresponding "parent" object. For
4191 example, the resultset:
4192
4193   my $rs = $schema->resultset('CD')->search({}, {
4194     '+columns' => [ qw/ tracks.title tracks.position / ],
4195     join => 'tracks',
4196     collapse => 1,
4197   });
4198
4199 While executing the following query:
4200
4201   SELECT me.*, tracks.title, tracks.position
4202     FROM cd me
4203     LEFT JOIN track tracks
4204       ON tracks.cdid = me.cdid
4205
4206 Will return only as many objects as there are rows in the CD source, even
4207 though the result of the query may span many rows. Each of these CD objects
4208 will in turn have multiple "Track" objects hidden behind the has_many
4209 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4210 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4211 product"), with each CD object containing exactly one of all fetched Track data.
4212
4213 When a collapse is requested on a non-ordered resultset, an order by some
4214 unique part of the main source (the left-most table) is inserted automatically.
4215 This is done so that the resultset is allowed to be "lazy" - calling
4216 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4217 object with all of its related data.
4218
4219 If an L</order_by> is already declared, and orders the resultset in a way that
4220 makes collapsing as described above impossible (e.g. C<< ORDER BY
4221 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4222 switch to "eager" mode and slurp the entire resultset before constructing the
4223 first object returned by L</next>.
4224
4225 Setting this attribute on a resultset that does not join any has_many
4226 relations is a no-op.
4227
4228 For a more in-depth discussion, see L</PREFETCHING>.
4229
4230 =head2 prefetch
4231
4232 =over 4
4233
4234 =item Value: ($rel_name | \@rel_names | \%rel_names)
4235
4236 =back
4237
4238 This attribute is a shorthand for specifying a L</join> spec, adding all
4239 columns from the joined related sources as L</+columns> and setting
4240 L</collapse> to a true value. For example, the following two queries are
4241 equivalent:
4242
4243   my $rs = $schema->resultset('Artist')->search({}, {
4244     prefetch => { cds => ['genre', 'tracks' ] },
4245   });
4246
4247 and
4248
4249   my $rs = $schema->resultset('Artist')->search({}, {
4250     join => { cds => ['genre', 'tracks' ] },
4251     collapse => 1,
4252     '+columns' => [
4253       (map
4254         { +{ "cds.$_" => "cds.$_" } }
4255         $schema->source('Artist')->related_source('cds')->columns
4256       ),
4257       (map
4258         { +{ "cds.genre.$_" => "genre.$_" } }
4259         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4260       ),
4261       (map
4262         { +{ "cds.tracks.$_" => "tracks.$_" } }
4263         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4264       ),
4265     ],
4266   });
4267
4268 Both producing the following SQL:
4269
4270   SELECT  me.artistid, me.name, me.rank, me.charfield,
4271           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4272           genre.genreid, genre.name,
4273           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4274     FROM artist me
4275     LEFT JOIN cd cds
4276       ON cds.artist = me.artistid
4277     LEFT JOIN genre genre
4278       ON genre.genreid = cds.genreid
4279     LEFT JOIN track tracks
4280       ON tracks.cd = cds.cdid
4281   ORDER BY me.artistid
4282
4283 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4284 the arguments are properly merged and generally do the right thing. For
4285 example, you may want to do the following:
4286
4287   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4288     { 'genre.genreid' => undef },
4289     {
4290       join => { cds => 'genre' },
4291       prefetch => 'cds',
4292     }
4293   );
4294
4295 Which generates the following SQL:
4296
4297   SELECT  me.artistid, me.name, me.rank, me.charfield,
4298           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4299     FROM artist me
4300     LEFT JOIN cd cds
4301       ON cds.artist = me.artistid
4302     LEFT JOIN genre genre
4303       ON genre.genreid = cds.genreid
4304   WHERE genre.genreid IS NULL
4305   ORDER BY me.artistid
4306
4307 For a more in-depth discussion, see L</PREFETCHING>.
4308
4309 =head2 alias
4310
4311 =over 4
4312
4313 =item Value: $source_alias
4314
4315 =back
4316
4317 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4318 nested search queries (sub-SELECTs) might need specific aliases set to
4319 reference inner queries.  For example:
4320
4321    my $q = $rs
4322       ->related_resultset('CDs')
4323       ->related_resultset('Tracks')
4324       ->search({
4325          'track.id' => { -ident => 'none_search.id' },
4326       })
4327       ->as_query;
4328
4329    my $ids = $self->search({
4330       -not_exists => $q,
4331    }, {
4332       alias    => 'none_search',
4333       group_by => 'none_search.id',
4334    })->get_column('id')->as_query;
4335
4336    $self->search({ id => { -in => $ids } })
4337
4338 This attribute is directly tied to L</current_source_alias>.
4339
4340 =head2 page
4341
4342 =over 4
4343
4344 =item Value: $page
4345
4346 =back
4347
4348 Makes the resultset paged and specifies the page to retrieve. Effectively
4349 identical to creating a non-pages resultset and then calling ->page($page)
4350 on it.
4351
4352 If L</rows> attribute is not specified it defaults to 10 rows per page.
4353
4354 When you have a paged resultset, L</count> will only return the number
4355 of rows in the page. To get the total, use the L</pager> and call
4356 C<total_entries> on it.
4357
4358 =head2 rows
4359
4360 =over 4
4361
4362 =item Value: $rows
4363
4364 =back
4365
4366 Specifies the maximum number of rows for direct retrieval or the number of
4367 rows per page if the page attribute or method is used.
4368
4369 =head2 offset
4370
4371 =over 4
4372
4373 =item Value: $offset
4374
4375 =back
4376
4377 Specifies the (zero-based) row number for the  first row to be returned, or the
4378 of the first row of the first page if paging is used.
4379
4380 =head2 software_limit
4381
4382 =over 4
4383
4384 =item Value: (0 | 1)
4385
4386 =back
4387
4388 When combined with L</rows> and/or L</offset> the generated SQL will not
4389 include any limit dialect stanzas. Instead the entire result will be selected
4390 as if no limits were specified, and DBIC will perform the limit locally, by
4391 artificially advancing and finishing the resulting L</cursor>.
4392
4393 This is the recommended way of performing resultset limiting when no sane RDBMS
4394 implementation is available (e.g.
4395 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4396 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4397
4398 =head2 group_by
4399
4400 =over 4
4401
4402 =item Value: \@columns
4403
4404 =back
4405
4406 A arrayref of columns to group by. Can include columns of joined tables.
4407
4408   group_by => [qw/ column1 column2 ... /]
4409
4410 =head2 having
4411
4412 =over 4
4413
4414 =item Value: $condition
4415
4416 =back
4417
4418 HAVING is a select statement attribute that is applied between GROUP BY and
4419 ORDER BY. It is applied to the after the grouping calculations have been
4420 done.
4421
4422   having => { 'count_employee' => { '>=', 100 } }
4423
4424 or with an in-place function in which case literal SQL is required:
4425
4426   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4427
4428 =head2 distinct
4429
4430 =over 4
4431
4432 =item Value: (0 | 1)
4433
4434 =back
4435
4436 Set to 1 to group by all columns. If the resultset already has a group_by
4437 attribute, this setting is ignored and an appropriate warning is issued.
4438
4439 =head2 where
4440
4441 =over 4
4442
4443 Adds to the WHERE clause.
4444
4445   # only return rows WHERE deleted IS NULL for all searches
4446   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4447
4448 Can be overridden by passing C<< { where => undef } >> as an attribute
4449 to a resultset.
4450
4451 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4452
4453 =back
4454
4455 =head2 cache
4456
4457 Set to 1 to cache search results. This prevents extra SQL queries if you
4458 revisit rows in your ResultSet:
4459
4460   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4461
4462   while( my $artist = $resultset->next ) {
4463     ... do stuff ...
4464   }
4465
4466   $rs->first; # without cache, this would issue a query
4467
4468 By default, searches are not cached.
4469
4470 For more examples of using these attributes, see
4471 L<DBIx::Class::Manual::Cookbook>.
4472
4473 =head2 for
4474
4475 =over 4
4476
4477 =item Value: ( 'update' | 'shared' | \$scalar )
4478
4479 =back
4480
4481 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4482 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4483 query.
4484
4485 =head1 PREFETCHING
4486
4487 DBIx::Class supports arbitrary related data prefetching from multiple related
4488 sources. Any combination of relationship types and column sets are supported.
4489 If L<collapsing|/collapse> is requested, there is an additional requirement of
4490 selecting enough data to make every individual object uniquely identifiable.
4491
4492 Here are some more involved examples, based on the following relationship map:
4493
4494   # Assuming:
4495   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4496   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4497   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4498
4499   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4500
4501   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4502
4503
4504
4505   my $rs = $schema->resultset('Tag')->search(
4506     undef,
4507     {
4508       prefetch => {
4509         cd => 'artist'
4510       }
4511     }
4512   );
4513
4514 The initial search results in SQL like the following:
4515
4516   SELECT tag.*, cd.*, artist.* FROM tag
4517   JOIN cd ON tag.cd = cd.cdid
4518   JOIN artist ON cd.artist = artist.artistid
4519
4520 L<DBIx::Class> has no need to go back to the database when we access the
4521 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4522 case.
4523
4524 Simple prefetches will be joined automatically, so there is no need
4525 for a C<join> attribute in the above search.
4526
4527 The L</prefetch> attribute can be used with any of the relationship types
4528 and multiple prefetches can be specified together. Below is a more complex
4529 example that prefetches a CD's artist, its liner notes (if present),
4530 the cover image, the tracks on that CD, and the guests on those
4531 tracks.
4532
4533   my $rs = $schema->resultset('CD')->search(
4534     undef,
4535     {
4536       prefetch => [
4537         { artist => 'record_label'},  # belongs_to => belongs_to
4538         'liner_note',                 # might_have
4539         'cover_image',                # has_one
4540         { tracks => 'guests' },       # has_many => has_many
4541       ]
4542     }
4543   );
4544
4545 This will produce SQL like the following:
4546
4547   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4548          tracks.*, guests.*
4549     FROM cd me
4550     JOIN artist artist
4551       ON artist.artistid = me.artistid
4552     JOIN record_label record_label
4553       ON record_label.labelid = artist.labelid
4554     LEFT JOIN track tracks
4555       ON tracks.cdid = me.cdid
4556     LEFT JOIN guest guests
4557       ON guests.trackid = track.trackid
4558     LEFT JOIN liner_notes liner_note
4559       ON liner_note.cdid = me.cdid
4560     JOIN cd_artwork cover_image
4561       ON cover_image.cdid = me.cdid
4562   ORDER BY tracks.cd
4563
4564 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4565 C<tracks>, and C<guests> of the CD will all be available through the
4566 relationship accessors without the need for additional queries to the
4567 database.
4568
4569 =head3 CAVEATS
4570
4571 Prefetch does a lot of deep magic. As such, it may not behave exactly
4572 as you might expect.
4573
4574 =over 4
4575
4576 =item *
4577
4578 Prefetch uses the L</cache> to populate the prefetched relationships. This
4579 may or may not be what you want.
4580
4581 =item *
4582
4583 If you specify a condition on a prefetched relationship, ONLY those
4584 rows that match the prefetched condition will be fetched into that relationship.
4585 This means that adding prefetch to a search() B<may alter> what is returned by
4586 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4587
4588   my $artist_rs = $schema->resultset('Artist')->search({
4589       'cds.year' => 2008,
4590   }, {
4591       join => 'cds',
4592   });
4593
4594   my $count = $artist_rs->first->cds->count;
4595
4596   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4597
4598   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4599
4600   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4601
4602 That cmp_ok() may or may not pass depending on the datasets involved. In other
4603 words the C<WHERE> condition would apply to the entire dataset, just like
4604 it would in regular SQL. If you want to add a condition only to the "right side"
4605 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4606 condition|DBIx::Class::Relationship::Base/condition>
4607
4608 =back
4609
4610 =head1 DBIC BIND VALUES
4611
4612 Because DBIC may need more information to bind values than just the column name
4613 and value itself, it uses a special format for both passing and receiving bind
4614 values.  Each bind value should be composed of an arrayref of
4615 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4616
4617 =over 4
4618
4619 =item dbd_attrs
4620
4621 If present (in any form), this is what is being passed directly to bind_param.
4622 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4623 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4624
4625 If this is specified, all other bind options described below are ignored.
4626
4627 =item sqlt_datatype
4628
4629 If present, this is used to infer the actual bind attribute by passing to
4630 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4631 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4632
4633 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4634 currently drivers are expected to "Do the Right Thing" when given a common
4635 datatype name.  (Not ideal, but that's what we got at this point.)
4636
4637 =item sqlt_size
4638
4639 Currently used to correctly allocate buffers for bind_param_inout().
4640 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4641 or to a sensible value based on the "data_type".
4642
4643 =item dbic_colname
4644
4645 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4646 explicitly specified they are never overridden).  Also used by some weird DBDs,
4647 where the column name should be available at bind_param time (e.g. Oracle).
4648
4649 =back
4650
4651 For backwards compatibility and convenience, the following shortcuts are
4652 supported:
4653
4654   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4655   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4656   [ undef,   $val ] === [ {}, $val ]
4657   $val              === [ {}, $val ]
4658
4659 =head1 AUTHOR AND CONTRIBUTORS
4660
4661 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4662
4663 =head1 LICENSE
4664
4665 You may distribute this code under the same terms as Perl itself.
4666