t/10_10informix_common.t

   1 use strict;
   2 use warnings;
   3 use Test::More;
   4 use Test::Exception;
   5 use Try::Tiny;
   6 use File::Path 'rmtree';
   7 use DBIx::Class::Schema::Loader 'make_schema_at';
   8 use DBIx::Class::Schema::Loader::Utils 'split_name';
   9 use String::ToIdentifier::EN::Unicode 'to_identifier';
  10 use namespace::clean;
  11
  12 use lib qw(t/lib);
  13
  14 use dbixcsl_common_tests ();
  15 use dbixcsl_test_dir '$tdir';
  16
  17 use constant EXTRA_DUMP_DIR => "$tdir/informix_extra_dump";
  18
  19 # to support " quoted identifiers
  20 BEGIN { $ENV{DELIMIDENT} = 'y' }
  21
  22 # This test doesn't run over a shared memory connection, because of the single connection limit.
  23
  24 my $dsn      = $ENV{DBICTEST_INFORMIX_DSN} || '';
  25 my $user     = $ENV{DBICTEST_INFORMIX_USER} || '';
  26 my $password = $ENV{DBICTEST_INFORMIX_PASS} || '';
  27
  28 my ($schema, $extra_schema); # for cleanup in END for extra tests
  29
  30 my $tester = dbixcsl_common_tests->new(
  31     vendor         => 'Informix',
  32     auto_inc_pk    => 'serial primary key',
  33     null           => '',
  34     default_function     => 'current year to fraction(5)',
  35     default_function_def => 'datetime year to fraction(5) default current year to fraction(5)',
  36     dsn            => $dsn,
  37     user           => $user,
  38     password       => $password,
  39     loader_options => { preserve_case => 1 },
  40     quote_char     => '"',
  41     data_types => {
  42         # http://publib.boulder.ibm.com/infocenter/idshelp/v115/index.jsp?topic=/com.ibm.sqlr.doc/ids_sqr_094.htm
  43
  44         # Numeric Types
  45         'int'              => { data_type => 'integer' },
  46         integer            => { data_type => 'integer' },
  47         int8               => { data_type => 'bigint' },
  48         bigint             => { data_type => 'bigint' },
  49         serial             => { data_type => 'integer', is_auto_increment => 1 },
  50         bigserial          => { data_type => 'bigint',  is_auto_increment => 1 },
  51         serial8            => { data_type => 'bigint',  is_auto_increment => 1 },
  52         smallint           => { data_type => 'smallint' },
  53         real               => { data_type => 'real' },
  54         smallfloat         => { data_type => 'real' },
  55         # just 'double' is a syntax error
  56         'double precision' => { data_type => 'double precision' },
  57         float              => { data_type => 'double precision' },
  58         'float(1)'         => { data_type => 'double precision' },
  59         'float(5)'         => { data_type => 'double precision' },
  60         'float(10)'        => { data_type => 'double precision' },
  61         'float(15)'        => { data_type => 'double precision' },
  62         'float(16)'        => { data_type => 'double precision' },
  63         numeric            => { data_type => 'numeric' },
  64         decimal            => { data_type => 'numeric' },
  65         dec                => { data_type => 'numeric' },
  66         'numeric(6,3)'     => { data_type => 'numeric', size => [6,3] },
  67         'decimal(6,3)'     => { data_type => 'numeric', size => [6,3] },
  68         'dec(6,3)'         => { data_type => 'numeric', size => [6,3] },
  69
  70         # Boolean Type
  71         # XXX this should map to 'boolean'
  72         boolean            => { data_type => 'smallint' },
  73
  74         # Money Type
  75         money              => { data_type => 'money' },
  76         'money(3,3)'       => { data_type => 'numeric', size => [3,3] },
  77
  78         # Byte Type
  79         byte               => { data_type => 'bytea', original => { data_type => 'byte' } },
  80
  81         # Character String Types
  82         char               => { data_type => 'char', size => 1 },
  83         'char(3)'          => { data_type => 'char', size => 3 },
  84         character          => { data_type => 'char', size => 1 },
  85         'character(3)'     => { data_type => 'char', size => 3 },
  86         'varchar(3)'       => { data_type => 'varchar', size => 3 },
  87         'character varying(3)'
  88                            => { data_type => 'varchar', size => 3 },
  89         # XXX min size not supported, colmin from syscolumns is NULL
  90         'varchar(3,2)'     => { data_type => 'varchar', size => 3 },
  91         'character varying(3,2)'
  92                            => { data_type => 'varchar', size => 3 },
  93         nchar              => { data_type => 'nchar', size => 1 },
  94         'nchar(3)'         => { data_type => 'nchar', size => 3 },
  95         'nvarchar(3)'      => { data_type => 'nvarchar', size => 3 },
  96         'nvarchar(3,2)'    => { data_type => 'nvarchar', size => 3 },
  97         'lvarchar(3)'      => { data_type => 'lvarchar', size => 3 },
  98         'lvarchar(33)'     => { data_type => 'lvarchar', size => 33 },
  99         text               => { data_type => 'text' },
 100
 101         # DateTime Types
 102         date               => { data_type => 'date' },
 103         'date default today'
 104                            => { data_type => 'date', default_value => \'today' },
 105         # XXX support all precisions
 106         'datetime year to fraction(5)',
 107                            => { data_type => 'datetime year to fraction(5)' },
 108         'datetime year to fraction(5) default current year to fraction(5)',
 109                            => { data_type => 'datetime year to fraction(5)', default_value => \'current year to fraction(5)' },
 110         # XXX do interval
 111
 112         # Blob Types
 113         # XXX no way to distinguish opaque types boolean, blob and clob
 114         blob               => { data_type => 'blob' },
 115         clob               => { data_type => 'blob' },
 116
 117         # IDSSECURITYLABEL Type
 118         #
 119         # This requires the DBSECADM privilege and a security policy on the
 120         # table, things I know nothing about.
 121 #        idssecuritylabel   => { data_type => 'idssecuritylabel' },
 122
 123         # List Types
 124         # XXX need to introspect element type too
 125         'list(varchar(20) not null)'
 126                            => { data_type => 'list' },
 127         'multiset(varchar(20) not null)'
 128                            => { data_type => 'multiset' },
 129         'set(varchar(20) not null)'
 130                            => { data_type => 'set' },
 131     },
 132     extra => {
 133         count => 26 * 2,
 134         run   => sub {
 135             ($schema) = @_;
 136
 137             SKIP: {
 138                 skip 'Set the DBICTEST_INFORMIX_EXTRADB_DSN, _USER and _PASS environment variables to run the multi-database tests', 26 * 2
 139                     unless $ENV{DBICTEST_INFORMIX_EXTRADB_DSN};
 140
 141                 $extra_schema = $schema->clone;
 142                 $extra_schema->connection(@ENV{map "DBICTEST_INFORMIX_EXTRADB_$_",
 143                     qw/DSN USER PASS/
 144                 });
 145
 146                 my $dbh1 = $schema->storage->dbh;
 147                 my $dbh2 = $extra_schema->storage->dbh;
 148
 149                 $dbh1->do(<<'EOF');
 150                     CREATE TABLE informix_loader_test4 (
 151                         id SERIAL PRIMARY KEY,
 152                         value VARCHAR(100)
 153                     )
 154 EOF
 155                 $dbh1->do(<<'EOF');
 156                     CREATE TABLE informix_loader_test5 (
 157                         id SERIAL PRIMARY KEY,
 158                         value VARCHAR(100),
 159                         four_id INTEGER REFERENCES informix_loader_test4 (id)
 160                     )
 161 EOF
 162                 $dbh1->do(<<'EOF');
 163 ALTER TABLE informix_loader_test5 ADD CONSTRAINT UNIQUE (four_id) CONSTRAINT loader_test5_uniq
 164 EOF
 165                 $dbh2->do(<<'EOF');
 166                     CREATE TABLE informix_loader_test5 (
 167                         pk SERIAL PRIMARY KEY,
 168                         value VARCHAR(100),
 169                         four_id INTEGER
 170                     )
 171 EOF
 172                 $dbh2->do(<<'EOF');
 173 ALTER TABLE informix_loader_test5 ADD CONSTRAINT UNIQUE (four_id) CONSTRAINT loader_test5_uniq
 174 EOF
 175                 $dbh2->do(<<"EOF");
 176                     CREATE TABLE informix_loader_test6 (
 177                         id SERIAL PRIMARY KEY,
 178                         value VARCHAR(100)
 179                     )
 180 EOF
 181                 $dbh2->do(<<"EOF");
 182                     CREATE TABLE informix_loader_test7 (
 183                         id SERIAL PRIMARY KEY,
 184                         value VARCHAR(100),
 185                         six_id INTEGER UNIQUE REFERENCES informix_loader_test6 (id)
 186                     )
 187 EOF
 188
 189                 my $db1 = db_name($schema);
 190                 my $db2 = db_name($extra_schema);
 191
 192                 my $db1_moniker = join '', map ucfirst lc, split_name to_identifier $db1;
 193                 my $db2_moniker = join '', map ucfirst lc, split_name to_identifier $db2;
 194
 195                 foreach my $db_schema ({ $db1 => '%', $db2 => '%' }, { '%' => '%' }) {
 196                     lives_and {
 197                         my @warns;
 198                         local $SIG{__WARN__} = sub {
 199                             push @warns, $_[0] unless $_[0] =~ /\bcollides\b/
 200                                 || $_[0] =~ /unreferencable/;
 201                         };
 202
 203                         make_schema_at(
 204                             'InformixMultiDatabase',
 205                             {
 206                                 naming => 'current',
 207                                 db_schema => $db_schema,
 208                                 dump_directory => EXTRA_DUMP_DIR,
 209                                 quiet => 1,
 210                             },
 211                             [ $dsn, $user, $password ],
 212                         );
 213
 214                         diag join "\n", @warns if @warns;
 215
 216                         is @warns, 0;
 217                     } "dumped schema for databases $db1 and $db2 with no warnings";
 218
 219                     my $test_schema;
 220
 221                     lives_and {
 222                         ok $test_schema = InformixMultiDatabase->connect($dsn, $user, $password);
 223                     } 'connected test schema';
 224
 225                     my ($rsrc, $rs, $row, $rel_info, %uniqs);
 226
 227                     lives_and {
 228                         ok $rsrc = $test_schema->source("InformixLoaderTest4");
 229                     } 'got source for table in database one';
 230
 231                     is try { $rsrc->column_info('id')->{is_auto_increment} }, 1,
 232                         'column in database one';
 233
 234                     is try { $rsrc->column_info('value')->{data_type} }, 'varchar',
 235                         'column in database one';
 236
 237                     is try { $rsrc->column_info('value')->{size} }, 100,
 238                         'column in database one';
 239
 240                     lives_and {
 241                         ok $rs = $test_schema->resultset("InformixLoaderTest4");
 242                     } 'got resultset for table in database one';
 243
 244                     lives_and {
 245                         ok $row = $rs->create({ value => 'foo' });
 246                     } 'executed SQL on table in database one';
 247
 248                     $rel_info = try { $rsrc->relationship_info("informix_loader_test5") };
 249
 250                     is_deeply $rel_info->{cond}, {
 251                         'foreign.four_id' => 'self.id'
 252                     }, 'relationship in database one';
 253
 254                     is $rel_info->{attrs}{accessor}, 'single',
 255                         'relationship in database one';
 256
 257                     is $rel_info->{attrs}{join_type}, 'LEFT',
 258                         'relationship in database one';
 259
 260                     lives_and {
 261                         ok $rsrc = $test_schema->source("${db1_moniker}InformixLoaderTest5");
 262                     } 'got source for table in database one';
 263
 264                     %uniqs = try { $rsrc->unique_constraints };
 265
 266                     is keys %uniqs, 2,
 267                         'got unique and primary constraint in database one';
 268
 269                     delete $uniqs{primary};
 270
 271                     is_deeply ((values %uniqs)[0], ['four_id'],
 272                         'correct unique constraint in database one');
 273
 274                     lives_and {
 275                         ok $rsrc = $test_schema->source("InformixLoaderTest6");
 276                     } 'got source for table in database two';
 277
 278                     is try { $rsrc->column_info('id')->{is_auto_increment} }, 1,
 279                         'column in database two introspected correctly';
 280
 281                     is try { $rsrc->column_info('value')->{data_type} }, 'varchar',
 282                         'column in database two introspected correctly';
 283
 284                     is try { $rsrc->column_info('value')->{size} }, 100,
 285                         'column in database two introspected correctly';
 286
 287                     lives_and {
 288                         ok $rs = $test_schema->resultset("InformixLoaderTest6");
 289                     } 'got resultset for table in database two';
 290
 291                     lives_and {
 292                         ok $row = $rs->create({ value => 'foo' });
 293                     } 'executed SQL on table in database two';
 294
 295                     $rel_info = try { $rsrc->relationship_info('informix_loader_test7') };
 296
 297                     is_deeply $rel_info->{cond}, {
 298                         'foreign.six_id' => 'self.id'
 299                     }, 'relationship in database two';
 300
 301                     is $rel_info->{attrs}{accessor}, 'single',
 302                         'relationship in database two';
 303
 304                     is $rel_info->{attrs}{join_type}, 'LEFT',
 305                         'relationship in database two';
 306
 307                     lives_and {
 308                         ok $rsrc = $test_schema->source("InformixLoaderTest7");
 309                     } 'got source for table in database two';
 310
 311                     %uniqs = try { $rsrc->unique_constraints };
 312
 313                     is keys %uniqs, 2,
 314                         'got unique and primary constraint in database two';
 315
 316                     delete $uniqs{primary};
 317
 318                     is_deeply ((values %uniqs)[0], ['six_id'],
 319                         'correct unique constraint in database two');
 320                 }
 321             }
 322         },
 323     },
 324 );
 325
 326 if( !$dsn ) {
 327     $tester->skip_tests('You need to set the DBICTEST_INFORMIX_DSN, _USER, and _PASS environment variables');
 328 }
 329 else {
 330     $tester->run_tests();
 331 }
 332
 333 sub db_name {
 334     my $schema = shift;
 335
 336     # When we clone the schema, it still references the original loader, which
 337     # references the original schema.
 338     local $schema->loader->{schema} = $schema;
 339
 340     return $schema->loader->_current_db;
 341 }
 342
 343 END {
 344     if (not $ENV{SCHEMA_LOADER_TESTS_NOCLEANUP}) {
 345         if (my $dbh2 = try { $extra_schema->storage->dbh }) {
 346             my $dbh1 = $schema->storage->dbh;
 347
 348             try {
 349                 $dbh2->do('DROP TABLE informix_loader_test7');
 350                 $dbh2->do('DROP TABLE informix_loader_test6');
 351                 $dbh2->do('DROP TABLE informix_loader_test5');
 352                 $dbh1->do('DROP TABLE informix_loader_test5');
 353                 $dbh1->do('DROP TABLE informix_loader_test4');
 354             }
 355             catch {
 356                 die "Error dropping test tables: $_";
 357             };
 358         }
 359
 360         rmtree EXTRA_DUMP_DIR;
 361     }
 362 }
 363 # vim:et sts=4 sw=4 tw=0: