Makefile.PL

   1 use inc::Module::Install 1.00;
   2 use strict;
   3 use warnings;
   4
   5 use 5.008001;
   6
   7 use FindBin;
   8 use lib "$FindBin::Bin/lib";
   9 use DBIx::Class::Optional::Dependencies;
  10
  11 # adjust ENV for $AUTHOR system() calls
  12 use Config;
  13 $ENV{PERL5LIB} = join ($Config{path_sep}, @INC);
  14
  15 use Getopt::Long ();
  16
  17 my $getopt = Getopt::Long::Parser->new(
  18   config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
  19 );
  20 my $args = {
  21   skip_author_deps => undef,
  22 };
  23 $getopt->getoptions($args, 'skip_author_deps');
  24 if (@ARGV) {
  25   warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
  26 }
  27
  28 # get cpanX --installdeps . to behave in a checkout (most users do not need
  29 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  30 # for that)
  31 ##
  32 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  33 ##
  34 $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  35
  36 ###
  37 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  38 ### All of them should go to DBIx::Class::Optional::Dependencies
  39 ###
  40
  41 name     'DBIx-Class';
  42 perl_version '5.008001';
  43 all_from 'lib/DBIx/Class.pm';
  44
  45 my $build_requires = {
  46   # needed for testing only, not for operation
  47   'DBD::SQLite'              => '1.29',
  48 };
  49
  50 my $test_requires = {
  51   'File::Temp'               => '0.22',
  52   'Test::Builder'            => '0.33',
  53   'Test::Exception'          => '0.31',
  54   'Test::More'               => '0.92',
  55   'Test::Warn'               => '0.21',
  56 };
  57
  58 my $runtime_requires = {
  59   'Carp::Clan'               => '6.0',
  60   'Class::Accessor::Grouped' => '0.10000',
  61   'Class::C3::Componentised' => '1.0005',
  62   'Class::Inspector'         => '1.24',
  63   'Config::Any'              => '0.20',
  64   'Context::Preserve'        => '0.01',
  65   'Data::Dumper::Concise'    => '1.000',
  66   'Data::Page'               => '2.00',
  67   'MRO::Compat'              => '0.09',
  68   'Module::Find'             => '0.06',
  69   'Path::Class'              => '0.18',
  70   'Scope::Guard'             => '0.03',
  71   'SQL::Abstract'            => '1.72',
  72   'Try::Tiny'                => '0.04',
  73
  74   # XS (or XS-dependent) libs
  75   'DBI'                      => '1.609',
  76   'namespace::clean'         => '0.14',
  77   'Sub::Name'                => '0.04',
  78   'Variable::Magic'          => '0.44',
  79
  80   # dual-life corelibs needing a specific bugfixed version
  81   'File::Path'               => '2.07',
  82 };
  83
  84 # this is so we can order requires alphabetically
  85 # copies are needed for author requires injection
  86 my $reqs = {
  87   build_requires => { %$build_requires },
  88   requires => { %$runtime_requires },
  89   test_requires => { %$test_requires },
  90 };
  91
  92 my %reqs_for_group = %{DBIx::Class::Optional::Dependencies->req_group_list};
  93
  94 # exclude the rdbms_* groups which are for DBIC users
  95 my $opt_testdeps = {
  96   map { %{$reqs_for_group{$_}} } grep { !/^rdbms_/ } keys %reqs_for_group
  97 };
  98
  99 # require extra modules for testing if we're in a checkout
 100 my $optdep_msg;
 101 if ($Module::Install::AUTHOR) {
 102   if ($args->{skip_author_deps}) {
 103     $optdep_msg = <<'EOW';
 104
 105 ******************************************************************************
 106 ******************************************************************************
 107 ***                                                                        ***
 108 *** IGNORING AUTHOR MODE: no optional test dependencies will be forced.    ***
 109 ***                                                                        ***
 110 *** If you are using this checkout with the intention of submitting a DBIC ***
 111 *** patch, you are *STRONGLY ENCOURAGED* to install all dependencies, so   ***
 112 *** that every possible unit-test will run.                                ***
 113 ***                                                                        ***
 114 ******************************************************************************
 115 ******************************************************************************
 116
 117 EOW
 118   }
 119   else {
 120     $optdep_msg = <<'EOW';
 121
 122 ******************************************************************************
 123 ******************************************************************************
 124 ***                                                                        ***
 125 *** AUTHOR MODE: all optional test dependencies converted to hard requires ***
 126 ***       ( to disable re-run Makefile.PL with --skip_author_deps )        ***
 127 ***                                                                        ***
 128 ******************************************************************************
 129 ******************************************************************************
 130
 131 EOW
 132
 133     $reqs->{test_requires} = {
 134       %{$reqs->{test_requires}},
 135       %$opt_testdeps
 136     };
 137   }
 138 }
 139
 140 # compose final req list, for alphabetical ordering
 141 my %final_req;
 142 for my $rtype (keys %$reqs) {
 143   for my $mod (keys %{$reqs->{$rtype}} ) {
 144
 145     # sanity check req duplications
 146     if ($final_req{$mod}) {
 147       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 148     }
 149
 150     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 151   }
 152 }
 153
 154 # actual require
 155 for my $mod (sort keys %final_req) {
 156   my ($rtype, $ver) = @{$final_req{$mod}};
 157   no strict 'refs';
 158   $rtype->($mod, $ver);
 159 }
 160
 161 # output twice since the deplist is > 70 lines
 162 warn $optdep_msg if $Module::Install::AUTHOR;
 163 auto_install();
 164 warn $optdep_msg if $Module::Install::AUTHOR;
 165
 166 # re-create various autogenerated documentation bits
 167 if ($Module::Install::AUTHOR) {
 168
 169   print "Regenerating README\n";
 170   system('pod2text lib/DBIx/Class.pm > README');
 171
 172   if (-f 'MANIFEST') {
 173     print "Removing MANIFEST\n";
 174     unlink 'MANIFEST';
 175   }
 176
 177   print "Regenerating Optional/Dependencies.pod\n";
 178   require DBIx::Class::Optional::Dependencies;
 179   DBIx::Class::Optional::Dependencies->_gen_pod (Meta->version);
 180
 181   # FIXME Disabled due to unsolved issues, ask theorbtwo
 182   #  require Module::Install::Pod::Inherit;
 183   #  PodInherit();
 184 }
 185
 186
 187 tests_recursive (qw|
 188     t
 189 |);
 190
 191 # temporary(?) until I get around to fix M::I wrt xt/
 192 # needs Module::Install::AuthorTests
 193 eval {
 194   recursive_author_tests (qw/xt/);
 195   1;
 196 } || do {
 197   if ($Module::Install::AUTHOR && ! $args->{skip_author_deps}) {
 198     my $err = $@;
 199     eval { require Module::Install::AuthorTests }
 200       || die "\nYou need Module::Install::AuthorTests installed to run this Makefile.PL in author mode (or supply --skip_author_deps):\n\n$@\n";
 201     die $@;
 202   }
 203 };
 204
 205
 206 install_script (qw|
 207     script/dbicadmin
 208 |);
 209
 210
 211 ### Mangle makefile - read the comments for more info
 212 #
 213 postamble <<"EOP";
 214
 215 # This will add an extra dep-spec for the distdir target,
 216 # which `make` will fold together in a first-come first-serve
 217 # fashion. What we do here is essentially adding extra
 218 # commands to execute once the distdir is assembled (via
 219 # create_distdir), but before control is returned to a higher
 220 # calling rule.
 221 distdir : dbicadmin_pod_inject
 222
 223 # The pod self-injection code is in fact a hidden option in
 224 # dbicadmin itself
 225 dbicadmin_pod_inject :
 226 \tcd \$(DISTVNAME) && \$(ABSPERL) -Ilib script/dbicadmin --selfinject-pod
 227
 228 # Regenerate manifest before running create_distdir.
 229 create_distdir : manifest
 230
 231 EOP
 232
 233 homepage 'http://www.dbix-class.org/';
 234 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
 235 resources 'license'     => 'http://dev.perl.org/licenses/';
 236 resources 'repository'  => 'git://git.shadowcat.co.uk/dbsrgits/DBIx-Class.git';
 237 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
 238 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
 239
 240 # Deprecated/internal modules need no exposure
 241 no_index directory => $_ for (qw|
 242   lib/DBIx/Class/Admin
 243   lib/DBIx/Class/PK/Auto
 244   lib/DBIx/Class/CDBICompat
 245 |);
 246 no_index package => $_ for (qw/
 247   DBIx::Class::Storage::DBIHacks
 248 /);
 249
 250 WriteAll();
 251
 252 # Re-write META.yml to _exclude_ all forced build-requires (we do not want to ship
 253 # this) We are also not using M::I::AuthorRequires as this will be an extra dep,
 254 # and deps in Makefile.PL still suck
 255 # Also always test the result so we stop shipping borked dependency lists to CPAN
 256
 257 # FIXME test_requires is not yet part of META
 258 my %original_build_requires = ( %$build_requires, %$test_requires );
 259 my @all_build_requires = @{delete Meta->{values}{build_requires}};
 260 my %removed_build_requires;
 261
 262 for (@all_build_requires) {
 263   if ($original_build_requires{$_->[0]}) {
 264     push @{Meta->{values}{build_requires}}, $_;
 265   }
 266   else {
 267     $removed_build_requires{$_->[0]} = $_->[1]
 268       unless $_->[0] eq 'ExtUtils::MakeMaker';
 269   }
 270 }
 271
 272 # Rewrite only in author mode, the original META should not contain anything anyway
 273 # if we executed as non-author
 274 if ($Module::Install::AUTHOR && keys %removed_build_requires) {
 275   print "Regenerating META with author requires excluded\n";
 276   Meta->write;
 277 }
 278
 279 # test that we really took things away (just in case, happened twice somehow)
 280 exit 0 unless -f 'META.yml';  # in case bizarro comes around
 281 my $meta = do { local @ARGV = 'META.yml'; local $/; <> };
 282
 283 # this is safe as there is a fatal check earlier to make sure $opt_testdeps does
 284 # not contain any real dependencies
 285 my @illegal_leftovers = grep
 286   { $meta =~ /^ \s+ \Q$_\E \: \s+ /mx }
 287   ( sort keys %$opt_testdeps )
 288 ;
 289
 290 if (@illegal_leftovers) {
 291   die join ("\n",
 292     "\n\nFATAL FAIL! It looks like some author dependencies made it to the META.yml:\n",
 293     map { "\t$_" } @illegal_leftovers
 294   ) . "\n\n";
 295 }