t/lib/dbixcsl_dumper_tests.pm

   1 package dbixcsl_dumper_tests;
   2
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use File::Path;
   7 use IPC::Open3;
   8 use IO::Handle;
   9 use List::Util 'any';
  10 use DBIx::Class::Schema::Loader::Utils 'dumper_squashed';
  11 use DBIx::Class::Schema::Loader ();
  12 use Class::Unload ();
  13 use namespace::clean;
  14
  15 use dbixcsl_test_dir '$tdir';
  16
  17 my $DUMP_PATH = "$tdir/dump";
  18
  19 sub cleanup {
  20     rmtree($DUMP_PATH, 1, 1);
  21 }
  22
  23 sub class_file {
  24     my ($self, $class) = @_;
  25
  26     $class =~ s{::}{/}g;
  27     $class = $DUMP_PATH . '/' . $class . '.pm';
  28
  29     return $class;
  30 }
  31
  32 sub append_to_class {
  33     my ($self, $class, $string) = @_;
  34
  35     $class = $self->class_file($class);
  36
  37     open(my $appendfh, '>>', $class) or die "Failed to open '$class' for append: $!";
  38
  39     print $appendfh $string;
  40
  41     close($appendfh);
  42 }
  43
  44 sub dump_test {
  45     my ($self, %tdata) = @_;
  46
  47
  48     $tdata{options}{dump_directory} = $DUMP_PATH;
  49     $tdata{options}{use_namespaces} ||= 0;
  50
  51     SKIP: for my $dumper (\&_dump_directly, \&_dump_dbicdump) {
  52         skip 'skipping dbicdump tests on Win32', 1,
  53             if $dumper == \&_dump_dbicdump && $^O eq 'MSWin32';
  54
  55         _test_dumps(\%tdata, $dumper->(%tdata));
  56     }
  57 }
  58
  59
  60 sub _dump_directly {
  61     my %tdata = @_;
  62
  63     my $schema_class = $tdata{classname};
  64
  65     no strict 'refs';
  66     @{$schema_class . '::ISA'} = ('DBIx::Class::Schema::Loader');
  67     $schema_class->loader_options(
  68         quiet => 1,
  69         %{$tdata{options}},
  70     );
  71
  72     my @warns;
  73     eval {
  74         local $SIG{__WARN__} = sub { push(@warns, @_) };
  75         $schema_class->connect(_get_connect_info(\%tdata));
  76     };
  77     my $err = $@;
  78
  79     my $classes = !$err && $schema_class->loader->generated_classes;
  80
  81     Class::Unload->unload($schema_class);
  82
  83     _check_error($err, $tdata{error});
  84
  85     return \@warns, $classes;
  86 }
  87
  88 sub _dump_dbicdump {
  89     my %tdata = @_;
  90
  91     # use $^X so we execute ./script/dbicdump with the same perl binary that the tests were executed with
  92     my @cmd = ($^X, qw(script/dbicdump));
  93
  94     $tdata{options}{quiet} = 1 unless exists $tdata{options}{quiet};
  95
  96     while (my ($opt, $val) = each(%{ $tdata{options} })) {
  97         $val = dumper_squashed $val if ref $val;
  98
  99         my $param = "$opt=$val";
 100
 101         if ($^O eq 'MSWin32') {
 102             $param = q{"} . $param . q{"}; # that's not nearly enough...
 103         }
 104
 105         push @cmd, '-o', $param;
 106     }
 107
 108     my @connect_info = _get_connect_info(\%tdata);
 109
 110     for my $info (@connect_info) {
 111         $info = dumper_squashed $info if ref $info;
 112     }
 113
 114     push @cmd, $tdata{classname}, @connect_info;
 115
 116     # make sure our current @INC gets used by dbicdump
 117     use Config;
 118     local $ENV{PERL5LIB} = join $Config{path_sep}, @INC, ($ENV{PERL5LIB} || '');
 119
 120     my $std = { map { $_ => IO::Handle->new } (qw/in out err/) };
 121     my $pid = open3(@{$std}{qw/in out err/}, @cmd);
 122
 123     waitpid($pid, 0);
 124
 125     my @stdout = $std->{out}->getlines;
 126     ok (!scalar @stdout, 'Silence on STDOUT');
 127
 128     my @warnings = $std->{err}->getlines;
 129     if ($? >> 8 != 0) {
 130         my $exception = pop @warnings;
 131         _check_error($exception, $tdata{error});
 132     }
 133
 134     return \@warnings;
 135 }
 136
 137 sub _get_connect_info {
 138     my $opts = shift;
 139
 140     my $test_db_class = $opts->{test_db_class} || 'make_dbictest_db';
 141
 142     eval "require $test_db_class;";
 143     die $@ if $@;
 144
 145     my $dsn = do {
 146         no strict 'refs';
 147         ${$test_db_class . '::dsn'};
 148     };
 149
 150     return ($dsn, @{ $opts->{extra_connect_info} || [] });
 151 }
 152
 153 sub _check_error {
 154     my ($got, $expected) = @_;
 155
 156     return unless $got;
 157
 158     if (not $expected) {
 159         fail "Unexpected error in " . ((caller(1))[3]) . ": $got";
 160         return;
 161     }
 162
 163     if (ref $expected eq 'Regexp') {
 164         like $got, $expected, 'error matches expected pattern';
 165         return;
 166     }
 167
 168     is $got, $expected, 'error matches';
 169 }
 170
 171 sub _test_dumps {
 172     my ($tdata, $warns, $classes) = @_;
 173
 174     my %tdata = %{$tdata};
 175
 176     my $schema_class = $tdata{classname};
 177     my $check_warns = $tdata{warnings};
 178
 179     is(@$warns, @$check_warns, "$schema_class warning count")
 180         or diag @$warns;
 181
 182     for(my $i = 0; $i <= $#$check_warns; $i++) {
 183         like(($warns->[$i] || ''), $check_warns->[$i], "$schema_class warning $i");
 184     }
 185
 186     if ($classes && (my $results = $tdata{generated_results})) {
 187         my $ns = $tdata{options}{use_namespaces} ? ("::".($tdata{result_namespace} || "Result")) : "";
 188         is_deeply(
 189             [ sort grep { $_ ne $schema_class } @$classes ],
 190             [ sort map { "${schema_class}${ns}::$_" } @$results ],
 191             "$schema_class generated_classes set correctly",
 192         );
 193     }
 194
 195     my $file_regexes = $tdata{regexes};
 196     my $file_neg_regexes = $tdata{neg_regexes} || {};
 197     my $schema_regexes = delete $file_regexes->{schema};
 198
 199     my $schema_path = $DUMP_PATH . '/' . $schema_class;
 200     $schema_path =~ s{::}{/}g;
 201
 202     _dump_file_like($schema_path . '.pm', @$schema_regexes) if $schema_regexes;
 203
 204     foreach my $src (keys %$file_regexes) {
 205         my $src_file = $schema_path . '/' . $src . '.pm';
 206         _dump_file_like($src_file, @{$file_regexes->{$src}});
 207     }
 208     foreach my $src (keys %$file_neg_regexes) {
 209         my $src_file = $schema_path . '/' . $src . '.pm';
 210         _dump_file_not_like($src_file, @{$file_neg_regexes->{$src}});
 211     }
 212 }
 213
 214 sub _slurp {
 215     my $path = shift;
 216     open(my $dumpfh, '<:raw', $path) or die "Failed to open '$path': $!";
 217     my $contents = do { local $/; <$dumpfh>; };
 218     close($dumpfh);
 219     return ($path, $contents);
 220 }
 221
 222 sub _dump_file_like {
 223     my ($path, $contents) = _slurp shift;
 224     like($contents, $_, "$path matches $_") for @_;
 225 }
 226
 227 sub _dump_file_not_like {
 228     my ($path, $contents) = _slurp shift;
 229     unlike($contents, $_, "$path does not match $_") for @_;
 230 }
 231
 232 END {
 233     __PACKAGE__->cleanup unless $ENV{SCHEMA_LOADER_TESTS_NOCLEANUP}
 234 }