t/lib/dbixcsl_common_tests.pm

   1 package dbixcsl_common_tests;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use DBIx::Class::Schema::Loader;
   8 use DBI;
   9
  10 sub new {
  11     my $class = shift;
  12
  13     my $self;
  14
  15     if( ref($_[0]) eq 'HASH') {
  16        my $args = shift;
  17        $self = { (%$args) };
  18     }
  19     else {
  20        $self = { @_ };
  21     }
  22
  23     # Only MySQL uses this
  24     $self->{innodb} ||= '';
  25
  26     $self->{verbose} = $ENV{TEST_VERBOSE} || 0;
  27
  28     return bless $self => $class;
  29 }
  30
  31 sub skip_tests {
  32     my ($self, $why) = @_;
  33
  34     plan skip_all => $why;
  35 }
  36
  37 sub _monikerize {
  38     my $name = shift;
  39     return 'LoaderTest2X' if $name =~ /^loader_test2$/i;
  40     return undef;
  41 }
  42
  43 sub run_tests {
  44     my $self = shift;
  45
  46     plan tests => 80;
  47
  48     $self->create();
  49
  50     my $schema_class = 'DBIXCSL_Test::Schema';
  51
  52     my $debug = ($self->{verbose} > 1) ? 1 : 0;
  53
  54     my @connect_info = ( $self->{dsn}, $self->{user}, $self->{password} );
  55     my %loader_opts = (
  56         constraint              => qr/^(?:\S+\.)?loader_test[0-9]+$/i,
  57         relationships           => 1,
  58         additional_classes      => 'TestAdditional',
  59         additional_base_classes => 'TestAdditionalBase',
  60         left_base_classes       => [ qw/TestLeftBase/ ],
  61         components              => [ qw/TestComponent/ ],
  62         inflect_plural          => { loader_test4 => 'loader_test4zes' },
  63         inflect_singular        => { fkid => 'fkid_singular' },
  64         moniker_map             => \&_monikerize,
  65         debug                   => $debug,
  66     );
  67
  68     $loader_opts{db_schema} = $self->{db_schema} if $self->{db_schema};
  69     eval { require Class::Inspector };
  70     if($@) {
  71         $self->{_no_rs_components} = 1;
  72     }
  73     else {
  74         $loader_opts{resultset_components} = [ qw/TestRSComponent/ ];
  75     }
  76
  77     {
  78        my @loader_warnings;
  79        local $SIG{__WARN__} = sub { push(@loader_warnings, $_[0]); };
  80         eval qq{
  81             package $schema_class;
  82             use base qw/DBIx::Class::Schema::Loader/;
  83
  84             __PACKAGE__->loader_options(\%loader_opts);
  85             __PACKAGE__->connection(\@connect_info);
  86         };
  87         ok(!$@, "Loader initialization") or diag $@;
  88         if($self->{skip_rels}) {
  89             is(scalar(@loader_warnings), 0)
  90               or diag "Did not get the expected 0 warnings.  Warnings are: "
  91                 . join('',@loader_warnings);
  92             ok(1);
  93         }
  94         else {
  95             is(scalar(@loader_warnings), 1)
  96               or diag "Did not get the expected 1 warning.  Warnings are: "
  97                 . join('',@loader_warnings);
  98             like($loader_warnings[0], qr/loader_test9 has no primary key/i);
  99         }
 100     }
 101
 102     my $conn = $schema_class->clone;
 103     my $monikers = {};
 104     my $classes = {};
 105     foreach my $source_name ($schema_class->sources) {
 106         my $table_name = $schema_class->source($source_name)->from;
 107         $monikers->{$table_name} = $source_name;
 108         $classes->{$table_name} = $schema_class . q{::} . $source_name;
 109     }
 110
 111     my $moniker1 = $monikers->{loader_test1};
 112     my $class1   = $classes->{loader_test1};
 113     my $rsobj1   = $conn->resultset($moniker1);
 114
 115     my $moniker2 = $monikers->{loader_test2};
 116     my $class2   = $classes->{loader_test2};
 117     my $rsobj2   = $conn->resultset($moniker2);
 118
 119     my $moniker23 = $monikers->{LOADER_TEST23};
 120     my $class23   = $classes->{LOADER_TEST23};
 121     my $rsobj23   = $conn->resultset($moniker1);
 122
 123     my $moniker24 = $monikers->{LoAdEr_test24};
 124     my $class24   = $classes->{LoAdEr_test24};
 125     my $rsobj24   = $conn->resultset($moniker2);
 126
 127     isa_ok( $rsobj1, "DBIx::Class::ResultSet" );
 128     isa_ok( $rsobj2, "DBIx::Class::ResultSet" );
 129     isa_ok( $rsobj23, "DBIx::Class::ResultSet" );
 130     isa_ok( $rsobj24, "DBIx::Class::ResultSet" );
 131
 132     my @columns_lt2 = $class2->columns;
 133     is($columns_lt2[0], 'id', "Column Ordering 0");
 134     is($columns_lt2[1], 'dat', "Column Ordering 1");
 135     is($columns_lt2[2], 'dat2', "Column Ordering 2");
 136
 137     my %uniq1 = $class1->unique_constraints;
 138     my $uniq1_test = 0;
 139     foreach my $ucname (keys %uniq1) {
 140         my $cols_arrayref = $uniq1{$ucname};
 141         if(@$cols_arrayref == 1 && $cols_arrayref->[0] eq 'dat') {
 142            $uniq1_test = 1;
 143            last;
 144         }
 145     }
 146     ok($uniq1_test) or diag "Unique constraints not working";
 147
 148     my %uniq2 = $class2->unique_constraints;
 149     my $uniq2_test = 0;
 150     foreach my $ucname (keys %uniq2) {
 151         my $cols_arrayref = $uniq2{$ucname};
 152         if(@$cols_arrayref == 2
 153            && $cols_arrayref->[0] eq 'dat2'
 154            && $cols_arrayref->[1] eq 'dat') {
 155             $uniq2_test = 2;
 156             last;
 157         }
 158     }
 159     ok($uniq2_test) or diag "Multi-col unique constraints not working";
 160
 161     is($moniker2, 'LoaderTest2X', "moniker_map testing");
 162
 163     {
 164         my ($skip_tab, $skip_tabo, $skip_taba, $skip_cmeth,
 165             $skip_rsmeth, $skip_tcomp, $skip_trscomp);
 166
 167         can_ok( $class1, 'test_additional_base' ) or $skip_tab = 1;
 168         can_ok( $class1, 'test_additional_base_override' ) or $skip_tabo = 1;
 169         can_ok( $class1, 'test_additional_base_additional' ) or $skip_taba = 1;
 170         can_ok( $class1, 'dbix_class_testcomponent' ) or $skip_tcomp = 1;
 171         can_ok( $class1, 'loader_test1_classmeth' ) or $skip_cmeth = 1;
 172
 173         TODO: {
 174             local $TODO = "Not yet supported by ResultSetManger code";
 175             can_ok( $rsobj1, 'loader_test1_rsmeth' ) or $skip_rsmeth = 1;
 176         }
 177
 178         SKIP: {
 179             skip "Pre-requisite test failed", 1 if $skip_tab;
 180             is( $class1->test_additional_base, "test_additional_base",
 181                 "Additional Base method" );
 182         }
 183
 184         SKIP: {
 185             skip "Pre-requisite test failed", 1 if $skip_tabo;
 186             is( $class1->test_additional_base_override,
 187                 "test_left_base_override",
 188                 "Left Base overrides Additional Base method" );
 189         }
 190
 191         SKIP: {
 192             skip "Pre-requisite test failed", 1 if $skip_taba;
 193             is( $class1->test_additional_base_additional, "test_additional",
 194                 "Additional Base can use Additional package method" );
 195         }
 196
 197         SKIP: {
 198             skip "Pre-requisite test failed", 1 if $skip_tcomp;
 199             is( $class1->dbix_class_testcomponent,
 200                 'dbix_class_testcomponent works' );
 201         }
 202
 203         SKIP: {
 204             skip "These two tests need Class::Inspector installed", 2
 205                      if $self->{_no_rs_components};
 206             can_ok($rsobj1, 'dbix_class_testrscomponent') or $skip_trscomp = 1;
 207             SKIP: {
 208                 skip "Pre-requisite test failed", 1 if $skip_trscomp;
 209                 is( $rsobj1->dbix_class_testrscomponent,
 210                     'dbix_class_testrscomponent works' );
 211             }
 212         }
 213
 214         SKIP: {
 215             skip "Pre-requisite test failed", 1 if $skip_cmeth;
 216             is( $class1->loader_test1_classmeth, 'all is well' );
 217         }
 218
 219         # XXX put this back in when the TODO above works...
 220         #SKIP: {
 221         #    skip "Pre-requisite test failed", 1 if $skip_rsmeth;
 222         #    is( $rsobj1->loader_test1_rsmeth, 'all is still well' );
 223         #}
 224     }
 225
 226
 227     my $obj    = $rsobj1->find(1);
 228     is( $obj->id,  1 );
 229     is( $obj->dat, "foo" );
 230     is( $rsobj2->count, 4 );
 231     my $saved_id;
 232     eval {
 233         my $new_obj1 = $rsobj1->create({ dat => 'newthing' });
 234         $saved_id = $new_obj1->id;
 235     };
 236     ok(!$@) or diag "Died during create new record using a PK::Auto key: $@";
 237     ok($saved_id) or diag "Failed to get PK::Auto-generated id";
 238
 239     my $new_obj1 = $rsobj1->search({ dat => 'newthing' })->first;
 240     ok($new_obj1) or diag "Cannot find newly inserted PK::Auto record";
 241     is($new_obj1->id, $saved_id);
 242
 243     my ($obj2) = $rsobj2->search({ dat => 'bbb' })->first;
 244     is( $obj2->id, 2 );
 245
 246     SKIP: {
 247         skip $self->{skip_rels}, 42 if $self->{skip_rels};
 248
 249         my $moniker3 = $monikers->{loader_test3};
 250         my $class3   = $classes->{loader_test3};
 251         my $rsobj3   = $conn->resultset($moniker3);
 252
 253         my $moniker4 = $monikers->{loader_test4};
 254         my $class4   = $classes->{loader_test4};
 255         my $rsobj4   = $conn->resultset($moniker4);
 256
 257         my $moniker5 = $monikers->{loader_test5};
 258         my $class5   = $classes->{loader_test5};
 259         my $rsobj5   = $conn->resultset($moniker5);
 260
 261         my $moniker6 = $monikers->{loader_test6};
 262         my $class6   = $classes->{loader_test6};
 263         my $rsobj6   = $conn->resultset($moniker6);
 264
 265         my $moniker7 = $monikers->{loader_test7};
 266         my $class7   = $classes->{loader_test7};
 267         my $rsobj7   = $conn->resultset($moniker7);
 268
 269         my $moniker8 = $monikers->{loader_test8};
 270         my $class8   = $classes->{loader_test8};
 271         my $rsobj8   = $conn->resultset($moniker8);
 272
 273         my $moniker9 = $monikers->{loader_test9};
 274         my $class9   = $classes->{loader_test9};
 275         my $rsobj9   = $conn->resultset($moniker9);
 276
 277         my $moniker16 = $monikers->{loader_test16};
 278         my $class16   = $classes->{loader_test16};
 279         my $rsobj16   = $conn->resultset($moniker16);
 280
 281         my $moniker17 = $monikers->{loader_test17};
 282         my $class17   = $classes->{loader_test17};
 283         my $rsobj17   = $conn->resultset($moniker17);
 284
 285         my $moniker18 = $monikers->{loader_test18};
 286         my $class18   = $classes->{loader_test18};
 287         my $rsobj18   = $conn->resultset($moniker18);
 288
 289         my $moniker19 = $monikers->{loader_test19};
 290         my $class19   = $classes->{loader_test19};
 291         my $rsobj19   = $conn->resultset($moniker19);
 292
 293         my $moniker20 = $monikers->{loader_test20};
 294         my $class20   = $classes->{loader_test20};
 295         my $rsobj20   = $conn->resultset($moniker20);
 296
 297         my $moniker21 = $monikers->{loader_test21};
 298         my $class21   = $classes->{loader_test21};
 299         my $rsobj21   = $conn->resultset($moniker21);
 300
 301         my $moniker22 = $monikers->{loader_test22};
 302         my $class22   = $classes->{loader_test22};
 303         my $rsobj22   = $conn->resultset($moniker22);
 304
 305         isa_ok( $rsobj3, "DBIx::Class::ResultSet" );
 306         isa_ok( $rsobj4, "DBIx::Class::ResultSet" );
 307         isa_ok( $rsobj5, "DBIx::Class::ResultSet" );
 308         isa_ok( $rsobj6, "DBIx::Class::ResultSet" );
 309         isa_ok( $rsobj7, "DBIx::Class::ResultSet" );
 310         isa_ok( $rsobj8, "DBIx::Class::ResultSet" );
 311         isa_ok( $rsobj9, "DBIx::Class::ResultSet" );
 312         isa_ok( $rsobj16, "DBIx::Class::ResultSet" );
 313         isa_ok( $rsobj17, "DBIx::Class::ResultSet" );
 314         isa_ok( $rsobj18, "DBIx::Class::ResultSet" );
 315         isa_ok( $rsobj19, "DBIx::Class::ResultSet" );
 316         isa_ok( $rsobj20, "DBIx::Class::ResultSet" );
 317         isa_ok( $rsobj21, "DBIx::Class::ResultSet" );
 318         isa_ok( $rsobj22, "DBIx::Class::ResultSet" );
 319
 320         # basic rel test
 321         my $obj4 = $rsobj4->find(123);
 322         isa_ok( $obj4->fkid_singular, $class3);
 323
 324         my $obj3 = $rsobj3->find(1);
 325         my $rs_rel4 = $obj3->search_related('loader_test4zes');
 326         isa_ok( $rs_rel4->first, $class4);
 327
 328         # find on multi-col pk
 329         my $obj5 = $rsobj5->find({id1 => 1, id2 => 1});
 330         is( $obj5->id2, 1 );
 331
 332         # mulit-col fk def
 333         my $obj6 = $rsobj6->find(1);
 334         isa_ok( $obj6->loader_test2, $class2);
 335         isa_ok( $obj6->loader_test5, $class5);
 336
 337         # fk that references a non-pk key (UNIQUE)
 338         my $obj8 = $rsobj8->find(1);
 339         isa_ok( $obj8->loader_test7, $class7);
 340
 341         # test double-fk 17 ->-> 16
 342         my $obj17 = $rsobj17->find(33);
 343
 344         my $rs_rel16_one = $obj17->loader16_one;
 345         isa_ok($rs_rel16_one, $class16);
 346         is($rs_rel16_one->dat, 'y16');
 347
 348         my $rs_rel16_two = $obj17->loader16_two;
 349         isa_ok($rs_rel16_two, $class16);
 350         is($rs_rel16_two->dat, 'z16');
 351
 352         my $obj16 = $rsobj16->find(2);
 353         my $rs_rel17 = $obj16->search_related('loader_test17_loader16_ones');
 354         isa_ok($rs_rel17->first, $class17);
 355         is($rs_rel17->first->id, 3);
 356
 357         # XXX test m:m 18 <- 20 -> 19
 358
 359         # XXX test double-fk m:m 21 <- 22 -> 21
 360
 361         # from Chisel's tests...
 362         SKIP: {
 363             if($self->{vendor} =~ /sqlite/i) {
 364                 skip 'SQLite cannot do the advanced tests', 8;
 365             }
 366
 367             my $moniker10 = $monikers->{loader_test10};
 368             my $class10   = $classes->{loader_test10};
 369             my $rsobj10   = $conn->resultset($moniker10);
 370
 371             my $moniker11 = $monikers->{loader_test11};
 372             my $class11   = $classes->{loader_test11};
 373             my $rsobj11   = $conn->resultset($moniker11);
 374
 375             isa_ok( $rsobj10, "DBIx::Class::ResultSet" );
 376             isa_ok( $rsobj11, "DBIx::Class::ResultSet" );
 377
 378             my $obj10 = $rsobj10->create({ subject => 'xyzzy' });
 379
 380             $obj10->update();
 381             ok( defined $obj10, '$obj10 is defined' );
 382
 383             my $obj11 = $rsobj11->create({ loader_test10 => $obj10->id() });
 384             $obj11->update();
 385             ok( defined $obj11, '$obj11 is defined' );
 386
 387             eval {
 388                 my $obj10_2 = $obj11->loader_test10;
 389                 $obj10_2->loader_test11( $obj11->id11() );
 390                 $obj10_2->update();
 391             };
 392             is($@, '', 'No errors after eval{}');
 393
 394             SKIP: {
 395                 skip 'Previous eval block failed', 3
 396                     unless ($@ eq '');
 397
 398                 my $results = $rsobj10->search({ subject => 'xyzzy' });
 399                 is( $results->count(), 1,
 400                     'One $rsobj10 returned from search' );
 401
 402                 my $obj10_3 = $results->first();
 403                 isa_ok( $obj10_3, $class10 );
 404                 is( $obj10_3->loader_test11()->id(), $obj11->id(),
 405                     'found same $rsobj11 object we expected' );
 406             }
 407         }
 408
 409         SKIP: {
 410             skip 'This vendor cannot do inline relationship definitions', 5
 411                 if $self->{no_inline_rels};
 412
 413             my $moniker12 = $monikers->{loader_test12};
 414             my $class12   = $classes->{loader_test12};
 415             my $rsobj12   = $conn->resultset($moniker12);
 416
 417             my $moniker13 = $monikers->{loader_test13};
 418             my $class13   = $classes->{loader_test13};
 419             my $rsobj13   = $conn->resultset($moniker13);
 420
 421             isa_ok( $rsobj12, "DBIx::Class::ResultSet" );
 422             isa_ok( $rsobj13, "DBIx::Class::ResultSet" );
 423
 424             my $obj13 = $rsobj13->find(1);
 425             isa_ok( $obj13->id, $class12 );
 426             isa_ok( $obj13->loader_test12, $class12);
 427             isa_ok( $obj13->dat, $class12);
 428         }
 429
 430         SKIP: {
 431             skip 'This vendor cannot do out-of-line implicit rel defs', 3
 432                 if $self->{no_implicit_rels};
 433             my $moniker14 = $monikers->{loader_test14};
 434             my $class14   = $classes->{loader_test14};
 435             my $rsobj14   = $conn->resultset($moniker14);
 436
 437             my $moniker15 = $monikers->{loader_test15};
 438             my $class15   = $classes->{loader_test15};
 439             my $rsobj15   = $conn->resultset($moniker15);
 440
 441             isa_ok( $rsobj14, "DBIx::Class::ResultSet" );
 442             isa_ok( $rsobj15, "DBIx::Class::ResultSet" );
 443
 444             my $obj15 = $rsobj15->find(1);
 445             isa_ok( $obj15->loader_test14, $class14 );
 446         }
 447     }
 448
 449     # rescan test
 450     SKIP: {
 451         skip $self->{skip_rels}, 4 if $self->{skip_rels};
 452
 453         my @statements_rescan = (
 454             qq{
 455                 CREATE TABLE loader_test25 (
 456                     id INTEGER NOT NULL PRIMARY KEY,
 457                     loader_test2 INTEGER NOT NULL,
 458                     FOREIGN KEY (loader_test2) REFERENCES loader_test2 (id)
 459                 ) $self->{innodb}
 460             },
 461             q{ INSERT INTO loader_test25 (id,loader_test2) VALUES(123, 1) },
 462             q{ INSERT INTO loader_test25 (id,loader_test2) VALUES(321, 2) },
 463         );
 464
 465         my $dbh = $self->dbconnect(1);
 466         $dbh->do($_) for @statements_rescan;
 467         $dbh->disconnect;
 468
 469         my @new = $conn->rescan;
 470         is(scalar(@new), 1);
 471         is($new[0], 'LoaderTest25');
 472
 473         my $rsobj25   = $conn->resultset('LoaderTest25');
 474         isa_ok($rsobj25, 'DBIx::Class::ResultSet');
 475         my $obj25 = $rsobj25->find(123);
 476         isa_ok( $obj25->loader_test2, $class2);
 477     }
 478 }
 479
 480 sub dbconnect {
 481     my ($self, $complain) = @_;
 482
 483     my $dbh = DBI->connect(
 484          $self->{dsn}, $self->{user},
 485          $self->{password},
 486          {
 487              RaiseError => $complain,
 488              PrintError => $complain,
 489              AutoCommit => 1,
 490          }
 491     );
 492
 493     die "Failed to connect to database: $DBI::errstr" if !$dbh;
 494
 495     return $dbh;
 496 }
 497
 498 sub create {
 499     my $self = shift;
 500
 501     $self->{_created} = 1;
 502
 503     my @statements = (
 504         qq{
 505             CREATE TABLE loader_test1 (
 506                 id $self->{auto_inc_pk},
 507                 dat VARCHAR(32) NOT NULL UNIQUE
 508             ) $self->{innodb}
 509         },
 510
 511         q{ INSERT INTO loader_test1 (dat) VALUES('foo') },
 512         q{ INSERT INTO loader_test1 (dat) VALUES('bar') },
 513         q{ INSERT INTO loader_test1 (dat) VALUES('baz') },
 514
 515         qq{
 516             CREATE TABLE loader_test2 (
 517                 id $self->{auto_inc_pk},
 518                 dat VARCHAR(32) NOT NULL,
 519                 dat2 VARCHAR(32) NOT NULL,
 520                 UNIQUE (dat2, dat)
 521             ) $self->{innodb}
 522         },
 523
 524         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('aaa', 'zzz') },
 525         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('bbb', 'yyy') },
 526         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('ccc', 'xxx') },
 527         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('ddd', 'www') },
 528
 529         qq{
 530             CREATE TABLE LOADER_TEST23 (
 531                 ID INTEGER NOT NULL PRIMARY KEY,
 532                 DAT VARCHAR(32) NOT NULL UNIQUE
 533             ) $self->{innodb}
 534         },
 535
 536         qq{
 537             CREATE TABLE LoAdEr_test24 (
 538                 iD INTEGER NOT NULL PRIMARY KEY,
 539                 DaT VARCHAR(32) NOT NULL UNIQUE
 540             ) $self->{innodb}
 541         },
 542     );
 543
 544     my @statements_reltests = (
 545         qq{
 546             CREATE TABLE loader_test3 (
 547                 id INTEGER NOT NULL PRIMARY KEY,
 548                 dat VARCHAR(32)
 549             ) $self->{innodb}
 550         },
 551
 552         q{ INSERT INTO loader_test3 (id,dat) VALUES(1,'aaa') },
 553         q{ INSERT INTO loader_test3 (id,dat) VALUES(2,'bbb') },
 554         q{ INSERT INTO loader_test3 (id,dat) VALUES(3,'ccc') },
 555         q{ INSERT INTO loader_test3 (id,dat) VALUES(4,'ddd') },
 556
 557         qq{
 558             CREATE TABLE loader_test4 (
 559                 id INTEGER NOT NULL PRIMARY KEY,
 560                 fkid INTEGER NOT NULL,
 561                 dat VARCHAR(32),
 562                 FOREIGN KEY( fkid ) REFERENCES loader_test3 (id)
 563             ) $self->{innodb}
 564         },
 565
 566         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(123,1,'aaa') },
 567         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(124,2,'bbb') },
 568         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(125,3,'ccc') },
 569         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(126,4,'ddd') },
 570
 571         qq{
 572             CREATE TABLE loader_test5 (
 573                 id1 INTEGER NOT NULL,
 574                 iD2 INTEGER NOT NULL,
 575                 dat VARCHAR(8),
 576                 PRIMARY KEY (id1,id2)
 577             ) $self->{innodb}
 578         },
 579
 580         q{ INSERT INTO loader_test5 (id1,id2,dat) VALUES (1,1,'aaa') },
 581
 582         qq{
 583             CREATE TABLE loader_test6 (
 584                 id INTEGER NOT NULL PRIMARY KEY,
 585                 Id2 INTEGER,
 586                 loader_test2 INTEGER,
 587                 dat VARCHAR(8),
 588                 FOREIGN KEY (loader_test2)  REFERENCES loader_test2 (id),
 589                 FOREIGN KEY(id,Id2) REFERENCES loader_test5 (id1,iD2)
 590             ) $self->{innodb}
 591         },
 592
 593         (q{ INSERT INTO loader_test6 (id, id2,loader_test2,dat) } .
 594          q{ VALUES (1, 1,1,'aaa') }),
 595
 596         qq{
 597             CREATE TABLE loader_test7 (
 598                 id INTEGER NOT NULL PRIMARY KEY,
 599                 id2 VARCHAR(8) NOT NULL UNIQUE,
 600                 dat VARCHAR(8)
 601             ) $self->{innodb}
 602         },
 603
 604         q{ INSERT INTO loader_test7 (id,id2,dat) VALUES (1,'aaa','bbb') },
 605
 606         qq{
 607             CREATE TABLE loader_test8 (
 608                 id INTEGER NOT NULL PRIMARY KEY,
 609                 loader_test7 VARCHAR(8) NOT NULL,
 610                 dat VARCHAR(8),
 611                 FOREIGN KEY (loader_test7) REFERENCES loader_test7 (id2)
 612             ) $self->{innodb}
 613         },
 614
 615         (q{ INSERT INTO loader_test8 (id,loader_test7,dat) } .
 616          q{ VALUES (1,'aaa','bbb') }),
 617
 618         qq{
 619             CREATE TABLE loader_test9 (
 620                 loader_test9 VARCHAR(8) NOT NULL
 621             ) $self->{innodb}
 622         },
 623
 624         qq{
 625             CREATE TABLE loader_test16 (
 626                 id INTEGER NOT NULL PRIMARY KEY,
 627                 dat  VARCHAR(8)
 628             ) $self->{innodb}
 629         },
 630
 631         qq{ INSERT INTO loader_test16 (id,dat) VALUES (2,'x16') },
 632         qq{ INSERT INTO loader_test16 (id,dat) VALUES (4,'y16') },
 633         qq{ INSERT INTO loader_test16 (id,dat) VALUES (6,'z16') },
 634
 635         qq{
 636             CREATE TABLE loader_test17 (
 637                 id INTEGER NOT NULL PRIMARY KEY,
 638                 loader16_one INTEGER,
 639                 loader16_two INTEGER,
 640                 FOREIGN KEY (loader16_one) REFERENCES loader_test16 (id),
 641                 FOREIGN KEY (loader16_two) REFERENCES loader_test16 (id)
 642             ) $self->{innodb}
 643         },
 644
 645         qq{ INSERT INTO loader_test17 (id, loader16_one, loader16_two) VALUES (3, 2, 4) },
 646         qq{ INSERT INTO loader_test17 (id, loader16_one, loader16_two) VALUES (33, 4, 6) },
 647
 648         qq{
 649             CREATE TABLE loader_test18 (
 650                 id INTEGER NOT NULL PRIMARY KEY,
 651                 dat  VARCHAR(8)
 652             ) $self->{innodb}
 653         },
 654
 655         qq{ INSERT INTO loader_test18 (id,dat) VALUES (1,'x18') },
 656         qq{ INSERT INTO loader_test18 (id,dat) VALUES (2,'y18') },
 657         qq{ INSERT INTO loader_test18 (id,dat) VALUES (3,'z18') },
 658
 659         qq{
 660             CREATE TABLE loader_test19 (
 661                 id INTEGER NOT NULL PRIMARY KEY,
 662                 dat  VARCHAR(8)
 663             ) $self->{innodb}
 664         },
 665
 666         qq{ INSERT INTO loader_test19 (id,dat) VALUES (4,'x19') },
 667         qq{ INSERT INTO loader_test19 (id,dat) VALUES (5,'y19') },
 668         qq{ INSERT INTO loader_test19 (id,dat) VALUES (6,'z19') },
 669
 670         qq{
 671             CREATE TABLE loader_test20 (
 672                 parent INTEGER NOT NULL,
 673                 child INTEGER NOT NULL,
 674                 PRIMARY KEY (parent, child),
 675                 FOREIGN KEY (parent) REFERENCES loader_test18 (id),
 676                 FOREIGN KEY (child) REFERENCES loader_test19 (id)
 677             ) $self->{innodb}
 678         },
 679
 680         q{ INSERT INTO loader_test20 (parent, child) VALUES (1,4) },
 681         q{ INSERT INTO loader_test20 (parent, child) VALUES (2,5) },
 682         q{ INSERT INTO loader_test20 (parent, child) VALUES (3,6) },
 683
 684         qq{
 685             CREATE TABLE loader_test21 (
 686                 id INTEGER NOT NULL PRIMARY KEY,
 687                 dat  VARCHAR(8)
 688             ) $self->{innodb}
 689         },
 690
 691         q{ INSERT INTO loader_test21 (id,dat) VALUES (7,'a21')},
 692         q{ INSERT INTO loader_test21 (id,dat) VALUES (11,'b21')},
 693         q{ INSERT INTO loader_test21 (id,dat) VALUES (13,'c21')},
 694         q{ INSERT INTO loader_test21 (id,dat) VALUES (17,'d21')},
 695
 696         qq{
 697             CREATE TABLE loader_test22 (
 698                 parent INTEGER NOT NULL,
 699                 child INTEGER NOT NULL,
 700                 PRIMARY KEY (parent, child),
 701                 FOREIGN KEY (parent) REFERENCES loader_test21 (id),
 702                 FOREIGN KEY (child) REFERENCES loader_test21 (id)
 703             ) $self->{innodb}
 704         },
 705
 706         q{ INSERT INTO loader_test22 (parent, child) VALUES (7,11)},
 707         q{ INSERT INTO loader_test22 (parent, child) VALUES (11,13)},
 708         q{ INSERT INTO loader_test22 (parent, child) VALUES (13,17)},
 709     );
 710
 711     my @statements_advanced = (
 712         qq{
 713             CREATE TABLE loader_test10 (
 714                 id10 $self->{auto_inc_pk},
 715                 subject VARCHAR(8),
 716                 loader_test11 INTEGER
 717             ) $self->{innodb}
 718         },
 719
 720         qq{
 721             CREATE TABLE loader_test11 (
 722                 id11 $self->{auto_inc_pk},
 723                 message VARCHAR(8) DEFAULT 'foo',
 724                 loader_test10 INTEGER,
 725                 FOREIGN KEY (loader_test10) REFERENCES loader_test10 (id10)
 726             ) $self->{innodb}
 727         },
 728
 729         (q{ ALTER TABLE loader_test10 ADD CONSTRAINT } .
 730          q{ loader_test11_fk FOREIGN KEY (loader_test11) } .
 731          q{ REFERENCES loader_test11 (id11) }),
 732     );
 733
 734     my @statements_inline_rels = (
 735         qq{
 736             CREATE TABLE loader_test12 (
 737                 id INTEGER NOT NULL PRIMARY KEY,
 738                 id2 VARCHAR(8) NOT NULL UNIQUE,
 739                 dat VARCHAR(8) NOT NULL UNIQUE
 740             ) $self->{innodb}
 741         },
 742
 743         q{ INSERT INTO loader_test12 (id,id2,dat) VALUES (1,'aaa','bbb') },
 744
 745         qq{
 746             CREATE TABLE loader_test13 (
 747                 id INTEGER NOT NULL PRIMARY KEY REFERENCES loader_test12,
 748                 loader_test12 VARCHAR(8) NOT NULL REFERENCES loader_test12 (id2),
 749                 dat VARCHAR(8) REFERENCES loader_test12 (dat)
 750             ) $self->{innodb}
 751         },
 752
 753         (q{ INSERT INTO loader_test13 (id,loader_test12,dat) } .
 754          q{ VALUES (1,'aaa','bbb') }),
 755     );
 756
 757
 758     my @statements_implicit_rels = (
 759         qq{
 760             CREATE TABLE loader_test14 (
 761                 id INTEGER NOT NULL PRIMARY KEY,
 762                 dat VARCHAR(8)
 763             ) $self->{innodb}
 764         },
 765
 766         q{ INSERT INTO loader_test14 (id,dat) VALUES (123,'aaa') },
 767
 768         qq{
 769             CREATE TABLE loader_test15 (
 770                 id INTEGER NOT NULL PRIMARY KEY,
 771                 loader_test14 INTEGER NOT NULL,
 772                 FOREIGN KEY (loader_test14) REFERENCES loader_test14
 773             ) $self->{innodb}
 774         },
 775
 776         q{ INSERT INTO loader_test15 (id,loader_test14) VALUES (1,123) },
 777     );
 778
 779     $self->drop_tables;
 780
 781     my $dbh = $self->dbconnect(1);
 782
 783     # Silence annoying but harmless postgres "NOTICE:  CREATE TABLE..."
 784     local $SIG{__WARN__} = sub {
 785         my $msg = shift;
 786         print STDERR $msg unless $msg =~ m{^NOTICE:\s+CREATE TABLE};
 787     };
 788
 789     $dbh->do($_) for (@statements);
 790     unless($self->{skip_rels}) {
 791         # hack for now, since DB2 doesn't like inline comments, and we need
 792         # to test one for mysql, which works on everyone else...
 793         # this all needs to be refactored anyways.
 794         $dbh->do($_) for (@statements_reltests);
 795         unless($self->{vendor} =~ /sqlite/i) {
 796             $dbh->do($_) for (@statements_advanced);
 797         }
 798         unless($self->{no_inline_rels}) {
 799             $dbh->do($_) for (@statements_inline_rels);
 800         }
 801         unless($self->{no_implicit_rels}) {
 802             $dbh->do($_) for (@statements_implicit_rels);
 803         }
 804     }
 805     $dbh->disconnect();
 806 }
 807
 808 sub drop_tables {
 809     my $self = shift;
 810
 811     my @tables = qw/
 812         loader_test1
 813         loader_test2
 814         LOADER_TEST23
 815         LoAdEr_test24
 816     /;
 817
 818     my @tables_reltests = qw/
 819         loader_test4
 820         loader_test3
 821         loader_test6
 822         loader_test5
 823         loader_test8
 824         loader_test7
 825         loader_test9
 826         loader_test17
 827         loader_test16
 828         loader_test20
 829         loader_test19
 830         loader_test18
 831         loader_test22
 832         loader_test21
 833     /;
 834
 835     my @tables_advanced = qw/
 836         loader_test11
 837         loader_test10
 838     /;
 839
 840     my @tables_inline_rels = qw/
 841         loader_test13
 842         loader_test12
 843     /;
 844
 845     my @tables_implicit_rels = qw/
 846         loader_test15
 847         loader_test14
 848     /;
 849
 850     my @tables_rescan = qw/ loader_test25 /;
 851
 852     my $drop_fk_mysql =
 853         q{ALTER TABLE loader_test10 DROP FOREIGN KEY loader_test11_fk;};
 854
 855     my $drop_fk =
 856         q{ALTER TABLE loader_test10 DROP CONSTRAINT loader_test11_fk;};
 857
 858     my $dbh = $self->dbconnect(0);
 859
 860     unless($self->{skip_rels}) {
 861         $dbh->do("DROP TABLE $_") for (@tables_reltests);
 862         unless($self->{vendor} =~ /sqlite/i) {
 863             if($self->{vendor} =~ /mysql/i) {
 864                 $dbh->do($drop_fk_mysql);
 865             }
 866             else {
 867                 $dbh->do($drop_fk);
 868             }
 869             $dbh->do("DROP TABLE $_") for (@tables_advanced);
 870         }
 871         unless($self->{no_inline_rels}) {
 872             $dbh->do("DROP TABLE $_") for (@tables_inline_rels);
 873         }
 874         unless($self->{no_implicit_rels}) {
 875             $dbh->do("DROP TABLE $_") for (@tables_implicit_rels);
 876         }
 877         $dbh->do("DROP TABLE $_") for (@tables_rescan);
 878     }
 879     $dbh->do("DROP TABLE $_") for (@tables);
 880     $dbh->disconnect;
 881 }
 882
 883 sub DESTROY {
 884     my $self = shift;
 885     $self->drop_tables if $self->{_created};
 886 }
 887
 888 1;