t/lib/dbixcsl_common_tests.pm

   1 package dbixcsl_common_tests;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use DBIx::Class::Schema::Loader;
   8 use DBI;
   9
  10 sub new {
  11     my $class = shift;
  12
  13     my $self;
  14
  15     if( ref($_[0]) eq 'HASH') {
  16        my $args = shift;
  17        $self = { (%$args) };
  18     }
  19     else {
  20        $self = { @_ };
  21     }
  22
  23     # Only MySQL uses this
  24     $self->{innodb} ||= '';
  25
  26     $self->{verbose} = $ENV{TEST_VERBOSE} || 0;
  27
  28     return bless $self => $class;
  29 }
  30
  31 sub skip_tests {
  32     my ($self, $why) = @_;
  33
  34     plan skip_all => $why;
  35 }
  36
  37 sub _monikerize {
  38     my $name = shift;
  39     return 'LoaderTest2X' if $name =~ /^loader_test2$/i;
  40     return undef;
  41 }
  42
  43 sub run_tests {
  44     my $self = shift;
  45
  46     plan tests => 50;
  47
  48     $self->create();
  49
  50     my $schema_class = 'DBIXCSL_Test::Schema';
  51
  52     my $debug = ($self->{verbose} > 1) ? 1 : 0;
  53
  54     my %loader_opts = (
  55         connect_info            => [ $self->{dsn}, $self->{user},
  56                                      $self->{password} ],
  57         constraint              => '^(?:\S+\.)?(?i:loader_test)[0-9]+$',
  58         relationships           => 1,
  59         additional_classes      => 'TestAdditional',
  60         additional_base_classes => 'TestAdditionalBase',
  61         left_base_classes       => [ qw/TestLeftBase/ ],
  62         components              => [ qw/TestComponent/ ],
  63         resultset_components    => [ qw/TestRSComponent/ ],
  64         inflect_map             => { loader_test4 => 'loader_test4zes' },
  65         moniker_map             => \&_monikerize,
  66         debug                   => $debug,
  67     );
  68
  69     $loader_opts{db_schema} = $self->{db_schema} if $self->{db_schema};
  70     $loader_opts{drop_db_schema} = $self->{drop_db_schema} if $self->{drop_db_schema};
  71
  72     eval qq{
  73         package $schema_class;
  74         use base qw/DBIx::Class::Schema::Loader/;
  75
  76         __PACKAGE__->load_from_connection(\%loader_opts);
  77     };
  78     ok(!$@, "Loader initialization") or diag $@;
  79
  80     my $conn = $schema_class->connect($self->{dsn},$self->{user},$self->{password});
  81     my $monikers = $schema_class->loader->monikers;
  82     my $classes = $schema_class->loader->classes;
  83
  84     my $moniker1 = $monikers->{loader_test1};
  85     my $class1   = $classes->{loader_test1};
  86     my $rsobj1   = $conn->resultset($moniker1);
  87
  88     my $moniker2 = $monikers->{loader_test2};
  89     my $class2   = $classes->{loader_test2};
  90     my $rsobj2   = $conn->resultset($moniker2);
  91
  92     isa_ok( $rsobj1, "DBIx::Class::ResultSet" );
  93     isa_ok( $rsobj2, "DBIx::Class::ResultSet" );
  94
  95     is($moniker2, 'LoaderTest2X', "moniker_map testing");
  96
  97     {
  98         my ($skip_tab, $skip_tabo, $skip_taba, $skip_cmeth,
  99             $skip_rsmeth, $skip_tcomp, $skip_trscomp);
 100
 101         can_ok( $class1, 'test_additional_base' ) or $skip_tab = 1;
 102         can_ok( $class1, 'test_additional_base_override' ) or $skip_tabo = 1;
 103         can_ok( $class1, 'test_additional_base_additional' ) or $skip_taba = 1;
 104         can_ok( $class1, 'dbix_class_testcomponent' ) or $skip_tcomp = 1;
 105         can_ok( $rsobj1, 'dbix_class_testrscomponent' ) or $skip_trscomp = 1;
 106         can_ok( $class1, 'loader_test1_classmeth' ) or $skip_cmeth = 1;
 107
 108         TODO: {
 109             local $TODO = "Not yet supported by ResultSetManger code";
 110             can_ok( $rsobj1, 'loader_test1_rsmeth' ) or $skip_rsmeth = 1;
 111         }
 112
 113         SKIP: {
 114             skip "Pre-requisite test failed", 1 if $skip_tab;
 115             is( $class1->test_additional_base, "test_additional_base",
 116                 "Additional Base method" );
 117         }
 118
 119         SKIP: {
 120             skip "Pre-requisite test failed", 1 if $skip_tabo;
 121             is( $class1->test_additional_base_override,
 122                 "test_left_base_override",
 123                 "Left Base overrides Additional Base method" );
 124         }
 125
 126         SKIP: {
 127             skip "Pre-requisite test failed", 1 if $skip_taba;
 128             is( $class1->test_additional_base_additional, "test_additional",
 129                 "Additional Base can use Additional package method" );
 130         }
 131
 132         SKIP: {
 133             skip "Pre-requisite test failed", 1 if $skip_tcomp;
 134             is( $class1->dbix_class_testcomponent,
 135                 'dbix_class_testcomponent works' );
 136         }
 137
 138         SKIP: {
 139             skip "Pre-requisite test failed", 1 if $skip_trscomp;
 140             is( $rsobj1->dbix_class_testrscomponent,
 141                 'dbix_class_testrscomponent works' );
 142         }
 143
 144         SKIP: {
 145             skip "Pre-requisite test failed", 1 if $skip_cmeth;
 146             is( $class1->loader_test1_classmeth, 'all is well' );
 147         }
 148
 149         # XXX put this back in when the TODO above works...
 150         #SKIP: {
 151         #    skip "Pre-requisite test failed", 1 if $skip_rsmeth;
 152         #    is( $rsobj1->loader_test1_rsmeth, 'all is still well' );
 153         #}
 154     }
 155
 156
 157     my $obj    = $rsobj1->find(1);
 158     is( $obj->id,  1 );
 159     is( $obj->dat, "foo" );
 160     is( $rsobj2->count, 4 );
 161
 162     my ($obj2) = $rsobj2->find( dat => 'bbb' );
 163     is( $obj2->id, 2 );
 164
 165     SKIP: {
 166         skip $self->{skip_rels}, 29 if $self->{skip_rels};
 167
 168         my $moniker3 = $monikers->{loader_test3};
 169         my $class3   = $classes->{loader_test3};
 170         my $rsobj3   = $conn->resultset($moniker3);
 171
 172         my $moniker4 = $monikers->{loader_test4};
 173         my $class4   = $classes->{loader_test4};
 174         my $rsobj4   = $conn->resultset($moniker4);
 175
 176         my $moniker5 = $monikers->{loader_test5};
 177         my $class5   = $classes->{loader_test5};
 178         my $rsobj5   = $conn->resultset($moniker5);
 179
 180         my $moniker6 = $monikers->{loader_test6};
 181         my $class6   = $classes->{loader_test6};
 182         my $rsobj6   = $conn->resultset($moniker6);
 183
 184         my $moniker7 = $monikers->{loader_test7};
 185         my $class7   = $classes->{loader_test7};
 186         my $rsobj7   = $conn->resultset($moniker7);
 187
 188         my $moniker8 = $monikers->{loader_test8};
 189         my $class8   = $classes->{loader_test8};
 190         my $rsobj8   = $conn->resultset($moniker8);
 191
 192         my $moniker9 = $monikers->{loader_test9};
 193         my $class9   = $classes->{loader_test9};
 194         my $rsobj9   = $conn->resultset($moniker9);
 195
 196         isa_ok( $rsobj3, "DBIx::Class::ResultSet" );
 197         isa_ok( $rsobj4, "DBIx::Class::ResultSet" );
 198         isa_ok( $rsobj5, "DBIx::Class::ResultSet" );
 199         isa_ok( $rsobj6, "DBIx::Class::ResultSet" );
 200         isa_ok( $rsobj7, "DBIx::Class::ResultSet" );
 201         isa_ok( $rsobj8, "DBIx::Class::ResultSet" );
 202         isa_ok( $rsobj9, "DBIx::Class::ResultSet" );
 203
 204         # basic rel test
 205         my $obj4 = $rsobj4->find(123);
 206         isa_ok( $obj4->fkid, $class3);
 207
 208         my $obj3 = $rsobj3->find(1);
 209         my $rs_rel4 = $obj3->search_related('loader_test4zes');
 210         isa_ok( $rs_rel4->first, $class4);
 211
 212         # fk def in comments should not be parsed
 213         my $obj5 = $rsobj5->find( id1 => 1, id2 => 1 );
 214         is( ref( $obj5->id2 ), '' );
 215
 216         # mulit-col fk def
 217         my $obj6 = $rsobj6->find(1);
 218         isa_ok( $obj6->loader_test2, $class2);
 219         isa_ok( $obj6->loader_test5, $class5);
 220
 221         # fk that references a non-pk key (UNIQUE)
 222         my $obj8 = $rsobj8->find(1);
 223         isa_ok( $obj8->loader_test7, $class7);
 224
 225         # from Chisel's tests...
 226         SKIP: {
 227             if($self->{vendor} =~ /sqlite/i) {
 228                 skip 'SQLite cannot do the advanced tests', 8;
 229             }
 230
 231             my $moniker10 = $monikers->{loader_test10};
 232             my $class10   = $classes->{loader_test10};
 233             my $rsobj10   = $conn->resultset($moniker10);
 234
 235             my $moniker11 = $monikers->{loader_test11};
 236             my $class11   = $classes->{loader_test11};
 237             my $rsobj11   = $conn->resultset($moniker11);
 238
 239             isa_ok( $rsobj10, "DBIx::Class::ResultSet" );
 240             isa_ok( $rsobj11, "DBIx::Class::ResultSet" );
 241
 242             my $obj10 = $rsobj10->create({ subject => 'xyzzy' });
 243
 244             $obj10->update();
 245             ok( defined $obj10, '$obj10 is defined' );
 246
 247             my $obj11 = $rsobj11->create({ loader_test10 => $obj10->id() });
 248             $obj11->update();
 249             ok( defined $obj11, '$obj11 is defined' );
 250
 251             eval {
 252                 my $obj10_2 = $obj11->loader_test10;
 253                 $obj10_2->loader_test11( $obj11->id11() );
 254                 $obj10_2->update();
 255             };
 256             is($@, '', 'No errors after eval{}');
 257
 258             SKIP: {
 259                 skip 'Previous eval block failed', 3
 260                     unless ($@ eq '');
 261
 262                 my $results = $rsobj10->search({ subject => 'xyzzy' });
 263                 is( $results->count(), 1,
 264                     'One $rsobj10 returned from search' );
 265
 266                 my $obj10_3 = $results->first();
 267                 isa_ok( $obj10_3, $class10 );
 268                 is( $obj10_3->loader_test11()->id(), $obj11->id(),
 269                     'found same $rsobj11 object we expected' );
 270             }
 271         }
 272
 273         SKIP: {
 274             skip 'This vendor cannot do inline relationship definitions', 5
 275                 if $self->{no_inline_rels};
 276
 277             my $moniker12 = $monikers->{loader_test12};
 278             my $class12   = $classes->{loader_test12};
 279             my $rsobj12   = $conn->resultset($moniker12);
 280
 281             my $moniker13 = $monikers->{loader_test13};
 282             my $class13   = $classes->{loader_test13};
 283             my $rsobj13   = $conn->resultset($moniker13);
 284
 285             isa_ok( $rsobj12, "DBIx::Class::ResultSet" );
 286             isa_ok( $rsobj13, "DBIx::Class::ResultSet" );
 287
 288             my $obj13 = $rsobj13->find(1);
 289             isa_ok( $obj13->id, $class12 );
 290             isa_ok( $obj13->loader_test12, $class12);
 291             isa_ok( $obj13->dat, $class12);
 292         }
 293
 294         SKIP: {
 295             skip 'This vendor cannot do out-of-line implicit rel defs', 3
 296                 if $self->{no_implicit_rels};
 297             my $moniker14 = $monikers->{loader_test14};
 298             my $class14   = $classes->{loader_test14};
 299             my $rsobj14   = $conn->resultset($moniker14);
 300
 301             my $moniker15 = $monikers->{loader_test15};
 302             my $class15   = $classes->{loader_test15};
 303             my $rsobj15   = $conn->resultset($moniker15);
 304
 305             isa_ok( $rsobj14, "DBIx::Class::ResultSet" );
 306             isa_ok( $rsobj15, "DBIx::Class::ResultSet" );
 307
 308             my $obj15 = $rsobj15->find(1);
 309             isa_ok( $obj15->loader_test14, $class14 );
 310         }
 311     }
 312 }
 313
 314 sub dbconnect {
 315     my ($self, $complain) = @_;
 316
 317     my $dbh = DBI->connect(
 318          $self->{dsn}, $self->{user},
 319          $self->{password},
 320          {
 321              RaiseError => $complain,
 322              PrintError => $complain,
 323              AutoCommit => 1,
 324          }
 325     );
 326
 327     die "Failed to connect to database: $DBI::errstr" if !$dbh;
 328
 329     return $dbh;
 330 }
 331
 332 sub create {
 333     my $self = shift;
 334
 335     my @statements = (
 336         qq{
 337             CREATE TABLE loader_test1 (
 338                 id $self->{auto_inc_pk},
 339                 dat VARCHAR(32)
 340             ) $self->{innodb}
 341         },
 342
 343         q{ INSERT INTO loader_test1 (dat) VALUES('foo') },
 344         q{ INSERT INTO loader_test1 (dat) VALUES('bar') },
 345         q{ INSERT INTO loader_test1 (dat) VALUES('baz') },
 346
 347         qq{
 348             CREATE TABLE loader_test2 (
 349                 id $self->{auto_inc_pk},
 350                 dat VARCHAR(32)
 351             ) $self->{innodb}
 352         },
 353
 354         q{ INSERT INTO loader_test2 (dat) VALUES('aaa') },
 355         q{ INSERT INTO loader_test2 (dat) VALUES('bbb') },
 356         q{ INSERT INTO loader_test2 (dat) VALUES('ccc') },
 357         q{ INSERT INTO loader_test2 (dat) VALUES('ddd') },
 358     );
 359
 360     my @statements_reltests = (
 361         qq{
 362             CREATE TABLE loader_test3 (
 363                 id INTEGER NOT NULL PRIMARY KEY,
 364                 dat VARCHAR(32)
 365             ) $self->{innodb}
 366         },
 367
 368         q{ INSERT INTO loader_test3 (id,dat) VALUES(1,'aaa') },
 369         q{ INSERT INTO loader_test3 (id,dat) VALUES(2,'bbb') },
 370         q{ INSERT INTO loader_test3 (id,dat) VALUES(3,'ccc') },
 371         q{ INSERT INTO loader_test3 (id,dat) VALUES(4,'ddd') },
 372
 373         qq{
 374             CREATE TABLE loader_test4 (
 375                 id INTEGER NOT NULL PRIMARY KEY,
 376                 fkid INTEGER NOT NULL,
 377                 dat VARCHAR(32),
 378                 FOREIGN KEY (fkid) REFERENCES loader_test3 (id)
 379             ) $self->{innodb}
 380         },
 381
 382         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(123,1,'aaa') },
 383         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(124,2,'bbb') },
 384         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(125,3,'ccc') },
 385         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(126,4,'ddd') },
 386
 387         qq{
 388             CREATE TABLE loader_test5 (
 389                 id1 INTEGER NOT NULL,
 390                 id2 INTEGER NOT NULL, -- , id2 INTEGER REFERENCES loader_test1,
 391                 dat VARCHAR(8),
 392                 PRIMARY KEY (id1,id2)
 393             ) $self->{innodb}
 394         },
 395
 396         q{ INSERT INTO loader_test5 (id1,id2,dat) VALUES (1,1,'aaa') },
 397
 398         qq{
 399             CREATE TABLE loader_test6 (
 400                 id INTEGER NOT NULL PRIMARY KEY,
 401                 id2 INTEGER,
 402                 loader_test2 INTEGER,
 403                 dat VARCHAR(8),
 404                 FOREIGN KEY (loader_test2) REFERENCES loader_test2 (id),
 405                 FOREIGN KEY (id, id2 ) REFERENCES loader_test5 (id1,id2)
 406             ) $self->{innodb}
 407         },
 408
 409         (q{ INSERT INTO loader_test6 (id, id2,loader_test2,dat) } .
 410          q{ VALUES (1, 1,1,'aaa') }),
 411
 412         qq{
 413             CREATE TABLE loader_test7 (
 414                 id INTEGER NOT NULL PRIMARY KEY,
 415                 id2 VARCHAR(8) NOT NULL UNIQUE,
 416                 dat VARCHAR(8)
 417             ) $self->{innodb}
 418         },
 419
 420         q{ INSERT INTO loader_test7 (id,id2,dat) VALUES (1,'aaa','bbb') },
 421
 422         qq{
 423             CREATE TABLE loader_test8 (
 424                 id INTEGER NOT NULL PRIMARY KEY,
 425                 loader_test7 VARCHAR(8) NOT NULL,
 426                 dat VARCHAR(8),
 427                 FOREIGN KEY (loader_test7) REFERENCES loader_test7 (id2)
 428             ) $self->{innodb}
 429         },
 430
 431         (q{ INSERT INTO loader_test8 (id,loader_test7,dat) } .
 432          q{ VALUES (1,'aaa','bbb') }),
 433
 434         qq{
 435             CREATE TABLE loader_test9 (
 436                 loader_test9 VARCHAR(8) NOT NULL
 437             ) $self->{innodb}
 438         },
 439     );
 440
 441     my @statements_advanced = (
 442         qq{
 443             CREATE TABLE loader_test10 (
 444                 id10 $self->{auto_inc_pk},
 445                 subject VARCHAR(8),
 446                 loader_test11 INTEGER
 447             ) $self->{innodb}
 448         },
 449
 450         qq{
 451             CREATE TABLE loader_test11 (
 452                 id11 $self->{auto_inc_pk},
 453                 message VARCHAR(8) DEFAULT 'foo',
 454                 loader_test10 INTEGER,
 455                 FOREIGN KEY (loader_test10) REFERENCES loader_test10 (id10)
 456             ) $self->{innodb}
 457         },
 458
 459         (q{ ALTER TABLE loader_test10 ADD CONSTRAINT } .
 460          q{ loader_test11_fk FOREIGN KEY (loader_test11) } .
 461          q{ REFERENCES loader_test11 (id11) }),
 462     );
 463
 464     my @statements_inline_rels = (
 465         qq{
 466             CREATE TABLE loader_test12 (
 467                 id INTEGER NOT NULL PRIMARY KEY,
 468                 id2 VARCHAR(8) NOT NULL UNIQUE,
 469                 dat VARCHAR(8) NOT NULL UNIQUE
 470             ) $self->{innodb}
 471         },
 472
 473         q{ INSERT INTO loader_test12 (id,id2,dat) VALUES (1,'aaa','bbb') },
 474
 475         qq{
 476             CREATE TABLE loader_test13 (
 477                 id INTEGER NOT NULL PRIMARY KEY REFERENCES loader_test12,
 478                 loader_test12 VARCHAR(8) NOT NULL REFERENCES loader_test12 (id2),
 479                 dat VARCHAR(8) REFERENCES loader_test12 (dat)
 480             ) $self->{innodb}
 481         },
 482
 483         (q{ INSERT INTO loader_test13 (id,loader_test12,dat) } .
 484          q{ VALUES (1,'aaa','bbb') }),
 485     );
 486
 487
 488     my @statements_implicit_rels = (
 489         qq{
 490             CREATE TABLE loader_test14 (
 491                 id INTEGER NOT NULL PRIMARY KEY,
 492                 dat VARCHAR(8)
 493             ) $self->{innodb}
 494         },
 495
 496         q{ INSERT INTO loader_test14 (id,dat) VALUES (123,'aaa') },
 497
 498         qq{
 499             CREATE TABLE loader_test15 (
 500                 id INTEGER NOT NULL PRIMARY KEY,
 501                 loader_test14 INTEGER NOT NULL,
 502                 FOREIGN KEY (loader_test14) REFERENCES loader_test14
 503             ) $self->{innodb}
 504         },
 505
 506         q{ INSERT INTO loader_test15 (id,loader_test14) VALUES (1,123) },
 507    );
 508
 509     $self->drop_tables;
 510
 511     $self->{created} = 1;
 512
 513     my $dbh = $self->dbconnect(1);
 514
 515     # Silence annoying but harmless postgres "NOTICE:  CREATE TABLE..."
 516     local $SIG{__WARN__} = sub {
 517         my $msg = shift;
 518         print STDERR $msg unless $msg =~ m{^NOTICE:\s+CREATE TABLE};
 519     };
 520
 521     $dbh->do($_) for (@statements);
 522     unless($self->{skip_rels}) {
 523         # hack for now, since DB2 doesn't like inline comments, and we need
 524         # to test one for mysql, which works on everyone else...
 525         # this all needs to be refactored anyways.
 526         if($self->{vendor} =~ /DB2/i) {
 527             @statements_reltests = map { s/--.*\n//; $_ } @statements_reltests;
 528         }
 529         $dbh->do($_) for (@statements_reltests);
 530         unless($self->{vendor} =~ /sqlite/i) {
 531             $dbh->do($_) for (@statements_advanced);
 532         }
 533         unless($self->{no_inline_rels}) {
 534             $dbh->do($_) for (@statements_inline_rels);
 535         }
 536         unless($self->{no_implicit_rels}) {
 537             $dbh->do($_) for (@statements_implicit_rels);
 538         }
 539     }
 540     $dbh->disconnect();
 541 }
 542
 543 sub drop_tables {
 544     my $self = shift;
 545
 546     return unless $self->{created};
 547
 548     my @tables = qw/
 549         loader_test1
 550         loader_test2
 551     /;
 552
 553     my @tables_reltests = qw/
 554         loader_test4
 555         loader_test3
 556         loader_test6
 557         loader_test5
 558         loader_test8
 559         loader_test7
 560         loader_test9
 561     /;
 562
 563     my @tables_advanced = qw/
 564         loader_test11
 565         loader_test10
 566     /;
 567
 568     my @tables_inline_rels = qw/
 569         loader_test13
 570         loader_test12
 571     /;
 572
 573     my @tables_implicit_rels = qw/
 574         loader_test15
 575         loader_test14
 576     /;
 577
 578     my $drop_fk_mysql =
 579         q{ALTER TABLE loader_test10 DROP FOREIGN KEY loader_test11_fk;};
 580
 581     my $drop_fk =
 582         q{ALTER TABLE loader_test10 DROP CONSTRAINT loader_test11_fk;};
 583
 584     my $dbh = $self->dbconnect(0);
 585
 586     unless($self->{skip_rels}) {
 587         $dbh->do("DROP TABLE $_") for (@tables_reltests);
 588         unless($self->{vendor} =~ /sqlite/i) {
 589             if($self->{vendor} =~ /mysql/i) {
 590                 $dbh->do($drop_fk_mysql);
 591             }
 592             else {
 593                 $dbh->do($drop_fk);
 594             }
 595             $dbh->do("DROP TABLE $_") for (@tables_advanced);
 596         }
 597         unless($self->{no_inline_rels}) {
 598             $dbh->do("DROP TABLE $_") for (@tables_inline_rels);
 599         }
 600         unless($self->{no_implicit_rels}) {
 601             $dbh->do("DROP TABLE $_") for (@tables_implicit_rels);
 602         }
 603     }
 604     $dbh->do("DROP TABLE $_") for (@tables);
 605     $dbh->disconnect;
 606 }
 607
 608 sub DESTROY { shift->drop_tables; }
 609
 610 1;