t/10_07mssql_common.t

   1 use strict;
   2 use warnings;
   3 use Test::More;
   4 use Test::Exception;
   5 use DBIx::Class::Schema::Loader::Utils 'warnings_exist_silent';
   6 use namespace::clean;
   7
   8 # use this if you keep a copy of DBD::Sybase linked to FreeTDS somewhere else
   9 BEGIN {
  10   if (my $lib_dirs = $ENV{DBICTEST_MSSQL_PERL5LIB}) {
  11     unshift @INC, $_ for split /:/, $lib_dirs;
  12   }
  13 }
  14
  15 my ($dsns, $common_version);
  16 for (qw/MSSQL MSSQL_ODBC/) {
  17   next unless $ENV{"DBICTEST_${_}_DSN"};
  18
  19   $dsns->{$_}{dsn} = $ENV{"DBICTEST_${_}_DSN"};
  20   $dsns->{$_}{user} = $ENV{"DBICTEST_${_}_USER"};
  21   $dsns->{$_}{password} = $ENV{"DBICTEST_${_}_PASS"};
  22
  23   require DBI;
  24   my $dbh = DBI->connect (@{$dsns->{$_}}{qw/dsn user password/}, { RaiseError => 1, PrintError => 0} );
  25   my $srv_ver = eval {
  26     $dbh->get_info(18)
  27       ||
  28     $dbh->selectrow_hashref('master.dbo.xp_msver ProductVersion')->{Character_Value}
  29   } || 0;
  30
  31   my ($maj_srv_ver) = $srv_ver =~ /^(\d+)/;
  32
  33   if (! defined $common_version or $common_version > $maj_srv_ver ) {
  34     $common_version = $maj_srv_ver;
  35   }
  36 }
  37
  38 plan skip_all => 'You need to set the DBICTEST_MSSQL_DSN, _USER and _PASS and/or the DBICTEST_MSSQL_ODBC_DSN, _USER and _PASS environment variables'
  39   unless $dsns;
  40
  41 use lib qw(t/lib);
  42 use dbixcsl_common_tests;
  43
  44 my $mssql_2008_new_data_types = {
  45   date     => { data_type => 'date' },
  46   time     => { data_type => 'time' },
  47   'time(0)'=> { data_type => 'time', size => 0 },
  48   'time(1)'=> { data_type => 'time', size => 1 },
  49   'time(2)'=> { data_type => 'time', size => 2 },
  50   'time(3)'=> { data_type => 'time', size => 3 },
  51   'time(4)'=> { data_type => 'time', size => 4 },
  52   'time(5)'=> { data_type => 'time', size => 5 },
  53   'time(6)'=> { data_type => 'time', size => 6 },
  54   'time(7)'=> { data_type => 'time' },
  55   datetimeoffset => { data_type => 'datetimeoffset' },
  56   'datetimeoffset(0)' => { data_type => 'datetimeoffset', size => 0 },
  57   'datetimeoffset(1)' => { data_type => 'datetimeoffset', size => 1 },
  58   'datetimeoffset(2)' => { data_type => 'datetimeoffset', size => 2 },
  59   'datetimeoffset(3)' => { data_type => 'datetimeoffset', size => 3 },
  60   'datetimeoffset(4)' => { data_type => 'datetimeoffset', size => 4 },
  61   'datetimeoffset(5)' => { data_type => 'datetimeoffset', size => 5 },
  62   'datetimeoffset(6)' => { data_type => 'datetimeoffset', size => 6 },
  63   'datetimeoffset(7)' => { data_type => 'datetimeoffset' },
  64   datetime2      => { data_type => 'datetime2' },
  65   'datetime2(0)' => { data_type => 'datetime2', size => 0 },
  66   'datetime2(1)' => { data_type => 'datetime2', size => 1 },
  67   'datetime2(2)' => { data_type => 'datetime2', size => 2 },
  68   'datetime2(3)' => { data_type => 'datetime2', size => 3 },
  69   'datetime2(4)' => { data_type => 'datetime2', size => 4 },
  70   'datetime2(5)' => { data_type => 'datetime2', size => 5 },
  71   'datetime2(6)' => { data_type => 'datetime2', size => 6 },
  72   'datetime2(7)' => { data_type => 'datetime2' },
  73
  74   hierarchyid      => { data_type => 'hierarchyid' },
  75 };
  76
  77 my $tester = dbixcsl_common_tests->new(
  78     vendor      => 'mssql',
  79     auto_inc_pk => 'INTEGER IDENTITY NOT NULL PRIMARY KEY',
  80     default_function_def => 'DATETIME DEFAULT getdate()',
  81     connect_info => [values %$dsns],
  82     preserve_case_mode_is_exclusive => 1,
  83     quote_char => [ qw/[ ]/ ],
  84     basic_date_datatype => ($common_version >= 10) ? 'DATE' : 'SMALLDATETIME',
  85     data_types => {
  86         # http://msdn.microsoft.com/en-us/library/ms187752.aspx
  87
  88         # numeric types
  89         'int identity' => { data_type => 'integer', is_auto_increment => 1 },
  90         bigint   => { data_type => 'bigint' },
  91         int      => { data_type => 'integer' },
  92         integer  => { data_type => 'integer' },
  93         smallint => { data_type => 'smallint' },
  94         tinyint  => { data_type => 'tinyint' },
  95         money       => { data_type => 'money' },
  96         smallmoney  => { data_type => 'smallmoney' },
  97         bit         => { data_type => 'bit' },
  98         real           => { data_type => 'real' },
  99         'float(14)'    => { data_type => 'real' },
 100         'float(24)'    => { data_type => 'real' },
 101         'float(25)'    => { data_type => 'double precision' },
 102         'float(53)'    => { data_type => 'double precision' },
 103         float          => { data_type => 'double precision' },
 104         'double precision'
 105                        => { data_type => 'double precision' },
 106         'numeric(6,3)' => { data_type => 'numeric', size => [6,3] },
 107         'decimal(6,3)' => { data_type => 'decimal', size => [6,3] },
 108         'dec(6,3)'     => { data_type => 'decimal', size => [6,3] },
 109         numeric        => { data_type => 'numeric' },
 110         decimal        => { data_type => 'decimal' },
 111         dec            => { data_type => 'decimal' },
 112
 113         # datetime types
 114         datetime => { data_type => 'datetime' },
 115         # test rewriting getdate() to current_timestamp
 116         'datetime default getdate()'
 117                  => { data_type => 'datetime', default_value => \'current_timestamp',
 118                       original => { default_value => \'getdate()' } },
 119         smalldatetime  => { data_type => 'smalldatetime' },
 120
 121         ($common_version >= 10) ? %$mssql_2008_new_data_types : (),
 122
 123         # string types
 124         char           => { data_type => 'char', size => 1 },
 125         'char(2)'      => { data_type => 'char', size => 2 },
 126         character      => { data_type => 'char', size => 1 },
 127         'character(2)' => { data_type => 'char', size => 2 },
 128         'varchar(2)'   => { data_type => 'varchar', size => 2 },
 129
 130         nchar          => { data_type => 'nchar', size => 1 },
 131         'nchar(2)'     => { data_type => 'nchar', size => 2 },
 132         'nvarchar(2)'  => { data_type => 'nvarchar', size => 2 },
 133
 134         # binary types
 135         'binary'       => { data_type => 'binary', size => 1 },
 136         'binary(2)'    => { data_type => 'binary', size => 2 },
 137         'varbinary(2)' => { data_type => 'varbinary', size => 2 },
 138
 139         # blob types
 140         'varchar(max)'   => { data_type => 'text' },
 141         text             => { data_type => 'text' },
 142
 143         'nvarchar(max)'  => { data_type => 'ntext' },
 144         ntext            => { data_type => 'ntext' },
 145
 146         'varbinary(max)' => { data_type => 'image' },
 147         image            => { data_type => 'image' },
 148
 149         # other types
 150         timestamp        => { data_type => 'timestamp', inflate_datetime => 0 },
 151         rowversion       => { data_type => 'rowversion' },
 152         uniqueidentifier => { data_type => 'uniqueidentifier' },
 153         sql_variant      => { data_type => 'sql_variant' },
 154         xml              => { data_type => 'xml' },
 155     },
 156     extra => {
 157         create => [
 158             q{
 159                 CREATE TABLE [mssql_loader_test1.dot] (
 160                     id INT IDENTITY NOT NULL PRIMARY KEY,
 161                     dat VARCHAR(8)
 162                 )
 163             },
 164             q{
 165                 CREATE TABLE mssql_loader_test3 (
 166                     id INT IDENTITY NOT NULL PRIMARY KEY
 167                 )
 168             },
 169             q{
 170                 CREATE VIEW mssql_loader_test4 AS
 171                 SELECT * FROM mssql_loader_test3
 172             },
 173             # test capitalization of cols in unique constraints and rels
 174             q{ SET QUOTED_IDENTIFIER ON },
 175             q{ SET ANSI_NULLS ON },
 176             q{
 177                 CREATE TABLE [MSSQL_Loader_Test5] (
 178                     [Id] INT IDENTITY NOT NULL PRIMARY KEY,
 179                     [FooCol] INT NOT NULL,
 180                     [BarCol] INT NOT NULL,
 181                     UNIQUE ([FooCol], [BarCol])
 182                 )
 183             },
 184             q{
 185                 CREATE TABLE [MSSQL_Loader_Test6] (
 186                     [Five_Id] INT REFERENCES [MSSQL_Loader_Test5] ([Id])
 187                 )
 188             },
 189         ],
 190         pre_drop_ddl => [
 191             'CREATE TABLE mssql_loader_test3 (id INT IDENTITY NOT NULL PRIMARY KEY)',
 192             'DROP VIEW mssql_loader_test4',
 193         ],
 194         drop   => [
 195             '[mssql_loader_test1.dot]',
 196             'mssql_loader_test3',
 197             'MSSQL_Loader_Test6',
 198             'MSSQL_Loader_Test5',
 199         ],
 200         count  => 10,
 201         run    => sub {
 202             my ($schema, $monikers, $classes) = @_;
 203
 204 # Test that the table above (with '.' in name) gets loaded correctly.
 205             ok((my $rs = eval {
 206                 $schema->resultset($monikers->{'[mssql_loader_test1.dot]'}) }),
 207                 'got a resultset for table with dot in name');
 208
 209             ok((my $from = eval { $rs->result_source->from }),
 210                 'got an $rsrc->from for table with dot in name');
 211
 212             is ref($from), 'SCALAR', '->table with dot in name is a scalar ref';
 213
 214             is eval { $$from }, "[mssql_loader_test1.dot]",
 215                 '->table with dot in name has correct name';
 216
 217 # Test capitalization of columns and unique constraints
 218             ok ((my $rsrc = $schema->resultset($monikers->{mssql_loader_test5})->result_source),
 219                 'got result_source');
 220
 221             if ($schema->_loader->preserve_case) {
 222                 is_deeply [ $rsrc->columns ], [qw/Id FooCol BarCol/],
 223                     'column name case is preserved with case-sensitive collation';
 224
 225                 my %uniqs = $rsrc->unique_constraints;
 226                 delete $uniqs{primary};
 227
 228                 is_deeply ((values %uniqs)[0], [qw/FooCol BarCol/],
 229                     'column name case is preserved in unique constraint with case-sensitive collation');
 230             }
 231             else {
 232                 is_deeply [ $rsrc->columns ], [qw/id foocol barcol/],
 233                     'column names are lowercased for case-insensitive collation';
 234
 235                 my %uniqs = $rsrc->unique_constraints;
 236                 delete $uniqs{primary};
 237
 238                 is_deeply ((values %uniqs)[0], [qw/foocol barcol/],
 239                     'columns in unique constraint lowercased for case-insensitive collation');
 240             }
 241
 242             lives_and {
 243                 my $five_row = $schema->resultset($monikers->{mssql_loader_test5})->new_result({});
 244
 245                 if ($schema->_loader->preserve_case) {
 246                     $five_row->foo_col(1);
 247                     $five_row->bar_col(2);
 248                 }
 249                 else {
 250                     $five_row->foocol(1);
 251                     $five_row->barcol(2);
 252                 }
 253                 $five_row->insert;
 254
 255                 my $six_row = $five_row->create_related('mssql_loader_test6s', {});
 256
 257                 is $six_row->five->id, 1;
 258             } 'relationships for mixed-case tables/columns detected';
 259
 260 # Test that a bad view (where underlying table is gone) is ignored.
 261             my $dbh = $schema->storage->dbh;
 262             $dbh->do("DROP TABLE mssql_loader_test3");
 263
 264             warnings_exist_silent { $schema->rescan }
 265               qr/^Bad table or view 'mssql_loader_test4'/, 'bad view ignored';
 266
 267             throws_ok {
 268                 $schema->resultset($monikers->{mssql_loader_test4})
 269             } qr/Can't find source/,
 270                 'no source registered for bad view';
 271         },
 272     },
 273 );
 274
 275 $tester->run_tests();
 276
 277 # vim:et sts=4 sw=4 tw=0: