t/lib/dbixcsl_common_tests.pm

   1 package dbixcsl_common_tests;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use DBIx::Class::Schema::Loader;
   8 use DBI;
   9
  10 sub new {
  11     my $class = shift;
  12
  13     my $self;
  14
  15     if( ref($_[0]) eq 'HASH') {
  16        my $args = shift;
  17        $self = { (%$args) };
  18     }
  19     else {
  20        $self = { @_ };
  21     }
  22
  23     # Only MySQL uses this
  24     $self->{innodb} ||= '';
  25
  26     $self->{verbose} = $ENV{TEST_VERBOSE} || 0;
  27
  28     return bless $self => $class;
  29 }
  30
  31 sub skip_tests {
  32     my ($self, $why) = @_;
  33
  34     plan skip_all => $why;
  35 }
  36
  37 sub run_tests {
  38     my $self = shift;
  39
  40     plan tests => 49;
  41
  42     $self->create();
  43
  44     my $schema_class = 'DBIXCSL_Test::Schema';
  45
  46     my $debug = ($self->{verbose} > 1) ? 1 : 0;
  47
  48     my %loader_opts = (
  49         dsn                     => $self->{dsn},
  50         user                    => $self->{user},
  51         password                => $self->{password},
  52         constraint              => '^(?:\S+\.)?(?i:loader_test)[0-9]+$',
  53         relationships           => 1,
  54         additional_classes      => 'TestAdditional',
  55         additional_base_classes => 'TestAdditionalBase',
  56         left_base_classes       => [ qw/TestLeftBase/ ],
  57         components              => [ qw/TestComponent/ ],
  58         resultset_components    => [ qw/TestRSComponent/ ],
  59         debug                   => $debug,
  60     );
  61
  62     $loader_opts{db_schema} = $self->{db_schema} if $self->{db_schema};
  63     $loader_opts{drop_db_schema} = $self->{drop_db_schema} if $self->{drop_db_schema};
  64
  65     eval qq{
  66         package $schema_class;
  67         use base qw/DBIx::Class::Schema::Loader/;
  68
  69         __PACKAGE__->load_from_connection(\%loader_opts);
  70     };
  71     ok(!$@, "Loader initialization") or diag $@;
  72
  73     my $conn = $schema_class->connect($self->{dsn},$self->{user},$self->{password});
  74     my $monikers = $schema_class->loader->monikers;
  75     my $classes = $schema_class->loader->classes;
  76
  77     my $moniker1 = $monikers->{loader_test1};
  78     my $class1   = $classes->{loader_test1};
  79     my $rsobj1   = $conn->resultset($moniker1);
  80
  81     my $moniker2 = $monikers->{loader_test2};
  82     my $class2   = $classes->{loader_test2};
  83     my $rsobj2   = $conn->resultset($moniker2);
  84
  85     isa_ok( $rsobj1, "DBIx::Class::ResultSet" );
  86     isa_ok( $rsobj2, "DBIx::Class::ResultSet" );
  87
  88     {
  89         my ($skip_tab, $skip_tabo, $skip_taba, $skip_cmeth,
  90             $skip_rsmeth, $skip_tcomp, $skip_trscomp);
  91
  92         can_ok( $class1, 'test_additional_base' ) or $skip_tab = 1;
  93         can_ok( $class1, 'test_additional_base_override' ) or $skip_tabo = 1;
  94         can_ok( $class1, 'test_additional_base_additional' ) or $skip_taba = 1;
  95         can_ok( $class1, 'dbix_class_testcomponent' ) or $skip_tcomp = 1;
  96         can_ok( $rsobj1, 'dbix_class_testrscomponent' ) or $skip_trscomp = 1;
  97         can_ok( $class1, 'loader_test1_classmeth' ) or $skip_cmeth = 1;
  98
  99         TODO: {
 100             local $TODO = "Not yet supported by ResultSetManger code";
 101             can_ok( $rsobj1, 'loader_test1_rsmeth' ) or $skip_rsmeth = 1;
 102         }
 103
 104         SKIP: {
 105             skip "Pre-requisite test failed", 1 if $skip_tab;
 106             is( $class1->test_additional_base, "test_additional_base",
 107                 "Additional Base method" );
 108         }
 109
 110         SKIP: {
 111             skip "Pre-requisite test failed", 1 if $skip_tabo;
 112             is( $class1->test_additional_base_override,
 113                 "test_left_base_override",
 114                 "Left Base overrides Additional Base method" );
 115         }
 116
 117         SKIP: {
 118             skip "Pre-requisite test failed", 1 if $skip_taba;
 119             is( $class1->test_additional_base_additional, "test_additional",
 120                 "Additional Base can use Additional package method" );
 121         }
 122
 123         SKIP: {
 124             skip "Pre-requisite test failed", 1 if $skip_tcomp;
 125             is( $class1->dbix_class_testcomponent,
 126                 'dbix_class_testcomponent works' );
 127         }
 128
 129         SKIP: {
 130             skip "Pre-requisite test failed", 1 if $skip_trscomp;
 131             is( $rsobj1->dbix_class_testrscomponent,
 132                 'dbix_class_testrscomponent works' );
 133         }
 134
 135         SKIP: {
 136             skip "Pre-requisite test failed", 1 if $skip_cmeth;
 137             is( $class1->loader_test1_classmeth, 'all is well' );
 138         }
 139
 140         # XXX put this back in when the TODO above works...
 141         #SKIP: {
 142         #    skip "Pre-requisite test failed", 1 if $skip_rsmeth;
 143         #    is( $rsobj1->loader_test1_rsmeth, 'all is still well' );
 144         #}
 145     }
 146
 147
 148     my $obj    = $rsobj1->find(1);
 149     is( $obj->id,  1 );
 150     is( $obj->dat, "foo" );
 151     is( $rsobj2->count, 4 );
 152
 153     my ($obj2) = $rsobj2->find( dat => 'bbb' );
 154     is( $obj2->id, 2 );
 155
 156     SKIP: {
 157         skip $self->{skip_rels}, 29 if $self->{skip_rels};
 158
 159         my $moniker3 = $monikers->{loader_test3};
 160         my $class3   = $classes->{loader_test3};
 161         my $rsobj3   = $conn->resultset($moniker3);
 162
 163         my $moniker4 = $monikers->{loader_test4};
 164         my $class4   = $classes->{loader_test4};
 165         my $rsobj4   = $conn->resultset($moniker4);
 166
 167         my $moniker5 = $monikers->{loader_test5};
 168         my $class5   = $classes->{loader_test5};
 169         my $rsobj5   = $conn->resultset($moniker5);
 170
 171         my $moniker6 = $monikers->{loader_test6};
 172         my $class6   = $classes->{loader_test6};
 173         my $rsobj6   = $conn->resultset($moniker6);
 174
 175         my $moniker7 = $monikers->{loader_test7};
 176         my $class7   = $classes->{loader_test7};
 177         my $rsobj7   = $conn->resultset($moniker7);
 178
 179         my $moniker8 = $monikers->{loader_test8};
 180         my $class8   = $classes->{loader_test8};
 181         my $rsobj8   = $conn->resultset($moniker8);
 182
 183         my $moniker9 = $monikers->{loader_test9};
 184         my $class9   = $classes->{loader_test9};
 185         my $rsobj9   = $conn->resultset($moniker9);
 186
 187         isa_ok( $rsobj3, "DBIx::Class::ResultSet" );
 188         isa_ok( $rsobj4, "DBIx::Class::ResultSet" );
 189         isa_ok( $rsobj5, "DBIx::Class::ResultSet" );
 190         isa_ok( $rsobj6, "DBIx::Class::ResultSet" );
 191         isa_ok( $rsobj7, "DBIx::Class::ResultSet" );
 192         isa_ok( $rsobj8, "DBIx::Class::ResultSet" );
 193         isa_ok( $rsobj9, "DBIx::Class::ResultSet" );
 194
 195         # basic rel test
 196         my $obj4 = $rsobj4->find(123);
 197         isa_ok( $obj4->fkid, $class3);
 198
 199         my $obj3 = $rsobj3->find(1);
 200         my $rs_rel4 = $obj3->search_related('loader_test4s');
 201         isa_ok( $rs_rel4->first, $class4);
 202
 203         # fk def in comments should not be parsed
 204         my $obj5 = $rsobj5->find( id1 => 1, id2 => 1 );
 205         is( ref( $obj5->id2 ), '' );
 206
 207         # mulit-col fk def
 208         my $obj6 = $rsobj6->find(1);
 209         isa_ok( $obj6->loader_test2, $class2);
 210         isa_ok( $obj6->loader_test5, $class5);
 211
 212         # fk that references a non-pk key (UNIQUE)
 213         my $obj8 = $rsobj8->find(1);
 214         isa_ok( $obj8->loader_test7, $class7);
 215
 216         # from Chisel's tests...
 217         SKIP: {
 218             if($self->{vendor} =~ /sqlite/i) {
 219                 skip 'SQLite cannot do the advanced tests', 8;
 220             }
 221
 222             my $moniker10 = $monikers->{loader_test10};
 223             my $class10   = $classes->{loader_test10};
 224             my $rsobj10   = $conn->resultset($moniker10);
 225
 226             my $moniker11 = $monikers->{loader_test11};
 227             my $class11   = $classes->{loader_test11};
 228             my $rsobj11   = $conn->resultset($moniker11);
 229
 230             isa_ok( $rsobj10, "DBIx::Class::ResultSet" );
 231             isa_ok( $rsobj11, "DBIx::Class::ResultSet" );
 232
 233             my $obj10 = $rsobj10->create({ subject => 'xyzzy' });
 234
 235             $obj10->update();
 236             ok( defined $obj10, '$obj10 is defined' );
 237
 238             my $obj11 = $rsobj11->create({ loader_test10 => $obj10->id() });
 239             $obj11->update();
 240             ok( defined $obj11, '$obj11 is defined' );
 241
 242             eval {
 243                 my $obj10_2 = $obj11->loader_test10;
 244                 $obj10_2->loader_test11( $obj11->id11() );
 245                 $obj10_2->update();
 246             };
 247             is($@, '', 'No errors after eval{}');
 248
 249             SKIP: {
 250                 skip 'Previous eval block failed', 3
 251                     unless ($@ eq '');
 252
 253                 my $results = $rsobj10->search({ subject => 'xyzzy' });
 254                 is( $results->count(), 1,
 255                     'One $rsobj10 returned from search' );
 256
 257                 my $obj10_3 = $results->first();
 258                 isa_ok( $obj10_3, $class10 );
 259                 is( $obj10_3->loader_test11()->id(), $obj11->id(),
 260                     'found same $rsobj11 object we expected' );
 261             }
 262         }
 263
 264         SKIP: {
 265             skip 'This vendor cannot do inline relationship definitions', 5
 266                 if $self->{no_inline_rels};
 267
 268             my $moniker12 = $monikers->{loader_test12};
 269             my $class12   = $classes->{loader_test12};
 270             my $rsobj12   = $conn->resultset($moniker12);
 271
 272             my $moniker13 = $monikers->{loader_test13};
 273             my $class13   = $classes->{loader_test13};
 274             my $rsobj13   = $conn->resultset($moniker13);
 275
 276             isa_ok( $rsobj12, "DBIx::Class::ResultSet" );
 277             isa_ok( $rsobj13, "DBIx::Class::ResultSet" );
 278
 279             my $obj13 = $rsobj13->find(1);
 280             isa_ok( $obj13->id, $class12 );
 281             isa_ok( $obj13->loader_test12, $class12);
 282             isa_ok( $obj13->dat, $class12);
 283         }
 284
 285         SKIP: {
 286             skip 'This vendor cannot do out-of-line implicit rel defs', 3
 287                 if $self->{no_implicit_rels};
 288             my $moniker14 = $monikers->{loader_test14};
 289             my $class14   = $classes->{loader_test14};
 290             my $rsobj14   = $conn->resultset($moniker14);
 291
 292             my $moniker15 = $monikers->{loader_test15};
 293             my $class15   = $classes->{loader_test15};
 294             my $rsobj15   = $conn->resultset($moniker15);
 295
 296             isa_ok( $rsobj14, "DBIx::Class::ResultSet" );
 297             isa_ok( $rsobj15, "DBIx::Class::ResultSet" );
 298
 299             my $obj15 = $rsobj15->find(1);
 300             isa_ok( $obj15->loader_test14, $class14 );
 301         }
 302     }
 303 }
 304
 305 sub dbconnect {
 306     my ($self, $complain) = @_;
 307
 308     my $dbh = DBI->connect(
 309          $self->{dsn}, $self->{user},
 310          $self->{password},
 311          {
 312              RaiseError => $complain,
 313              PrintError => $complain,
 314              AutoCommit => 1,
 315          }
 316     );
 317
 318     die "Failed to connect to database: $DBI::errstr" if !$dbh;
 319
 320     return $dbh;
 321 }
 322
 323 sub create {
 324     my $self = shift;
 325
 326     my @statements = (
 327         qq{
 328             CREATE TABLE loader_test1 (
 329                 id $self->{auto_inc_pk},
 330                 dat VARCHAR(32)
 331             ) $self->{innodb}
 332         },
 333
 334         q{ INSERT INTO loader_test1 (dat) VALUES('foo') },
 335         q{ INSERT INTO loader_test1 (dat) VALUES('bar') },
 336         q{ INSERT INTO loader_test1 (dat) VALUES('baz') },
 337
 338         qq{
 339             CREATE TABLE loader_test2 (
 340                 id $self->{auto_inc_pk},
 341                 dat VARCHAR(32)
 342             ) $self->{innodb}
 343         },
 344
 345         q{ INSERT INTO loader_test2 (dat) VALUES('aaa') },
 346         q{ INSERT INTO loader_test2 (dat) VALUES('bbb') },
 347         q{ INSERT INTO loader_test2 (dat) VALUES('ccc') },
 348         q{ INSERT INTO loader_test2 (dat) VALUES('ddd') },
 349     );
 350
 351     my @statements_reltests = (
 352         qq{
 353             CREATE TABLE loader_test3 (
 354                 id INTEGER NOT NULL PRIMARY KEY,
 355                 dat VARCHAR(32)
 356             ) $self->{innodb}
 357         },
 358
 359         q{ INSERT INTO loader_test3 (id,dat) VALUES(1,'aaa') },
 360         q{ INSERT INTO loader_test3 (id,dat) VALUES(2,'bbb') },
 361         q{ INSERT INTO loader_test3 (id,dat) VALUES(3,'ccc') },
 362         q{ INSERT INTO loader_test3 (id,dat) VALUES(4,'ddd') },
 363
 364         qq{
 365             CREATE TABLE loader_test4 (
 366                 id INTEGER NOT NULL PRIMARY KEY,
 367                 fkid INTEGER NOT NULL,
 368                 dat VARCHAR(32),
 369                 FOREIGN KEY (fkid) REFERENCES loader_test3 (id)
 370             ) $self->{innodb}
 371         },
 372
 373         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(123,1,'aaa') },
 374         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(124,2,'bbb') },
 375         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(125,3,'ccc') },
 376         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(126,4,'ddd') },
 377
 378         qq{
 379             CREATE TABLE loader_test5 (
 380                 id1 INTEGER NOT NULL,
 381                 id2 INTEGER NOT NULL, -- , id2 INTEGER REFERENCES loader_test1,
 382                 dat VARCHAR(8),
 383                 PRIMARY KEY (id1,id2)
 384             ) $self->{innodb}
 385         },
 386
 387         q{ INSERT INTO loader_test5 (id1,id2,dat) VALUES (1,1,'aaa') },
 388
 389         qq{
 390             CREATE TABLE loader_test6 (
 391                 id INTEGER NOT NULL PRIMARY KEY,
 392                 id2 INTEGER,
 393                 loader_test2 INTEGER,
 394                 dat VARCHAR(8),
 395                 FOREIGN KEY (loader_test2) REFERENCES loader_test2 (id),
 396                 FOREIGN KEY (id, id2 ) REFERENCES loader_test5 (id1,id2)
 397             ) $self->{innodb}
 398         },
 399
 400         (q{ INSERT INTO loader_test6 (id, id2,loader_test2,dat) } .
 401          q{ VALUES (1, 1,1,'aaa') }),
 402
 403         qq{
 404             CREATE TABLE loader_test7 (
 405                 id INTEGER NOT NULL PRIMARY KEY,
 406                 id2 VARCHAR(8) NOT NULL UNIQUE,
 407                 dat VARCHAR(8)
 408             ) $self->{innodb}
 409         },
 410
 411         q{ INSERT INTO loader_test7 (id,id2,dat) VALUES (1,'aaa','bbb') },
 412
 413         qq{
 414             CREATE TABLE loader_test8 (
 415                 id INTEGER NOT NULL PRIMARY KEY,
 416                 loader_test7 VARCHAR(8) NOT NULL,
 417                 dat VARCHAR(8),
 418                 FOREIGN KEY (loader_test7) REFERENCES loader_test7 (id2)
 419             ) $self->{innodb}
 420         },
 421
 422         (q{ INSERT INTO loader_test8 (id,loader_test7,dat) } .
 423          q{ VALUES (1,'aaa','bbb') }),
 424
 425         qq{
 426             CREATE TABLE loader_test9 (
 427                 loader_test9 VARCHAR(8) NOT NULL
 428             ) $self->{innodb}
 429         },
 430     );
 431
 432     my @statements_advanced = (
 433         qq{
 434             CREATE TABLE loader_test10 (
 435                 id10 $self->{auto_inc_pk},
 436                 subject VARCHAR(8),
 437                 loader_test11 INTEGER
 438             ) $self->{innodb}
 439         },
 440
 441         qq{
 442             CREATE TABLE loader_test11 (
 443                 id11 $self->{auto_inc_pk},
 444                 message VARCHAR(8) DEFAULT 'foo',
 445                 loader_test10 INTEGER,
 446                 FOREIGN KEY (loader_test10) REFERENCES loader_test10 (id10)
 447             ) $self->{innodb}
 448         },
 449
 450         (q{ ALTER TABLE loader_test10 ADD CONSTRAINT } .
 451          q{ loader_test11_fk FOREIGN KEY (loader_test11) } .
 452          q{ REFERENCES loader_test11 (id11) }),
 453     );
 454
 455     my @statements_inline_rels = (
 456         qq{
 457             CREATE TABLE loader_test12 (
 458                 id INTEGER NOT NULL PRIMARY KEY,
 459                 id2 VARCHAR(8) NOT NULL UNIQUE,
 460                 dat VARCHAR(8) NOT NULL UNIQUE
 461             ) $self->{innodb}
 462         },
 463
 464         q{ INSERT INTO loader_test12 (id,id2,dat) VALUES (1,'aaa','bbb') },
 465
 466         qq{
 467             CREATE TABLE loader_test13 (
 468                 id INTEGER NOT NULL PRIMARY KEY REFERENCES loader_test12,
 469                 loader_test12 VARCHAR(8) NOT NULL REFERENCES loader_test12 (id2),
 470                 dat VARCHAR(8) REFERENCES loader_test12 (dat)
 471             ) $self->{innodb}
 472         },
 473
 474         (q{ INSERT INTO loader_test13 (id,loader_test12,dat) } .
 475          q{ VALUES (1,'aaa','bbb') }),
 476     );
 477
 478
 479     my @statements_implicit_rels = (
 480         qq{
 481             CREATE TABLE loader_test14 (
 482                 id INTEGER NOT NULL PRIMARY KEY,
 483                 dat VARCHAR(8)
 484             ) $self->{innodb}
 485         },
 486
 487         q{ INSERT INTO loader_test14 (id,dat) VALUES (123,'aaa') },
 488
 489         qq{
 490             CREATE TABLE loader_test15 (
 491                 id INTEGER NOT NULL PRIMARY KEY,
 492                 loader_test14 INTEGER NOT NULL,
 493                 FOREIGN KEY (loader_test14) REFERENCES loader_test14
 494             ) $self->{innodb}
 495         },
 496
 497         q{ INSERT INTO loader_test15 (id,loader_test14) VALUES (1,123) },
 498    );
 499
 500     $self->drop_tables;
 501
 502     $self->{created} = 1;
 503
 504     my $dbh = $self->dbconnect(1);
 505
 506     # Silence annoying but harmless postgres "NOTICE:  CREATE TABLE..."
 507     local $SIG{__WARN__} = sub {
 508         my $msg = shift;
 509         print STDERR $msg unless $msg =~ m{^NOTICE:\s+CREATE TABLE};
 510     };
 511
 512     $dbh->do($_) for (@statements);
 513     unless($self->{skip_rels}) {
 514         # hack for now, since DB2 doesn't like inline comments, and we need
 515         # to test one for mysql, which works on everyone else...
 516         # this all needs to be refactored anyways.
 517         if($self->{vendor} =~ /DB2/i) {
 518             @statements_reltests = map { s/--.*\n//; $_ } @statements_reltests;
 519         }
 520         $dbh->do($_) for (@statements_reltests);
 521         unless($self->{vendor} =~ /sqlite/i) {
 522             $dbh->do($_) for (@statements_advanced);
 523         }
 524         unless($self->{no_inline_rels}) {
 525             $dbh->do($_) for (@statements_inline_rels);
 526         }
 527         unless($self->{no_implicit_rels}) {
 528             $dbh->do($_) for (@statements_implicit_rels);
 529         }
 530     }
 531     $dbh->disconnect();
 532 }
 533
 534 sub drop_tables {
 535     my $self = shift;
 536
 537     return unless $self->{created};
 538
 539     my @tables = qw/
 540         loader_test1
 541         loader_test2
 542     /;
 543
 544     my @tables_reltests = qw/
 545         loader_test4
 546         loader_test3
 547         loader_test6
 548         loader_test5
 549         loader_test8
 550         loader_test7
 551         loader_test9
 552     /;
 553
 554     my @tables_advanced = qw/
 555         loader_test11
 556         loader_test10
 557     /;
 558
 559     my @tables_inline_rels = qw/
 560         loader_test13
 561         loader_test12
 562     /;
 563
 564     my @tables_implicit_rels = qw/
 565         loader_test15
 566         loader_test14
 567     /;
 568
 569     my $drop_fk_mysql =
 570         q{ALTER TABLE loader_test10 DROP FOREIGN KEY loader_test11_fk;};
 571
 572     my $drop_fk =
 573         q{ALTER TABLE loader_test10 DROP CONSTRAINT loader_test11_fk;};
 574
 575     my $dbh = $self->dbconnect(0);
 576
 577     unless($self->{skip_rels}) {
 578         $dbh->do("DROP TABLE $_") for (@tables_reltests);
 579         unless($self->{vendor} =~ /sqlite/i) {
 580             if($self->{vendor} =~ /mysql/i) {
 581                 $dbh->do($drop_fk_mysql);
 582             }
 583             else {
 584                 $dbh->do($drop_fk);
 585             }
 586             $dbh->do("DROP TABLE $_") for (@tables_advanced);
 587         }
 588         unless($self->{no_inline_rels}) {
 589             $dbh->do("DROP TABLE $_") for (@tables_inline_rels);
 590         }
 591         unless($self->{no_implicit_rels}) {
 592             $dbh->do("DROP TABLE $_") for (@tables_implicit_rels);
 593         }
 594     }
 595     $dbh->do("DROP TABLE $_") for (@tables);
 596     $dbh->disconnect;
 597 }
 598
 599 sub DESTROY { shift->drop_tables; }
 600
 601 1;