t/23dumpmore.t

   1 use strict;
   2 use Test::More;
   3 use lib qw(t/lib);
   4 use File::Path;
   5 use IPC::Open3;
   6 use make_dbictest_db;
   7 require DBIx::Class::Schema::Loader;
   8
   9 my $DUMP_PATH = './t/_dump';
  10
  11 sub dump_directly {
  12     my %tdata = @_;
  13
  14     my $schema_class = $tdata{classname};
  15
  16     no strict 'refs';
  17     @{$schema_class . '::ISA'} = ('DBIx::Class::Schema::Loader');
  18     $schema_class->loader_options(%{$tdata{options}});
  19
  20     my @warns;
  21     eval {
  22         local $SIG{__WARN__} = sub { push(@warns, @_) };
  23         $schema_class->connect($make_dbictest_db::dsn);
  24     };
  25     my $err = $@;
  26     $schema_class->storage->disconnect if !$err && $schema_class->storage;
  27     undef *{$schema_class};
  28
  29     is($err, $tdata{error});
  30
  31     return @warns;
  32 }
  33
  34 sub dump_dbicdump {
  35     my %tdata = @_;
  36
  37     # use $^X so we execute ./script/dbicdump with the same perl binary that the tests were executed with
  38     my @cmd = ($^X, qw(./script/dbicdump));
  39
  40     while (my ($opt, $val) = each(%{ $tdata{options} })) {
  41         push @cmd, '-o', "$opt=$val";
  42     }
  43
  44     push @cmd, $tdata{classname}, $make_dbictest_db::dsn;
  45
  46     # make sure our current @INC gets used by dbicdump
  47     use Config;
  48     local $ENV{PERL5LIB} = join $Config{path_sep}, @INC, $ENV{PERL5LIB};
  49
  50     my ($in, $out, $err);
  51     my $pid = open3($in, $out, $err, @cmd);
  52
  53     my @warns = <$out>;
  54     waitpid($pid, 0);
  55
  56     return @warns;
  57 }
  58
  59 sub do_dump_test {
  60     my %tdata = @_;
  61
  62     $tdata{options}{dump_directory} = $DUMP_PATH;
  63     $tdata{options}{use_namespaces} ||= 0;
  64
  65     for my $dumper (\&dump_directly, \&dump_dbicdump) {
  66         test_dumps(\%tdata, $dumper->(%tdata));
  67     }
  68 }
  69
  70 sub test_dumps {
  71     my ($tdata, @warns) = @_;
  72
  73     my %tdata = %{$tdata};
  74
  75     my $schema_class = $tdata{classname};
  76     my $check_warns = $tdata{warnings};
  77     is(@warns, @$check_warns, "$schema_class warning count");
  78     for(my $i = 0; $i <= $#$check_warns; $i++) {
  79         like($warns[$i], $check_warns->[$i], "$schema_class warning $i");
  80     }
  81
  82     my $file_regexes = $tdata{regexes};
  83     my $file_neg_regexes = $tdata{neg_regexes} || {};
  84     my $schema_regexes = delete $file_regexes->{schema};
  85
  86     my $schema_path = $DUMP_PATH . '/' . $schema_class;
  87     $schema_path =~ s{::}{/}g;
  88     dump_file_like($schema_path . '.pm', @$schema_regexes);
  89     foreach my $src (keys %$file_regexes) {
  90         my $src_file = $schema_path . '/' . $src . '.pm';
  91         dump_file_like($src_file, @{$file_regexes->{$src}});
  92     }
  93     foreach my $src (keys %$file_neg_regexes) {
  94         my $src_file = $schema_path . '/' . $src . '.pm';
  95         dump_file_not_like($src_file, @{$file_neg_regexes->{$src}});
  96     }
  97 }
  98
  99 sub dump_file_like {
 100     my $path = shift;
 101     open(my $dumpfh, '<', $path) or die "Failed to open '$path': $!";
 102     my $contents = do { local $/; <$dumpfh>; };
 103     close($dumpfh);
 104     my $num = 1;
 105     like($contents, $_, "like $path " . $num++) for @_;
 106 }
 107
 108 sub dump_file_not_like {
 109     my $path = shift;
 110     open(my $dumpfh, '<', $path) or die "Failed to open '$path': $!";
 111     my $contents = do { local $/; <$dumpfh>; };
 112     close($dumpfh);
 113     my $num = 1;
 114     unlike($contents, $_, "unlike $path ". $num++) for @_;
 115 }
 116
 117 sub append_to_class {
 118     my ($class, $string) = @_;
 119     $class =~ s{::}{/}g;
 120     $class = $DUMP_PATH . '/' . $class . '.pm';
 121     open(my $appendfh, '>>', $class) or die "Failed to open '$class' for append: $!";
 122     print $appendfh $string;
 123     close($appendfh);
 124 }
 125
 126 rmtree($DUMP_PATH, 1, 1);
 127
 128 # test out the POD
 129
 130 do_dump_test(
 131     classname => 'DBICTest::DumpMore::1',
 132     options => { },
 133     error => '',
 134     warnings => [
 135         qr/Dumping manual schema for DBICTest::DumpMore::1 to directory /,
 136         qr/Schema dump completed/,
 137     ],
 138     regexes => {
 139         schema => [
 140             qr/package DBICTest::DumpMore::1;/,
 141             qr/->load_classes/,
 142         ],
 143         Foo => [
 144 qr/package DBICTest::DumpMore::1::Foo;/,
 145 qr/=head1 NAME\n\nDBICTest::DumpMore::1::Foo\n\n=cut\n\n/,
 146 qr/=head1 ACCESSORS\n\n/,
 147 qr/=head2 fooid\n\n  data_type: INTEGER\n  default_value: undef\n  is_nullable: 1\n  size: undef\n\n/,
 148 qr/=head2 footext\n\n  data_type: TEXT\n  default_value: undef\n  is_nullable: 1\n  size: undef\n\n/,
 149 qr/->set_primary_key/,
 150 qr/=head1 RELATIONS\n\n/,
 151 qr/=head2 bars\n\nType: has_many\n\nRelated object: L<DBICTest::DumpMore::1::Bar>\n\n=cut\n\n/,
 152 qr/1;\n$/,
 153         ],
 154         Bar => [
 155 qr/package DBICTest::DumpMore::1::Bar;/,
 156 qr/=head1 NAME\n\nDBICTest::DumpMore::1::Bar\n\n=cut\n\n/,
 157 qr/=head1 ACCESSORS\n\n/,
 158 qr/=head2 barid\n\n  data_type: INTEGER\n  default_value: undef\n  is_nullable: 1\n  size: undef\n\n/,
 159 qr/=head2 fooref\n\n  data_type: INTEGER\n  default_value: undef\n  is_foreign_key: 1\n  is_nullable: 1\n  size: undef\n\n/,
 160 qr/->set_primary_key/,
 161 qr/=head1 RELATIONS\n\n/,
 162 qr/=head2 fooref\n\nType: belongs_to\n\nRelated object: L<DBICTest::DumpMore::1::Foo>\n\n=cut\n\n/,
 163 qr/1;\n$/,
 164         ],
 165     },
 166 );
 167
 168 append_to_class('DBICTest::DumpMore::1::Foo',q{# XXX This is my custom content XXX});
 169
 170 do_dump_test(
 171     classname => 'DBICTest::DumpMore::1',
 172     options => { },
 173     error => '',
 174     warnings => [
 175         qr/Dumping manual schema for DBICTest::DumpMore::1 to directory /,
 176         qr/Schema dump completed/,
 177     ],
 178     regexes => {
 179         schema => [
 180             qr/package DBICTest::DumpMore::1;/,
 181             qr/->load_classes/,
 182         ],
 183         Foo => [
 184             qr/package DBICTest::DumpMore::1::Foo;/,
 185             qr/->set_primary_key/,
 186             qr/1;\n# XXX This is my custom content XXX/,
 187         ],
 188         Bar => [
 189             qr/package DBICTest::DumpMore::1::Bar;/,
 190             qr/->set_primary_key/,
 191             qr/1;\n$/,
 192         ],
 193     },
 194 );
 195
 196 do_dump_test(
 197     classname => 'DBICTest::DumpMore::1',
 198     options => { really_erase_my_files => 1 },
 199     error => '',
 200     warnings => [
 201         qr/Dumping manual schema for DBICTest::DumpMore::1 to directory /,
 202         qr/Deleting existing file /,
 203         qr/Deleting existing file /,
 204         qr/Deleting existing file /,
 205         qr/Schema dump completed/,
 206     ],
 207     regexes => {
 208         schema => [
 209             qr/package DBICTest::DumpMore::1;/,
 210             qr/->load_classes/,
 211         ],
 212         Foo => [
 213             qr/package DBICTest::DumpMore::1::Foo;/,
 214             qr/->set_primary_key/,
 215             qr/1;\n$/,
 216         ],
 217         Bar => [
 218             qr/package DBICTest::DumpMore::1::Bar;/,
 219             qr/->set_primary_key/,
 220             qr/1;\n$/,
 221         ],
 222     },
 223     neg_regexes => {
 224         Foo => [
 225             qr/# XXX This is my custom content XXX/,
 226         ],
 227     },
 228 );
 229
 230 do_dump_test(
 231     classname => 'DBICTest::DumpMore::1',
 232     options => { use_namespaces => 1, generate_pod => 0 },
 233     error => '',
 234     warnings => [
 235         qr/Dumping manual schema for DBICTest::DumpMore::1 to directory /,
 236         qr/Schema dump completed/,
 237     ],
 238     neg_regexes => {
 239         'Result/Foo' => [
 240             qr/^=/m,
 241         ],
 242     },
 243 );
 244
 245 do_dump_test(
 246     classname => 'DBICTest::DumpMore::1',
 247     options => { use_namespaces => 1 },
 248     error => '',
 249     warnings => [
 250         qr/Dumping manual schema for DBICTest::DumpMore::1 to directory /,
 251         qr/Schema dump completed/,
 252     ],
 253     regexes => {
 254         schema => [
 255             qr/package DBICTest::DumpMore::1;/,
 256             qr/->load_namespaces/,
 257         ],
 258         'Result/Foo' => [
 259             qr/package DBICTest::DumpMore::1::Result::Foo;/,
 260             qr/->set_primary_key/,
 261             qr/1;\n$/,
 262         ],
 263         'Result/Bar' => [
 264             qr/package DBICTest::DumpMore::1::Result::Bar;/,
 265             qr/->set_primary_key/,
 266             qr/1;\n$/,
 267         ],
 268     },
 269 );
 270
 271 do_dump_test(
 272     classname => 'DBICTest::DumpMore::1',
 273     options => { use_namespaces => 1,
 274                  result_namespace => 'Res',
 275                  resultset_namespace => 'RSet',
 276                  default_resultset_class => 'RSetBase',
 277              },
 278     error => '',
 279     warnings => [
 280         qr/Dumping manual schema for DBICTest::DumpMore::1 to directory /,
 281         qr/Schema dump completed/,
 282     ],
 283     regexes => {
 284         schema => [
 285             qr/package DBICTest::DumpMore::1;/,
 286             qr/->load_namespaces/,
 287             qr/result_namespace => 'Res'/,
 288             qr/resultset_namespace => 'RSet'/,
 289             qr/default_resultset_class => 'RSetBase'/,
 290         ],
 291         'Res/Foo' => [
 292             qr/package DBICTest::DumpMore::1::Res::Foo;/,
 293             qr/->set_primary_key/,
 294             qr/1;\n$/,
 295         ],
 296         'Res/Bar' => [
 297             qr/package DBICTest::DumpMore::1::Res::Bar;/,
 298             qr/->set_primary_key/,
 299             qr/1;\n$/,
 300         ],
 301     },
 302 );
 303
 304 do_dump_test(
 305     classname => 'DBICTest::DumpMore::1',
 306     options => { use_namespaces => 1,
 307                  result_namespace => '+DBICTest::DumpMore::1::Res',
 308                  resultset_namespace => 'RSet',
 309                  default_resultset_class => 'RSetBase',
 310                  result_base_class => 'My::ResultBaseClass',
 311                  schema_base_class => 'My::SchemaBaseClass',
 312              },
 313     error => '',
 314     warnings => [
 315         qr/Dumping manual schema for DBICTest::DumpMore::1 to directory /,
 316         qr/Schema dump completed/,
 317     ],
 318     regexes => {
 319         schema => [
 320             qr/package DBICTest::DumpMore::1;/,
 321             qr/->load_namespaces/,
 322             qr/result_namespace => '\+DBICTest::DumpMore::1::Res'/,
 323             qr/resultset_namespace => 'RSet'/,
 324             qr/default_resultset_class => 'RSetBase'/,
 325             qr/use base 'My::SchemaBaseClass'/,
 326         ],
 327         'Res/Foo' => [
 328             qr/package DBICTest::DumpMore::1::Res::Foo;/,
 329             qr/use base 'My::ResultBaseClass'/,
 330             qr/->set_primary_key/,
 331             qr/1;\n$/,
 332         ],
 333         'Res/Bar' => [
 334             qr/package DBICTest::DumpMore::1::Res::Bar;/,
 335             qr/use base 'My::ResultBaseClass'/,
 336             qr/->set_primary_key/,
 337             qr/1;\n$/,
 338         ],
 339     },
 340 );
 341
 342 done_testing;
 343
 344 END { rmtree($DUMP_PATH, 1, 1) unless $ENV{SCHEMA_LOADER_TESTS_NOCLEANUP} }