t/backcompat/0.04006/lib/dbixcsl_common_tests.pm

   1 package dbixcsl_common_tests;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use DBIx::Class::Schema::Loader;
   8 use DBI;
   9
  10 sub new {
  11     my $class = shift;
  12
  13     my $self;
  14
  15     if( ref($_[0]) eq 'HASH') {
  16        my $args = shift;
  17        $self = { (%$args) };
  18     }
  19     else {
  20        $self = { @_ };
  21     }
  22
  23     # Only MySQL uses this
  24     $self->{innodb} ||= '';
  25
  26     $self->{verbose} = $ENV{TEST_VERBOSE} || 0;
  27
  28     return bless $self => $class;
  29 }
  30
  31 sub skip_tests {
  32     my ($self, $why) = @_;
  33
  34     plan skip_all => $why;
  35 }
  36
  37 sub _monikerize {
  38     my $name = shift;
  39     return 'LoaderTest2X' if $name =~ /^loader_test2$/i;
  40     return undef;
  41 }
  42
  43 sub run_tests {
  44     my $self = shift;
  45
  46     plan tests => 101;
  47
  48     $self->create();
  49
  50     my $schema_class = 'DBIXCSL_Test::Schema';
  51
  52     my $debug = ($self->{verbose} > 1) ? 1 : 0;
  53
  54     my @connect_info = ( $self->{dsn}, $self->{user}, $self->{password} );
  55     my %loader_opts = (
  56         constraint              => qr/^(?:\S+\.)?loader_test[0-9]+$/i,
  57         relationships           => 1,
  58         additional_classes      => 'TestAdditional',
  59         additional_base_classes => 'TestAdditionalBase',
  60         left_base_classes       => [ qw/TestLeftBase/ ],
  61         components              => [ qw/TestComponent/ ],
  62         inflect_plural          => { loader_test4 => 'loader_test4zes' },
  63         inflect_singular        => { fkid => 'fkid_singular' },
  64         moniker_map             => \&_monikerize,
  65         debug                   => $debug,
  66     );
  67
  68     $loader_opts{db_schema} = $self->{db_schema} if $self->{db_schema};
  69     eval { require Class::Inspector };
  70     if($@) {
  71         $self->{_no_rs_components} = 1;
  72     }
  73     else {
  74         $loader_opts{resultset_components} = [ qw/TestRSComponent/ ];
  75     }
  76
  77     {
  78        my @loader_warnings;
  79        local $SIG{__WARN__} = sub { push(@loader_warnings, $_[0]); };
  80         eval qq{
  81             package $schema_class;
  82             use base qw/DBIx::Class::Schema::Loader/;
  83
  84             __PACKAGE__->loader_options(\%loader_opts);
  85             __PACKAGE__->connection(\@connect_info);
  86         };
  87         ok(!$@, "Loader initialization") or diag $@;
  88
  89         my $warn_count = 0;
  90         $warn_count++ if grep /ResultSetManager/, @loader_warnings;
  91         $warn_count++ if grep /Dynamic schema detected/, @loader_warnings;
  92         $warn_count++ for grep /^Bad table or view/, @loader_warnings;
  93
  94         if($self->{skip_rels}) {
  95             is(scalar(@loader_warnings), $warn_count)
  96               or diag "Did not get the expected 0 warnings.  Warnings are: "
  97                 . join('',@loader_warnings);
  98             ok(1);
  99         }
 100         else {
 101             $warn_count++;
 102             is(scalar(@loader_warnings), $warn_count)
 103               or diag "Did not get the expected 1 warning.  Warnings are: "
 104                 . join('',@loader_warnings);
 105             is(grep(/loader_test9 has no primary key/, @loader_warnings), 1);
 106         }
 107     }
 108
 109     my $conn = $schema_class->clone;
 110     my $monikers = {};
 111     my $classes = {};
 112     foreach my $source_name ($schema_class->sources) {
 113         my $table_name = $schema_class->source($source_name)->from;
 114         $monikers->{$table_name} = $source_name;
 115         $classes->{$table_name} = $schema_class . q{::} . $source_name;
 116     }
 117
 118 # for debugging...
 119 #    {
 120 #        mkdir '/tmp/HLAGH';
 121 #        $conn->_loader->{dump_directory} = '/tmp/HLAGH';
 122 #        $conn->_loader->_dump_to_dir(values %$classes);
 123 #    }
 124
 125     my $moniker1 = $monikers->{loader_test1};
 126     my $class1   = $classes->{loader_test1};
 127     my $rsobj1   = $conn->resultset($moniker1);
 128
 129     my $moniker2 = $monikers->{loader_test2};
 130     my $class2   = $classes->{loader_test2};
 131     my $rsobj2   = $conn->resultset($moniker2);
 132
 133     my $moniker23 = $monikers->{LOADER_TEST23};
 134     my $class23   = $classes->{LOADER_TEST23};
 135     my $rsobj23   = $conn->resultset($moniker1);
 136
 137     my $moniker24 = $monikers->{LoAdEr_test24};
 138     my $class24   = $classes->{LoAdEr_test24};
 139     my $rsobj24   = $conn->resultset($moniker2);
 140
 141     isa_ok( $rsobj1, "DBIx::Class::ResultSet" );
 142     isa_ok( $rsobj2, "DBIx::Class::ResultSet" );
 143     isa_ok( $rsobj23, "DBIx::Class::ResultSet" );
 144     isa_ok( $rsobj24, "DBIx::Class::ResultSet" );
 145
 146     my @columns_lt2 = $class2->columns;
 147     is($columns_lt2[0], 'id', "Column Ordering 0");
 148     is($columns_lt2[1], 'dat', "Column Ordering 1");
 149     is($columns_lt2[2], 'dat2', "Column Ordering 2");
 150
 151     my %uniq1 = $class1->unique_constraints;
 152     my $uniq1_test = 0;
 153     foreach my $ucname (keys %uniq1) {
 154         my $cols_arrayref = $uniq1{$ucname};
 155         if(@$cols_arrayref == 1 && $cols_arrayref->[0] eq 'dat') {
 156            $uniq1_test = 1;
 157            last;
 158         }
 159     }
 160     ok($uniq1_test) or diag "Unique constraints not working";
 161
 162     my %uniq2 = $class2->unique_constraints;
 163     my $uniq2_test = 0;
 164     foreach my $ucname (keys %uniq2) {
 165         my $cols_arrayref = $uniq2{$ucname};
 166         if(@$cols_arrayref == 2
 167            && $cols_arrayref->[0] eq 'dat2'
 168            && $cols_arrayref->[1] eq 'dat') {
 169             $uniq2_test = 2;
 170             last;
 171         }
 172     }
 173     ok($uniq2_test) or diag "Multi-col unique constraints not working";
 174
 175     is($moniker2, 'LoaderTest2X', "moniker_map testing");
 176
 177     {
 178         my ($skip_tab, $skip_tabo, $skip_taba, $skip_cmeth,
 179             $skip_rsmeth, $skip_tcomp, $skip_trscomp);
 180
 181         can_ok( $class1, 'test_additional_base' ) or $skip_tab = 1;
 182         can_ok( $class1, 'test_additional_base_override' ) or $skip_tabo = 1;
 183         can_ok( $class1, 'test_additional_base_additional' ) or $skip_taba = 1;
 184         can_ok( $class1, 'dbix_class_testcomponent' ) or $skip_tcomp = 1;
 185         can_ok( $class1, 'loader_test1_classmeth' ) or $skip_cmeth = 1;
 186
 187         can_ok( $rsobj1, 'loader_test1_rsmeth' ) or $skip_rsmeth = 1;
 188
 189         SKIP: {
 190             skip "Pre-requisite test failed", 1 if $skip_tab;
 191             is( $class1->test_additional_base, "test_additional_base",
 192                 "Additional Base method" );
 193         }
 194
 195         SKIP: {
 196             skip "Pre-requisite test failed", 1 if $skip_tabo;
 197             is( $class1->test_additional_base_override,
 198                 "test_left_base_override",
 199                 "Left Base overrides Additional Base method" );
 200         }
 201
 202         SKIP: {
 203             skip "Pre-requisite test failed", 1 if $skip_taba;
 204             is( $class1->test_additional_base_additional, "test_additional",
 205                 "Additional Base can use Additional package method" );
 206         }
 207
 208         SKIP: {
 209             skip "Pre-requisite test failed", 1 if $skip_tcomp;
 210             is( $class1->dbix_class_testcomponent,
 211                 'dbix_class_testcomponent works' );
 212         }
 213
 214         SKIP: {
 215             skip "These two tests need Class::Inspector installed", 2
 216                      if $self->{_no_rs_components};
 217             can_ok($rsobj1, 'dbix_class_testrscomponent') or $skip_trscomp = 1;
 218             SKIP: {
 219                 skip "Pre-requisite test failed", 1 if $skip_trscomp;
 220                 is( $rsobj1->dbix_class_testrscomponent,
 221                     'dbix_class_testrscomponent works' );
 222             }
 223         }
 224
 225         SKIP: {
 226             skip "Pre-requisite test failed", 1 if $skip_cmeth;
 227             is( $class1->loader_test1_classmeth, 'all is well' );
 228         }
 229
 230         # XXX put this back in when the TODO above works...
 231         #SKIP: {
 232         #    skip "Pre-requisite test failed", 1 if $skip_rsmeth;
 233         #    is( $rsobj1->loader_test1_rsmeth, 'all is still well' );
 234         #}
 235     }
 236
 237
 238     my $obj    = $rsobj1->find(1);
 239     is( $obj->id,  1 );
 240     is( $obj->dat, "foo" );
 241     is( $rsobj2->count, 4 );
 242     my $saved_id;
 243     eval {
 244         my $new_obj1 = $rsobj1->create({ dat => 'newthing' });
 245         $saved_id = $new_obj1->id;
 246     };
 247     ok(!$@) or diag "Died during create new record using a PK::Auto key: $@";
 248     ok($saved_id) or diag "Failed to get PK::Auto-generated id";
 249
 250     my $new_obj1 = $rsobj1->search({ dat => 'newthing' })->first;
 251     ok($new_obj1) or diag "Cannot find newly inserted PK::Auto record";
 252     is($new_obj1->id, $saved_id);
 253
 254     my ($obj2) = $rsobj2->search({ dat => 'bbb' })->first;
 255     is( $obj2->id, 2 );
 256
 257     SKIP: {
 258         skip $self->{skip_rels}, 63 if $self->{skip_rels};
 259
 260         my $moniker3 = $monikers->{loader_test3};
 261         my $class3   = $classes->{loader_test3};
 262         my $rsobj3   = $conn->resultset($moniker3);
 263
 264         my $moniker4 = $monikers->{loader_test4};
 265         my $class4   = $classes->{loader_test4};
 266         my $rsobj4   = $conn->resultset($moniker4);
 267
 268         my $moniker5 = $monikers->{loader_test5};
 269         my $class5   = $classes->{loader_test5};
 270         my $rsobj5   = $conn->resultset($moniker5);
 271
 272         my $moniker6 = $monikers->{loader_test6};
 273         my $class6   = $classes->{loader_test6};
 274         my $rsobj6   = $conn->resultset($moniker6);
 275
 276         my $moniker7 = $monikers->{loader_test7};
 277         my $class7   = $classes->{loader_test7};
 278         my $rsobj7   = $conn->resultset($moniker7);
 279
 280         my $moniker8 = $monikers->{loader_test8};
 281         my $class8   = $classes->{loader_test8};
 282         my $rsobj8   = $conn->resultset($moniker8);
 283
 284         my $moniker9 = $monikers->{loader_test9};
 285         my $class9   = $classes->{loader_test9};
 286         my $rsobj9   = $conn->resultset($moniker9);
 287
 288         my $moniker16 = $monikers->{loader_test16};
 289         my $class16   = $classes->{loader_test16};
 290         my $rsobj16   = $conn->resultset($moniker16);
 291
 292         my $moniker17 = $monikers->{loader_test17};
 293         my $class17   = $classes->{loader_test17};
 294         my $rsobj17   = $conn->resultset($moniker17);
 295
 296         my $moniker18 = $monikers->{loader_test18};
 297         my $class18   = $classes->{loader_test18};
 298         my $rsobj18   = $conn->resultset($moniker18);
 299
 300         my $moniker19 = $monikers->{loader_test19};
 301         my $class19   = $classes->{loader_test19};
 302         my $rsobj19   = $conn->resultset($moniker19);
 303
 304         my $moniker20 = $monikers->{loader_test20};
 305         my $class20   = $classes->{loader_test20};
 306         my $rsobj20   = $conn->resultset($moniker20);
 307
 308         my $moniker21 = $monikers->{loader_test21};
 309         my $class21   = $classes->{loader_test21};
 310         my $rsobj21   = $conn->resultset($moniker21);
 311
 312         my $moniker22 = $monikers->{loader_test22};
 313         my $class22   = $classes->{loader_test22};
 314         my $rsobj22   = $conn->resultset($moniker22);
 315
 316         my $moniker25 = $monikers->{loader_test25};
 317         my $class25   = $classes->{loader_test25};
 318         my $rsobj25   = $conn->resultset($moniker25);
 319
 320         my $moniker26 = $monikers->{loader_test26};
 321         my $class26   = $classes->{loader_test26};
 322         my $rsobj26   = $conn->resultset($moniker26);
 323
 324         isa_ok( $rsobj3, "DBIx::Class::ResultSet" );
 325         isa_ok( $rsobj4, "DBIx::Class::ResultSet" );
 326         isa_ok( $rsobj5, "DBIx::Class::ResultSet" );
 327         isa_ok( $rsobj6, "DBIx::Class::ResultSet" );
 328         isa_ok( $rsobj7, "DBIx::Class::ResultSet" );
 329         isa_ok( $rsobj8, "DBIx::Class::ResultSet" );
 330         isa_ok( $rsobj9, "DBIx::Class::ResultSet" );
 331         isa_ok( $rsobj16, "DBIx::Class::ResultSet" );
 332         isa_ok( $rsobj17, "DBIx::Class::ResultSet" );
 333         isa_ok( $rsobj18, "DBIx::Class::ResultSet" );
 334         isa_ok( $rsobj19, "DBIx::Class::ResultSet" );
 335         isa_ok( $rsobj20, "DBIx::Class::ResultSet" );
 336         isa_ok( $rsobj21, "DBIx::Class::ResultSet" );
 337         isa_ok( $rsobj22, "DBIx::Class::ResultSet" );
 338         isa_ok( $rsobj25, "DBIx::Class::ResultSet" );
 339         isa_ok( $rsobj26, "DBIx::Class::ResultSet" );
 340
 341         # basic rel test
 342         my $obj4 = $rsobj4->find(123);
 343         isa_ok( $obj4->fkid_singular, $class3);
 344
 345         my $obj3 = $rsobj3->find(1);
 346         my $rs_rel4 = $obj3->search_related('loader_test4zes');
 347         isa_ok( $rs_rel4->first, $class4);
 348
 349         # test that _id is not stripped and prepositions in rel names are
 350         # ignored
 351         ok ($rsobj4->result_source->has_relationship('loader_test5_to_ids'),
 352             "rel with preposition 'to' and _id pluralized backward-compatibly");
 353
 354         ok ($rsobj4->result_source->has_relationship('loader_test5_from_ids'),
 355             "rel with preposition 'from' and _id pluralized backward-compatibly");
 356
 357         # check that default relationship attributes are not applied in 0.04006 mode
 358         is $rsobj3->result_source->relationship_info('loader_test4zes')->{attrs}{cascade_delete}, 1,
 359             'cascade_delete => 1 on has_many by default';
 360
 361         is $rsobj3->result_source->relationship_info('loader_test4zes')->{attrs}{cascade_copy}, 1,
 362             'cascade_copy => 1 on has_many by default';
 363
 364         ok ((not exists $rsobj3->result_source->relationship_info('loader_test4zes')->{attrs}{on_delete}),
 365             'has_many does not have on_delete');
 366
 367         ok ((not exists $rsobj3->result_source->relationship_info('loader_test4zes')->{attrs}{on_update}),
 368             'has_many does not have on_update');
 369
 370         ok ((not exists $rsobj3->result_source->relationship_info('loader_test4zes')->{attrs}{is_deferrable}),
 371             'has_many does not have is_deferrable');
 372
 373         isnt $rsobj4->result_source->relationship_info('fkid_singular')->{attrs}{on_delete}, 'CASCADE',
 374             "on_delete => 'CASCADE' not on belongs_to by default";
 375
 376         isnt $rsobj4->result_source->relationship_info('fkid_singular')->{attrs}{on_update}, 'CASCADE',
 377             "on_update => 'CASCADE' not on belongs_to by default";
 378
 379         isnt $rsobj4->result_source->relationship_info('fkid_singular')->{attrs}{is_deferrable}, 1,
 380             "is_deferrable => 1 not on belongs_to by default";
 381
 382         ok ((not exists $rsobj4->result_source->relationship_info('fkid_singular')->{attrs}{cascade_delete}),
 383             'belongs_to does not have cascade_delete');
 384
 385         ok ((not exists $rsobj4->result_source->relationship_info('fkid_singular')->{attrs}{cascade_copy}),
 386             'belongs_to does not have cascade_copy');
 387
 388         # find on multi-col pk
 389         my $obj5 = $rsobj5->find({id1 => 1, id2 => 1});
 390         is( $obj5->id2, 1 );
 391
 392         # mulit-col fk def
 393         my $obj6 = $rsobj6->find(1);
 394         isa_ok( $obj6->loader_test2, $class2);
 395         isa_ok( $obj6->loader_test5, $class5);
 396
 397         # fk that references a non-pk key (UNIQUE)
 398         my $obj8 = $rsobj8->find(1);
 399         isa_ok( $obj8->loader_test7, $class7);
 400
 401         # test double-fk 17 ->-> 16
 402         my $obj17 = $rsobj17->find(33);
 403
 404         my $rs_rel16_one = $obj17->loader16_one;
 405         isa_ok($rs_rel16_one, $class16);
 406         is($rs_rel16_one->dat, 'y16');
 407
 408         my $rs_rel16_two = $obj17->loader16_two;
 409         isa_ok($rs_rel16_two, $class16);
 410         is($rs_rel16_two->dat, 'z16');
 411
 412         my $obj16 = $rsobj16->find(2);
 413         my $rs_rel17 = $obj16->search_related('loader_test17_loader16_ones');
 414         isa_ok($rs_rel17->first, $class17);
 415         is($rs_rel17->first->id, 3);
 416
 417         # XXX test m:m 18 <- 20 -> 19
 418
 419         # XXX test double-fk m:m 21 <- 22 -> 21
 420
 421         # test double multi-col fk 26 -> 25
 422         my $obj26 = $rsobj26->find(33);
 423
 424         my $rs_rel25_one = $obj26->loader_test25_id_rel1;
 425         isa_ok($rs_rel25_one, $class25);
 426         is($rs_rel25_one->dat, 'x25');
 427
 428         my $rs_rel25_two = $obj26->loader_test25_id_rel2;
 429         isa_ok($rs_rel25_two, $class25);
 430         is($rs_rel25_two->dat, 'y25');
 431
 432         my $obj25 = $rsobj25->find(3,42);
 433         my $rs_rel26 = $obj25->search_related('loader_test26_id_rel1s');
 434         isa_ok($rs_rel26->first, $class26);
 435         is($rs_rel26->first->id, 3);
 436
 437         # from Chisel's tests...
 438         SKIP: {
 439             if($self->{vendor} =~ /sqlite/i) {
 440                 skip 'SQLite cannot do the advanced tests', 8;
 441             }
 442
 443             my $moniker10 = $monikers->{loader_test10};
 444             my $class10   = $classes->{loader_test10};
 445             my $rsobj10   = $conn->resultset($moniker10);
 446
 447             my $moniker11 = $monikers->{loader_test11};
 448             my $class11   = $classes->{loader_test11};
 449             my $rsobj11   = $conn->resultset($moniker11);
 450
 451             isa_ok( $rsobj10, "DBIx::Class::ResultSet" );
 452             isa_ok( $rsobj11, "DBIx::Class::ResultSet" );
 453
 454             my $obj10 = $rsobj10->create({ subject => 'xyzzy' });
 455
 456             $obj10->update();
 457             ok( defined $obj10, '$obj10 is defined' );
 458
 459             my $obj11 = $rsobj11->create({ loader_test10 => $obj10->id() });
 460             $obj11->update();
 461             ok( defined $obj11, '$obj11 is defined' );
 462
 463             eval {
 464                 my $obj10_2 = $obj11->loader_test10;
 465                 $obj10_2->loader_test11( $obj11->id11() );
 466                 $obj10_2->update();
 467             };
 468             is($@, '', 'No errors after eval{}');
 469
 470             SKIP: {
 471                 skip 'Previous eval block failed', 3
 472                     unless ($@ eq '');
 473
 474                 my $results = $rsobj10->search({ subject => 'xyzzy' });
 475                 is( $results->count(), 1,
 476                     'One $rsobj10 returned from search' );
 477
 478                 my $obj10_3 = $results->first();
 479                 isa_ok( $obj10_3, $class10 );
 480                 is( $obj10_3->loader_test11()->id(), $obj11->id(),
 481                     'found same $rsobj11 object we expected' );
 482             }
 483         }
 484
 485         SKIP: {
 486             skip 'This vendor cannot do inline relationship definitions', 6
 487                 if $self->{no_inline_rels};
 488
 489             my $moniker12 = $monikers->{loader_test12};
 490             my $class12   = $classes->{loader_test12};
 491             my $rsobj12   = $conn->resultset($moniker12);
 492
 493             my $moniker13 = $monikers->{loader_test13};
 494             my $class13   = $classes->{loader_test13};
 495             my $rsobj13   = $conn->resultset($moniker13);
 496
 497             isa_ok( $rsobj12, "DBIx::Class::ResultSet" );
 498             isa_ok( $rsobj13, "DBIx::Class::ResultSet" );
 499
 500             my $obj13 = $rsobj13->find(1);
 501             isa_ok( $obj13->id, $class12 );
 502             isa_ok( $obj13->loader_test12, $class12);
 503             isa_ok( $obj13->dat, $class12);
 504
 505             my $obj12 = $rsobj12->find(1);
 506             isa_ok( $obj12->loader_test13_ids, "DBIx::Class::ResultSet" );
 507         }
 508
 509         SKIP: {
 510             skip 'This vendor cannot do out-of-line implicit rel defs', 3
 511                 if $self->{no_implicit_rels};
 512             my $moniker14 = $monikers->{loader_test14};
 513             my $class14   = $classes->{loader_test14};
 514             my $rsobj14   = $conn->resultset($moniker14);
 515
 516             my $moniker15 = $monikers->{loader_test15};
 517             my $class15   = $classes->{loader_test15};
 518             my $rsobj15   = $conn->resultset($moniker15);
 519
 520             isa_ok( $rsobj14, "DBIx::Class::ResultSet" );
 521             isa_ok( $rsobj15, "DBIx::Class::ResultSet" );
 522
 523             my $obj15 = $rsobj15->find(1);
 524             isa_ok( $obj15->loader_test14, $class14 );
 525         }
 526     }
 527
 528     # rescan test
 529     SKIP: {
 530         skip $self->{skip_rels}, 4 if $self->{skip_rels};
 531
 532         my @statements_rescan = (
 533             qq{
 534                 CREATE TABLE loader_test30 (
 535                     id INTEGER NOT NULL PRIMARY KEY,
 536                     loader_test2 INTEGER NOT NULL,
 537                     FOREIGN KEY (loader_test2) REFERENCES loader_test2 (id)
 538                 ) $self->{innodb}
 539             },
 540             q{ INSERT INTO loader_test30 (id,loader_test2) VALUES(123, 1) },
 541             q{ INSERT INTO loader_test30 (id,loader_test2) VALUES(321, 2) },
 542         );
 543
 544         {
 545             my $dbh = $self->dbconnect(1);
 546             $dbh->do($_) for @statements_rescan;
 547             $dbh->disconnect;
 548         }
 549
 550         my @new = do {
 551             local $SIG{__WARN__} = sub {};
 552             $conn->rescan;
 553         };
 554         is(scalar(@new), 1);
 555         is($new[0], 'LoaderTest30');
 556
 557         my $rsobj30   = $conn->resultset('LoaderTest30');
 558         isa_ok($rsobj30, 'DBIx::Class::ResultSet');
 559         my $obj30 = $rsobj30->find(123);
 560         isa_ok( $obj30->loader_test2, $class2);
 561     }
 562 }
 563
 564 sub dbconnect {
 565     my ($self, $complain) = @_;
 566
 567     my $dbh = DBI->connect(
 568          $self->{dsn}, $self->{user},
 569          $self->{password},
 570          {
 571              RaiseError => $complain,
 572              PrintError => $complain,
 573              AutoCommit => 1,
 574          }
 575     );
 576     if ($self->{dsn} =~ /^[^:]+:SQLite:/) {
 577       $dbh->do ('PRAGMA synchronous = OFF');
 578     }
 579     elsif ($self->{dsn} =~ /^[^:]+:Pg:/) {
 580       $dbh->do ('SET client_min_messages=WARNING');
 581     }
 582
 583     die "Failed to connect to database: $DBI::errstr" if !$dbh;
 584
 585     return $dbh;
 586 }
 587
 588 sub create {
 589     my $self = shift;
 590
 591     $self->{_created} = 1;
 592
 593     my $make_auto_inc = $self->{auto_inc_cb} || sub {};
 594     my @statements = (
 595         qq{
 596             CREATE TABLE loader_test1 (
 597                 id $self->{auto_inc_pk},
 598                 dat VARCHAR(32) NOT NULL UNIQUE
 599             ) $self->{innodb}
 600         },
 601         $make_auto_inc->(qw/loader_test1 id/),
 602
 603         q{ INSERT INTO loader_test1 (dat) VALUES('foo') },
 604         q{ INSERT INTO loader_test1 (dat) VALUES('bar') },
 605         q{ INSERT INTO loader_test1 (dat) VALUES('baz') },
 606
 607         qq{
 608             CREATE TABLE loader_test2 (
 609                 id $self->{auto_inc_pk},
 610                 dat VARCHAR(32) NOT NULL,
 611                 dat2 VARCHAR(32) NOT NULL,
 612                 UNIQUE (dat2, dat)
 613             ) $self->{innodb}
 614         },
 615         $make_auto_inc->(qw/loader_test2 id/),
 616
 617         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('aaa', 'zzz') },
 618         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('bbb', 'yyy') },
 619         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('ccc', 'xxx') },
 620         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('ddd', 'www') },
 621
 622         qq{
 623             CREATE TABLE LOADER_TEST23 (
 624                 ID INTEGER NOT NULL PRIMARY KEY,
 625                 DAT VARCHAR(32) NOT NULL UNIQUE
 626             ) $self->{innodb}
 627         },
 628
 629         qq{
 630             CREATE TABLE LoAdEr_test24 (
 631                 iD INTEGER NOT NULL PRIMARY KEY,
 632                 DaT VARCHAR(32) NOT NULL UNIQUE
 633             ) $self->{innodb}
 634         },
 635     );
 636
 637     my @statements_reltests = (
 638         qq{
 639             CREATE TABLE loader_test3 (
 640                 id INTEGER NOT NULL PRIMARY KEY,
 641                 dat VARCHAR(32)
 642             ) $self->{innodb}
 643         },
 644
 645         q{ INSERT INTO loader_test3 (id,dat) VALUES(1,'aaa') },
 646         q{ INSERT INTO loader_test3 (id,dat) VALUES(2,'bbb') },
 647         q{ INSERT INTO loader_test3 (id,dat) VALUES(3,'ccc') },
 648         q{ INSERT INTO loader_test3 (id,dat) VALUES(4,'ddd') },
 649
 650         qq{
 651             CREATE TABLE loader_test4 (
 652                 id INTEGER NOT NULL PRIMARY KEY,
 653                 fkid INTEGER NOT NULL,
 654                 dat VARCHAR(32),
 655                 FOREIGN KEY( fkid ) REFERENCES loader_test3 (id)
 656             ) $self->{innodb}
 657         },
 658
 659         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(123,1,'aaa') },
 660         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(124,2,'bbb') },
 661         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(125,3,'ccc') },
 662         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(126,4,'ddd') },
 663
 664         qq{
 665             CREATE TABLE loader_test5 (
 666                 id1 INTEGER NOT NULL,
 667                 iD2 INTEGER NOT NULL,
 668                 dat VARCHAR(8),
 669                 from_id INTEGER,
 670                 to_id INTEGER,
 671                 PRIMARY KEY (id1,id2),
 672                 FOREIGN KEY (from_id) REFERENCES loader_test4 (id),
 673                 FOREIGN KEY (to_id) REFERENCES loader_test4 (id)
 674             ) $self->{innodb}
 675         },
 676
 677         q{ INSERT INTO loader_test5 (id1,id2,dat) VALUES (1,1,'aaa') },
 678
 679         qq{
 680             CREATE TABLE loader_test6 (
 681                 id INTEGER NOT NULL PRIMARY KEY,
 682                 Id2 INTEGER,
 683                 loader_test2 INTEGER,
 684                 dat VARCHAR(8),
 685                 FOREIGN KEY (loader_test2)  REFERENCES loader_test2 (id),
 686                 FOREIGN KEY(id,Id2) REFERENCES loader_test5 (id1,iD2)
 687             ) $self->{innodb}
 688         },
 689
 690         (q{ INSERT INTO loader_test6 (id, id2,loader_test2,dat) } .
 691          q{ VALUES (1, 1,1,'aaa') }),
 692
 693         qq{
 694             CREATE TABLE loader_test7 (
 695                 id INTEGER NOT NULL PRIMARY KEY,
 696                 id2 VARCHAR(8) NOT NULL UNIQUE,
 697                 dat VARCHAR(8)
 698             ) $self->{innodb}
 699         },
 700
 701         q{ INSERT INTO loader_test7 (id,id2,dat) VALUES (1,'aaa','bbb') },
 702
 703         qq{
 704             CREATE TABLE loader_test8 (
 705                 id INTEGER NOT NULL PRIMARY KEY,
 706                 loader_test7 VARCHAR(8) NOT NULL,
 707                 dat VARCHAR(8),
 708                 FOREIGN KEY (loader_test7) REFERENCES loader_test7 (id2)
 709             ) $self->{innodb}
 710         },
 711
 712         (q{ INSERT INTO loader_test8 (id,loader_test7,dat) } .
 713          q{ VALUES (1,'aaa','bbb') }),
 714
 715         qq{
 716             CREATE TABLE loader_test9 (
 717                 loader_test9 VARCHAR(8) NOT NULL
 718             ) $self->{innodb}
 719         },
 720
 721         qq{
 722             CREATE TABLE loader_test16 (
 723                 id INTEGER NOT NULL PRIMARY KEY,
 724                 dat  VARCHAR(8)
 725             ) $self->{innodb}
 726         },
 727
 728         qq{ INSERT INTO loader_test16 (id,dat) VALUES (2,'x16') },
 729         qq{ INSERT INTO loader_test16 (id,dat) VALUES (4,'y16') },
 730         qq{ INSERT INTO loader_test16 (id,dat) VALUES (6,'z16') },
 731
 732         qq{
 733             CREATE TABLE loader_test17 (
 734                 id INTEGER NOT NULL PRIMARY KEY,
 735                 loader16_one INTEGER,
 736                 loader16_two INTEGER,
 737                 FOREIGN KEY (loader16_one) REFERENCES loader_test16 (id),
 738                 FOREIGN KEY (loader16_two) REFERENCES loader_test16 (id)
 739             ) $self->{innodb}
 740         },
 741
 742         qq{ INSERT INTO loader_test17 (id, loader16_one, loader16_two) VALUES (3, 2, 4) },
 743         qq{ INSERT INTO loader_test17 (id, loader16_one, loader16_two) VALUES (33, 4, 6) },
 744
 745         qq{
 746             CREATE TABLE loader_test18 (
 747                 id INTEGER NOT NULL PRIMARY KEY,
 748                 dat  VARCHAR(8)
 749             ) $self->{innodb}
 750         },
 751
 752         qq{ INSERT INTO loader_test18 (id,dat) VALUES (1,'x18') },
 753         qq{ INSERT INTO loader_test18 (id,dat) VALUES (2,'y18') },
 754         qq{ INSERT INTO loader_test18 (id,dat) VALUES (3,'z18') },
 755
 756         qq{
 757             CREATE TABLE loader_test19 (
 758                 id INTEGER NOT NULL PRIMARY KEY,
 759                 dat  VARCHAR(8)
 760             ) $self->{innodb}
 761         },
 762
 763         qq{ INSERT INTO loader_test19 (id,dat) VALUES (4,'x19') },
 764         qq{ INSERT INTO loader_test19 (id,dat) VALUES (5,'y19') },
 765         qq{ INSERT INTO loader_test19 (id,dat) VALUES (6,'z19') },
 766
 767         qq{
 768             CREATE TABLE loader_test20 (
 769                 parent INTEGER NOT NULL,
 770                 child INTEGER NOT NULL,
 771                 PRIMARY KEY (parent, child),
 772                 FOREIGN KEY (parent) REFERENCES loader_test18 (id),
 773                 FOREIGN KEY (child) REFERENCES loader_test19 (id)
 774             ) $self->{innodb}
 775         },
 776
 777         q{ INSERT INTO loader_test20 (parent, child) VALUES (1,4) },
 778         q{ INSERT INTO loader_test20 (parent, child) VALUES (2,5) },
 779         q{ INSERT INTO loader_test20 (parent, child) VALUES (3,6) },
 780
 781         qq{
 782             CREATE TABLE loader_test21 (
 783                 id INTEGER NOT NULL PRIMARY KEY,
 784                 dat  VARCHAR(8)
 785             ) $self->{innodb}
 786         },
 787
 788         q{ INSERT INTO loader_test21 (id,dat) VALUES (7,'a21')},
 789         q{ INSERT INTO loader_test21 (id,dat) VALUES (11,'b21')},
 790         q{ INSERT INTO loader_test21 (id,dat) VALUES (13,'c21')},
 791         q{ INSERT INTO loader_test21 (id,dat) VALUES (17,'d21')},
 792
 793         qq{
 794             CREATE TABLE loader_test22 (
 795                 parent INTEGER NOT NULL,
 796                 child INTEGER NOT NULL,
 797                 PRIMARY KEY (parent, child),
 798                 FOREIGN KEY (parent) REFERENCES loader_test21 (id),
 799                 FOREIGN KEY (child) REFERENCES loader_test21 (id)
 800             ) $self->{innodb}
 801         },
 802
 803         q{ INSERT INTO loader_test22 (parent, child) VALUES (7,11)},
 804         q{ INSERT INTO loader_test22 (parent, child) VALUES (11,13)},
 805         q{ INSERT INTO loader_test22 (parent, child) VALUES (13,17)},
 806
 807         qq{
 808             CREATE TABLE loader_test25 (
 809                 id1 INTEGER NOT NULL,
 810                 id2 INTEGER NOT NULL,
 811                 dat VARCHAR(8),
 812                 PRIMARY KEY (id1,id2)
 813             ) $self->{innodb}
 814         },
 815
 816         q{ INSERT INTO loader_test25 (id1,id2,dat) VALUES (33,5,'x25') },
 817         q{ INSERT INTO loader_test25 (id1,id2,dat) VALUES (33,7,'y25') },
 818         q{ INSERT INTO loader_test25 (id1,id2,dat) VALUES (3,42,'z25') },
 819
 820         qq{
 821             CREATE TABLE loader_test26 (
 822                id INTEGER NOT NULL PRIMARY KEY,
 823                rel1 INTEGER NOT NULL,
 824                rel2 INTEGER NOT NULL,
 825                FOREIGN KEY (id, rel1) REFERENCES loader_test25 (id1, id2),
 826                FOREIGN KEY (id, rel2) REFERENCES loader_test25 (id1, id2)
 827             ) $self->{innodb}
 828         },
 829
 830         q{ INSERT INTO loader_test26 (id,rel1,rel2) VALUES (33,5,7) },
 831         q{ INSERT INTO loader_test26 (id,rel1,rel2) VALUES (3,42,42) },
 832     );
 833
 834     my @statements_advanced = (
 835         qq{
 836             CREATE TABLE loader_test10 (
 837                 id10 $self->{auto_inc_pk},
 838                 subject VARCHAR(8),
 839                 loader_test11 INTEGER
 840             ) $self->{innodb}
 841         },
 842         $make_auto_inc->(qw/loader_test10 id10/),
 843
 844         qq{
 845             CREATE TABLE loader_test11 (
 846                 id11 $self->{auto_inc_pk},
 847                 message VARCHAR(8) DEFAULT 'foo',
 848                 loader_test10 INTEGER,
 849                 FOREIGN KEY (loader_test10) REFERENCES loader_test10 (id10)
 850             ) $self->{innodb}
 851         },
 852         $make_auto_inc->(qw/loader_test11 id11/),
 853
 854         (q{ ALTER TABLE loader_test10 ADD CONSTRAINT } .
 855          q{ loader_test11_fk FOREIGN KEY (loader_test11) } .
 856          q{ REFERENCES loader_test11 (id11) }),
 857     );
 858
 859     my @statements_inline_rels = (
 860         qq{
 861             CREATE TABLE loader_test12 (
 862                 id INTEGER NOT NULL PRIMARY KEY,
 863                 id2 VARCHAR(8) NOT NULL UNIQUE,
 864                 dat VARCHAR(8) NOT NULL UNIQUE
 865             ) $self->{innodb}
 866         },
 867
 868         q{ INSERT INTO loader_test12 (id,id2,dat) VALUES (1,'aaa','bbb') },
 869
 870         qq{
 871             CREATE TABLE loader_test13 (
 872                 id INTEGER NOT NULL PRIMARY KEY REFERENCES loader_test12,
 873                 loader_test12 VARCHAR(8) NOT NULL REFERENCES loader_test12 (id2),
 874                 dat VARCHAR(8) REFERENCES loader_test12 (dat)
 875             ) $self->{innodb}
 876         },
 877
 878         (q{ INSERT INTO loader_test13 (id,loader_test12,dat) } .
 879          q{ VALUES (1,'aaa','bbb') }),
 880     );
 881
 882
 883     my @statements_implicit_rels = (
 884         qq{
 885             CREATE TABLE loader_test14 (
 886                 id INTEGER NOT NULL PRIMARY KEY,
 887                 dat VARCHAR(8)
 888             ) $self->{innodb}
 889         },
 890
 891         q{ INSERT INTO loader_test14 (id,dat) VALUES (123,'aaa') },
 892
 893         qq{
 894             CREATE TABLE loader_test15 (
 895                 id INTEGER NOT NULL PRIMARY KEY,
 896                 loader_test14 INTEGER NOT NULL,
 897                 FOREIGN KEY (loader_test14) REFERENCES loader_test14
 898             ) $self->{innodb}
 899         },
 900
 901         q{ INSERT INTO loader_test15 (id,loader_test14) VALUES (1,123) },
 902     );
 903
 904     $self->drop_tables;
 905
 906     my $dbh = $self->dbconnect(1);
 907
 908     $dbh->do($_) for (@statements);
 909     unless($self->{skip_rels}) {
 910         # hack for now, since DB2 doesn't like inline comments, and we need
 911         # to test one for mysql, which works on everyone else...
 912         # this all needs to be refactored anyways.
 913         $dbh->do($_) for (@statements_reltests);
 914         unless($self->{vendor} =~ /sqlite/i) {
 915             $dbh->do($_) for (@statements_advanced);
 916         }
 917         unless($self->{no_inline_rels}) {
 918             $dbh->do($_) for (@statements_inline_rels);
 919         }
 920         unless($self->{no_implicit_rels}) {
 921             $dbh->do($_) for (@statements_implicit_rels);
 922         }
 923     }
 924     $dbh->disconnect();
 925 }
 926
 927 sub drop_tables {
 928     my $self = shift;
 929
 930     my @tables = qw/
 931         loader_test1
 932         loader_test2
 933         LOADER_TEST23
 934         LoAdEr_test24
 935     /;
 936
 937     my @tables_auto_inc = (
 938         [ qw/loader_test1 id/ ],
 939         [ qw/loader_test2 id/ ],
 940     );
 941
 942     my @tables_reltests = qw/
 943         loader_test4
 944         loader_test3
 945         loader_test6
 946         loader_test5
 947         loader_test8
 948         loader_test7
 949         loader_test9
 950         loader_test17
 951         loader_test16
 952         loader_test20
 953         loader_test19
 954         loader_test18
 955         loader_test22
 956         loader_test21
 957         loader_test26
 958         loader_test25
 959     /;
 960
 961     my @tables_advanced = qw/
 962         loader_test11
 963         loader_test10
 964     /;
 965
 966     my @tables_advanced_auto_inc = (
 967         [ qw/loader_test10 id10/ ],
 968         [ qw/loader_test11 id11/ ],
 969     );
 970
 971     my @tables_inline_rels = qw/
 972         loader_test13
 973         loader_test12
 974     /;
 975
 976     my @tables_implicit_rels = qw/
 977         loader_test15
 978         loader_test14
 979     /;
 980
 981     my @tables_rescan = qw/ loader_test30 /;
 982
 983     my $drop_fk_mysql =
 984         q{ALTER TABLE loader_test10 DROP FOREIGN KEY loader_test11_fk};
 985
 986     my $drop_fk =
 987         q{ALTER TABLE loader_test10 DROP CONSTRAINT loader_test11_fk};
 988
 989     my $dbh = $self->dbconnect(0);
 990
 991     my $drop_auto_inc = $self->{auto_inc_drop_cb} || sub {};
 992
 993     unless($self->{skip_rels}) {
 994         $dbh->do("DROP TABLE $_") for (@tables_reltests);
 995         unless($self->{vendor} =~ /sqlite/i) {
 996             if($self->{vendor} =~ /mysql/i) {
 997                 $dbh->do($drop_fk_mysql);
 998             }
 999             else {
1000                 $dbh->do($drop_fk);
1001             }
1002             $dbh->do("DROP TABLE $_") for (@tables_advanced);
1003             $dbh->do($_) for map { $drop_auto_inc->(@$_) } @tables_advanced_auto_inc;
1004         }
1005         unless($self->{no_inline_rels}) {
1006             $dbh->do("DROP TABLE $_") for (@tables_inline_rels);
1007         }
1008         unless($self->{no_implicit_rels}) {
1009             $dbh->do("DROP TABLE $_") for (@tables_implicit_rels);
1010         }
1011         $dbh->do("DROP TABLE $_") for (@tables_rescan);
1012     }
1013     $dbh->do("DROP TABLE $_") for (@tables);
1014     $dbh->do($_) for map { $drop_auto_inc->(@$_) } @tables_auto_inc;
1015     $dbh->disconnect;
1016 }
1017
1018 sub DESTROY {
1019     my $self = shift;
1020     $self->drop_tables if $self->{_created};
1021 }
1022
1023 1;