lib/DBIx/Class/Schema/Loader/Utils.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Schema::Loader::Utils;
   3
   4 use strict;
   5 use warnings;
   6 use Test::More;
   7 use String::CamelCase 'wordsplit';
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use Scalar::Util 'looks_like_number';
  10 use namespace::clean;
  11 use Exporter 'import';
  12 use Data::Dumper ();
  13
  14 our @EXPORT_OK = qw/split_name dumper dumper_squashed eval_package_without_redefine_warnings class_path no_warnings warnings_exist warnings_exist_silent slurp_file write_file array_eq sigwarn_silencer/;
  15
  16 use constant BY_CASE_TRANSITION_V7 =>
  17     qr/(?<=[[:lower:]\d])[\W_]*(?=[[:upper:]])|[\W_]+/;
  18
  19 use constant BY_NON_ALPHANUM =>
  20     qr/[\W_]+/;
  21
  22 my $LF   = "\x0a";
  23 my $CRLF = "\x0d\x0a";
  24
  25 sub split_name($;$) {
  26     my ($name, $v) = @_;
  27
  28     my $is_camel_case = $name =~ /[[:upper:]]/ && $name =~ /[[:lower:]]/;
  29
  30     if ((not $v) || $v >= 8) {
  31         return map split(BY_NON_ALPHANUM, $_), wordsplit($name);
  32     }
  33
  34     return split $is_camel_case ? BY_CASE_TRANSITION_V7 : BY_NON_ALPHANUM, $name;
  35 }
  36
  37 sub dumper($) {
  38     my $val = shift;
  39
  40     my $dd = Data::Dumper->new([]);
  41     $dd->Terse(1)->Indent(1)->Useqq(1)->Deparse(1)->Quotekeys(0)->Sortkeys(1);
  42     return $dd->Values([ $val ])->Dump;
  43 }
  44
  45 sub dumper_squashed($) {
  46     my $val = shift;
  47
  48     my $dd = Data::Dumper->new([]);
  49     $dd->Terse(1)->Indent(1)->Useqq(1)->Deparse(1)->Quotekeys(0)->Sortkeys(1)->Indent(0);
  50     return $dd->Values([ $val ])->Dump;
  51 }
  52
  53 # copied from DBIx::Class::_Util, import from there once it's released
  54 sub sigwarn_silencer {
  55   my $pattern = shift;
  56
  57   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  58
  59   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  60
  61   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  62 }
  63
  64 sub eval_package_without_redefine_warnings {
  65     my ($pkg, $code) = @_;
  66
  67     local $SIG{__WARN__} = sigwarn_silencer(qr/^Subroutine \S+ redefined/);
  68
  69     # This hairiness is to handle people using "use warnings FATAL => 'all';"
  70     # in their custom or external content.
  71     my @delete_syms;
  72     my $try_again = 1;
  73
  74     while ($try_again) {
  75         eval $code;
  76
  77         if (my ($sym) = $@ =~ /^Subroutine (\S+) redefined/) {
  78             delete $INC{ +class_path($pkg) };
  79             push @delete_syms, $sym;
  80
  81             foreach my $sym (@delete_syms) {
  82                 no strict 'refs';
  83                 undef *{"${pkg}::${sym}"};
  84             }
  85         }
  86         elsif ($@) {
  87             die $@ if $@;
  88         }
  89         else {
  90             $try_again = 0;
  91         }
  92     }
  93 }
  94
  95 sub class_path {
  96     my $class = shift;
  97
  98     my $class_path = $class;
  99     $class_path =~ s{::}{/}g;
 100     $class_path .= '.pm';
 101
 102     return $class_path;
 103 }
 104
 105 sub no_warnings(&;$) {
 106     my ($code, $test_name) = @_;
 107
 108     my $failed = 0;
 109
 110     my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 111     local $SIG{__WARN__} = sub {
 112         $failed = 1;
 113         $warn_handler->(@_);
 114     };
 115
 116     $code->();
 117
 118     ok ((not $failed), $test_name);
 119 }
 120
 121 sub warnings_exist(&$$) {
 122     my ($code, $re, $test_name) = @_;
 123
 124     my $matched = 0;
 125
 126     my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 127     local $SIG{__WARN__} = sub {
 128         if ($_[0] =~ $re) {
 129             $matched = 1;
 130         }
 131         else {
 132             $warn_handler->(@_)
 133         }
 134     };
 135
 136     $code->();
 137
 138     ok $matched, $test_name;
 139 }
 140
 141 sub warnings_exist_silent(&$$) {
 142     my ($code, $re, $test_name) = @_;
 143
 144     my $matched = 0;
 145
 146     local $SIG{__WARN__} = sub { $matched = 1 if $_[0] =~ $re; };
 147
 148     $code->();
 149
 150     ok $matched, $test_name;
 151 }
 152
 153 sub slurp_file($) {
 154     my $file_name = shift;
 155
 156     open my $fh, '<:encoding(UTF-8)', $file_name,
 157         or croak "Can't open '$file_name' for reading: $!";
 158
 159     my $data = do { local $/; <$fh> };
 160
 161     close $fh;
 162
 163     $data =~ s/$CRLF|$LF/\n/g;
 164
 165     return $data;
 166 }
 167
 168 sub write_file($$) {
 169     my $file_name = shift;
 170
 171     open my $fh, '>:encoding(UTF-8)', $file_name,
 172         or croak "Can't open '$file_name' for writing: $!";
 173
 174     print $fh shift;
 175     close $fh;
 176 }
 177
 178 sub array_eq($$) {
 179     no warnings 'uninitialized';
 180     my ($a, $b) = @_;
 181
 182     return unless @$a == @$b;
 183
 184     for (my $i = 0; $i < @$a; $i++) {
 185         if (looks_like_number $a->[$i]) {
 186             return unless $a->[$i] == $b->[$i];
 187         }
 188         else {
 189             return unless $a->[$i] eq $b->[$i];
 190         }
 191     }
 192     return 1;
 193 }
 194
 195 1;
 196 # vim:et sts=4 sw=4 tw=0: