t/lib/dbixcsl_common_tests.pm

   1 package dbixcsl_common_tests;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use DBIx::Class::Schema::Loader;
   8 use DBI;
   9
  10 sub new {
  11     my $class = shift;
  12
  13     my $self;
  14
  15     if( ref($_[0]) eq 'HASH') {
  16        my $args = shift;
  17        $self = { (%$args) };
  18     }
  19     else {
  20        $self = { @_ };
  21     }
  22
  23     # Only MySQL uses this
  24     $self->{innodb} ||= '';
  25
  26     $self->{verbose} = $ENV{TEST_VERBOSE} || 0;
  27
  28     return bless $self => $class;
  29 }
  30
  31 sub skip_tests {
  32     my ($self, $why) = @_;
  33
  34     plan skip_all => $why;
  35 }
  36
  37 sub _monikerize {
  38     my $name = shift;
  39     return 'LoaderTest2X' if $name =~ /^loader_test2$/i;
  40     return undef;
  41 }
  42
  43 sub run_tests {
  44     my $self = shift;
  45
  46     plan tests => 54;
  47
  48     $self->create();
  49
  50     my $schema_class = 'DBIXCSL_Test::Schema';
  51
  52     my $debug = ($self->{verbose} > 1) ? 1 : 0;
  53
  54     my %loader_opts = (
  55         connect_info            => [ $self->{dsn}, $self->{user},
  56                                      $self->{password} ],
  57         constraint              => '^(?:\S+\.)?(?i:loader_test)[0-9]+$',
  58         relationships           => 1,
  59         additional_classes      => 'TestAdditional',
  60         additional_base_classes => 'TestAdditionalBase',
  61         left_base_classes       => [ qw/TestLeftBase/ ],
  62         components              => [ qw/TestComponent/ ],
  63         resultset_components    => [ qw/TestRSComponent/ ],
  64         inflect_map             => { loader_test4 => 'loader_test4zes' },
  65         moniker_map             => \&_monikerize,
  66         debug                   => $debug,
  67     );
  68
  69     $loader_opts{db_schema} = $self->{db_schema} if $self->{db_schema};
  70     $loader_opts{drop_db_schema} = $self->{drop_db_schema} if $self->{drop_db_schema};
  71
  72     eval qq{
  73         package $schema_class;
  74         use base qw/DBIx::Class::Schema::Loader/;
  75
  76         __PACKAGE__->load_from_connection(\%loader_opts);
  77     };
  78     ok(!$@, "Loader initialization") or diag $@;
  79
  80     my $conn = $schema_class->connect($self->{dsn},$self->{user},$self->{password});
  81     my $monikers = $schema_class->loader->monikers;
  82     my $classes = $schema_class->loader->classes;
  83
  84     my $moniker1 = $monikers->{loader_test1};
  85     my $class1   = $classes->{loader_test1};
  86     my $rsobj1   = $conn->resultset($moniker1);
  87
  88     my $moniker2 = $monikers->{loader_test2};
  89     my $class2   = $classes->{loader_test2};
  90     my $rsobj2   = $conn->resultset($moniker2);
  91
  92     isa_ok( $rsobj1, "DBIx::Class::ResultSet" );
  93     isa_ok( $rsobj2, "DBIx::Class::ResultSet" );
  94
  95     is($moniker2, 'LoaderTest2X', "moniker_map testing");
  96
  97     {
  98         my ($skip_tab, $skip_tabo, $skip_taba, $skip_cmeth,
  99             $skip_rsmeth, $skip_tcomp, $skip_trscomp);
 100
 101         can_ok( $class1, 'test_additional_base' ) or $skip_tab = 1;
 102         can_ok( $class1, 'test_additional_base_override' ) or $skip_tabo = 1;
 103         can_ok( $class1, 'test_additional_base_additional' ) or $skip_taba = 1;
 104         can_ok( $class1, 'dbix_class_testcomponent' ) or $skip_tcomp = 1;
 105         can_ok( $rsobj1, 'dbix_class_testrscomponent' ) or $skip_trscomp = 1;
 106         can_ok( $class1, 'loader_test1_classmeth' ) or $skip_cmeth = 1;
 107
 108         TODO: {
 109             local $TODO = "Not yet supported by ResultSetManger code";
 110             can_ok( $rsobj1, 'loader_test1_rsmeth' ) or $skip_rsmeth = 1;
 111         }
 112
 113         SKIP: {
 114             skip "Pre-requisite test failed", 1 if $skip_tab;
 115             is( $class1->test_additional_base, "test_additional_base",
 116                 "Additional Base method" );
 117         }
 118
 119         SKIP: {
 120             skip "Pre-requisite test failed", 1 if $skip_tabo;
 121             is( $class1->test_additional_base_override,
 122                 "test_left_base_override",
 123                 "Left Base overrides Additional Base method" );
 124         }
 125
 126         SKIP: {
 127             skip "Pre-requisite test failed", 1 if $skip_taba;
 128             is( $class1->test_additional_base_additional, "test_additional",
 129                 "Additional Base can use Additional package method" );
 130         }
 131
 132         SKIP: {
 133             skip "Pre-requisite test failed", 1 if $skip_tcomp;
 134             is( $class1->dbix_class_testcomponent,
 135                 'dbix_class_testcomponent works' );
 136         }
 137
 138         SKIP: {
 139             skip "Pre-requisite test failed", 1 if $skip_trscomp;
 140             is( $rsobj1->dbix_class_testrscomponent,
 141                 'dbix_class_testrscomponent works' );
 142         }
 143
 144         SKIP: {
 145             skip "Pre-requisite test failed", 1 if $skip_cmeth;
 146             is( $class1->loader_test1_classmeth, 'all is well' );
 147         }
 148
 149         # XXX put this back in when the TODO above works...
 150         #SKIP: {
 151         #    skip "Pre-requisite test failed", 1 if $skip_rsmeth;
 152         #    is( $rsobj1->loader_test1_rsmeth, 'all is still well' );
 153         #}
 154     }
 155
 156
 157     my $obj    = $rsobj1->find(1);
 158     is( $obj->id,  1 );
 159     is( $obj->dat, "foo" );
 160     is( $rsobj2->count, 4 );
 161     my $saved_id;
 162     eval {
 163         my $new_obj1 = $rsobj1->create({ dat => 'newthing' });
 164         $saved_id = $new_obj1->id;
 165     };
 166     ok(!$@) or diag "Died during create new record using a PK::Auto key: $@";
 167     ok($saved_id) or diag "Failed to get PK::Auto-generated id";
 168
 169     my $new_obj1 = $rsobj1->search({ dat => 'newthing' })->first;
 170     ok($new_obj1) or diag "Cannot find newly inserted PK::Auto record";
 171     is($new_obj1->id, $saved_id);
 172
 173     my ($obj2) = $rsobj2->find( dat => 'bbb' );
 174     is( $obj2->id, 2 );
 175
 176     SKIP: {
 177         skip $self->{skip_rels}, 29 if $self->{skip_rels};
 178
 179         my $moniker3 = $monikers->{loader_test3};
 180         my $class3   = $classes->{loader_test3};
 181         my $rsobj3   = $conn->resultset($moniker3);
 182
 183         my $moniker4 = $monikers->{loader_test4};
 184         my $class4   = $classes->{loader_test4};
 185         my $rsobj4   = $conn->resultset($moniker4);
 186
 187         my $moniker5 = $monikers->{loader_test5};
 188         my $class5   = $classes->{loader_test5};
 189         my $rsobj5   = $conn->resultset($moniker5);
 190
 191         my $moniker6 = $monikers->{loader_test6};
 192         my $class6   = $classes->{loader_test6};
 193         my $rsobj6   = $conn->resultset($moniker6);
 194
 195         my $moniker7 = $monikers->{loader_test7};
 196         my $class7   = $classes->{loader_test7};
 197         my $rsobj7   = $conn->resultset($moniker7);
 198
 199         my $moniker8 = $monikers->{loader_test8};
 200         my $class8   = $classes->{loader_test8};
 201         my $rsobj8   = $conn->resultset($moniker8);
 202
 203         my $moniker9 = $monikers->{loader_test9};
 204         my $class9   = $classes->{loader_test9};
 205         my $rsobj9   = $conn->resultset($moniker9);
 206
 207         isa_ok( $rsobj3, "DBIx::Class::ResultSet" );
 208         isa_ok( $rsobj4, "DBIx::Class::ResultSet" );
 209         isa_ok( $rsobj5, "DBIx::Class::ResultSet" );
 210         isa_ok( $rsobj6, "DBIx::Class::ResultSet" );
 211         isa_ok( $rsobj7, "DBIx::Class::ResultSet" );
 212         isa_ok( $rsobj8, "DBIx::Class::ResultSet" );
 213         isa_ok( $rsobj9, "DBIx::Class::ResultSet" );
 214
 215         # basic rel test
 216         my $obj4 = $rsobj4->find(123);
 217         isa_ok( $obj4->fkid, $class3);
 218
 219         my $obj3 = $rsobj3->find(1);
 220         my $rs_rel4 = $obj3->search_related('loader_test4zes');
 221         isa_ok( $rs_rel4->first, $class4);
 222
 223         # fk def in comments should not be parsed
 224         my $obj5 = $rsobj5->find( id1 => 1, id2 => 1 );
 225         is( ref( $obj5->id2 ), '' );
 226
 227         # mulit-col fk def
 228         my $obj6 = $rsobj6->find(1);
 229         isa_ok( $obj6->loader_test2, $class2);
 230         isa_ok( $obj6->loader_test5, $class5);
 231
 232         # fk that references a non-pk key (UNIQUE)
 233         my $obj8 = $rsobj8->find(1);
 234         isa_ok( $obj8->loader_test7, $class7);
 235
 236         # from Chisel's tests...
 237         SKIP: {
 238             if($self->{vendor} =~ /sqlite/i) {
 239                 skip 'SQLite cannot do the advanced tests', 8;
 240             }
 241
 242             my $moniker10 = $monikers->{loader_test10};
 243             my $class10   = $classes->{loader_test10};
 244             my $rsobj10   = $conn->resultset($moniker10);
 245
 246             my $moniker11 = $monikers->{loader_test11};
 247             my $class11   = $classes->{loader_test11};
 248             my $rsobj11   = $conn->resultset($moniker11);
 249
 250             isa_ok( $rsobj10, "DBIx::Class::ResultSet" );
 251             isa_ok( $rsobj11, "DBIx::Class::ResultSet" );
 252
 253             my $obj10 = $rsobj10->create({ subject => 'xyzzy' });
 254
 255             $obj10->update();
 256             ok( defined $obj10, '$obj10 is defined' );
 257
 258             my $obj11 = $rsobj11->create({ loader_test10 => $obj10->id() });
 259             $obj11->update();
 260             ok( defined $obj11, '$obj11 is defined' );
 261
 262             eval {
 263                 my $obj10_2 = $obj11->loader_test10;
 264                 $obj10_2->loader_test11( $obj11->id11() );
 265                 $obj10_2->update();
 266             };
 267             is($@, '', 'No errors after eval{}');
 268
 269             SKIP: {
 270                 skip 'Previous eval block failed', 3
 271                     unless ($@ eq '');
 272
 273                 my $results = $rsobj10->search({ subject => 'xyzzy' });
 274                 is( $results->count(), 1,
 275                     'One $rsobj10 returned from search' );
 276
 277                 my $obj10_3 = $results->first();
 278                 isa_ok( $obj10_3, $class10 );
 279                 is( $obj10_3->loader_test11()->id(), $obj11->id(),
 280                     'found same $rsobj11 object we expected' );
 281             }
 282         }
 283
 284         SKIP: {
 285             skip 'This vendor cannot do inline relationship definitions', 5
 286                 if $self->{no_inline_rels};
 287
 288             my $moniker12 = $monikers->{loader_test12};
 289             my $class12   = $classes->{loader_test12};
 290             my $rsobj12   = $conn->resultset($moniker12);
 291
 292             my $moniker13 = $monikers->{loader_test13};
 293             my $class13   = $classes->{loader_test13};
 294             my $rsobj13   = $conn->resultset($moniker13);
 295
 296             isa_ok( $rsobj12, "DBIx::Class::ResultSet" );
 297             isa_ok( $rsobj13, "DBIx::Class::ResultSet" );
 298
 299             my $obj13 = $rsobj13->find(1);
 300             isa_ok( $obj13->id, $class12 );
 301             isa_ok( $obj13->loader_test12, $class12);
 302             isa_ok( $obj13->dat, $class12);
 303         }
 304
 305         SKIP: {
 306             skip 'This vendor cannot do out-of-line implicit rel defs', 3
 307                 if $self->{no_implicit_rels};
 308             my $moniker14 = $monikers->{loader_test14};
 309             my $class14   = $classes->{loader_test14};
 310             my $rsobj14   = $conn->resultset($moniker14);
 311
 312             my $moniker15 = $monikers->{loader_test15};
 313             my $class15   = $classes->{loader_test15};
 314             my $rsobj15   = $conn->resultset($moniker15);
 315
 316             isa_ok( $rsobj14, "DBIx::Class::ResultSet" );
 317             isa_ok( $rsobj15, "DBIx::Class::ResultSet" );
 318
 319             my $obj15 = $rsobj15->find(1);
 320             isa_ok( $obj15->loader_test14, $class14 );
 321         }
 322     }
 323 }
 324
 325 sub dbconnect {
 326     my ($self, $complain) = @_;
 327
 328     my $dbh = DBI->connect(
 329          $self->{dsn}, $self->{user},
 330          $self->{password},
 331          {
 332              RaiseError => $complain,
 333              PrintError => $complain,
 334              AutoCommit => 1,
 335          }
 336     );
 337
 338     die "Failed to connect to database: $DBI::errstr" if !$dbh;
 339
 340     return $dbh;
 341 }
 342
 343 sub create {
 344     my $self = shift;
 345
 346     my @statements = (
 347         qq{
 348             CREATE TABLE loader_test1 (
 349                 id $self->{auto_inc_pk},
 350                 dat VARCHAR(32)
 351             ) $self->{innodb}
 352         },
 353
 354         q{ INSERT INTO loader_test1 (dat) VALUES('foo') },
 355         q{ INSERT INTO loader_test1 (dat) VALUES('bar') },
 356         q{ INSERT INTO loader_test1 (dat) VALUES('baz') },
 357
 358         qq{
 359             CREATE TABLE loader_test2 (
 360                 id $self->{auto_inc_pk},
 361                 dat VARCHAR(32)
 362             ) $self->{innodb}
 363         },
 364
 365         q{ INSERT INTO loader_test2 (dat) VALUES('aaa') },
 366         q{ INSERT INTO loader_test2 (dat) VALUES('bbb') },
 367         q{ INSERT INTO loader_test2 (dat) VALUES('ccc') },
 368         q{ INSERT INTO loader_test2 (dat) VALUES('ddd') },
 369     );
 370
 371     my @statements_reltests = (
 372         qq{
 373             CREATE TABLE loader_test3 (
 374                 id INTEGER NOT NULL PRIMARY KEY,
 375                 dat VARCHAR(32)
 376             ) $self->{innodb}
 377         },
 378
 379         q{ INSERT INTO loader_test3 (id,dat) VALUES(1,'aaa') },
 380         q{ INSERT INTO loader_test3 (id,dat) VALUES(2,'bbb') },
 381         q{ INSERT INTO loader_test3 (id,dat) VALUES(3,'ccc') },
 382         q{ INSERT INTO loader_test3 (id,dat) VALUES(4,'ddd') },
 383
 384         qq{
 385             CREATE TABLE loader_test4 (
 386                 id INTEGER NOT NULL PRIMARY KEY,
 387                 fkid INTEGER NOT NULL,
 388                 dat VARCHAR(32),
 389                 FOREIGN KEY (fkid) REFERENCES loader_test3 (id)
 390             ) $self->{innodb}
 391         },
 392
 393         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(123,1,'aaa') },
 394         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(124,2,'bbb') },
 395         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(125,3,'ccc') },
 396         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(126,4,'ddd') },
 397
 398         qq{
 399             CREATE TABLE loader_test5 (
 400                 id1 INTEGER NOT NULL,
 401                 id2 INTEGER NOT NULL, -- , id2 INTEGER REFERENCES loader_test1,
 402                 dat VARCHAR(8),
 403                 PRIMARY KEY (id1,id2)
 404             ) $self->{innodb}
 405         },
 406
 407         q{ INSERT INTO loader_test5 (id1,id2,dat) VALUES (1,1,'aaa') },
 408
 409         qq{
 410             CREATE TABLE loader_test6 (
 411                 id INTEGER NOT NULL PRIMARY KEY,
 412                 id2 INTEGER,
 413                 loader_test2 INTEGER,
 414                 dat VARCHAR(8),
 415                 FOREIGN KEY (loader_test2) REFERENCES loader_test2 (id),
 416                 FOREIGN KEY (id, id2 ) REFERENCES loader_test5 (id1,id2)
 417             ) $self->{innodb}
 418         },
 419
 420         (q{ INSERT INTO loader_test6 (id, id2,loader_test2,dat) } .
 421          q{ VALUES (1, 1,1,'aaa') }),
 422
 423         qq{
 424             CREATE TABLE loader_test7 (
 425                 id INTEGER NOT NULL PRIMARY KEY,
 426                 id2 VARCHAR(8) NOT NULL UNIQUE,
 427                 dat VARCHAR(8)
 428             ) $self->{innodb}
 429         },
 430
 431         q{ INSERT INTO loader_test7 (id,id2,dat) VALUES (1,'aaa','bbb') },
 432
 433         qq{
 434             CREATE TABLE loader_test8 (
 435                 id INTEGER NOT NULL PRIMARY KEY,
 436                 loader_test7 VARCHAR(8) NOT NULL,
 437                 dat VARCHAR(8),
 438                 FOREIGN KEY (loader_test7) REFERENCES loader_test7 (id2)
 439             ) $self->{innodb}
 440         },
 441
 442         (q{ INSERT INTO loader_test8 (id,loader_test7,dat) } .
 443          q{ VALUES (1,'aaa','bbb') }),
 444
 445         qq{
 446             CREATE TABLE loader_test9 (
 447                 loader_test9 VARCHAR(8) NOT NULL
 448             ) $self->{innodb}
 449         },
 450     );
 451
 452     my @statements_advanced = (
 453         qq{
 454             CREATE TABLE loader_test10 (
 455                 id10 $self->{auto_inc_pk},
 456                 subject VARCHAR(8),
 457                 loader_test11 INTEGER
 458             ) $self->{innodb}
 459         },
 460
 461         qq{
 462             CREATE TABLE loader_test11 (
 463                 id11 $self->{auto_inc_pk},
 464                 message VARCHAR(8) DEFAULT 'foo',
 465                 loader_test10 INTEGER,
 466                 FOREIGN KEY (loader_test10) REFERENCES loader_test10 (id10)
 467             ) $self->{innodb}
 468         },
 469
 470         (q{ ALTER TABLE loader_test10 ADD CONSTRAINT } .
 471          q{ loader_test11_fk FOREIGN KEY (loader_test11) } .
 472          q{ REFERENCES loader_test11 (id11) }),
 473     );
 474
 475     my @statements_inline_rels = (
 476         qq{
 477             CREATE TABLE loader_test12 (
 478                 id INTEGER NOT NULL PRIMARY KEY,
 479                 id2 VARCHAR(8) NOT NULL UNIQUE,
 480                 dat VARCHAR(8) NOT NULL UNIQUE
 481             ) $self->{innodb}
 482         },
 483
 484         q{ INSERT INTO loader_test12 (id,id2,dat) VALUES (1,'aaa','bbb') },
 485
 486         qq{
 487             CREATE TABLE loader_test13 (
 488                 id INTEGER NOT NULL PRIMARY KEY REFERENCES loader_test12,
 489                 loader_test12 VARCHAR(8) NOT NULL REFERENCES loader_test12 (id2),
 490                 dat VARCHAR(8) REFERENCES loader_test12 (dat)
 491             ) $self->{innodb}
 492         },
 493
 494         (q{ INSERT INTO loader_test13 (id,loader_test12,dat) } .
 495          q{ VALUES (1,'aaa','bbb') }),
 496     );
 497
 498
 499     my @statements_implicit_rels = (
 500         qq{
 501             CREATE TABLE loader_test14 (
 502                 id INTEGER NOT NULL PRIMARY KEY,
 503                 dat VARCHAR(8)
 504             ) $self->{innodb}
 505         },
 506
 507         q{ INSERT INTO loader_test14 (id,dat) VALUES (123,'aaa') },
 508
 509         qq{
 510             CREATE TABLE loader_test15 (
 511                 id INTEGER NOT NULL PRIMARY KEY,
 512                 loader_test14 INTEGER NOT NULL,
 513                 FOREIGN KEY (loader_test14) REFERENCES loader_test14
 514             ) $self->{innodb}
 515         },
 516
 517         q{ INSERT INTO loader_test15 (id,loader_test14) VALUES (1,123) },
 518    );
 519
 520     $self->drop_tables;
 521
 522     $self->{created} = 1;
 523
 524     my $dbh = $self->dbconnect(1);
 525
 526     # Silence annoying but harmless postgres "NOTICE:  CREATE TABLE..."
 527     local $SIG{__WARN__} = sub {
 528         my $msg = shift;
 529         print STDERR $msg unless $msg =~ m{^NOTICE:\s+CREATE TABLE};
 530     };
 531
 532     $dbh->do($_) for (@statements);
 533     unless($self->{skip_rels}) {
 534         # hack for now, since DB2 doesn't like inline comments, and we need
 535         # to test one for mysql, which works on everyone else...
 536         # this all needs to be refactored anyways.
 537         if($self->{vendor} =~ /DB2/i) {
 538             @statements_reltests = map { s/--.*\n//; $_ } @statements_reltests;
 539         }
 540         $dbh->do($_) for (@statements_reltests);
 541         unless($self->{vendor} =~ /sqlite/i) {
 542             $dbh->do($_) for (@statements_advanced);
 543         }
 544         unless($self->{no_inline_rels}) {
 545             $dbh->do($_) for (@statements_inline_rels);
 546         }
 547         unless($self->{no_implicit_rels}) {
 548             $dbh->do($_) for (@statements_implicit_rels);
 549         }
 550     }
 551     $dbh->disconnect();
 552 }
 553
 554 sub drop_tables {
 555     my $self = shift;
 556
 557     return unless $self->{created};
 558
 559     my @tables = qw/
 560         loader_test1
 561         loader_test2
 562     /;
 563
 564     my @tables_reltests = qw/
 565         loader_test4
 566         loader_test3
 567         loader_test6
 568         loader_test5
 569         loader_test8
 570         loader_test7
 571         loader_test9
 572     /;
 573
 574     my @tables_advanced = qw/
 575         loader_test11
 576         loader_test10
 577     /;
 578
 579     my @tables_inline_rels = qw/
 580         loader_test13
 581         loader_test12
 582     /;
 583
 584     my @tables_implicit_rels = qw/
 585         loader_test15
 586         loader_test14
 587     /;
 588
 589     my $drop_fk_mysql =
 590         q{ALTER TABLE loader_test10 DROP FOREIGN KEY loader_test11_fk;};
 591
 592     my $drop_fk =
 593         q{ALTER TABLE loader_test10 DROP CONSTRAINT loader_test11_fk;};
 594
 595     my $dbh = $self->dbconnect(0);
 596
 597     unless($self->{skip_rels}) {
 598         $dbh->do("DROP TABLE $_") for (@tables_reltests);
 599         unless($self->{vendor} =~ /sqlite/i) {
 600             if($self->{vendor} =~ /mysql/i) {
 601                 $dbh->do($drop_fk_mysql);
 602             }
 603             else {
 604                 $dbh->do($drop_fk);
 605             }
 606             $dbh->do("DROP TABLE $_") for (@tables_advanced);
 607         }
 608         unless($self->{no_inline_rels}) {
 609             $dbh->do("DROP TABLE $_") for (@tables_inline_rels);
 610         }
 611         unless($self->{no_implicit_rels}) {
 612             $dbh->do("DROP TABLE $_") for (@tables_implicit_rels);
 613         }
 614     }
 615     $dbh->do("DROP TABLE $_") for (@tables);
 616     $dbh->disconnect;
 617 }
 618
 619 sub DESTROY { shift->drop_tables; }
 620
 621 1;