t/10_07mssql_common.t

   1 use strict;
   2 use warnings;
   3 use Test::More;
   4 use Test::Exception;
   5 use DBIx::Class::Schema::Loader::Utils 'warnings_exist_silent';
   6 use namespace::clean;
   7
   8 # use this if you keep a copy of DBD::Sybase linked to FreeTDS somewhere else
   9 BEGIN {
  10   if (my $lib_dirs = $ENV{DBICTEST_MSSQL_PERL5LIB}) {
  11     unshift @INC, $_ for split /:/, $lib_dirs;
  12   }
  13 }
  14
  15 my ($dsns, $common_version);
  16 for (qw/MSSQL MSSQL_ODBC MSSQL_ADO/) {
  17   next unless $ENV{"DBICTEST_${_}_DSN"};
  18
  19   $dsns->{$_}{dsn} = $ENV{"DBICTEST_${_}_DSN"};
  20   $dsns->{$_}{user} = $ENV{"DBICTEST_${_}_USER"};
  21   $dsns->{$_}{password} = $ENV{"DBICTEST_${_}_PASS"};
  22
  23   require DBI;
  24   my $dbh = DBI->connect (@{$dsns->{$_}}{qw/dsn user password/}, { RaiseError => 1, PrintError => 0} );
  25   my $srv_ver = eval {
  26     $dbh->get_info(18)
  27       ||
  28     $dbh->selectrow_hashref('master.dbo.xp_msver ProductVersion')->{Character_Value}
  29   } || 0;
  30
  31   my ($maj_srv_ver) = $srv_ver =~ /^(\d+)/;
  32
  33   if (! defined $common_version or $common_version > $maj_srv_ver ) {
  34     $common_version = $maj_srv_ver;
  35   }
  36 }
  37
  38 plan skip_all => 'You need to set the DBICTEST_MSSQL_DSN, _USER and _PASS and/or the DBICTEST_MSSQL_ODBC_DSN, _USER and _PASS environment variables'
  39   unless $dsns;
  40
  41 use lib qw(t/lib);
  42 use dbixcsl_common_tests;
  43
  44 my $mssql_2008_new_data_types = {
  45   date     => { data_type => 'date' },
  46   time     => { data_type => 'time' },
  47   'time(0)'=> { data_type => 'time', size => 0 },
  48   'time(1)'=> { data_type => 'time', size => 1 },
  49   'time(2)'=> { data_type => 'time', size => 2 },
  50   'time(3)'=> { data_type => 'time', size => 3 },
  51   'time(4)'=> { data_type => 'time', size => 4 },
  52   'time(5)'=> { data_type => 'time', size => 5 },
  53   'time(6)'=> { data_type => 'time', size => 6 },
  54   'time(7)'=> { data_type => 'time' },
  55   datetimeoffset => { data_type => 'datetimeoffset' },
  56   'datetimeoffset(0)' => { data_type => 'datetimeoffset', size => 0 },
  57   'datetimeoffset(1)' => { data_type => 'datetimeoffset', size => 1 },
  58   'datetimeoffset(2)' => { data_type => 'datetimeoffset', size => 2 },
  59   'datetimeoffset(3)' => { data_type => 'datetimeoffset', size => 3 },
  60   'datetimeoffset(4)' => { data_type => 'datetimeoffset', size => 4 },
  61   'datetimeoffset(5)' => { data_type => 'datetimeoffset', size => 5 },
  62   'datetimeoffset(6)' => { data_type => 'datetimeoffset', size => 6 },
  63   'datetimeoffset(7)' => { data_type => 'datetimeoffset' },
  64   datetime2      => { data_type => 'datetime2' },
  65   'datetime2(0)' => { data_type => 'datetime2', size => 0 },
  66   'datetime2(1)' => { data_type => 'datetime2', size => 1 },
  67   'datetime2(2)' => { data_type => 'datetime2', size => 2 },
  68   'datetime2(3)' => { data_type => 'datetime2', size => 3 },
  69   'datetime2(4)' => { data_type => 'datetime2', size => 4 },
  70   'datetime2(5)' => { data_type => 'datetime2', size => 5 },
  71   'datetime2(6)' => { data_type => 'datetime2', size => 6 },
  72   'datetime2(7)' => { data_type => 'datetime2' },
  73
  74   hierarchyid      => { data_type => 'hierarchyid' },
  75 };
  76
  77 my $tester = dbixcsl_common_tests->new(
  78     vendor      => 'mssql',
  79     auto_inc_pk => 'INTEGER IDENTITY NOT NULL PRIMARY KEY',
  80     default_function_def => 'DATETIME DEFAULT getdate()',
  81     connect_info => [values %$dsns],
  82     preserve_case_mode_is_exclusive => 1,
  83     quote_char => [ qw/[ ]/ ],
  84     basic_date_datatype => ($common_version >= 10) ? 'DATE' : 'SMALLDATETIME',
  85     data_types => {
  86         # http://msdn.microsoft.com/en-us/library/ms187752.aspx
  87
  88         # numeric types
  89         'int identity' => { data_type => 'integer', is_auto_increment => 1 },
  90         bigint   => { data_type => 'bigint' },
  91         int      => { data_type => 'integer' },
  92         integer  => { data_type => 'integer' },
  93         smallint => { data_type => 'smallint' },
  94         tinyint  => { data_type => 'tinyint' },
  95         money       => { data_type => 'money' },
  96         smallmoney  => { data_type => 'smallmoney' },
  97         bit         => { data_type => 'bit' },
  98         real           => { data_type => 'real' },
  99         'float(14)'    => { data_type => 'real' },
 100         'float(24)'    => { data_type => 'real' },
 101         'float(25)'    => { data_type => 'double precision' },
 102         'float(53)'    => { data_type => 'double precision' },
 103         float          => { data_type => 'double precision' },
 104         'double precision'
 105                        => { data_type => 'double precision' },
 106         'numeric(6)'   => { data_type => 'numeric', size => [6,0] },
 107         'numeric(6,3)' => { data_type => 'numeric', size => [6,3] },
 108         'decimal(6)'   => { data_type => 'decimal', size => [6,0] },
 109         'decimal(6,3)' => { data_type => 'decimal', size => [6,3] },
 110         'dec(6,3)'     => { data_type => 'decimal', size => [6,3] },
 111         numeric        => { data_type => 'numeric' },
 112         decimal        => { data_type => 'decimal' },
 113         dec            => { data_type => 'decimal' },
 114
 115         # datetime types
 116         datetime => { data_type => 'datetime' },
 117         # test rewriting getdate() to current_timestamp
 118         'datetime default getdate()'
 119                  => { data_type => 'datetime', default_value => \'current_timestamp',
 120                       original => { default_value => \'getdate()' } },
 121         smalldatetime  => { data_type => 'smalldatetime' },
 122
 123         ($common_version >= 10) ? %$mssql_2008_new_data_types : (),
 124
 125         # string types
 126         char           => { data_type => 'char', size => 1 },
 127         'char(2)'      => { data_type => 'char', size => 2 },
 128         character      => { data_type => 'char', size => 1 },
 129         'character(2)' => { data_type => 'char', size => 2 },
 130         'varchar(2)'   => { data_type => 'varchar', size => 2 },
 131
 132         nchar          => { data_type => 'nchar', size => 1 },
 133         'nchar(2)'     => { data_type => 'nchar', size => 2 },
 134         'nvarchar(2)'  => { data_type => 'nvarchar', size => 2 },
 135
 136         # binary types
 137         'binary'       => { data_type => 'binary', size => 1 },
 138         'binary(2)'    => { data_type => 'binary', size => 2 },
 139         'varbinary(2)' => { data_type => 'varbinary', size => 2 },
 140
 141         # blob types
 142         'varchar(max)'   => { data_type => 'text' },
 143         text             => { data_type => 'text' },
 144
 145         'nvarchar(max)'  => { data_type => 'ntext' },
 146         ntext            => { data_type => 'ntext' },
 147
 148         'varbinary(max)' => { data_type => 'image' },
 149         image            => { data_type => 'image' },
 150
 151         # other types
 152         timestamp        => { data_type => 'timestamp', inflate_datetime => 0 },
 153         rowversion       => { data_type => 'rowversion' },
 154         uniqueidentifier => { data_type => 'uniqueidentifier' },
 155         sql_variant      => { data_type => 'sql_variant' },
 156         xml              => { data_type => 'xml' },
 157     },
 158     extra => {
 159         create => [
 160             q{
 161                 CREATE TABLE [mssql_loader_test1.dot] (
 162                     id INT IDENTITY NOT NULL PRIMARY KEY,
 163                     dat VARCHAR(8)
 164                 )
 165             },
 166             q{
 167                 CREATE TABLE mssql_loader_test3 (
 168                     id INT IDENTITY NOT NULL PRIMARY KEY
 169                 )
 170             },
 171             q{
 172                 CREATE VIEW mssql_loader_test4 AS
 173                 SELECT * FROM mssql_loader_test3
 174             },
 175             # test capitalization of cols in unique constraints and rels
 176             q{ SET QUOTED_IDENTIFIER ON },
 177             q{ SET ANSI_NULLS ON },
 178             q{
 179                 CREATE TABLE [MSSQL_Loader_Test5] (
 180                     [Id] INT IDENTITY NOT NULL PRIMARY KEY,
 181                     [FooCol] INT NOT NULL,
 182                     [BarCol] INT NOT NULL,
 183                     UNIQUE ([FooCol], [BarCol])
 184                 )
 185             },
 186             q{
 187                 CREATE TABLE [MSSQL_Loader_Test6] (
 188                     [Five_Id] INT REFERENCES [MSSQL_Loader_Test5] ([Id])
 189                 )
 190             },
 191         ],
 192         pre_drop_ddl => [
 193             'CREATE TABLE mssql_loader_test3 (id INT IDENTITY NOT NULL PRIMARY KEY)',
 194             'DROP VIEW mssql_loader_test4',
 195         ],
 196         drop   => [
 197             '[mssql_loader_test1.dot]',
 198             'mssql_loader_test3',
 199             'MSSQL_Loader_Test6',
 200             'MSSQL_Loader_Test5',
 201         ],
 202         count  => 10,
 203         run    => sub {
 204             my ($schema, $monikers, $classes) = @_;
 205
 206 # Test that the table above (with '.' in name) gets loaded correctly.
 207             ok((my $rs = eval {
 208                 $schema->resultset($monikers->{'[mssql_loader_test1.dot]'}) }),
 209                 'got a resultset for table with dot in name');
 210
 211             ok((my $from = eval { $rs->result_source->from }),
 212                 'got an $rsrc->from for table with dot in name');
 213
 214             is ref($from), 'SCALAR', '->table with dot in name is a scalar ref';
 215
 216             is eval { $$from }, "[mssql_loader_test1.dot]",
 217                 '->table with dot in name has correct name';
 218
 219 # Test capitalization of columns and unique constraints
 220             ok ((my $rsrc = $schema->resultset($monikers->{mssql_loader_test5})->result_source),
 221                 'got result_source');
 222
 223             if ($schema->_loader->preserve_case) {
 224                 is_deeply [ $rsrc->columns ], [qw/Id FooCol BarCol/],
 225                     'column name case is preserved with case-sensitive collation';
 226
 227                 my %uniqs = $rsrc->unique_constraints;
 228                 delete $uniqs{primary};
 229
 230                 is_deeply ((values %uniqs)[0], [qw/FooCol BarCol/],
 231                     'column name case is preserved in unique constraint with case-sensitive collation');
 232             }
 233             else {
 234                 is_deeply [ $rsrc->columns ], [qw/id foocol barcol/],
 235                     'column names are lowercased for case-insensitive collation';
 236
 237                 my %uniqs = $rsrc->unique_constraints;
 238                 delete $uniqs{primary};
 239
 240                 is_deeply ((values %uniqs)[0], [qw/foocol barcol/],
 241                     'columns in unique constraint lowercased for case-insensitive collation');
 242             }
 243
 244             lives_and {
 245                 my $five_row = $schema->resultset($monikers->{mssql_loader_test5})->new_result({});
 246
 247                 if ($schema->_loader->preserve_case) {
 248                     $five_row->foo_col(1);
 249                     $five_row->bar_col(2);
 250                 }
 251                 else {
 252                     $five_row->foocol(1);
 253                     $five_row->barcol(2);
 254                 }
 255                 $five_row->insert;
 256
 257                 my $six_row = $five_row->create_related('mssql_loader_test6s', {});
 258
 259                 is $six_row->five->id, 1;
 260             } 'relationships for mixed-case tables/columns detected';
 261
 262 # Test that a bad view (where underlying table is gone) is ignored.
 263             my $dbh = $schema->storage->dbh;
 264             $dbh->do("DROP TABLE mssql_loader_test3");
 265
 266             warnings_exist_silent { $schema->rescan }
 267               qr/^Bad table or view 'mssql_loader_test4'/, 'bad view ignored';
 268
 269             throws_ok {
 270                 $schema->resultset($monikers->{mssql_loader_test4})
 271             } qr/Can't find source/,
 272                 'no source registered for bad view';
 273         },
 274     },
 275 );
 276
 277 $tester->run_tests();
 278
 279 # vim:et sts=4 sw=4 tw=0: