lib/DBIx/Class/Schema/Loader/RelBuilder.pm

   1 package DBIx::Class::Schema::Loader::RelBuilder;
   2
   3 use strict;
   4 use warnings;
   5 use base 'Class::Accessor::Grouped';
   6 use mro 'c3';
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use Scalar::Util 'weaken';
   9 use DBIx::Class::Schema::Loader::Utils qw/split_name slurp_file/;
  10 use Try::Tiny;
  11 use List::MoreUtils qw/apply uniq any/;
  12 use namespace::clean;
  13 use Lingua::EN::Inflect::Phrase ();
  14 use Lingua::EN::Tagger ();
  15 use String::ToIdentifier::EN ();
  16 use String::ToIdentifier::EN::Unicode ();
  17 use Class::Unload ();
  18 use Class::Inspector ();
  19
  20 our $VERSION = '0.07010';
  21
  22 # Glossary:
  23 #
  24 # remote_relname -- name of relationship from the local table referring to the remote table
  25 # local_relname  -- name of relationship from the remote table referring to the local table
  26 # remote_method  -- relationship type from remote table to local table, usually has_many
  27
  28 =head1 NAME
  29
  30 DBIx::Class::Schema::Loader::RelBuilder - Builds relationships for DBIx::Class::Schema::Loader
  31
  32 =head1 SYNOPSIS
  33
  34 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  35
  36 =head1 DESCRIPTION
  37
  38 This class builds relationships for L<DBIx::Class::Schema::Loader>.  This
  39 is module is not (yet) for external use.
  40
  41 =head1 METHODS
  42
  43 =head2 new
  44
  45 Arguments: $loader object
  46
  47 =head2 generate_code
  48
  49 Arguments:
  50
  51     [
  52         [ local_moniker1 (scalar), fk_info1 (arrayref), uniq_info1 (arrayref) ]
  53         [ local_moniker2 (scalar), fk_info2 (arrayref), uniq_info2 (arrayref) ]
  54         ...
  55     ]
  56
  57 This generates the code for the relationships of each table.
  58
  59 C<local_moniker> is the moniker name of the table which had the REFERENCES
  60 statements.  The fk_info arrayref's contents should take the form:
  61
  62     [
  63         {
  64             local_table    => 'some_table',
  65             local_moniker  => 'SomeTable',
  66             local_columns  => [ 'col2', 'col3' ],
  67             remote_table   => 'another_table_moniker',
  68             remote_moniker => 'AnotherTableMoniker',
  69             remote_columns => [ 'col5', 'col7' ],
  70         },
  71         {
  72             local_table    => 'some_other_table',
  73             local_moniker  => 'SomeOtherTable',
  74             local_columns  => [ 'col1', 'col4' ],
  75             remote_table   => 'yet_another_table_moniker',
  76             remote_moniker => 'YetAnotherTableMoniker',
  77             remote_columns => [ 'col1', 'col2' ],
  78         },
  79         # ...
  80     ],
  81
  82 The uniq_info arrayref's contents should take the form:
  83
  84     [
  85         [
  86             uniq_constraint_name         => [ 'col1', 'col2' ],
  87         ],
  88         [
  89             another_uniq_constraint_name => [ 'col1', 'col2' ],
  90         ],
  91     ],
  92
  93 This method will return the generated relationships as a hashref keyed on the
  94 class names.  The values are arrayrefs of hashes containing method name and
  95 arguments, like so:
  96
  97   {
  98       'Some::Source::Class' => [
  99           { method => 'belongs_to', arguments => [ 'col1', 'Another::Source::Class' ],
 100           { method => 'has_many', arguments => [ 'anothers', 'Yet::Another::Source::Class', 'col15' ],
 101       ],
 102       'Another::Source::Class' => [
 103           # ...
 104       ],
 105       # ...
 106   }
 107
 108 =cut
 109
 110 __PACKAGE__->mk_group_accessors('simple', qw/
 111     loader
 112     schema
 113     inflect_plural
 114     inflect_singular
 115     relationship_attrs
 116     rel_collision_map
 117     rel_name_map
 118     _temp_classes
 119     __tagger
 120 /);
 121
 122 sub new {
 123     my ($class, $loader) = @_;
 124
 125     # from old POD about this constructor:
 126     # C<$schema_class> should be a schema class name, where the source
 127     # classes have already been set up and registered.  Column info,
 128     # primary key, and unique constraints will be drawn from this
 129     # schema for all of the existing source monikers.
 130
 131     # Options inflect_plural and inflect_singular are optional, and
 132     # are better documented in L<DBIx::Class::Schema::Loader::Base>.
 133
 134     my $self = {
 135         loader             => $loader,
 136         schema             => $loader->schema,
 137         inflect_plural     => $loader->inflect_plural,
 138         inflect_singular   => $loader->inflect_singular,
 139         relationship_attrs => $loader->relationship_attrs,
 140         rel_collision_map  => $loader->rel_collision_map,
 141         rel_name_map       => $loader->rel_name_map,
 142         _temp_classes      => [],
 143     };
 144
 145     weaken $self->{loader}; #< don't leak
 146
 147     bless $self => $class;
 148
 149     # validate the relationship_attrs arg
 150     if( defined $self->relationship_attrs ) {
 151         ref $self->relationship_attrs eq 'HASH'
 152             or croak "relationship_attrs must be a hashref";
 153     }
 154
 155     return $self;
 156 }
 157
 158
 159 # pluralize a relationship name
 160 sub _inflect_plural {
 161     my ($self, $relname) = @_;
 162
 163     return '' if !defined $relname || $relname eq '';
 164
 165     my $result;
 166     my $mapped = 0;
 167
 168     if( ref $self->inflect_plural eq 'HASH' ) {
 169         if (exists $self->inflect_plural->{$relname}) {
 170             $result = $self->inflect_plural->{$relname};
 171             $mapped = 1;
 172         }
 173     }
 174     elsif( ref $self->inflect_plural eq 'CODE' ) {
 175         my $inflected = $self->inflect_plural->($relname);
 176         if ($inflected) {
 177             $result = $inflected;
 178             $mapped = 1;
 179         }
 180     }
 181
 182     return ($result, $mapped) if $mapped;
 183
 184     return ($self->_to_PL($relname), 0);
 185 }
 186
 187 # Singularize a relationship name
 188 sub _inflect_singular {
 189     my ($self, $relname) = @_;
 190
 191     return '' if !defined $relname || $relname eq '';
 192
 193     my $result;
 194     my $mapped = 0;
 195
 196     if( ref $self->inflect_singular eq 'HASH' ) {
 197         if (exists $self->inflect_singular->{$relname}) {
 198             $result = $self->inflect_singular->{$relname};
 199             $mapped = 1;
 200         }
 201     }
 202     elsif( ref $self->inflect_singular eq 'CODE' ) {
 203         my $inflected = $self->inflect_singular->($relname);
 204         if ($inflected) {
 205             $result = $inflected;
 206             $mapped = 1;
 207         }
 208     }
 209
 210     return ($result, $mapped) if $mapped;
 211
 212     return ($self->_to_S($relname), 0);
 213 }
 214
 215 sub _to_PL {
 216     my ($self, $name) = @_;
 217
 218     $name =~ s/_/ /g;
 219     my $plural = Lingua::EN::Inflect::Phrase::to_PL($name);
 220     $plural =~ s/ /_/g;
 221
 222     return $plural;
 223 }
 224
 225 sub _to_S {
 226     my ($self, $name) = @_;
 227
 228     $name =~ s/_/ /g;
 229     my $singular = Lingua::EN::Inflect::Phrase::to_S($name);
 230     $singular =~ s/ /_/g;
 231
 232     return $singular;
 233 }
 234
 235 sub _default_relationship_attrs { +{
 236     has_many => {
 237         cascade_delete => 0,
 238         cascade_copy   => 0,
 239     },
 240     might_have => {
 241         cascade_delete => 0,
 242         cascade_copy   => 0,
 243     },
 244     belongs_to => {
 245         on_delete => 'CASCADE',
 246         on_update => 'CASCADE',
 247         is_deferrable => 1,
 248     },
 249 } }
 250
 251 # accessor for options to be passed to each generated relationship
 252 # type.  take single argument, the relationship type name, and returns
 253 # either a hashref (if some options are set), or nothing
 254 sub _relationship_attrs {
 255     my ( $self, $reltype ) = @_;
 256     my $r = $self->relationship_attrs;
 257
 258     my %composite = (
 259         %{ $self->_default_relationship_attrs->{$reltype} || {} },
 260         %{ $r->{all} || {} }
 261     );
 262
 263     if( my $specific = $r->{$reltype} ) {
 264         while( my ($k,$v) = each %$specific ) {
 265             $composite{$k} = $v;
 266         }
 267     }
 268     return \%composite;
 269 }
 270
 271 sub _strip_id_postfix {
 272     my ($self, $name) = @_;
 273
 274     $name =~ s/_?(?:id|ref|cd|code|num)\z//i;
 275
 276     return $name;
 277 }
 278
 279 sub _array_eq {
 280     my ($self, $a, $b) = @_;
 281
 282     return unless @$a == @$b;
 283
 284     for (my $i = 0; $i < @$a; $i++) {
 285         return unless $a->[$i] eq $b->[$i];
 286     }
 287     return 1;
 288 }
 289
 290 sub _remote_attrs {
 291     my ($self, $local_moniker, $local_cols) = @_;
 292
 293     # get our base set of attrs from _relationship_attrs, if present
 294     my $attrs = $self->_relationship_attrs('belongs_to') || {};
 295
 296     # If the referring column is nullable, make 'belongs_to' an
 297     # outer join, unless explicitly set by relationship_attrs
 298     my $nullable = grep { $self->schema->source($local_moniker)->column_info($_)->{is_nullable} } @$local_cols;
 299     $attrs->{join_type} = 'LEFT' if $nullable && !defined $attrs->{join_type};
 300
 301     return $attrs;
 302 }
 303
 304 sub _sanitize_name {
 305     my ($self, $name) = @_;
 306
 307     $name =~ s/\W+/_/g;
 308
 309     return $name;
 310 }
 311
 312 sub _normalize_name {
 313     my ($self, $name) = @_;
 314
 315     $name = $self->_sanitize_name($name);
 316
 317     my @words = split_name $name;
 318
 319     return join '_', map lc, @words;
 320 }
 321
 322 sub _remote_relname {
 323     my ($self, $remote_table, $cond) = @_;
 324
 325     my $remote_relname;
 326     # for single-column case, set the remote relname to the column
 327     # name, to make filter accessors work, but strip trailing _id
 328     if(scalar keys %{$cond} == 1) {
 329         my ($col) = values %{$cond};
 330         $col = $self->_strip_id_postfix($self->_normalize_name($col));
 331         ($remote_relname) = $self->_inflect_singular($col);
 332     }
 333     else {
 334         ($remote_relname) = $self->_inflect_singular($self->_normalize_name($remote_table));
 335     }
 336
 337     return $remote_relname;
 338 }
 339
 340 sub _resolve_relname_collision {
 341     my ($self, $moniker, $cols, $relname) = @_;
 342
 343     return $relname if $relname eq 'id'; # this shouldn't happen, but just in case
 344
 345     my $table = $self->loader->moniker_to_table->{$moniker};
 346
 347     if ($self->loader->_is_result_class_method($relname, $table)) {
 348         if (my $map = $self->rel_collision_map) {
 349             for my $re (keys %$map) {
 350                 if (my @matches = $relname =~ /$re/) {
 351                     return sprintf $map->{$re}, @matches;
 352                 }
 353             }
 354         }
 355
 356         my $new_relname = $relname;
 357         while ($self->loader->_is_result_class_method($new_relname, $table)) {
 358             $new_relname .= '_rel'
 359         }
 360
 361         warn <<"EOF";
 362 Relationship '$relname' in source '$moniker' for columns '@{[ join ',', @$cols ]}' collides with an inherited method. Renaming to '$new_relname'.
 363 See "RELATIONSHIP NAME COLLISIONS" in perldoc DBIx::Class::Schema::Loader::Base .
 364 EOF
 365
 366         return $new_relname;
 367     }
 368
 369     return $relname;
 370 }
 371
 372 sub generate_code {
 373     my ($self, $tables) = @_;
 374
 375     # make a copy to destroy
 376     my @tables = @$tables;
 377
 378     my $all_code = {};
 379
 380     while (my ($local_moniker, $rels, $uniqs) = @{ shift @tables || [] }) {
 381         my $local_class = $self->schema->class($local_moniker);
 382
 383         my %counters;
 384         foreach my $rel (@$rels) {
 385             next if !$rel->{remote_source};
 386             $counters{$rel->{remote_source}}++;
 387         }
 388
 389         foreach my $rel (@$rels) {
 390             my $remote_moniker = $rel->{remote_source}
 391                 or next;
 392
 393             my $remote_class   = $self->schema->class($remote_moniker);
 394             my $remote_obj     = $self->schema->source($remote_moniker);
 395             my $remote_cols    = $rel->{remote_columns} || [ $remote_obj->primary_columns ];
 396
 397             my $local_cols     = $rel->{local_columns};
 398
 399             if($#$local_cols != $#$remote_cols) {
 400                 croak "Column count mismatch: $local_moniker (@$local_cols) "
 401                     . "$remote_moniker (@$remote_cols)";
 402             }
 403
 404             my %cond;
 405             foreach my $i (0 .. $#$local_cols) {
 406                 $cond{$remote_cols->[$i]} = $local_cols->[$i];
 407             }
 408
 409             my ( $local_relname, $remote_relname, $remote_method ) =
 410                 $self->_relnames_and_method( $local_moniker, $rel, \%cond,  $uniqs, \%counters );
 411             my $local_method  = 'belongs_to';
 412
 413             ($remote_relname) = $self->_rel_name_map($remote_relname, $local_method, $local_class, $local_moniker, $local_cols, $remote_class, $remote_moniker, $remote_cols);
 414             ($local_relname)  = $self->_rel_name_map($local_relname, $remote_method, $remote_class, $remote_moniker, $remote_cols, $local_class, $local_moniker, $local_cols);
 415
 416             $remote_relname   = $self->_resolve_relname_collision($local_moniker,  $local_cols,  $remote_relname);
 417             $local_relname    = $self->_resolve_relname_collision($remote_moniker, $remote_cols, $local_relname);
 418
 419             push(@{$all_code->{$local_class}},
 420                 { method => $local_method,
 421                   args => [ $remote_relname,
 422                             $remote_class,
 423                             \%cond,
 424                             $self->_remote_attrs($local_moniker, $local_cols),
 425                   ],
 426                   extra => {
 427                       local_class    => $local_class,
 428                       local_moniker  => $local_moniker,
 429                       remote_moniker => $remote_moniker,
 430                   },
 431                 }
 432             );
 433
 434             my %rev_cond = reverse %cond;
 435             for (keys %rev_cond) {
 436                 $rev_cond{"foreign.$_"} = "self.".$rev_cond{$_};
 437                 delete $rev_cond{$_};
 438             }
 439
 440             push(@{$all_code->{$remote_class}},
 441                 { method => $remote_method,
 442                   args => [ $local_relname,
 443                             $local_class,
 444                             \%rev_cond,
 445                             $self->_relationship_attrs($remote_method),
 446                   ],
 447                   extra => {
 448                       local_class    => $remote_class,
 449                       local_moniker  => $remote_moniker,
 450                       remote_moniker => $local_moniker,
 451                   },
 452                 }
 453             );
 454         }
 455     }
 456
 457     # disambiguate rels with the same name
 458     foreach my $class (keys %$all_code) {
 459         my $dups = $self->_duplicates($all_code->{$class});
 460
 461         $self->_disambiguate($all_code->{$class}, $dups) if $dups;
 462     }
 463
 464     $self->_cleanup;
 465
 466     return $all_code;
 467 }
 468
 469 sub _duplicates {
 470     my ($self, $rels) = @_;
 471
 472     my @rels = map [ $_->{args}[0] => $_ ], @$rels;
 473     my %rel_names;
 474     $rel_names{$_}++ foreach map $_->[0], @rels;
 475
 476     my @dups = grep $rel_names{$_} > 1, keys %rel_names;
 477
 478     my %dups;
 479
 480     foreach my $dup (@dups) {
 481         $dups{$dup} = [ map $_->[1], grep { $_->[0] eq $dup } @rels ];
 482     }
 483
 484     return if not %dups;
 485
 486     return \%dups;
 487 }
 488
 489 sub _tagger {
 490     my $self = shift;
 491
 492     $self->__tagger(Lingua::EN::Tagger->new) unless $self->__tagger;
 493
 494     return $self->__tagger;
 495 }
 496
 497 sub _adjectives {
 498     my ($self, @cols) = @_;
 499
 500     my @adjectives;
 501
 502     foreach my $col (@cols) {
 503         my @words = split_name $col;
 504
 505         my $tagged = $self->_tagger->get_readable(join ' ', @words);
 506
 507         push @adjectives, $tagged =~ m{\G(\w+)/JJ\s+}g;
 508     }
 509
 510     return @adjectives;
 511 }
 512
 513 sub _name_to_identifier {
 514     my ($self, $name) = @_;
 515
 516     my $to_identifier = $self->loader->naming->{force_ascii} ?
 517         \&String::ToIdentifier::EN::to_identifier
 518         : \&String::ToIdentifier::EN::Unicode::to_identifier;
 519
 520     return join '_', map lc, split_name $to_identifier->($name, '_');
 521 }
 522
 523 sub _disambiguate {
 524     my ($self, $all_rels, $dups) = @_;
 525
 526     DUP: foreach my $dup (keys %$dups) {
 527         my @rels = @{ $dups->{$dup} };
 528
 529         # Check if there are rels to the same table name in different
 530         # schemas/databases, if so qualify them.
 531         my @tables = map $self->loader->moniker_to_table->{$_->{extra}{remote_moniker}},
 532                         @rels;
 533
 534         # databases are different, prepend database
 535         if ($tables[0]->can('database') && (uniq map $_->database||'', @tables) > 1) {
 536             # If any rels are in the same database, we have to distinguish by
 537             # both schema and database.
 538             my %db_counts;
 539             $db_counts{$_}++ for map $_->database, @tables;
 540             my $use_schema = any { $_ > 1 } values %db_counts;
 541
 542             foreach my $i (0..$#rels) {
 543                 my $rel   = $rels[$i];
 544                 my $table = $tables[$i];
 545
 546                 $rel->{args}[0] = $self->_name_to_identifier($table->database)
 547                     . ($use_schema ? ('_' . $self->name_to_identifier($table->schema)) : '')
 548                     . '_' . $rel->{args}[0];
 549             }
 550             next DUP;
 551         }
 552         # schemas are different, prepend schema
 553         elsif ((uniq map $_->schema||'', @tables) > 1) {
 554             foreach my $i (0..$#rels) {
 555                 my $rel   = $rels[$i];
 556                 my $table = $tables[$i];
 557
 558                 $rel->{args}[0] = $self->_name_to_identifier($table->schema)
 559                     . '_' . $rel->{args}[0];
 560             }
 561             next DUP;
 562         }
 563
 564         foreach my $rel (@rels) {
 565             next if $rel->{method} eq 'belongs_to';
 566
 567             my @to_cols = apply { s/^foreign\.//i }
 568                 keys %{ $rel->{args}[2] };
 569
 570             my @adjectives = $self->_adjectives(@to_cols);
 571
 572             # If there are no adjectives, and there is only one might_have
 573             # rel to that class, we hardcode 'active'.
 574
 575             my $to_class = $rel->{args}[1];
 576
 577             if ((not @adjectives)
 578                 && (grep { $_->{method} eq 'might_have'
 579                            && $_->{args}[1] eq $to_class } @$all_rels) == 1) {
 580
 581                 @adjectives = 'active';
 582             }
 583
 584             if (@adjectives) {
 585                 my $rel_name = join '_', sort(@adjectives), $rel->{args}[0];
 586
 587                 ($rel_name) = $rel->{method} eq 'might_have' ?
 588                     $self->_inflect_singular($rel_name)
 589                     :
 590                     $self->_inflect_plural($rel_name);
 591
 592                 my ($local_class, $local_moniker, $remote_moniker)
 593                     = @{ $rel->{extra} }
 594                         {qw/local_class local_moniker remote_moniker/};
 595
 596                 my @from_cols = apply { s/^self\.//i }
 597                     values %{ $rel->{args}[2] };
 598
 599                 ($rel_name) = $self->_rel_name_map($rel_name, $rel->{method}, $local_class, $local_moniker, \@from_cols, $to_class, $remote_moniker, \@to_cols);
 600
 601                 $rel_name = $self->_resolve_relname_collision($local_moniker, \@from_cols, $rel_name);
 602
 603                 $rel->{args}[0] = $rel_name;
 604             }
 605         }
 606     }
 607
 608     # Check again for duplicates, since the heuristics above may not have resolved them all.
 609
 610     if ($dups = $self->_duplicates($all_rels)) {
 611         foreach my $dup (keys %$dups) {
 612             # sort by method
 613             my @rels = map $_->[1], sort { $a->[0] <=> $b->[0] } map [
 614                 ($_->{method} eq 'belongs_to' ? 3 : $_->{method} eq 'has_many' ? 2 : 1), $_
 615             ], @{ $dups->{$dup} };
 616
 617             my $rel_num = 2;
 618
 619             foreach my $rel (@rels[1 .. $#rels]) {
 620                 my $inflect_type = $rel->{method} eq 'has_many' ?
 621                     'inflect_plural'
 622                     :
 623                     'inflect_singular';
 624
 625                 my $inflect_method = "_$inflect_type";
 626
 627                 my $relname_new_uninflected = $rel->{args}[0] . "_$rel_num";
 628
 629                 $rel_num++;
 630
 631                 my ($local_class, $local_moniker, $remote_moniker)
 632                     = @{ $rel->{extra} }
 633                         {qw/local_class local_moniker remote_moniker/};
 634
 635                 my @from_cols = apply { s/^self\.//i }
 636                     values %{ $rel->{args}[2] };
 637
 638                 my @to_cols = apply { s/^foreign\.//i }
 639                     keys %{ $rel->{args}[2] };
 640
 641                 my $to_class = $rel->{args}[1];
 642
 643                 my ($relname_new, $inflect_mapped) =
 644                     $self->$inflect_method($relname_new_uninflected);
 645
 646                 my $rel_name_mapped;
 647
 648                 ($relname_new, $rel_name_mapped) = $self->_rel_name_map($relname_new, $rel->{method}, $local_class, $local_moniker, \@from_cols, $to_class, $remote_moniker, \@to_cols);
 649
 650                 my $mapped = $inflect_mapped || $rel_name_mapped;
 651
 652                 warn <<"EOF" unless $mapped;
 653 Could not find a proper name for relationship '$relname_new' in source
 654 '$local_moniker' for columns '@{[ join ',', @from_cols ]}'. Supply a value in
 655 '$inflect_type' or 'rel_name_map' for '$relname_new_uninflected' to name this
 656 relationship.
 657 EOF
 658
 659                 $relname_new = $self->_resolve_relname_collision($local_moniker, \@from_cols, $relname_new);
 660
 661                 $rel->{args}[0] = $relname_new;
 662             }
 663         }
 664     }
 665 }
 666
 667 sub _relnames_and_method {
 668     my ( $self, $local_moniker, $rel, $cond, $uniqs, $counters ) = @_;
 669
 670     my $remote_moniker  = $rel->{remote_source};
 671     my $remote_obj      = $self->schema->source( $remote_moniker );
 672     my $remote_class    = $self->schema->class(  $remote_moniker );
 673     my $remote_relname  = $self->_remote_relname( $rel->{remote_table}, $cond);
 674
 675     my $local_cols      = $rel->{local_columns};
 676     my $local_table     = $rel->{local_table};
 677     my $local_class     = $self->schema->class($local_moniker);
 678     my $local_source    = $self->schema->source($local_moniker);
 679
 680     my $local_relname_uninflected = $self->_normalize_name($local_table);
 681     my ($local_relname) = $self->_inflect_plural($self->_normalize_name($local_table));
 682
 683     my $remote_method = 'has_many';
 684
 685     # If the local columns have a UNIQUE constraint, this is a one-to-one rel
 686     if ($self->_array_eq([ $local_source->primary_columns ], $local_cols) ||
 687             grep { $self->_array_eq($_->[1], $local_cols) } @$uniqs) {
 688         $remote_method   = 'might_have';
 689         ($local_relname) = $self->_inflect_singular($local_relname_uninflected);
 690     }
 691
 692     # If more than one rel between this pair of tables, use the local
 693     # col names to distinguish, unless the rel was created previously.
 694     if ($counters->{$remote_moniker} > 1) {
 695         my $relationship_exists = 0;
 696
 697         if (-f (my $existing_remote_file = $self->loader->get_dump_filename($remote_class))) {
 698             my $class = "${remote_class}Temporary";
 699
 700             if (not Class::Inspector->loaded($class)) {
 701                 my $code = slurp_file $existing_remote_file;
 702
 703                 $code =~ s/(?<=package $remote_class)/Temporary/g;
 704
 705                 $code =~ s/__PACKAGE__->meta->make_immutable[^;]*;//g;
 706
 707                 eval $code;
 708                 die $@ if $@;
 709
 710                 push @{ $self->_temp_classes }, $class;
 711             }
 712
 713             if ($class->has_relationship($local_relname)) {
 714                 my $rel_cols = [ sort { $a cmp $b } apply { s/^foreign\.//i }
 715                     (keys %{ $class->relationship_info($local_relname)->{cond} }) ];
 716
 717                 $relationship_exists = 1 if $self->_array_eq([ sort @$local_cols ], $rel_cols);
 718             }
 719         }
 720
 721         if (not $relationship_exists) {
 722             my $colnames = q{_} . $self->_normalize_name(join '_', @$local_cols);
 723             $remote_relname .= $colnames if keys %$cond > 1;
 724
 725             $local_relname = $self->_strip_id_postfix($self->_normalize_name($local_table . $colnames));
 726
 727             $local_relname_uninflected = $local_relname;
 728             ($local_relname) = $self->_inflect_plural($local_relname);
 729
 730             # if colnames were added and this is a might_have, re-inflect
 731             if ($remote_method eq 'might_have') {
 732                 ($local_relname) = $self->_inflect_singular($local_relname_uninflected);
 733             }
 734         }
 735     }
 736
 737     return ($local_relname, $remote_relname, $remote_method);
 738 }
 739
 740 sub _rel_name_map {
 741     my ($self, $relname, $method, $local_class, $local_moniker, $local_cols,
 742         $remote_class, $remote_moniker, $remote_cols) = @_;
 743
 744     my $info = {
 745         name           => $relname,
 746         type           => $method,
 747         local_class    => $local_class,
 748         local_moniker  => $local_moniker,
 749         local_columns  => $local_cols,
 750         remote_class   => $remote_class,
 751         remote_moniker => $remote_moniker,
 752         remote_columns => $remote_cols,
 753     };
 754
 755     my $new_name = $relname;
 756
 757     my $map = $self->rel_name_map;
 758     my $mapped = 0;
 759
 760     if ('HASH' eq ref($map)) {
 761         my $name = $info->{name};
 762         my $moniker = $info->{local_moniker};
 763         if ($map->{$moniker} and 'HASH' eq ref($map->{$moniker})
 764             and $map->{$moniker}{$name}
 765         ) {
 766             $new_name = $map->{$moniker}{$name};
 767             $mapped   = 1;
 768         }
 769         elsif ($map->{$name} and not 'HASH' eq ref($map->{$name})) {
 770             $new_name = $map->{$name};
 771             $mapped   = 1;
 772         }
 773     }
 774     elsif ('CODE' eq ref($map)) {
 775         my $name = $map->($info);
 776         if ($name) {
 777             $new_name = $name;
 778             $mapped   = 1;
 779         }
 780     }
 781
 782     return ($new_name, $mapped);
 783 }
 784
 785 sub _cleanup {
 786     my $self = shift;
 787
 788     for my $class (@{ $self->_temp_classes }) {
 789         Class::Unload->unload($class);
 790     }
 791
 792     $self->_temp_classes([]);
 793 }
 794
 795 =head1 AUTHOR
 796
 797 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 798
 799 =head1 LICENSE
 800
 801 This library is free software; you can redistribute it and/or modify it under
 802 the same terms as Perl itself.
 803
 804 =cut
 805
 806 1;
 807 # vim:et sts=4 sw=4 tw=0: