script/dbicdump

   1 #!/usr/bin/perl
   2
   3 =encoding UTF-8
   4
   5 =head1 NAME
   6
   7 dbicdump - Dump a schema using DBIx::Class::Schema::Loader
   8
   9 =head1 SYNOPSIS
  10
  11     dbicdump <configuration_file>
  12     dbicdump [-I <lib-path>] [-o <loader_option>=<value> ] \
  13              <schema_class> <connect_info>
  14
  15 Examples:
  16
  17     $ dbicdump schema.conf
  18
  19     $ dbicdump -o dump_directory=./lib \
  20       -o components='["InflateColumn::DateTime"]' \
  21       MyApp::Schema dbi:SQLite:./foo.db
  22
  23     $ dbicdump -o dump_directory=./lib \
  24       -o components='["InflateColumn::DateTime"]' \
  25       MyApp::Schema dbi:SQLite:./foo.db '{ quote_char => "\"" }'
  26
  27     $ dbicdump -Ilib -o dump_directory=./lib \
  28       -o components='["InflateColumn::DateTime"]' \
  29       -o preserve_case=1 \
  30       MyApp::Schema dbi:mysql:database=foo user pass \
  31       '{ quote_char => "`" }'
  32
  33     $ dbicdump -o dump_directory=./lib \
  34       -o components='["InflateColumn::DateTime"]' \
  35       MyApp::Schema 'dbi:mysql:database=foo;host=domain.tld;port=3306' \
  36       user pass
  37
  38 On Windows that would be:
  39
  40     $ dbicdump -o dump_directory=.\lib ^
  41       -o components="[q{InflateColumn::DateTime}]" ^
  42       -o preserve_case=1 ^
  43       MyApp::Schema dbi:mysql:database=foo user pass ^
  44       "{ quote_char => q{`} }"
  45
  46 Configuration files must have schema_class and connect_info sections,
  47 an example of a general config file is as follows:
  48
  49     schema_class MyApp::Schema
  50
  51     lib /extra/perl/libs
  52
  53     # connection string
  54     <connect_info>
  55         dsn     dbi:mysql:example
  56         user    root
  57         pass    secret
  58     </connect_info>
  59
  60     # dbic loader options
  61     <loader_options>
  62         dump_directory ./lib
  63         components     InflateColumn::DateTime
  64         components     TimeStamp
  65     </loader_options>
  66
  67 Using a config file requires L<Config::Any> installed.
  68
  69 The optional C<lib> key is equivalent to the C<-I> option.
  70
  71 =head1 DESCRIPTION
  72
  73 Dbicdump generates a L<DBIx::Class> schema using
  74 L<DBIx::Class::Schema::Loader/make_schema_at> and dumps it to disk.
  75
  76 You can pass any L<DBIx::Class::Schema::Loader::Base> constructor option using
  77 C<< -o <option>=<value> >>. For convenience, option names will have C<->
  78 replaced with C<_> and values that look like references or quote-like
  79 operators will be C<eval>-ed before being passed to the constructor.
  80
  81 The C<dump_directory> option defaults to the current directory if not
  82 specified.
  83
  84 =head1 SEE ALSO
  85
  86 L<DBIx::Class::Schema::Loader>, L<DBIx::Class>.
  87
  88 =head1 AUTHORS
  89
  90 See L<DBIx::Class::Schema::Loader/AUTHORS>.
  91
  92 =head1 LICENSE
  93
  94 This program is free software; you can redistribute it and/or modify it
  95 under the same terms as Perl itself.
  96
  97 =cut
  98
  99 use strict;
 100 use warnings;
 101 use Getopt::Long;
 102 use Pod::Usage;
 103 use DBIx::Class::Schema::Loader 'make_schema_at';
 104 use namespace::clean;
 105 use DBIx::Class::Schema::Loader::Base ();
 106 use DBIx::Class::Schema::Loader::Optional::Dependencies ();
 107 require lib;
 108
 109 my $loader_options;
 110
 111 Getopt::Long::Configure('gnu_getopt');
 112
 113 GetOptions(
 114     'I=s'                => sub { shift; lib->import(shift) },
 115     'loader-option|o=s%' => \&handle_option,
 116 );
 117
 118 $loader_options->{dump_directory} ||= '.';
 119
 120 if (@ARGV == 1) {
 121     if (not DBIx::Class::Schema::Loader::Optional::Dependencies->req_ok_for('dbicdump_config')) {
 122         die sprintf "You must install the following CPAN modules to use a config file with dbicdump: %s.\n",
 123             DBIx::Class::Schema::Loader::Optional::Dependencies->req_missing_for('dbicdump_config');
 124     }
 125
 126     my $configuration_file = shift @ARGV;
 127
 128     my $configurations = Config::Any->load_files({
 129         use_ext => 1,
 130         flatten_to_hash => 1,
 131         files => [$configuration_file]
 132     });
 133
 134     my $c = (values %$configurations)[0];
 135
 136     unless (keys %{$c->{connect_info}} && $c->{schema_class}) {
 137         pod2usage(1);
 138     }
 139
 140     my @libs;
 141
 142     if ($c->{lib}) {
 143         if (ref $c->{lib}) {
 144             @libs = @{ $c->{lib} };
 145         }
 146
 147         @libs = ($c->{lib});
 148     }
 149
 150     lib->import($_) for @libs;
 151
 152     my ($dsn, $user, $pass, $options) =
 153         map { $c->{connect_info}->{$_} } qw/dsn user pass options/;
 154         $options ||= {};
 155         $c->{loader_options}->{dump_directory} ||=
 156             $loader_options->{dump_directory};
 157
 158     make_schema_at(
 159         $c->{schema_class},
 160         $c->{loader_options} || {},
 161         [ $dsn, $user, $pass, %{$options} ],
 162     );
 163 }
 164 else {
 165     my ($schema_class, @loader_connect_info) = @ARGV
 166         or pod2usage(1);
 167
 168     my $dsn = shift @loader_connect_info;
 169
 170     my ($user, $pass) = $dsn =~ /sqlite/i ? ('', '')
 171         : splice @loader_connect_info, 0, 2;
 172
 173     my @extra_connect_info_opts = map parse_value($_), @loader_connect_info;
 174
 175     make_schema_at(
 176         $schema_class,
 177         $loader_options,
 178         [ $dsn, $user, $pass, @extra_connect_info_opts ],
 179     );
 180 }
 181
 182 exit 0;
 183
 184 sub parse_value {
 185     my $value = shift;
 186
 187     $value = eval $value if $value =~ /^\s*(?:sub\s*\{|q\w?\s*[^\w\s]|[[{])/;
 188
 189     return $value;
 190 }
 191
 192 sub handle_option {
 193     my ($self, $key, $value) = @_;
 194
 195     $key =~ tr/-/_/;
 196     die "Unknown option: $key\n"
 197         unless DBIx::Class::Schema::Loader::Base->can($key);
 198
 199     $value = parse_value $value;
 200
 201     $loader_options->{$key} = $value;
 202 }
 203
 204 1;
 205
 206 __END__